lisp/outline.el

   1 ;;; outline.el --- outline mode commands for Emacs
   2
   3 ;; Copyright (C) 1986, 1993-1995, 1997, 2000-2014 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: outlines
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This package is a major mode for editing outline-format documents.
  27 ;; An outline can be `abstracted' to show headers at any given level,
  28 ;; with all stuff below hidden.  See the Emacs manual for details.
  29
  30 ;;; Todo:
  31
  32 ;; - subtree-terminators
  33 ;; - better handle comments before function bodies (i.e. heading)
  34 ;; - don't bother hiding whitespace
  35
  36 ;;; Code:
  37
  38 (defvar font-lock-warning-face)
  39
  40
  41 (defgroup outlines nil
  42   "Support for hierarchical outlining."
  43   :prefix "outline-"
  44   :group 'wp)
  45
  46 (defvar outline-regexp "[*\^L]+"
  47   "Regular expression to match the beginning of a heading.
  48 Any line whose beginning matches this regexp is considered to start a heading.
  49 Note that Outline mode only checks this regexp at the start of a line,
  50 so the regexp need not (and usually does not) start with `^'.
  51 The recommended way to set this is with a Local Variables: list
  52 in the file it applies to.  See also `outline-heading-end-regexp'.")
  53 ;;;###autoload(put 'outline-regexp 'safe-local-variable 'stringp)
  54
  55 (defvar outline-heading-end-regexp "\n"
  56   "Regular expression to match the end of a heading line.
  57 You can assume that point is at the beginning of a heading when this
  58 regexp is searched for.  The heading ends at the end of the match.
  59 The recommended way to set this is with a `Local Variables:' list
  60 in the file it applies to.")
  61 ;;;###autoload(put 'outline-heading-end-regexp 'safe-local-variable 'stringp)
  62
  63 (defvar outline-mode-prefix-map
  64   (let ((map (make-sparse-keymap)))
  65     (define-key map "@" 'outline-mark-subtree)
  66     (define-key map "\C-n" 'outline-next-visible-heading)
  67     (define-key map "\C-p" 'outline-previous-visible-heading)
  68     (define-key map "\C-i" 'show-children)
  69     (define-key map "\C-s" 'show-subtree)
  70     (define-key map "\C-d" 'hide-subtree)
  71     (define-key map "\C-u" 'outline-up-heading)
  72     (define-key map "\C-f" 'outline-forward-same-level)
  73     (define-key map "\C-b" 'outline-backward-same-level)
  74     (define-key map "\C-t" 'hide-body)
  75     (define-key map "\C-a" 'show-all)
  76     (define-key map "\C-c" 'hide-entry)
  77     (define-key map "\C-e" 'show-entry)
  78     (define-key map "\C-l" 'hide-leaves)
  79     (define-key map "\C-k" 'show-branches)
  80     (define-key map "\C-q" 'hide-sublevels)
  81     (define-key map "\C-o" 'hide-other)
  82     (define-key map "\C-^" 'outline-move-subtree-up)
  83     (define-key map "\C-v" 'outline-move-subtree-down)
  84     (define-key map [(control ?<)] 'outline-promote)
  85     (define-key map [(control ?>)] 'outline-demote)
  86     (define-key map "\C-m" 'outline-insert-heading)
  87     ;; Where to bind outline-cycle ?
  88     map))
  89
  90 (defvar outline-mode-menu-bar-map
  91   (let ((map (make-sparse-keymap)))
  92
  93     (define-key map [hide] (cons "Hide" (make-sparse-keymap "Hide")))
  94
  95     (define-key map [hide hide-other]
  96       '(menu-item "Hide Other" hide-other
  97                   :help "Hide everything except current body and parent and top-level headings"))
  98     (define-key map [hide hide-sublevels]
  99       '(menu-item "Hide Sublevels" hide-sublevels
 100                   :help "Hide everything but the top LEVELS levels of headers, in whole buffer"))
 101     (define-key map [hide hide-subtree]
 102       '(menu-item "Hide Subtree" hide-subtree
 103                   :help "Hide everything after this heading at deeper levels"))
 104     (define-key map [hide hide-entry]
 105       '(menu-item "Hide Entry" hide-entry
 106                   :help "Hide the body directly following this heading"))
 107     (define-key map [hide hide-body]
 108       '(menu-item "Hide Body" hide-body
 109                   :help "Hide all body lines in buffer, leaving all headings visible"))
 110     (define-key map [hide hide-leaves]
 111       '(menu-item "Hide Leaves" hide-leaves
 112                   :help "Hide the body after this heading and at deeper levels"))
 113
 114     (define-key map [show] (cons "Show" (make-sparse-keymap "Show")))
 115
 116     (define-key map [show show-subtree]
 117       '(menu-item "Show Subtree" show-subtree
 118                   :help "Show everything after this heading at deeper levels"))
 119     (define-key map [show show-children]
 120       '(menu-item "Show Children" show-children
 121                   :help "Show all direct subheadings of this heading"))
 122     (define-key map [show show-branches]
 123       '(menu-item "Show Branches" show-branches
 124                   :help "Show all subheadings of this heading, but not their bodies"))
 125     (define-key map [show show-entry]
 126       '(menu-item "Show Entry" show-entry
 127                   :help "Show the body directly following this heading"))
 128     (define-key map [show show-all]
 129       '(menu-item "Show All" show-all
 130                   :help "Show all of the text in the buffer"))
 131
 132     (define-key map [headings]
 133       (cons "Headings" (make-sparse-keymap "Headings")))
 134
 135     (define-key map [headings demote-subtree]
 136       '(menu-item "Demote Subtree" outline-demote
 137                   :help "Demote headings lower down the tree"))
 138     (define-key map [headings promote-subtree]
 139       '(menu-item "Promote Subtree" outline-promote
 140                   :help "Promote headings higher up the tree"))
 141     (define-key map [headings move-subtree-down]
 142       '(menu-item "Move Subtree Down" outline-move-subtree-down
 143                   :help "Move the current subtree down past arg headlines of the same level"))
 144     (define-key map [headings move-subtree-up]
 145       '(menu-item "Move Subtree Up" outline-move-subtree-up
 146                   :help "Move the current subtree up past arg headlines of the same level"))
 147     (define-key map [headings copy]
 148       '(menu-item "Copy to Kill Ring" outline-headers-as-kill
 149                   :enable mark-active
 150                   :help "Save the visible outline headers in region at the start of the kill ring"))
 151     (define-key map [headings outline-insert-heading]
 152       '(menu-item "New Heading" outline-insert-heading
 153                   :help "Insert a new heading at same depth at point"))
 154     (define-key map [headings outline-backward-same-level]
 155
 156       '(menu-item "Previous Same Level" outline-backward-same-level
 157                   :help "Move backward to the arg'th subheading at same level as this one."))
 158     (define-key map [headings outline-forward-same-level]
 159
 160       '(menu-item "Next Same Level" outline-forward-same-level
 161                   :help "Move forward to the arg'th subheading at same level as this one"))
 162     (define-key map [headings outline-previous-visible-heading]
 163
 164       '(menu-item "Previous" outline-previous-visible-heading
 165                   :help "Move to the previous heading line"))
 166     (define-key map [headings outline-next-visible-heading]
 167
 168       '(menu-item "Next" outline-next-visible-heading
 169                   :help "Move to the next visible heading line"))
 170     (define-key map [headings outline-up-heading]
 171
 172       '(menu-item "Up" outline-up-heading
 173                   :help "Move to the visible heading line of which the present line is a subheading"))
 174     map))
 175
 176 (defvar outline-minor-mode-menu-bar-map
 177   (let ((map (make-sparse-keymap)))
 178     (define-key map [outline]
 179       (cons "Outline"
 180             (nconc (make-sparse-keymap "Outline")
 181                    ;; Remove extra separator
 182                    (cdr
 183                     ;; Flatten the major mode's menus into a single menu.
 184                     (apply 'append
 185                            (mapcar (lambda (x)
 186                                      (if (consp x)
 187                                          ;; Add a separator between each
 188                                          ;; part of the unified menu.
 189                                          (cons '(--- "---") (cdr x))))
 190                                    outline-mode-menu-bar-map))))))
 191     map))
 192
 193
 194 (defvar outline-mode-map
 195   (let ((map (make-sparse-keymap)))
 196     (define-key map "\C-c" outline-mode-prefix-map)
 197     (define-key map [menu-bar] outline-mode-menu-bar-map)
 198     map))
 199
 200 (defvar outline-font-lock-keywords
 201   '(;;
 202     ;; Highlight headings according to the level.
 203     (eval . (list (concat "^\\(?:" outline-regexp "\\).+")
 204                   0 '(outline-font-lock-face) nil t)))
 205   "Additional expressions to highlight in Outline mode.")
 206
 207 (defface outline-1
 208   '((t :inherit font-lock-function-name-face))
 209   "Level 1."
 210   :group 'outlines)
 211
 212 (defface outline-2
 213   '((t :inherit font-lock-variable-name-face))
 214   "Level 2."
 215   :group 'outlines)
 216
 217 (defface outline-3
 218   '((t :inherit font-lock-keyword-face))
 219   "Level 3."
 220   :group 'outlines)
 221
 222 (defface outline-4
 223   '((t :inherit font-lock-comment-face))
 224   "Level 4."
 225   :group 'outlines)
 226
 227 (defface outline-5
 228   '((t :inherit font-lock-type-face))
 229   "Level 5."
 230   :group 'outlines)
 231
 232 (defface outline-6
 233   '((t :inherit font-lock-constant-face))
 234   "Level 6."
 235   :group 'outlines)
 236
 237 (defface outline-7
 238   '((t :inherit font-lock-builtin-face))
 239   "Level 7."
 240   :group 'outlines)
 241
 242 (defface outline-8
 243   '((t :inherit font-lock-string-face))
 244   "Level 8."
 245   :group 'outlines)
 246
 247 (defvar outline-font-lock-faces
 248   [outline-1 outline-2 outline-3 outline-4
 249    outline-5 outline-6 outline-7 outline-8])
 250
 251 ;; (defvar outline-font-lock-levels nil)
 252 ;; (make-variable-buffer-local 'outline-font-lock-levels)
 253
 254 (defun outline-font-lock-face ()
 255   ;; (save-excursion
 256   ;;   (outline-back-to-heading t)
 257   ;;   (let* ((count 0)
 258   ;;       (start-level (funcall outline-level))
 259   ;;       (level start-level)
 260   ;;       face-level)
 261   ;;     (while (not (setq face-level
 262   ;;                    (if (or (bobp) (eq level 1)) 0
 263   ;;                      (cdr (assq level outline-font-lock-levels)))))
 264   ;;    (outline-up-heading 1 t)
 265   ;;    (setq count (1+ count))
 266   ;;    (setq level (funcall outline-level)))
 267   ;;     ;; Remember for later.
 268   ;;     (unless (zerop count)
 269   ;;    (setq face-level (+ face-level count))
 270   ;;    (push (cons start-level face-level) outline-font-lock-levels))
 271   ;;     (condition-case nil
 272   ;;      (aref outline-font-lock-faces face-level)
 273   ;;    (error font-lock-warning-face))))
 274   (save-excursion
 275     (goto-char (match-beginning 0))
 276     (looking-at outline-regexp)
 277     (aref outline-font-lock-faces (% (1- (funcall outline-level)) (length outline-font-lock-faces)))))
 278
 279 (defvar outline-view-change-hook nil
 280   "Normal hook to be run after outline visibility changes.")
 281
 282 (defvar outline-mode-hook nil
 283   "This hook is run when outline mode starts.")
 284
 285 (defvar outline-blank-line nil
 286   "Non-nil means to leave unhidden blank line before heading.")
 287
 288 ;;;###autoload
 289 (define-derived-mode outline-mode text-mode "Outline"
 290   "Set major mode for editing outlines with selective display.
 291 Headings are lines which start with asterisks: one for major headings,
 292 two for subheadings, etc.  Lines not starting with asterisks are body lines.
 293
 294 Body text or subheadings under a heading can be made temporarily
 295 invisible, or visible again.  Invisible lines are attached to the end
 296 of the heading, so they move with it, if the line is killed and yanked
 297 back.  A heading with text hidden under it is marked with an ellipsis (...).
 298
 299 Commands:\\<outline-mode-map>
 300 \\[outline-next-visible-heading]   outline-next-visible-heading      move by visible headings
 301 \\[outline-previous-visible-heading]   outline-previous-visible-heading
 302 \\[outline-forward-same-level]   outline-forward-same-level        similar but skip subheadings
 303 \\[outline-backward-same-level]   outline-backward-same-level
 304 \\[outline-up-heading]   outline-up-heading                 move from subheading to heading
 305
 306 \\[hide-body]   make all text invisible (not headings).
 307 \\[show-all]    make everything in buffer visible.
 308 \\[hide-sublevels]  make only the first N levels of headers visible.
 309
 310 The remaining commands are used when point is on a heading line.
 311 They apply to some of the body or subheadings of that heading.
 312 \\[hide-subtree]   hide-subtree make body and subheadings invisible.
 313 \\[show-subtree]   show-subtree make body and subheadings visible.
 314 \\[show-children]   show-children       make direct subheadings visible.
 315                  No effect on body, or subheadings 2 or more levels down.
 316                  With arg N, affects subheadings N levels down.
 317 \\[hide-entry]     make immediately following body invisible.
 318 \\[show-entry]     make it visible.
 319 \\[hide-leaves]    make body under heading and under its subheadings invisible.
 320                      The subheadings remain visible.
 321 \\[show-branches]  make all subheadings at all levels visible.
 322
 323 The variable `outline-regexp' can be changed to control what is a heading.
 324 A line is a heading if `outline-regexp' matches something at the
 325 beginning of the line.  The longer the match, the deeper the level.
 326
 327 Turning on outline mode calls the value of `text-mode-hook' and then of
 328 `outline-mode-hook', if they are non-nil."
 329   (make-local-variable 'line-move-ignore-invisible)
 330   (setq line-move-ignore-invisible t)
 331   ;; Cause use of ellipses for invisible text.
 332   (add-to-invisibility-spec '(outline . t))
 333   (set (make-local-variable 'paragraph-start)
 334        (concat paragraph-start "\\|\\(?:" outline-regexp "\\)"))
 335   ;; Inhibit auto-filling of header lines.
 336   (set (make-local-variable 'auto-fill-inhibit-regexp) outline-regexp)
 337   (set (make-local-variable 'paragraph-separate)
 338        (concat paragraph-separate "\\|\\(?:" outline-regexp "\\)"))
 339   (set (make-local-variable 'font-lock-defaults)
 340        '(outline-font-lock-keywords t nil nil backward-paragraph))
 341   (setq imenu-generic-expression
 342         (list (list nil (concat "^\\(?:" outline-regexp "\\).*$") 0)))
 343   (add-hook 'change-major-mode-hook 'show-all nil t))
 344
 345 (defcustom outline-minor-mode-prefix "\C-c@"
 346   "Prefix key to use for Outline commands in Outline minor mode.
 347 The value of this variable is checked as part of loading Outline mode.
 348 After that, changing the prefix key requires manipulating keymaps."
 349   :type 'string
 350   :group 'outlines)
 351
 352 ;;;###autoload
 353 (define-minor-mode outline-minor-mode
 354   "Toggle Outline minor mode.
 355 With a prefix argument ARG, enable Outline minor mode if ARG is
 356 positive, and disable it otherwise.  If called from Lisp, enable
 357 the mode if ARG is omitted or nil.
 358
 359 See the command `outline-mode' for more information on this mode."
 360   nil " Outl" (list (cons [menu-bar] outline-minor-mode-menu-bar-map)
 361                     (cons outline-minor-mode-prefix outline-mode-prefix-map))
 362   :group 'outlines
 363   (if outline-minor-mode
 364       (progn
 365         ;; Turn off this mode if we change major modes.
 366         (add-hook 'change-major-mode-hook
 367                   (lambda () (outline-minor-mode -1))
 368                   nil t)
 369         (set (make-local-variable 'line-move-ignore-invisible) t)
 370         ;; Cause use of ellipses for invisible text.
 371         (add-to-invisibility-spec '(outline . t)))
 372     (setq line-move-ignore-invisible nil)
 373     ;; Cause use of ellipses for invisible text.
 374     (remove-from-invisibility-spec '(outline . t))
 375     ;; When turning off outline mode, get rid of any outline hiding.
 376     (show-all)))
 377 \f
 378 (defvar outline-level 'outline-level
 379   "Function of no args to compute a header's nesting level in an outline.
 380 It can assume point is at the beginning of a header line and that the match
 381 data reflects the `outline-regexp'.")
 382 ;;;###autoload(put 'outline-level 'risky-local-variable t)
 383
 384 (defvar outline-heading-alist ()
 385   "Alist associating a heading for every possible level.
 386 Each entry is of the form (HEADING . LEVEL).
 387 This alist is used two ways: to find the heading corresponding to
 388 a given level and to find the level of a given heading.
 389 If a mode or document needs several sets of outline headings (for example
 390 numbered and unnumbered sections), list them set by set and sorted by level
 391 within each set.  For example in texinfo mode:
 392
 393      (setq outline-heading-alist
 394       '((\"@chapter\" . 2) (\"@section\" . 3) (\"@subsection\" . 4)
 395            (\"@subsubsection\" . 5)
 396         (\"@unnumbered\" . 2) (\"@unnumberedsec\" . 3)
 397            (\"@unnumberedsubsec\" . 4)  (\"@unnumberedsubsubsec\" . 5)
 398         (\"@appendix\" . 2) (\"@appendixsec\" . 3)...
 399            (\"@appendixsubsec\" . 4) (\"@appendixsubsubsec\" . 5) ..))
 400
 401 Instead of sorting the entries in each set, you can also separate the
 402 sets with nil.")
 403 (make-variable-buffer-local 'outline-heading-alist)
 404
 405 ;; This used to count columns rather than characters, but that made ^L
 406 ;; appear to be at level 2 instead of 1.  Columns would be better for
 407 ;; tab handling, but the default regexp doesn't use tabs, and anyone
 408 ;; who changes the regexp can also redefine the outline-level variable
 409 ;; as appropriate.
 410 (defun outline-level ()
 411   "Return the depth to which a statement is nested in the outline.
 412 Point must be at the beginning of a header line.
 413 This is actually either the level specified in `outline-heading-alist'
 414 or else the number of characters matched by `outline-regexp'."
 415   (or (cdr (assoc (match-string 0) outline-heading-alist))
 416       (- (match-end 0) (match-beginning 0))))
 417
 418 (defun outline-next-preface ()
 419   "Skip forward to just before the next heading line.
 420 If there's no following heading line, stop before the newline
 421 at the end of the buffer."
 422   (if (re-search-forward (concat "\n\\(?:" outline-regexp "\\)")
 423                          nil 'move)
 424       (goto-char (match-beginning 0)))
 425   (if (and (bolp) (or outline-blank-line (eobp)) (not (bobp)))
 426       (forward-char -1)))
 427
 428 (defun outline-next-heading ()
 429   "Move to the next (possibly invisible) heading line."
 430   (interactive)
 431   ;; Make sure we don't match the heading we're at.
 432   (if (and (bolp) (not (eobp))) (forward-char 1))
 433   (if (re-search-forward (concat "^\\(?:" outline-regexp "\\)")
 434                          nil 'move)
 435       (goto-char (match-beginning 0))))
 436
 437 (defun outline-previous-heading ()
 438   "Move to the previous (possibly invisible) heading line."
 439   (interactive)
 440   (re-search-backward (concat "^\\(?:" outline-regexp "\\)")
 441                       nil 'move))
 442
 443 (defsubst outline-invisible-p (&optional pos)
 444   "Non-nil if the character after point is invisible."
 445   (get-char-property (or pos (point)) 'invisible))
 446
 447 (defun outline-back-to-heading (&optional invisible-ok)
 448   "Move to previous heading line, or beg of this line if it's a heading.
 449 Only visible heading lines are considered, unless INVISIBLE-OK is non-nil."
 450   (beginning-of-line)
 451   (or (outline-on-heading-p invisible-ok)
 452       (let (found)
 453         (save-excursion
 454           (while (not found)
 455             (or (re-search-backward (concat "^\\(?:" outline-regexp "\\)")
 456                                     nil t)
 457                 (error "before first heading"))
 458             (setq found (and (or invisible-ok (not (outline-invisible-p)))
 459                              (point)))))
 460         (goto-char found)
 461         found)))
 462
 463 (defun outline-on-heading-p (&optional invisible-ok)
 464   "Return t if point is on a (visible) heading line.
 465 If INVISIBLE-OK is non-nil, an invisible heading line is ok too."
 466   (save-excursion
 467     (beginning-of-line)
 468     (and (bolp) (or invisible-ok (not (outline-invisible-p)))
 469          (looking-at outline-regexp))))
 470
 471 (defun outline-insert-heading ()
 472   "Insert a new heading at same depth at point."
 473   (interactive)
 474   (let ((head (save-excursion
 475                 (condition-case nil
 476                     (outline-back-to-heading)
 477                   (error (outline-next-heading)))
 478                 (if (eobp)
 479                     (or (caar outline-heading-alist) "")
 480                   (match-string 0)))))
 481     (unless (or (string-match "[ \t]\\'" head)
 482                 (not (string-match (concat "\\`\\(?:" outline-regexp "\\)")
 483                                    (concat head " "))))
 484       (setq head (concat head " ")))
 485     (unless (bolp) (end-of-line) (newline))
 486     (insert head)
 487     (unless (eolp)
 488       (save-excursion (newline-and-indent)))
 489     (run-hooks 'outline-insert-heading-hook)))
 490
 491 (defun outline-invent-heading (head up)
 492   (save-match-data
 493     ;; Let's try to invent one by repeating or deleting the last char.
 494     (let ((new-head (if up (substring head 0 -1)
 495                       (concat head (substring head -1)))))
 496       (if (string-match (concat "\\`\\(?:" outline-regexp "\\)")
 497                         new-head)
 498           ;; Why bother checking that it is indeed higher/lower level ?
 499           new-head
 500         ;; Didn't work, so ask what to do.
 501         (read-string (format "%s heading for `%s': "
 502                              (if up "Parent" "Demoted") head)
 503                      head nil nil t)))))
 504
 505 (defun outline-promote (&optional which)
 506   "Promote headings higher up the tree.
 507 If transient-mark-mode is on, and mark is active, promote headings in
 508 the region (from a Lisp program, pass `region' for WHICH).  Otherwise:
 509 without prefix argument, promote current heading and all headings in the
 510 subtree (from a Lisp program, pass `subtree' for WHICH); with prefix
 511 argument, promote just the current heading (from a Lisp program, pass
 512 nil for WHICH, or do not pass any argument)."
 513   (interactive
 514    (list (if (and transient-mark-mode mark-active) 'region
 515            (outline-back-to-heading)
 516            (if current-prefix-arg nil 'subtree))))
 517   (cond
 518    ((eq which 'region)
 519     (outline-map-region 'outline-promote (region-beginning) (region-end)))
 520    (which
 521     (outline-map-region 'outline-promote
 522                         (point)
 523                         (save-excursion (outline-get-next-sibling) (point))))
 524    (t
 525     (outline-back-to-heading t)
 526     (let* ((head (match-string-no-properties 0))
 527            (level (save-match-data (funcall outline-level)))
 528            (up-head (or (outline-head-from-level (1- level) head)
 529                         ;; Use the parent heading, if it is really
 530                         ;; one level less.
 531                         (save-excursion
 532                           (save-match-data
 533                             (outline-up-heading 1 t)
 534                             (and (= (1- level) (funcall outline-level))
 535                                  (match-string-no-properties 0))))
 536                         ;; Bummer!! There is no lower level heading.
 537                         (outline-invent-heading head 'up))))
 538
 539       (unless (rassoc level outline-heading-alist)
 540         (push (cons head level) outline-heading-alist))
 541
 542       (replace-match up-head nil t)))))
 543
 544 (defun outline-demote (&optional which)
 545   "Demote headings lower down the tree.
 546 If transient-mark-mode is on, and mark is active, demote headings in
 547 the region (from a Lisp program, pass `region' for WHICH).  Otherwise:
 548 without prefix argument, demote current heading and all headings in the
 549 subtree (from a Lisp program, pass `subtree' for WHICH); with prefix
 550 argument, demote just the current heading (from a Lisp program, pass
 551 nil for WHICH, or do not pass any argument)."
 552   (interactive
 553    (list (if (and transient-mark-mode mark-active) 'region
 554            (outline-back-to-heading)
 555            (if current-prefix-arg nil 'subtree))))
 556   (cond
 557    ((eq which 'region)
 558     (outline-map-region 'outline-demote (region-beginning) (region-end)))
 559    (which
 560     (outline-map-region 'outline-demote
 561                         (point)
 562                         (save-excursion (outline-get-next-sibling) (point))))
 563    (t
 564     (let* ((head (match-string-no-properties 0))
 565            (level (save-match-data (funcall outline-level)))
 566            (down-head
 567             (or (outline-head-from-level (1+ level) head)
 568                 (save-excursion
 569                   (save-match-data
 570                     (while (and (progn (outline-next-heading) (not (eobp)))
 571                                 (<= (funcall outline-level) level)))
 572                     (when (eobp)
 573                       ;; Try again from the beginning of the buffer.
 574                       (goto-char (point-min))
 575                       (while (and (progn (outline-next-heading) (not (eobp)))
 576                                   (<= (funcall outline-level) level))))
 577                     (unless (eobp)
 578                       (looking-at outline-regexp)
 579                       (match-string-no-properties 0))))
 580                 ;; Bummer!! There is no higher-level heading in the buffer.
 581                 (outline-invent-heading head nil))))
 582
 583       (unless (rassoc level outline-heading-alist)
 584         (push (cons head level) outline-heading-alist))
 585       (replace-match down-head nil t)))))
 586
 587 (defun outline-head-from-level (level head &optional alist)
 588   "Get new heading with level LEVEL from ALIST.
 589 If there are no such entries, return nil.
 590 ALIST defaults to `outline-heading-alist'.
 591 Similar to (car (rassoc LEVEL ALIST)).
 592 If there are several different entries with same new level, choose
 593 the one with the smallest distance to the association of HEAD in the alist.
 594 This makes it possible for promotion to work in modes with several
 595 independent sets of headings (numbered, unnumbered, appendix...)"
 596   (unless alist (setq alist outline-heading-alist))
 597   (let ((l (rassoc level alist))
 598         ll h hl l2 l2l)
 599     (cond
 600      ((null l) nil)
 601      ;; If there's no HEAD after L, any other entry for LEVEL after L
 602      ;; can't be much better than L.
 603      ((null (setq h (assoc head (setq ll (memq l alist))))) (car l))
 604      ;; If there's no other entry for LEVEL, just keep L.
 605      ((null (setq l2 (rassoc level (cdr ll)))) (car l))
 606      ;; Now we have L, L2, and H: see if L2 seems better than L.
 607      ;; If H is after L2, L2 is better.
 608      ((memq h (setq l2l (memq l2 (cdr ll))))
 609       (outline-head-from-level level head l2l))
 610      ;; Now we have H between L and L2.
 611      ;; If there's a separator between L and H, prefer L2.
 612      ((memq h (memq nil ll))
 613       (outline-head-from-level level head l2l))
 614      ;; If there's a separator between L2 and H, prefer L.
 615      ((memq l2 (memq nil (setq hl (memq h ll)))) (car l))
 616      ;; No separator between L and L2, check the distance.
 617      ((< (* 2 (length hl)) (+ (length ll) (length l2l)))
 618       (outline-head-from-level level head l2l))
 619      ;; If all else fails, just keep L.
 620      (t (car l)))))
 621
 622 (defun outline-map-region (fun beg end)
 623   "Call FUN for every heading between BEG and END.
 624 When FUN is called, point is at the beginning of the heading and
 625 the match data is set appropriately."
 626   (save-excursion
 627     (setq end (copy-marker end))
 628     (goto-char beg)
 629     (when (re-search-forward (concat "^\\(?:" outline-regexp "\\)") end t)
 630       (goto-char (match-beginning 0))
 631       (funcall fun)
 632       (while (and (progn
 633                     (outline-next-heading)
 634                     (< (point) end))
 635                   (not (eobp)))
 636         (funcall fun)))))
 637
 638 ;; Vertical tree motion
 639
 640 (defun outline-move-subtree-up (&optional arg)
 641   "Move the current subtree up past ARG headlines of the same level."
 642   (interactive "p")
 643   (outline-move-subtree-down (- arg)))
 644
 645 (defun outline-move-subtree-down (&optional arg)
 646   "Move the current subtree down past ARG headlines of the same level."
 647   (interactive "p")
 648   (let ((movfunc (if (> arg 0) 'outline-get-next-sibling
 649                    'outline-get-last-sibling))
 650         (ins-point (make-marker))
 651         (cnt (abs arg))
 652         beg end folded)
 653     ;; Select the tree
 654     (outline-back-to-heading)
 655     (setq beg (point))
 656     (save-match-data
 657       (save-excursion (outline-end-of-heading)
 658                       (setq folded (outline-invisible-p)))
 659       (outline-end-of-subtree))
 660     (if (= (char-after) ?\n) (forward-char 1))
 661     (setq end (point))
 662     ;; Find insertion point, with error handling
 663     (goto-char beg)
 664     (while (> cnt 0)
 665       (or (funcall movfunc)
 666           (progn (goto-char beg)
 667                  (error "Cannot move past superior level")))
 668       (setq cnt (1- cnt)))
 669     (if (> arg 0)
 670         ;; Moving forward - still need to move over subtree
 671         (progn (outline-end-of-subtree)
 672                (if (= (char-after) ?\n) (forward-char 1))))
 673     (move-marker ins-point (point))
 674     (insert (delete-and-extract-region beg end))
 675     (goto-char ins-point)
 676     (if folded (hide-subtree))
 677     (move-marker ins-point nil)))
 678
 679 (defun outline-end-of-heading ()
 680   (if (re-search-forward outline-heading-end-regexp nil 'move)
 681       (forward-char -1)))
 682
 683 (defun outline-next-visible-heading (arg)
 684   "Move to the next visible heading line.
 685 With argument, repeats or can move backward if negative.
 686 A heading line is one that starts with a `*' (or that
 687 `outline-regexp' matches)."
 688   (interactive "p")
 689   (if (< arg 0)
 690       (beginning-of-line)
 691     (end-of-line))
 692   (let (found-heading-p)
 693     (while (and (not (bobp)) (< arg 0))
 694       (while (and (not (bobp))
 695                   (setq found-heading-p
 696                         (re-search-backward
 697                          (concat "^\\(?:" outline-regexp "\\)")
 698                          nil 'move))
 699                   (outline-invisible-p)))
 700       (setq arg (1+ arg)))
 701     (while (and (not (eobp)) (> arg 0))
 702       (while (and (not (eobp))
 703                   (setq found-heading-p
 704                         (re-search-forward
 705                          (concat "^\\(?:" outline-regexp "\\)")
 706                          nil 'move))
 707                   (outline-invisible-p (match-beginning 0))))
 708       (setq arg (1- arg)))
 709     (if found-heading-p (beginning-of-line))))
 710
 711 (defun outline-previous-visible-heading (arg)
 712   "Move to the previous heading line.
 713 With argument, repeats or can move forward if negative.
 714 A heading line is one that starts with a `*' (or that
 715 `outline-regexp' matches)."
 716   (interactive "p")
 717   (outline-next-visible-heading (- arg)))
 718
 719 (defun outline-mark-subtree ()
 720   "Mark the current subtree in an outlined document.
 721 This puts point at the start of the current subtree, and mark at the end."
 722   (interactive)
 723   (let ((beg))
 724     (if (outline-on-heading-p)
 725         ;; we are already looking at a heading
 726         (beginning-of-line)
 727       ;; else go back to previous heading
 728       (outline-previous-visible-heading 1))
 729     (setq beg (point))
 730     (outline-end-of-subtree)
 731     (push-mark (point) nil t)
 732     (goto-char beg)))
 733 \f
 734
 735 (defvar outline-isearch-open-invisible-function nil
 736   "Function called if `isearch' finishes in an invisible overlay.
 737 The function is called with the overlay as its only argument.
 738 If nil, `show-entry' is called to reveal the invisible text.")
 739
 740 (put 'outline 'reveal-toggle-invisible 'outline-reveal-toggle-invisible)
 741 (defun outline-flag-region (from to flag)
 742   "Hide or show lines from FROM to TO, according to FLAG.
 743 If FLAG is nil then text is shown, while if FLAG is t the text is hidden."
 744   (remove-overlays from to 'invisible 'outline)
 745   (when flag
 746     ;; We use `front-advance' here because the invisible text begins at the
 747     ;; very end of the heading, before the newline, so text inserted at FROM
 748     ;; belongs to the heading rather than to the entry.
 749     (let ((o (make-overlay from to nil 'front-advance)))
 750       (overlay-put o 'evaporate t)
 751       (overlay-put o 'invisible 'outline)
 752       (overlay-put o 'isearch-open-invisible
 753                    (or outline-isearch-open-invisible-function
 754                        'outline-isearch-open-invisible))))
 755   ;; Seems only used by lazy-lock.  I.e. obsolete.
 756   (run-hooks 'outline-view-change-hook))
 757
 758 (defun outline-reveal-toggle-invisible (o hidep)
 759   (save-excursion
 760     (goto-char (overlay-start o))
 761     (if hidep
 762         ;; When hiding the area again, we could just clean it up and let
 763         ;; reveal do the rest, by simply doing:
 764         ;; (remove-overlays (overlay-start o) (overlay-end o)
 765         ;;                  'invisible 'outline)
 766         ;;
 767         ;; That works fine as long as everything is in sync, but if the
 768         ;; structure of the document is changed while revealing parts of it,
 769         ;; the resulting behavior can be ugly.  I.e. we need to make
 770         ;; sure that we hide exactly a subtree.
 771         (progn
 772           (let ((end (overlay-end o)))
 773             (delete-overlay o)
 774             (while (progn
 775                      (hide-subtree)
 776                      (outline-next-visible-heading 1)
 777                      (and (not (eobp)) (< (point) end))))))
 778
 779       ;; When revealing, we just need to reveal sublevels.  If point is
 780       ;; inside one of the sublevels, reveal will call us again.
 781       ;; But we need to preserve the original overlay.
 782       (let ((o1 (copy-overlay o)))
 783         (overlay-put o 'invisible nil)  ;Show (most of) the text.
 784         (while (progn
 785                  (show-entry)
 786                  (show-children)
 787                  ;; Normally just the above is needed.
 788                  ;; But in odd cases, the above might fail to show anything.
 789                  ;; To avoid an infinite loop, we have to make sure that
 790                  ;; *something* gets shown.
 791                  (and (equal (overlay-start o) (overlay-start o1))
 792                       (< (point) (overlay-end o))
 793                       (= 0 (forward-line 1)))))
 794         ;; If still nothing was shown, just kill the damn thing.
 795         (when (equal (overlay-start o) (overlay-start o1))
 796           ;; I've seen it happen at the end of buffer.
 797           (delete-overlay o1))))))
 798
 799 ;; Function to be set as an outline-isearch-open-invisible' property
 800 ;; to the overlay that makes the outline invisible (see
 801 ;; `outline-flag-region').
 802 (defun outline-isearch-open-invisible (_overlay)
 803   ;; We rely on the fact that isearch places point on the matched text.
 804   (show-entry))
 805 \f
 806 (defun hide-entry ()
 807   "Hide the body directly following this heading."
 808   (interactive)
 809   (save-excursion
 810     (outline-back-to-heading)
 811     (outline-end-of-heading)
 812     (outline-flag-region (point) (progn (outline-next-preface) (point)) t)))
 813
 814 (defun show-entry ()
 815   "Show the body directly following this heading.
 816 Show the heading too, if it is currently invisible."
 817   (interactive)
 818   (save-excursion
 819     (outline-back-to-heading t)
 820     (outline-flag-region (1- (point))
 821                          (progn (outline-next-preface) (point)) nil)))
 822
 823 (defun hide-body ()
 824   "Hide all body lines in buffer, leaving all headings visible."
 825   (interactive)
 826   (hide-region-body (point-min) (point-max)))
 827
 828 (defun hide-region-body (start end)
 829   "Hide all body lines in the region, but not headings."
 830   ;; Nullify the hook to avoid repeated calls to `outline-flag-region'
 831   ;; wasting lots of time running `lazy-lock-fontify-after-outline'
 832   ;; and run the hook finally.
 833   (let (outline-view-change-hook)
 834     (save-excursion
 835       (save-restriction
 836         (narrow-to-region start end)
 837         (goto-char (point-min))
 838         (if (outline-on-heading-p)
 839             (outline-end-of-heading)
 840           (outline-next-preface))
 841         (while (not (eobp))
 842           (outline-flag-region (point)
 843                                (progn (outline-next-preface) (point)) t)
 844           (unless (eobp)
 845             (forward-char (if (looking-at "\n\n") 2 1))
 846             (outline-end-of-heading))))))
 847   (run-hooks 'outline-view-change-hook))
 848
 849 (defun show-all ()
 850   "Show all of the text in the buffer."
 851   (interactive)
 852   (outline-flag-region (point-min) (point-max) nil))
 853
 854 (defun hide-subtree ()
 855   "Hide everything after this heading at deeper levels."
 856   (interactive)
 857   (outline-flag-subtree t))
 858
 859 (defun hide-leaves ()
 860   "Hide the body after this heading and at deeper levels."
 861   (interactive)
 862   (save-excursion
 863     (outline-back-to-heading)
 864 ;; Turned off to fix bug reported by Otto Maddox on 22 Nov 2005.
 865 ;;    (outline-end-of-heading)
 866     (hide-region-body (point) (progn (outline-end-of-subtree) (point)))))
 867
 868 (defun show-subtree ()
 869   "Show everything after this heading at deeper levels."
 870   (interactive)
 871   (outline-flag-subtree nil))
 872
 873 (defun outline-show-heading ()
 874   "Show the current heading and move to its end."
 875   (outline-flag-region (- (point)
 876                           (if (bobp) 0
 877                             (if (and outline-blank-line
 878                                      (eq (char-before (1- (point))) ?\n))
 879                                 2 1)))
 880                        (progn (outline-end-of-heading) (point))
 881                        nil))
 882
 883 (defun hide-sublevels (levels)
 884   "Hide everything but the top LEVELS levels of headers, in whole buffer."
 885   (interactive (list
 886                 (cond
 887                  (current-prefix-arg (prefix-numeric-value current-prefix-arg))
 888                  ((save-excursion (beginning-of-line)
 889                                   (looking-at outline-regexp))
 890                   (funcall outline-level))
 891                  (t 1))))
 892   (if (< levels 1)
 893       (error "Must keep at least one level of headers"))
 894   (save-excursion
 895     (let* (outline-view-change-hook
 896            (beg (progn
 897                   (goto-char (point-min))
 898                   ;; Skip the prelude, if any.
 899                   (unless (outline-on-heading-p t) (outline-next-heading))
 900                   (point)))
 901            (end (progn
 902                   (goto-char (point-max))
 903                   ;; Keep empty last line, if available.
 904                   (if (bolp) (1- (point)) (point)))))
 905       (if (< end beg)
 906           (setq beg (prog1 end (setq end beg))))
 907       ;; First hide everything.
 908       (outline-flag-region beg end t)
 909       ;; Then unhide the top level headers.
 910       (outline-map-region
 911        (lambda ()
 912          (if (<= (funcall outline-level) levels)
 913              (outline-show-heading)))
 914        beg end)
 915       ;; Finally unhide any trailing newline.
 916       (goto-char (point-max))
 917       (if (and (bolp) (not (bobp)) (outline-invisible-p (1- (point))))
 918           (outline-flag-region (1- (point)) (point) nil))))
 919   (run-hooks 'outline-view-change-hook))
 920
 921 (defun hide-other ()
 922   "Hide everything except current body and parent and top-level headings."
 923   (interactive)
 924   (hide-sublevels 1)
 925   (let (outline-view-change-hook)
 926     (save-excursion
 927       (outline-back-to-heading t)
 928       (show-entry)
 929       (while (condition-case nil (progn (outline-up-heading 1 t) (not (bobp)))
 930                (error nil))
 931         (outline-flag-region (1- (point))
 932                              (save-excursion (forward-line 1) (point))
 933                              nil))))
 934   (run-hooks 'outline-view-change-hook))
 935
 936 (defun outline-toggle-children ()
 937   "Show or hide the current subtree depending on its current state."
 938   (interactive)
 939   (save-excursion
 940     (outline-back-to-heading)
 941     (if (not (outline-invisible-p (line-end-position)))
 942         (hide-subtree)
 943       (show-children)
 944       (show-entry))))
 945
 946 (defun outline-flag-subtree (flag)
 947   (save-excursion
 948     (outline-back-to-heading)
 949     (outline-end-of-heading)
 950     (outline-flag-region (point)
 951                           (progn (outline-end-of-subtree) (point))
 952                           flag)))
 953
 954 (defun outline-end-of-subtree ()
 955   (outline-back-to-heading)
 956   (let ((first t)
 957         (level (funcall outline-level)))
 958     (while (and (not (eobp))
 959                 (or first (> (funcall outline-level) level)))
 960       (setq first nil)
 961       (outline-next-heading))
 962     (if (and (bolp) (not (eolp)))
 963         ;; We stopped at a nonempty line (the next heading).
 964         (progn
 965           ;; Go to end of line before heading
 966           (forward-char -1)
 967           (if (and outline-blank-line (bolp))
 968               ;; leave blank line before heading
 969               (forward-char -1))))))
 970 \f
 971 (defun show-branches ()
 972   "Show all subheadings of this heading, but not their bodies."
 973   (interactive)
 974   (show-children 1000))
 975
 976 (defun show-children (&optional level)
 977   "Show all direct subheadings of this heading.
 978 Prefix arg LEVEL is how many levels below the current level should be shown.
 979 Default is enough to cause the following heading to appear."
 980   (interactive "P")
 981   (setq level
 982         (if level (prefix-numeric-value level)
 983           (save-excursion
 984             (outline-back-to-heading)
 985             (let ((start-level (funcall outline-level)))
 986               (outline-next-heading)
 987               (if (eobp)
 988                   1
 989                 (max 1 (- (funcall outline-level) start-level)))))))
 990   (let (outline-view-change-hook)
 991     (save-excursion
 992       (outline-back-to-heading)
 993       (setq level (+ level (funcall outline-level)))
 994       (outline-map-region
 995        (lambda ()
 996          (if (<= (funcall outline-level) level)
 997              (outline-show-heading)))
 998        (point)
 999        (progn (outline-end-of-subtree)
1000               (if (eobp) (point-max) (1+ (point)))))))
1001   (run-hooks 'outline-view-change-hook))
1002
1003 \f
1004
1005 (defun outline-up-heading (arg &optional invisible-ok)
1006   "Move to the visible heading line of which the present line is a subheading.
1007 With argument, move up ARG levels.
1008 If INVISIBLE-OK is non-nil, also consider invisible lines."
1009   (interactive "p")
1010   (and (eq this-command 'outline-up-heading)
1011        (or (eq last-command 'outline-up-heading) (push-mark)))
1012   (outline-back-to-heading invisible-ok)
1013   (let ((start-level (funcall outline-level)))
1014     (when (<= start-level 1)
1015       (error "Already at top level of the outline"))
1016     (while (and (> start-level 1) (> arg 0) (not (bobp)))
1017       (let ((level start-level))
1018         (while (not (or (< level start-level) (bobp)))
1019           (if invisible-ok
1020               (outline-previous-heading)
1021             (outline-previous-visible-heading 1))
1022           (setq level (funcall outline-level)))
1023         (setq start-level level))
1024       (setq arg (- arg 1))))
1025   (looking-at outline-regexp))
1026
1027 (defun outline-forward-same-level (arg)
1028   "Move forward to the ARG'th subheading at same level as this one.
1029 Stop at the first and last subheadings of a superior heading."
1030   (interactive "p")
1031   (outline-back-to-heading)
1032   (while (> arg 0)
1033     (let ((point-to-move-to (save-excursion
1034                               (outline-get-next-sibling))))
1035       (if point-to-move-to
1036           (progn
1037             (goto-char point-to-move-to)
1038             (setq arg (1- arg)))
1039         (progn
1040           (setq arg 0)
1041           (error "No following same-level heading"))))))
1042
1043 (defun outline-get-next-sibling ()
1044   "Move to next heading of the same level, and return point.
1045 If there is no such heading, return nil."
1046   (let ((level (funcall outline-level)))
1047     (outline-next-visible-heading 1)
1048     (while (and (not (eobp)) (> (funcall outline-level) level))
1049       (outline-next-visible-heading 1))
1050     (if (or (eobp) (< (funcall outline-level) level))
1051         nil
1052       (point))))
1053
1054 (defun outline-backward-same-level (arg)
1055   "Move backward to the ARG'th subheading at same level as this one.
1056 Stop at the first and last subheadings of a superior heading."
1057   (interactive "p")
1058   (outline-back-to-heading)
1059   (while (> arg 0)
1060     (let ((point-to-move-to (save-excursion
1061                               (outline-get-last-sibling))))
1062       (if point-to-move-to
1063           (progn
1064             (goto-char point-to-move-to)
1065             (setq arg (1- arg)))
1066         (progn
1067           (setq arg 0)
1068           (error "No previous same-level heading"))))))
1069
1070 (defun outline-get-last-sibling ()
1071   "Move to previous heading of the same level, and return point.
1072 If there is no such heading, return nil."
1073   (let ((opoint (point))
1074         (level (funcall outline-level)))
1075     (outline-previous-visible-heading 1)
1076     (when (and (/= (point) opoint) (outline-on-heading-p))
1077       (while (and (> (funcall outline-level) level)
1078                   (not (bobp)))
1079         (outline-previous-visible-heading 1))
1080       (if (< (funcall outline-level) level)
1081           nil
1082         (point)))))
1083 \f
1084 (defun outline-headers-as-kill (beg end)
1085   "Save the visible outline headers in region at the start of the kill ring.
1086
1087 Text shown between the headers isn't copied.  Two newlines are
1088 inserted between saved headers.  Yanking the result may be a
1089 convenient way to make a table of contents of the buffer."
1090   (interactive "r")
1091   (save-excursion
1092     (save-restriction
1093       (narrow-to-region beg end)
1094       (goto-char (point-min))
1095       (let ((buffer (current-buffer))
1096             start end)
1097         (with-temp-buffer
1098           (with-current-buffer buffer
1099             ;; Boundary condition: starting on heading:
1100             (when (outline-on-heading-p)
1101               (outline-back-to-heading)
1102               (setq start (point)
1103                     end (progn (outline-end-of-heading)
1104                                (point)))
1105               (insert-buffer-substring buffer start end)
1106               (insert "\n\n")))
1107           (let ((temp-buffer (current-buffer)))
1108             (with-current-buffer buffer
1109               (while (outline-next-heading)
1110                 (unless (outline-invisible-p)
1111                   (setq start (point)
1112                         end (progn (outline-end-of-heading) (point)))
1113                   (with-current-buffer temp-buffer
1114                     (insert-buffer-substring buffer start end)
1115                     (insert "\n\n"))))))
1116           (kill-new (buffer-string)))))))
1117
1118 (provide 'outline)
1119 (provide 'noutline)
1120
1121 ;;; outline.el ends here