lisp/calendar/lunar.el

   1 ;;; lunar.el --- calendar functions for phases of the moon
   2
   3 ;; Copyright (C) 1992-1993, 1995, 1997, 2001-2014 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
   7 ;; Maintainer: Glenn Morris <rgm@gnu.org>
   8 ;; Keywords: calendar
   9 ;; Human-Keywords: moon, lunar phases, calendar, diary
  10 ;; Package: calendar
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; See calendar.el.
  30
  31 ;; Based on ``Astronomical Formulae for Calculators,'' 3rd ed., by Jean Meeus,
  32 ;; Willmann-Bell, Inc., 1985 and ``Astronomical Algorithms'' by Jean Meeus,
  33 ;; Willmann-Bell, Inc., 1991.
  34 ;;
  35 ;; WARNING: The calculations will be accurate only to within a few minutes.
  36
  37 ;; The author would be delighted to have an astronomically more sophisticated
  38 ;; person rewrite the code for the lunar calculations in this file!
  39
  40 ;;; Code:
  41
  42 (require 'calendar)
  43 (require 'solar)
  44 (require 'cal-dst)
  45 ;; calendar-astro-to-absolute and v versa are cal-autoloads.
  46 ;;;(require 'cal-julian)
  47
  48 (defcustom lunar-phase-names
  49   '("New Moon" "First Quarter Moon" "Full Moon" "Last Quarter Moon")
  50   "List of names for the lunar phases."
  51   :type '(list
  52           (string :tag "New Moon")
  53           (string :tag "First Quarter Moon")
  54           (string :tag "Full Moon")
  55           (string :tag "Last Quarter Moon"))
  56   :group 'calendar
  57   :version "23.2")
  58
  59 (defun lunar-phase (index)
  60   "Local date and time of lunar phase INDEX.
  61 Integer below INDEX/4 gives the lunation number, counting from Jan 1, 1900;
  62 remainder mod 4 gives the phase: 0 new moon, 1 first quarter, 2 full moon,
  63 3 last quarter.  Returns a list (DATE TIME PHASE)."
  64   (let* ((phase (mod index 4))
  65          (index (/ index 4.0))
  66          (time (/ index 1236.85))
  67          (date (+ (calendar-absolute-from-gregorian '(1 0.5 1900))
  68                   0.75933
  69                   (* 29.53058868 index) ; FIXME 29.530588853?
  70                   (* 0.0001178 time time)
  71                   (* -0.000000155 time time time)
  72                   (* 0.00033
  73                      (solar-sin-degrees (+ 166.56
  74                                            (* 132.87 time)
  75                                            (* -0.009173 time time))))))
  76          (sun-anomaly (mod
  77                        (+ 359.2242
  78                           (* 29.105356 index)
  79                           (* -0.0000333 time time)
  80                           (* -0.00000347 time time time))
  81                        360.0))
  82          (moon-anomaly (mod
  83                         (+ 306.0253
  84                            (* 385.81691806 index)
  85                            (* 0.0107306 time time)
  86                            (* 0.00001236 time time time))
  87                         360.0))
  88          (moon-lat (mod
  89                     (+ 21.2964
  90                        (* 390.67050646 index)
  91                        (* -0.0016528 time time)
  92                        (* -0.00000239 time time time))
  93                     360.0))
  94          (adjustment
  95           (if (memq phase '(0 2))
  96               (+ (* (- 0.1734 (* 0.000393 time))
  97                     (solar-sin-degrees sun-anomaly))
  98                  (* 0.0021 (solar-sin-degrees (* 2 sun-anomaly)))
  99                  (* -0.4068 (solar-sin-degrees moon-anomaly))
 100                  (* 0.0161 (solar-sin-degrees (* 2 moon-anomaly)))
 101                  (* -0.0004 (solar-sin-degrees (* 3 moon-anomaly)))
 102                  (* 0.0104 (solar-sin-degrees (* 2 moon-lat)))
 103                  (* -0.0051 (solar-sin-degrees (+ sun-anomaly moon-anomaly)))
 104                  (* -0.0074 (solar-sin-degrees (- sun-anomaly moon-anomaly)))
 105                  (* 0.0004 (solar-sin-degrees (+ (* 2 moon-lat) sun-anomaly)))
 106                  (* -0.0004 (solar-sin-degrees (- (* 2 moon-lat) sun-anomaly)))
 107                  (* -0.0006 (solar-sin-degrees
 108                              (+ (* 2 moon-lat) moon-anomaly)))
 109                  (* 0.0010 (solar-sin-degrees (- (* 2 moon-lat) moon-anomaly)))
 110                  (* 0.0005 (solar-sin-degrees
 111                             (+ (* 2 moon-anomaly) sun-anomaly))))
 112             (+ (* (- 0.1721 (* 0.0004 time))
 113                   (solar-sin-degrees sun-anomaly))
 114                (* 0.0021 (solar-sin-degrees (* 2 sun-anomaly)))
 115                (* -0.6280 (solar-sin-degrees moon-anomaly))
 116                (* 0.0089 (solar-sin-degrees (* 2 moon-anomaly)))
 117                (* -0.0004 (solar-sin-degrees (* 3 moon-anomaly)))
 118                (* 0.0079 (solar-sin-degrees (* 2 moon-lat)))
 119                (* -0.0119 (solar-sin-degrees (+ sun-anomaly moon-anomaly)))
 120                (* -0.0047 (solar-sin-degrees (- sun-anomaly moon-anomaly)))
 121                (* 0.0003 (solar-sin-degrees (+ (* 2 moon-lat) sun-anomaly)))
 122                (* -0.0004 (solar-sin-degrees (- (* 2 moon-lat) sun-anomaly)))
 123                (* -0.0006 (solar-sin-degrees (+ (* 2 moon-lat) moon-anomaly)))
 124                (* 0.0021 (solar-sin-degrees (- (* 2 moon-lat) moon-anomaly)))
 125                (* 0.0003 (solar-sin-degrees
 126                           (+ (* 2 moon-anomaly) sun-anomaly)))
 127                (* 0.0004 (solar-sin-degrees
 128                           (- sun-anomaly (* 2 moon-anomaly))))
 129                (* -0.0003 (solar-sin-degrees
 130                            (+ (* 2 sun-anomaly) moon-anomaly))))))
 131          (adj (+ 0.0028
 132                  (* -0.0004 (solar-cosine-degrees
 133                              sun-anomaly))
 134                  (* 0.0003 (solar-cosine-degrees
 135                             moon-anomaly))))
 136          (adjustment (cond ((= phase 1) (+ adjustment adj))
 137                            ((= phase 2) (- adjustment adj))
 138                            (t adjustment)))
 139          (date (+ date adjustment))
 140          (date (+ date (/ (- calendar-time-zone
 141                              (solar-ephemeris-correction
 142                               (calendar-extract-year
 143                                (calendar-gregorian-from-absolute
 144                                 (truncate date)))))
 145                           60.0 24.0)))
 146          (time (* 24 (- date (truncate date))))
 147          (date (calendar-gregorian-from-absolute (truncate date)))
 148          (adj (dst-adjust-time date time)))
 149     (list (car adj) (apply 'solar-time-string (cdr adj)) phase)))
 150
 151 (defconst lunar-cycles-per-year 12.3685 ; 365.25/29.530588853
 152   "Mean number of lunar cycles per 365.25 day year.")
 153
 154 ;; FIXME new-moon index; use in lunar-phase-list implies always below.
 155 (defun lunar-index (date)
 156   "Return the lunar index for Gregorian date DATE.
 157 This is 4 times the approximate number of new moons since 1 Jan 1900.
 158 The factor of 4 allows (mod INDEX 4) to represent the four quarters."
 159   (* 4 (truncate
 160         (* lunar-cycles-per-year
 161            ;; Years since 1900, as a real.
 162            (+ (calendar-extract-year date)
 163               (/ (calendar-day-number date) 366.0)
 164               -1900)))))
 165
 166 (defun lunar-phase-list (month year)
 167   "List of lunar phases for three months starting with Gregorian MONTH, YEAR."
 168   (let* ((index (lunar-index (list month 1 year)))
 169          (new-moon (lunar-phase index))
 170          (end-date (let ((end-month month)
 171                          (end-year year))
 172                      (calendar-increment-month end-month end-year 3)
 173                      (list (list end-month 1 end-year))))
 174          ;; Alternative for start-date:
 175 ;;;         (calendar-gregorian-from-absolute
 176 ;;;          (1- (calendar-absolute-from-gregorian (list month 1 year))))
 177          (start-date (progn
 178                        (calendar-increment-month month year -1)
 179                        (list (list month
 180                                    (calendar-last-day-of-month month year)
 181                                    year))))
 182          list)
 183     (while (calendar-date-compare new-moon end-date)
 184       (if (calendar-date-compare start-date new-moon)
 185           (setq list (append list (list new-moon))))
 186       (setq index (1+ index)
 187             new-moon (lunar-phase index)))
 188     list))
 189
 190 (defun lunar-phase-name (phase)
 191   "Name of lunar PHASE.
 192 0 = new moon, 1 = first quarter, 2 = full moon, 3 = last quarter."
 193   (nth phase lunar-phase-names))
 194
 195 (defvar displayed-month)                ; from calendar-generate
 196 (defvar displayed-year)
 197
 198 ;;;###cal-autoload
 199 (defun calendar-lunar-phases (&optional event)
 200   "Create a buffer with the lunar phases for the current calendar window.
 201 If EVENT is non-nil, it's an event indicating the buffer position to
 202 use instead of point."
 203   (interactive (list last-nonmenu-event))
 204   ;; If called from a menu, with the calendar window not selected.
 205   (with-current-buffer
 206       (if event (window-buffer (posn-window (event-start event)))
 207         (current-buffer))
 208     (message "Computing phases of the moon...")
 209     (let ((m1 displayed-month)
 210           (y1 displayed-year)
 211           (m2 displayed-month)
 212           (y2 displayed-year))
 213       (calendar-increment-month m1 y1 -1)
 214       (calendar-increment-month m2 y2 1)
 215       (calendar-in-read-only-buffer lunar-phases-buffer
 216         (calendar-set-mode-line
 217          (if (= y1 y2)
 218              (format "Phases of the Moon from %s to %s, %d%%-"
 219                      (calendar-month-name m1) (calendar-month-name m2) y2)
 220            (format "Phases of the Moon from %s, %d to %s, %d%%-"
 221                    (calendar-month-name m1) y1 (calendar-month-name m2) y2)))
 222         (insert
 223          (mapconcat
 224           (lambda (x)
 225             (format "%s: %s %s" (calendar-date-string (car x))
 226                     (lunar-phase-name (nth 2 x))
 227                     (cadr x)))
 228           (lunar-phase-list m1 y1) "\n")))
 229       (message "Computing phases of the moon...done"))))
 230
 231 ;;;###cal-autoload
 232 (define-obsolete-function-alias 'calendar-phases-of-moon
 233   'calendar-lunar-phases "23.1")
 234
 235 ;;;###autoload
 236 (defun lunar-phases (&optional arg)
 237   "Display the quarters of the moon for last month, this month, and next month.
 238 If called with an optional prefix argument ARG, prompts for month and year.
 239 This function is suitable for execution in an init file."
 240   (interactive "P")
 241   (save-excursion
 242     (let* ((date (if arg (calendar-read-date t)
 243                    (calendar-current-date)))
 244            (displayed-month (calendar-extract-month date))
 245            (displayed-year (calendar-extract-year date)))
 246       (calendar-lunar-phases))))
 247
 248 ;;;###autoload
 249 (define-obsolete-function-alias 'phases-of-moon 'lunar-phases "23.1")
 250
 251 (defvar date)
 252
 253 ;; To be called from diary-list-sexp-entries, where DATE is bound.
 254
 255 ;;;###diary-autoload
 256 (defun diary-lunar-phases (&optional mark)
 257   "Moon phases diary entry.
 258 An optional parameter MARK specifies a face or single-character string to
 259 use when highlighting the day in the calendar."
 260   (let* ((index (lunar-index date))
 261          (phase (lunar-phase index)))
 262     (while (calendar-date-compare phase (list date))
 263       (setq index (1+ index)
 264             phase (lunar-phase index)))
 265     (if (calendar-date-equal (car phase) date)
 266         (cons mark (concat (lunar-phase-name (nth 2 phase)) " "
 267                            (cadr phase))))))
 268
 269 ;;;###diary-autoload
 270 (define-obsolete-function-alias 'diary-phases-of-moon
 271   'diary-lunar-phases "23.1")
 272
 273 ;; For the Chinese calendar the calculations for the new moon need to be more
 274 ;; accurate than those above, so we use more terms in the approximation.
 275 (defun lunar-new-moon-time (k)
 276   "Astronomical (Julian) day number of K th new moon."
 277   (let* ((T (/ k 1236.85))
 278          (T2 (* T T))
 279          (T3 (* T T T))
 280          (T4 (* T2 T2))
 281          (JDE (+ 2451550.09765
 282                  (* 29.530588853 k)
 283                  (* 0.0001337 T2)
 284                  (* -0.000000150 T3)
 285                  (* 0.00000000073 T4)))
 286          (E (- 1 (* 0.002516 T) (* 0.0000074 T2)))
 287          (sun-anomaly (+ 2.5534
 288                          (* 29.10535669 k)
 289                          (* -0.0000218 T2)
 290                          (* -0.00000011 T3)))
 291          (moon-anomaly (+ 201.5643
 292                           (* 385.81693528 k)
 293                           (* 0.0107438 T2)
 294                           (* 0.00001239 T3)
 295                           (* -0.000000058 T4)))
 296          (moon-argument (+ 160.7108
 297                            (* 390.67050274 k)
 298                            (* -0.0016341 T2)
 299                            (* -0.00000227 T3)
 300                            (* 0.000000011 T4)))
 301          (omega (+ 124.7746
 302                    (* -1.56375580 k)
 303                    (* 0.0020691 T2)
 304                    (* 0.00000215 T3)))
 305          (A1  (+ 299.77 (*  0.107408 k) (* -0.009173 T2)))
 306          (A2  (+ 251.88 (*  0.016321 k)))
 307          (A3  (+ 251.83 (* 26.641886 k)))
 308          (A4  (+ 349.42 (* 36.412478 k)))
 309          (A5  (+  84.66 (* 18.206239 k)))
 310          (A6  (+ 141.74 (* 53.303771 k)))
 311          (A7  (+ 207.14 (*  2.453732 k)))
 312          (A8  (+ 154.84 (*  7.306860 k)))
 313          (A9  (+  34.52 (* 27.261239 k)))
 314          (A10 (+ 207.19 (*  0.121824 k)))
 315          (A11 (+ 291.34 (*  1.844379 k)))
 316          (A12 (+ 161.72 (* 24.198154 k)))
 317          (A13 (+ 239.56 (* 25.513099 k)))
 318          (A14 (+ 331.55 (*  3.592518 k)))
 319          (correction
 320           (+ (* -0.40720   (solar-sin-degrees moon-anomaly))
 321              (*  0.17241 E (solar-sin-degrees sun-anomaly))
 322              (*  0.01608   (solar-sin-degrees (* 2 moon-anomaly)))
 323              (*  0.01039   (solar-sin-degrees (* 2 moon-argument)))
 324              (*  0.00739 E (solar-sin-degrees (- moon-anomaly sun-anomaly)))
 325              (* -0.00514 E (solar-sin-degrees (+ moon-anomaly sun-anomaly)))
 326              (*  0.00208 E E (solar-sin-degrees (* 2 sun-anomaly)))
 327              (* -0.00111   (solar-sin-degrees
 328                             (- moon-anomaly (* 2 moon-argument))))
 329              (* -0.00057   (solar-sin-degrees
 330                             (+ moon-anomaly (* 2 moon-argument))))
 331              (*  0.00056 E (solar-sin-degrees
 332                             (+ (* 2 moon-anomaly) sun-anomaly)))
 333              (* -0.00042   (solar-sin-degrees (* 3 moon-anomaly)))
 334              (*  0.00042 E (solar-sin-degrees
 335                             (+ sun-anomaly (* 2 moon-argument))))
 336              (*  0.00038 E (solar-sin-degrees
 337                             (- sun-anomaly (* 2 moon-argument))))
 338              (* -0.00024 E (solar-sin-degrees
 339                             (- (* 2 moon-anomaly) sun-anomaly)))
 340              (* -0.00017   (solar-sin-degrees omega))
 341              (* -0.00007   (solar-sin-degrees
 342                             (+ moon-anomaly (* 2 sun-anomaly))))
 343              (*  0.00004   (solar-sin-degrees
 344                             (- (* 2 moon-anomaly) (* 2 moon-argument))))
 345              (*  0.00004   (solar-sin-degrees (* 3 sun-anomaly)))
 346              (*  0.00003   (solar-sin-degrees (+ moon-anomaly sun-anomaly
 347                                                  (* -2 moon-argument))))
 348              (*  0.00003   (solar-sin-degrees
 349                             (+ (* 2 moon-anomaly) (* 2 moon-argument))))
 350              (* -0.00003   (solar-sin-degrees (+ moon-anomaly sun-anomaly
 351                                                  (* 2 moon-argument))))
 352              (*  0.00003   (solar-sin-degrees (- moon-anomaly sun-anomaly
 353                                                  (* -2 moon-argument))))
 354              (* -0.00002   (solar-sin-degrees (- moon-anomaly sun-anomaly
 355                                                  (* 2 moon-argument))))
 356              (* -0.00002   (solar-sin-degrees
 357                             (+ (* 3 moon-anomaly) sun-anomaly)))
 358              (*  0.00002   (solar-sin-degrees (* 4 moon-anomaly)))))
 359          (additional
 360           (+ (* 0.000325 (solar-sin-degrees A1))
 361              (* 0.000165 (solar-sin-degrees A2))
 362              (* 0.000164 (solar-sin-degrees A3))
 363              (* 0.000126 (solar-sin-degrees A4))
 364              (* 0.000110 (solar-sin-degrees A5))
 365              (* 0.000062 (solar-sin-degrees A6))
 366              (* 0.000060 (solar-sin-degrees A7))
 367              (* 0.000056 (solar-sin-degrees A8))
 368              (* 0.000047 (solar-sin-degrees A9))
 369              (* 0.000042 (solar-sin-degrees A10))
 370              (* 0.000040 (solar-sin-degrees A11))
 371              (* 0.000037 (solar-sin-degrees A12))
 372              (* 0.000035 (solar-sin-degrees A13))
 373              (* 0.000023 (solar-sin-degrees A14))))
 374          (newJDE (+ JDE correction additional)))
 375     (+ newJDE
 376        (- (solar-ephemeris-correction
 377            (calendar-extract-year
 378             (calendar-gregorian-from-absolute
 379              (floor (calendar-astro-to-absolute newJDE))))))
 380        (/ calendar-time-zone 60.0 24.0))))
 381
 382 (defun lunar-new-moon-on-or-after (d)
 383   "Julian day number of first new moon on or after Julian day number D.
 384 The fractional part is the time of day.
 385
 386 The date and time are local time, including any daylight saving rules,
 387 as governed by the values of `calendar-daylight-savings-starts',
 388 `calendar-daylight-savings-starts-time', `calendar-daylight-savings-ends',
 389 `calendar-daylight-savings-ends-time', `calendar-daylight-time-offset', and
 390 `calendar-time-zone'."
 391   (let* ((date (calendar-gregorian-from-absolute
 392                 (floor (calendar-astro-to-absolute d))))
 393          (year (+ (calendar-extract-year date)
 394                   (/ (calendar-day-number date) 365.25)))
 395          (k (floor (* (- year 2000.0) lunar-cycles-per-year)))
 396          (date (lunar-new-moon-time k))
 397          (a-date (progn
 398                    (while (< date d)
 399                      (setq k (1+ k)
 400                            date (lunar-new-moon-time k)))
 401                    (calendar-astro-to-absolute date)))
 402          (time (* 24 (- a-date (truncate a-date))))
 403          (date (calendar-gregorian-from-absolute (truncate a-date)))
 404          (adj (dst-adjust-time date time)))
 405     (calendar-astro-from-absolute
 406      (+ (calendar-absolute-from-gregorian (car adj))
 407         (/ (cadr adj) 24.0)))))
 408
 409 (provide 'lunar)
 410
 411 ;;; lunar.el ends here