lisp/emacs-lisp/find-func.el

   1 ;;; find-func.el --- find the definition of the Emacs Lisp function near point
   2
   3 ;; Copyright (C) 1997, 1999, 2001-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Jens Petersen <petersen@kurims.kyoto-u.ac.jp>
   6 ;; Maintainer: petersen@kurims.kyoto-u.ac.jp
   7 ;; Keywords: emacs-lisp, functions, variables
   8 ;; Created: 97/07/25
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26 ;;
  27 ;; The funniest thing about this is that I can't imagine why a package
  28 ;; so obviously useful as this hasn't been written before!!
  29 ;; ;;; find-func
  30 ;; (find-function-setup-keys)
  31 ;;
  32 ;; or just:
  33 ;;
  34 ;; (load "find-func")
  35 ;;
  36 ;; if you don't like the given keybindings and away you go!  It does
  37 ;; pretty much what you would expect, putting the cursor at the
  38 ;; definition of the function or variable at point.
  39 ;;
  40 ;; The code started out from `describe-function', `describe-key'
  41 ;; ("help.el") and `fff-find-loaded-emacs-lisp-function' (Noah Friedman's
  42 ;; "fff.el").
  43
  44 ;;; Code:
  45
  46 ;;; User variables:
  47
  48 (defgroup find-function nil
  49   "Finds the definition of the Emacs Lisp symbol near point."
  50 ;;   :prefix "find-function"
  51   :group 'lisp)
  52
  53 (defconst find-function-space-re "\\(?:\\s-\\|\n\\|;.*\n\\)+")
  54
  55 (defcustom find-function-regexp
  56   ;; Match things like (defun foo ...), (defmacro foo ...),
  57   ;; (define-skeleton foo ...), (define-generic-mode 'foo ...),
  58   ;;  (define-derived-mode foo ...), (define-minor-mode foo)
  59   (concat
  60    "^\\s-*(\\(def\\(ine-skeleton\\|ine-generic-mode\\|ine-derived-mode\\|\
  61 ine\\(?:-global\\)?-minor-mode\\|ine-compilation-mode\\|un-cvs-mode\\|\
  62 foo\\|[^icfgv]\\(\\w\\|\\s_\\)+\\*?\\)\\|easy-mmode-define-[a-z-]+\\|easy-menu-define\\|\
  63 menu-bar-make-toggle\\)"
  64    find-function-space-re
  65    "\\('\\|\(quote \\)?%s\\(\\s-\\|$\\|\(\\|\)\\)")
  66   "The regexp used by `find-function' to search for a function definition.
  67 Note it must contain a `%s' at the place where `format'
  68 should insert the function name.  The default value avoids `defconst',
  69 `defgroup', `defvar', `defface'.
  70
  71 Please send improvements and fixes to the maintainer."
  72   :type 'regexp
  73   :group 'find-function
  74   :version "21.1")
  75
  76 (defcustom find-variable-regexp
  77   (concat
  78    "^\\s-*(\\(def[^fumag]\\(\\w\\|\\s_\\)+\\*?\\|\
  79 easy-mmode-def\\(map\\|syntax\\)\\|easy-menu-define\\)"
  80    find-function-space-re
  81    "%s\\(\\s-\\|$\\)")
  82   "The regexp used by `find-variable' to search for a variable definition.
  83 Note it must contain a `%s' at the place where `format'
  84 should insert the variable name.  The default value
  85 avoids `defun', `defmacro', `defalias', `defadvice', `defgroup', `defface'.
  86
  87 Please send improvements and fixes to the maintainer."
  88   :type 'regexp
  89   :group 'find-function
  90   :version "21.1")
  91
  92 (defcustom find-face-regexp
  93   (concat"^\\s-*(defface" find-function-space-re "%s\\(\\s-\\|$\\)")
  94   "The regexp used by `find-face' to search for a face definition.
  95 Note it must contain a `%s' at the place where `format'
  96 should insert the face name.
  97
  98 Please send improvements and fixes to the maintainer."
  99   :type 'regexp
 100   :group 'find-function
 101   :version "22.1")
 102
 103 (defvar find-function-regexp-alist
 104   '((nil . find-function-regexp)
 105     (defvar . find-variable-regexp)
 106     (defface . find-face-regexp))
 107   "Alist mapping definition types into regexp variables.
 108 Each regexp variable's value should actually be a format string
 109 to be used to substitute the desired symbol name into the regexp.")
 110 (put 'find-function-regexp-alist 'risky-local-variable t)
 111
 112 (defcustom find-function-source-path nil
 113   "The default list of directories where `find-function' searches.
 114
 115 If this variable is nil then `find-function' searches `load-path' by
 116 default."
 117   :type '(repeat directory)
 118   :group 'find-function)
 119
 120 (defcustom find-function-recenter-line 1
 121   "The window line-number from which to start displaying a symbol definition.
 122 A value of nil implies center the beginning of the definition.
 123 See `find-function' and `find-variable'."
 124   :type '(choice (const :tag "Center" nil)
 125                  integer)
 126   :group 'find-function
 127   :version "20.3")
 128
 129 (defcustom find-function-after-hook nil
 130   "Hook run after finding symbol definition.
 131
 132 See the functions `find-function' and `find-variable'."
 133   :type 'hook
 134   :group 'find-function
 135   :version "20.3")
 136
 137 ;;; Functions:
 138
 139 (defun find-library-suffixes ()
 140   (let ((suffixes nil))
 141     (dolist (suffix (get-load-suffixes) (nreverse suffixes))
 142       (unless (string-match "elc" suffix) (push suffix suffixes)))))
 143
 144 (defun find-library--load-name (library)
 145   (let ((name library))
 146     (dolist (dir load-path)
 147       (let ((rel (file-relative-name library dir)))
 148         (if (and (not (string-match "\\`\\.\\./" rel))
 149                  (< (length rel) (length name)))
 150             (setq name rel))))
 151     (unless (equal name library) name)))
 152
 153 (defun find-library-name (library)
 154   "Return the absolute file name of the Emacs Lisp source of LIBRARY.
 155 LIBRARY should be a string (the name of the library)."
 156   ;; If the library is byte-compiled, try to find a source library by
 157   ;; the same name.
 158   (if (string-match "\\.el\\(c\\(\\..*\\)?\\)\\'" library)
 159       (setq library (replace-match "" t t library)))
 160   (or
 161    (locate-file library
 162                 (or find-function-source-path load-path)
 163                 (find-library-suffixes))
 164    (locate-file library
 165                 (or find-function-source-path load-path)
 166                 load-file-rep-suffixes)
 167    (when (file-name-absolute-p library)
 168      (let ((rel (find-library--load-name library)))
 169        (when rel
 170          (or
 171           (locate-file rel
 172                        (or find-function-source-path load-path)
 173                        (find-library-suffixes))
 174           (locate-file rel
 175                        (or find-function-source-path load-path)
 176                        load-file-rep-suffixes)))))
 177    (error "Can't find library %s" library)))
 178
 179 (defvar find-function-C-source-directory
 180   (let ((dir (expand-file-name "src" source-directory)))
 181     (when (and (file-directory-p dir) (file-readable-p dir))
 182       dir))
 183   "Directory where the C source files of Emacs can be found.
 184 If nil, do not try to find the source code of functions and variables
 185 defined in C.")
 186
 187 (declare-function ad-get-advice-info "advice" (function))
 188
 189 (defun find-function-advised-original (func)
 190   "Return the original function symbol of an advised function FUNC.
 191 If FUNC is not the symbol of an advised function, just returns FUNC."
 192   (or (and (symbolp func)
 193            (featurep 'advice)
 194            (let ((ofunc (cdr (assq 'origname (ad-get-advice-info func)))))
 195              (and (fboundp ofunc) ofunc)))
 196       func))
 197
 198 (defun find-function-C-source (fun-or-var file type)
 199   "Find the source location where FUN-OR-VAR is defined in FILE.
 200 TYPE should be nil to find a function, or `defvar' to find a variable."
 201   (let ((dir (or find-function-C-source-directory
 202                  (read-directory-name "Emacs C source dir: " nil nil t))))
 203     (setq file (expand-file-name file dir))
 204     (if (file-readable-p file)
 205         (if (null find-function-C-source-directory)
 206             (setq find-function-C-source-directory dir))
 207       (error "The C source file %s is not available"
 208              (file-name-nondirectory file))))
 209   (unless type
 210     ;; Either or both an alias and its target might be advised.
 211     (setq fun-or-var (find-function-advised-original
 212                       (indirect-function
 213                        (find-function-advised-original fun-or-var)))))
 214   (with-current-buffer (find-file-noselect file)
 215     (goto-char (point-min))
 216     (unless (re-search-forward
 217              (if type
 218                  (concat "DEFVAR[A-Z_]*[ \t\n]*([ \t\n]*\""
 219                          (regexp-quote (symbol-name fun-or-var))
 220                          "\"")
 221                (concat "DEFUN[ \t\n]*([ \t\n]*\""
 222                        (regexp-quote (subr-name fun-or-var))
 223                        "\""))
 224              nil t)
 225       (error "Can't find source for %s" fun-or-var))
 226     (cons (current-buffer) (match-beginning 0))))
 227
 228 ;;;###autoload
 229 (defun find-library (library)
 230   "Find the Emacs Lisp source of LIBRARY.
 231 LIBRARY should be a string (the name of the library)."
 232   (interactive
 233    (let* ((dirs (or find-function-source-path load-path))
 234           (suffixes (find-library-suffixes))
 235           (table (apply-partially 'locate-file-completion-table
 236                                   dirs suffixes))
 237           (def (if (eq (function-called-at-point) 'require)
 238                    ;; `function-called-at-point' may return 'require
 239                    ;; with `point' anywhere on this line.  So wrap the
 240                    ;; `save-excursion' below in a `condition-case' to
 241                    ;; avoid reporting a scan-error here.
 242                    (condition-case nil
 243                        (save-excursion
 244                          (backward-up-list)
 245                          (forward-char)
 246                          (forward-sexp 2)
 247                          (thing-at-point 'symbol))
 248                      (error nil))
 249                  (thing-at-point 'symbol))))
 250      (when (and def (not (test-completion def table)))
 251        (setq def nil))
 252      (list
 253       (completing-read (if def (format "Library name (default %s): " def)
 254                          "Library name: ")
 255                        table nil nil nil nil def))))
 256   (let ((buf (find-file-noselect (find-library-name library))))
 257     (condition-case nil (switch-to-buffer buf) (error (pop-to-buffer buf)))))
 258
 259 ;;;###autoload
 260 (defun find-function-search-for-symbol (symbol type library)
 261   "Search for SYMBOL's definition of type TYPE in LIBRARY.
 262 Visit the library in a buffer, and return a cons cell (BUFFER . POSITION),
 263 or just (BUFFER . nil) if the definition can't be found in the file.
 264
 265 If TYPE is nil, look for a function definition.
 266 Otherwise, TYPE specifies the kind of definition,
 267 and it is interpreted via `find-function-regexp-alist'.
 268 The search is done in the source for library LIBRARY."
 269   (if (null library)
 270       (error "Don't know where `%s' is defined" symbol))
 271   ;; Some functions are defined as part of the construct
 272   ;; that defines something else.
 273   (while (and (symbolp symbol) (get symbol 'definition-name))
 274     (setq symbol (get symbol 'definition-name)))
 275   (if (string-match "\\`src/\\(.*\\.\\(c\\|m\\)\\)\\'" library)
 276       (find-function-C-source symbol (match-string 1 library) type)
 277     (when (string-match "\\.el\\(c\\)\\'" library)
 278       (setq library (substring library 0 (match-beginning 1))))
 279     ;; Strip extension from .emacs.el to make sure symbol is searched in
 280     ;; .emacs too.
 281     (when (string-match "\\.emacs\\(.el\\)" library)
 282       (setq library (substring library 0 (match-beginning 1))))
 283     (let* ((filename (find-library-name library))
 284            (regexp-symbol (cdr (assq type find-function-regexp-alist))))
 285       (with-current-buffer (find-file-noselect filename)
 286         (let ((regexp (format (symbol-value regexp-symbol)
 287                               ;; Entry for ` (backquote) macro in loaddefs.el,
 288                               ;; (defalias (quote \`)..., has a \ but
 289                               ;; (symbol-name symbol) doesn't.  Add an
 290                               ;; optional \ to catch this.
 291                               (concat "\\\\?"
 292                                       (regexp-quote (symbol-name symbol)))))
 293               (case-fold-search))
 294           (with-syntax-table emacs-lisp-mode-syntax-table
 295             (goto-char (point-min))
 296             (if (or (re-search-forward regexp nil t)
 297                     ;; `regexp' matches definitions using known forms like
 298                     ;; `defun', or `defvar'.  But some functions/variables
 299                     ;; are defined using special macros (or functions), so
 300                     ;; if `regexp' can't find the definition, we look for
 301                     ;; something of the form "(SOMETHING <symbol> ...)".
 302                     ;; This fails to distinguish function definitions from
 303                     ;; variable declarations (or even uses thereof), but is
 304                     ;; a good pragmatic fallback.
 305                     (re-search-forward
 306                      (concat "^([^ ]+" find-function-space-re "['(]?"
 307                              (regexp-quote (symbol-name symbol))
 308                              "\\_>")
 309                      nil t))
 310                 (progn
 311                   (beginning-of-line)
 312                   (cons (current-buffer) (point)))
 313               (cons (current-buffer) nil))))))))
 314
 315 ;;;###autoload
 316 (defun find-function-noselect (function &optional lisp-only)
 317   "Return a pair (BUFFER . POINT) pointing to the definition of FUNCTION.
 318
 319 Finds the source file containing the definition of FUNCTION
 320 in a buffer and the point of the definition.  The buffer is
 321 not selected.  If the function definition can't be found in
 322 the buffer, returns (BUFFER).
 323
 324 If FUNCTION is a built-in function, this function normally
 325 attempts to find it in the Emacs C sources; however, if LISP-ONLY
 326 is non-nil, signal an error instead.
 327
 328 If the file where FUNCTION is defined is not known, then it is
 329 searched for in `find-function-source-path' if non-nil, otherwise
 330 in `load-path'."
 331   (if (not function)
 332     (error "You didn't specify a function"))
 333   (let ((def (symbol-function (find-function-advised-original function)))
 334         aliases)
 335     ;; FIXME for completeness, it might be nice to print something like:
 336     ;; foo (which is advised), which is an alias for bar (which is advised).
 337     (while (symbolp def)
 338       (or (eq def function)
 339           (if aliases
 340               (setq aliases (concat aliases
 341                                     (format ", which is an alias for `%s'"
 342                                             (symbol-name def))))
 343             (setq aliases (format "`%s' is an alias for `%s'"
 344                                   function (symbol-name def)))))
 345       (setq function (symbol-function (find-function-advised-original function))
 346             def (symbol-function (find-function-advised-original function))))
 347     (if aliases
 348         (message "%s" aliases))
 349     (let ((library
 350            (cond ((autoloadp def) (nth 1 def))
 351                  ((subrp def)
 352                   (if lisp-only
 353                       (error "%s is a built-in function" function))
 354                   (help-C-file-name def 'subr))
 355                  ((symbol-file function 'defun)))))
 356       (find-function-search-for-symbol function nil library))))
 357
 358 (defun find-function-read (&optional type)
 359   "Read and return an interned symbol, defaulting to the one near point.
 360
 361 If TYPE is nil, insist on a symbol with a function definition.
 362 Otherwise TYPE should be `defvar' or `defface'.
 363 If TYPE is nil, defaults using `function-called-at-point',
 364 otherwise uses `variable-at-point'."
 365   (let* ((symb1 (cond ((null type) (function-called-at-point))
 366                       ((eq type 'defvar) (variable-at-point))
 367                       (t (variable-at-point t))))
 368          (symb  (unless (eq symb1 0) symb1))
 369          (predicate (cdr (assq type '((nil . fboundp)
 370                                       (defvar . boundp)
 371                                       (defface . facep)))))
 372          (prompt-type (cdr (assq type '((nil . "function")
 373                                         (defvar . "variable")
 374                                         (defface . "face")))))
 375          (prompt (concat "Find " prompt-type
 376                          (and symb (format " (default %s)" symb))
 377                          ": "))
 378          (enable-recursive-minibuffers t))
 379     (list (intern (completing-read
 380                    prompt obarray predicate
 381                    t nil nil (and symb (symbol-name symb)))))))
 382
 383 (defun find-function-do-it (symbol type switch-fn)
 384   "Find Emacs Lisp SYMBOL in a buffer and display it.
 385 TYPE is nil to search for a function definition,
 386 or else `defvar' or `defface'.
 387
 388 The variable `find-function-recenter-line' controls how
 389 to recenter the display.  SWITCH-FN is the function to call
 390 to display and select the buffer.
 391 See also `find-function-after-hook'.
 392
 393 Set mark before moving, if the buffer already existed."
 394   (let* ((orig-point (point))
 395         (orig-buf (window-buffer))
 396         (orig-buffers (buffer-list))
 397         (buffer-point (save-excursion
 398                         (find-definition-noselect symbol type)))
 399         (new-buf (car buffer-point))
 400         (new-point (cdr buffer-point)))
 401     (when buffer-point
 402       (when (memq new-buf orig-buffers)
 403         (push-mark orig-point))
 404       (funcall switch-fn new-buf)
 405       (when new-point (goto-char new-point))
 406       (recenter find-function-recenter-line)
 407       (run-hooks 'find-function-after-hook))))
 408
 409 ;;;###autoload
 410 (defun find-function (function)
 411   "Find the definition of the FUNCTION near point.
 412
 413 Finds the source file containing the definition of the function
 414 near point (selected by `function-called-at-point') in a buffer and
 415 places point before the definition.
 416 Set mark before moving, if the buffer already existed.
 417
 418 The library where FUNCTION is defined is searched for in
 419 `find-function-source-path', if non-nil, otherwise in `load-path'.
 420 See also `find-function-recenter-line' and `find-function-after-hook'."
 421   (interactive (find-function-read))
 422   (find-function-do-it function nil 'switch-to-buffer))
 423
 424 ;;;###autoload
 425 (defun find-function-other-window (function)
 426   "Find, in another window, the definition of FUNCTION near point.
 427
 428 See `find-function' for more details."
 429   (interactive (find-function-read))
 430   (find-function-do-it function nil 'switch-to-buffer-other-window))
 431
 432 ;;;###autoload
 433 (defun find-function-other-frame (function)
 434   "Find, in another frame, the definition of FUNCTION near point.
 435
 436 See `find-function' for more details."
 437   (interactive (find-function-read))
 438   (find-function-do-it function nil 'switch-to-buffer-other-frame))
 439
 440 ;;;###autoload
 441 (defun find-variable-noselect (variable &optional file)
 442   "Return a pair `(BUFFER . POINT)' pointing to the definition of VARIABLE.
 443
 444 Finds the library containing the definition of VARIABLE in a buffer and
 445 the point of the definition.  The buffer is not selected.
 446 If the variable's definition can't be found in the buffer, return (BUFFER).
 447
 448 The library where VARIABLE is defined is searched for in FILE or
 449 `find-function-source-path', if non-nil, otherwise in `load-path'."
 450   (if (not variable)
 451       (error "You didn't specify a variable")
 452     (let ((library (or file
 453                        (symbol-file variable 'defvar)
 454                        (help-C-file-name variable 'var))))
 455       (find-function-search-for-symbol variable 'defvar library))))
 456
 457 ;;;###autoload
 458 (defun find-variable (variable)
 459   "Find the definition of the VARIABLE at or before point.
 460
 461 Finds the library containing the definition of the variable
 462 near point (selected by `variable-at-point') in a buffer and
 463 places point before the definition.
 464
 465 Set mark before moving, if the buffer already existed.
 466
 467 The library where VARIABLE is defined is searched for in
 468 `find-function-source-path', if non-nil, otherwise in `load-path'.
 469 See also `find-function-recenter-line' and `find-function-after-hook'."
 470   (interactive (find-function-read 'defvar))
 471   (find-function-do-it variable 'defvar 'switch-to-buffer))
 472
 473 ;;;###autoload
 474 (defun find-variable-other-window (variable)
 475   "Find, in another window, the definition of VARIABLE near point.
 476
 477 See `find-variable' for more details."
 478   (interactive (find-function-read 'defvar))
 479   (find-function-do-it variable 'defvar 'switch-to-buffer-other-window))
 480
 481 ;;;###autoload
 482 (defun find-variable-other-frame (variable)
 483   "Find, in another frame, the definition of VARIABLE near point.
 484
 485 See `find-variable' for more details."
 486   (interactive (find-function-read 'defvar))
 487   (find-function-do-it variable 'defvar 'switch-to-buffer-other-frame))
 488
 489 ;;;###autoload
 490 (defun find-definition-noselect (symbol type &optional file)
 491   "Return a pair `(BUFFER . POINT)' pointing to the definition of SYMBOL.
 492 If the definition can't be found in the buffer, return (BUFFER).
 493 TYPE says what type of definition: nil for a function, `defvar' for a
 494 variable, `defface' for a face.  This function does not switch to the
 495 buffer nor display it.
 496
 497 The library where SYMBOL is defined is searched for in FILE or
 498 `find-function-source-path', if non-nil, otherwise in `load-path'."
 499   (cond
 500    ((not symbol)
 501     (error "You didn't specify a symbol"))
 502    ((null type)
 503     (find-function-noselect symbol))
 504    ((eq type 'defvar)
 505     (find-variable-noselect symbol file))
 506    (t
 507     (let ((library (or file (symbol-file symbol type))))
 508       (find-function-search-for-symbol symbol type library)))))
 509
 510 ;; For symmetry, this should be called find-face; but some programs
 511 ;; assume that, if that name is defined, it means something else.
 512 ;;;###autoload
 513 (defun find-face-definition (face)
 514   "Find the definition of FACE.  FACE defaults to the name near point.
 515
 516 Finds the Emacs Lisp library containing the definition of the face
 517 near point (selected by `variable-at-point') in a buffer and
 518 places point before the definition.
 519
 520 Set mark before moving, if the buffer already existed.
 521
 522 The library where FACE is defined is searched for in
 523 `find-function-source-path', if non-nil, otherwise in `load-path'.
 524 See also `find-function-recenter-line' and `find-function-after-hook'."
 525   (interactive (find-function-read 'defface))
 526   (find-function-do-it face 'defface 'switch-to-buffer))
 527
 528 ;;;###autoload
 529 (defun find-function-on-key (key)
 530   "Find the function that KEY invokes.  KEY is a string.
 531 Set mark before moving, if the buffer already existed."
 532   (interactive "kFind function on key: ")
 533   (let (defn)
 534     (save-excursion
 535       (let* ((event (and (eventp key) (aref key 0))) ; Null event OK below.
 536              (start (event-start event))
 537              (modifiers (event-modifiers event))
 538              (window (and (or (memq 'click modifiers) (memq 'down modifiers)
 539                               (memq 'drag modifiers))
 540                           (posn-window start))))
 541         ;; For a mouse button event, go to the button it applies to
 542         ;; to get the right key bindings.  And go to the right place
 543         ;; in case the keymap depends on where you clicked.
 544         (when (windowp window)
 545           (set-buffer (window-buffer window))
 546           (goto-char (posn-point start)))
 547         (setq defn (key-binding key))))
 548     (let ((key-desc (key-description key)))
 549       (if (or (null defn) (integerp defn))
 550           (message "%s is unbound" key-desc)
 551         (if (consp defn)
 552             (message "%s runs %s" key-desc (prin1-to-string defn))
 553           (find-function-other-window defn))))))
 554
 555 ;;;###autoload
 556 (defun find-function-at-point ()
 557   "Find directly the function at point in the other window."
 558   (interactive)
 559   (let ((symb (function-called-at-point)))
 560     (when symb
 561       (find-function-other-window symb))))
 562
 563 ;;;###autoload
 564 (defun find-variable-at-point ()
 565   "Find directly the variable at point in the other window."
 566   (interactive)
 567   (let ((symb (variable-at-point)))
 568     (when (and symb (not (equal symb 0)))
 569       (find-variable-other-window symb))))
 570
 571 ;;;###autoload
 572 (defun find-function-setup-keys ()
 573   "Define some key bindings for the find-function family of functions."
 574   (define-key ctl-x-map "F" 'find-function)
 575   (define-key ctl-x-4-map "F" 'find-function-other-window)
 576   (define-key ctl-x-5-map "F" 'find-function-other-frame)
 577   (define-key ctl-x-map "K" 'find-function-on-key)
 578   (define-key ctl-x-map "V" 'find-variable)
 579   (define-key ctl-x-4-map "V" 'find-variable-other-window)
 580   (define-key ctl-x-5-map "V" 'find-variable-other-frame))
 581
 582 (provide 'find-func)
 583
 584 ;;; find-func.el ends here