lisp/international/mule-diag.el

   1 ;;; mule-diag.el --- show diagnosis of multilingual environment (Mule)
   2
   3 ;; Copyright (C) 1997-1998, 2000-2014 Free Software Foundation, Inc.
   4 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   5 ;;   2005, 2006, 2007, 2008, 2009, 2010, 2011
   6 ;;   National Institute of Advanced Industrial Science and Technology (AIST)
   7 ;;   Registration Number H14PRO021
   8 ;; Copyright (C) 2003
   9 ;;   National Institute of Advanced Industrial Science and Technology (AIST)
  10 ;;   Registration Number H13PRO009
  11
  12 ;; Keywords: multilingual, charset, coding system, fontset, diagnosis, i18n
  13
  14 ;; This file is part of GNU Emacs.
  15
  16 ;; GNU Emacs is free software: you can redistribute it and/or modify
  17 ;; it under the terms of the GNU General Public License as published by
  18 ;; the Free Software Foundation, either version 3 of the License, or
  19 ;; (at your option) any later version.
  20
  21 ;; GNU Emacs is distributed in the hope that it will be useful,
  22 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 ;; GNU General Public License for more details.
  25
  26 ;; You should have received a copy of the GNU General Public License
  27 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  28
  29 ;;; Commentary:
  30
  31 ;;; Code:
  32
  33 ;; Make sure the help-xref button type is defined.
  34 (require 'help-mode)
  35
  36 ;;; General utility function
  37
  38 (defun print-list (&rest args)
  39   "Print all arguments with single space separator in one line."
  40   (princ (mapconcat (lambda (arg) (prin1-to-string arg t)) args " "))
  41   (princ "\n"))
  42
  43 ;;; CHARSET
  44
  45 (define-button-type 'sort-listed-character-sets
  46   'help-echo (purecopy "mouse-2, RET: sort on this column")
  47   'face 'bold
  48   'action #'(lambda (button)
  49               (sort-listed-character-sets (button-get button 'sort-key))))
  50
  51 (define-button-type 'list-charset-chars
  52   :supertype 'help-xref
  53   'help-function #'list-charset-chars
  54   'help-echo "mouse-2, RET: show table of characters for this character set")
  55
  56 ;;;###autoload
  57 (defun list-character-sets (arg)
  58   "Display a list of all character sets.
  59
  60 The D column contains the dimension of this character set.  The CH
  61 column contains the number of characters in a block of this character
  62 set.  The FINAL-BYTE column contains an ISO-2022 <final-byte> to use
  63 in the designation escape sequence for this character set in
  64 ISO-2022-based coding systems.
  65
  66 With prefix ARG, the output format gets more cryptic,
  67 but still shows the full information."
  68   (interactive "P")
  69   (help-setup-xref (list #'list-character-sets arg)
  70                    (called-interactively-p 'interactive))
  71   (with-output-to-temp-buffer "*Character Set List*"
  72     (with-current-buffer standard-output
  73       (if arg
  74           (list-character-sets-2)
  75         ;; Insert header.
  76         (insert "Supplementary character sets are shown below.\n")
  77         (insert
  78          (substitute-command-keys
  79           (concat "Use "
  80                   (if (display-mouse-p) "\\[help-follow-mouse] or ")
  81                   "\\[help-follow]:\n")))
  82         (insert "  on a column title to sort by that title,")
  83         (indent-to 48)
  84         (insert "+----DIMENSION\n")
  85         (insert "  on a charset name to list characters.")
  86         (indent-to 48)
  87         (insert "| +--CHARS\n")
  88         (let ((columns '(("CHARSET-NAME" . name) "\t\t\t\t\t"
  89                          ("D CH  FINAL-BYTE" . iso-spec)))
  90               pos)
  91           (while columns
  92             (if (stringp (car columns))
  93                 (insert (car columns))
  94               (insert-text-button (car (car columns))
  95                                   :type 'sort-listed-character-sets
  96                                   'sort-key (cdr (car columns)))
  97               (goto-char (point-max)))
  98             (setq columns (cdr columns)))
  99           (insert "\n"))
 100         (insert "------------\t\t\t\t\t- --- ----------\n")
 101
 102         ;; Insert body sorted by charset IDs.
 103         (list-character-sets-1 'name)))))
 104
 105 (defun sort-listed-character-sets (sort-key)
 106   (if sort-key
 107       (save-excursion
 108         (let ((buffer-read-only nil))
 109           (goto-char (point-min))
 110           (search-forward "\n-")
 111           (forward-line 1)
 112           (delete-region (point) (point-max))
 113           (list-character-sets-1 sort-key)))))
 114
 115 (defun list-character-sets-1 (sort-key)
 116   "Insert a list of character sets sorted by SORT-KEY.
 117 SORT-KEY should be `name' or `iso-spec' (default `name')."
 118   (or sort-key
 119       (setq sort-key 'name))
 120   (let ((tail charset-list)
 121         charset-info-list supplementary-list charset sort-func)
 122     (dolist (charset charset-list)
 123       ;; Generate a list that contains all information to display.
 124       (let ((elt (list charset
 125                        (charset-dimension charset)
 126                        (charset-chars charset)
 127                        (charset-iso-final-char charset))))
 128         (if (plist-get (charset-plist charset) :supplementary-p)
 129             (push elt supplementary-list)
 130           (push elt charset-info-list))))
 131
 132     ;; Determine a predicate for `sort' by SORT-KEY.
 133     (setq sort-func
 134           (cond ((eq sort-key 'name)
 135                  (lambda (x y) (string< (car x) (car y))))
 136
 137                 ((eq sort-key 'iso-spec)
 138                  ;; Sort by DIMENSION CHARS FINAL-CHAR
 139                  (function
 140                   (lambda (x y)
 141                     (or (< (nth 1 x) (nth 1 y))
 142                         (and (= (nth 1 x) (nth 1 y))
 143                              (or (< (nth 2 x) (nth 2 y))
 144                                  (and (= (nth 2 x) (nth 2 y))
 145                                       (< (nth 3 x) (nth 3 y)))))))))
 146                 (t
 147                  (error "Invalid charset sort key: %s" sort-key))))
 148
 149     (setq charset-info-list (sort charset-info-list sort-func))
 150     (setq supplementary-list (sort supplementary-list sort-func))
 151
 152     ;; Insert information of character sets.
 153     (dolist (elt (append charset-info-list (list t) supplementary-list))
 154       (if (eq elt t)
 155           (progn
 156             (insert "\n-------------- ")
 157             (insert-text-button "Supplementary Character Sets"
 158                                 'type 'help-info
 159                                 'help-args '("(emacs)Charsets"))
 160             (insert " --------------
 161 Character sets for defining other charsets, or for backward compatibility
 162 "))
 163         (insert-text-button (symbol-name (car elt)) ; NAME
 164                             :type 'list-charset-chars
 165                             'help-args (list (car elt)))
 166         (goto-char (point-max))
 167         (insert "\t")
 168         (indent-to 48)
 169         (insert (format "%d %3d "
 170                         (nth 1 elt) (nth 2 elt)) ; DIMENSION and CHARS
 171                 (if (< (nth 3 elt) 0)
 172                     "none"
 173                   (nth 3 elt))))        ; FINAL-CHAR
 174       (insert "\n"))))
 175
 176
 177 ;; List all character sets in a form that a program can easily parse.
 178
 179 (defun list-character-sets-2 ()
 180   (insert "#########################
 181 ## LIST OF CHARSETS
 182 ## Each line corresponds to one charset.
 183 ## The following attributes are listed in this order
 184 ## separated by a colon `:' in one line.
 185 ##      CHARSET-SYMBOL-NAME,
 186 ##      DIMENSION (1-4)
 187 ##      CHARS (number of characters in first dimension of charset)
 188 ##      ISO-FINAL-CHAR (character code of ISO-2022's final character)
 189 ##              -1 means that no final character is assigned.
 190 ##      DESCRIPTION (describing string of the charset)
 191 ")
 192   (dolist (charset charset-list)
 193     (princ (format "%s:%d:%d:%d:%s\n"
 194                    charset
 195                    (charset-dimension charset)
 196                    (charset-chars charset)
 197 ;;;                (char-width (make-char charset))
 198 ;;;                (charset-direction charset)
 199                    (charset-iso-final-char charset)
 200 ;;;                (charset-iso-graphic-plane charset)
 201                    (charset-description charset)))))
 202
 203 (defvar non-iso-charset-alist nil
 204   "Obsolete.")
 205 (make-obsolete-variable 'non-iso-charset-alist "no longer relevant." "23.1")
 206
 207 (defun decode-codepage-char (codepage code)
 208   "Decode a character that has code CODE in CODEPAGE.
 209 Return a decoded character string.  Each CODEPAGE corresponds to a
 210 coding system cpCODEPAGE."
 211   (declare (obsolete decode-char "23.1"))
 212   (decode-char (intern (format "cp%d" codepage)) code))
 213
 214 ;; A variable to hold charset input history.
 215 (defvar charset-history nil)
 216
 217
 218 ;;;###autoload
 219 (defun read-charset (prompt &optional default-value initial-input)
 220   "Read a character set from the minibuffer, prompting with string PROMPT.
 221 It must be an Emacs character set listed in the variable `charset-list'.
 222
 223 Optional arguments are DEFAULT-VALUE and INITIAL-INPUT.
 224 DEFAULT-VALUE, if non-nil, is the default value.
 225 INITIAL-INPUT, if non-nil, is a string inserted in the minibuffer initially.
 226 See the documentation of the function `completing-read' for the detailed
 227 meanings of these arguments."
 228   (let* ((table (mapcar (lambda (x) (list (symbol-name x))) charset-list))
 229          (charset (completing-read prompt table
 230                                    nil t initial-input 'charset-history
 231                                    default-value)))
 232     (if (> (length charset) 0)
 233         (intern charset))))
 234
 235 ;; List characters of the range MIN and MAX of CHARSET.  If dimension
 236 ;; of CHARSET is two (i.e. 2-byte charset), ROW is the first byte
 237 ;; (block index) of the characters, and MIN and MAX are the second
 238 ;; bytes of the characters.  If the dimension is one, ROW should be 0.
 239
 240 (defun list-block-of-chars (charset row min max)
 241   (let (i ch)
 242     (insert-char ?- (+ 7 (* 4 16)))
 243     (insert "\n     ")
 244     (setq i 0)
 245     (while (< i 16)
 246       (insert (format "%4X" i))
 247       (setq i (1+ i)))
 248     (setq i (* (/ min 16) 16))
 249     (while (<= i max)
 250       (if (= (% i 16) 0)
 251           (insert (format "\n%6Xx" (/ (+ (* row 256) i) 16))))
 252       (setq ch (if (< i min)
 253                    32
 254                  (or (decode-char charset (+ (* row 256) i))
 255                      32)))              ; gap in mapping
 256       ;; Don't insert control codes, non-Unicode characters.
 257       (if (or (< ch 32) (= ch 127))
 258           (setq ch (single-key-description ch))
 259         (if (and (>= ch 128) (< ch 160))
 260             (setq ch (format "%02Xh" ch))
 261           (if (> ch #x10FFFF)
 262               (setq ch 32))))
 263       (insert "\t" ch)
 264       (setq i (1+ i))))
 265   (insert "\n"))
 266
 267 ;;;###autoload
 268 (defun list-charset-chars (charset)
 269   "Display a list of characters in character set CHARSET."
 270   (interactive (list (read-charset "Character set: ")))
 271   (or (charsetp charset)
 272       (error "Invalid character set: %s" charset))
 273   (with-output-to-temp-buffer "*Character List*"
 274     (with-current-buffer standard-output
 275       (if (coding-system-p charset)
 276           ;; Useful to be able to do C-u C-x = to find file code, for
 277           ;; instance:
 278           (set-buffer-file-coding-system charset))
 279       (setq mode-line-format (copy-sequence mode-line-format))
 280       (let ((slot (memq 'mode-line-buffer-identification mode-line-format)))
 281         (if slot
 282             (setcdr slot
 283                     (cons (format " (%s)" charset)
 284                           (cdr slot)))))
 285       (setq tab-width 4)
 286       (set-buffer-multibyte t)
 287       (let ((dim (charset-dimension charset))
 288             (chars (charset-chars charset))
 289             ;;  (plane (charset-iso-graphic-plane charset))
 290             (plane 1)
 291             (range (plist-get (charset-plist charset) :code-space))
 292             min max min2 max2)
 293         (if (> dim 2)
 294             (error "Can only list 1- and 2-dimensional charsets"))
 295         (insert (format "Characters in the coded character set %s.\n" charset))
 296         (narrow-to-region (point) (point))
 297         (setq min (aref range 0)
 298               max (aref range 1))
 299         (if (= dim 1)
 300             (list-block-of-chars charset 0 min max)
 301           (setq min2 (aref range 2)
 302                 max2 (aref range 3))
 303           (let ((i min2))
 304             (while (<= i max2)
 305               (list-block-of-chars charset i min max)
 306               (setq i (1+ i)))))
 307         (put-text-property (point-min) (point-max) 'charset charset)
 308         (widen)))))
 309
 310
 311 ;;;###autoload
 312 (defun describe-character-set (charset)
 313   "Display information about built-in character set CHARSET."
 314   (interactive (list (read-charset "Charset: ")))
 315   (or (charsetp charset)
 316       (error "Invalid charset: %S" charset))
 317   (help-setup-xref (list #'describe-character-set charset)
 318                    (called-interactively-p 'interactive))
 319   (with-output-to-temp-buffer (help-buffer)
 320     (with-current-buffer standard-output
 321       (insert "Character set: " (symbol-name charset))
 322       (let ((name (get-charset-property charset :name)))
 323         (if (not (eq name charset))
 324             (insert " (alias of " (symbol-name name) ?\))))
 325       (insert "\n\n" (charset-description charset) "\n\n")
 326       (insert "Number of contained characters: ")
 327       (dotimes (i (charset-dimension charset))
 328         (unless (= i 0)
 329           (insert ?x))
 330         (insert (format "%d" (charset-chars charset (1+ i)))))
 331       (insert ?\n)
 332       (let ((char (charset-iso-final-char charset)))
 333         (when (> char 0)
 334           (insert "Final char of ISO2022 designation sequence: ")
 335           (insert (format "`%c'\n" char))))
 336       (let (aliases)
 337         (dolist (c charset-list)
 338           (if (and (not (eq c charset))
 339                    (eq charset (get-charset-property c :name)))
 340               (push c aliases)))
 341         (if aliases
 342             (insert "Aliases: " (mapconcat #'symbol-name aliases ", ") ?\n)))
 343
 344       (dolist (elt `((:ascii-compatible-p "ASCII compatible." nil)
 345                      (:map "Map file: " identity)
 346                      (:unify-map "Unification map file: " identity)
 347                      (:invalid-code
 348                       nil
 349                       ,(lambda (c)
 350                          (format "Invalid character: %c (code %d)" c c)))
 351                      (:emacs-mule-id "Id in emacs-mule coding system: "
 352                                      number-to-string)
 353                      (:parents "Parents: "
 354                                (lambda (parents)
 355                                  (mapconcat ,(lambda (elt)
 356                                                (format "%s" elt))
 357                                             parents
 358                                             ", ")))
 359                      (:code-space "Code space: " ,(lambda (c)
 360                                                     (format "%s" c)))
 361                      (:code-offset "Code offset: " number-to-string)
 362                      (:iso-revision-number "ISO revision number: "
 363                                            number-to-string)
 364                      (:supplementary-p
 365                       "Used only as a parent of some other charset." nil)))
 366         (let ((val (get-charset-property charset (car elt))))
 367           (when val
 368             (if (cadr elt) (insert (cadr elt)))
 369             (if (nth 2 elt)
 370                 (let ((print-length 10) (print-level 2))
 371                   (princ (funcall (nth 2 elt) val) (current-buffer))))
 372             (insert ?\n)))))))
 373 \f
 374 ;;; CODING-SYSTEM
 375
 376 (defvar graphic-register)               ; dynamic bondage
 377
 378 ;; Print information about designation of each graphic register in
 379 ;; DESIGNATIONS in human readable format.  See the documentation of
 380 ;; `define-coding-system' for the meaning of DESIGNATIONS
 381 ;; (`:designation' property).
 382 (defun print-designation (designations)
 383   (let (charset)
 384     (dotimes (graphic-register 4)
 385       (setq charset (aref designations graphic-register))
 386       (princ (format
 387               "  G%d -- %s\n"
 388               graphic-register
 389               (cond ((null charset)
 390                      "never used")
 391                     ((eq charset t)
 392                      "no initial designation, and used by any charsets")
 393                     ((symbolp charset)
 394                      (format "%s:%s"
 395                              charset (charset-description charset)))
 396                     ((listp charset)
 397                      (if (charsetp (car charset))
 398                          (format "%s:%s, and also used by the following:"
 399                                  (car charset)
 400                                  (charset-description (car charset)))
 401                        "no initial designation, and used by the following:"))
 402                     (t
 403                      "invalid designation information"))))
 404       (when (listp charset)
 405         (setq charset (cdr charset))
 406         (while charset
 407           (cond ((eq (car charset) t)
 408                  (princ "\tany other charsets\n"))
 409                 ((charsetp (car charset))
 410                  (princ (format "\t%s:%s\n"
 411                                 (car charset)
 412                                 (charset-description (car charset)))))
 413                 (t
 414                  "invalid designation information"))
 415           (setq charset (cdr charset)))))))
 416
 417 ;;;###autoload
 418 (defun describe-coding-system (coding-system)
 419   "Display information about CODING-SYSTEM."
 420   (interactive "zDescribe coding system (default current choices): ")
 421   (if (null coding-system)
 422       (describe-current-coding-system)
 423     (help-setup-xref (list #'describe-coding-system coding-system)
 424                      (called-interactively-p 'interactive))
 425     (with-output-to-temp-buffer (help-buffer)
 426       (print-coding-system-briefly coding-system 'doc-string)
 427       (let ((type (coding-system-type coding-system))
 428             ;; Fixme: use this
 429             (extra-spec (coding-system-plist coding-system)))
 430         (princ "Type: ")
 431         (princ type)
 432         (cond ((eq type 'undecided)
 433                (princ " (do automatic conversion)"))
 434               ((eq type 'utf-8)
 435                (princ " (UTF-8: Emacs internal multibyte form)"))
 436               ((eq type 'utf-16)
 437                ;; (princ " (UTF-16)")
 438                )
 439               ((eq type 'shift-jis)
 440                (princ " (Shift-JIS, MS-KANJI)"))
 441               ((eq type 'iso-2022)
 442                (princ " (variant of ISO-2022)\n")
 443                (princ "Initial designations:\n")
 444                (print-designation (coding-system-get coding-system
 445                                                      :designation))
 446
 447                (when (coding-system-get coding-system :flags)
 448                  (princ "Other specifications: \n  ")
 449                  (apply #'print-list
 450                         (coding-system-get coding-system :flags))))
 451               ((eq type 'charset)
 452                (princ " (charset)"))
 453               ((eq type 'ccl)
 454                (princ " (do conversion by CCL program)"))
 455               ((eq type 'raw-text)
 456                (princ " (text with random binary characters)"))
 457               ((eq type 'emacs-mule)
 458                (princ " (Emacs 21 internal encoding)"))
 459               ((eq type 'big5))
 460               (t (princ ": invalid coding-system.")))
 461         (princ "\nEOL type: ")
 462         (let ((eol-type (coding-system-eol-type coding-system)))
 463           (cond ((vectorp eol-type)
 464                  (princ "Automatic selection from:\n\t")
 465                  (princ eol-type)
 466                  (princ "\n"))
 467                 ((or (null eol-type) (eq eol-type 0)) (princ "LF\n"))
 468                 ((eq eol-type 1) (princ "CRLF\n"))
 469                 ((eq eol-type 2) (princ "CR\n"))
 470                 (t (princ "invalid\n")))))
 471       (let ((postread (coding-system-get coding-system :post-read-conversion)))
 472         (when postread
 473           (princ "After decoding text normally,")
 474           (princ " perform post-conversion using the function: ")
 475           (princ "\n  ")
 476           (princ postread)
 477           (princ "\n")))
 478       (let ((prewrite (coding-system-get coding-system :pre-write-conversion)))
 479         (when prewrite
 480           (princ "Before encoding text normally,")
 481           (princ " perform pre-conversion using the function: ")
 482           (princ "\n  ")
 483           (princ prewrite)
 484           (princ "\n")))
 485       (with-current-buffer standard-output
 486         (let ((charsets (coding-system-charset-list coding-system)))
 487           (when (and (not (eq (coding-system-base coding-system) 'raw-text))
 488                      charsets)
 489             (cond
 490              ((eq charsets 'iso-2022)
 491               (insert "This coding system can encode all ISO 2022 charsets."))
 492              ((eq charsets 'emacs-mule)
 493               (insert "This coding system can encode all emacs-mule charsets\
 494 ."""))
 495              (t
 496               (insert "This coding system encodes the following charsets:\n ")
 497               (while charsets
 498                 (insert " " (symbol-name (car charsets)))
 499                 (search-backward (symbol-name (car charsets)))
 500                 (help-xref-button 0 'help-character-set (car charsets))
 501                 (goto-char (point-max))
 502                 (setq charsets (cdr charsets)))))))))))
 503
 504 ;;;###autoload
 505 (defun describe-current-coding-system-briefly ()
 506   "Display coding systems currently used in a brief format in echo area.
 507
 508 The format is \"F[..],K[..],T[..],P>[..],P<[..], default F[..],P<[..],P<[..]\",
 509 where mnemonics of the following coding systems come in this order
 510 in place of `..':
 511   `buffer-file-coding-system' (of the current buffer)
 512   eol-type of `buffer-file-coding-system' (of the current buffer)
 513   Value returned by `keyboard-coding-system'
 514   eol-type of `keyboard-coding-system'
 515   Value returned by `terminal-coding-system'.
 516   eol-type of `terminal-coding-system'
 517   `process-coding-system' for read (of the current buffer, if any)
 518   eol-type of `process-coding-system' for read (of the current buffer, if any)
 519   `process-coding-system' for write (of the current buffer, if any)
 520   eol-type of `process-coding-system' for write (of the current buffer, if any)
 521   default `buffer-file-coding-system'
 522   eol-type of default `buffer-file-coding-system'
 523   `default-process-coding-system' for read
 524   eol-type of `default-process-coding-system' for read
 525   `default-process-coding-system' for write
 526   eol-type of `default-process-coding-system'"
 527   (interactive)
 528   (let* ((proc (get-buffer-process (current-buffer)))
 529          (process-coding-systems (if proc (process-coding-system proc))))
 530     (message
 531      "F[%c%s],K[%c%s],T[%c%s],P>[%c%s],P<[%c%s], default F[%c%s],P>[%c%s],P<[%c%s]"
 532      (coding-system-mnemonic buffer-file-coding-system)
 533      (coding-system-eol-type-mnemonic buffer-file-coding-system)
 534      (coding-system-mnemonic (keyboard-coding-system))
 535      (coding-system-eol-type-mnemonic (keyboard-coding-system))
 536      (coding-system-mnemonic (terminal-coding-system))
 537      (coding-system-eol-type-mnemonic (terminal-coding-system))
 538      (coding-system-mnemonic (car process-coding-systems))
 539      (coding-system-eol-type-mnemonic (car process-coding-systems))
 540      (coding-system-mnemonic (cdr process-coding-systems))
 541      (coding-system-eol-type-mnemonic (cdr process-coding-systems))
 542      (coding-system-mnemonic (default-value 'buffer-file-coding-system))
 543      (coding-system-eol-type-mnemonic
 544       (default-value 'buffer-file-coding-system))
 545      (coding-system-mnemonic (car default-process-coding-system))
 546      (coding-system-eol-type-mnemonic (car default-process-coding-system))
 547      (coding-system-mnemonic (cdr default-process-coding-system))
 548      (coding-system-eol-type-mnemonic (cdr default-process-coding-system))
 549      )))
 550
 551 (defun print-coding-system-briefly (coding-system &optional doc-string)
 552   "Print symbol name and mnemonic letter of CODING-SYSTEM with `princ'.
 553 If DOC-STRING is non-nil, print also the docstring of CODING-SYSTEM.
 554 If DOC-STRING is `tightly', don't print an empty line before the
 555 docstring, and print only the first line of the docstring."
 556   (if (not coding-system)
 557       (princ "nil\n")
 558     (princ (format "%c -- %s"
 559                    (coding-system-mnemonic coding-system)
 560                    coding-system))
 561     (let ((aliases (coding-system-aliases coding-system)))
 562       (cond ((eq coding-system (car aliases))
 563              (if (cdr aliases)
 564                  (princ (format " %S" (cons 'alias: (cdr aliases))))))
 565             ((memq coding-system aliases)
 566              (princ (format " (alias of %s)" (car aliases))))
 567             (t
 568              (let ((eol-type (coding-system-eol-type coding-system))
 569                    (base-eol-type (coding-system-eol-type (car aliases))))
 570                (if (and (integerp eol-type)
 571                         (vectorp base-eol-type)
 572                         (not (eq coding-system (aref base-eol-type eol-type))))
 573                    (princ (format " (alias of %s)"
 574                                   (aref base-eol-type eol-type))))))))
 575     (princ "\n")
 576     (or (eq doc-string 'tightly)
 577         (princ "\n"))
 578     (if doc-string
 579         (let ((doc (or (coding-system-doc-string coding-system) "")))
 580           (when (eq doc-string 'tightly)
 581             (if (string-match "\n" doc)
 582                 (setq doc (substring doc 0 (match-beginning 0))))
 583             (setq doc (concat "  " doc)))
 584           (princ (format "%s\n" doc))))))
 585
 586 ;;;###autoload
 587 (defun describe-current-coding-system ()
 588   "Display coding systems currently used, in detail."
 589   (interactive)
 590   (with-output-to-temp-buffer "*Help*"
 591     (let* ((proc (get-buffer-process (current-buffer)))
 592            (process-coding-systems (if proc (process-coding-system proc))))
 593       (princ "Coding system for saving this buffer:\n  ")
 594       (if (local-variable-p 'buffer-file-coding-system)
 595           (print-coding-system-briefly buffer-file-coding-system)
 596         (princ "Not set locally, use the default.\n"))
 597       (princ "Default coding system (for new files):\n  ")
 598       (print-coding-system-briefly (default-value 'buffer-file-coding-system))
 599       (princ "Coding system for keyboard input:\n  ")
 600       (print-coding-system-briefly (keyboard-coding-system))
 601       (princ "Coding system for terminal output:\n  ")
 602       (print-coding-system-briefly (terminal-coding-system))
 603       (when (boundp 'selection-coding-system)
 604           (princ "Coding system for inter-client cut and paste:\n  ")
 605           (print-coding-system-briefly selection-coding-system))
 606       (when (get-buffer-process (current-buffer))
 607         (princ "Coding systems for process I/O:\n")
 608         (princ "  encoding input to the process: ")
 609         (print-coding-system-briefly (cdr process-coding-systems))
 610         (princ "  decoding output from the process: ")
 611         (print-coding-system-briefly (car process-coding-systems)))
 612       (princ "Defaults for subprocess I/O:\n")
 613       (princ "  decoding: ")
 614       (print-coding-system-briefly (car default-process-coding-system))
 615       (princ "  encoding: ")
 616       (print-coding-system-briefly (cdr default-process-coding-system)))
 617
 618     (with-current-buffer standard-output
 619
 620       (princ "
 621 Priority order for recognizing coding systems when reading files:\n")
 622       (let ((i 1))
 623         (dolist (elt (coding-system-priority-list))
 624           (princ (format "  %d. %s " i elt))
 625           (let ((aliases (coding-system-aliases elt)))
 626             (if (eq elt (car aliases))
 627                 (if (cdr aliases)
 628                     (princ (cons 'alias: (cdr aliases))))
 629               (princ (list 'alias 'of (car aliases))))
 630             (terpri)
 631             (setq i (1+ i)))))
 632
 633       (princ "\n  Other coding systems cannot be distinguished automatically
 634   from these, and therefore cannot be recognized automatically
 635   with the present coding system priorities.\n\n")
 636
 637       ;; Fixme: should this be replaced or junked?
 638       (if nil
 639       (let ((categories '(coding-category-iso-7 coding-category-iso-7-else))
 640             coding-system codings)
 641         (while categories
 642           (setq coding-system (symbol-value (car categories)))
 643           (mapc
 644            (lambda (x)
 645              (if (and (not (eq x coding-system))
 646                        (let ((flags (coding-system-get :flags)))
 647                          (not (or (memq 'use-roman flags)
 648                                   (memq 'use-oldjis flags)))))
 649                  (setq codings (cons x codings))))
 650            (get (car categories) 'coding-systems))
 651           (if codings
 652               (let ((max-col (window-width))
 653                     pos)
 654                 (princ (format "\
 655   The following are decoded correctly but recognized as %s:\n   "
 656                                coding-system))
 657                 (while codings
 658                   (setq pos (point))
 659                   (insert (format " %s" (car codings)))
 660                   (when (> (current-column) max-col)
 661                     (goto-char pos)
 662                     (insert "\n   ")
 663                     (goto-char (point-max)))
 664                   (setq codings (cdr codings)))
 665                 (insert "\n\n")))
 666           (setq categories (cdr categories)))))
 667
 668       (princ "Particular coding systems specified for certain file names:\n")
 669       (terpri)
 670       (princ "  OPERATION\tTARGET PATTERN\t\tCODING SYSTEM(s)\n")
 671       (princ "  ---------\t--------------\t\t----------------\n")
 672       (let ((func (lambda (operation alist)
 673                     (princ "  ")
 674                     (princ operation)
 675                     (if (not alist)
 676                         (princ "\tnothing specified\n")
 677                       (while alist
 678                         (indent-to 16)
 679                         (prin1 (car (car alist)))
 680                         (if (>= (current-column) 40)
 681                             (newline))
 682                         (indent-to 40)
 683                         (princ (cdr (car alist)))
 684                         (princ "\n")
 685                         (setq alist (cdr alist)))))))
 686         (funcall func "File I/O" file-coding-system-alist)
 687         (funcall func "Process I/O" process-coding-system-alist)
 688         (funcall func "Network I/O" network-coding-system-alist))
 689       (help-mode))))
 690
 691 (defun print-coding-system (coding-system)
 692   "Print detailed information on CODING-SYSTEM."
 693   (let ((type (coding-system-type coding-system))
 694         (eol-type (coding-system-eol-type coding-system))
 695         (flags (coding-system-get coding-system :flags))
 696         (aliases (coding-system-aliases coding-system)))
 697     (if (not (eq (car aliases) coding-system))
 698         (princ (format "%s (alias of %s)\n" coding-system (car aliases)))
 699       (princ coding-system)
 700       (dolist (alias (cdr aliases))
 701         (princ ",")
 702         (princ alias))
 703       (princ (format ":%s:%c:%d:"
 704                      type
 705                      (coding-system-mnemonic coding-system)
 706                      (if (integerp eol-type) eol-type 3)))
 707       (cond ((eq type 'iso2022)
 708              (let ((idx 0)
 709                    charset)
 710                (while (< idx 4)
 711                  (setq charset (aref flags idx))
 712                  (cond ((null charset)
 713                         (princ -1))
 714                        ((eq charset t)
 715                         (princ -2))
 716                        ((charsetp charset)
 717                         (princ charset))
 718                        ((listp charset)
 719                         (princ "(")
 720                         (princ (car charset))
 721                         (setq charset (cdr charset))
 722                         (while charset
 723                           (princ ",")
 724                           (princ (car charset))
 725                           (setq charset (cdr charset)))
 726                         (princ ")")))
 727                  (princ ",")
 728                  (setq idx (1+ idx)))
 729                (while (< idx 12)
 730                  (princ (if (aref flags idx) 1 0))
 731                  (princ ",")
 732                  (setq idx (1+ idx)))
 733                (princ (if (aref flags idx) 1 0))))
 734             ((eq type 'ccl)
 735              (let (i len)
 736                (if (symbolp (car flags))
 737                    (princ (format " %s" (car flags)))
 738                  (setq i 0 len (length (car flags)))
 739                  (while (< i len)
 740                    (princ (format " %x" (aref (car flags) i)))
 741                    (setq i (1+ i))))
 742                (princ ",")
 743                (if (symbolp (cdr flags))
 744                    (princ (format "%s" (cdr flags)))
 745                  (setq i 0 len (length (cdr flags)))
 746                  (while (< i len)
 747                    (princ (format " %x" (aref (cdr flags) i)))
 748                    (setq i (1+ i))))))
 749             (t (princ 0)))
 750       (princ ":")
 751       (princ (coding-system-doc-string coding-system))
 752       (princ "\n"))))
 753
 754 ;;;###autoload
 755 (defun list-coding-systems (&optional arg)
 756   "Display a list of all coding systems.
 757 This shows the mnemonic letter, name, and description of each coding system.
 758
 759 With prefix ARG, the output format gets more cryptic,
 760 but still contains full information about each coding system."
 761   (interactive "P")
 762   (with-output-to-temp-buffer "*Help*"
 763     (list-coding-systems-1 arg)))
 764
 765 (defun list-coding-systems-1 (arg)
 766   (if (null arg)
 767       (princ "\
 768 ###############################################
 769 # List of coding systems in the following format:
 770 # MNEMONIC-LETTER -- CODING-SYSTEM-NAME
 771 #   DOC-STRING
 772 ")
 773     (princ "\
 774 #########################
 775 ## LIST OF CODING SYSTEMS
 776 ## Each line corresponds to one coding system
 777 ## Format of a line is:
 778 ##   NAME[,ALIAS...]:TYPE:MNEMONIC:EOL:FLAGS:POST-READ-CONVERSION
 779 ##      :PRE-WRITE-CONVERSION:DOC-STRING,
 780 ## where
 781 ##  NAME = coding system name
 782 ##  ALIAS = alias of the coding system
 783 ##  TYPE = nil (no conversion), t (undecided or automatic detection),
 784 ##         0 (EMACS-MULE), 1 (SJIS), 2 (ISO2022), 3 (BIG5), or 4 (CCL)
 785 ##  EOL = 0 (LF), 1 (CRLF), 2 (CR), or 3 (Automatic detection)
 786 ##  FLAGS =
 787 ##    if TYPE = 2 then
 788 ##      comma (`,') separated data of the following:
 789 ##        G0, G1, G2, G3, SHORT-FORM, ASCII-EOL, ASCII-CNTL, SEVEN,
 790 ##        LOCKING-SHIFT, SINGLE-SHIFT, USE-ROMAN, USE-OLDJIS, NO-ISO6429
 791 ##    else if TYPE = 4 then
 792 ##      comma (`,') separated CCL programs for read and write
 793 ##    else
 794 ##      0
 795 ##  POST-READ-CONVERSION, PRE-WRITE-CONVERSION = function name to be called
 796 ##
 797 "))
 798   (dolist (coding-system (sort-coding-systems (coding-system-list 'base-only)))
 799     (if (null arg)
 800         (print-coding-system-briefly coding-system 'tightly)
 801       (print-coding-system coding-system))))
 802
 803 ;; Fixme: delete?
 804 ;;;###autoload
 805 (defun list-coding-categories ()
 806   "Display a list of all coding categories."
 807   (with-output-to-temp-buffer "*Help*"
 808     (princ "\
 809 ############################
 810 ## LIST OF CODING CATEGORIES (ordered by priority)
 811 ## CATEGORY:CODING-SYSTEM
 812 ##
 813 ")
 814     (let ((l coding-category-list))
 815       (while l
 816         (princ (format "%s:%s\n" (car l) (symbol-value (car l))))
 817         (setq l (cdr l))))))
 818 \f
 819 ;;; FONT
 820
 821 (declare-function font-info "font.c" (name &optional frame))
 822
 823 (defun describe-font-internal (font-info &optional ignored)
 824   "Print information about a font in FONT-INFO.
 825 The IGNORED argument is ignored."
 826   (print-list "name (opened by):" (aref font-info 0))
 827   (print-list "       full name:" (aref font-info 1))
 828   (print-list "            size:" (format "%2d" (aref font-info 2)))
 829   (print-list "          height:" (format "%2d" (aref font-info 3)))
 830   (print-list " baseline-offset:" (format "%2d" (aref font-info 4)))
 831   (print-list "relative-compose:" (format "%2d" (aref font-info 5))))
 832
 833 ;;;###autoload
 834 (defun describe-font (fontname)
 835   "Display information about a font whose name is FONTNAME.
 836 The font must be already used by Emacs."
 837   (interactive "sFont name (default current choice for ASCII chars): ")
 838   (or (and window-system (fboundp 'fontset-list))
 839       (error "No fonts being used"))
 840   (let (font-info)
 841     (if (or (not fontname) (= (length fontname) 0))
 842         (setq fontname (face-attribute 'default :font)))
 843     (setq font-info (font-info fontname))
 844     (if (null font-info)
 845         (if (fontp fontname 'font-object)
 846             ;; The font should be surely used.  So, there's some
 847             ;; problem about getting information about it.  It is
 848             ;; better to print the fontname to show which font has
 849             ;; this problem.
 850             (message "No information about \"%s\"" (font-xlfd-name fontname))
 851           (message "No matching font found"))
 852       (with-output-to-temp-buffer "*Help*"
 853         (describe-font-internal font-info)))))
 854
 855 (defun print-fontset-element (val)
 856   ;; VAL has this format:
 857   ;;  ((REQUESTED-FONT-NAME OPENED-FONT-NAME ...) ...)
 858   ;; CHAR RANGE is already inserted.  Get character codes from
 859   ;; the current line.
 860   (beginning-of-line)
 861   (let ((from (following-char))
 862         (to (if (looking-at "[^.]*[.]* ")
 863                 (char-after (match-end 0)))))
 864     (if (re-search-forward "[ \t]*$" nil t)
 865         (delete-region (match-beginning 0) (match-end 0)))
 866
 867     ;; For non-ASCII characters, insert also CODE RANGE.
 868     (if (or (>= from 128) (and to (>= to 128)))
 869         (if to
 870             (insert (format " (#x%02X .. #x%02X)" from to))
 871           (insert (format " (#x%02X)" from))))
 872
 873     ;; Insert a requested font name.
 874     (dolist (elt val)
 875       (if (not elt)
 876           (insert "\n    -- inhibit fallback fonts --")
 877         (let ((requested (car elt)))
 878           (if (stringp requested)
 879               (insert "\n    " requested)
 880             (let (family registry weight slant width adstyle)
 881               (if (and (fboundp 'fontp) (fontp requested))
 882                   (setq family (font-get requested :family)
 883                         registry (font-get requested :registry)
 884                         weight (font-get requested :weight)
 885                         slant (font-get requested :slant)
 886                         width (font-get requested :width)
 887                         adstyle (font-get requested :adstyle))
 888                 (setq family (aref requested 0)
 889                       registry (aref requested 5)
 890                       weight (aref requested 1)
 891                       slant (aref requested 2)
 892                       width (aref requested 3)
 893                       adstyle (aref requested 4)))
 894               (if (not family)
 895                   (setq family "*-*")
 896                 (if (symbolp family)
 897                     (setq family (symbol-name family)))
 898                 (or (string-match "-" family)
 899                     (setq family (concat "*-" family))))
 900               (if (not registry)
 901                   (setq registry "*-*")
 902                 (if (symbolp registry)
 903                     (setq registry (symbol-name registry)))
 904                 (or (string-match "-" registry)
 905                     (= (aref registry (1- (length registry))) ?*)
 906                     (setq registry (concat registry "*"))))
 907               (insert (format"\n    -%s-%s-%s-%s-%s-*-*-*-*-*-*-%s"
 908                              family (or weight "*") (or slant "*") (or width "*")
 909                              (or adstyle "*") registry)))))
 910
 911         ;; Insert opened font names (if any).
 912         (if (and (boundp 'print-opened) (symbol-value 'print-opened))
 913             (dolist (opened (cdr elt))
 914               (insert "\n\t[" opened "]")))))))
 915
 916 (declare-function query-fontset "fontset.c" (pattern &optional regexpp))
 917 (declare-function fontset-info "fontset.c" (fontset &optional frame))
 918
 919 (defun print-fontset (fontset &optional print-opened)
 920   "Print information about FONTSET.
 921 FONTSET nil means the fontset of the selected frame, t means the
 922 default fontset.
 923 If optional arg PRINT-OPENED is non-nil, also print names of all opened
 924 fonts for FONTSET.  This function actually inserts the information in
 925 the current buffer."
 926   (if (eq fontset t)
 927       (setq fontset (query-fontset "fontset-default"))
 928     (if (eq fontset nil)
 929         (setq fontset (face-attribute 'default :fontset))))
 930   (beginning-of-line)
 931   (narrow-to-region (point) (point))
 932   (insert "Fontset: " fontset "\n")
 933   (insert (propertize "CHAR RANGE" 'face 'underline)
 934            " (" (propertize "CODE RANGE" 'face 'underline) ")\n")
 935   (insert "    " (propertize "FONT NAME" 'face 'underline)
 936           " (" (propertize "REQUESTED" 'face 'underline)
 937           " and [" (propertize "OPENED" 'face 'underline) "])")
 938   (let* ((info (fontset-info fontset))
 939          (default-info (char-table-extra-slot info 0))
 940          start1 end1 start2 end2)
 941     (describe-vector info 'print-fontset-element)
 942     (when (char-table-range info nil)
 943       ;; The default of FONTSET is described.
 944       (setq start1 (re-search-backward "^default"))
 945       (delete-region (point) (line-end-position))
 946       (insert "\n  ---<fallback to the default of the specified fontset>---")
 947       (put-text-property (line-beginning-position) (point) 'face 'highlight)
 948       (goto-char (point-max))
 949       (setq end1 (setq start2 (point))))
 950     (when default-info
 951       (insert "\n  ---<fallback to the default fontset>---")
 952       (put-text-property (line-beginning-position) (point) 'face 'highlight)
 953       (describe-vector default-info 'print-fontset-element)
 954       (when (char-table-range default-info nil)
 955         ;; The default of the default fontset is described.
 956         (setq end2 (re-search-backward "^default"))
 957         (delete-region (point) (line-end-position))
 958         (insert "\n  ---<fallback to the default of the default fontset>---")
 959         (put-text-property (line-beginning-position) (point) 'face 'highlight)))
 960       (if (and start1 end2)
 961           ;; Reorder the printed information to match with the font
 962           ;; searching strategy; i.e. FONTSET, the default fontset,
 963           ;; default of FONTSET, default of the default fontset.
 964           (transpose-regions start1 end1 start2 end2))
 965       (goto-char (point-max)))
 966   (widen))
 967
 968 (defvar fontset-alias-alist)
 969 (declare-function fontset-list "fontset.c" ())
 970
 971 ;;;###autoload
 972 (defun describe-fontset (fontset)
 973   "Display information about FONTSET.
 974 This shows which font is used for which character(s)."
 975   (interactive
 976    (if (not (and window-system (fboundp 'fontset-list)))
 977        (error "No fontsets being used")
 978      (let ((fontset-list (nconc
 979                           (fontset-list)
 980                           (mapcar 'cdr fontset-alias-alist)))
 981            (completion-ignore-case t))
 982        (list (completing-read
 983               "Fontset (default used by the current frame): "
 984               fontset-list nil t)))))
 985   (if (= (length fontset) 0)
 986       (setq fontset (face-attribute 'default :fontset))
 987     (setq fontset (query-fontset fontset)))
 988   (help-setup-xref (list #'describe-fontset fontset)
 989                    (called-interactively-p 'interactive))
 990   (with-output-to-temp-buffer (help-buffer)
 991     (with-current-buffer standard-output
 992       (print-fontset fontset t))))
 993
 994 (declare-function fontset-plain-name "fontset" (fontset))
 995
 996 ;;;###autoload
 997 (defun list-fontsets (arg)
 998   "Display a list of all fontsets.
 999 This shows the name, size, and style of each fontset.
1000 With prefix arg, also list the fonts contained in each fontset;
1001 see the function `describe-fontset' for the format of the list."
1002   (interactive "P")
1003   (if (not (and window-system (fboundp 'fontset-list)))
1004       (error "No fontsets being used")
1005     (help-setup-xref (list #'list-fontsets arg)
1006                      (called-interactively-p 'interactive))
1007     (with-output-to-temp-buffer (help-buffer)
1008       (with-current-buffer standard-output
1009         ;; This code is duplicated near the end of mule-diag.
1010         (let ((fontsets
1011                (sort (fontset-list)
1012                      (lambda (x y)
1013                        (string< (fontset-plain-name x)
1014                                 (fontset-plain-name y))))))
1015           (while fontsets
1016             (if arg
1017                 (print-fontset (car fontsets) nil)
1018               (insert "Fontset: " (car fontsets) "\n"))
1019             (setq fontsets (cdr fontsets))))))))
1020 \f
1021 ;;;###autoload
1022 (defun list-input-methods ()
1023   "Display information about all input methods."
1024   (interactive)
1025   (help-setup-xref '(list-input-methods)
1026                    (called-interactively-p 'interactive))
1027   (with-output-to-temp-buffer (help-buffer)
1028     (list-input-methods-1)
1029     (with-current-buffer standard-output
1030       (save-excursion
1031         (goto-char (point-min))
1032         (while (re-search-forward
1033                 "^  \\([^ ]+\\) (`.*' in mode line)$" nil t)
1034           (help-xref-button 1 'help-input-method (match-string 1)))))))
1035
1036 (defun list-input-methods-1 ()
1037   (if (not input-method-alist)
1038       (princ "
1039 No input method is available, perhaps because you have not
1040 installed LEIM (Libraries of Emacs Input Methods).")
1041     (princ "LANGUAGE\n  NAME (`TITLE' in mode line)\n")
1042     (princ "    SHORT-DESCRIPTION\n------------------------------\n")
1043     (setq input-method-alist
1044           (sort input-method-alist
1045                 (lambda (x y) (string< (nth 1 x) (nth 1 y)))))
1046
1047     (let (language)
1048       (dolist (elt input-method-alist)
1049         (when (not (equal language (nth 1 elt)))
1050           (setq language (nth 1 elt))
1051           (princ language)
1052           (terpri))
1053         (princ (format "  %s (`%s' in mode line)\n    %s\n"
1054                        (car elt)
1055                        (let ((title (nth 3 elt)))
1056                          (if (and (consp title) (stringp (car title)))
1057                              (car title)
1058                            title))
1059                        ;; If the doc is multi-line, indent all
1060                        ;; non-blank lines. (Bug#8066)
1061                        (replace-regexp-in-string "\n\\(.\\)" "\n    \\1"
1062                                                  (or (nth 4 elt) ""))))))))
1063 \f
1064 ;;; DIAGNOSIS
1065
1066 ;; Insert a header of a section with SECTION-NUMBER and TITLE.
1067 (defun insert-section (section-number title)
1068   (insert "########################################\n"
1069           "# Section " (format "%d" section-number) ".  " title "\n"
1070           "########################################\n\n"))
1071
1072 ;;;###autoload
1073 (defun mule-diag ()
1074   "Display diagnosis of the multilingual environment (Mule).
1075
1076 This shows various information related to the current multilingual
1077 environment, including lists of input methods, coding systems,
1078 character sets, and fontsets (if Emacs is running under a window
1079 system which uses fontsets)."
1080   (interactive)
1081   (with-output-to-temp-buffer "*Mule-Diagnosis*"
1082     (with-current-buffer standard-output
1083       (insert "###############################################\n"
1084               "### Current Status of Multilingual Features ###\n"
1085               "###############################################\n\n"
1086               "CONTENTS: Section 1.  General Information\n"
1087               "          Section 2.  Display\n"
1088               "          Section 3.  Input methods\n"
1089               "          Section 4.  Coding systems\n"
1090               "          Section 5.  Character sets\n")
1091       (if (and window-system (fboundp 'fontset-list))
1092           (insert "          Section 6.  Fontsets\n"))
1093       (insert "\n")
1094
1095       (insert-section 1 "General Information")
1096       (insert "Version of this emacs:\n  " (emacs-version) "\n\n")
1097       (insert "Configuration options:\n  " system-configuration-options "\n\n")
1098       (insert "Multibyte characters awareness:\n"
1099               (format "  default: %S\n" (default-value
1100                                           'enable-multibyte-characters))
1101               (format "  current-buffer: %S\n\n" enable-multibyte-characters))
1102       (insert "Current language environment: " current-language-environment
1103               "\n\n")
1104
1105       (insert-section 2 "Display")
1106       (if window-system
1107           (insert (format "Window-system: %s" window-system))
1108         (insert "Terminal: " (getenv "TERM")))
1109       (insert "\n\n")
1110
1111       (if window-system
1112           (let ((font (cdr (assq 'font (frame-parameters)))))
1113             (insert "The font and fontset of the selected frame are:\n"
1114                     "     font: " font "\n"
1115                     "  fontset: " (face-attribute 'default :fontset) "\n"))
1116         (insert "Coding system of the terminal: "
1117                 (symbol-name (terminal-coding-system))))
1118       (insert "\n\n")
1119
1120       (insert-section 3 "Input methods")
1121       (list-input-methods-1)
1122       (insert "\n")
1123       (if default-input-method
1124           (insert (format "Default input method: %s\n" default-input-method))
1125         (insert "No default input method is specified\n"))
1126
1127       (insert-section 4 "Coding systems")
1128       (list-coding-systems-1 t)
1129       (insert "\n")
1130
1131       (insert-section 5 "Character sets")
1132       (list-character-sets-2)
1133       (insert "\n")
1134
1135       (when (and window-system (fboundp 'fontset-list))
1136         ;; This code duplicates most of list-fontsets.
1137         (insert-section 6 "Fontsets")
1138         (insert "Fontset-Name\t\t\t\t\t\t  WDxHT Style\n")
1139         (insert "------------\t\t\t\t\t\t  ----- -----\n")
1140         (dolist (fontset (fontset-list))
1141           (print-fontset fontset t)
1142           (insert "\n")))
1143       (help-print-return-message))))
1144
1145 ;;;###autoload
1146 (defun font-show-log (&optional limit)
1147   "Show log of font listing and opening.
1148 Prefix arg LIMIT says how many fonts to show for each listing.
1149 The default is 20.  If LIMIT is negative, do not limit the listing."
1150   (interactive "P")
1151   (setq limit (if limit (prefix-numeric-value limit) 20))
1152   (if (eq font-log t)
1153       (message "Font logging is currently suppressed")
1154     (with-output-to-temp-buffer "*Help*"
1155       (set-buffer standard-output)
1156       (dolist (elt (reverse font-log))
1157         (insert (format "%s: %s\n" (car elt) (cadr elt)))
1158         (setq elt (nth 2 elt))
1159         (if (or (vectorp elt) (listp elt))
1160             (let ((i 0))
1161               (catch 'tag
1162                 (mapc #'(lambda (x)
1163                           (setq i (1+ i))
1164                           (when (= i limit)
1165                             (insert "  ...\n")
1166                             (throw 'tag nil))
1167                           (insert (format "  %s\n" x)))
1168                       elt)))
1169           (insert (format "  %s\n" elt)))))))
1170
1171
1172 (provide 'mule-diag)
1173
1174 ;;; mule-diag.el ends here