lisp/url/url-handlers.el

   1 ;;; url-handlers.el --- file-name-handler stuff for URL loading
   2
   3 ;; Copyright (C) 1996-1999, 2004-2014 Free Software Foundation, Inc.
   4
   5 ;; Keywords: comm, data, processes, hypermedia
   6
   7 ;; This file is part of GNU Emacs.
   8 ;;
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 ;; (require 'url)
  27 (require 'url-parse)
  28 ;; (require 'url-util)
  29 (eval-when-compile (require 'mm-decode))
  30 ;; (require 'mailcap)
  31 ;; The following are autoloaded instead of `require'd to avoid eagerly
  32 ;; loading all of URL when turning on url-handler-mode in the .emacs.
  33 (autoload 'url-expand-file-name "url-expand" "Convert url to a fully specified url, and canonicalize it.")
  34 (autoload 'mm-dissect-buffer "mm-decode" "Dissect the current buffer and return a list of MIME handles.")
  35 (autoload 'url-scheme-get-property "url-methods" "Get property of a URL SCHEME.")
  36
  37 ;; Always used after mm-dissect-buffer and defined in the same file.
  38 (declare-function mm-save-part-to-file "mm-decode" (handle file))
  39 (declare-function mm-destroy-parts "mm-decode" (handles))
  40 ;; mm-decode loads mm-bodies.
  41 (declare-function mm-decode-string "mm-bodies" (string charset))
  42 ;; mm-decode loads mail-parse.
  43 (declare-function mail-content-type-get "mail-parse" (ct attribute))
  44
  45 ;; Implementation status
  46 ;; ---------------------
  47 ;; Function                             Status
  48 ;; ------------------------------------------------------------
  49 ;; add-name-to-file                     Needs DAV Bindings
  50 ;; copy-file                            Broken (assumes 1st item is URL)
  51 ;; delete-directory                     Finished (DAV)
  52 ;; delete-file                          Finished (DAV)
  53 ;; diff-latest-backup-file
  54 ;; directory-file-name                  unnecessary (what about VMS)?
  55 ;; directory-files                      Finished (DAV)
  56 ;; dired-call-process
  57 ;; dired-compress-file
  58 ;; dired-uncache
  59 ;; expand-file-name                     Finished
  60 ;; file-accessible-directory-p
  61 ;; file-attributes                      Finished, better with DAV
  62 ;; file-directory-p                     Needs DAV, finished
  63 ;; file-executable-p                    Finished
  64 ;; file-exists-p                        Finished
  65 ;; file-local-copy
  66 ;; file-modes
  67 ;; file-name-all-completions            Finished (DAV)
  68 ;; file-name-as-directory
  69 ;; file-name-completion                 Finished (DAV)
  70 ;; file-name-directory
  71 ;; file-name-nondirectory
  72 ;; file-name-sans-versions              why?
  73 ;; file-newer-than-file-p
  74 ;; file-ownership-preserved-p           No way to know
  75 ;; file-readable-p                      Finished
  76 ;; file-regular-p                       !directory_p
  77 ;; file-remote-p                        Finished
  78 ;; file-symlink-p                       Needs DAV bindings
  79 ;; file-truename                        Needs DAV bindings
  80 ;; file-writable-p                      Check for LOCK?
  81 ;; find-backup-file-name                why?
  82 ;; get-file-buffer                      why?
  83 ;; insert-directory                     Use DAV
  84 ;; insert-file-contents                 Finished
  85 ;; load
  86 ;; make-directory                       Finished (DAV)
  87 ;; make-symbolic-link                   Needs DAV bindings
  88 ;; rename-file                          Finished (DAV)
  89 ;; set-file-modes                       Use mod_dav specific executable flag?
  90 ;; set-visited-file-modtime             Impossible?
  91 ;; shell-command                        Impossible?
  92 ;; unhandled-file-name-directory
  93 ;; vc-registered                        Finished (DAV)
  94 ;; verify-visited-file-modtime
  95 ;; write-region
  96
  97 (defvar url-handler-regexp) ; defined below to avoid recursive load (revno:108572)
  98
  99 ;;;###autoload
 100 (define-minor-mode url-handler-mode
 101   "Toggle using `url' library for URL filenames (URL Handler mode).
 102 With a prefix argument ARG, enable URL Handler mode if ARG is
 103 positive, and disable it otherwise.  If called from Lisp, enable
 104 the mode if ARG is omitted or nil."
 105   :global t :group 'url
 106   ;; Remove old entry, if any.
 107   (setq file-name-handler-alist
 108         (delq (rassq 'url-file-handler file-name-handler-alist)
 109               file-name-handler-alist))
 110   (if url-handler-mode
 111       (push (cons url-handler-regexp 'url-file-handler)
 112             file-name-handler-alist)))
 113
 114 (defcustom url-handler-regexp "\\`\\(https?\\|ftp\\|file\\|nfs\\)://"
 115   "Regular expression for URLs handled by `url-handler-mode'.
 116 When URL Handler mode is enabled, this regular expression is
 117 added to `file-name-handler-alist'.
 118
 119 Some valid URL protocols just do not make sense to visit
 120 interactively \(about, data, info, irc, mailto, etc\).  This
 121 regular expression avoids conflicts with local files that look
 122 like URLs \(Gnus is particularly bad at this\)."
 123   :group 'url
 124   :type 'regexp
 125   :set (lambda (symbol value)
 126          (let ((enable url-handler-mode))
 127            (url-handler-mode 0)
 128            (set-default symbol value)
 129            (if enable
 130                (url-handler-mode)))))
 131
 132 (defun url-run-real-handler (operation args)
 133   (let ((inhibit-file-name-handlers (cons 'url-file-handler
 134                                           (if (eq operation inhibit-file-name-operation)
 135                                               inhibit-file-name-handlers)))
 136         (inhibit-file-name-operation operation))
 137     (apply operation args)))
 138
 139 ;;;###autoload
 140 (defun url-file-handler (operation &rest args)
 141   "Function called from the `file-name-handler-alist' routines.
 142 OPERATION is what needs to be done (`file-exists-p', etc).  ARGS are
 143 the arguments that would have been passed to OPERATION."
 144   (let ((fn (get operation 'url-file-handlers))
 145         (val nil)
 146         (hooked nil))
 147     (if (and (not fn) (intern-soft (format "url-%s" operation))
 148              (fboundp (intern-soft (format "url-%s" operation))))
 149         (error "Missing URL handler mapping for %s" operation))
 150     (if fn
 151         (setq hooked t
 152               val (save-match-data (apply fn args)))
 153       (setq hooked nil
 154             val (url-run-real-handler operation args)))
 155     (url-debug 'handlers "%s %S%S => %S" (if hooked "Hooked" "Real")
 156                operation args val)
 157     val))
 158
 159 (defun url-file-handler-identity (&rest args)
 160   ;; Identity function
 161   (car args))
 162
 163 ;; These are operations that we can fully support
 164 (put 'file-readable-p 'url-file-handlers 'url-file-exists-p)
 165 (put 'substitute-in-file-name 'url-file-handlers 'url-file-handler-identity)
 166 (put 'file-name-absolute-p 'url-file-handlers (lambda (&rest ignored) t))
 167 (put 'expand-file-name 'url-file-handlers 'url-handler-expand-file-name)
 168 (put 'directory-file-name 'url-file-handlers 'url-handler-directory-file-name)
 169 (put 'unhandled-file-name-directory 'url-file-handlers 'url-handler-unhandled-file-name-directory)
 170 (put 'file-remote-p 'url-file-handlers 'url-handler-file-remote-p)
 171 ;; (put 'file-name-as-directory 'url-file-handlers 'url-handler-file-name-as-directory)
 172
 173 ;; These are operations that we do not support yet (DAV!!!)
 174 (put 'file-writable-p 'url-file-handlers 'ignore)
 175 (put 'file-symlink-p 'url-file-handlers 'ignore)
 176 ;; Just like for ange-ftp: let's not waste time trying to look for RCS/foo,v
 177 ;; files and such since we can't do anything clever with them anyway.
 178 (put 'vc-registered 'url-file-handlers 'ignore)
 179
 180 (defun url-handler-expand-file-name (file &optional base)
 181   ;; When we see "/foo/bar" in a file whose working dir is "http://bla/bla",
 182   ;; there are two interpretations possible: either it's a local "/foo/bar"
 183   ;; or it's "http:/bla/foo/bar".  When working with URLs, the second
 184   ;; interpretation is the right one, but when working with Emacs file
 185   ;; names, the first is preferred.
 186   (if (file-name-absolute-p file)
 187       (expand-file-name file "/")
 188     (url-expand-file-name file base)))
 189
 190 ;; directory-file-name and file-name-as-directory are kind of hard to
 191 ;; implement really right for URLs since URLs can have repeated / chars.
 192 ;; We'd want the following behavior:
 193 ;; idempotence: (d-f-n (d-f-n X) == (d-f-n X)
 194 ;; idempotence: (f-n-a-d (f-n-a-d X) == (f-n-a-d X)
 195 ;; reversible:  (d-f-n (f-n-a-d (d-f-n X))) == (d-f-n X)
 196 ;; reversible:  (f-n-a-d (d-f-n (f-n-a-d X))) == (f-n-a-d X)
 197 (defun url-handler-directory-file-name (dir)
 198   ;; When there's more than a single /, just don't touch the slashes at all.
 199   (if (string-match "//\\'" dir) dir
 200     (url-run-real-handler 'directory-file-name (list dir))))
 201
 202 (defun url-handler-unhandled-file-name-directory (filename)
 203   (let ((url (url-generic-parse-url filename)))
 204     (if (equal (url-type url) "file")
 205         ;; `file' URLs are actually local.  The filename part may be ""
 206         ;; which really stands for "/".
 207         ;; FIXME: maybe we should check that the host part is "" or "localhost"
 208         ;; or some name that represents the local host?
 209         (or (file-name-directory (url-filename url)) "/")
 210       ;; All other URLs are not expected to be directly accessible from
 211       ;; a local process.
 212       nil)))
 213
 214 (defun url-handler-file-remote-p (filename &optional identification connected)
 215   (let ((url (url-generic-parse-url filename)))
 216     (if (and (url-type url) (not (equal (url-type url) "file")))
 217         ;; Maybe we can find a suitable check for CONNECTED.  For now,
 218         ;; we ignore it.
 219         (cond
 220          ((eq identification 'method) (url-type url))
 221          ((eq identification 'user) (url-user url))
 222          ((eq identification 'host) (url-host url))
 223          ((eq identification 'localname) (url-filename url))
 224          (t (url-recreate-url
 225              (url-parse-make-urlobj (url-type url) (url-user url) nil
 226                                     (url-host url) (url-port url)))))
 227       ;; If there is no URL type, or it is a "file://" URL, the
 228       ;; filename is expected to be non remote.  A more subtle check
 229       ;; for "file://" URLs could be applied, as said in
 230       ;; `url-handler-unhandled-file-name-directory'.
 231       nil)))
 232
 233 ;; The actual implementation
 234 ;;;###autoload
 235 (defun url-copy-file (url newname &optional ok-if-already-exists
 236                           keep-time preserve-uid-gid)
 237   "Copy URL to NEWNAME.  Both args must be strings.
 238 Signals a `file-already-exists' error if file NEWNAME already exists,
 239 unless a third argument OK-IF-ALREADY-EXISTS is supplied and non-nil.
 240 A number as third arg means request confirmation if NEWNAME already exists.
 241 This is what happens in interactive use with M-x.
 242 Fourth arg KEEP-TIME non-nil means give the new file the same
 243 last-modified time as the old one.  (This works on only some systems.)
 244 Fifth arg PRESERVE-UID-GID is ignored.
 245 A prefix arg makes KEEP-TIME non-nil."
 246   (if (and (file-exists-p newname)
 247            (not ok-if-already-exists))
 248       (error "Opening output file: File already exists, %s" newname))
 249   (let ((buffer (url-retrieve-synchronously url))
 250         (handle nil))
 251     (if (not buffer)
 252         (error "Opening input file: No such file or directory, %s" url))
 253     (with-current-buffer buffer
 254       (setq handle (mm-dissect-buffer t)))
 255     (mm-save-part-to-file handle newname)
 256     (kill-buffer buffer)
 257     (mm-destroy-parts handle)))
 258 (put 'copy-file 'url-file-handlers 'url-copy-file)
 259
 260 ;;;###autoload
 261 (defun url-file-local-copy (url &rest ignored)
 262   "Copy URL into a temporary file on this machine.
 263 Returns the name of the local copy, or nil, if FILE is directly
 264 accessible."
 265   (let ((filename (make-temp-file "url")))
 266     (url-copy-file url filename 'ok-if-already-exists)
 267     filename))
 268 (put 'file-local-copy 'url-file-handlers 'url-file-local-copy)
 269
 270 (defun url-insert (buffer &optional beg end)
 271   "Insert the body of a URL object.
 272 BUFFER should be a complete URL buffer as returned by `url-retrieve'.
 273 If the headers specify a coding-system, it is applied to the body before it is inserted.
 274 Returns a list of the form (SIZE CHARSET), where SIZE is the size in bytes
 275 of the inserted text and CHARSET is the charset that was specified in the header,
 276 or nil if none was found.
 277 BEG and END can be used to only insert a subpart of the body.
 278 They count bytes from the beginning of the body."
 279   (let* ((handle (with-current-buffer buffer (mm-dissect-buffer t)))
 280          (data (with-current-buffer (mm-handle-buffer handle)
 281                  (if beg
 282                      (buffer-substring (+ (point-min) beg)
 283                                        (if end (+ (point-min) end) (point-max)))
 284                    (buffer-string))))
 285          (charset (mail-content-type-get (mm-handle-type handle)
 286                                           'charset)))
 287     (mm-destroy-parts handle)
 288     (if charset
 289         (insert (mm-decode-string data (mm-charset-to-coding-system charset)))
 290       (insert data))
 291     (list (length data) charset)))
 292
 293 ;;;###autoload
 294 (defun url-insert-file-contents (url &optional visit beg end replace)
 295   (let ((buffer (url-retrieve-synchronously url)))
 296     (if (not buffer)
 297         (error "Opening input file: No such file or directory, %s" url))
 298     (if visit (setq buffer-file-name url))
 299     (save-excursion
 300       (let* ((start (point))
 301              (size-and-charset (url-insert buffer beg end)))
 302         (kill-buffer buffer)
 303         (when replace
 304           (delete-region (point-min) start)
 305           (delete-region (point) (point-max)))
 306         (unless (cadr size-and-charset)
 307           ;; If the headers don't specify any particular charset, use the
 308           ;; usual heuristic/rules that we apply to files.
 309           (decode-coding-inserted-region start (point) url visit beg end replace))
 310         (list url (car size-and-charset))))))
 311 (put 'insert-file-contents 'url-file-handlers 'url-insert-file-contents)
 312
 313 (defun url-file-name-completion (url directory &optional predicate)
 314   ;; Even if it's not implemented, it's not an error to ask for completion,
 315   ;; in case it's available (bug#14806).
 316   ;; (error "Unimplemented")
 317   url)
 318 (put 'file-name-completion 'url-file-handlers 'url-file-name-completion)
 319
 320 (defun url-file-name-all-completions (file directory)
 321   ;; Even if it's not implemented, it's not an error to ask for completion,
 322   ;; in case it's available (bug#14806).
 323   ;; (error "Unimplemented")
 324   nil)
 325 (put 'file-name-all-completions
 326      'url-file-handlers 'url-file-name-all-completions)
 327
 328 ;; All other handlers map onto their respective backends.
 329 (defmacro url-handlers-create-wrapper (method args)
 330   `(progn
 331      (defun ,(intern (format "url-%s" method)) ,args
 332        ,(format "URL file-name-handler wrapper for `%s' call.\n---\n%s" method
 333                 (or (documentation method t) "No original documentation."))
 334        (setq url (url-generic-parse-url url))
 335        (when (url-type url)
 336          (funcall (url-scheme-get-property (url-type url) (quote ,method))
 337                   ,@(remove '&rest (remove '&optional args)))))
 338      (unless (get ',method 'url-file-handlers)
 339        (put ',method 'url-file-handlers ',(intern (format "url-%s" method))))))
 340
 341 (url-handlers-create-wrapper file-exists-p (url))
 342 (url-handlers-create-wrapper file-attributes (url &optional id-format))
 343 (url-handlers-create-wrapper file-symlink-p (url))
 344 (url-handlers-create-wrapper file-writable-p (url))
 345 (url-handlers-create-wrapper file-directory-p (url))
 346 (url-handlers-create-wrapper file-executable-p (url))
 347 (url-handlers-create-wrapper directory-files (url &optional full match nosort))
 348 (url-handlers-create-wrapper file-truename (url &optional counter prev-dirs))
 349
 350 (add-hook 'find-file-hook 'url-handlers-set-buffer-mode)
 351
 352 (defun url-handlers-set-buffer-mode ()
 353   "Set correct modes for the current buffer if visiting a remote file."
 354   (and (stringp buffer-file-name)
 355        (string-match url-handler-regexp buffer-file-name)
 356        (auto-save-mode 0)))
 357
 358 (provide 'url-handlers)
 359
 360 ;;; url-handlers.el ends here