configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 gameuser=games
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 dnl _ON results in a '--without' option in the --help output, so
 151 dnl the help text should refer to "don't compile", etc.
 152 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 153 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 154 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 155 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 156 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 157 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 158 OPTION_DEFAULT_OFF([imagemagick],[compile with ImageMagick image support])
 159
 160 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 161 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 162 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 163
 164 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 165 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 166 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 167 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 168
 169 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 170 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 171 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 172 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 173
 174 ## For the times when you want to build Emacs but don't have
 175 ## a suitable makeinfo, and can live without the manuals.
 176 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 177 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 178
 179 ## This is an option because I do not know if all info/man support
 180 ## compressed files, nor how to test if they do so.
 181 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 182 if test $with_compress_info = yes; then
 183    GZIP_INFO=yes
 184 else
 185    GZIP_INFO=
 186 fi
 187 AC_SUBST(GZIP_INFO)
 188
 189 AC_ARG_WITH([pkg-config-prog],dnl
 190 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 191                   [path to pkg-config for finding GTK and librsvg])])
 192 if test "X${with_pkg_config_prog}" != X; then
 193    if test "${with_pkg_config_prog}" != yes; then
 194       PKG_CONFIG="${with_pkg_config_prog}"
 195    fi
 196 fi
 197
 198 CRT_DIR=
 199 AC_ARG_WITH([crt-dir],dnl
 200 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 201 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 202 CRT_DIR="${with_crt_dir}"
 203
 204 AC_ARG_WITH([gnustep-conf],dnl
 205 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 206 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 207   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 208 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 209      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 210
 211 AC_ARG_ENABLE(ns-self-contained,
 212 [AS_HELP_STRING([--disable-ns-self-contained],
 213                 [disable self contained build under NeXTstep])],
 214    EN_NS_SELF_CONTAINED=$enableval,
 215    EN_NS_SELF_CONTAINED=yes)
 216
 217 AC_ARG_ENABLE(asserts,
 218 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 219       USE_XASSERTS=$enableval,
 220       USE_XASSERTS=no)
 221
 222 AC_ARG_ENABLE(maintainer-mode,
 223 [AS_HELP_STRING([--enable-maintainer-mode],
 224                 [enable make rules and dependencies not useful (and sometimes
 225                  confusing) to the casual installer])],
 226       USE_MAINTAINER_MODE=$enableval,
 227       USE_MAINTAINER_MODE=no)
 228 if test $USE_MAINTAINER_MODE = yes; then
 229   MAINT=
 230 else
 231   MAINT=#
 232 fi
 233 AC_SUBST(MAINT)
 234
 235 AC_ARG_ENABLE(locallisppath,
 236 [AS_HELP_STRING([--enable-locallisppath=PATH],
 237                 [directories Emacs should search for lisp files specific
 238                  to this site])],
 239 if test "${enableval}" = "no"; then
 240   locallisppath=
 241 elif test "${enableval}" != "yes"; then
 242   locallisppath=${enableval}
 243 fi)
 244
 245 AC_ARG_ENABLE(checking,
 246 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 247                 [enable expensive run-time checks.  With LIST,
 248                  enable only specific categories of checks.
 249                  Categories are: all,yes,no.
 250                  Flags are: stringbytes, stringoverrun, stringfreelist,
 251                  xmallocoverrun, conslist])],
 252 [ac_checking_flags="${enableval}"],[])
 253 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 254 for check in $ac_checking_flags
 255 do
 256         case $check in
 257         # these set all the flags to specific states
 258         yes)            ac_enable_checking=1 ;;
 259         no)             ac_enable_checking= ;
 260                         ac_gc_check_stringbytes= ;
 261                         ac_gc_check_string_overrun= ;
 262                         ac_gc_check_string_free_list= ;
 263                         ac_xmalloc_overrun= ;
 264                         ac_gc_check_cons_list= ;;
 265         all)            ac_enable_checking=1 ;
 266                         ac_gc_check_stringbytes=1 ;
 267                         ac_gc_check_string_overrun=1 ;
 268                         ac_gc_check_string_free_list=1 ;
 269                         ac_xmalloc_overrun=1 ;
 270                         ac_gc_check_cons_list=1 ;;
 271         # these enable particular checks
 272         stringbytes)    ac_gc_check_stringbytes=1 ;;
 273         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 274         stringfreelist) ac_gc_check_string_free_list=1 ;;
 275         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 276         conslist)       ac_gc_check_cons_list=1 ;;
 277         *)      AC_MSG_ERROR(unknown check category $check) ;;
 278         esac
 279 done
 280 IFS="$ac_save_IFS"
 281
 282 if test x$ac_enable_checking != x ; then
 283   AC_DEFINE(ENABLE_CHECKING, 1,
 284 [Enable expensive run-time checking of data types?])
 285 fi
 286 if test x$ac_gc_check_stringbytes != x ; then
 287   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 288 [Define this temporarily to hunt a bug.  If defined, the size of
 289    strings is redundantly recorded in sdata structures so that it can
 290    be compared to the sizes recorded in Lisp strings.])
 291 fi
 292 if test x$ac_gc_check_stringoverrun != x ; then
 293   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 294 [Define this to check for short string overrun.])
 295 fi
 296 if test x$ac_gc_check_string_free_list != x ; then
 297   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 298 [Define this to check the string free list.])
 299 fi
 300 if test x$ac_xmalloc_overrun != x ; then
 301   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 302 [Define this to check for malloc buffer overrun.])
 303 fi
 304 if test x$ac_gc_check_cons_list != x ; then
 305   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 306 [Define this to check for errors in cons list.])
 307 fi
 308
 309 AC_ARG_ENABLE(use-lisp-union-type,
 310 [AS_HELP_STRING([--enable-use-lisp-union-type],
 311                 [use a union for the Lisp_Object data type.
 312                 This is only useful for development for catching certain types of bugs.])],
 313 if test "${enableval}" != "no"; then
 314    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 315    [Define this to use a lisp union for the Lisp_Object data type.])
 316 fi)
 317
 318
 319 AC_ARG_ENABLE(profiling,
 320 [AS_HELP_STRING([--enable-profiling],
 321                 [build emacs with profiling support.
 322                  This might not work on all platforms])],
 323 [ac_enable_profiling="${enableval}"],[])
 324 if test x$ac_enable_profiling != x ; then
 325    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 326    PROFILING_LDFLAGS="-pg"
 327 else
 328    PROFILING_CFLAGS=
 329    PROFILING_LDFLAGS=
 330 fi
 331 AC_SUBST(PROFILING_CFLAGS)
 332 AC_SUBST(PROFILING_LDFLAGS)
 333
 334 AC_ARG_ENABLE(autodepend,
 335 [AS_HELP_STRING([--enable-autodepend],
 336                 [automatically generate dependencies to .h-files.
 337                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 338                  found])],
 339 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 340
 341 #### Make srcdir absolute, if it isn't already.  It's important to
 342 #### avoid running the path through pwd unnecessarily, since pwd can
 343 #### give you automounter prefixes, which can go away.  We do all this
 344 #### so Emacs can find its files when run uninstalled.
 345 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 346 unset CDPATH
 347 case "${srcdir}" in
 348   /* ) ;;
 349   . )
 350     ## We may be able to use the $PWD environment variable to make this
 351     ## absolute.  But sometimes PWD is inaccurate.
 352     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 353     ## but that tested only for a well-formed and valid PWD,
 354     ## it did not object when PWD was well-formed and valid but just wrong.
 355     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 356     then
 357       srcdir="$PWD"
 358     else
 359       srcdir="`(cd ${srcdir}; pwd)`"
 360     fi
 361   ;;
 362   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 363 esac
 364
 365 #### Check if the source directory already has a configured system in it.
 366 if test `pwd` != `(cd ${srcdir} && pwd)` \
 367    && test -f "${srcdir}/src/config.h" ; then
 368   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 369    as a build directory right now; it has been configured in its own
 370    right.  To configure in another directory as well, you MUST
 371    use GNU make.  If you do not have GNU make, then you must
 372    now do `make distclean' in ${srcdir},
 373    and then run $0 again.]])
 374 fi
 375
 376 #### Given the configuration name, set machfile and opsysfile to the
 377 #### names of the m/*.h and s/*.h files we should use.
 378
 379 ### Canonicalize the configuration name.
 380
 381 AC_CANONICAL_HOST
 382 canonical=$host
 383 configuration=${host_alias-${build_alias-$host}}
 384
 385 dnl This used to use changequote, but, apart from `changequote is evil'
 386 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 387 dnl the great gob of text.  Thus it's not processed for possible expansion.
 388 dnl Just make sure the brackets remain balanced.
 389 dnl
 390 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 391 dnl indicated by comments.
 392 dnl quotation begins
 393 [
 394
 395 ### If you add support for a new configuration, add code to this
 396 ### switch statement to recognize your configuration name and select
 397 ### the appropriate operating system and machine description files.
 398
 399 ### You would hope that you could choose an m/*.h file pretty much
 400 ### based on the machine portion of the configuration name, and an s/*.h
 401 ### file based on the operating system portion.  However, it turns out
 402 ### that each m/*.h file is pretty manufacturer-specific - for
 403 ### example mips.h is MIPS
 404 ### So we basically have to have a special case for each
 405 ### configuration name.
 406 ###
 407 ### As far as handling version numbers on operating systems is
 408 ### concerned, make sure things will fail in a fixable way.  If
 409 ### /etc/MACHINES doesn't say anything about version numbers, be
 410 ### prepared to handle anything reasonably.  If version numbers
 411 ### matter, be sure /etc/MACHINES says something about it.
 412
 413 machine='' opsys='' unported=no
 414 case "${canonical}" in
 415
 416   ## FreeBSD ports
 417   *-*-freebsd* )
 418     opsys=freebsd
 419     case "${canonical}" in
 420       alpha*)           machine=alpha ;;
 421       amd64-*|x86_64-*) machine=amdx86-64 ;;
 422       arm*)             machine=arm ;;
 423       ia64-*)           machine=ia64 ;;
 424       i[3456]86-*)      machine=intel386 ;;
 425       powerpc-*)        machine=macppc ;;
 426       sparc-*)          machine=sparc ;;
 427       sparc64-*)        machine=sparc ;;
 428     esac
 429   ;;
 430
 431   ## FreeBSD kernel + glibc based userland
 432   *-*-kfreebsd*gnu* )
 433     opsys=gnu-kfreebsd
 434     case "${canonical}" in
 435       alpha*)           machine=alpha ;;
 436       amd64-*|x86_64-*) machine=amdx86-64 ;;
 437       ia64-*)           machine=ia64 ;;
 438       i[3456]86-*)      machine=intel386 ;;
 439       powerpc-*)        machine=macppc ;;
 440       sparc-*)          machine=sparc ;;
 441       sparc64-*)        machine=sparc ;;
 442     esac
 443   ;;
 444
 445   ## NetBSD ports
 446   *-*-netbsd* )
 447     opsys=netbsd
 448     case "${canonical}" in
 449       alpha*)      machine=alpha ;;
 450       x86_64-*)    machine=amdx86-64 ;;
 451       arm-*)       machine=arm ;;
 452       hppa-*)      machine=hp800 ;;
 453       i[3456]86-*) machine=intel386 ;;
 454       m68k-*)      machine=m68k ;;
 455       powerpc-*)   machine=macppc ;;
 456       mips-*)      machine=mips ;;
 457       mipse[bl]-*) machine=mips ;;
 458       sparc*-)     machine=sparc ;;
 459       vax-*)       machine=vax ;;
 460     esac
 461   ;;
 462
 463   ## OpenBSD ports
 464   *-*-openbsd* )
 465     opsys=openbsd
 466     case "${canonical}" in
 467       alpha*)    machine=alpha ;;
 468       x86_64-*)  machine=amdx86-64 ;;
 469       arm-*)     machine=arm ;;
 470       hppa-*)    machine=hp800 ;;
 471       i386-*)    machine=intel386 ;;
 472       powerpc-*) machine=macppc ;;
 473       sparc*)    machine=sparc ;;
 474       vax-*)     machine=vax ;;
 475     esac
 476   ;;
 477
 478   alpha*-*-linux-gnu* )
 479     machine=alpha opsys=gnu-linux
 480   ;;
 481
 482   arm*-*-linux-gnu* )
 483     machine=arm opsys=gnu-linux
 484   ;;
 485
 486   ## Apple Darwin / Mac OS X
 487   *-apple-darwin* )
 488     case "${canonical}" in
 489       i[3456]86-* )  machine=intel386 ;;
 490       powerpc-* )    machine=macppc ;;
 491       x86_64-* )     machine=amdx86-64 ;;
 492       * )            unported=yes ;;
 493     esac
 494     opsys=darwin
 495     # Define CPP as follows to make autoconf work correctly.
 496     CPP="${CC-cc} -E -no-cpp-precomp"
 497     # Use fink packages if available.
 498     if test -d /sw/include && test -d /sw/lib; then
 499       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 500       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 501       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 502     fi
 503   ;;
 504
 505   ## HP 9000 series 700 and 800, running HP/UX
 506   hppa*-hp-hpux10.2* )
 507     machine=hp800 opsys=hpux10-20
 508   ;;
 509   hppa*-hp-hpux1[1-9]* )
 510     machine=hp800 opsys=hpux11
 511     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 512   ;;
 513
 514   hppa*-*-linux-gnu* )
 515     machine=hp800 opsys=gnu-linux
 516   ;;
 517
 518   ## IBM machines
 519   s390-*-linux-gnu* )
 520     machine=ibms390 opsys=gnu-linux
 521   ;;
 522   s390x-*-linux-gnu* )
 523     machine=ibms390x opsys=gnu-linux
 524   ;;
 525   rs6000-ibm-aix4.[23]* )
 526     machine=ibmrs6000 opsys=aix4-2
 527   ;;
 528   powerpc-ibm-aix4.[23]*  )
 529     machine=ibmrs6000 opsys=aix4-2
 530   ;;
 531   rs6000-ibm-aix[56]* )
 532     machine=ibmrs6000 opsys=aix4-2
 533   ;;
 534   powerpc-ibm-aix[56]*  )
 535     machine=ibmrs6000 opsys=aix4-2
 536   ;;
 537
 538   ## Macintosh PowerPC
 539   powerpc*-*-linux-gnu* )
 540     machine=macppc opsys=gnu-linux
 541   ;;
 542
 543   ## Silicon Graphics machines
 544   ## Iris 4D
 545   mips-sgi-irix6.5 )
 546     machine=iris4d opsys=irix6-5
 547     # Without defining _LANGUAGE_C, things get masked out in the headers
 548     # so that, for instance, grepping for `free' in stdlib.h fails and
 549     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 550     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 551     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 552   ;;
 553
 554   ## Suns
 555   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 556     machine=sparc opsys=gnu-linux
 557   ;;
 558
 559   *-sun-solaris* \
 560     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 561     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 562     case "${canonical}" in
 563       i[3456]86-*-* )     machine=intel386 ;;
 564       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 565       sparc* )          machine=sparc ;;
 566       * )               unported=yes ;;
 567     esac
 568     case "${canonical}" in
 569       *-sunos5.6* | *-solaris2.6* )
 570                 opsys=sol2-6
 571                 NON_GNU_CPP=/usr/ccs/lib/cpp
 572                 RANLIB="ar -ts"
 573                 ;;
 574       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 575                 opsys=sol2-6
 576                 emacs_check_sunpro_c=yes
 577                 NON_GNU_CPP=/usr/ccs/lib/cpp
 578                 ;;
 579       *-sunos5* | *-solaris* )
 580                 opsys=sol2-10
 581                 emacs_check_sunpro_c=yes
 582                 NON_GNU_CPP=/usr/ccs/lib/cpp
 583                 ;;
 584     esac
 585     ## Watch out for a compiler that we know will not work.
 586     case "${canonical}" in
 587      *-solaris* | *-sunos5* )
 588                 if [ "x$CC" = x/usr/ucb/cc ]; then
 589                   ## /usr/ucb/cc doesn't work;
 590                   ## we should find some other compiler that does work.
 591                   unset CC
 592                 fi
 593                 ;;
 594       *) ;;
 595     esac
 596   ;;
 597
 598   ## IA-64
 599   ia64*-*-linux* )
 600     machine=ia64 opsys=gnu-linux
 601   ;;
 602
 603   ## Intel 386 machines where we don't care about the manufacturer.
 604   i[3456]86-*-* )
 605     machine=intel386
 606     case "${canonical}" in
 607       *-cygwin )                opsys=cygwin ;;
 608       *-darwin* )               opsys=darwin
 609                                 CPP="${CC-cc} -E -no-cpp-precomp"
 610                                 ;;
 611       *-linux-gnu* )            opsys=gnu-linux ;;
 612       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 613       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 614       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 615       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 616     esac
 617   ;;
 618
 619   ## m68k Linux-based GNU system
 620   m68k-*-linux-gnu* )
 621     machine=m68k opsys=gnu-linux
 622   ;;
 623
 624   ## Mips Linux-based GNU system
 625   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 626     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 627     machine=mips opsys=gnu-linux
 628   ;;
 629
 630   ## AMD x86-64 Linux-based GNU system
 631   x86_64-*-linux-gnu* )
 632     machine=amdx86-64 opsys=gnu-linux
 633   ;;
 634
 635   ## Tensilica Xtensa Linux-based GNU system
 636   xtensa*-*-linux-gnu* )
 637     machine=xtensa opsys=gnu-linux
 638     ;;
 639
 640   ## SuperH Linux-based GNU system
 641   sh[34]*-*-linux-gnu* )
 642     machine=sh3 opsys=gnu-linux
 643   ;;
 644
 645   * )
 646     unported=yes
 647   ;;
 648 esac
 649
 650 ### If the code above didn't choose an operating system, just choose
 651 ### an operating system based on the configuration name.  You really
 652 ### only want to use this when you have no idea what the right
 653 ### operating system is; if you know what operating systems a machine
 654 ### runs, it's cleaner to make it explicit in the case statement
 655 ### above.
 656 if test x"${opsys}" = x; then
 657   case "${canonical}" in
 658     *-gnu* )                            opsys=gnu ;;
 659     * )
 660       unported=yes
 661     ;;
 662   esac
 663 fi
 664
 665 ]
 666 dnl quotation ends
 667
 668 if test $unported = yes; then
 669   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 670 Check `etc/MACHINES' for recognized configuration names.])
 671 fi
 672
 673 machfile="m/${machine}.h"
 674 opsysfile="s/${opsys}.h"
 675
 676
 677 #### Choose a compiler.
 678 test -n "$CC" && cc_specified=yes
 679
 680 # Save the value of CFLAGS that the user specified.
 681 SPECIFIED_CFLAGS="$CFLAGS"
 682
 683 dnl Sets GCC=yes if using gcc.
 684 AC_PROG_CC
 685
 686 # On Suns, sometimes $CPP names a directory.
 687 if test -n "$CPP" && test -d "$CPP"; then
 688   CPP=
 689 fi
 690
 691 ## If not using gcc, and on Solaris, and no CPP specified, see if
 692 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 693 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 694  test x"$CPP" = x; then
 695   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 696   AC_CACHE_VAL(emacs_cv_sunpro_c,
 697   [AC_TRY_LINK([],
 698 [#ifndef __SUNPRO_C
 699 fail;
 700 #endif
 701 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 702   AC_MSG_RESULT($emacs_cv_sunpro_c)
 703
 704   if test x"$emacs_cv_sunpro_c" = xyes; then
 705     NON_GNU_CPP="$CC -E -Xs"
 706   fi
 707 fi
 708
 709 #### Some systems specify a CPP to use unless we are using GCC.
 710 #### Now that we know whether we are using GCC, we can decide whether
 711 #### to use that one.
 712 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 713 then
 714   CPP="$NON_GNU_CPP"
 715 fi
 716
 717 #### Some systems specify a CC to use unless we are using GCC.
 718 #### Now that we know whether we are using GCC, we can decide whether
 719 #### to use that one.
 720 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 721   test x$cc_specified != xyes
 722 then
 723   CC="$NON_GNU_CC"
 724 fi
 725
 726 if test x$GCC = xyes; then
 727   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 728 else
 729   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 730 fi
 731
 732 dnl checks for Unix variants
 733 AC_USE_SYSTEM_EXTENSIONS
 734
 735 ### Use -Wno-pointer-sign if the compiler supports it
 736 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 737 SAVE_CFLAGS="$CFLAGS"
 738 CFLAGS="$CFLAGS -Wno-pointer-sign"
 739 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 740 if test $has_option = yes; then
 741    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 742 fi
 743 AC_MSG_RESULT($has_option)
 744 CFLAGS="$SAVE_CFLAGS"
 745 unset has_option
 746 unset SAVE_CFLAGS
 747
 748 ### Use -Wdeclaration-after-statement if the compiler supports it
 749 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 750 SAVE_CFLAGS="$CFLAGS"
 751 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 752 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 753 if test $has_option = yes; then
 754    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 755 fi
 756 AC_MSG_RESULT($has_option)
 757 CFLAGS="$SAVE_CFLAGS"
 758 unset has_option
 759 unset SAVE_CFLAGS
 760
 761 ### Use -Wold-style-definition if the compiler supports it
 762 # This can be removed when conversion to standard C is finished.
 763 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 764 SAVE_CFLAGS="$CFLAGS"
 765 CFLAGS="$CFLAGS -Wold-style-definition"
 766 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 767 if test $has_option = yes; then
 768    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 769 fi
 770 AC_MSG_RESULT($has_option)
 771 CFLAGS="$SAVE_CFLAGS"
 772 unset has_option
 773 unset SAVE_CFLAGS
 774
 775 ### Use -Wimplicit-function-declaration if the compiler supports it
 776 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 777 SAVE_CFLAGS="$CFLAGS"
 778 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 779 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 780 if test $has_option = yes; then
 781    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 782 fi
 783 AC_MSG_RESULT($has_option)
 784 CFLAGS="$SAVE_CFLAGS"
 785 unset has_option
 786 unset SAVE_CFLAGS
 787
 788 AC_SUBST(C_WARNINGS_SWITCH)
 789
 790
 791 #### Some other nice autoconf tests.
 792
 793 dnl checks for programs
 794 AC_PROG_CPP
 795 AC_PROG_INSTALL
 796 if test "x$RANLIB" = x; then
 797   AC_PROG_RANLIB
 798 fi
 799
 800 ## Although we're running on an amd64 kernel, we're actually compiling for
 801 ## the x86 architecture.  The user should probably have provided an
 802 ## explicit --build to `configure', but if everything else than the kernel
 803 ## is running in i386 mode, we can help them out.
 804 if test "$machine" = "amdx86-64"; then
 805   AC_CHECK_DECL([i386])
 806   if test "$ac_cv_have_decl_i386" = "yes"; then
 807     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 808     machine=intel386
 809     machfile="m/${machine}.h"
 810   fi
 811 fi
 812
 813 AC_PATH_PROG(INSTALL_INFO, install-info)
 814 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 815 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 816 dnl Don't use GZIP, which is used by gzip for additional parameters.
 817 AC_PATH_PROG(GZIP_PROG, gzip)
 818
 819
 820 ## Need makeinfo >= 4.6 (?) to build the manuals.
 821 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 822 dnl By this stage, configure has already checked for egrep and set EGREP,
 823 dnl or exited with an error if no egrep was found.
 824 if test "$MAKEINFO" != "no" && \
 825   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 826    MAKEINFO=no
 827 fi
 828
 829 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 830 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 831 ## therefore in the category of "special tools" not normally required, which
 832 ## configure does not have to check for (eg autoconf itself).
 833 ## In a Bazaar checkout on the other hand, the manuals are not included.
 834 ## So makeinfo is a requirement to build from Bazaar, and configure
 835 ## should test for it as it does for any other build requirement.
 836 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 837 ## with pre-built manuals, from a Bazaar checkout.
 838 if test "$MAKEINFO" = "no"; then
 839   if test "x${with_makeinfo}" = "xno"; then
 840     MAKEINFO=off
 841   elif test ! -e $srcdir/info/emacs; then
 842     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 843 source tree does not seem to have pre-built manuals in the `info' directory.
 844 Either install a suitable version of makeinfo, or re-run configure
 845 with the `--without-makeinfo' option to build without the manuals.] )
 846   fi
 847 fi
 848
 849 dnl Add our options to ac_link now, after it is set up.
 850
 851 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 852 then
 853   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 854 fi
 855
 856 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 857 then
 858   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 859 fi
 860
 861 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 862 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 863 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 864 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 865 dnl if not built to support GNU ld.
 866
 867 late_LDFLAGS=$LDFLAGS
 868 if test "$GCC" = yes; then
 869   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 870 else
 871   LDFLAGS="$LDFLAGS -znocombreloc"
 872 fi
 873
 874 AC_MSG_CHECKING([for -znocombreloc])
 875 AC_LINK_IFELSE([main(){return 0;}],
 876   [AC_MSG_RESULT(yes)],
 877   LDFLAGS=$late_LDFLAGS
 878   [AC_MSG_RESULT(no)])
 879
 880
 881 # The value of CPP is a quoted variable reference, so we need to do this
 882 # to get its actual value...
 883 CPP=`eval "echo $CPP"`
 884
 885
 886 dnl Not used by any currently supported platform.
 887 dnl The function dump-emacs will not be defined and temacs will do
 888 dnl (load "loadup") automatically unless told otherwise.
 889 CANNOT_DUMP=no
 890 case "$opsys" in
 891   your-opsys-here)
 892    CANNOT_DUMP=yes
 893    AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 894   ;;
 895 esac
 896 AC_SUBST(CANNOT_DUMP)
 897
 898
 899 UNEXEC_OBJ=unexelf.o
 900 case "$opsys" in
 901   # MSDOS uses unexcoff.o
 902   # MSWindows uses unexw32.o
 903   aix4-2)
 904    UNEXEC_OBJ=unexaix.o
 905    ;;
 906   cygwin)
 907    UNEXEC_OBJ=unexcw.o
 908    ;;
 909   darwin)
 910    UNEXEC_OBJ=unexmacosx.o
 911    ;;
 912   hpux10-20 | hpux11)
 913    UNEXEC_OBJ=unexhp9k800.o
 914    ;;
 915   sol2-10)
 916    # Use the Solaris dldump() function, called from unexsol.c, to dump
 917    # emacs, instead of the generic ELF dump code found in unexelf.c.
 918    # The resulting binary has a complete symbol table, and is better
 919    # for debugging and other observability tools (debuggers, pstack, etc).
 920    #
 921    # If you encounter a problem using dldump(), please consider sending
 922    # a message to the OpenSolaris tools-linking mailing list:
 923    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 924    #
 925    # It is likely that dldump() works with older Solaris too, but this has
 926    # not been tested, so for now this change is for Solaris 10 or newer.
 927    UNEXEC_OBJ=unexsol.o
 928    ;;
 929 esac
 930
 931 LD_SWITCH_SYSTEM=
 932 case "$opsys" in
 933   freebsd)
 934    ## Let `ld' find image libs and similar things in /usr/local/lib.
 935    ## The system compiler, GCC, has apparently been modified to not
 936    ## look there, contrary to what a stock GCC would do.
 937    LD_SWITCH_SYSTEM=-L/usr/local/lib
 938    ;;
 939
 940   gnu-linux)
 941    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 942    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 943    ;;
 944
 945   netbsd)
 946    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 947    ;;
 948
 949   openbsd)
 950    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 951    ## otherwise Emacs dumps core on elf systems.
 952    LD_SWITCH_SYSTEM="-Z"
 953    ;;
 954 esac
 955 AC_SUBST(LD_SWITCH_SYSTEM)
 956
 957 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 958
 959 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 960 ## which has not been defined yet.  When this was handled with cpp,
 961 ## it was expanded to null when configure sourced the s/*.h file.
 962 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 963 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 964 ## (or somesuch), but because it is supposed to go at the _front_
 965 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 966 ## Compare with the gnu-linux case below, which added to the end
 967 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 968 ## LD_SWITCH_SYSTEM_TEMACS.
 969 case "$opsys" in
 970   netbsd|openbsd)
 971    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 972    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 973 esac
 974
 975
 976 C_SWITCH_MACHINE=
 977 if test "$machine" = "alpha"; then
 978   AC_CHECK_DECL([__ELF__])
 979   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 980     ## With ELF, make sure that all common symbols get allocated to in the
 981     ## data section.  Otherwise, the dump of temacs may miss variables in
 982     ## the shared library that have been initialized.  For example, with
 983     ## GNU libc, __malloc_initialized would normally be resolved to the
 984     ## shared library's .bss section, which is fatal.
 985     if test "x$GCC" = "xyes"; then
 986       C_SWITCH_MACHINE="-fno-common"
 987     else
 988       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 989     fi
 990   else
 991     UNEXEC_OBJ=unexalpha.o
 992   fi
 993 fi
 994 AC_SUBST(C_SWITCH_MACHINE)
 995
 996 AC_SUBST(UNEXEC_OBJ)
 997
 998 C_SWITCH_SYSTEM=
 999 ## Some programs in src produce warnings saying certain subprograms
1000 ## are too complex and need a MAXMEM value greater than 2000 for
1001 ## additional optimization.  --nils@exp-math.uni-essen.de
1002 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1003   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1004 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1005 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1006 AC_SUBST(C_SWITCH_SYSTEM)
1007
1008
1009 LIBS_SYSTEM=
1010 case "$opsys" in
1011   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1012   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1013
1014   freebsd) LIBS_SYSTEM="-lutil" ;;
1015
1016   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1017
1018   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1019
1020   ## Motif needs -lgen.
1021   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1022 esac
1023 AC_SUBST(LIBS_SYSTEM)
1024
1025
1026 ### Make sure subsequent tests use flags consistent with the build flags.
1027
1028 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1029   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1030 else
1031   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1032 fi
1033
1034 dnl For AC_FUNC_GETLOADAVG, at least:
1035 AC_CONFIG_LIBOBJ_DIR(src)
1036
1037 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1038 AC_SYS_LARGEFILE
1039
1040
1041 ## If user specified a crt-dir, use that unconditionally.
1042 if test "X$CRT_DIR" = "X"; then
1043
1044   case "$canonical" in
1045     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1046     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1047     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1048     ## For anything else (eg /usr/lib32), it is up the user to specify
1049     ## the location (bug#5655).
1050     ## Test for crtn.o, not just the directory, because sometimes the
1051     ## directory exists but does not have the relevant files (bug#1287).
1052     ## FIXME better to test for binary compatibility somehow.
1053     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1054     ;;
1055
1056     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1057   esac
1058
1059   case "$opsys" in
1060     hpux10-20) CRT_DIR=/lib ;;
1061   esac
1062
1063   ## Default is /usr/lib.
1064   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1065
1066 else
1067
1068   ## Some platforms don't use any of these files, so it is not
1069   ## appropriate to put this test outside the if block.
1070   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1071     AC_MSG_ERROR([crt*.o not found in specified location.])
1072
1073 fi
1074
1075 AC_SUBST(CRT_DIR)
1076
1077 LIB_MATH=-lm
1078 LIB_STANDARD=
1079 START_FILES=
1080
1081 case $opsys in
1082   cygwin )
1083     LIB_MATH=
1084     START_FILES='pre-crt0.o'
1085     ;;
1086   darwin )
1087     ## Adding -lm confuses the dynamic linker, so omit it.
1088     LIB_MATH=
1089     START_FILES='pre-crt0.o'
1090     ;;
1091   freebsd )
1092     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1093     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1094     ;;
1095   gnu-linux | gnu-kfreebsd )
1096     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1097     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1098     ;;
1099   hpux10-20 | hpux11 )
1100     LIB_STANDARD=-lc
1101     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1102     ;;
1103   netbsd | openbsd )
1104     if test -f $CRT_DIR/crti.o; then
1105         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1106         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1107     else
1108         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1109         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1110     fi
1111     ;;
1112 esac
1113
1114 AC_SUBST(LIB_MATH)
1115 AC_SUBST(START_FILES)
1116
1117 dnl This function definition taken from Gnome 2.0
1118 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1119 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1120 dnl also defines GSTUFF_PKG_ERRORS on error
1121 AC_DEFUN([PKG_CHECK_MODULES], [
1122   succeeded=no
1123
1124   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1125
1126   if test "$PKG_CONFIG" = "no" ; then
1127      ifelse([$4], , [AC_MSG_ERROR([
1128       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1129   else
1130      PKG_CONFIG_MIN_VERSION=0.9.0
1131      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1132         AC_MSG_CHECKING(for $2)
1133
1134         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1135             AC_MSG_RESULT(yes)
1136             succeeded=yes
1137
1138             AC_MSG_CHECKING($1_CFLAGS)
1139             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1140             AC_MSG_RESULT($$1_CFLAGS)
1141
1142             AC_MSG_CHECKING($1_LIBS)
1143             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1144             AC_MSG_RESULT($$1_LIBS)
1145         else
1146             AC_MSG_RESULT(no)
1147             $1_CFLAGS=""
1148             $1_LIBS=""
1149             ## If we have a custom action on failure, don't print errors, but
1150             ## do set a variable so people can do so.
1151             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1152             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1153         fi
1154
1155         AC_SUBST($1_CFLAGS)
1156         AC_SUBST($1_LIBS)
1157      else
1158         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1159         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1160      fi
1161   fi
1162
1163   if test $succeeded = yes; then
1164      ifelse([$3], , :, [$3])
1165   else
1166      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1167   fi
1168 ])
1169
1170
1171 if test "${with_sound}" != "no"; then
1172   # Sound support for GNU/Linux and the free BSDs.
1173   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1174     have_sound_header=yes)
1175   # Emulation library used on NetBSD.
1176   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1177   AC_SUBST(LIBSOUND)
1178
1179   ALSA_REQUIRED=1.0.0
1180   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1181   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1182   if test $HAVE_ALSA = yes; then
1183     SAVE_CFLAGS="$CFLAGS"
1184     SAVE_LDFLAGS="$LDFLAGS"
1185     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1186     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1187     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1188                     emacs_alsa_normal=yes,
1189                     emacs_alsa_normal=no)
1190     if test "$emacs_alsa_normal" != yes; then
1191       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1192                      [snd_lib_error_set_handler (0);],
1193                      emacs_alsa_subdir=yes,
1194                      emacs_alsa_subdir=no)
1195       if test "$emacs_alsa_subdir" != yes; then
1196         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1197       fi
1198       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1199     fi
1200
1201     CFLAGS="$SAVE_CFLAGS"
1202     LDFLAGS="$SAVE_LDFLAGS"
1203     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1204     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1205     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1206   fi
1207
1208   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1209   dnl compiles only on the specified platforms.  For others, it
1210   dnl probably doesn't make sense to try.
1211   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1212      case "$opsys" in
1213        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1214        gnu-linux|freebsd|netbsd)
1215          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1216          ;;
1217      esac
1218   fi
1219
1220   AC_SUBST(CFLAGS_SOUND)
1221 fi
1222
1223 dnl checks for header files
1224 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1225   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1226   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1227   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1228   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1229
1230 AC_MSG_CHECKING(if personality LINUX32 can be set)
1231 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1232                emacs_cv_personality_linux32=yes,
1233                emacs_cv_personality_linux32=no)
1234 AC_MSG_RESULT($emacs_cv_personality_linux32)
1235
1236 if test $emacs_cv_personality_linux32 = yes; then
1237   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1238             [Define to 1 if personality LINUX32 can be set.])
1239 fi
1240
1241 dnl On Solaris 8 there's a compilation warning for term.h because
1242 dnl it doesn't define `bool'.
1243 AC_CHECK_HEADERS(term.h, , , -)
1244 AC_HEADER_STDC
1245 AC_HEADER_TIME
1246 AC_CHECK_DECLS([sys_siglist])
1247 if test $ac_cv_have_decl_sys_siglist != yes; then
1248   # For Tru64, at least:
1249   AC_CHECK_DECLS([__sys_siglist])
1250   if test $ac_cv_have_decl___sys_siglist = yes; then
1251     AC_DEFINE(sys_siglist, __sys_siglist,
1252               [Define to any substitute for sys_siglist.])
1253   fi
1254 fi
1255 AC_HEADER_SYS_WAIT
1256
1257 dnl Some systems have utime.h but don't declare the struct anyplace.
1258 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1259 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1260 #include <sys/time.h>
1261 #include <time.h>
1262 #else
1263 #ifdef HAVE_SYS_TIME_H
1264 #include <sys/time.h>
1265 #else
1266 #include <time.h>
1267 #endif
1268 #endif
1269 #ifdef HAVE_UTIME_H
1270 #include <utime.h>
1271 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1272   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1273 if test $emacs_cv_struct_utimbuf = yes; then
1274   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1275 fi
1276
1277 dnl checks for typedefs
1278 AC_TYPE_SIGNAL
1279
1280 dnl Check for speed_t typedef.
1281 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1282   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1283     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1284 if test $emacs_cv_speed_t = yes; then
1285   AC_DEFINE(HAVE_SPEED_T, 1,
1286            [Define to 1 if `speed_t' is declared by <termios.h>.])
1287 fi
1288
1289 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1290 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1291 #include <sys/time.h>
1292 #include <time.h>
1293 #else
1294 #ifdef HAVE_SYS_TIME_H
1295 #include <sys/time.h>
1296 #else
1297 #include <time.h>
1298 #endif
1299 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1300   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1301 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1302 if test $emacs_cv_struct_timeval = yes; then
1303   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1304 fi
1305
1306 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1307 AC_TRY_COMPILE([#include <math.h>],
1308 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1309   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1310 HAVE_EXCEPTION=$emacs_cv_struct_exception
1311 if test $emacs_cv_struct_exception != yes; then
1312   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1313 fi
1314
1315 AC_CHECK_HEADERS(sys/socket.h)
1316 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1317 #if HAVE_SYS_SOCKET_H
1318 #include <sys/socket.h>
1319 #endif])
1320
1321 dnl checks for structure members
1322 AC_STRUCT_TM
1323 AC_STRUCT_TIMEZONE
1324 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1325                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1326                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1327                 [#include <time.h>])
1328 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1329                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1330                   struct ifreq.ifr_addr], , ,
1331                  [AC_INCLUDES_DEFAULT
1332 #if HAVE_SYS_SOCKET_H
1333 #include <sys/socket.h>
1334 #endif
1335 #if HAVE_NET_IF_H
1336 #include <net/if.h>
1337 #endif])
1338
1339 dnl checks for compiler characteristics
1340
1341 dnl Testing __STDC__ to determine prototype support isn't good enough.
1342 dnl DEC C, for instance, doesn't define it with default options, and
1343 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1344 dnl and void *.
1345 AC_C_PROTOTYPES
1346 AC_C_VOLATILE
1347 AC_C_CONST
1348 dnl This isn't useful because we can't turn on use of `inline' unless
1349 dnl the compiler groks `extern inline'.
1350 dnl AC_C_INLINE
1351 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1352   [AC_TRY_COMPILE(, [void * foo;],
1353                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1354 if test $emacs_cv_void_star = yes; then
1355   AC_DEFINE(POINTER_TYPE, void)
1356 else
1357   AC_DEFINE(POINTER_TYPE, char)
1358 fi
1359 AH_TEMPLATE(POINTER_TYPE,
1360             [Define as `void' if your compiler accepts `void *'; otherwise
1361              define as `char'.])dnl
1362
1363 dnl Check for endianess
1364 AC_C_BIGENDIAN
1365
1366 dnl check for Make feature
1367 AC_PROG_MAKE_SET
1368
1369 DEPFLAGS=
1370 MKDEPDIR=":"
1371 deps_frag=deps.mk
1372 dnl check for GNU Make if we have GCC and autodepend is on.
1373 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1374    AC_MSG_CHECKING([whether we are using GNU Make])
1375    HAVE_GNU_MAKE=no
1376    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1377    if test "x$testval" != x; then
1378       HAVE_GNU_MAKE=yes
1379    else
1380       ac_enable_autodepend=no
1381    fi
1382    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1383    if test $HAVE_GNU_MAKE = yes; then
1384       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1385       SAVE_CFLAGS="$CFLAGS"
1386       CFLAGS="$CFLAGS -MMD -MF deps.d"
1387       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1388       CFLAGS="$SAVE_CFLAGS"
1389       test -f deps.d || ac_enable_autodepend=no
1390       rm -rf deps.d
1391       AC_MSG_RESULT([$ac_enable_autodepend])
1392    fi
1393    if test $ac_enable_autodepend = yes; then
1394       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1395       ## In parallel builds, another make might create depdir between
1396       ## the first test and mkdir, so stick another test on the end.
1397       ## Or use mkinstalldirs?  mkdir -p is not portable.
1398       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1399       deps_frag=autodeps.mk
1400    fi
1401 fi
1402 deps_frag=$srcdir/src/$deps_frag
1403 AC_SUBST(MKDEPDIR)
1404 AC_SUBST(DEPFLAGS)
1405 AC_SUBST_FILE(deps_frag)
1406
1407
1408 dnl checks for operating system services
1409 AC_SYS_LONG_FILE_NAMES
1410
1411 #### Choose a window system.
1412
1413 AC_PATH_X
1414 if test "$no_x" = yes; then
1415   window_system=none
1416 else
1417   window_system=x11
1418 fi
1419
1420 ## Workaround for bug in autoconf <= 2.62.
1421 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1422 ## No need to do anything special for these standard directories.
1423 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1424
1425    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1426
1427 fi
1428
1429 LD_SWITCH_X_SITE_AUX=
1430 LD_SWITCH_X_SITE_AUX_RPATH=
1431 if test "${x_libraries}" != NONE; then
1432   if test -n "${x_libraries}"; then
1433     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1434     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1435     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1436   fi
1437   x_default_search_path=""
1438   x_search_path=${x_libraries}
1439   if test -z "${x_search_path}"; then
1440     x_search_path=/usr/lib
1441   fi
1442   for x_library in `echo ${x_search_path}: | \
1443                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1444     x_search_path="\
1445 ${x_library}/X11/%L/%T/%N%C%S:\
1446 ${x_library}/X11/%l/%T/%N%C%S:\
1447 ${x_library}/X11/%T/%N%C%S:\
1448 ${x_library}/X11/%L/%T/%N%S:\
1449 ${x_library}/X11/%l/%T/%N%S:\
1450 ${x_library}/X11/%T/%N%S"
1451     if test x"${x_default_search_path}" = x; then
1452       x_default_search_path=${x_search_path}
1453     else
1454       x_default_search_path="${x_search_path}:${x_default_search_path}"
1455     fi
1456   done
1457 fi
1458 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1459 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1460
1461 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1462   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1463 fi
1464
1465 if test x"${x_includes}" = x; then
1466   bitmapdir=/usr/include/X11/bitmaps
1467 else
1468   # accumulate include directories that have X11 bitmap subdirectories
1469   bmd_acc="dummyval"
1470   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1471     if test -d "${bmd}/X11/bitmaps"; then
1472       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1473     fi
1474     if test -d "${bmd}/bitmaps"; then
1475       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1476     fi
1477   done
1478   if test ${bmd_acc} != "dummyval"; then
1479     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1480   fi
1481 fi
1482
1483 HAVE_NS=no
1484 NS_IMPL_COCOA=no
1485 NS_IMPL_GNUSTEP=no
1486 tmp_CPPFLAGS="$CPPFLAGS"
1487 tmp_CFLAGS="$CFLAGS"
1488 CPPFLAGS="$CPPFLAGS -x objective-c"
1489 CFLAGS="$CFLAGS -x objective-c"
1490 TEMACS_LDFLAGS2="\${LDFLAGS} \${PROFILING_LDFLAGS}"
1491 dnl I don't think it's especially important, but src/Makefile.in
1492 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1493 dnl trailing "/" to it, so now we do it here.
1494 if test "${with_ns}" != no; then
1495   if test "${opsys}" = darwin; then
1496      NS_IMPL_COCOA=yes
1497      ns_appdir=`pwd`/nextstep/Emacs.app/
1498      ns_appbindir=${ns_appdir}Contents/MacOS/
1499      ns_appresdir=${ns_appdir}Contents/Resources
1500      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1501   elif test -f $GNUSTEP_CONFIG_FILE; then
1502      NS_IMPL_GNUSTEP=yes
1503      ns_appdir=`pwd`/nextstep/Emacs.app/
1504      ns_appbindir=${ns_appdir}
1505      ns_appresdir=${ns_appdir}Resources
1506      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1507      dnl FIXME sourcing this several times in subshells seems inefficient.
1508      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1509      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1510      dnl I seemed to need these as well with GNUstep-startup 0.25.
1511      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1512      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1513      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1514        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1515      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1516        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1517      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1518      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1519      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1520      LIB_STANDARD=
1521      START_FILES=
1522      TEMACS_LDFLAGS2=
1523   fi
1524   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1525                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1526   files are missing or cannot be compiled.])])
1527   NS_HAVE_NSINTEGER=yes
1528   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1529                                      [NSInteger i;])],
1530                     ns_have_nsinteger=yes,
1531                     ns_have_nsinteger=no)
1532   if test $ns_have_nsinteger = no; then
1533     NS_HAVE_NSINTEGER=no
1534   fi
1535 fi
1536 AC_SUBST(TEMACS_LDFLAGS2)
1537
1538 ns_frag=/dev/null
1539 NS_OBJ=
1540 NS_SUPPORT=
1541 if test "${HAVE_NS}" = yes; then
1542   window_system=nextstep
1543   with_xft=no
1544   # set up packaging dirs
1545   exec_prefix=${ns_appbindir}
1546   libexecdir=${ns_appbindir}/libexec
1547   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1548      prefix=${ns_appresdir}
1549   fi
1550   ns_frag=$srcdir/src/ns.mk
1551   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1552   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1553 fi
1554 CFLAGS="$tmp_CFLAGS"
1555 CPPFLAGS="$tmp_CPPFLAGS"
1556 AC_SUBST(NS_OBJ)
1557 AC_SUBST(NS_SUPPORT)
1558 AC_SUBST(LIB_STANDARD)
1559 AC_SUBST_FILE(ns_frag)
1560
1561 case "${window_system}" in
1562   x11 )
1563     HAVE_X_WINDOWS=yes
1564     HAVE_X11=yes
1565     case "${with_x_toolkit}" in
1566       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1567       motif ) USE_X_TOOLKIT=MOTIF ;;
1568       gtk ) with_gtk=yes
1569 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1570 dnl USE_X_TOOLKIT is set.
1571             USE_X_TOOLKIT=none ;;
1572       gtk3 ) with_gtk3=yes
1573              USE_X_TOOLKIT=none ;;
1574       no ) USE_X_TOOLKIT=none ;;
1575 dnl If user did not say whether to use a toolkit, make this decision later:
1576 dnl use the toolkit if we have gtk, or X11R5 or newer.
1577       * ) USE_X_TOOLKIT=maybe ;;
1578     esac
1579   ;;
1580   nextstep | none )
1581     HAVE_X_WINDOWS=no
1582     HAVE_X11=no
1583     USE_X_TOOLKIT=none
1584   ;;
1585 esac
1586
1587 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1588    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1589    if test "$HAVE_XSERVER" = true ||
1590       test -n "$DISPLAY" ||
1591       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1592         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1593 were found.  You should install the relevant development files for X
1594 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1595 sure you have development files for image handling, i.e.
1596 tiff, gif, jpeg, png and xpm.
1597 If you are sure you want Emacs compiled without X window support, pass
1598   --without-x
1599 to configure.])
1600    fi
1601 fi
1602
1603 ### If we're using X11, we should use the X menu package.
1604 HAVE_MENUS=no
1605 case ${HAVE_X11} in
1606   yes ) HAVE_MENUS=yes ;;
1607 esac
1608
1609 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1610 # Assume not, until told otherwise.
1611 GNU_MALLOC=yes
1612 doug_lea_malloc=yes
1613 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1614 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1615 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1616                emacs_cv_var___after_morecore_hook,
1617 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1618   emacs_cv_var___after_morecore_hook=yes,
1619   emacs_cv_var___after_morecore_hook=no)])
1620 if test $emacs_cv_var___after_morecore_hook = no; then
1621   doug_lea_malloc=no
1622 fi
1623
1624
1625 dnl See comments in aix4-2.h about maybe using system malloc there.
1626 system_malloc=no
1627 case "$opsys" in
1628   ## darwin ld insists on the use of malloc routines in the System framework.
1629   darwin|sol2-10) system_malloc=yes ;;
1630 esac
1631
1632 if test "${system_malloc}" = "yes"; then
1633   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1634   GNU_MALLOC=no
1635   GNU_MALLOC_reason="
1636     (The GNU allocators don't work with this system configuration.)"
1637   GMALLOC_OBJ=
1638   VMLIMIT_OBJ=
1639 else
1640   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1641   VMLIMIT_OBJ=vm-limit.o
1642 fi
1643 AC_SUBST(GMALLOC_OBJ)
1644 AC_SUBST(VMLIMIT_OBJ)
1645
1646 if test "$doug_lea_malloc" = "yes" ; then
1647   if test "$GNU_MALLOC" = yes ; then
1648     GNU_MALLOC_reason="
1649       (Using Doug Lea's new malloc from the GNU C Library.)"
1650   fi
1651   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1652             [Define to 1 if you are using the GNU C Library.])
1653
1654   ## Use mmap directly for allocating larger buffers.
1655   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1656   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1657   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1658   case "$opsys" in
1659     gnu*) REL_ALLOC=no ;;
1660   esac
1661 fi
1662
1663 if test x"${REL_ALLOC}" = x; then
1664   REL_ALLOC=${GNU_MALLOC}
1665 fi
1666
1667 use_mmap_for_buffers=no
1668 case "$opsys" in
1669   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1670 esac
1671
1672 AC_FUNC_MMAP
1673 if test $use_mmap_for_buffers = yes; then
1674   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1675   REL_ALLOC=no
1676 fi
1677
1678 LIBS="$LIBS_SYSTEM $LIBS"
1679
1680 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1681 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1682 AC_CHECK_LIB(dnet, dnet_ntoa)
1683 dnl This causes -lresolv to get used in subsequent tests,
1684 dnl which causes failures on some systems such as HPUX 9.
1685 dnl AC_CHECK_LIB(resolv, gethostbyname)
1686
1687 dnl FIXME replace main with a function we actually want from this library.
1688 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1689
1690 AC_CHECK_LIB(pthreads, cma_open)
1691
1692 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1693 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1694 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1695 ## added to LIBS in configure would never contain the pthreads part,
1696 ## but the value used in Makefiles might.  FIXME?
1697 ##
1698 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1699 ## be harmless on older versions of X where it happens to exist.
1700 test "$opsys" = "aix4-2" && \
1701   test $ac_cv_lib_pthreads_cma_open = yes && \
1702   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1703
1704 dnl Check for need for bigtoc support on IBM AIX
1705
1706 case ${host_os} in
1707 aix*)
1708   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1709     case $GCC in
1710     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1711     *) gdb_cv_bigtoc=-bbigtoc ;;
1712     esac
1713
1714     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1715     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1716   ])
1717   ;;
1718 esac
1719
1720 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1721 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1722 # REAL_CPPFLAGS later on.
1723
1724 REAL_CFLAGS="$CFLAGS"
1725 REAL_CPPFLAGS="$CPPFLAGS"
1726
1727 if test "${HAVE_X11}" = "yes"; then
1728   DEFS="$C_SWITCH_X_SITE $DEFS"
1729   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1730   LIBS="-lX11 $LIBS"
1731   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1732   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1733
1734   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1735   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1736   # but it's more convenient here to set LD_RUN_PATH
1737   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1738   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1739     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1740     export LD_RUN_PATH
1741   fi
1742
1743   if test "${opsys}" = "gnu-linux"; then
1744     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1745     AC_TRY_LINK([],
1746      [XOpenDisplay ("foo");],
1747      [xlinux_first_failure=no],
1748      [xlinux_first_failure=yes])
1749     if test "${xlinux_first_failure}" = "yes"; then
1750       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1751       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1752       OLD_CPPFLAGS="$CPPFLAGS"
1753       OLD_LIBS="$LIBS"
1754       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1755       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1756       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1757       LIBS="$LIBS -b i486-linuxaout"
1758       AC_TRY_LINK([],
1759        [XOpenDisplay ("foo");],
1760        [xlinux_second_failure=no],
1761        [xlinux_second_failure=yes])
1762       if test "${xlinux_second_failure}" = "yes"; then
1763         # If we get the same failure with -b, there is no use adding -b.
1764         # So take it out.  This plays safe.
1765         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1766         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1767         CPPFLAGS="$OLD_CPPFLAGS"
1768         LIBS="$OLD_LIBS"
1769         AC_MSG_RESULT(no)
1770       else
1771         AC_MSG_RESULT(yes)
1772       fi
1773     else
1774       AC_MSG_RESULT(no)
1775     fi
1776   fi
1777
1778   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1779   # header files included from there.
1780   AC_MSG_CHECKING(for Xkb)
1781   AC_TRY_LINK([#include <X11/Xlib.h>
1782 #include <X11/XKBlib.h>],
1783         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1784         emacs_xkb=yes, emacs_xkb=no)
1785   AC_MSG_RESULT($emacs_xkb)
1786   if test $emacs_xkb = yes; then
1787     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1788   fi
1789
1790   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1791 XScreenNumberOfScreen XSetWMProtocols)
1792 fi
1793
1794 if test "${window_system}" = "x11"; then
1795   AC_MSG_CHECKING(X11 version 6)
1796   AC_CACHE_VAL(emacs_cv_x11_version_6,
1797   [AC_TRY_LINK([#include <X11/Xlib.h>],
1798 [#if XlibSpecificationRelease < 6
1799 fail;
1800 #endif
1801 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1802   if test $emacs_cv_x11_version_6 = yes; then
1803     AC_MSG_RESULT(6 or newer)
1804     AC_DEFINE(HAVE_X11R6, 1,
1805               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1806     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1807     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1808     ## XIM support.
1809     case "$opsys" in
1810       sol2-*) : ;;
1811       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1812            [Define if you have usable X11R6-style XIM support.])
1813          ;;
1814     esac
1815   else
1816     AC_MSG_RESULT(before 6)
1817   fi
1818 fi
1819
1820
1821 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1822 HAVE_RSVG=no
1823 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1824   if test "${with_rsvg}" != "no"; then
1825     RSVG_REQUIRED=2.11.0
1826     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1827
1828     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1829     AC_SUBST(RSVG_CFLAGS)
1830     AC_SUBST(RSVG_LIBS)
1831
1832     if test ".${RSVG_CFLAGS}" != "."; then
1833       HAVE_RSVG=yes
1834       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1835       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1836       LIBS="$RSVG_LIBS $LIBS"
1837     fi
1838   fi
1839 fi
1840
1841 HAVE_IMAGEMAGICK=no
1842 if test "${with_imagemagick}" != "no"; then
1843   IMAGEMAGICK_MODULE="Wand"
1844   PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, :, :)
1845   AC_SUBST(IMAGEMAGICK_CFLAGS)
1846   AC_SUBST(IMAGEMAGICK_LIBS)
1847
1848   if test ".${IMAGEMAGICK_CFLAGS}" != "."; then
1849     HAVE_IMAGEMAGICK=yes
1850     AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1851     CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1852     LIBS="$IMAGEMAGICK_LIBS $LIBS"
1853   fi
1854
1855   AC_DEFINE(HAVE_MAGICKEXPORTIMAGEPIXELS, 1, [Define to 1 if MagickExportImagePixels is defined.])
1856   AC_CHECK_FUNCS_ONCE(MagickExportImagePixels)
1857
1858 fi
1859
1860
1861 HAVE_GTK=no
1862 if test "${with_gtk3}" = "yes"; then
1863   GLIB_REQUIRED=2.6
1864   GTK_REQUIRED=2.90
1865   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1866
1867   dnl Checks for libraries.
1868   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1869   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1870      AC_MSG_ERROR($GTK_PKG_ERRORS)
1871   fi
1872 fi
1873
1874 if test "$pkg_check_gtk" != "yes"; then
1875   HAVE_GTK=no
1876 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1877   GLIB_REQUIRED=2.6
1878   GTK_REQUIRED=2.6
1879   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1880
1881   dnl Checks for libraries.
1882   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1883   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1884      AC_MSG_ERROR($GTK_PKG_ERRORS)
1885   fi
1886 fi
1887 fi
1888
1889 GTK_OBJ=
1890 if test x"$pkg_check_gtk" = xyes; then
1891
1892   AC_SUBST(GTK_CFLAGS)
1893   AC_SUBST(GTK_LIBS)
1894   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1895   CFLAGS="$CFLAGS $GTK_CFLAGS"
1896   LIBS="$GTK_LIBS $LIBS"
1897   dnl Try to compile a simple GTK program.
1898   GTK_COMPILES=no
1899   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1900   if test "${GTK_COMPILES}" != "yes"; then
1901     if test "$USE_X_TOOLKIT" != "maybe"; then
1902       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1903     fi
1904   else
1905     HAVE_GTK=yes
1906     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1907     GTK_OBJ=gtkutil.o
1908     USE_X_TOOLKIT=none
1909     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1910       :
1911     else
1912       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1913        closing open displays.  This is no problem if you just use
1914        one display, but if you use more than one and close one of them
1915        Emacs may crash.]])
1916       sleep 3
1917     fi
1918   fi
1919
1920 fi
1921 AC_SUBST(GTK_OBJ)
1922
1923
1924 if test "${HAVE_GTK}" = "yes"; then
1925
1926   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1927   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1928   if test "$with_toolkit_scroll_bars" != no; then
1929     with_toolkit_scroll_bars=yes
1930   fi
1931
1932   dnl  Check if we have the old file selection dialog declared and
1933   dnl  in the link library.  In 2.x it may be in the library,
1934   dnl  but not declared if deprecated featured has been selected out.
1935   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1936   HAVE_GTK_FILE_SELECTION=no
1937   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1938                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1939 #include <gtk/gtk.h>])
1940   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1941     AC_CHECK_FUNCS(gtk_file_selection_new)
1942   fi
1943
1944   dnl Check if pthreads are available.  Emacs only needs this when using
1945   dnl gtk_file_chooser under Gnome.
1946     HAVE_GTK_AND_PTHREAD=no
1947     AC_CHECK_HEADERS(pthread.h)
1948     if test "$ac_cv_header_pthread_h"; then
1949       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1950     fi
1951     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1952       case "${canonical}" in
1953         *-hpux*) ;;
1954         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1955       esac
1956       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1957                [Define to 1 if you have GTK and pthread (-lpthread).])
1958     fi
1959
1960   dnl Check for functions introduced in 2.14 and later.
1961   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1962                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1963                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1964                  gtk_orientable_set_orientation)
1965
1966 fi
1967
1968 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1969 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1970 dnl also not configured.
1971 HAVE_DBUS=no
1972 DBUS_OBJ=
1973 if test "${with_dbus}" = "yes"; then
1974    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1975    if test "$HAVE_DBUS" = yes; then
1976      LIBS="$LIBS $DBUS_LIBS"
1977      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1978      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1979      DBUS_OBJ=dbusbind.o
1980    fi
1981 fi
1982 AC_SUBST(DBUS_OBJ)
1983
1984 dnl GConf has been tested under GNU/Linux only.
1985 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1986 HAVE_GCONF=no
1987 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1988    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1989    if test "$HAVE_GCONF" = yes; then
1990       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1991    fi
1992 fi
1993
1994 dnl SELinux is available for GNU/Linux only.
1995 HAVE_LIBSELINUX=no
1996 LIBSELINUX_LIBS=
1997 if test "${with_selinux}" = "yes"; then
1998    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1999    if test "$HAVE_LIBSELINUX" = yes; then
2000       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2001       LIBSELINUX_LIBS=-lselinux
2002    fi
2003 fi
2004 AC_SUBST(LIBSELINUX_LIBS)
2005
2006 dnl Do not put whitespace before the #include statements below.
2007 dnl Older compilers (eg sunos4 cc) choke on it.
2008 HAVE_XAW3D=no
2009 LUCID_LIBW=
2010 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2011   if test "$with_xaw3d" != no; then
2012     AC_MSG_CHECKING(for xaw3d)
2013     AC_CACHE_VAL(emacs_cv_xaw3d,
2014     [AC_TRY_LINK([
2015 #include <X11/Intrinsic.h>
2016 #include <X11/Xaw3d/Simple.h>],
2017       [],
2018       emacs_cv_xaw3d=yes,
2019       emacs_cv_xaw3d=no)])
2020   else
2021     emacs_cv_xaw3d=no
2022   fi
2023   if test $emacs_cv_xaw3d = yes; then
2024     AC_MSG_RESULT([yes; using Lucid toolkit])
2025     USE_X_TOOLKIT=LUCID
2026     HAVE_XAW3D=yes
2027     LUCID_LIBW=-lXaw3d
2028     AC_DEFINE(HAVE_XAW3D, 1,
2029               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2030   else
2031     AC_MSG_RESULT(no)
2032     AC_MSG_CHECKING(for libXaw)
2033     AC_CACHE_VAL(emacs_cv_xaw,
2034     [AC_TRY_LINK([
2035 #include <X11/Intrinsic.h>
2036 #include <X11/Xaw/Simple.h>],
2037       [],
2038       emacs_cv_xaw=yes,
2039       emacs_cv_xaw=no)])
2040     if test $emacs_cv_xaw = yes; then
2041       AC_MSG_RESULT([yes; using Lucid toolkit])
2042       USE_X_TOOLKIT=LUCID
2043       LUCID_LIBW=-lXaw
2044     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2045       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2046     else
2047       AC_MSG_RESULT([no; do not use toolkit by default])
2048       USE_X_TOOLKIT=none
2049     fi
2050   fi
2051 fi
2052
2053 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2054
2055 LIBXTR6=
2056 if test "${USE_X_TOOLKIT}" != "none"; then
2057   AC_MSG_CHECKING(X11 toolkit version)
2058   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2059   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2060 [#if XtSpecificationRelease < 6
2061 fail;
2062 #endif
2063 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2064   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2065   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2066     AC_MSG_RESULT(6 or newer)
2067     AC_DEFINE(HAVE_X11XTR6, 1,
2068               [Define to 1 if you have the X11R6 or newer version of Xt.])
2069     LIBXTR6="-lSM -lICE"
2070     case "$opsys" in
2071       ## Use libw.a along with X11R6 Xt.
2072       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2073     esac
2074   else
2075     AC_MSG_RESULT(before 6)
2076   fi
2077
2078 dnl If using toolkit, check whether libXmu.a exists.
2079 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2080   OLDLIBS="$LIBS"
2081   if test x$HAVE_X11XTR6 = xyes; then
2082     LIBS="-lXt -lSM -lICE $LIBS"
2083   else
2084     LIBS="-lXt $LIBS"
2085   fi
2086   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2087   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2088 fi
2089 AC_SUBST(LIBXTR6)
2090
2091 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2092 dnl Why not just test for libxmu in the normal way?
2093 LIBXMU=-lXmu
2094 case "$machine" in
2095   ## These machines don't supply Xmu.
2096   hpux* | aix4-2 )
2097     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2098     ;;
2099 esac
2100 AC_SUBST(LIBXMU)
2101
2102 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2103 if test "${HAVE_X11}" = "yes"; then
2104   if test "${USE_X_TOOLKIT}" != "none"; then
2105     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2106   fi
2107 fi
2108
2109 LIBXP=
2110 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2111   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2112   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2113     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2114 int x = 5;
2115 #else
2116 Motif version prior to 2.1.
2117 #endif],
2118     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2119   if test $emacs_cv_motif_version_2_1 = yes; then
2120     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2121   else
2122     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2123     # We put this in CFLAGS temporarily to precede other -I options
2124     # that might be in CFLAGS temporarily.
2125     # We put this in CPPFLAGS where it precedes the other -I options.
2126     OLD_CPPFLAGS=$CPPFLAGS
2127     OLD_CFLAGS=$CFLAGS
2128     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2129     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2130     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2131       [int x = 5;],
2132       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2133     if test $emacs_cv_lesstif = yes; then
2134       # Make sure this -I option remains in CPPFLAGS after it is set
2135       # back to REAL_CPPFLAGS.
2136       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2137       # have those other -I options anyway.  Ultimately, having this
2138       # directory ultimately in CPPFLAGS will be enough.
2139       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2140       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2141     else
2142       CFLAGS=$OLD_CFLAGS
2143       CPPFLAGS=$OLD_CPPFLAGS
2144     fi
2145   fi
2146 fi
2147
2148 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2149 dnl using Motif or Xaw3d is available, and unless
2150 dnl --with-toolkit-scroll-bars=no was specified.
2151
2152 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2153             [Define to 1 if we should use toolkit scroll bars.])dnl
2154 USE_TOOLKIT_SCROLL_BARS=no
2155 if test "${with_toolkit_scroll_bars}" != "no"; then
2156   if test "${USE_X_TOOLKIT}" != "none"; then
2157     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2158       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2159       HAVE_XAW3D=no
2160       USE_TOOLKIT_SCROLL_BARS=yes
2161     elif test "${HAVE_XAW3D}" = "yes"; then
2162       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2163       USE_TOOLKIT_SCROLL_BARS=yes
2164     fi
2165   elif test "${HAVE_GTK}" = "yes"; then
2166     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2167     USE_TOOLKIT_SCROLL_BARS=yes
2168   elif test "${HAVE_NS}" = "yes"; then
2169     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2170     USE_TOOLKIT_SCROLL_BARS=yes
2171   fi
2172 fi
2173
2174 dnl See if XIM is available.
2175 AC_TRY_COMPILE([
2176           #include <X11/Xlib.h>
2177           #include <X11/Xresource.h>],
2178          [XIMProc  callback;],
2179          [HAVE_XIM=yes
2180          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2181          HAVE_XIM=no)
2182
2183 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2184
2185 if test "${with_xim}" != "no"; then
2186   AC_DEFINE(USE_XIM, 1,
2187             [Define to 1 if we should use XIM, if it is available.])
2188 fi
2189
2190
2191 if test "${HAVE_XIM}" != "no"; then
2192   late_CFLAGS=$CFLAGS
2193   if test "$GCC" = yes; then
2194     CFLAGS="$CFLAGS --pedantic-errors"
2195   fi
2196   AC_TRY_COMPILE([
2197 #include <X11/Xlib.h>
2198 #include <X11/Xresource.h>],
2199 [Display *display;
2200 XrmDatabase db;
2201 char *res_name;
2202 char *res_class;
2203 XIMProc  callback;
2204 XPointer *client_data;
2205 #ifndef __GNUC__
2206 /* If we're not using GCC, it's probably not XFree86, and this is
2207    probably right, but we can't use something like --pedantic-errors.  */
2208 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2209                                            char*, XIMProc, XPointer*);
2210 #endif
2211 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2212    client_data);],
2213     [emacs_cv_arg6_star=yes])
2214   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2215          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2216 either XPointer or XPointer*.])dnl
2217   if test "$emacs_cv_arg6_star" = yes; then
2218     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2219   else
2220     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2221   fi
2222   CFLAGS=$late_CFLAGS
2223 fi
2224
2225 ### Start of font-backend (under any platform) section.
2226 # (nothing here yet -- this is a placeholder)
2227 ### End of font-backend (under any platform) section.
2228
2229 ### Start of font-backend (under X11) section.
2230 if test "${HAVE_X11}" = "yes"; then
2231    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2232
2233    ## Use -lXft if available, unless `--with-xft=no'.
2234    HAVE_XFT=maybe
2235     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2236       with_xft="no";
2237     fi
2238     if test "x${with_xft}" != "xno"; then
2239
2240       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2241       ## Because xftfont.c uses XRenderQueryExtension, we also
2242       ## need to link to -lXrender.
2243       HAVE_XRENDER=no
2244       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2245       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2246         OLD_CPPFLAGS="$CPPFLAGS"
2247         OLD_CFLAGS="$CFLAGS"
2248         OLD_LIBS="$LIBS"
2249         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2250         CFLAGS="$CFLAGS $XFT_CFLAGS"
2251         XFT_LIBS="-lXrender $XFT_LIBS"
2252         LIBS="$XFT_LIBS $LIBS"
2253         AC_CHECK_HEADER(X11/Xft/Xft.h,
2254           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2255
2256         if test "${HAVE_XFT}" = "yes"; then
2257           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2258             AC_SUBST(XFT_LIBS)
2259           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2260         else
2261           CPPFLAGS="$OLD_CPPFLAGS"
2262           CFLAGS="$OLD_CFLAGS"
2263           LIBS="$OLD_LIBS"
2264         fi                        # "${HAVE_XFT}" = "yes"
2265       fi                          # "$HAVE_XFT" != no
2266     fi                            # "x${with_xft}" != "xno"
2267
2268     dnl For the "Does Emacs use" message at the end.
2269     if test "$HAVE_XFT" != "yes"; then
2270        HAVE_XFT=no
2271     fi
2272
2273
2274     HAVE_FREETYPE=no
2275     ## We used to allow building with FreeType and without Xft.
2276     ## However, the ftx font backend driver is not in good shape.
2277     if test "${HAVE_XFT}" = "yes"; then
2278       dnl As we use Xft, we anyway use freetype.
2279       dnl There's no need for additional CFLAGS and LIBS.
2280       HAVE_FREETYPE=yes
2281       FONTCONFIG_CFLAGS=
2282       FONTCONFIG_LIBS=
2283     fi
2284
2285     HAVE_LIBOTF=no
2286     if test "${HAVE_FREETYPE}" = "yes"; then
2287       AC_DEFINE(HAVE_FREETYPE, 1,
2288                 [Define to 1 if using the freetype and fontconfig libraries.])
2289       if test "${with_libotf}" != "no"; then
2290         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2291                           HAVE_LIBOTF=no)
2292         if test "$HAVE_LIBOTF" = "yes"; then
2293           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2294           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2295                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2296                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2297           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2298             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2299                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2300           fi
2301         fi
2302       fi
2303     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2304     dnl Does the new font backend require it, or can it work without it?
2305     fi
2306
2307     HAVE_M17N_FLT=no
2308     if test "${HAVE_LIBOTF}" = yes; then
2309       if test "${with_m17n_flt}" != "no"; then
2310         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2311         if test "$HAVE_M17N_FLT" = "yes"; then
2312           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2313         fi
2314       fi
2315     fi
2316 else
2317     HAVE_XFT=no
2318     HAVE_FREETYPE=no
2319     HAVE_LIBOTF=no
2320     HAVE_M17N_FLT=no
2321 fi
2322
2323 ### End of font-backend (under X11) section.
2324
2325 AC_SUBST(FREETYPE_CFLAGS)
2326 AC_SUBST(FREETYPE_LIBS)
2327 AC_SUBST(FONTCONFIG_CFLAGS)
2328 AC_SUBST(FONTCONFIG_LIBS)
2329 AC_SUBST(LIBOTF_CFLAGS)
2330 AC_SUBST(LIBOTF_LIBS)
2331 AC_SUBST(M17N_FLT_CFLAGS)
2332 AC_SUBST(M17N_FLT_LIBS)
2333
2334 ### Use -lXpm if available, unless `--with-xpm=no'.
2335 HAVE_XPM=no
2336 LIBXPM=
2337 if test "${HAVE_X11}" = "yes"; then
2338   if test "${with_xpm}" != "no"; then
2339     AC_CHECK_HEADER(X11/xpm.h,
2340       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2341     if test "${HAVE_XPM}" = "yes"; then
2342       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2343       AC_EGREP_CPP(no_return_alloc_pixels,
2344       [#include "X11/xpm.h"
2345 #ifndef XpmReturnAllocPixels
2346 no_return_alloc_pixels
2347 #endif
2348       ], HAVE_XPM=no, HAVE_XPM=yes)
2349
2350       if test "${HAVE_XPM}" = "yes"; then
2351         AC_MSG_RESULT(yes)
2352       else
2353         AC_MSG_RESULT(no)
2354       fi
2355     fi
2356   fi
2357
2358   if test "${HAVE_XPM}" = "yes"; then
2359     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2360     LIBXPM=-lXpm
2361   fi
2362 fi
2363 AC_SUBST(LIBXPM)
2364
2365 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2366 HAVE_JPEG=no
2367 LIBJPEG=
2368 if test "${HAVE_X11}" = "yes"; then
2369   if test "${with_jpeg}" != "no"; then
2370     dnl Checking for jpeglib.h can lose because of a redefinition of
2371     dnl  HAVE_STDLIB_H.
2372     AC_CHECK_HEADER(jerror.h,
2373       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2374   fi
2375
2376   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2377   if test "${HAVE_JPEG}" = "yes"; then
2378     AC_DEFINE(HAVE_JPEG)
2379     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2380         [#include <jpeglib.h>
2381          version=JPEG_LIB_VERSION
2382 ],
2383         [AC_DEFINE(HAVE_JPEG)],
2384         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2385         HAVE_JPEG=no])
2386   fi
2387   if test "${HAVE_JPEG}" = "yes"; then
2388     LIBJPEG=-ljpeg
2389   fi
2390 fi
2391 AC_SUBST(LIBJPEG)
2392
2393 ### Use -lpng if available, unless `--with-png=no'.
2394 HAVE_PNG=no
2395 LIBPNG=
2396 if test "${HAVE_X11}" = "yes"; then
2397   if test "${with_png}" != "no"; then
2398     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2399     # in /usr/include/libpng.
2400     AC_CHECK_HEADERS(png.h libpng/png.h)
2401     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2402       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2403     fi
2404   fi
2405
2406   if test "${HAVE_PNG}" = "yes"; then
2407     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2408     LIBPNG="-lpng -lz -lm"
2409   fi
2410 fi
2411 AC_SUBST(LIBPNG)
2412
2413 ### Use -ltiff if available, unless `--with-tiff=no'.
2414 HAVE_TIFF=no
2415 LIBTIFF=
2416 if test "${HAVE_X11}" = "yes"; then
2417   if test "${with_tiff}" != "no"; then
2418     AC_CHECK_HEADER(tiffio.h,
2419       [tifflibs="-lz -lm"
2420       # At least one tiff package requires the jpeg library.
2421       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2422       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2423   fi
2424
2425   if test "${HAVE_TIFF}" = "yes"; then
2426     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2427     dnl FIXME -lz -lm, as per libpng?
2428     LIBTIFF=-ltiff
2429   fi
2430 fi
2431 AC_SUBST(LIBTIFF)
2432
2433 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2434 HAVE_GIF=no
2435 LIBGIF=
2436 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2437   AC_CHECK_HEADER(gif_lib.h,
2438 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2439 # Earlier versions can crash Emacs.
2440     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2441
2442   if test "$HAVE_GIF" = yes; then
2443     LIBGIF=-lgif
2444   elif test "$HAVE_GIF" = maybe; then
2445 # If gif_lib.h but no libgif, try libungif.
2446     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2447     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2448   fi
2449
2450   if test "${HAVE_GIF}" = "yes"; then
2451     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2452   fi
2453 fi
2454 AC_SUBST(LIBGIF)
2455
2456 dnl Check for required libraries.
2457 if test "${HAVE_X11}" = "yes"; then
2458   MISSING=""
2459   WITH_NO=""
2460   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2461     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2462   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2463     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2464   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2465     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2466   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2467     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2468   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2469     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2470
2471   if test "X${MISSING}" != X; then
2472     AC_MSG_ERROR([The following required libraries were not found:
2473     $MISSING
2474 Maybe some development libraries/packages are missing?
2475 If you don't want to link with them give
2476     $WITH_NO
2477 as options to configure])
2478   fi
2479 fi
2480
2481 ### Use -lgpm if available, unless `--with-gpm=no'.
2482 HAVE_GPM=no
2483 LIBGPM=
2484 MOUSE_SUPPORT=
2485 if test "${with_gpm}" != "no"; then
2486   AC_CHECK_HEADER(gpm.h,
2487     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2488
2489   if test "${HAVE_GPM}" = "yes"; then
2490     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2491     LIBGPM=-lgpm
2492     ## May be reset below.
2493     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2494   fi
2495 fi
2496 AC_SUBST(LIBGPM)
2497
2498 dnl Check for malloc/malloc.h on darwin
2499 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2500
2501 C_SWITCH_X_SYSTEM=
2502 ### Use NeXTstep API to implement GUI.
2503 if test "${HAVE_NS}" = "yes"; then
2504   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2505   if test "${NS_IMPL_COCOA}" = "yes"; then
2506     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2507     GNU_OBJC_CFLAGS=
2508   fi
2509   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2510     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2511     # See also .m.o rule in Makefile.in */
2512     # FIXME: are all these flags really needed?  Document here why.  */
2513     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2514     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2515   fi
2516   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2517     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2518   fi
2519   # We also have mouse menus.
2520   HAVE_MENUS=yes
2521   OTHER_FILES=ns-app
2522 fi
2523
2524
2525 ### Use session management (-lSM -lICE) if available
2526 HAVE_X_SM=no
2527 LIBXSM=
2528 if test "${HAVE_X11}" = "yes"; then
2529   AC_CHECK_HEADER(X11/SM/SMlib.h,
2530     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2531
2532   if test "${HAVE_X_SM}" = "yes"; then
2533     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2534     LIBXSM="-lSM -lICE"
2535     case "$LIBS" in
2536       *-lSM*) ;;
2537       *)      LIBS="$LIBXSM $LIBS" ;;
2538     esac
2539   fi
2540 fi
2541 AC_SUBST(LIBXSM)
2542
2543 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2544 AC_CACHE_CHECK(whether netdb declares h_errno,
2545                emacs_cv_netdb_declares_h_errno,
2546 [AC_TRY_LINK([#include <netdb.h>],
2547   [return h_errno;],
2548   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2549 if test $emacs_cv_netdb_declares_h_errno = yes; then
2550   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2551 fi
2552
2553 AC_FUNC_ALLOCA
2554
2555 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2556 dnl FIXME is there an autoconf test that does the right thing, without
2557 dnl needing to call A_M_E afterwards?
2558 if test x"$ac_cv_func_alloca_works" != xyes; then
2559    AC_MSG_ERROR( [a system implementation of alloca is required] )
2560 fi
2561
2562 # fmod, logb, and frexp are found in -lm on most systems.
2563 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2564 AC_CHECK_LIB(m, sqrt)
2565
2566 # Check for mail-locking functions in a "mail" library.  Probably this should
2567 # have the same check as for liblockfile below.
2568 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2569 if test $have_mail = yes; then
2570   LIBS_MAIL=-lmail
2571   LIBS="$LIBS_MAIL $LIBS"
2572   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2573 else
2574   LIBS_MAIL=
2575 fi
2576 dnl Debian, at least:
2577 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2578 if test $have_lockfile = yes; then
2579    LIBS_MAIL=-llockfile
2580    LIBS="$LIBS_MAIL $LIBS"
2581    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2582 else
2583 # If we have the shared liblockfile, assume we must use it for mail
2584 # locking (e.g. Debian).  If we couldn't link against liblockfile
2585 # (no liblockfile.a installed), ensure that we don't need to.
2586   dnl This works for files generally, not just executables.
2587   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2588   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2589                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2590   if test $ac_cv_prog_liblockfile = yes; then
2591     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2592 This probably means that movemail could lose mail.
2593 There may be a `development' package to install containing liblockfile.])
2594   fi
2595 fi
2596 AC_CHECK_FUNCS(touchlock)
2597 AC_CHECK_HEADERS(maillock.h)
2598 AC_SUBST(LIBS_MAIL)
2599
2600 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2601 ## interlock access to the mail spool.  The alternative is a lock file named
2602 ## /usr/spool/mail/$USER.lock.
2603 mail_lock=no
2604 case "$opsys" in
2605   aix4-2) mail_lock="lockf" ;;
2606
2607   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2608
2609   ## On GNU/Linux systems, both methods are used by various mail programs.
2610   ## I assume most people are using newer mailers that have heard of flock.
2611   ## Change this if you need to.
2612   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2613   ## configure gets the right answers, and that means *NOT* using flock.
2614   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2615   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2616   ## Debian maintainer hasn't provided a clean fix for Emacs.
2617   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2618   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2619   ## correct logic.  -- fx
2620   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2621   ## liblockfile is a Free Software replacement for libmail, used on
2622   ## Debian systems and elsewhere. -rfr.
2623   gnu-*)
2624     mail_lock="flock"
2625     if test $have_mail = yes || test $have_lockfile = yes; then
2626       test $ac_cv_header_maillock_h = yes && mail_lock=no
2627     fi
2628     ;;
2629 esac
2630
2631 BLESSMAIL_TARGET=
2632 case "$mail_lock" in
2633   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2634
2635   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2636
2637   *) BLESSMAIL_TARGET="need-blessmail" ;;
2638 esac
2639 AC_SUBST(BLESSMAIL_TARGET)
2640
2641
2642 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2643 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2644 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2645 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2646 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2647 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2648 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2649 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2650 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2651 cfmakeraw cfsetspeed isnan copysign __executable_start)
2652
2653 AC_CHECK_HEADERS(sys/un.h)
2654
2655 AC_FUNC_MKTIME
2656 if test "$ac_cv_func_working_mktime" = no; then
2657   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2658 fi
2659
2660 AC_FUNC_GETLOADAVG
2661
2662 AC_FUNC_FSEEKO
2663
2664 # Configure getopt.
2665 m4_include([m4/getopt.m4])
2666 gl_GETOPT_IFELSE([
2667   gl_GETOPT_SUBSTITUTE_HEADER
2668   gl_PREREQ_GETOPT
2669   GETOPTOBJS='getopt.o getopt1.o'
2670 ])
2671 AC_SUBST(GETOPTOBJS)
2672
2673 AC_FUNC_GETPGRP
2674
2675 AC_FUNC_STRFTIME
2676
2677 # UNIX98 PTYs.
2678 AC_CHECK_FUNCS(grantpt)
2679
2680 # PTY-related GNU extensions.
2681 AC_CHECK_FUNCS(getpt)
2682
2683 # Check this now, so that we will NOT find the above functions in ncurses.
2684 # That is because we have not set up to link ncurses in lib-src.
2685 # It's better to believe a function is not available
2686 # than to expect to find it in ncurses.
2687 # Also we need tputs and friends to be able to build at all.
2688 have_tputs_et_al=true
2689 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2690 if test "$have_tputs_et_al" != true; then
2691   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2692 Maybe some development libraries/packages are missing?  Try installing
2693 libncurses-dev(el), libterminfo-dev(el) or similar.])
2694 fi
2695 # Must define this when any termcap library is found.
2696 AC_DEFINE(HAVE_LIBNCURSES, 1,
2697           [Define to 1 if you have the `ncurses' library (-lncurses).])
2698 ## FIXME This was the cpp logic, but I am not sure it is right.
2699 ## The above test has not necessarily found libncurses.
2700 HAVE_LIBNCURSES=yes
2701
2702 ## Use terminfo instead of termcap?
2703 ## Note only system files NOT using terminfo are:
2704 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2705 ## darwin|gnu without ncurses.
2706 TERMINFO=no
2707 LIBS_TERMCAP=
2708 case "$opsys" in
2709   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2710   ## hpux10-20: Use the system provided termcap(3) library.
2711   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2712   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2713   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2714
2715   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2716   ##  The ncurses library has been moved out of the System framework in
2717   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2718   ##  option to use it.
2719   darwin|gnu*)
2720     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2721     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2722       TERMINFO=yes
2723       LIBS_TERMCAP="-lncurses"
2724     fi
2725     ;;
2726
2727   freebsd)
2728     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2729     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2730     [AC_TRY_LINK([#include <osreldate.h>],
2731 [#if __FreeBSD_version < 400000
2732 fail;
2733 #endif
2734 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2735
2736     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2737
2738     if test $emacs_cv_freebsd_terminfo = yes; then
2739       TERMINFO=yes
2740       LIBS_TERMCAP="-lncurses"
2741     else
2742       LIBS_TERMCAP="-ltermcap"
2743     fi
2744     ;;
2745
2746   netbsd)
2747     if test $ac_cv_search_tputs = -lterminfo; then
2748       TERMINFO=yes
2749       LIBS_TERMCAP="-lterminfo"
2750     else
2751       LIBS_TERMCAP="-ltermcap"
2752     fi
2753     ;;
2754
2755 esac
2756
2757 case "$opsys" in
2758   ## hpux: Make sure we get select from libc rather than from libcurses
2759   ##  because libcurses on HPUX 10.10 has a broken version of select.
2760   ##  We used to use -lc -lcurses, but this may be cleaner.
2761   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2762
2763   openbsd) LIBS_TERMCAP="-lncurses" ;;
2764
2765   ## Must use system termcap, if we use any termcap.  It does special things.
2766   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2767 esac
2768
2769 TERMCAP_OBJ=tparam.o
2770 if test $TERMINFO = yes; then
2771   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2772
2773   ## Default used to be -ltermcap.  Add a case above if need something else.
2774   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2775
2776   TERMCAP_OBJ=terminfo.o
2777 fi
2778 AC_SUBST(LIBS_TERMCAP)
2779 AC_SUBST(TERMCAP_OBJ)
2780
2781
2782 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2783 resolv=no
2784 AC_TRY_LINK([#include <netinet/in.h>
2785 #include <arpa/nameser.h>
2786 #include <resolv.h>],
2787     [return res_init();],
2788     have_res_init=yes, have_res_init=no)
2789 if test "$have_res_init" = no; then
2790   OLIBS="$LIBS"
2791   LIBS="$LIBS -lresolv"
2792   AC_MSG_CHECKING(for res_init with -lresolv)
2793   AC_TRY_LINK([#include <netinet/in.h>
2794 #include <arpa/nameser.h>
2795 #include <resolv.h>],
2796     [return res_init();],
2797     have_res_init=yes, have_res_init=no)
2798   AC_MSG_RESULT($have_res_init)
2799   if test "$have_res_init" = yes ; then
2800     resolv=yes
2801   fi
2802   LIBS="$OLIBS"
2803 fi
2804
2805 if test "$have_res_init" = yes; then
2806   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2807 fi
2808
2809 # Do we need the Hesiod library to provide the support routines?
2810 LIBHESIOD=
2811 if test "$with_hesiod" != no ; then
2812   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2813   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2814      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2815                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2816   if test "$resolv" = yes ; then
2817     RESOLVLIB=-lresolv
2818   else
2819     RESOLVLIB=
2820   fi
2821   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2822         hesiod=yes, :, $RESOLVLIB)])
2823
2824   if test x"$hesiod" = xyes; then
2825     AC_DEFINE(HAVE_LIBHESIOD, 1,
2826               [Define to 1 if you have the hesiod library (-lhesiod).])
2827     LIBHESIOD=-lhesiod
2828   fi
2829 fi
2830 AC_SUBST(LIBHESIOD)
2831
2832 # Do we need libresolv (due to res_init or Hesiod)?
2833 if test "$resolv" = yes ; then
2834   AC_DEFINE(HAVE_LIBRESOLV, 1,
2835             [Define to 1 if you have the resolv library (-lresolv).])
2836   LIBRESOLV=-lresolv
2837 else
2838   LIBRESOLV=
2839 fi
2840 AC_SUBST(LIBRESOLV)
2841
2842 # These tell us which Kerberos-related libraries to use.
2843 COM_ERRLIB=
2844 CRYPTOLIB=
2845 KRB5LIB=
2846 DESLIB=
2847 KRB4LIB=
2848
2849 if test "${with_kerberos}" != no; then
2850   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2851   if test $have_com_err = yes; then
2852     COM_ERRLIB=-lcom_err
2853     LIBS="$COM_ERRLIB $LIBS"
2854     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2855   fi
2856   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2857   if test $have_crypto = yes; then
2858     CRYPTOLIB=-lcrypto
2859     LIBS="$CRYPTOLIB $LIBS"
2860     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2861   fi
2862   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2863   if test $have_k5crypto = yes; then
2864     CRYPTOLIB=-lk5crypto
2865     LIBS="$CRYPTOLIB $LIBS"
2866     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2867   fi
2868   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2869   if test $have_krb5=yes; then
2870     KRB5LIB=-lkrb5
2871     LIBS="$KRB5LIB $LIBS"
2872     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2873   fi
2874   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2875   if test "${with_kerberos5}" = no; then
2876     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2877     if test $have_des425 = yes; then
2878       DESLIB=-ldes425
2879       LIBS="$DESLIB $LIBS"
2880       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2881     else
2882       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2883       if test $have_des = yes; then
2884         DESLIB=-ldes
2885         LIBS="$DESLIB $LIBS"
2886         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2887       fi
2888     fi
2889     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2890     if test $have_krb4 = yes; then
2891       KRB4LIB=-lkrb4
2892       LIBS="$KRB4LIB $LIBS"
2893       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2894     else
2895       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2896       if test $have_krb = yes; then
2897         KRB4LIB=-lkrb
2898         LIBS="$KRB4LIB $LIBS"
2899         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2900       fi
2901     fi
2902   fi
2903
2904   if test "${with_kerberos5}" != no; then
2905     AC_CHECK_HEADERS(krb5.h,
2906       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2907                         [#include <krb5.h>])])
2908   else
2909     AC_CHECK_HEADERS(des.h,,
2910                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2911                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2912     AC_CHECK_HEADERS(krb.h,,
2913                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2914                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2915   fi
2916   AC_CHECK_HEADERS(com_err.h)
2917 fi
2918
2919 AC_SUBST(COM_ERRLIB)
2920 AC_SUBST(CRYPTOLIB)
2921 AC_SUBST(KRB5LIB)
2922 AC_SUBST(DESLIB)
2923 AC_SUBST(KRB4LIB)
2924
2925 # Solaris requires -lintl if you want strerror (which calls dgettext)
2926 # to return localized messages.
2927 AC_CHECK_LIB(intl, dgettext)
2928
2929 AC_MSG_CHECKING(whether localtime caches TZ)
2930 AC_CACHE_VAL(emacs_cv_localtime_cache,
2931 [if test x$ac_cv_func_tzset = xyes; then
2932 AC_TRY_RUN([#include <time.h>
2933 extern char **environ;
2934 unset_TZ ()
2935 {
2936   char **from, **to;
2937   for (to = from = environ; (*to = *from); from++)
2938     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2939       to++;
2940 }
2941 char TZ_GMT0[] = "TZ=GMT0";
2942 char TZ_PST8[] = "TZ=PST8";
2943 main()
2944 {
2945   time_t now = time ((time_t *) 0);
2946   int hour_GMT0, hour_unset;
2947   if (putenv (TZ_GMT0) != 0)
2948     exit (1);
2949   hour_GMT0 = localtime (&now)->tm_hour;
2950   unset_TZ ();
2951   hour_unset = localtime (&now)->tm_hour;
2952   if (putenv (TZ_PST8) != 0)
2953     exit (1);
2954   if (localtime (&now)->tm_hour == hour_GMT0)
2955     exit (1);
2956   unset_TZ ();
2957   if (localtime (&now)->tm_hour != hour_unset)
2958     exit (1);
2959   exit (0);
2960 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2961 [# If we have tzset, assume the worst when cross-compiling.
2962 emacs_cv_localtime_cache=yes])
2963 else
2964         # If we lack tzset, report that localtime does not cache TZ,
2965         # since we can't invalidate the cache if we don't have tzset.
2966         emacs_cv_localtime_cache=no
2967 fi])dnl
2968 AC_MSG_RESULT($emacs_cv_localtime_cache)
2969 if test $emacs_cv_localtime_cache = yes; then
2970   AC_DEFINE(LOCALTIME_CACHE, 1,
2971             [Define to 1 if localtime caches TZ.])
2972 fi
2973
2974 if test "x$HAVE_TIMEVAL" = xyes; then
2975   AC_CHECK_FUNCS(gettimeofday)
2976   if test $ac_cv_func_gettimeofday = yes; then
2977     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2978                    emacs_cv_gettimeofday_two_arguments,
2979     [AC_TRY_COMPILE([
2980 #ifdef TIME_WITH_SYS_TIME
2981 #include <sys/time.h>
2982 #include <time.h>
2983 #else
2984 #ifdef HAVE_SYS_TIME_H
2985 #include <sys/time.h>
2986 #else
2987 #include <time.h>
2988 #endif
2989 #endif],
2990       [struct timeval time;
2991        gettimeofday (&time, 0);],
2992       emacs_cv_gettimeofday_two_arguments=yes,
2993       emacs_cv_gettimeofday_two_arguments=no)])
2994     if test $emacs_cv_gettimeofday_two_arguments = no; then
2995       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2996                 [Define to 1 if gettimeofday accepts only one argument.])
2997     fi
2998   fi
2999 fi
3000
3001 ok_so_far=yes
3002 AC_CHECK_FUNC(socket, , ok_so_far=no)
3003 if test $ok_so_far = yes; then
3004   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3005 fi
3006 if test $ok_so_far = yes; then
3007   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3008 fi
3009 if test $ok_so_far = yes; then
3010 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3011   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3012             [Define to 1 if you have inet sockets.])
3013 fi
3014
3015 AC_CHECK_HEADERS(sys/ioctl.h)
3016
3017 if test -f /usr/lpp/X11/bin/smt.exp; then
3018   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3019             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3020 fi
3021
3022 AC_MSG_CHECKING(whether system supports dynamic ptys)
3023 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3024   AC_MSG_RESULT(yes)
3025   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3026 else
3027   AC_MSG_RESULT(no)
3028 fi
3029
3030 AC_FUNC_FORK
3031
3032 dnl Adapted from Haible's version.
3033 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3034   [AC_TRY_LINK([#include <langinfo.h>],
3035     [char* cs = nl_langinfo(CODESET);],
3036     emacs_cv_langinfo_codeset=yes,
3037     emacs_cv_langinfo_codeset=no)
3038   ])
3039 if test $emacs_cv_langinfo_codeset = yes; then
3040   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3041     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3042 fi
3043
3044 AC_CHECK_TYPES(size_t)
3045
3046 AC_TYPE_MBSTATE_T
3047
3048 dnl Restrict could probably be used effectively other than in regex.c.
3049 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3050   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3051                   emacs_cv_c_restrict=yes,
3052                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3053                                   emacs_cv_c_restrict=__restrict,
3054                                   emacs_cv_c_restrict=no)])])
3055 case "$emacs_cv_c_restrict" in
3056   yes) emacs_restrict=restrict;;
3057   no) emacs_restrict="";;
3058   *) emacs_restrict="$emacs_cv_c_restrict";;
3059 esac
3060 if test "$emacs_restrict" != __restrict; then
3061   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3062     [Define to compiler's equivalent of C99 restrict keyword.
3063      Don't define if equivalent is `__restrict'.])
3064 fi
3065
3066 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3067   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3068                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3069 if test "$emacs_cv_c_restrict_arr" = yes; then
3070   AC_DEFINE(__restrict_arr, __restrict,
3071     [Define to compiler's equivalent of C99 restrict keyword in array
3072      declarations.  Define as empty for no equivalent.])
3073 fi
3074
3075 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3076 dnl how the tty code is related to POSIX and/or other versions of termios.
3077 dnl The following looks like a useful start.
3078 dnl
3079 dnl AC_SYS_POSIX_TERMIOS
3080 dnl if test $ac_cv_sys_posix_termios = yes; then
3081 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3082 dnl                                and macros for terminal control.])
3083 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3084 dnl fi
3085
3086 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3087
3088 # Set up the CFLAGS for real compilation, so we can substitute it.
3089 CFLAGS="$REAL_CFLAGS"
3090 CPPFLAGS="$REAL_CPPFLAGS"
3091
3092 ## Hack to detect a buggy GCC version.
3093 if test "x$GCC" = xyes \
3094    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3095    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3096    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3097    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3098 fi
3099
3100 #### Find out which version of Emacs this is.
3101 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3102          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3103 if test x"${version}" = x; then
3104   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3105 fi
3106 if test x"${version}" != x"$PACKAGE_VERSION"; then
3107   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3108 fi
3109
3110 ### Specify what sort of things we'll be editing into Makefile and config.h.
3111 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3112 AC_SUBST(version)
3113 AC_SUBST(configuration)
3114 ## Unused?
3115 AC_SUBST(canonical)
3116 AC_SUBST(srcdir)
3117 AC_SUBST(prefix)
3118 AC_SUBST(exec_prefix)
3119 AC_SUBST(bindir)
3120 AC_SUBST(datadir)
3121 AC_SUBST(sharedstatedir)
3122 AC_SUBST(libexecdir)
3123 AC_SUBST(mandir)
3124 AC_SUBST(infodir)
3125 AC_SUBST(lispdir)
3126 AC_SUBST(locallisppath)
3127 AC_SUBST(lisppath)
3128 AC_SUBST(x_default_search_path)
3129 AC_SUBST(etcdir)
3130 AC_SUBST(archlibdir)
3131 AC_SUBST(docdir)
3132 AC_SUBST(bitmapdir)
3133 AC_SUBST(gamedir)
3134 AC_SUBST(gameuser)
3135 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3136 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3137 ## end of LIBX_BASE, but nothing ever set it.
3138 AC_SUBST(LD_SWITCH_X_SITE)
3139 AC_SUBST(C_SWITCH_X_SITE)
3140 AC_SUBST(C_SWITCH_X_SYSTEM)
3141 AC_SUBST(CFLAGS)
3142 ## Used in lwlib/Makefile.in.
3143 AC_SUBST(X_TOOLKIT_TYPE)
3144 AC_SUBST(machfile)
3145 AC_SUBST(opsysfile)
3146 AC_SUBST(GETLOADAVG_LIBS)
3147 AC_SUBST(ns_appdir)
3148 AC_SUBST(ns_appbindir)
3149 AC_SUBST(ns_appresdir)
3150 AC_SUBST(ns_appsrc)
3151 AC_SUBST(GNU_OBJC_CFLAGS)
3152 AC_SUBST(OTHER_FILES)
3153
3154 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3155                    [Define to the canonical Emacs configuration name.])
3156 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3157                    [Define to the options passed to configure.])
3158 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3159                    [Define to the used machine dependent file.])
3160 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3161                    [Define to the used os dependent file.])
3162
3163 XMENU_OBJ=
3164 XOBJ=
3165 FONT_OBJ=
3166 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3167   AC_DEFINE(HAVE_X_WINDOWS, 1,
3168             [Define to 1 if you want to use the X window system.])
3169   XMENU_OBJ=xmenu.o
3170   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3171   FONT_OBJ=xfont.o
3172   if test "$HAVE_XFT" = "yes"; then
3173     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3174   elif test "$HAVE_FREETYPE" = "yes"; then
3175     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3176   fi
3177   AC_SUBST(FONT_OBJ)
3178 fi
3179 AC_SUBST(XMENU_OBJ)
3180 AC_SUBST(XOBJ)
3181 AC_SUBST(FONT_OBJ)
3182
3183 WIDGET_OBJ=
3184 MOTIF_LIBW=
3185 if test "${USE_X_TOOLKIT}" != "none" ; then
3186   WIDGET_OBJ=widget.o
3187   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3188   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3189     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3190   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3191     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3192     MOTIF_LIBW=-lXm
3193     case "$opsys" in
3194       gnu-linux)
3195         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3196         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3197         ;;
3198
3199       unixware)
3200         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3201         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3202         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3203         ;;
3204
3205       aix4-2)
3206         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3207         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3208         ;;
3209     esac
3210     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3211   fi
3212 fi
3213 AC_SUBST(WIDGET_OBJ)
3214
3215 TOOLKIT_LIBW=
3216 case "$USE_X_TOOLKIT" in
3217   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3218   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3219   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3220 esac
3221 AC_SUBST(TOOLKIT_LIBW)
3222
3223 if test "$USE_X_TOOLKIT" = "none"; then
3224   LIBXT_OTHER="\$(LIBXSM)"
3225   OLDXMENU_TARGET="really-oldXMenu"
3226 else
3227   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3228   OLDXMENU_TARGET="really-lwlib"
3229 fi
3230 AC_SUBST(LIBXT_OTHER)
3231
3232 ## The X Menu stuff is present in the X10 distribution, but missing
3233 ## from X11.  If we have X10, just use the installed library;
3234 ## otherwise, use our own copy.
3235 if test "${HAVE_X11}" = "yes" ; then
3236   AC_DEFINE(HAVE_X11, 1,
3237             [Define to 1 if you want to use version 11 of X windows.
3238              Otherwise, Emacs expects to use version 10.])
3239
3240   if test "$USE_X_TOOLKIT" = "none"; then
3241     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3242   else
3243     OLDXMENU="\${lwlibdir}liblw.a"
3244   fi
3245   LIBXMENU="\$(OLDXMENU)"
3246   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3247   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3248 else
3249   ## For a syntactically valid Makefile; not actually used for anything.
3250   ## See comments in src/Makefile.in.
3251   OLDXMENU=nothing
3252   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3253   if test "${HAVE_X_WINDOWS}" = "yes"; then
3254     LIBXMENU="-lXMenu"
3255   else
3256     LIBXMENU=
3257   fi
3258   LIBX_OTHER=
3259   OLDXMENU_DEPS=
3260 fi
3261
3262 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3263   OLDXMENU_TARGET=
3264   OLDXMENU=nothing
3265   LIBXMENU=
3266   OLDXMENU_DEPS=
3267 fi
3268
3269 AC_SUBST(OLDXMENU_TARGET)
3270 AC_SUBST(OLDXMENU)
3271 AC_SUBST(LIBXMENU)
3272 AC_SUBST(LIBX_OTHER)
3273 AC_SUBST(OLDXMENU_DEPS)
3274
3275 if test "${HAVE_MENUS}" = "yes" ; then
3276   AC_DEFINE(HAVE_MENUS, 1,
3277             [Define to 1 if you have mouse menus.
3278              (This is automatic if you use X, but the option to specify it remains.)
3279              It is also defined with other window systems that support xmenu.c.])
3280 fi
3281
3282 if test "${GNU_MALLOC}" = "yes" ; then
3283   AC_DEFINE(GNU_MALLOC, 1,
3284             [Define to 1 if you want to use the GNU memory allocator.])
3285 fi
3286
3287 RALLOC_OBJ=
3288 if test "${REL_ALLOC}" = "yes" ; then
3289   AC_DEFINE(REL_ALLOC, 1,
3290             [Define REL_ALLOC if you want to use the relocating allocator for
3291              buffer space.])
3292
3293   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3294 fi
3295 AC_SUBST(RALLOC_OBJ)
3296
3297 if test "$opsys" = "cygwin"; then
3298   CYGWIN_OBJ="sheap.o"
3299   ## Cygwin differs because of its unexec().
3300   PRE_ALLOC_OBJ=
3301   POST_ALLOC_OBJ=lastfile.o
3302 else
3303   CYGWIN_OBJ=
3304   PRE_ALLOC_OBJ=lastfile.o
3305   POST_ALLOC_OBJ=
3306 fi
3307 AC_SUBST(CYGWIN_OBJ)
3308 AC_SUBST(PRE_ALLOC_OBJ)
3309 AC_SUBST(POST_ALLOC_OBJ)
3310
3311
3312 case "$opsys" in
3313   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3314
3315   darwin)
3316    ## The -headerpad option tells ld (see man page) to leave room at the
3317    ## end of the header for adding load commands.  Needed for dumping.
3318    ## 0x690 is the total size of 30 segment load commands (at 56
3319    ## each); under Cocoa 31 commands are required.
3320    if test "$HAVE_NS" = "yes"; then
3321      libs_nsgui="-framework AppKit"
3322      headerpad_extra=6C8
3323    else
3324      libs_nsgui=
3325      headerpad_extra=690
3326    fi
3327    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3328
3329    ## This is here because src/Makefile.in did some extra fiddling around
3330    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3331    ##   #ifndef LD_SWITCH_SYSTEM
3332    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3333    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3334    ## not using gcc, darwin system not on an alpha (ie darwin, since
3335    ## darwin + alpha does not occur).
3336    ## Because this was done in src/Makefile.in, the resulting part of
3337    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3338    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3339    ## rather than LD_SWITCH_SYSTEM.
3340    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3341      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3342    ;;
3343
3344   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3345   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3346   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3347   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3348   ## had different values in configure (in ac_link) and src/Makefile.in.
3349   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3350   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3351
3352   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3353 esac
3354
3355 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3356   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3357 fi
3358
3359 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3360
3361
3362 LINKER=
3363 ORDINARY_LINK=
3364 case "$opsys" in
3365   ## gnu: GNU needs its own crt0.
3366   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3367
3368   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3369   ## library search parth, i.e. it won't search /usr/lib for libc and
3370   ## friends.  Using -nostartfiles instead avoids this problem, and
3371   ## will also work on earlier NetBSD releases.
3372   netbsd|openbsd) LINKER="\$(CC) -nostartfiles" ;;
3373
3374   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3375   ##   MkLinux/LinuxPPC needs this.
3376   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3377   gnu-*)
3378     case "$machine" in
3379       macppc|ibms390x) LINKER="\$(CC) -nostdlib" ;;
3380     esac
3381     ;;
3382 esac
3383
3384
3385 if test "x$ORDINARY_LINK" = "xyes"; then
3386
3387   LINKER="\$(CC)"
3388   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3389
3390 ## The system files defining neither ORDINARY_LINK nor LINKER are:
3391 ## freebsd, gnu-* not on macppc|ibms390x.
3392 elif test "x$GCC" = "xyes" && test "x$LINKER" = "x"; then
3393
3394   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3395   ## places that are difficult to figure out at make time.  Fortunately,
3396   ## these same versions allow you to pass arbitrary flags on to the
3397   ## linker, so there is no reason not to use it as a linker.
3398   ##
3399   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3400   ## searching for libraries in its internal directories, so we have to
3401   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3402   LINKER="\$(CC) -nostdlib"
3403 fi
3404
3405 test "x$LINKER" = "x" && LINKER=ld
3406 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3407 test "$NS_IMPL_GNUSTEP" = "yes" && LINKER="\$(CC) -rdynamic"
3408
3409 AC_SUBST(LINKER)
3410
3411
3412 ## FIXME? The logic here is not precisely the same as that above.
3413 ## There is no check here for a pre-defined LINKER.
3414 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3415 LIB_GCC=
3416 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3417
3418   case "$opsys" in
3419     freebsd|netbsd|openbsd) LIB_GCC= ;;
3420
3421     gnu-*)
3422       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3423       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3424       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3425       if test "$machine" = "arm"; then
3426         LIB_GCC="-lgcc_s"
3427       else
3428         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3429         ## immediately undefine it again and redefine it to empty.
3430         ## Was the C_SWITCH_X_SITE part really necessary?
3431 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3432         LIB_GCC=
3433       fi
3434       ;;
3435
3436     ## Ask GCC where to find libgcc.a.
3437     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3438   esac
3439 fi                              dnl if $GCC
3440 AC_SUBST(LIB_GCC)
3441
3442
3443 TOOLTIP_SUPPORT=
3444 WINDOW_SUPPORT=
3445 ## If we're using X11/GNUstep, define some consequences.
3446 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3447   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3448   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3449   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3450   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3451
3452   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3453   test "$HAVE_X_WINDOWS" = "yes" && \
3454     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3455
3456 fi
3457 AC_SUBST(MOUSE_SUPPORT)
3458 AC_SUBST(TOOLTIP_SUPPORT)
3459 AC_SUBST(WINDOW_SUPPORT)
3460
3461
3462 AH_TOP([/* GNU Emacs site configuration template file.
3463    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3464      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3465
3466 This file is part of GNU Emacs.
3467
3468 GNU Emacs is free software: you can redistribute it and/or modify
3469 it under the terms of the GNU General Public License as published by
3470 the Free Software Foundation, either version 3 of the License, or
3471 (at your option) any later version.
3472
3473 GNU Emacs is distributed in the hope that it will be useful,
3474 but WITHOUT ANY WARRANTY; without even the implied warranty of
3475 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3476 GNU General Public License for more details.
3477
3478 You should have received a copy of the GNU General Public License
3479 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3480
3481
3482 /* No code in Emacs #includes config.h twice, but some bits of code
3483    intended to work with other packages as well (like gmalloc.c)
3484    think they can include it as many times as they like.  */
3485 #ifndef EMACS_CONFIG_H
3486 #define EMACS_CONFIG_H
3487 ])dnl
3488
3489 AH_BOTTOM([
3490 /* Define AMPERSAND_FULL_NAME if you use the convention
3491    that & in the full name stands for the login id.  */
3492 /* Turned on June 1996 supposing nobody will mind it.  */
3493 #define AMPERSAND_FULL_NAME
3494
3495 /* If using GNU, then support inline function declarations.  */
3496 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3497    generally, because even if non-gcc compilers accept `inline', they
3498    may reject `extern inline'.  */
3499 #if defined (__GNUC__) && defined (OPTIMIZE)
3500 #define INLINE __inline__
3501 #else
3502 #define INLINE
3503 #endif
3504
3505 /* `subprocesses' should be defined if you want to
3506    have code for asynchronous subprocesses
3507    (as used in M-x compile and M-x shell).
3508    Only MSDOS does not support this (it overrides
3509    this in its config_opsysfile below).  */
3510
3511 #define subprocesses
3512
3513 /* Include the os and machine dependent files.  */
3514 #include config_opsysfile
3515 #include config_machfile
3516
3517 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3518   (There is probably a better place to do this, but right now the Cocoa
3519    side does this in s/darwin.h and we cannot
3520    parallel this exactly since GNUstep is multi-OS.  */
3521 #ifdef HAVE_NS
3522 # ifdef NS_IMPL_GNUSTEP
3523 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3524 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3525 #  define SYSTEM_PURESIZE_EXTRA 30000
3526 # endif /* NS_IMPL_GNUSTEP */
3527 #endif /* HAVE_NS */
3528
3529 /* SIGTYPE is the macro we actually use.  */
3530 #ifndef SIGTYPE
3531 #define SIGTYPE RETSIGTYPE
3532 #endif
3533
3534 #ifdef emacs /* Don't do this for lib-src.  */
3535 /* Tell regex.c to use a type compatible with Emacs.  */
3536 #define RE_TRANSLATE_TYPE Lisp_Object
3537 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3538 #ifdef make_number
3539 /* If make_number is a macro, use it.  */
3540 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3541 #else
3542 /* If make_number is a function, avoid it.  */
3543 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3544 #endif
3545 #endif
3546
3547 /* Avoid link-time collision with system mktime if we will use our own.  */
3548 #if ! HAVE_MKTIME || BROKEN_MKTIME
3549 #define mktime emacs_mktime
3550 #endif
3551
3552 #define my_strftime nstrftime   /* for strftime.c */
3553
3554 /* These default definitions are good for almost all machines.
3555    The exceptions override them in m/MACHINE.h.  */
3556
3557 #ifndef BITS_PER_CHAR
3558 #define BITS_PER_CHAR 8
3559 #endif
3560
3561 #ifndef BITS_PER_SHORT
3562 #define BITS_PER_SHORT 16
3563 #endif
3564
3565 /* Note that lisp.h uses this in a preprocessor conditional, so it
3566    would not work to use sizeof.  That being so, we do all of them
3567    without sizeof, for uniformity's sake.  */
3568 #ifndef BITS_PER_INT
3569 #define BITS_PER_INT 32
3570 #endif
3571
3572 #ifndef BITS_PER_LONG
3573 #ifdef _LP64
3574 #define BITS_PER_LONG 64
3575 #else
3576 #define BITS_PER_LONG 32
3577 #endif
3578 #endif
3579
3580 /* Define if the compiler supports function prototypes.  It may do so but
3581    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3582 #undef PROTOTYPES
3583
3584 #ifdef HAVE_STRING_H
3585 #include <string.h>
3586 #endif
3587
3588 #ifdef HAVE_STDLIB_H
3589 #include <stdlib.h>
3590 #endif
3591
3592 #ifdef HAVE_ALLOCA_H
3593 # include <alloca.h>
3594 #elif defined __GNUC__
3595 # define alloca __builtin_alloca
3596 #elif defined _AIX
3597 # define alloca __alloca
3598 #else
3599 # include <stddef.h>
3600 # ifdef  __cplusplus
3601 extern "C"
3602 # endif
3603 void *alloca (size_t);
3604 #endif
3605
3606 #ifndef HAVE_SIZE_T
3607 typedef unsigned size_t;
3608 #endif
3609
3610 #ifndef HAVE_STRCHR
3611 #define strchr(a, b) index (a, b)
3612 #endif
3613
3614 #ifndef HAVE_STRRCHR
3615 #define strrchr(a, b) rindex (a, b)
3616 #endif
3617
3618 #if defined __GNUC__ && (__GNUC__ > 2 \
3619                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3620 #define NO_RETURN       __attribute__ ((__noreturn__))
3621 #else
3622 #define NO_RETURN       /* nothing */
3623 #endif
3624
3625 /* These won't be used automatically yet.  We also need to know, at least,
3626    that the stack is continuous.  */
3627 #ifdef __GNUC__
3628 #  ifndef GC_SETJMP_WORKS
3629   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3630 #    define GC_SETJMP_WORKS 1
3631 #  endif
3632 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3633 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3634 #  endif
3635 #endif
3636
3637 #endif /* EMACS_CONFIG_H */
3638
3639 /*
3640 Local Variables:
3641 mode: c
3642 End:
3643 */
3644 ])dnl
3645
3646 #### Report on what we decided to do.
3647 #### Report GTK as a toolkit, even if it doesn't use Xt.
3648 #### It makes printing result more understandable as using GTK sets
3649 #### toolkit_scroll_bars to yes by default.
3650 if test "${HAVE_GTK}" = "yes"; then
3651   USE_X_TOOLKIT=GTK
3652 fi
3653
3654 echo "
3655 Configured for \`${canonical}'.
3656
3657   Where should the build process find the source code?    ${srcdir}
3658   What operating system and machine description files should Emacs use?
3659         \`${opsysfile}' and \`${machfile}'
3660   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3661   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3662   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3663   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3664   What window system should Emacs use?                    ${window_system}
3665   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3666
3667 if test -n "${x_includes}"; then
3668 echo "  Where do we find X Windows header files?                ${x_includes}"
3669 else
3670 echo "  Where do we find X Windows header files?                Standard dirs"
3671 fi
3672 if test -n "${x_libraries}"; then
3673 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3674 else
3675 echo "  Where do we find X Windows libraries?                   Standard dirs"
3676 fi
3677
3678 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3679 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3680 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3681 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3682 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3683 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3684 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3685 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3686 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3687 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3688 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3689 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3690
3691 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3692 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3693 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3694 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3695
3696 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3697 echo
3698
3699 if test $USE_XASSERTS = yes; then
3700    echo "  Compiling with asserts turned on."
3701    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3702 fi
3703
3704 echo
3705
3706 if test "$HAVE_NS" = "yes"; then
3707    echo
3708    echo "You must run \"make install\" in order to test the built application.
3709 The installed application will go to nextstep/Emacs.app and can be
3710 run or moved from there."
3711    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3712       echo "The application will be fully self-contained."
3713     else
3714       echo "The lisp resources for the application will be installed under ${prefix}.
3715 You may need to run \"make install\" with sudo.  The application will fail
3716 to run if these resources are not installed."
3717    fi
3718    echo
3719 fi
3720
3721 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3722   echo "D-Bus integration has been tested for GNU/Linux only."
3723   echo
3724 fi
3725
3726
3727 # Remove any trailing slashes in these variables.
3728 [test "${prefix}" != NONE &&
3729   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3730 test "${exec_prefix}" != NONE &&
3731   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3732
3733 dnl You might wonder (I did) why epaths.h is generated by running make,
3734 dnl rather than just letting configure generate it from epaths.in.
3735 dnl One reason is that the various paths are not fully expanded (see above);
3736 dnl eg gamedir=${prefix}/var/games/emacs.
3737 dnl Secondly, the GNU Coding standards require that one should be able
3738 dnl to run `make prefix=/some/where/else' and override the values set
3739 dnl by configure.  This also explains the `move-if-change' test and
3740 dnl the use of force in the `epaths-force' rule in Makefile.in.
3741 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3742         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3743         doc/lispref/Makefile src/Makefile \
3744         lwlib/Makefile lisp/Makefile leim/Makefile, [
3745
3746 ### Make the necessary directories, if they don't exist.
3747 for dir in etc lisp ; do
3748   test -d ${dir} || mkdir ${dir}
3749 done
3750
3751 echo creating src/epaths.h
3752 ${MAKE-make} epaths-force
3753
3754 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3755   echo creating src/.gdbinit
3756   echo source $srcdir/src/.gdbinit > src/.gdbinit
3757 fi
3758
3759 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3760
3761 m4_if(dnl       Do not change this comment
3762    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3763 )dnl