lisp/help.el

   1 ;;; help.el --- help commands for Emacs
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2017 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This code implements GNU Emacs's built-in help system, the one invoked by
  28 ;; `M-x help-for-help'.
  29
  30 ;;; Code:
  31
  32 ;; Get the macro make-help-screen when this is compiled,
  33 ;; or run interpreted, but not when the compiled code is loaded.
  34 (eval-when-compile (require 'help-macro))
  35
  36 ;; This makes `with-output-to-temp-buffer' buffers use `help-mode'.
  37 (add-hook 'temp-buffer-setup-hook 'help-mode-setup)
  38 (add-hook 'temp-buffer-show-hook 'help-mode-finish)
  39
  40 ;; `help-window-point-marker' is a marker you can move to a valid
  41 ;; position of the buffer shown in the help window in order to override
  42 ;; the standard positioning mechanism (`point-min') chosen by
  43 ;; `with-output-to-temp-buffer' and `with-temp-buffer-window'.
  44 ;; `with-help-window' has this point nowhere before exiting.  Currently
  45 ;; used by `view-lossage' to assert that the last keystrokes are always
  46 ;; visible.
  47 (defvar help-window-point-marker (make-marker)
  48   "Marker to override default `window-point' in help windows.")
  49
  50 (defvar help-window-old-frame nil
  51   "Frame selected at the time `with-help-window' is invoked.")
  52
  53 (defvar help-map
  54   (let ((map (make-sparse-keymap)))
  55     (define-key map (char-to-string help-char) 'help-for-help)
  56     (define-key map [help] 'help-for-help)
  57     (define-key map [f1] 'help-for-help)
  58     (define-key map "." 'display-local-help)
  59     (define-key map "?" 'help-for-help)
  60
  61     (define-key map "\C-a" 'about-emacs)
  62     (define-key map "\C-c" 'describe-copying)
  63     (define-key map "\C-d" 'view-emacs-debugging)
  64     (define-key map "\C-e" 'view-external-packages)
  65     (define-key map "\C-f" 'view-emacs-FAQ)
  66     (define-key map "\C-m" 'view-order-manuals)
  67     (define-key map "\C-n" 'view-emacs-news)
  68     (define-key map "\C-o" 'describe-distribution)
  69     (define-key map "\C-p" 'view-emacs-problems)
  70     (define-key map "\C-t" 'view-emacs-todo)
  71     (define-key map "\C-w" 'describe-no-warranty)
  72
  73     ;; This does not fit the pattern, but it is natural given the C-\ command.
  74     (define-key map "\C-\\" 'describe-input-method)
  75
  76     (define-key map "C" 'describe-coding-system)
  77     (define-key map "F" 'Info-goto-emacs-command-node)
  78     (define-key map "I" 'describe-input-method)
  79     (define-key map "K" 'Info-goto-emacs-key-command-node)
  80     (define-key map "L" 'describe-language-environment)
  81     (define-key map "S" 'info-lookup-symbol)
  82
  83     (define-key map "a" 'apropos-command)
  84     (define-key map "b" 'describe-bindings)
  85     (define-key map "c" 'describe-key-briefly)
  86     (define-key map "d" 'apropos-documentation)
  87     (define-key map "e" 'view-echo-area-messages)
  88     (define-key map "f" 'describe-function)
  89     (define-key map "g" 'describe-gnu-project)
  90     (define-key map "h" 'view-hello-file)
  91
  92     (define-key map "i" 'info)
  93     (define-key map "4i" 'info-other-window)
  94
  95     (define-key map "k" 'describe-key)
  96     (define-key map "l" 'view-lossage)
  97     (define-key map "m" 'describe-mode)
  98     (define-key map "o" 'describe-symbol)
  99     (define-key map "n" 'view-emacs-news)
 100     (define-key map "p" 'finder-by-keyword)
 101     (define-key map "P" 'describe-package)
 102     (define-key map "r" 'info-emacs-manual)
 103     (define-key map "s" 'describe-syntax)
 104     (define-key map "t" 'help-with-tutorial)
 105     (define-key map "w" 'where-is)
 106     (define-key map "v" 'describe-variable)
 107     (define-key map "q" 'help-quit)
 108     map)
 109   "Keymap for characters following the Help key.")
 110
 111 (define-key global-map (char-to-string help-char) 'help-command)
 112 (define-key global-map [help] 'help-command)
 113 (define-key global-map [f1] 'help-command)
 114 (fset 'help-command help-map)
 115
 116 ;; insert-button makes the action nil if it is not store somewhere
 117 (defvar help-button-cache nil)
 118
 119 \f
 120 (defun help-quit ()
 121   "Just exit from the Help command's command loop."
 122   (interactive)
 123   nil)
 124
 125 (defvar help-return-method nil
 126   "What to do to \"exit\" the help buffer.
 127 This is a list
 128  (WINDOW . t)              delete the selected window (and possibly its frame,
 129                            see `quit-window'), go to WINDOW.
 130  (WINDOW . quit-window)    do quit-window, then select WINDOW.
 131  (WINDOW BUF START POINT)  display BUF at START, POINT, then select WINDOW.")
 132
 133 (define-obsolete-function-alias 'print-help-return-message 'help-print-return-message "23.2")
 134 (defun help-print-return-message (&optional function)
 135   "Display or return message saying how to restore windows after help command.
 136 This function assumes that `standard-output' is the help buffer.
 137 It computes a message, and applies the optional argument FUNCTION to it.
 138 If FUNCTION is nil, it applies `message', thus displaying the message.
 139 In addition, this function sets up `help-return-method', which see, that
 140 specifies what to do when the user exits the help buffer.
 141
 142 Do not call this in the scope of `with-help-window'."
 143   (and (not (get-buffer-window standard-output))
 144        (let ((first-message
 145               (cond ((or
 146                       pop-up-frames
 147                       (special-display-p (buffer-name standard-output)))
 148                      (setq help-return-method (cons (selected-window) t))
 149                      ;; If the help output buffer is a special display buffer,
 150                      ;; don't say anything about how to get rid of it.
 151                      ;; First of all, the user will do that with the window
 152                      ;; manager, not with Emacs.
 153                      ;; Secondly, the buffer has not been displayed yet,
 154                      ;; so we don't know whether its frame will be selected.
 155                      nil)
 156                     ((not (one-window-p t))
 157                      (setq help-return-method
 158                            (cons (selected-window) 'quit-window))
 159                      "Type \\[display-buffer] RET to restore the other window.")
 160                     (pop-up-windows
 161                      (setq help-return-method (cons (selected-window) t))
 162                      "Type \\[delete-other-windows] to remove help window.")
 163                     (t
 164                      (setq help-return-method
 165                            (list (selected-window) (window-buffer)
 166                                  (window-start) (window-point)))
 167                      "Type \\[switch-to-buffer] RET to remove help window."))))
 168          (funcall (or function 'message)
 169                   (concat
 170                    (if first-message
 171                        (substitute-command-keys first-message))
 172                    (if first-message "  ")
 173                    ;; If the help buffer will go in a separate frame,
 174                    ;; it's no use mentioning a command to scroll, so don't.
 175                    (if (or pop-up-windows
 176                            (special-display-p (buffer-name standard-output)))
 177                        nil
 178                      (if (same-window-p (buffer-name standard-output))
 179                          ;; Say how to scroll this window.
 180                          (substitute-command-keys
 181                           "\\[scroll-up] to scroll the help.")
 182                        ;; Say how to scroll some other window.
 183                        (substitute-command-keys
 184                         "\\[scroll-other-window] to scroll the help."))))))))
 185
 186 ;; So keyboard macro definitions are documented correctly
 187 (fset 'defining-kbd-macro (symbol-function 'start-kbd-macro))
 188
 189 (defalias 'help 'help-for-help-internal)
 190 ;; find-function can find this.
 191 (defalias 'help-for-help 'help-for-help-internal)
 192 ;; It can't find this, but nobody will look.
 193 (make-help-screen help-for-help-internal
 194   (purecopy "Type a help option: [abcCdefFgiIkKlLmnprstvw.] C-[cdefmnoptw] or ?")
 195   ;; Don't purecopy this one, because it's not evaluated (it's
 196   ;; directly used as a docstring in a function definition, so it'll
 197   ;; be moved to the DOC file anyway: no need for purecopying it).
 198   "You have typed %THIS-KEY%, the help character.  Type a Help option:
 199 \(Use SPC or DEL to scroll through this text.  Type \\<help-map>\\[help-quit] to exit the Help command.)
 200
 201 a PATTERN   Show commands whose name matches the PATTERN (a list of words
 202               or a regexp).  See also the `apropos' command.
 203 b           Display all key bindings.
 204 c KEYS      Display the command name run by the given key sequence.
 205 C CODING    Describe the given coding system, or RET for current ones.
 206 d PATTERN   Show a list of functions, variables, and other items whose
 207               documentation matches the PATTERN (a list of words or a regexp).
 208 e           Go to the *Messages* buffer which logs echo-area messages.
 209 f FUNCTION  Display documentation for the given function.
 210 F COMMAND   Show the Emacs manual's section that describes the command.
 211 g           Display information about the GNU project.
 212 h           Display the HELLO file which illustrates various scripts.
 213 i           Start the Info documentation reader: read included manuals.
 214 I METHOD    Describe a specific input method, or RET for current.
 215 k KEYS      Display the full documentation for the key sequence.
 216 K KEYS      Show the Emacs manual's section for the command bound to KEYS.
 217 l           Show last 300 input keystrokes (lossage).
 218 L LANG-ENV  Describes a specific language environment, or RET for current.
 219 m           Display documentation of current minor modes and current major mode,
 220               including their special commands.
 221 n           Display news of recent Emacs changes.
 222 o SYMBOL    Display the given function or variable's documentation and value.
 223 p TOPIC     Find packages matching a given topic keyword.
 224 P PACKAGE   Describe the given Emacs Lisp package.
 225 r           Display the Emacs manual in Info mode.
 226 s           Display contents of current syntax table, plus explanations.
 227 S SYMBOL    Show the section for the given symbol in the Info manual
 228               for the programming language used in this buffer.
 229 t           Start the Emacs learn-by-doing tutorial.
 230 v VARIABLE  Display the given variable's documentation and value.
 231 w COMMAND   Display which keystrokes invoke the given command (where-is).
 232 .           Display any available local help at point in the echo area.
 233
 234 C-a         Information about Emacs.
 235 C-c         Emacs copying permission (GNU General Public License).
 236 C-d         Instructions for debugging GNU Emacs.
 237 C-e         External packages and information about Emacs.
 238 C-f         Emacs FAQ.
 239 C-m         How to order printed Emacs manuals.
 240 C-n         News of recent Emacs changes.
 241 C-o         Emacs ordering and distribution information.
 242 C-p         Info about known Emacs problems.
 243 C-t         Emacs TODO list.
 244 C-w         Information on absence of warranty for GNU Emacs."
 245   help-map)
 246
 247 \f
 248
 249 (defun function-called-at-point ()
 250   "Return a function around point or else called by the list containing point.
 251 If that doesn't give a function, return nil."
 252   (with-syntax-table emacs-lisp-mode-syntax-table
 253     (or (condition-case ()
 254             (save-excursion
 255               (or (not (zerop (skip-syntax-backward "_w")))
 256                   (eq (char-syntax (following-char)) ?w)
 257                   (eq (char-syntax (following-char)) ?_)
 258                   (forward-sexp -1))
 259               (skip-chars-forward "'")
 260               (let ((obj (read (current-buffer))))
 261                 (and (symbolp obj) (fboundp obj) obj)))
 262           (error nil))
 263         (condition-case ()
 264             (save-excursion
 265               (save-restriction
 266                 (narrow-to-region (max (point-min)
 267                                        (- (point) 1000)) (point-max))
 268                 ;; Move up to surrounding paren, then after the open.
 269                 (backward-up-list 1)
 270                 (forward-char 1)
 271                 ;; If there is space here, this is probably something
 272                 ;; other than a real Lisp function call, so ignore it.
 273                 (if (looking-at "[ \t]")
 274                     (error "Probably not a Lisp function call"))
 275                 (let ((obj (read (current-buffer))))
 276                   (and (symbolp obj) (fboundp obj) obj))))
 277           (error nil))
 278         (let* ((str (find-tag-default))
 279                (sym (if str (intern-soft str))))
 280           (if (and sym (fboundp sym))
 281               sym
 282             (save-match-data
 283               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 284                 (setq sym (intern-soft (match-string 1 str)))
 285                 (and (fboundp sym) sym))))))))
 286
 287 \f
 288 ;;; `User' help functions
 289
 290 (defun view-help-file (file &optional dir)
 291   (view-file (expand-file-name file (or dir data-directory)))
 292   (goto-address-mode 1)
 293   (goto-char (point-min)))
 294
 295 (defun describe-distribution ()
 296   "Display info on how to obtain the latest version of GNU Emacs."
 297   (interactive)
 298   (view-help-file "DISTRIB"))
 299
 300 (defun describe-copying ()
 301   "Display info on how you may redistribute copies of GNU Emacs."
 302   (interactive)
 303   (view-help-file "COPYING"))
 304
 305 ;; Maybe this command should just be removed.
 306 (defun describe-gnu-project ()
 307   "Browse online information on the GNU project."
 308   (interactive)
 309   (browse-url "https://www.gnu.org/gnu/thegnuproject.html"))
 310
 311 (define-obsolete-function-alias 'describe-project 'describe-gnu-project "22.2")
 312
 313 (defun describe-no-warranty ()
 314   "Display info on all the kinds of warranty Emacs does NOT have."
 315   (interactive)
 316   (describe-copying)
 317   (let (case-fold-search)
 318     (search-forward "Disclaimer of Warranty")
 319     (forward-line 0)
 320     (recenter 0)))
 321
 322 (defun describe-prefix-bindings ()
 323   "Describe the bindings of the prefix used to reach this command.
 324 The prefix described consists of all but the last event
 325 of the key sequence that ran this command."
 326   (interactive)
 327   (let ((key (this-command-keys)))
 328     (describe-bindings
 329      (if (stringp key)
 330          (substring key 0 (1- (length key)))
 331        (let ((prefix (make-vector (1- (length key)) nil))
 332              (i 0))
 333          (while (< i (length prefix))
 334            (aset prefix i (aref key i))
 335            (setq i (1+ i)))
 336          prefix)))))
 337 ;; Make C-h after a prefix, when not specifically bound,
 338 ;; run describe-prefix-bindings.
 339 (setq prefix-help-command 'describe-prefix-bindings)
 340
 341 (defun view-emacs-news (&optional version)
 342   "Display info on recent changes to Emacs.
 343 With argument, display info only for the selected version."
 344   (interactive "P")
 345   (unless version
 346     (setq version emacs-major-version))
 347   (when (consp version)
 348     (let* ((all-versions
 349             (let (res)
 350               (mapc
 351                (lambda (file)
 352                  (with-temp-buffer
 353                    (insert-file-contents
 354                     (expand-file-name file data-directory))
 355                    (while (re-search-forward
 356                            (if (member file '("NEWS.18" "NEWS.1-17"))
 357                                "Changes in \\(?:Emacs\\|version\\)?[ \t]*\\([0-9]+\\(?:\\.[0-9]+\\)?\\)"
 358                              "^\\* [^0-9\n]*\\([0-9]+\\.[0-9]+\\)") nil t)
 359                      (setq res (cons (match-string-no-properties 1) res)))))
 360                (cons "NEWS"
 361                      (directory-files data-directory nil
 362                                       "^NEWS\\.[0-9][-0-9]*$" nil)))
 363               (sort (delete-dups res) #'string>)))
 364            (current (car all-versions)))
 365       (setq version (completing-read
 366                      (format "Read NEWS for the version (default %s): " current)
 367                      all-versions nil nil nil nil current))
 368       (if (integerp (string-to-number version))
 369           (setq version (string-to-number version))
 370         (unless (or (member version all-versions)
 371                     (<= (string-to-number version) (string-to-number current)))
 372           (error "No news about version %s" version)))))
 373   (when (integerp version)
 374     (cond ((<= version 12)
 375            (setq version (format "1.%d" version)))
 376           ((<= version 18)
 377            (setq version (format "%d" version)))
 378           ((> version emacs-major-version)
 379            (error "No news about Emacs %d (yet)" version))))
 380   (let* ((vn (if (stringp version)
 381                  (string-to-number version)
 382                version))
 383          (file (cond
 384                 ((>= vn emacs-major-version) "NEWS")
 385                 ((< vn 18) "NEWS.1-17")
 386                 (t (format "NEWS.%d" vn))))
 387          res)
 388     (view-file (expand-file-name file data-directory))
 389     (widen)
 390     (goto-char (point-min))
 391     (when (stringp version)
 392       (when (re-search-forward
 393              (concat (if (< vn 19)
 394                          "Changes in Emacs[ \t]*"
 395                        "^\\* [^0-9\n]*") version "$")
 396              nil t)
 397         (beginning-of-line)
 398         (narrow-to-region
 399          (point)
 400          (save-excursion
 401            (while (and (setq res
 402                              (re-search-forward
 403                               (if (< vn 19)
 404                                   "Changes in \\(?:Emacs\\|version\\)?[ \t]*\\([0-9]+\\(?:\\.[0-9]+\\)?\\)"
 405                                 "^\\* [^0-9\n]*\\([0-9]+\\.[0-9]+\\)") nil t))
 406                        (equal (match-string-no-properties 1) version)))
 407            (or res (goto-char (point-max)))
 408            (beginning-of-line)
 409            (point)))))))
 410
 411 (defun view-emacs-todo (&optional _arg)
 412   "Display the Emacs TODO list."
 413   (interactive "P")
 414   (view-help-file "TODO"))
 415
 416 (define-obsolete-function-alias 'view-todo 'view-emacs-todo "22.2")
 417
 418
 419 (defun view-echo-area-messages ()
 420   "View the log of recent echo-area messages: the `*Messages*' buffer.
 421 The number of messages retained in that buffer
 422 is specified by the variable `message-log-max'."
 423   (interactive)
 424   (with-current-buffer (messages-buffer)
 425     (goto-char (point-max))
 426     (display-buffer (current-buffer))))
 427
 428 (defun view-order-manuals ()
 429   "Display information on how to buy printed copies of Emacs manuals."
 430   (interactive)
 431 ;;  (view-help-file "ORDERS")
 432   (info "(emacs)Printed Books"))
 433
 434 (defun view-emacs-FAQ ()
 435   "Display the Emacs Frequently Asked Questions (FAQ) file."
 436   (interactive)
 437   ;; (find-file-read-only (expand-file-name "FAQ" data-directory))
 438   (info "(efaq)"))
 439
 440 (defun view-emacs-problems ()
 441   "Display info on known problems with Emacs and possible workarounds."
 442   (interactive)
 443   (view-help-file "PROBLEMS"))
 444
 445 (defun view-emacs-debugging ()
 446   "Display info on how to debug Emacs problems."
 447   (interactive)
 448   (view-help-file "DEBUG"))
 449
 450 ;; This used to visit MORE.STUFF; maybe it should just be removed.
 451 (defun view-external-packages ()
 452   "Display info on where to get more Emacs packages."
 453   (interactive)
 454   (info "(efaq)Packages that do not come with Emacs"))
 455
 456 (defun view-lossage ()
 457   "Display last few input keystrokes and the commands run.
 458
 459 To record all your input, use `open-dribble-file'."
 460   (interactive)
 461   (help-setup-xref (list #'view-lossage)
 462                    (called-interactively-p 'interactive))
 463   (with-help-window (help-buffer)
 464     (princ " ")
 465     (princ (mapconcat (lambda (key)
 466                         (cond
 467                          ((and (consp key) (null (car key)))
 468                           (format "[%s]\n" (if (symbolp (cdr key)) (cdr key)
 469                                            "anonymous-command")))
 470                          ((or (integerp key) (symbolp key) (listp key))
 471                           (single-key-description key))
 472                          (t
 473                           (prin1-to-string key nil))))
 474                       (recent-keys 'include-cmds)
 475                       " "))
 476     (with-current-buffer standard-output
 477       (goto-char (point-min))
 478       (while (not (eobp))
 479         (move-to-column 50)
 480         (unless (eolp)
 481           (fill-region (line-beginning-position) (line-end-position)))
 482         (forward-line 1))
 483       ;; jidanni wants to see the last keystrokes immediately.
 484       (set-marker help-window-point-marker (point)))))
 485
 486 \f
 487 ;; Key bindings
 488
 489 (defun describe-bindings (&optional prefix buffer)
 490   "Display a buffer showing a list of all defined keys, and their definitions.
 491 The keys are displayed in order of precedence.
 492
 493 The optional argument PREFIX, if non-nil, should be a key sequence;
 494 then we display only bindings that start with that prefix.
 495 The optional argument BUFFER specifies which buffer's bindings
 496 to display (default, the current buffer).  BUFFER can be a buffer
 497 or a buffer name."
 498   (interactive)
 499   (or buffer (setq buffer (current-buffer)))
 500   (help-setup-xref (list #'describe-bindings prefix buffer)
 501                    (called-interactively-p 'interactive))
 502   (with-help-window (help-buffer)
 503     ;; Be aware that `describe-buffer-bindings' puts its output into
 504     ;; the current buffer.
 505     (with-current-buffer (help-buffer)
 506       (describe-buffer-bindings buffer prefix))))
 507
 508 ;; This function used to be in keymap.c.
 509 (defun describe-bindings-internal (&optional menus prefix)
 510   "Show a list of all defined keys, and their definitions.
 511 We put that list in a buffer, and display the buffer.
 512
 513 The optional argument MENUS, if non-nil, says to mention menu bindings.
 514 \(Ordinarily these are omitted from the output.)
 515 The optional argument PREFIX, if non-nil, should be a key sequence;
 516 then we display only bindings that start with that prefix."
 517   (declare (obsolete describe-buffer-bindings "24.4"))
 518   (let ((buf (current-buffer)))
 519     (with-help-window (help-buffer)
 520       ;; Be aware that `describe-buffer-bindings' puts its output into
 521       ;; the current buffer.
 522       (with-current-buffer (help-buffer)
 523         (describe-buffer-bindings buf prefix menus)))))
 524
 525 (defun where-is (definition &optional insert)
 526   "Print message listing key sequences that invoke the command DEFINITION.
 527 Argument is a command definition, usually a symbol with a function definition.
 528 If INSERT (the prefix arg) is non-nil, insert the message in the buffer."
 529   (interactive
 530    (let ((fn (function-called-at-point))
 531          (enable-recursive-minibuffers t)
 532          val)
 533      (setq val (completing-read
 534                 (if fn
 535                     (format "Where is command (default %s): " fn)
 536                   "Where is command: ")
 537                 obarray 'commandp t nil nil
 538                 (and fn (symbol-name fn))))
 539      (list (unless (equal val "") (intern val))
 540            current-prefix-arg)))
 541   (unless definition (error "No command"))
 542   (let ((func (indirect-function definition))
 543         (defs nil)
 544         (standard-output (if insert (current-buffer) standard-output)))
 545     ;; In DEFS, find all symbols that are aliases for DEFINITION.
 546     (mapatoms (lambda (symbol)
 547                 (and (fboundp symbol)
 548                      (not (eq symbol definition))
 549                      (eq func (condition-case ()
 550                                   (indirect-function symbol)
 551                                 (error symbol)))
 552                      (push symbol defs))))
 553     ;; Look at all the symbols--first DEFINITION,
 554     ;; then its aliases.
 555     (dolist (symbol (cons definition defs))
 556       (let* ((remapped (command-remapping symbol))
 557              (keys (where-is-internal
 558                     symbol overriding-local-map nil nil remapped))
 559              (keys (mapconcat 'key-description keys ", "))
 560              string)
 561         (setq string
 562               (if insert
 563                   (if (> (length keys) 0)
 564                       (if remapped
 565                           (format "%s (%s) (remapped from %s)"
 566                                   keys remapped symbol)
 567                         (format "%s (%s)" keys symbol))
 568                     (format "M-x %s RET" symbol))
 569                 (if (> (length keys) 0)
 570                     (if remapped
 571                         (format "%s is remapped to %s which is on %s"
 572                                 symbol remapped keys)
 573                       (format "%s is on %s" symbol keys))
 574                   ;; If this is the command the user asked about,
 575                   ;; and it is not on any key, say so.
 576                   ;; For other symbols, its aliases, say nothing
 577                   ;; about them unless they are on keys.
 578                   (if (eq symbol definition)
 579                       (format "%s is not on any key" symbol)))))
 580         (when string
 581           (unless (eq symbol definition)
 582             (princ ";\n its alias "))
 583           (princ string)))))
 584   nil)
 585
 586 (defun help-key-description (key untranslated)
 587   (let ((string (key-description key)))
 588     (if (or (not untranslated)
 589             (and (eq (aref untranslated 0) ?\e) (not (eq (aref key 0) ?\e))))
 590         string
 591       (let ((otherstring (key-description untranslated)))
 592         (if (equal string otherstring)
 593             string
 594           (format "%s (translated from %s)" string otherstring))))))
 595
 596 (defun help--analyze-key (key untranslated)
 597   "Get information about KEY its corresponding UNTRANSLATED events.
 598 Returns a list of the form (BRIEF-DESC DEFN EVENT MOUSE-MSG)."
 599   (if (numberp untranslated)
 600       (setq untranslated (this-single-command-raw-keys)))
 601   (let* ((event (aref key (if (and (symbolp (aref key 0))
 602                                    (> (length key) 1)
 603                                    (consp (aref key 1)))
 604                               1
 605                             0)))
 606          (modifiers (event-modifiers event))
 607          (mouse-msg (if (or (memq 'click modifiers) (memq 'down modifiers)
 608                             (memq 'drag modifiers)) " at that spot" ""))
 609          (defn (key-binding key t)))
 610     ;; Handle the case where we faked an entry in "Select and Paste" menu.
 611     (when (and (eq defn nil)
 612                (stringp (aref key (1- (length key))))
 613                (eq (key-binding (substring key 0 -1)) 'yank-menu))
 614       (setq defn 'menu-bar-select-yank))
 615     ;; Don't bother user with strings from (e.g.) the select-paste menu.
 616     (when (stringp (aref key (1- (length key))))
 617       (aset key (1- (length key)) "(any string)"))
 618     (when (and untranslated
 619                (stringp (aref untranslated (1- (length untranslated)))))
 620       (aset untranslated (1- (length untranslated)) "(any string)"))
 621     (list
 622      ;; Now describe the key, perhaps as changed.
 623      (let ((key-desc (help-key-description key untranslated)))
 624        (if (or (null defn) (integerp defn) (equal defn 'undefined))
 625            (format "%s%s is undefined" key-desc mouse-msg)
 626          (format "%s%s runs the command %S" key-desc mouse-msg defn)))
 627      defn event mouse-msg)))
 628
 629 (defun describe-key-briefly (&optional key insert untranslated)
 630   "Print the name of the function KEY invokes.  KEY is a string.
 631 If INSERT (the prefix arg) is non-nil, insert the message in the buffer.
 632 If non-nil, UNTRANSLATED is a vector of the untranslated events.
 633 It can also be a number in which case the untranslated events from
 634 the last key hit are used.
 635
 636 If KEY is a menu item or a tool-bar button that is disabled, this command
 637 temporarily enables it to allow getting help on disabled items and buttons."
 638   (interactive
 639    ;; Ignore mouse movement events because it's too easy to miss the
 640    ;; message while moving the mouse.
 641    (pcase-let ((`(,key ,_up-event) (help-read-key-sequence 'no-mouse-movement)))
 642      `(,key ,current-prefix-arg 1)))
 643   (princ (car (help--analyze-key key untranslated))
 644          (if insert (current-buffer) standard-output)))
 645
 646 (defun help--key-binding-keymap (key &optional accept-default no-remap position)
 647   "Return a keymap holding a binding for KEY within current keymaps.
 648 The effect of the arguments KEY, ACCEPT-DEFAULT, NO-REMAP and
 649 POSITION is as documented in the function `key-binding'."
 650   (let* ((active-maps (current-active-maps t position))
 651          map found)
 652     ;; We loop over active maps like key-binding does.
 653     (while (and
 654             (not found)
 655             (setq map (pop active-maps)))
 656       (setq found (lookup-key map key accept-default))
 657       (when (integerp found)
 658         ;; The first `found' characters of KEY were found but not the
 659         ;; whole sequence.
 660         (setq found nil)))
 661     (when found
 662       (if (and (symbolp found)
 663                (not no-remap)
 664                (command-remapping found))
 665           ;; The user might want to know in which map the binding is
 666           ;; found, or in which map the remapping is found.  The
 667           ;; default is to show the latter.
 668           (help--key-binding-keymap (vector 'remap found))
 669         map))))
 670
 671 (defun help--binding-locus (key position)
 672   "Describe in which keymap KEY is defined.
 673 Return a symbol pointing to that keymap if one exists ; otherwise
 674 return nil.  The argument POSITION is as documented in the
 675 function `key-binding'."
 676   (let ((map (help--key-binding-keymap key t nil position)))
 677     (when map
 678       (catch 'found
 679         (let ((advertised-syms (nconc
 680                                 (list 'overriding-terminal-local-map
 681                                       'overriding-local-map)
 682                                 (delq nil
 683                                       (mapcar
 684                                        (lambda (mode-and-map)
 685                                          (let ((mode (car mode-and-map)))
 686                                            (when (symbol-value mode)
 687                                              (intern-soft
 688                                               (format "%s-map" mode)))))
 689                                        minor-mode-map-alist))
 690                                 (list 'global-map
 691                                       (intern-soft (format "%s-map" major-mode)))))
 692               found)
 693           ;; Look into these advertised symbols first.
 694           (dolist (sym advertised-syms)
 695             (when (and
 696                    (boundp sym)
 697                    (eq map (symbol-value sym)))
 698               (throw 'found sym)))
 699           ;; Only look in other symbols otherwise.
 700           (mapatoms
 701            (lambda (x)
 702              (when (and (boundp x)
 703                         ;; Avoid let-bound symbols.
 704                         (special-variable-p x)
 705                         (eq (symbol-value x) map))
 706                (throw 'found x))))
 707           nil)))))
 708
 709 (defun help-read-key-sequence (&optional no-mouse-movement)
 710   "Reads a key sequence from the user.
 711 Returns a list of the form (KEY UP-EVENT), where KEY is the key
 712 sequence, and UP-EVENT is the up-event that was discarded by
 713 reading KEY, or nil.
 714 If NO-MOUSE-MOVEMENT is non-nil, ignore key sequences starting
 715 with `mouse-movement' events."
 716   (let ((enable-disabled-menus-and-buttons t)
 717         (cursor-in-echo-area t)
 718         saved-yank-menu)
 719     (unwind-protect
 720         (let (key down-ev)
 721           ;; If yank-menu is empty, populate it temporarily, so that
 722           ;; "Select and Paste" menu can generate a complete event.
 723           (when (null (cdr yank-menu))
 724             (setq saved-yank-menu (copy-sequence yank-menu))
 725             (menu-bar-update-yank-menu "(any string)" nil))
 726           (while
 727               (pcase (setq key (read-key-sequence "\
 728 Describe the following key, mouse click, or menu item: "))
 729                 ((and (pred vectorp) (let `(,key0 . ,_) (aref key 0))
 730                       (guard (symbolp key0)) (let keyname (symbol-name key0)))
 731                  (or
 732                   (and no-mouse-movement
 733                        (string-match "mouse-movement" keyname))
 734                   (and (string-match "\\(mouse\\|down\\|click\\|drag\\)"
 735                                      keyname)
 736                        (progn
 737                          ;; Discard events (e.g. <help-echo>) which might
 738                          ;; spuriously trigger the `sit-for'.
 739                          (sleep-for 0.01)
 740                          (while (read-event nil nil 0.01))
 741                          (not (sit-for (/ double-click-time 1000.0) t))))))))
 742           (list
 743            key
 744            ;; If KEY is a down-event, read and include the
 745            ;; corresponding up-event.  Note that there are also
 746            ;; down-events on scroll bars and mode lines: the actual
 747            ;; event then is in the second element of the vector.
 748            (and (vectorp key)
 749                 (let ((last-idx (1- (length key))))
 750                   (and (eventp (aref key last-idx))
 751                        (memq 'down (event-modifiers (aref key last-idx)))))
 752                 (or (and (eventp (setq down-ev (aref key 0)))
 753                          (memq 'down (event-modifiers down-ev))
 754                          ;; However, for the C-down-mouse-2 popup
 755                          ;; menu, there is no subsequent up-event.  In
 756                          ;; this case, the up-event is the next
 757                          ;; element in the supplied vector.
 758                          (= (length key) 1))
 759                     (and (> (length key) 1)
 760                          (eventp (setq down-ev (aref key 1)))
 761                          (memq 'down (event-modifiers down-ev))))
 762                 (if (and (terminal-parameter nil 'xterm-mouse-mode)
 763                          (equal (terminal-parameter nil 'xterm-mouse-last-down)
 764                                 down-ev))
 765                     (aref (read-key-sequence-vector nil) 0)
 766                   (read-event)))))
 767       ;; Put yank-menu back as it was, if we changed it.
 768       (when saved-yank-menu
 769         (setq yank-menu (copy-sequence saved-yank-menu))
 770         (fset 'yank-menu (cons 'keymap yank-menu))))))
 771
 772 (defun describe-key (&optional key untranslated up-event)
 773   "Display documentation of the function invoked by KEY.
 774 KEY can be any kind of a key sequence; it can include keyboard events,
 775 mouse events, and/or menu events.  When calling from a program,
 776 pass KEY as a string or a vector.
 777
 778 If non-nil, UNTRANSLATED is a vector of the corresponding untranslated events.
 779 It can also be a number, in which case the untranslated events from
 780 the last key sequence entered are used.
 781 UP-EVENT is the up-event that was discarded by reading KEY, or nil.
 782
 783 If KEY is a menu item or a tool-bar button that is disabled, this command
 784 temporarily enables it to allow getting help on disabled items and buttons."
 785   (interactive
 786    (pcase-let ((`(,key ,up-event) (help-read-key-sequence)))
 787      `(,key ,(prefix-numeric-value current-prefix-arg) ,up-event)))
 788   (pcase-let ((`(,brief-desc ,defn ,event ,mouse-msg)
 789                (help--analyze-key key untranslated))
 790               (defn-up nil) (defn-up-tricky nil)
 791               (key-locus-up nil) (key-locus-up-tricky nil)
 792               (mouse-1-remapped nil) (mouse-1-tricky nil)
 793               (ev-type nil))
 794     (if (or (null defn)
 795             (integerp defn)
 796             (equal defn 'undefined))
 797         (message "%s" brief-desc)
 798       (help-setup-xref (list #'describe-function defn)
 799                        (called-interactively-p 'interactive))
 800       ;; Need to do this before erasing *Help* buffer in case event
 801       ;; is a mouse click in an existing *Help* buffer.
 802       (when up-event
 803         (setq ev-type (event-basic-type up-event))
 804         (let ((sequence (vector up-event)))
 805           (when (and (eq ev-type 'mouse-1)
 806                      mouse-1-click-follows-link
 807                      (not (eq mouse-1-click-follows-link 'double))
 808                      (setq mouse-1-remapped
 809                            (mouse-on-link-p (event-start up-event))))
 810             (setq mouse-1-tricky (and (integerp mouse-1-click-follows-link)
 811                                       (> mouse-1-click-follows-link 0)))
 812             (cond ((stringp mouse-1-remapped)
 813                    (setq sequence mouse-1-remapped))
 814                   ((vectorp mouse-1-remapped)
 815                    (setcar up-event (elt mouse-1-remapped 0)))
 816                   (t (setcar up-event 'mouse-2))))
 817           (setq defn-up (key-binding sequence nil nil (event-start up-event)))
 818           (setq key-locus-up (help--binding-locus sequence (event-start up-event)))
 819           (when mouse-1-tricky
 820             (setq sequence (vector up-event))
 821             (aset sequence 0 'mouse-1)
 822             (setq defn-up-tricky (key-binding sequence nil nil (event-start up-event)))
 823             (setq key-locus-up-tricky (help--binding-locus sequence (event-start up-event))))))
 824       (with-help-window (help-buffer)
 825         (princ brief-desc)
 826         (let ((key-locus (help--binding-locus key (event-start event))))
 827           (when key-locus
 828             (princ (format " (found in %s)" key-locus))))
 829         (princ ", which is ")
 830         (describe-function-1 defn)
 831         (when up-event
 832           (unless (or (null defn-up)
 833                       (integerp defn-up)
 834                       (equal defn-up 'undefined))
 835             (princ (format "
 836
 837 ----------------- up-event %s----------------
 838
 839 %s%s%s runs the command %S%s, which is "
 840                            (if mouse-1-tricky "(short click) " "")
 841                            (key-description (vector up-event))
 842                            mouse-msg
 843                            (if mouse-1-remapped
 844                                " is remapped to <mouse-2>, which" "")
 845                            defn-up (if key-locus-up
 846                                        (format " (found in %s)" key-locus-up)
 847                                      "")))
 848             (describe-function-1 defn-up))
 849           (unless (or (null defn-up-tricky)
 850                       (integerp defn-up-tricky)
 851                       (eq defn-up-tricky 'undefined))
 852             (princ (format "
 853
 854 ----------------- up-event (long click) ----------------
 855
 856 Pressing <%S>%s for longer than %d milli-seconds
 857 runs the command %S%s, which is "
 858                            ev-type mouse-msg
 859                            mouse-1-click-follows-link
 860                            defn-up-tricky (if key-locus-up-tricky
 861                                               (format " (found in %s)" key-locus-up-tricky)
 862                                             "")))
 863             (describe-function-1 defn-up-tricky)))))))
 864 \f
 865 (defun describe-mode (&optional buffer)
 866   "Display documentation of current major mode and minor modes.
 867 A brief summary of the minor modes comes first, followed by the
 868 major mode description.  This is followed by detailed
 869 descriptions of the minor modes, each on a separate page.
 870
 871 For this to work correctly for a minor mode, the mode's indicator
 872 variable \(listed in `minor-mode-alist') must also be a function
 873 whose documentation describes the minor mode.
 874
 875 If called from Lisp with a non-nil BUFFER argument, display
 876 documentation for the major and minor modes of that buffer."
 877   (interactive "@")
 878   (unless buffer (setq buffer (current-buffer)))
 879   (help-setup-xref (list #'describe-mode buffer)
 880                    (called-interactively-p 'interactive))
 881   ;; For the sake of help-do-xref and help-xref-go-back,
 882   ;; don't switch buffers before calling `help-buffer'.
 883   (with-help-window (help-buffer)
 884     (with-current-buffer buffer
 885       (let (minor-modes)
 886         ;; Older packages do not register in minor-mode-list but only in
 887         ;; minor-mode-alist.
 888         (dolist (x minor-mode-alist)
 889           (setq x (car x))
 890           (unless (memq x minor-mode-list)
 891             (push x minor-mode-list)))
 892         ;; Find enabled minor mode we will want to mention.
 893         (dolist (mode minor-mode-list)
 894           ;; Document a minor mode if it is listed in minor-mode-alist,
 895           ;; non-nil, and has a function definition.
 896           (let ((fmode (or (get mode :minor-mode-function) mode)))
 897             (and (boundp mode) (symbol-value mode)
 898                  (fboundp fmode)
 899                  (let ((pretty-minor-mode
 900                         (if (string-match "\\(\\(-minor\\)?-mode\\)?\\'"
 901                                           (symbol-name fmode))
 902                             (capitalize
 903                              (substring (symbol-name fmode)
 904                                         0 (match-beginning 0)))
 905                           fmode)))
 906                    (push (list fmode pretty-minor-mode
 907                                (format-mode-line (assq mode minor-mode-alist)))
 908                          minor-modes)))))
 909         (setq minor-modes
 910               (sort minor-modes
 911                     (lambda (a b) (string-lessp (cadr a) (cadr b)))))
 912         (when minor-modes
 913           (princ "Enabled minor modes:\n")
 914           (make-local-variable 'help-button-cache)
 915           (with-current-buffer standard-output
 916             (dolist (mode minor-modes)
 917               (let ((mode-function (nth 0 mode))
 918                     (pretty-minor-mode (nth 1 mode))
 919                     (indicator (nth 2 mode)))
 920                 (save-excursion
 921                   (goto-char (point-max))
 922                   (princ "\n\f\n")
 923                   (push (point-marker) help-button-cache)
 924                   ;; Document the minor modes fully.
 925                   (insert-text-button
 926                    pretty-minor-mode 'type 'help-function
 927                    'help-args (list mode-function)
 928                    'button '(t))
 929                   (princ (format " minor mode (%s):\n"
 930                                  (if (zerop (length indicator))
 931                                      "no indicator"
 932                                    (format "indicator%s"
 933                                            indicator))))
 934                   (princ (documentation mode-function)))
 935                 (insert-button pretty-minor-mode
 936                                'action (car help-button-cache)
 937                                'follow-link t
 938                                'help-echo "mouse-2, RET: show full information")
 939                 (newline)))
 940             (forward-line -1)
 941             (fill-paragraph nil)
 942             (forward-line 1))
 943
 944           (princ "\n(Information about these minor modes follows the major mode info.)\n\n"))
 945         ;; Document the major mode.
 946         (let ((mode mode-name))
 947           (with-current-buffer standard-output
 948             (let ((start (point)))
 949               (insert (format-mode-line mode nil nil buffer))
 950               (add-text-properties start (point) '(face bold)))))
 951         (princ " mode")
 952         (let* ((mode major-mode)
 953                (file-name (find-lisp-object-file-name mode nil)))
 954           (when file-name
 955             (princ (format-message " defined in `%s'"
 956                                    (file-name-nondirectory file-name)))
 957             ;; Make a hyperlink to the library.
 958             (with-current-buffer standard-output
 959               (save-excursion
 960                 (re-search-backward (substitute-command-keys "`\\([^`']+\\)'")
 961                                     nil t)
 962                 (help-xref-button 1 'help-function-def mode file-name)))))
 963         (princ ":\n")
 964         (princ (documentation major-mode)))))
 965   ;; For the sake of IELM and maybe others
 966   nil)
 967
 968
 969 (defun describe-minor-mode (minor-mode)
 970   "Display documentation of a minor mode given as MINOR-MODE.
 971 MINOR-MODE can be a minor mode symbol or a minor mode indicator string
 972 appeared on the mode-line."
 973   (interactive (list (completing-read
 974                       "Minor mode: "
 975                               (nconc
 976                                (describe-minor-mode-completion-table-for-symbol)
 977                                (describe-minor-mode-completion-table-for-indicator)
 978                                ))))
 979   (if (symbolp minor-mode)
 980       (setq minor-mode (symbol-name minor-mode)))
 981   (let ((symbols (describe-minor-mode-completion-table-for-symbol))
 982         (indicators (describe-minor-mode-completion-table-for-indicator)))
 983     (cond
 984      ((member minor-mode symbols)
 985       (describe-minor-mode-from-symbol (intern minor-mode)))
 986      ((member minor-mode indicators)
 987       (describe-minor-mode-from-indicator minor-mode))
 988      (t
 989       (error "No such minor mode: %s" minor-mode)))))
 990
 991 ;; symbol
 992 (defun describe-minor-mode-completion-table-for-symbol ()
 993   ;; In order to list up all minor modes, minor-mode-list
 994   ;; is used here instead of minor-mode-alist.
 995   (delq nil (mapcar 'symbol-name minor-mode-list)))
 996
 997 (defun describe-minor-mode-from-symbol (symbol)
 998   "Display documentation of a minor mode given as a symbol, SYMBOL"
 999   (interactive (list (intern (completing-read
1000                               "Minor mode symbol: "
1001                               (describe-minor-mode-completion-table-for-symbol)))))
1002   (if (fboundp symbol)
1003       (describe-function symbol)
1004     (describe-variable symbol)))
1005
1006 ;; indicator
1007 (defun describe-minor-mode-completion-table-for-indicator ()
1008   (delq nil
1009         (mapcar (lambda (x)
1010                   (let ((i (format-mode-line x)))
1011                     ;; remove first space if existed
1012                     (cond
1013                      ((= 0 (length i))
1014                       nil)
1015                      ((eq (aref i 0) ?\s)
1016                       (substring i 1))
1017                      (t
1018                       i))))
1019                 minor-mode-alist)))
1020
1021 (defun describe-minor-mode-from-indicator (indicator)
1022   "Display documentation of a minor mode specified by INDICATOR.
1023 If you call this function interactively, you can give indicator which
1024 is currently activated with completion."
1025   (interactive (list
1026                 (completing-read
1027                  "Minor mode indicator: "
1028                  (describe-minor-mode-completion-table-for-indicator))))
1029   (let ((minor-mode (lookup-minor-mode-from-indicator indicator)))
1030     (if minor-mode
1031         (describe-minor-mode-from-symbol minor-mode)
1032       (error "Cannot find minor mode for `%s'" indicator))))
1033
1034 (defun lookup-minor-mode-from-indicator (indicator)
1035   "Return a minor mode symbol from its indicator on the mode line."
1036   ;; remove first space if existed
1037   (if (and (< 0 (length indicator))
1038            (eq (aref indicator 0) ?\s))
1039       (setq indicator (substring indicator 1)))
1040   (let ((minor-modes minor-mode-alist)
1041         result)
1042     (while minor-modes
1043       (let* ((minor-mode (car (car minor-modes)))
1044              (anindicator (format-mode-line
1045                            (car (cdr (car minor-modes))))))
1046         ;; remove first space if existed
1047         (if (and (stringp anindicator)
1048                  (> (length anindicator) 0)
1049                  (eq (aref anindicator 0) ?\s))
1050             (setq anindicator (substring anindicator 1)))
1051         (if (equal indicator anindicator)
1052             (setq result minor-mode
1053                   minor-modes nil)
1054           (setq minor-modes (cdr minor-modes)))))
1055     result))
1056 \f
1057 ;;; Automatic resizing of temporary buffers.
1058 (defcustom temp-buffer-max-height
1059   (lambda (buffer)
1060     (if (and (display-graphic-p) (eq (selected-window) (frame-root-window)))
1061         (/ (x-display-pixel-height) (frame-char-height) 2)
1062       (/ (- (frame-height) 2) 2)))
1063   "Maximum height of a window displaying a temporary buffer.
1064 This is effective only when Temp Buffer Resize mode is enabled.
1065 The value is the maximum height (in lines) which
1066 `resize-temp-buffer-window' will give to a window displaying a
1067 temporary buffer.  It can also be a function to be called to
1068 choose the height for such a buffer.  It gets one argument, the
1069 buffer, and should return a positive integer.  At the time the
1070 function is called, the window to be resized is selected."
1071   :type '(choice integer function)
1072   :group 'help
1073   :version "24.3")
1074
1075 (defcustom temp-buffer-max-width
1076   (lambda (buffer)
1077     (if (and (display-graphic-p) (eq (selected-window) (frame-root-window)))
1078         (/ (x-display-pixel-width) (frame-char-width) 2)
1079       (/ (- (frame-width) 2) 2)))
1080   "Maximum width of a window displaying a temporary buffer.
1081 This is effective only when Temp Buffer Resize mode is enabled.
1082 The value is the maximum width (in columns) which
1083 `resize-temp-buffer-window' will give to a window displaying a
1084 temporary buffer.  It can also be a function to be called to
1085 choose the width for such a buffer.  It gets one argument, the
1086 buffer, and should return a positive integer.  At the time the
1087 function is called, the window to be resized is selected."
1088   :type '(choice integer function)
1089   :group 'help
1090   :version "24.4")
1091
1092 (define-minor-mode temp-buffer-resize-mode
1093   "Toggle auto-resizing temporary buffer windows (Temp Buffer Resize Mode).
1094 With a prefix argument ARG, enable Temp Buffer Resize mode if ARG
1095 is positive, and disable it otherwise.  If called from Lisp,
1096 enable the mode if ARG is omitted or nil.
1097
1098 When Temp Buffer Resize mode is enabled, the windows in which we
1099 show a temporary buffer are automatically resized in height to
1100 fit the buffer's contents, but never more than
1101 `temp-buffer-max-height' nor less than `window-min-height'.
1102
1103 A window is resized only if it has been specially created for the
1104 buffer.  Windows that have shown another buffer before are not
1105 resized.  A frame is resized only if `fit-frame-to-buffer' is
1106 non-nil.
1107
1108 This mode is used by `help', `apropos' and `completion' buffers,
1109 and some others."
1110   :global t :group 'help
1111   (if temp-buffer-resize-mode
1112       ;; `help-make-xrefs' may add a `back' button and thus increase the
1113       ;; text size, so `resize-temp-buffer-window' must be run *after* it.
1114       (add-hook 'temp-buffer-show-hook 'resize-temp-buffer-window 'append)
1115     (remove-hook 'temp-buffer-show-hook 'resize-temp-buffer-window)))
1116
1117 (defun resize-temp-buffer-window (&optional window)
1118   "Resize WINDOW to fit its contents.
1119 WINDOW must be a live window and defaults to the selected one.
1120 Do not resize if WINDOW was not created by `display-buffer'.
1121
1122 If WINDOW is part of a vertical combination, restrain its new
1123 size by `temp-buffer-max-height' and do not resize if its minimum
1124 accessible position is scrolled out of view.  If WINDOW is part
1125 of a horizontal combination, restrain its new size by
1126 `temp-buffer-max-width'.  In both cases, the value of the option
1127 `fit-window-to-buffer-horizontally' can inhibit resizing.
1128
1129 If WINDOW is the root window of its frame, resize the frame
1130 provided `fit-frame-to-buffer' is non-nil.
1131
1132 This function may call `preserve-window-size' to preserve the
1133 size of WINDOW."
1134   (setq window (window-normalize-window window t))
1135   (let ((height (if (functionp temp-buffer-max-height)
1136                     (with-selected-window window
1137                       (funcall temp-buffer-max-height (window-buffer)))
1138                   temp-buffer-max-height))
1139         (width (if (functionp temp-buffer-max-width)
1140                    (with-selected-window window
1141                      (funcall temp-buffer-max-width (window-buffer)))
1142                  temp-buffer-max-width))
1143         (quit-cadr (cadr (window-parameter window 'quit-restore))))
1144     ;; Resize WINDOW iff it was made by `display-buffer'.
1145     (when (or (and (eq quit-cadr 'window)
1146                    (or (and (window-combined-p window)
1147                             (not (eq fit-window-to-buffer-horizontally
1148                                      'only))
1149                             (pos-visible-in-window-p (point-min) window))
1150                        (and (window-combined-p window t)
1151                             fit-window-to-buffer-horizontally)))
1152               (and (eq quit-cadr 'frame)
1153                    fit-frame-to-buffer
1154                    (eq window (frame-root-window window))))
1155         (fit-window-to-buffer window height nil width nil t))))
1156
1157 ;;; Help windows.
1158 (defcustom help-window-select nil
1159   "Non-nil means select help window for viewing.
1160 Choices are:
1161
1162  never (nil) Select help window only if there is no other window
1163              on its frame.
1164
1165  other       Select help window if and only if it appears on the
1166              previously selected frame, that frame contains at
1167              least two other windows and the help window is
1168              either new or showed a different buffer before.
1169
1170  always (t)  Always select the help window.
1171
1172 If this option is non-nil and the help window appears on another
1173 frame, then give that frame input focus too.  Note also that if
1174 the help window appears on another frame, it may get selected and
1175 its frame get input focus even if this option is nil.
1176
1177 This option has effect if and only if the help window was created
1178 by `with-help-window'."
1179   :type '(choice (const :tag "never (nil)" nil)
1180                  (const :tag "other" other)
1181                  (const :tag "always (t)" t))
1182   :group 'help
1183   :version "23.1")
1184
1185 (defcustom help-enable-auto-load t
1186   "Whether Help commands can perform autoloading.
1187 If non-nil, whenever \\[describe-function] is called for an
1188 autoloaded function whose docstring contains any key substitution
1189 construct (see `substitute-command-keys'), the library is loaded,
1190 so that the documentation can show the right key bindings."
1191   :type 'boolean
1192   :group 'help
1193   :version "24.3")
1194
1195 (defun help-window-display-message (quit-part window &optional scroll)
1196   "Display message telling how to quit and scroll help window.
1197 QUIT-PART is a string telling how to quit the help window WINDOW.
1198 Optional argument SCROLL non-nil means tell how to scroll WINDOW.
1199 SCROLL equal `other' means tell how to scroll the \"other\"
1200 window."
1201   (let ((scroll-part
1202          (cond
1203           ;; If we don't have QUIT-PART we probably reuse a window
1204           ;; showing the same buffer so we don't show any message.
1205           ((not quit-part) nil)
1206           ((pos-visible-in-window-p
1207             (with-current-buffer (window-buffer window)
1208               (point-max)) window t)
1209            ;; Buffer end is at least partially visible, no need to talk
1210            ;; about scrolling.
1211            ".")
1212           ((eq scroll 'other)
1213            ", \\[scroll-other-window] to scroll help.")
1214           (scroll ", \\[scroll-up] to scroll help."))))
1215     (message "%s"
1216      (substitute-command-keys (concat quit-part scroll-part)))))
1217
1218 (defun help-window-setup (window &optional value)
1219   "Set up help window WINDOW for `with-help-window'.
1220 WINDOW is the window used for displaying the help buffer.
1221 Return VALUE."
1222   (let* ((help-buffer (when (window-live-p window)
1223                         (window-buffer window)))
1224          (help-setup (when (window-live-p window)
1225                        (car (window-parameter window 'quit-restore))))
1226          (frame (window-frame window)))
1227
1228     (when help-buffer
1229       ;; Handle `help-window-point-marker'.
1230       (when (eq (marker-buffer help-window-point-marker) help-buffer)
1231         (set-window-point window help-window-point-marker)
1232         ;; Reset `help-window-point-marker'.
1233         (set-marker help-window-point-marker nil))
1234
1235       ;; If the help window appears on another frame, select it if
1236       ;; `help-window-select' is non-nil and give that frame input focus
1237       ;; too.  See also Bug#19012.
1238       (when (and help-window-select
1239                  (frame-live-p help-window-old-frame)
1240                  (not (eq frame help-window-old-frame)))
1241         (select-window window)
1242         (select-frame-set-input-focus frame))
1243
1244       (cond
1245        ((or (eq window (selected-window))
1246             ;; If the help window is on the selected frame, select
1247             ;; it if `help-window-select' is t or `help-window-select'
1248             ;; is 'other, the frame contains at least three windows, and
1249             ;; the help window did show another buffer before.  See also
1250             ;; Bug#11039.
1251             (and (eq frame (selected-frame))
1252                  (or (eq help-window-select t)
1253                      (and (eq help-window-select 'other)
1254                           (> (length (window-list nil 'no-mini)) 2)
1255                           (not (eq help-setup 'same))))
1256                  (select-window window)))
1257         ;; The help window is or gets selected ...
1258         (help-window-display-message
1259          (cond
1260           ((eq help-setup 'window)
1261            ;; ... and is new, ...
1262            "Type \"q\" to delete help window")
1263           ((eq help-setup 'frame)
1264            ;; ... on a new frame, ...
1265            "Type \"q\" to quit the help frame")
1266           ((eq help-setup 'other)
1267            ;; ... or displayed some other buffer before.
1268            "Type \"q\" to restore previous buffer"))
1269          window t))
1270        ((and (eq (window-frame window) help-window-old-frame)
1271              (= (length (window-list nil 'no-mini)) 2))
1272         ;; There are two windows on the help window's frame and the
1273         ;; other one is the selected one.
1274         (help-window-display-message
1275          (cond
1276           ((eq help-setup 'window)
1277            "Type \\[delete-other-windows] to delete the help window")
1278           ((eq help-setup 'other)
1279            "Type \"q\" in help window to restore its previous buffer"))
1280          window 'other))
1281        (t
1282         ;; The help window is not selected ...
1283         (help-window-display-message
1284          (cond
1285           ((eq help-setup 'window)
1286            ;; ... and is new, ...
1287            "Type \"q\" in help window to delete it")
1288           ((eq help-setup 'other)
1289            ;; ... or displayed some other buffer before.
1290            "Type \"q\" in help window to restore previous buffer"))
1291          window))))
1292     ;; Return VALUE.
1293     value))
1294
1295 ;; `with-help-window' is a wrapper for `with-temp-buffer-window'
1296 ;; providing the following additional twists:
1297
1298 ;; (1) It puts the buffer in `help-mode' (via `help-mode-setup') and
1299 ;;     adds cross references (via `help-mode-finish').
1300
1301 ;; (2) It issues a message telling how to scroll and quit the help
1302 ;;     window (via `help-window-setup').
1303
1304 ;; (3) An option (customizable via `help-window-select') to select the
1305 ;;     help window automatically.
1306
1307 ;; (4) A marker (`help-window-point-marker') to move point in the help
1308 ;;     window to an arbitrary buffer position.
1309 (defmacro with-help-window (buffer-name &rest body)
1310   "Display buffer named BUFFER-NAME in a help window.
1311 Evaluate the forms in BODY with standard output bound to a buffer
1312 called BUFFER-NAME (creating it if it does not exist), put that
1313 buffer in `help-mode', display the buffer in a window (see
1314 `with-temp-buffer-window' for details) and issue a message how to
1315 deal with that \"help\" window when it's no more needed.  Select
1316 the help window if the current value of the user option
1317 `help-window-select' says so.  Return last value in BODY."
1318   (declare (indent 1) (debug t))
1319   `(progn
1320      ;; Make `help-window-point-marker' point nowhere.  The only place
1321      ;; where this should be set to a buffer position is within BODY.
1322      (set-marker help-window-point-marker nil)
1323      (let ((temp-buffer-window-setup-hook
1324             (cons 'help-mode-setup temp-buffer-window-setup-hook))
1325            (temp-buffer-window-show-hook
1326             (cons 'help-mode-finish temp-buffer-window-show-hook)))
1327        (setq help-window-old-frame (selected-frame))
1328        (with-temp-buffer-window
1329         ,buffer-name nil 'help-window-setup (progn ,@body)))))
1330
1331 ;; Called from C, on encountering `help-char' when reading a char.
1332 ;; Don't print to *Help*; that would clobber Help history.
1333 (defun help-form-show ()
1334   "Display the output of a non-nil `help-form'."
1335   (let ((msg (eval help-form)))
1336     (if (stringp msg)
1337         (with-output-to-temp-buffer " *Char Help*"
1338           (princ msg)))))
1339
1340 \f
1341 (defun help--docstring-quote (string)
1342   "Return a doc string that represents STRING.
1343 The result, when formatted by `substitute-command-keys', should equal STRING."
1344   (replace-regexp-in-string "['\\`‘’]" "\\\\=\\&" string))
1345
1346 ;; The following functions used to be in help-fns.el, which is not preloaded.
1347 ;; But for various reasons, they are more widely needed, so they were
1348 ;; moved to this file, which is preloaded.  https://debbugs.gnu.org/17001
1349
1350 (defun help-split-fundoc (docstring def)
1351   "Split a function DOCSTRING into the actual doc and the usage info.
1352 Return (USAGE . DOC) or nil if there's no usage info, where USAGE info
1353 is a string describing the argument list of DEF, such as
1354 \"(apply FUNCTION &rest ARGUMENTS)\".
1355 DEF is the function whose usage we're looking for in DOCSTRING."
1356   ;; Functions can get the calling sequence at the end of the doc string.
1357   ;; In cases where `function' has been fset to a subr we can't search for
1358   ;; function's name in the doc string so we use `fn' as the anonymous
1359   ;; function name instead.
1360   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
1361     (let ((doc (unless (zerop (match-beginning 0))
1362                  (substring docstring 0 (match-beginning 0))))
1363           (usage-tail (match-string 1 docstring)))
1364       (cons (format "(%s%s"
1365                     ;; Replace `fn' with the actual function name.
1366                     (if (symbolp def)
1367                         (help--docstring-quote (format "%S" def))
1368                       'anonymous)
1369                     usage-tail)
1370             doc))))
1371
1372 (defun help-add-fundoc-usage (docstring arglist)
1373   "Add the usage info to DOCSTRING.
1374 If DOCSTRING already has a usage info, then just return it unchanged.
1375 The usage info is built from ARGLIST.  DOCSTRING can be nil.
1376 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
1377   (unless (stringp docstring) (setq docstring ""))
1378   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring)
1379           (eq arglist t))
1380       docstring
1381     (concat docstring
1382             (if (string-match "\n?\n\\'" docstring)
1383                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
1384               "\n\n")
1385             (if (stringp arglist)
1386                 (if (string-match "\\`[^ ]+\\(.*\\))\\'" arglist)
1387                     (concat "(fn" (match-string 1 arglist) ")")
1388                   (error "Unrecognized usage format"))
1389               (help--make-usage-docstring 'fn arglist)))))
1390
1391 (defun help-function-arglist (def &optional preserve-names)
1392   "Return a formal argument list for the function DEF.
1393 If PRESERVE-NAMES is non-nil, return a formal arglist that uses
1394 the same names as used in the original source code, when possible."
1395   ;; Handle symbols aliased to other symbols.
1396   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
1397   ;; Advice wrappers have "catch all" args, so fetch the actual underlying
1398   ;; function to find the real arguments.
1399   (while (advice--p def) (setq def (advice--cdr def)))
1400   ;; If definition is a macro, find the function inside it.
1401   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
1402   (cond
1403    ((and (byte-code-function-p def) (listp (aref def 0))) (aref def 0))
1404    ((eq (car-safe def) 'lambda) (nth 1 def))
1405    ((eq (car-safe def) 'closure) (nth 2 def))
1406    ((or (and (byte-code-function-p def) (integerp (aref def 0)))
1407         (subrp def) (module-function-p def))
1408     (or (when preserve-names
1409           (let* ((doc (condition-case nil (documentation def) (error nil)))
1410                  (docargs (if doc (car (help-split-fundoc doc nil))))
1411                  (arglist (if docargs
1412                               (cdar (read-from-string (downcase docargs)))))
1413                  (valid t))
1414             ;; Check validity.
1415             (dolist (arg arglist)
1416               (unless (and (symbolp arg)
1417                            (let ((name (symbol-name arg)))
1418                              (if (eq (aref name 0) ?&)
1419                                  (memq arg '(&rest &optional))
1420                                (not (string-match "\\." name)))))
1421                 (setq valid nil)))
1422             (when valid arglist)))
1423         (let* ((arity (func-arity def))
1424                (max (cdr arity))
1425                (min (car arity))
1426                (arglist ()))
1427           (dotimes (i min)
1428             (push (intern (concat "arg" (number-to-string (1+ i)))) arglist))
1429           (when (and (integerp max) (> max min))
1430             (push '&optional arglist)
1431             (dotimes (i (- max min))
1432               (push (intern (concat "arg" (number-to-string (+ 1 i min))))
1433                     arglist)))
1434           (unless (integerp max) (push '&rest arglist) (push 'rest arglist))
1435           (nreverse arglist))))
1436    ((and (autoloadp def) (not (eq (nth 4 def) 'keymap)))
1437     "[Arg list not available until function definition is loaded.]")
1438    (t t)))
1439
1440 (defun help--make-usage (function arglist)
1441   (cons (if (symbolp function) function 'anonymous)
1442         (mapcar (lambda (arg)
1443                   (if (not (symbolp arg)) arg
1444                     (let ((name (symbol-name arg)))
1445                       (cond
1446                        ((string-match "\\`&" name) arg)
1447                        ((string-match "\\`_." name)
1448                         (intern (upcase (substring name 1))))
1449                        (t (intern (upcase name)))))))
1450                 arglist)))
1451
1452 (define-obsolete-function-alias 'help-make-usage 'help--make-usage "25.1")
1453
1454 (defun help--make-usage-docstring (fn arglist)
1455   (let ((print-escape-newlines t))
1456     (help--docstring-quote (format "%S" (help--make-usage fn arglist)))))
1457
1458 \f
1459 (provide 'help)
1460
1461 ;;; help.el ends here