lisp/calendar/cal-julian.el

   1 ;;; cal-julian.el --- calendar functions for the Julian calendar
   2
   3 ;; Copyright (C) 1995, 1997, 2001-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
   6 ;; Maintainer: Glenn Morris <rgm@gnu.org>
   7 ;; Keywords: calendar
   8 ;; Human-Keywords: Julian calendar, Julian day number, calendar, diary
   9 ;; Package: calendar
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; See calendar.el.
  29
  30 ;;; Code:
  31
  32 (require 'calendar)
  33
  34 (defun calendar-julian-to-absolute (date)
  35   "The number of days elapsed between the Gregorian date 12/31/1 BC and DATE.
  36 The Gregorian date Sunday, December 31, 1 BC is imaginary."
  37   (let ((month (calendar-extract-month date))
  38         (year (calendar-extract-year date)))
  39     (+ (calendar-day-number date)
  40        (if (and (zerop (% year 100))
  41                 (not (zerop (% year 400)))
  42                 (> month 2))
  43            1 0)       ; correct for Julian but not Gregorian leap year
  44        (* 365 (1- year))
  45        (/ (1- year) 4)
  46        -2)))
  47
  48 (define-obsolete-function-alias 'calendar-absolute-from-julian
  49   'calendar-julian-to-absolute "23.1")
  50
  51 ;;;###cal-autoload
  52 (defun calendar-julian-from-absolute (date)
  53   "Compute the Julian (month day year) corresponding to the absolute DATE.
  54 The absolute date is the number of days elapsed since the (imaginary)
  55 Gregorian date Sunday, December 31, 1 BC."
  56   (let* ((approx (/ (+ date 2) 366))    ; approximation from below
  57          (year                 ; search forward from the approximation
  58           (+ approx
  59              (calendar-sum y approx
  60                            (>= date (calendar-julian-to-absolute
  61                                      (list 1 1 (1+ y))))
  62                            1)))
  63          (month                         ; search forward from January
  64           (1+ (calendar-sum m 1
  65                             (> date
  66                                (calendar-julian-to-absolute
  67                                 (list m
  68                                       (if (and (= m 2) (zerop (% year 4)))
  69                                           29
  70                                         (aref [31 28 31 30 31 30 31
  71                                                   31 30 31 30 31]
  72                                               (1- m)))
  73                                       year)))
  74                             1)))
  75          (day                       ; calculate the day by subtraction
  76           (- date (1- (calendar-julian-to-absolute (list month 1 year))))))
  77     (list month day year)))
  78
  79 ;;;###cal-autoload
  80 (defun calendar-julian-date-string (&optional date)
  81   "String of Julian date of Gregorian DATE.
  82 Defaults to today's date if DATE is not given.
  83 Driven by the variable `calendar-date-display-form'."
  84   (calendar-date-string
  85    (calendar-julian-from-absolute
  86     (calendar-absolute-from-gregorian (or date (calendar-current-date))))
  87    nil t))
  88
  89 ;;;###cal-autoload
  90 (defun calendar-julian-print-date ()
  91   "Show the Julian calendar equivalent of the date under the cursor."
  92   (interactive)
  93   (message "Julian date: %s"
  94            (calendar-julian-date-string (calendar-cursor-to-date t))))
  95
  96 (define-obsolete-function-alias 'calendar-print-julian-date
  97   'calendar-julian-print-date "23.1")
  98
  99 ;;;###cal-autoload
 100 (defun calendar-julian-goto-date (date &optional noecho)
 101   "Move cursor to Julian DATE; echo Julian date unless NOECHO is non-nil."
 102   (interactive
 103    (let* ((today (calendar-current-date))
 104           (year (calendar-read
 105                  "Julian calendar year (>0): "
 106                  (lambda (x) (> x 0))
 107                  (number-to-string
 108                   (calendar-extract-year
 109                    (calendar-julian-from-absolute
 110                     (calendar-absolute-from-gregorian
 111                      today))))))
 112           (month-array calendar-month-name-array)
 113           (completion-ignore-case t)
 114           (month (cdr (assoc-string
 115                        (completing-read
 116                         "Julian calendar month name: "
 117                         (mapcar 'list (append month-array nil))
 118                         nil t)
 119                        (calendar-make-alist month-array 1) t)))
 120           (last
 121            (if (and (zerop (% year 4)) (= month 2))
 122                29
 123              (aref [31 28 31 30 31 30 31 31 30 31 30 31] (1- month))))
 124           (day (calendar-read
 125                 (format "Julian calendar day (%d-%d): "
 126                         (if (and (= year 1) (= month 1)) 3 1) last)
 127                 (lambda (x)
 128                   (and (< (if (and (= year 1) (= month 1)) 2 0) x)
 129                        (<= x last))))))
 130      (list (list month day year))))
 131   (calendar-goto-date (calendar-gregorian-from-absolute
 132                        (calendar-julian-to-absolute date)))
 133   (or noecho (calendar-julian-print-date)))
 134
 135 (define-obsolete-function-alias 'calendar-goto-julian-date
 136   'calendar-julian-goto-date "23.1")
 137
 138 ;;;###holiday-autoload
 139 (defun holiday-julian (month day string)
 140   "Holiday on MONTH, DAY (Julian) called STRING.
 141 If MONTH, DAY (Julian) is visible, the value returned is corresponding
 142 Gregorian date in the form of the list (((month day year) STRING)).  Returns
 143 nil if it is not visible in the current calendar window."
 144   (let ((gdate (calendar-nongregorian-visible-p
 145                 month day 'calendar-julian-to-absolute
 146                 'calendar-julian-from-absolute
 147                 ;; In the Gregorian case, we'd use the lower year when
 148                 ;; month >= 11. In the Julian case, there is an offset
 149                 ;; of two weeks (ie 1 Nov Greg = 19 Oct Julian). So we
 150                 ;; use month >= 10, since it can't cause any problems.
 151                 (lambda (m) (< m 10)))))
 152     (if gdate (list (list gdate string)))))
 153
 154 ;;;###cal-autoload
 155 (defun calendar-astro-to-absolute (d)
 156   "Absolute date of astronomical (Julian) day number D."
 157   (- d 1721424.5))
 158
 159 (define-obsolete-function-alias 'calendar-absolute-from-astro
 160   'calendar-astro-to-absolute "23.1")
 161
 162 ;;;###cal-autoload
 163 (defun calendar-astro-from-absolute (d)
 164   "Astronomical (Julian) day number of absolute date D."
 165   (+ d 1721424.5))
 166
 167 ;;;###cal-autoload
 168 (defun calendar-astro-date-string (&optional date)
 169   "String of astronomical (Julian) day number after noon UTC of Gregorian DATE.
 170 Defaults to today's date if DATE is not given."
 171   (number-to-string
 172    (ceiling
 173     (calendar-astro-from-absolute
 174      (calendar-absolute-from-gregorian (or date (calendar-current-date)))))))
 175
 176 ;;;###cal-autoload
 177 (defun calendar-astro-print-day-number ()
 178   "Show astronomical (Julian) day number after noon UTC on cursor date."
 179   (interactive)
 180   (message
 181    "Astronomical (Julian) day number (at noon UTC): %s.0"
 182    (calendar-astro-date-string (calendar-cursor-to-date t))))
 183
 184 (define-obsolete-function-alias 'calendar-print-astro-day-number
 185   'calendar-astro-print-day-number "23.1")
 186
 187 ;;;###cal-autoload
 188 (defun calendar-astro-goto-day-number (daynumber &optional noecho)
 189   "Move cursor to astronomical (Julian) DAYNUMBER.
 190 Echo astronomical (Julian) day number unless NOECHO is non-nil."
 191   (interactive (list (calendar-read
 192                       "Astronomical (Julian) day number (>1721425): "
 193                       (lambda (x) (> x 1721425)))))
 194   (calendar-goto-date
 195    (calendar-gregorian-from-absolute
 196     (floor
 197      (calendar-astro-to-absolute daynumber))))
 198   (or noecho (calendar-astro-print-day-number)))
 199
 200 (define-obsolete-function-alias 'calendar-goto-astro-day-number
 201   'calendar-astro-goto-day-number "23.1")
 202
 203 (defvar date)
 204
 205 ;; To be called from diary-list-sexp-entries, where DATE is bound.
 206 ;;;###diary-autoload
 207 (defun diary-julian-date ()
 208   "Julian calendar equivalent of date diary entry."
 209   (format "Julian date: %s" (calendar-julian-date-string date)))
 210
 211 ;; To be called from diary-list-sexp-entries, where DATE is bound.
 212 ;;;###diary-autoload
 213 (defun diary-astro-day-number ()
 214   "Astronomical (Julian) day number diary entry."
 215   (format "Astronomical (Julian) day number at noon UTC: %s.0"
 216           (calendar-astro-date-string date)))
 217
 218 (provide 'cal-julian)
 219
 220 ;;; cal-julian.el ends here