lisp/ielm.el

   1 ;;; -*- lexical-binding: t -*-
   2 ;;; ielm.el --- interaction mode for Emacs Lisp
   3
   4 ;; Copyright (C) 1994, 2001-2014 Free Software Foundation, Inc.
   5
   6 ;; Author: David Smith <maa036@lancaster.ac.uk>
   7 ;; Maintainer: FSF
   8 ;; Created: 25 Feb 1994
   9 ;; Keywords: lisp
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; Provides a nice interface to evaluating Emacs Lisp expressions.
  29 ;; Input is handled by the comint package, and output is passed
  30 ;; through the pretty-printer.
  31
  32 ;; To start: M-x ielm.  Type C-h m in the *ielm* buffer for more info.
  33
  34 ;;; Code:
  35
  36 (require 'comint)
  37 (require 'pp)
  38
  39 ;;; User variables
  40
  41 (defgroup ielm nil
  42   "Interaction mode for Emacs Lisp."
  43   :group 'lisp)
  44
  45
  46 (defcustom ielm-noisy t
  47   "If non-nil, IELM will beep on error."
  48   :type 'boolean
  49   :group 'ielm)
  50
  51 (defcustom ielm-prompt-read-only t
  52   "If non-nil, the IELM prompt is read only.
  53 The read only region includes the newline before the prompt.
  54 Setting this variable does not affect existing IELM runs.
  55 This works by setting the buffer-local value of `comint-prompt-read-only'.
  56 Setting that value directly affects new prompts in the current buffer.
  57
  58 If this option is enabled, then the safe way to temporarily
  59 override the read-only-ness of IELM prompts is to call
  60 `comint-kill-whole-line' or `comint-kill-region' with no
  61 narrowing in effect.  This way you will be certain that none of
  62 the remaining prompts will be accidentally messed up.  You may
  63 wish to put something like the following in your init file:
  64
  65 \(add-hook 'ielm-mode-hook
  66           (lambda ()
  67              (define-key ielm-map \"\\C-w\" 'comint-kill-region)
  68              (define-key ielm-map [C-S-backspace]
  69                'comint-kill-whole-line)))
  70
  71 If you set `comint-prompt-read-only' to t, you might wish to use
  72 `comint-mode-hook' and `comint-mode-map' instead of
  73 `ielm-mode-hook' and `ielm-map'.  That will affect all comint
  74 buffers, including IELM buffers.  If you sometimes use IELM on
  75 text-only terminals or with `emacs -nw', you might wish to use
  76 another binding for `comint-kill-whole-line'."
  77   :type 'boolean
  78   :group 'ielm
  79   :version "22.1")
  80
  81 (defcustom ielm-prompt "ELISP> "
  82   "Prompt used in IELM.
  83 Setting this variable does not affect existing IELM runs.
  84
  85 Interrupting the IELM process with \\<ielm-map>\\[comint-interrupt-subjob],
  86 and then restarting it using \\[ielm], makes the then current
  87 default value affect _new_ prompts.  Unless the new prompt
  88 differs only in text properties from the old one, IELM will no
  89 longer recognize the old prompts.  However, executing \\[ielm]
  90 does not update the prompt of an *ielm* buffer with a running process.
  91 For IELM buffers that are not called `*ielm*', you can execute
  92 \\[inferior-emacs-lisp-mode] in that IELM buffer to update the value,
  93 for new prompts.  This works even if the buffer has a running process."
  94   :type 'string
  95   :group 'ielm)
  96
  97 (defvar ielm-prompt-internal "ELISP> "
  98   "Stored value of `ielm-prompt' in the current IELM buffer.
  99 This is an internal variable used by IELM.  Its purpose is to
 100 prevent a running IELM process from being messed up when the user
 101 customizes `ielm-prompt'.")
 102
 103 (defcustom ielm-dynamic-return t
 104   "Controls whether \\<ielm-map>\\[ielm-return] has intelligent behavior in IELM.
 105 If non-nil, \\[ielm-return] evaluates input for complete sexps, or inserts a newline
 106 and indents for incomplete sexps.  If nil, always inserts newlines."
 107   :type 'boolean
 108   :group 'ielm)
 109
 110 (defcustom ielm-dynamic-multiline-inputs t
 111   "Force multiline inputs to start from column zero?
 112 If non-nil, after entering the first line of an incomplete sexp, a newline
 113 will be inserted after the prompt, moving the input to the next line.
 114 This gives more frame width for large indented sexps, and allows functions
 115 such as `edebug-defun' to work with such inputs."
 116   :type 'boolean
 117   :group 'ielm)
 118
 119 (defcustom ielm-mode-hook nil
 120   "Hooks to be run when IELM (`inferior-emacs-lisp-mode') is started."
 121   :options '(turn-on-eldoc-mode)
 122   :type 'hook
 123   :group 'ielm)
 124 (defvaralias 'inferior-emacs-lisp-mode-hook 'ielm-mode-hook)
 125
 126 (defvar * nil
 127   "Most recent value evaluated in IELM.")
 128
 129 (defvar ** nil
 130   "Second-most-recent value evaluated in IELM.")
 131
 132 (defvar *** nil
 133   "Third-most-recent value evaluated in IELM.")
 134
 135 (defvar ielm-match-data nil
 136   "Match data saved at the end of last command.")
 137
 138 (defvar *1 nil
 139   "During IELM evaluation, most recent value evaluated in IELM.
 140 Normally identical to `*'.  However, if the working buffer is an IELM
 141 buffer, distinct from the process buffer, then `*' gives the value in
 142 the working buffer, `*1' the value in the process buffer.
 143 The intended value is only accessible during IELM evaluation.")
 144
 145 (defvar *2 nil
 146   "During IELM evaluation, second-most-recent value evaluated in IELM.
 147 Normally identical to `**'.  However, if the working buffer is an IELM
 148 buffer, distinct from the process buffer, then `**' gives the value in
 149 the working buffer, `*2' the value in the process buffer.
 150 The intended value is only accessible during IELM evaluation.")
 151
 152 (defvar *3 nil
 153   "During IELM evaluation, third-most-recent value evaluated in IELM.
 154 Normally identical to `***'.  However, if the working buffer is an IELM
 155 buffer, distinct from the process buffer, then `***' gives the value in
 156 the working buffer, `*3' the value in the process buffer.
 157 The intended value is only accessible during IELM evaluation.")
 158
 159 ;;; System variables
 160
 161 (defvar ielm-working-buffer nil
 162   "Buffer in which IELM sexps will be evaluated.
 163 This variable is buffer-local.")
 164
 165 (defvar ielm-header
 166   "*** Welcome to IELM ***  Type (describe-mode) for help.\n"
 167   "Message to display when IELM is started.")
 168
 169 (defvar ielm-map
 170   (let ((map (make-sparse-keymap)))
 171     (define-key map "\t" 'completion-at-point)
 172     (define-key map "\C-m" 'ielm-return)
 173     (define-key map "\e\C-m" 'ielm-return-for-effect)
 174     (define-key map "\C-j" 'ielm-send-input)
 175     (define-key map "\e\C-x" 'eval-defun)         ; for consistency with
 176     (define-key map "\e\t" 'completion-at-point)  ; lisp-interaction-mode
 177     ;; These bindings are from `lisp-mode-shared-map' -- can you inherit
 178     ;; from more than one keymap??
 179     (define-key map "\e\C-q" 'indent-sexp)
 180     (define-key map "\177" 'backward-delete-char-untabify)
 181     ;; Some convenience bindings for setting the working buffer
 182     (define-key map "\C-c\C-b" 'ielm-change-working-buffer)
 183     (define-key map "\C-c\C-f" 'ielm-display-working-buffer)
 184     (define-key map "\C-c\C-v" 'ielm-print-working-buffer)
 185     map)
 186   "Keymap for IELM mode.")
 187 (defvaralias 'inferior-emacs-lisp-mode-map 'ielm-map)
 188
 189 (easy-menu-define ielm-menu ielm-map
 190   "IELM mode menu."
 191   '("IELM"
 192     ["Change Working Buffer" ielm-change-working-buffer t]
 193     ["Display Working Buffer" ielm-display-working-buffer t]
 194     ["Print Working Buffer" ielm-print-working-buffer t]))
 195
 196 (defvar ielm-font-lock-keywords
 197   '(("\\(^\\*\\*\\*[^*]+\\*\\*\\*\\)\\(.*$\\)"
 198      (1 font-lock-comment-face)
 199      (2 font-lock-constant-face)))
 200   "Additional expressions to highlight in IELM buffers.")
 201
 202 ;;; Completion stuff
 203
 204 (defun ielm-tab nil
 205   "Possibly indent the current line as Lisp code."
 206   (interactive)
 207   (when (or (eq (preceding-char) ?\n)
 208             (eq (char-syntax (preceding-char)) ?\s))
 209     (ielm-indent-line)
 210     t))
 211
 212 (defun ielm-complete-symbol nil
 213   "Complete the Lisp symbol before point."
 214   ;; A wrapper for completion-at-point that returns non-nil if
 215   ;; completion has occurred
 216   (let* ((btick (buffer-modified-tick))
 217          (cbuffer (get-buffer "*Completions*"))
 218          (ctick (and cbuffer (buffer-modified-tick cbuffer)))
 219          (completion-at-point-functions '(lisp-completion-at-point)))
 220     (completion-at-point)
 221      ;; completion has occurred if:
 222     (or
 223      ;; the buffer has been modified
 224      (not (= btick (buffer-modified-tick)))
 225      ;; a completions buffer has been modified or created
 226      (if cbuffer
 227          (not (= ctick (buffer-modified-tick cbuffer)))
 228        (get-buffer "*Completions*")))))
 229
 230 (defun ielm-complete-filename nil
 231   "Dynamically complete filename before point, if in a string."
 232   (when (nth 3 (parse-partial-sexp comint-last-input-start (point)))
 233     (comint-dynamic-complete-filename)))
 234
 235 (defun ielm-indent-line nil
 236   "Indent the current line as Lisp code if it is not a prompt line."
 237   (when (save-excursion (comint-bol) (bolp))
 238     (lisp-indent-line)))
 239
 240 ;;; Working buffer manipulation
 241
 242 (defun ielm-print-working-buffer nil
 243   "Print the current IELM working buffer's name in the echo area."
 244   (interactive)
 245   (message "The current working buffer is: %s" (buffer-name ielm-working-buffer)))
 246
 247 (defun ielm-display-working-buffer nil
 248   "Display the current IELM working buffer.
 249 Don't forget that selecting that buffer will change its value of `point'
 250 to its value of `window-point'!"
 251   (interactive)
 252   (display-buffer ielm-working-buffer)
 253   (ielm-print-working-buffer))
 254
 255 (defun ielm-change-working-buffer (buf)
 256   "Change the current IELM working buffer to BUF.
 257 This is the buffer in which all sexps entered at the IELM prompt are
 258 evaluated.  You can achieve the same effect with a call to
 259 `set-buffer' at the IELM prompt."
 260   (interactive "bSet working buffer to: ")
 261   (let ((buffer (get-buffer buf)))
 262     (if (and buffer (buffer-live-p buffer))
 263         (setq ielm-working-buffer buffer)
 264       (error "No such buffer: %S" buf)))
 265   (ielm-print-working-buffer))
 266
 267 ;;; Other bindings
 268
 269 (defun ielm-return (&optional for-effect)
 270   "Newline and indent, or evaluate the sexp before the prompt.
 271 Complete sexps are evaluated; for incomplete sexps inserts a newline
 272 and indents.  If however `ielm-dynamic-return' is nil, this always
 273 simply inserts a newline."
 274   (interactive)
 275   (if ielm-dynamic-return
 276       (let ((state
 277              (save-excursion
 278                (end-of-line)
 279                (parse-partial-sexp (ielm-pm)
 280                                    (point)))))
 281         (if (and (< (car state) 1) (not (nth 3 state)))
 282             (ielm-send-input for-effect)
 283           (when (and ielm-dynamic-multiline-inputs
 284                      (save-excursion
 285                        (beginning-of-line)
 286                        (looking-at-p comint-prompt-regexp)))
 287             (save-excursion
 288               (goto-char (ielm-pm))
 289               (newline 1)))
 290           (newline-and-indent)))
 291     (newline)))
 292
 293 (defun ielm-return-for-effect ()
 294   "Like `ielm-return', but do not print the result."
 295   (interactive)
 296   (ielm-return t))
 297
 298 (defvar ielm-input)
 299
 300 (defun ielm-input-sender (_proc input)
 301   ;; Just sets the variable ielm-input, which is in the scope of
 302   ;; `ielm-send-input's call.
 303   (setq ielm-input input))
 304
 305 (defun ielm-send-input (&optional for-effect)
 306   "Evaluate the Emacs Lisp expression after the prompt."
 307   (interactive)
 308   (let (ielm-input)                     ; set by ielm-input-sender
 309     (comint-send-input)                 ; update history, markers etc.
 310     (ielm-eval-input ielm-input for-effect)))
 311
 312 ;;; Utility functions
 313
 314 (defun ielm-is-whitespace-or-comment (string)
 315   "Return non-nil if STRING is all whitespace or a comment."
 316   (or (string= string "")
 317       (string-match-p "\\`[ \t\n]*\\(?:;.*\\)*\\'" string)))
 318
 319 ;;; Evaluation
 320
 321 (defun ielm-standard-output-impl (process)
 322   "Return a function to use for `standard-output' while in ielm eval.
 323 The returned function takes one character as input.  Passing nil
 324 to this function instead of a character flushes the output
 325 buffer.  Passing t appends a terminating newline if the buffer is
 326 nonempty, then flushes the buffer."
 327   ;; Use an intermediate output buffer because doing redisplay for
 328   ;; each character we output is too expensive.  Set up a flush timer
 329   ;; so that users don't have to wait for whole lines to appear before
 330   ;; seeing output.
 331   (let* ((output-buffer nil)
 332          (flush-timer nil)
 333          (flush-buffer
 334           (lambda ()
 335             (comint-output-filter
 336              process
 337              (apply #'string (nreverse output-buffer)))
 338             (redisplay)
 339             (setf output-buffer nil)
 340             (when flush-timer
 341               (cancel-timer flush-timer)
 342               (setf flush-timer nil)))))
 343     (lambda (char)
 344       (let (flush-now)
 345         (cond ((and (eq char t) output-buffer)
 346                (push ?\n output-buffer)
 347                (setf flush-now t))
 348               ((characterp char)
 349                (push char output-buffer)))
 350         (if flush-now
 351             (funcall flush-buffer)
 352           (unless flush-timer
 353             (setf flush-timer (run-with-timer 0.1 nil flush-buffer))))))))
 354
 355 (defun ielm-eval-input (input-string &optional for-effect)
 356   "Evaluate the Lisp expression INPUT-STRING, and pretty-print the result."
 357   ;; This is the function that actually `sends' the input to the
 358   ;; `inferior Lisp process'. All comint-send-input does is works out
 359   ;; what that input is.  What this function does is evaluates that
 360   ;; input and produces `output' which gets inserted into the buffer,
 361   ;; along with a new prompt.  A better way of doing this might have
 362   ;; been to actually send the output to the `cat' process, and write
 363   ;; this as in output filter that converted sexps in the output
 364   ;; stream to their evaluated value.  But that would have involved
 365   ;; more process coordination than I was happy to deal with.
 366   (let ((string input-string)        ; input expression, as a string
 367         form                         ; form to evaluate
 368         pos                          ; End posn of parse in string
 369         result                       ; Result, or error message
 370         error-type                   ; string, nil if no error
 371         (output "")                  ; result to display
 372         (wbuf ielm-working-buffer)   ; current buffer after evaluation
 373         (pmark (ielm-pm)))
 374     (unless (ielm-is-whitespace-or-comment string)
 375       (condition-case err
 376           (let ((rout (read-from-string string)))
 377             (setq form (car rout)
 378                   pos (cdr rout)))
 379         (error (setq result (error-message-string err))
 380                (setq error-type "Read error")))
 381       (unless error-type
 382         ;; Make sure working buffer has not been killed
 383         (if (not (buffer-name ielm-working-buffer))
 384             (setq result "Working buffer has been killed"
 385                   error-type "IELM Error"
 386                   wbuf (current-buffer))
 387           (if (ielm-is-whitespace-or-comment (substring string pos))
 388               ;; To correctly handle the ielm-local variables *,
 389               ;; ** and ***, we need a temporary buffer to be
 390               ;; current at entry to the inner of the next two let
 391               ;; forms.  We need another temporary buffer to exit
 392               ;; that same let.  To avoid problems, neither of
 393               ;; these buffers should be alive during the
 394               ;; evaluation of form.
 395               (let* ((*1 *)
 396                      (*2 **)
 397                      (*3 ***)
 398                      (active-process (ielm-process))
 399                      (old-standard-output standard-output)
 400                      new-standard-output
 401                      ielm-temp-buffer)
 402                 (set-match-data ielm-match-data)
 403                 (save-excursion
 404                   (with-temp-buffer
 405                     (condition-case err
 406                         (unwind-protect
 407                             ;; The next let form creates default
 408                             ;; bindings for *, ** and ***.  But
 409                             ;; these default bindings are
 410                             ;; identical to the ielm-local
 411                             ;; bindings.  Hence, during the
 412                             ;; evaluation of form, the
 413                             ;; ielm-local values are going to be
 414                             ;; used in all buffers except for
 415                             ;; other ielm buffers, which override
 416                             ;; them.  Normally, the variables *1,
 417                             ;; *2 and *3 also have default
 418                             ;; bindings, which are not overridden.
 419                             (let ((* *1)
 420                                   (** *2)
 421                                   (*** *3))
 422                               (when (eq standard-output t)
 423                                 (setf new-standard-output
 424                                       (ielm-standard-output-impl
 425                                        active-process))
 426                                 (setf standard-output new-standard-output))
 427                               (kill-buffer (current-buffer))
 428                               (set-buffer wbuf)
 429                               (setq result
 430                                     (eval form lexical-binding))
 431                               (setq wbuf (current-buffer))
 432                               (setq
 433                                ielm-temp-buffer
 434                                (generate-new-buffer " *ielm-temp*"))
 435                               (set-buffer ielm-temp-buffer))
 436                           (when ielm-temp-buffer
 437                             (kill-buffer ielm-temp-buffer))
 438                           (when (eq new-standard-output standard-output)
 439                             (ignore-errors
 440                               (funcall standard-output t))
 441                             (setf standard-output old-standard-output)))
 442                       (error (setq result (error-message-string err))
 443                              (setq error-type "Eval error"))
 444                       (quit (setq result "Quit during evaluation")
 445                             (setq error-type "Eval error")))))
 446                 (setq ielm-match-data (match-data)))
 447             (setq error-type "IELM error")
 448             (setq result "More than one sexp in input"))))
 449
 450       ;; If the eval changed the current buffer, mention it here
 451       (unless (eq wbuf ielm-working-buffer)
 452         (message "current buffer is now: %s" wbuf)
 453         (setq ielm-working-buffer wbuf))
 454
 455       (goto-char pmark)
 456       (unless error-type
 457         (condition-case nil
 458             ;; Self-referential objects cause loops in the printer, so
 459             ;; trap quits here. May as well do errors, too
 460             (unless for-effect
 461               (setq output (concat output (pp-to-string result)
 462                                    (let ((str (eval-expression-print-format result)))
 463                                      (if str (propertize str 'font-lock-face 'shadow))))))
 464           (error (setq error-type "IELM Error")
 465                  (setq result "Error during pretty-printing (bug in pp)"))
 466           (quit  (setq error-type "IELM Error")
 467                  (setq result "Quit during pretty-printing"))))
 468       (if error-type
 469           (progn
 470             (when ielm-noisy (ding))
 471             (setq output (concat output "*** " error-type " ***  "))
 472             (setq output (concat output result)))
 473         ;; There was no error, so shift the *** values
 474         (setq *** **)
 475         (setq ** *)
 476         (setq * result))
 477       (when (or (not for-effect) (not (equal output "")))
 478         (setq output (concat output "\n"))))
 479     (setq output (concat output ielm-prompt-internal))
 480     (comint-output-filter (ielm-process) output)))
 481
 482 ;;; Process and marker utilities
 483
 484 (defun ielm-process nil
 485   ;; Return the current buffer's process.
 486   (get-buffer-process (current-buffer)))
 487
 488 (defun ielm-pm nil
 489   ;; Return the process mark of the current buffer.
 490   (process-mark (get-buffer-process (current-buffer))))
 491
 492 (defun ielm-set-pm (pos)
 493   ;; Set the process mark in the current buffer to POS.
 494   (set-marker (process-mark (get-buffer-process (current-buffer))) pos))
 495
 496 ;;; Major mode
 497
 498 (define-derived-mode inferior-emacs-lisp-mode comint-mode "IELM"
 499   "Major mode for interactively evaluating Emacs Lisp expressions.
 500 Uses the interface provided by `comint-mode' (which see).
 501
 502 * \\<ielm-map>\\[ielm-send-input] evaluates the sexp following the prompt.  There must be at most
 503   one top level sexp per prompt.
 504
 505 * \\[ielm-return] inserts a newline and indents, or evaluates a
 506   complete expression (but see variable `ielm-dynamic-return').
 507   Inputs longer than one line are moved to the line following the
 508   prompt (but see variable `ielm-dynamic-multiline-inputs').
 509
 510 * \\[ielm-return-for-effect] works like `ielm-return', except
 511   that it doesn't print the result of evaluating the input.  This
 512   functionality is useful when forms would generate voluminous
 513   output.
 514
 515 * \\[completion-at-point] completes Lisp symbols (or filenames, within strings),
 516   or indents the line if there is nothing to complete.
 517
 518 The current working buffer may be changed (with a call to `set-buffer',
 519 or with \\[ielm-change-working-buffer]), and its value is preserved between successive
 520 evaluations.  In this way, expressions may be evaluated in a different
 521 buffer than the *ielm* buffer.  By default, its name is shown on the
 522 mode line; you can always display it with \\[ielm-print-working-buffer], or the buffer itself
 523 with \\[ielm-display-working-buffer].
 524
 525 During evaluations, the values of the variables `*', `**', and `***'
 526 are the results of the previous, second previous and third previous
 527 evaluations respectively.  If the working buffer is another IELM
 528 buffer, then the values in the working buffer are used.  The variables
 529 `*1', `*2' and `*3', yield the process buffer values.
 530
 531 If, at the start of evaluation, `standard-output' is `t' (the
 532 default), `standard-output' is set to a special function that
 533 causes output to be directed to the ielm buffer.
 534 `standard-output' is restored after evaluation unless explicitly
 535 set to a different value during evaluation.  You can use (princ
 536 VALUE) or (pp VALUE) to write to the ielm buffer.
 537
 538 Expressions evaluated by IELM are not subject to `debug-on-quit' or
 539 `debug-on-error'.
 540
 541 The behavior of IELM may be customized with the following variables:
 542 * To stop beeping on error, set `ielm-noisy' to nil.
 543 * If you don't like the prompt, you can change it by setting `ielm-prompt'.
 544 * If you do not like that the prompt is (by default) read-only, set
 545   `ielm-prompt-read-only' to nil.
 546 * Set `ielm-dynamic-return' to nil for bindings like `lisp-interaction-mode'.
 547 * Entry to this mode runs `comint-mode-hook' and `ielm-mode-hook'
 548  (in that order).
 549
 550 Customized bindings may be defined in `ielm-map', which currently contains:
 551 \\{ielm-map}"
 552   :syntax-table emacs-lisp-mode-syntax-table
 553
 554   (setq comint-prompt-regexp (concat "^" (regexp-quote ielm-prompt)))
 555   (set (make-local-variable 'paragraph-separate) "\\'")
 556   (set (make-local-variable 'paragraph-start) comint-prompt-regexp)
 557   (setq comint-input-sender 'ielm-input-sender)
 558   (setq comint-process-echoes nil)
 559   (set (make-local-variable 'completion-at-point-functions)
 560        '(ielm-tab comint-replace-by-expanded-history
 561          ielm-complete-filename ielm-complete-symbol))
 562   (set (make-local-variable 'ielm-prompt-internal) ielm-prompt)
 563   (set (make-local-variable 'comint-prompt-read-only) ielm-prompt-read-only)
 564   (setq comint-get-old-input 'ielm-get-old-input)
 565   (set (make-local-variable 'comint-completion-addsuffix) '("/" . ""))
 566   (setq mode-line-process '(":%s on " (:eval (buffer-name ielm-working-buffer))))
 567   ;; Useful for `hs-minor-mode'.
 568   (setq-local comment-start ";")
 569   (setq-local comment-use-global-state t)
 570
 571   (set (make-local-variable 'indent-line-function) 'ielm-indent-line)
 572   (set (make-local-variable 'ielm-working-buffer) (current-buffer))
 573   (set (make-local-variable 'fill-paragraph-function) 'lisp-fill-paragraph)
 574
 575   ;; Value holders
 576   (set (make-local-variable '*) nil)
 577   (set (make-local-variable '**) nil)
 578   (set (make-local-variable '***) nil)
 579   (set (make-local-variable 'ielm-match-data) nil)
 580
 581   ;; font-lock support
 582   (set (make-local-variable 'font-lock-defaults)
 583        '(ielm-font-lock-keywords nil nil ((?: . "w") (?- . "w") (?* . "w"))))
 584
 585   ;; A dummy process to keep comint happy. It will never get any input
 586   (unless (comint-check-proc (current-buffer))
 587     ;; Was cat, but on non-Unix platforms that might not exist, so
 588     ;; use hexl instead, which is part of the Emacs distribution.
 589     (condition-case nil
 590         (start-process "ielm" (current-buffer) "hexl")
 591       (file-error (start-process "ielm" (current-buffer) "cat")))
 592     (set-process-query-on-exit-flag (ielm-process) nil)
 593     (goto-char (point-max))
 594
 595     ;; Lisp output can include raw characters that confuse comint's
 596     ;; carriage control code.
 597     (set (make-local-variable 'comint-inhibit-carriage-motion) t)
 598
 599     ;; Add a silly header
 600     (insert ielm-header)
 601     (ielm-set-pm (point-max))
 602     (unless comint-use-prompt-regexp
 603       (let ((inhibit-read-only t))
 604         (add-text-properties
 605          (point-min) (point-max)
 606          '(rear-nonsticky t field output inhibit-line-move-field-capture t))))
 607     (comint-output-filter (ielm-process) ielm-prompt-internal)
 608     (set-marker comint-last-input-start (ielm-pm))
 609     (set-process-filter (get-buffer-process (current-buffer)) 'comint-output-filter)))
 610
 611 (defun ielm-get-old-input nil
 612   ;; Return the previous input surrounding point
 613   (save-excursion
 614     (beginning-of-line)
 615     (unless (looking-at-p comint-prompt-regexp)
 616       (re-search-backward comint-prompt-regexp))
 617     (comint-skip-prompt)
 618     (buffer-substring (point) (progn (forward-sexp 1) (point)))))
 619
 620 ;;; User command
 621
 622 ;;;###autoload
 623 (defun ielm nil
 624   "Interactively evaluate Emacs Lisp expressions.
 625 Switches to the buffer `*ielm*', or creates it if it does not exist.
 626 See `inferior-emacs-lisp-mode' for details."
 627   (interactive)
 628   (let (old-point)
 629     (unless (comint-check-proc "*ielm*")
 630       (with-current-buffer (get-buffer-create "*ielm*")
 631         (unless (zerop (buffer-size)) (setq old-point (point)))
 632         (inferior-emacs-lisp-mode)))
 633     (switch-to-buffer "*ielm*")
 634     (when old-point (push-mark old-point))))
 635
 636 (provide 'ielm)
 637
 638 ;;; ielm.el ends here