lisp/calendar/cal-x.el

   1 ;;; cal-x.el --- calendar windows in dedicated frames
   2
   3 ;; Copyright (C) 1994-1995, 2001-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael Kifer <kifer@cs.sunysb.edu>
   6 ;;         Edward M. Reingold <reingold@cs.uiuc.edu>
   7 ;; Maintainer: Glenn Morris <rgm@gnu.org>
   8 ;; Keywords: calendar
   9 ;; Human-Keywords: calendar, dedicated frames
  10 ;; Package: calendar
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; See calendar.el.
  30
  31 ;;; Code:
  32
  33 (require 'calendar)
  34
  35 (defcustom diary-frame-parameters
  36   '((name . "Diary") (title . "Diary") (height . 10) (width . 80)
  37     (unsplittable . t) (minibuffer . nil))
  38   "Parameters of the diary frame, if the diary is in its own frame.
  39 Relevant if `calendar-setup' has the value `two-frames'."
  40   :type 'alist
  41   :options '((name string) (title string) (height integer) (width integer)
  42              (unsplittable boolean) (minibuffer boolean)
  43              (vertical-scroll-bars boolean))
  44   :group 'calendar)
  45
  46 (defcustom calendar-frame-parameters
  47   '((name . "Calendar") (title . "Calendar") (height . 10) (width . 80)
  48     (unsplittable . t) (minibuffer . nil) (vertical-scroll-bars . nil))
  49   "Parameters of the calendar frame, if the calendar is in a separate frame.
  50 Relevant if `calendar-setup' has the value `calendar-only' or `two-frames'."
  51   :type 'alist
  52   :options '((name string) (title string) (height integer) (width integer)
  53              (unsplittable boolean) (minibuffer boolean)
  54              (vertical-scroll-bars boolean))
  55   :group 'calendar)
  56
  57 (defcustom calendar-and-diary-frame-parameters
  58   '((name . "Calendar") (title . "Calendar") (height . 28) (width . 80)
  59     (minibuffer . nil))
  60   "Parameters of the frame that displays both the calendar and the diary.
  61 Relevant if `calendar-setup' has the value `one-frame'."
  62   :type 'alist
  63   :options '((name string) (title string) (height integer) (width integer)
  64              (unsplittable boolean) (minibuffer boolean)
  65              (vertical-scroll-bars boolean))
  66   :group 'calendar)
  67
  68 (define-obsolete-variable-alias 'calendar-after-frame-setup-hooks
  69   'calendar-after-frame-setup-hook "23.1")
  70
  71 (defcustom calendar-after-frame-setup-hook nil
  72   "List of functions to be run after creating a calendar and/or diary frame."
  73   :type 'hook
  74   :group 'calendar-hooks)
  75
  76 ;;; End of user options.
  77
  78 (defvar calendar-frame nil
  79   "Frame in which the calendar was last displayed.")
  80
  81 (defvar diary-frame nil
  82   "Frame in which the diary was last displayed.")
  83
  84 (defun calendar-frame-1 (frame)
  85   "Subroutine used by `calendar-frame-setup'.
  86 Runs `calendar-after-frame-setup-hook', selects frame, iconifies if needed."
  87   (run-hooks 'calendar-after-frame-setup-hook)
  88   (select-frame frame)
  89   (if (eq 'icon (cdr (assoc 'visibility (frame-parameters frame))))
  90       (iconify-or-deiconify-frame)))
  91
  92 ;; c-d-d is only called after (diary) has been run.
  93 (defvar diary-display-function)
  94
  95 (defun calendar-dedicate-diary ()
  96   "Display and dedicate the window associated with the diary buffer."
  97   (set-window-dedicated-p
  98    (display-buffer
  99     (if (if (listp diary-display-function)
 100             (or (memq 'diary-fancy-display diary-display-function)
 101                 (memq 'fancy-diary-display diary-display-function))
 102           (memq diary-display-function '(diary-fancy-display
 103                                          fancy-diary-display)))
 104         (progn
 105           ;; If there are no diary entries, there won't be a fancy-diary
 106           ;; to dedicate, so make a basic one.
 107           (or (get-buffer diary-fancy-buffer)
 108               (calendar-in-read-only-buffer diary-fancy-buffer
 109                 (calendar-set-mode-line "Diary Entries")))
 110           diary-fancy-buffer)
 111       (get-file-buffer diary-file)))
 112    t))
 113
 114 ;;;###cal-autoload
 115 (defun calendar-frame-setup (config &optional prompt)
 116   "Display the calendar, and optionally the diary, in a separate frame.
 117 CONFIG should be one of:
 118 `calendar-only' - just the calendar, no diary
 119 `one-frame'     - calendar and diary in a single frame
 120 `two-frames'    - calendar and diary each in a separate frame
 121
 122 If CONFIG has any other value, or if the display is not capable of
 123 multiple frames, then `calendar-basic-setup' is called.
 124
 125 If PROMPT is non-nil, prompt for the month and year to use."
 126   (if (not (and (display-multi-frame-p)
 127                 (memq config '(calendar-only one-frame two-frames))))
 128       (calendar-basic-setup prompt)
 129     (if (frame-live-p calendar-frame) (delete-frame calendar-frame))
 130     (unless (eq config 'calendar-only)
 131       (if (frame-live-p diary-frame) (delete-frame diary-frame)))
 132     (let ((calendar-view-diary-initially-flag (eq config 'one-frame))
 133           ;; For calendar-dedicate-diary in two-frames case.
 134           (pop-up-windows nil))
 135       (save-window-excursion
 136         ;; Do diary first so that calendar is always left current.
 137         (when (eq config 'two-frames)
 138           (calendar-frame-1
 139            (setq diary-frame (make-frame diary-frame-parameters)))
 140           (diary)
 141           (calendar-dedicate-diary))
 142         (calendar-frame-1
 143          (setq calendar-frame
 144                (make-frame (if (eq config 'one-frame)
 145                                calendar-and-diary-frame-parameters
 146                              calendar-frame-parameters))))
 147         (calendar-basic-setup prompt (not (eq config 'one-frame)))
 148         (set-window-buffer (selected-window) calendar-buffer)
 149         (set-window-dedicated-p (selected-window) t)
 150         (if (eq config 'one-frame)
 151             (calendar-dedicate-diary))))))
 152
 153
 154 ;;;###cal-autoload
 155 (defun calendar-one-frame-setup (&optional prompt)
 156   "Display calendar and diary in a single dedicated frame.
 157 See `calendar-frame-setup' for more information."
 158   (declare (obsolete calendar-frame-setup "23.1"))
 159   (calendar-frame-setup 'one-frame prompt))
 160
 161 ;;;###cal-autoload
 162 (defun calendar-only-one-frame-setup (&optional prompt)
 163   "Display calendar in a dedicated frame.
 164 See `calendar-frame-setup' for more information."
 165   (declare (obsolete calendar-frame-setup "23.1"))
 166   (calendar-frame-setup 'calendar-only prompt))
 167
 168 ;;;###cal-autoload
 169 (defun calendar-two-frame-setup (&optional prompt)
 170   "Display calendar and diary in separate, dedicated frames.
 171 See `calendar-frame-setup' for more information."
 172   (declare (obsolete calendar-frame-setup "23.1"))
 173   (calendar-frame-setup 'two-frames prompt))
 174
 175 ;; Undocumented and probably useless.
 176 (defvar cal-x-load-hook nil
 177   "Hook run on loading of the `cal-x' package.")
 178 (make-obsolete-variable 'cal-x-load-hook "it will be removed in future." "23.1")
 179
 180 (run-hooks 'cal-x-load-hook)
 181
 182
 183 (provide 'cal-x)
 184
 185 ;;; cal-x.el ends here