lisp/lpr.el

   1 ;;; lpr.el --- print Emacs buffer on line printer
   2
   3 ;; Copyright (C) 1985, 1988, 1992, 1994, 2001-2014 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: unix
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Commands to send the region or a buffer to your printer.  Entry points
  27 ;; are `lpr-buffer', `print-buffer', `lpr-region', or `print-region'; option
  28 ;; variables include `printer-name', `lpr-switches' and `lpr-command'.
  29
  30 ;;; Code:
  31
  32 ;;;###autoload
  33 (defvar lpr-windows-system
  34   (memq system-type '(ms-dos windows-nt))
  35   "Non-nil if running on MS-DOS or MS Windows.")
  36
  37 ;;;###autoload
  38 (defvar lpr-lp-system
  39   (memq system-type '(usg-unix-v hpux irix))
  40   "Non-nil if running on a system type that uses the \"lp\" command.")
  41
  42
  43 (defgroup lpr nil
  44   "Print Emacs buffer on line printer."
  45   :group 'wp)
  46
  47
  48 ;;;###autoload
  49 (defcustom printer-name
  50   (and (eq system-type 'ms-dos) "PRN")
  51   "The name of a local printer to which data is sent for printing.
  52 \(Note that PostScript files are sent to `ps-printer-name', which see.\)
  53
  54 On Unix-like systems, a string value should be a name understood by
  55 lpr's -P option; otherwise the value should be nil.
  56
  57 On MS-DOS and MS-Windows systems, a string value is taken as the name of
  58 a printer device or port, provided `lpr-command' is set to \"\".
  59 Typical non-default settings would be \"LPT1\" to \"LPT3\" for parallel
  60 printers, or \"COM1\" to \"COM4\" or \"AUX\" for serial printers, or
  61 \"//hostname/printer\" for a shared network printer.  You can also set
  62 it to the name of a file, in which case the output gets appended to that
  63 file.  If you want to discard the printed output, set this to \"NUL\"."
  64   :type '(choice :menu-tag "Printer Name"
  65                  :tag "Printer Name"
  66                  (const :tag "Default" nil)
  67                  ;; could use string but then we lose completion for files.
  68                  (file :tag "Name"))
  69   :group 'lpr)
  70
  71 ;;;###autoload
  72 (defcustom lpr-switches nil
  73   "List of strings to pass as extra options for the printer program.
  74 It is recommended to set `printer-name' instead of including an explicit
  75 switch on this list.
  76 See `lpr-command'."
  77   :type '(repeat (string :tag "Argument"))
  78   :group 'lpr)
  79
  80 (defcustom lpr-add-switches (memq system-type '(berkeley-unix gnu/linux))
  81   "Non-nil means construct `-T' and `-J' options for the printer program.
  82 These are made assuming that the program is `lpr';
  83 if you are using some other incompatible printer program,
  84 this variable should be nil."
  85   :type 'boolean
  86   :group 'lpr)
  87
  88 (defcustom lpr-printer-switch
  89   (if lpr-lp-system
  90       "-d "
  91     "-P")
  92   "Printer switch, that is, something like \"-P\", \"-d \", \"/D:\", etc.
  93 This switch is used in conjunction with `printer-name'."
  94   :type '(choice :menu-tag "Printer Name Switch"
  95                  :tag "Printer Name Switch"
  96                  (const :tag "None" nil)
  97                  (string :tag "Printer Switch"))
  98   :group 'lpr)
  99
 100 ;;;###autoload
 101 (defcustom lpr-command
 102  (purecopy
 103   (cond
 104    (lpr-windows-system
 105     "")
 106    (lpr-lp-system
 107     "lp")
 108    (t
 109     "lpr")))
 110   "Name of program for printing a file.
 111
 112 On MS-DOS and MS-Windows systems, if the value is an empty string then
 113 Emacs will write directly to the printer port named by `printer-name'.
 114 The programs `print' and `nprint' (the standard print programs on
 115 Windows NT and Novell Netware respectively) are handled specially, using
 116 `printer-name' as the destination for output; any other program is
 117 treated like `lpr' except that an explicit filename is given as the last
 118 argument."
 119   :type 'string
 120   :group 'lpr)
 121
 122 ;; Default is nil, because that enables us to use pr -f
 123 ;; which is more reliable than pr with no args, which is what lpr -p does.
 124 (defcustom lpr-headers-switches nil
 125   "List of strings of options to request page headings in the printer program.
 126 If nil, we run `lpr-page-header-program' to make page headings
 127 and print the result."
 128   :type '(choice (const nil)
 129                  (string :tag "Single argument")
 130                  (repeat :tag "Multiple arguments" (string :tag "Argument")))
 131   :group 'lpr)
 132
 133 (defcustom print-region-function
 134   (if (memq system-type '(ms-dos windows-nt))
 135       #'w32-direct-print-region-function
 136     #'call-process-region)
 137   "Function to call to print the region on a printer.
 138 See definition of `print-region-1' for calling conventions."
 139   :type 'function
 140   :group 'lpr)
 141
 142 (defcustom lpr-page-header-program "pr"
 143   "Name of program for adding page headers to a file."
 144   :type 'string
 145   :group 'lpr)
 146
 147 ;; Berkeley systems support -F, and GNU pr supports both -f and -F,
 148 ;; So it looks like -F is a better default.
 149 (defcustom lpr-page-header-switches '("-h" "%s" "-F")
 150   "List of strings to use as options for the page-header-generating program.
 151 If `%s' appears in any of the strings, it is substituted by the page title.
 152 Note that for correct quoting, `%s' should normally be a separate element.
 153 The variable `lpr-page-header-program' specifies the program to use."
 154   :type '(repeat string)
 155   :group 'lpr)
 156
 157 ;;;###autoload
 158 (defun lpr-buffer ()
 159   "Print buffer contents without pagination or page headers.
 160 See the variables `lpr-switches' and `lpr-command'
 161 for customization of the printer command."
 162   (interactive
 163    (unless (y-or-n-p "Send current buffer to default printer? ")
 164      (error "Cancelled")))
 165   (print-region-1 (point-min) (point-max) lpr-switches nil))
 166
 167 ;;;###autoload
 168 (defun print-buffer ()
 169   "Paginate and print buffer contents.
 170
 171 The variable `lpr-headers-switches' controls how to paginate.
 172 If it is nil (the default), we run the `pr' program (or whatever program
 173 `lpr-page-header-program' specifies) to paginate.
 174 `lpr-page-header-switches' specifies the switches for that program.
 175
 176 Otherwise, the switches in `lpr-headers-switches' are used
 177 in the print command itself; we expect them to request pagination.
 178
 179 See the variables `lpr-switches' and `lpr-command'
 180 for further customization of the printer command."
 181   (interactive
 182    (unless (y-or-n-p "Send current buffer to default printer? ")
 183      (error "Cancelled")))
 184   (print-region-1 (point-min) (point-max) lpr-switches t))
 185
 186 ;;;###autoload
 187 (defun lpr-region (start end)
 188   "Print region contents without pagination or page headers.
 189 See the variables `lpr-switches' and `lpr-command'
 190 for customization of the printer command."
 191   (interactive
 192    (if (y-or-n-p "Send selected text to default printer? ")
 193        (list (region-beginning) (region-end))
 194      (error "Cancelled")))
 195   (print-region-1 start end lpr-switches nil))
 196
 197 ;;;###autoload
 198 (defun print-region (start end)
 199   "Paginate and print the region contents.
 200
 201 The variable `lpr-headers-switches' controls how to paginate.
 202 If it is nil (the default), we run the `pr' program (or whatever program
 203 `lpr-page-header-program' specifies) to paginate.
 204 `lpr-page-header-switches' specifies the switches for that program.
 205
 206 Otherwise, the switches in `lpr-headers-switches' are used
 207 in the print command itself; we expect them to request pagination.
 208
 209 See the variables `lpr-switches' and `lpr-command'
 210 for further customization of the printer command."
 211   (interactive
 212    (if (y-or-n-p "Send selected text to default printer? ")
 213        (list (region-beginning) (region-end))
 214      (error "Cancelled")))
 215   (print-region-1 start end lpr-switches t))
 216
 217 (defun print-region-1 (start end switches page-headers)
 218   (and page-headers lpr-headers-switches
 219        ;; It's possible to use an lpr option to get page headers.
 220        (setq switches (append (if (stringp lpr-headers-switches)
 221                                   (list lpr-headers-switches)
 222                                 lpr-headers-switches)
 223                               switches)))
 224   ;; On some MIPS system, having a space in the job name
 225   ;; crashes the printer demon.  But using dashes looks ugly
 226   ;; and it seems to annoying to do for that MIPS system.
 227   (save-excursion
 228     (let ((name  (concat (buffer-name) " Emacs buffer"))
 229           ;; Make pipes use the same coding system as
 230           ;; writing the buffer to a file would.
 231           (coding-system-for-write (or coding-system-for-write
 232                                        buffer-file-coding-system))
 233           (coding-system-for-read  (or coding-system-for-read
 234                                        buffer-file-coding-system))
 235           (width tab-width))
 236       (if (/= tab-width 8)
 237           (let ((new-coords (print-region-new-buffer start end)))
 238             (setq start     (car new-coords)
 239                   end       (cdr new-coords)
 240                   tab-width width)
 241             (save-excursion
 242               (goto-char end)
 243               (setq end (point-marker)))
 244             (untabify (point-min) (point-max))))
 245       (if page-headers
 246           (if lpr-headers-switches
 247               ;; We handled this above by modifying SWITCHES.
 248               nil
 249             ;; Run a separate program to get page headers.
 250             (let ((new-coords (print-region-new-buffer start end)))
 251               (apply 'call-process-region (car new-coords) (cdr new-coords)
 252                      lpr-page-header-program t t nil
 253                      (mapcar (lambda (e) (format e name))
 254                              lpr-page-header-switches)))
 255             (setq start (point-min)
 256                   end   (point-max))))
 257       (lpr-print-region start end switches name))))
 258
 259 (defun lpr-print-region (start end switches name)
 260   (let ((buf (current-buffer))
 261         (nswitches (lpr-flatten-list
 262                     (mapcar #'lpr-eval-switch ; Dynamic evaluation
 263                             switches)))
 264         (switch-string (if switches
 265                            (concat " with options "
 266                                    (mapconcat #'identity switches " "))
 267                          "")))
 268     (message "Spooling%s..." switch-string)
 269     (with-temp-buffer
 270       (let ((retval
 271              (let ((tempbuf (current-buffer)))
 272                (with-current-buffer buf
 273                  (apply (or print-region-function 'call-process-region)
 274                         start end lpr-command
 275                         nil tempbuf nil
 276                         (nconc (and name lpr-add-switches
 277                                     (list "-J" name))
 278                                ;; These belong in pr if we are using that.
 279                                (and name lpr-add-switches lpr-headers-switches
 280                                     (list "-T" name))
 281                                (and (stringp printer-name)
 282                                     (string< "" printer-name)
 283                                     (list (concat lpr-printer-switch
 284                                                   printer-name)))
 285                                nswitches))))))
 286         (if (markerp end)
 287             (set-marker end nil))
 288         (funcall (if (memq retval '(nil 0)) #'message #'user-error)
 289                  "Spooling%s...done%s%s" switch-string
 290                  (pcase (count-lines (point-min) (point-max))
 291                    (0 "")
 292                    (1 ": ")
 293                    (_ ":\n"))
 294                  (buffer-string))))))
 295
 296 ;; This function copies the text between start and end
 297 ;; into a new buffer, makes that buffer current.
 298 ;; It returns the new range to print from the new current buffer
 299 ;; as (START . END).
 300
 301 (defun print-region-new-buffer (ostart oend)
 302   (if (string= (buffer-name) " *spool temp*")
 303       (cons ostart oend)
 304     (let ((oldbuf (current-buffer)))
 305       (set-buffer (get-buffer-create " *spool temp*"))
 306       (widen)
 307       (erase-buffer)
 308       (insert-buffer-substring oldbuf ostart oend)
 309       (cons (point-min) (point-max)))))
 310
 311 (defun printify-region (begin end)
 312   "Replace nonprinting characters in region with printable representations.
 313 The printable representations use ^ (for ASCII control characters) or hex.
 314 The characters tab, linefeed, space, return and formfeed are not affected."
 315   (interactive "r")
 316   (save-excursion
 317     (save-restriction
 318       (narrow-to-region begin end)
 319       (goto-char (point-min))
 320       (let (c)
 321         (while (re-search-forward "[\^@-\^h\^k\^n-\^_\177-\377]" nil t)
 322           (setq c (preceding-char))
 323           (delete-char -1)
 324           (insert (if (< c ?\s)
 325                       (format "\\^%c" (+ c ?@))
 326                     (format "\\%02x" c))))))))
 327
 328 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 329 ;; Functions hacked from `ps-print' package.
 330
 331 ;; Dynamic evaluation
 332 (defun lpr-eval-switch (arg)
 333   (cond ((stringp arg) arg)
 334         ((functionp arg) (funcall arg))
 335         ((symbolp arg) (symbol-value arg))
 336         ((consp arg) (apply (car arg) (cdr arg)))
 337         (t nil)))
 338
 339 ;; `lpr-flatten-list' is defined here (copied from "message.el" and
 340 ;; enhanced to handle dotted pairs as well) until we can get some
 341 ;; sensible autoloads, or `flatten-list' gets put somewhere decent.
 342
 343 ;; (lpr-flatten-list '((a . b) c (d . e) (f g h) i . j))
 344 ;; => (a b c d e f g h i j)
 345
 346 (defun lpr-flatten-list (&rest list)
 347   (lpr-flatten-list-1 list))
 348
 349 (defun lpr-flatten-list-1 (list)
 350   (cond
 351    ((null list) nil)
 352    ((consp list)
 353     (append (lpr-flatten-list-1 (car list))
 354             (lpr-flatten-list-1 (cdr list))))
 355    (t (list list))))
 356
 357 (provide 'lpr)
 358
 359 ;;; lpr.el ends here