lisp/emacs-lisp/cl.el

   1 ;;; cl.el --- Compatibility aliases for the old CL library.  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2012  Free Software Foundation, Inc.
   4
   5 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   6 ;; Keywords: extensions
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This is a compatibility file which provides the old names provided by CL
  26 ;; before we cleaned up its namespace usage.
  27
  28 ;;; Code:
  29
  30 (require 'cl-lib)
  31 (require 'macroexp)
  32
  33 ;; (defun cl--rename ()
  34 ;;   (let ((vdefs ())
  35 ;;         (fdefs ())
  36 ;;         (case-fold-search nil)
  37 ;;         (files '("cl.el" "cl-macs.el" "cl-seq.el" "cl-extra.el")))
  38 ;;     (dolist (file files)
  39 ;;       (with-current-buffer (find-file-noselect file)
  40 ;;         (goto-char (point-min))
  41 ;;         (while (re-search-forward
  42 ;;                 "^(\\(def[^ \t\n]*\\) +'?\\(\\(\\sw\\|\\s_\\)+\\)" nil t)
  43 ;;           (let ((name (match-string-no-properties 2))
  44 ;;                 (type (match-string-no-properties 1)))
  45 ;;             (unless (string-match-p "\\`cl-" name)
  46 ;;               (cond
  47 ;;                ((member type '("defvar" "defconst"))
  48 ;;                 (unless (member name vdefs) (push name vdefs)))
  49 ;;                ((member type '("defun" "defsubst" "defalias" "defmacro"))
  50 ;;                 (unless (member name fdefs) (push name fdefs)))
  51 ;;                ((member type '("def-edebug-spec" "defsetf" "define-setf-method"
  52 ;;                                "define-compiler-macro"))
  53 ;;                 nil)
  54 ;;                (t (error "Unknown type %S" type))))))))
  55 ;;     (let ((re (concat "\\_<" (regexp-opt (append vdefs fdefs)) "\\_>"))
  56 ;;           (conflicts ()))
  57 ;;       (dolist (file files)
  58 ;;         (with-current-buffer (find-file-noselect file)
  59 ;;           (goto-char (point-min))
  60 ;;           (while (re-search-forward re nil t)
  61 ;;             (replace-match "cl-\\&"))
  62 ;;           (save-buffer))))
  63 ;;     (with-current-buffer (find-file-noselect "cl-rename.el")
  64 ;;       (dolist (def vdefs)
  65 ;;         (insert (format "(defvaralias '%s 'cl-%s)\n" def def)))
  66 ;;       (dolist (def fdefs)
  67 ;;         (insert (format "(defalias '%s 'cl-%s)\n" def def)))
  68 ;;       (save-buffer))))
  69
  70 ;; (defun cl--unrename ()
  71 ;;   ;; Taken from "Naming Conventions" node of the doc.
  72 ;;   (let* ((names '(defun* defsubst* defmacro* function* member*
  73 ;;                          assoc* rassoc* get* remove* delete*
  74 ;;                          mapcar* sort* floor* ceiling* truncate*
  75 ;;                          round* mod* rem* random*))
  76 ;;          (files '("cl.el" "cl-lib.el" "cl-macs.el" "cl-seq.el" "cl-extra.el"))
  77 ;;          (re (concat "\\_<cl-" (regexp-opt (mapcar #'symbol-name names))
  78 ;;                      "\\_>")))
  79 ;;     (dolist (file files)
  80 ;;       (with-current-buffer (find-file-noselect file)
  81 ;;         (goto-char (point-min))
  82 ;;         (while (re-search-forward re nil t)
  83 ;;           (delete-region (1- (point)) (point)))
  84 ;;         (save-buffer)))))
  85
  86 ;;; Aliases to cl-lib's features.
  87
  88 (dolist (var '(
  89                ;; loop-result-var
  90                ;; loop-result
  91                ;; loop-initially
  92                ;; loop-finally
  93                ;; loop-bindings
  94                ;; loop-args
  95                ;; bind-inits
  96                ;; bind-block
  97                ;; lambda-list-keywords
  98                float-negative-epsilon
  99                float-epsilon
 100                least-negative-normalized-float
 101                least-positive-normalized-float
 102                least-negative-float
 103                least-positive-float
 104                most-negative-float
 105                most-positive-float
 106                ;; custom-print-functions
 107                ))
 108   (defvaralias var (intern (format "cl-%s" var))))
 109
 110 ;; Before overwriting subr.el's `dotimes' and `dolist', let's remember
 111 ;; them under a different name, so we can use them in our implementation
 112 ;; of `dotimes' and `dolist'.
 113 (unless (fboundp 'cl--dotimes)
 114   (defalias 'cl--dotimes (symbol-function 'dotimes) "The non-CL `dotimes'."))
 115 (unless (fboundp 'cl--dolist)
 116   (defalias 'cl--dolist (symbol-function 'dolist) "The non-CL `dolist'."))
 117
 118 (dolist (fun '(
 119                (get* . cl-get)
 120                (random* . cl-random)
 121                (rem* . cl-rem)
 122                (mod* . cl-mod)
 123                (round* . cl-round)
 124                (truncate* . cl-truncate)
 125                (ceiling* . cl-ceiling)
 126                (floor* . cl-floor)
 127                (rassoc* . cl-rassoc)
 128                (assoc* . cl-assoc)
 129                (member* . cl-member)
 130                (delete* . cl-delete)
 131                (remove* . cl-remove)
 132                (defsubst* . cl-defsubst)
 133                (sort* . cl-sort)
 134                (function* . cl-function)
 135                (defmacro* . cl-defmacro)
 136                (defun* . cl-defun)
 137                (mapcar* . cl-mapcar)
 138
 139                remprop
 140                getf
 141                tailp
 142                list-length
 143                nreconc
 144                revappend
 145                concatenate
 146                subseq
 147                random-state-p
 148                make-random-state
 149                signum
 150                isqrt
 151                lcm
 152                gcd
 153                notevery
 154                notany
 155                every
 156                some
 157                mapcon
 158                mapcan
 159                mapl
 160                maplist
 161                map
 162                equalp
 163                coerce
 164                tree-equal
 165                nsublis
 166                sublis
 167                nsubst-if-not
 168                nsubst-if
 169                nsubst
 170                subst-if-not
 171                subst-if
 172                subsetp
 173                nset-exclusive-or
 174                set-exclusive-or
 175                nset-difference
 176                set-difference
 177                nintersection
 178                intersection
 179                nunion
 180                union
 181                rassoc-if-not
 182                rassoc-if
 183                assoc-if-not
 184                assoc-if
 185                member-if-not
 186                member-if
 187                merge
 188                stable-sort
 189                search
 190                mismatch
 191                count-if-not
 192                count-if
 193                count
 194                position-if-not
 195                position-if
 196                position
 197                find-if-not
 198                find-if
 199                find
 200                nsubstitute-if-not
 201                nsubstitute-if
 202                nsubstitute
 203                substitute-if-not
 204                substitute-if
 205                substitute
 206                delete-duplicates
 207                remove-duplicates
 208                delete-if-not
 209                delete-if
 210                remove-if-not
 211                remove-if
 212                replace
 213                fill
 214                reduce
 215                compiler-macroexpand
 216                define-compiler-macro
 217                assert
 218                check-type
 219                typep
 220                deftype
 221                defstruct
 222                callf2
 223                callf
 224                letf*
 225                ;; letf
 226                rotatef
 227                shiftf
 228                remf
 229                psetf
 230                (define-setf-method . define-setf-expander)
 231                declare
 232                the
 233                locally
 234                multiple-value-setq
 235                multiple-value-bind
 236                symbol-macrolet
 237                macrolet
 238                progv
 239                psetq
 240                do-all-symbols
 241                do-symbols
 242                dotimes
 243                dolist
 244                do*
 245                do
 246                loop
 247                return-from
 248                return
 249                block
 250                etypecase
 251                typecase
 252                ecase
 253                case
 254                load-time-value
 255                eval-when
 256                destructuring-bind
 257                gentemp
 258                gensym
 259                pairlis
 260                acons
 261                subst
 262                adjoin
 263                copy-list
 264                ldiff
 265                list*
 266                cddddr
 267                cdddar
 268                cddadr
 269                cddaar
 270                cdaddr
 271                cdadar
 272                cdaadr
 273                cdaaar
 274                cadddr
 275                caddar
 276                cadadr
 277                cadaar
 278                caaddr
 279                caadar
 280                caaadr
 281                caaaar
 282                cdddr
 283                cddar
 284                cdadr
 285                cdaar
 286                caddr
 287                cadar
 288                caadr
 289                caaar
 290                tenth
 291                ninth
 292                eighth
 293                seventh
 294                sixth
 295                fifth
 296                fourth
 297                third
 298                endp
 299                rest
 300                second
 301                first
 302                svref
 303                copy-seq
 304                evenp
 305                oddp
 306                minusp
 307                plusp
 308                floatp-safe
 309                declaim
 310                proclaim
 311                nth-value
 312                multiple-value-call
 313                multiple-value-apply
 314                multiple-value-list
 315                values-list
 316                values
 317                pushnew
 318                decf
 319                incf
 320                ))
 321   (let ((new (if (consp fun) (prog1 (cdr fun) (setq fun (car fun)))
 322                (intern (format "cl-%s" fun)))))
 323     (defalias fun new)
 324     ;; If `cl-foo' is declare inline, then make `foo' inline as well, and
 325     ;; similarly.  Same for edebug specifications, indent rules and
 326     ;; doc-string position.
 327     ;; FIXME: For most of them, we should instead follow aliases
 328     ;; where applicable.
 329     (dolist (prop '(byte-optimizer doc-string-elt edebug-form-spec
 330                     lisp-indent-function))
 331       (if (get new prop)
 332         (put fun prop (get new prop))))))
 333
 334 ;;; Features provided a bit differently in Elisp.
 335
 336 ;; First, the old lexical-let is now better served by `lexical-binding', tho
 337 ;; it's not 100% compatible.
 338
 339 (defvar cl-closure-vars nil)
 340 (defvar cl--function-convert-cache nil)
 341
 342 (defun cl--function-convert (f)
 343   "Special macro-expander for special cases of (function F).
 344 The two cases that are handled are:
 345 - closure-conversion of lambda expressions for `lexical-let'.
 346 - renaming of F when it's a function defined via `cl-labels' or `labels'."
 347   (require 'cl-macs)
 348   (declare-function cl--expr-contains-any "cl-macs" (x y))
 349   (cond
 350    ;; ¡¡Big Ugly Hack!! We can't use a compiler-macro because those are checked
 351    ;; *after* handling `function', but we want to stop macroexpansion from
 352    ;; being applied infinitely, so we use a cache to return the exact `form'
 353    ;; being expanded even though we don't receive it.
 354    ((eq f (car cl--function-convert-cache)) (cdr cl--function-convert-cache))
 355    ((eq (car-safe f) 'lambda)
 356     (let ((body (mapcar (lambda (f)
 357                           (macroexpand-all f macroexpand-all-environment))
 358                         (cddr f))))
 359       (if (and cl-closure-vars
 360                (cl--expr-contains-any body cl-closure-vars))
 361           (let* ((new (mapcar 'cl-gensym cl-closure-vars))
 362                  (sub (cl-pairlis cl-closure-vars new)) (decls nil))
 363             (while (or (stringp (car body))
 364                        (eq (car-safe (car body)) 'interactive))
 365               (push (list 'quote (pop body)) decls))
 366             (put (car (last cl-closure-vars)) 'used t)
 367             `(list 'lambda '(&rest --cl-rest--)
 368                    ,@(cl-sublis sub (nreverse decls))
 369                    (list 'apply
 370                          (list 'quote
 371                                #'(lambda ,(append new (cadr f))
 372                                    ,@(cl-sublis sub body)))
 373                          ,@(nconc (mapcar (lambda (x) `(list 'quote ,x))
 374                                           cl-closure-vars)
 375                                   '((quote --cl-rest--))))))
 376         (let* ((newf `(lambda ,(cadr f) ,@body))
 377                (res `(function ,newf)))
 378           (setq cl--function-convert-cache (cons newf res))
 379           res))))
 380    (t
 381     (let ((found (assq f macroexpand-all-environment)))
 382       (if (and found (ignore-errors
 383                        (eq (cadr (cl-caddr found)) 'cl-labels-args)))
 384           (cadr (cl-caddr (cl-cadddr found)))
 385         (let ((res `(function ,f)))
 386           (setq cl--function-convert-cache (cons f res))
 387           res))))))
 388
 389 (defmacro lexical-let (bindings &rest body)
 390   "Like `let', but lexically scoped.
 391 The main visible difference is that lambdas inside BODY will create
 392 lexical closures as in Common Lisp.
 393 \n(fn BINDINGS BODY)"
 394   (declare (indent 1) (debug let))
 395   (let* ((cl-closure-vars cl-closure-vars)
 396          (vars (mapcar (function
 397                         (lambda (x)
 398                           (or (consp x) (setq x (list x)))
 399                           (push (make-symbol (format "--cl-%s--" (car x)))
 400                                 cl-closure-vars)
 401                           (set (car cl-closure-vars) [bad-lexical-ref])
 402                           (list (car x) (cadr x) (car cl-closure-vars))))
 403                        bindings))
 404          (ebody
 405           (macroexpand-all
 406            `(cl-symbol-macrolet
 407                 ,(mapcar (lambda (x)
 408                            `(,(car x) (symbol-value ,(cl-caddr x))))
 409                          vars)
 410               ,@body)
 411            (cons (cons 'function #'cl--function-convert)
 412                  macroexpand-all-environment))))
 413     (if (not (get (car (last cl-closure-vars)) 'used))
 414         ;; Turn (let ((foo (cl-gensym)))
 415         ;;        (set foo <val>) ...(symbol-value foo)...)
 416         ;; into (let ((foo <val>)) ...(symbol-value 'foo)...).
 417         ;; This is good because it's more efficient but it only works with
 418         ;; dynamic scoping, since with lexical scoping we'd need
 419         ;; (let ((foo <val>)) ...foo...).
 420         `(progn
 421            ,@(mapcar (lambda (x) `(defvar ,(cl-caddr x))) vars)
 422            (let ,(mapcar (lambda (x) (list (cl-caddr x) (cadr x))) vars)
 423            ,(cl-sublis (mapcar (lambda (x)
 424                               (cons (cl-caddr x)
 425                                     `',(cl-caddr x)))
 426                             vars)
 427                     ebody)))
 428       `(let ,(mapcar (lambda (x)
 429                        (list (cl-caddr x)
 430                              `(make-symbol ,(format "--%s--" (car x)))))
 431                      vars)
 432          (setf ,@(apply #'append
 433                         (mapcar (lambda (x)
 434                                   (list `(symbol-value ,(cl-caddr x)) (cadr x)))
 435                                 vars)))
 436          ,ebody))))
 437
 438 (defmacro lexical-let* (bindings &rest body)
 439   "Like `let*', but lexically scoped.
 440 The main visible difference is that lambdas inside BODY, and in
 441 successive bindings within BINDINGS, will create lexical closures
 442 as in Common Lisp.  This is similar to the behavior of `let*' in
 443 Common Lisp.
 444 \n(fn BINDINGS BODY)"
 445   (declare (indent 1) (debug let))
 446   (if (null bindings) (cons 'progn body)
 447     (setq bindings (reverse bindings))
 448     (while bindings
 449       (setq body (list `(lexical-let (,(pop bindings)) ,@body))))
 450     (car body)))
 451
 452 ;; This should really have some way to shadow 'byte-compile properties, etc.
 453 (defmacro flet (bindings &rest body)
 454   "Make temporary overriding function definitions.
 455 This is an analogue of a dynamically scoped `let' that operates on the function
 456 cell of FUNCs rather than their value cell.
 457 If you want the Common-Lisp style of `flet', you should use `cl-flet'.
 458 The FORMs are evaluated with the specified function definitions in place,
 459 then the definitions are undone (the FUNCs go back to their previous
 460 definitions, or lack thereof).
 461
 462 \(fn ((FUNC ARGLIST BODY...) ...) FORM...)"
 463   (declare (indent 1) (debug cl-flet)
 464            (obsolete "Use either `cl-flet' or `cl-letf'."  "24.2"))
 465   `(letf ,(mapcar
 466            (lambda (x)
 467              (if (or (and (fboundp (car x))
 468                           (eq (car-safe (symbol-function (car x))) 'macro))
 469                      (cdr (assq (car x) macroexpand-all-environment)))
 470                  (error "Use `labels', not `flet', to rebind macro names"))
 471              (let ((func `(cl-function
 472                            (lambda ,(cadr x)
 473                              (cl-block ,(car x) ,@(cddr x))))))
 474                (when (cl--compiling-file)
 475                  ;; Bug#411.  It would be nice to fix this.
 476                  (and (get (car x) 'byte-compile)
 477                       (error "Byte-compiling a redefinition of `%s' \
 478 will not work - use `labels' instead" (symbol-name (car x))))
 479                  ;; FIXME This affects the rest of the file, when it
 480                  ;; should be restricted to the flet body.
 481                  (and (boundp 'byte-compile-function-environment)
 482                       (push (cons (car x) (eval func))
 483                             byte-compile-function-environment)))
 484                (list `(symbol-function ',(car x)) func)))
 485            bindings)
 486      ,@body))
 487
 488 (defmacro labels (bindings &rest body)
 489   "Make temporary function bindings.
 490 Like `cl-labels' except that the lexical scoping is handled via `lexical-let'
 491 rather than relying on `lexical-binding'."
 492   (declare (indent 1) (debug cl-flet) (obsolete 'cl-labels "24.2"))
 493   (let ((vars nil) (sets nil) (newenv macroexpand-all-environment))
 494     (dolist (binding bindings)
 495       ;; It's important that (not (eq (symbol-name var1) (symbol-name var2)))
 496       ;; because these var's *names* get added to the macro-environment.
 497       (let ((var (make-symbol (format "--cl-%s--" (car binding)))))
 498         (push var vars)
 499         (push `(cl-function (lambda . ,(cdr binding))) sets)
 500         (push var sets)
 501         (push (cons (car binding)
 502                     `(lambda (&rest cl-labels-args)
 503                        (cl-list* 'funcall ',var
 504                                  cl-labels-args)))
 505               newenv)))
 506     (macroexpand-all `(lexical-let ,vars (setq ,@sets) ,@body) newenv)))
 507
 508 ;; Generalized variables are provided by gv.el, but some details are
 509 ;; not 100% compatible: not worth the trouble to add them to cl-lib.el, but we
 510 ;; still need to support old users of cl.el.
 511
 512 (defmacro cl--symbol-function (symbol)
 513   "Like `symbol-function' but return `cl--unbound' if not bound."
 514   ;; (declare (gv-setter (lambda (store)
 515   ;;                       `(if (eq ,store 'cl--unbound)
 516   ;;                            (fmakunbound ,symbol) (fset ,symbol ,store)))))
 517   `(if (fboundp ,symbol) (symbol-function ,symbol) 'cl--unbound))
 518 (gv-define-setter cl--symbol-function (store symbol)
 519   `(if (eq ,store 'cl--unbound) (fmakunbound ,symbol) (fset ,symbol ,store)))
 520
 521 (defmacro letf (bindings &rest body)
 522   "Dynamically scoped let-style bindings for places.
 523 Like `cl-letf', but with some extra backward compatibility."
 524   ;; Like cl-letf, but with special handling of symbol-function.
 525   `(cl-letf ,(mapcar (lambda (x) (if (eq (car-safe (car x)) 'symbol-function)
 526                                 `((cl--symbol-function ,@(cdar x)) ,@(cdr x))
 527                               x))
 528                      bindings)
 529             ,@body))
 530
 531 (defun cl--gv-adapt (cl-gv do)
 532   ;; This function is used by all .elc files that use define-setf-expander and
 533   ;; were compiled with Emacs>=24.2.
 534   (let ((vars (nth 0 cl-gv))
 535         (vals (nth 1 cl-gv))
 536         (binds ())
 537         (substs ()))
 538     ;; Use cl-sublis as was done in cl-setf-do-modify.
 539     (while vars
 540       (if (macroexp-copyable-p (car vals))
 541           (push (cons (pop vars) (pop vals)) substs)
 542         (push (list (pop vars) (pop vals)) binds)))
 543     (macroexp-let*
 544      binds
 545      (funcall do (cl-sublis substs (nth 4 cl-gv))
 546               ;; We'd like to do something like
 547               ;; (lambda ,(nth 2 cl-gv) ,(nth 3 cl-gv)).
 548               (lambda (exp)
 549                 (macroexp-let2 macroexp-copyable-p v exp
 550                   (cl-sublis (cons (cons (car (nth 2 cl-gv)) v)
 551                                    substs)
 552                              (nth 3 cl-gv))))))))
 553
 554 (defmacro define-setf-expander (name arglist &rest body)
 555   "Define a `setf' method.
 556 This method shows how to handle `setf's to places of the form (NAME ARGS...).
 557 The argument forms ARGS are bound according to ARGLIST, as if NAME were
 558 going to be expanded as a macro, then the BODY forms are executed and must
 559 return a list of five elements: a temporary-variables list, a value-forms
 560 list, a store-variables list (of length one), a store-form, and an access-
 561 form.  See `gv-define-expander', `gv-define-setter', and `gv-define-expander'
 562 for a better and simpler ways to define setf-methods."
 563   (declare (debug
 564             (&define name cl-lambda-list cl-declarations-or-string def-body)))
 565   `(progn
 566      ,@(if (stringp (car body))
 567            (list `(put ',name 'setf-documentation ,(pop body))))
 568      (gv-define-expander ,name
 569        (cl-function
 570         (lambda (do ,@arglist)
 571           (cl--gv-adapt (progn ,@body) do))))))
 572
 573 (defmacro defsetf (name arg1 &rest args)
 574   "Define a `setf' method.
 575 This macro is an easy-to-use substitute for `define-setf-expander' that works
 576 well for simple place forms.  In the simple `defsetf' form, `setf's of
 577 the form (setf (NAME ARGS...) VAL) are transformed to function or macro
 578 calls of the form (FUNC ARGS... VAL).  Example:
 579
 580   (cl-defsetf aref aset)
 581
 582 Alternate form: (cl-defsetf NAME ARGLIST (STORE) BODY...).
 583 Here, the above `setf' call is expanded by binding the argument forms ARGS
 584 according to ARGLIST, binding the value form VAL to STORE, then executing
 585 BODY, which must return a Lisp form that does the necessary `setf' operation.
 586 Actually, ARGLIST and STORE may be bound to temporary variables which are
 587 introduced automatically to preserve proper execution order of the arguments.
 588 Example:
 589
 590   (cl-defsetf nth (n x) (v) `(setcar (nthcdr ,n ,x) ,v))
 591
 592 \(fn NAME [FUNC | ARGLIST (STORE) BODY...])"
 593   (declare (debug
 594             (&define name
 595                      [&or [symbolp &optional stringp]
 596                           [cl-lambda-list (symbolp)]]
 597                      cl-declarations-or-string def-body)))
 598   (if (and (listp arg1) (consp args))
 599       ;; Like `gv-define-setter' but with `cl-function'.
 600       `(gv-define-expander ,name
 601          (lambda (do &rest args)
 602            (gv--defsetter ',name
 603                           (cl-function
 604                            (lambda (,@(car args) ,@arg1) ,@(cdr args)))
 605                           do args)))
 606     `(gv-define-simple-setter ,name ,arg1)))
 607
 608 ;; FIXME: CL used to provide a setf method for `apply', but I haven't been able
 609 ;; to find a case where it worked.  The code below tries to handle it as well.
 610 ;; (defun cl--setf-apply (form last-witness last)
 611 ;;   (cond
 612 ;;    ((not (consp form)) form)
 613 ;;    ((eq (ignore-errors (car (last form))) last-witness)
 614 ;;     `(apply #',(car form) ,@(butlast (cdr form)) ,last))
 615 ;;    ((and (memq (car form) '(let let*))
 616 ;;          (rassoc (list last-witness) (cadr form)))
 617 ;;     (let ((rebind (rassoc (list last-witness) (cadr form))))
 618 ;;     `(,(car form) ,(remq rebind (cadr form))
 619 ;;       ,@(mapcar (lambda (form) (cl--setf-apply form (car rebind) last))
 620 ;;                 (cddr form)))))
 621 ;;    (t (mapcar (lambda (form) (cl--setf-apply form last-witness last)) form))))
 622 ;; (gv-define-setter apply (val fun &rest args)
 623 ;;   (pcase fun (`#',(and (pred symbolp) f) (setq fun f))
 624 ;;          (_ (error "First arg to apply in setf is not #'SYM: %S" fun)))
 625 ;;   (let* ((butlast (butlast args))
 626 ;;          (last (car (last args)))
 627 ;;          (last-witness (make-symbol "--cl-tailarg--"))
 628 ;;          (setter (macroexpand `(setf (,fun ,@butlast ,last-witness) ,val)
 629 ;;                               macroexpand-all-environment)))
 630 ;;     (cl--setf-apply setter last-witness last)))
 631
 632
 633 ;; FIXME: CL used to provide get-setf-method, which was used by some
 634 ;; setf-expanders, but now that we use gv.el, it is a lot more difficult
 635 ;; and in general impossible to provide get-setf-method.  Hopefully, it
 636 ;; won't be needed.  If needed, we'll have to do something nasty along the
 637 ;; lines of
 638 ;; (defun get-setf-method (place &optional env)
 639 ;;   (let* ((witness (list 'cl-gsm))
 640 ;;          (expansion (gv-letplace (getter setter) place
 641 ;;                      `(,witness ,getter ,(funcall setter witness)))))
 642 ;;     ...find "let prefix" of expansion, extract getter and setter from
 643 ;;     ...the rest, and build the 5-tuple))
 644 (make-obsolete 'get-setf-method 'gv-letplace "24.2")
 645
 646 (defmacro define-modify-macro (name arglist func &optional doc)
 647   "Define a `setf'-like modify macro.
 648 If NAME is called, it combines its PLACE argument with the other arguments
 649 from ARGLIST using FUNC: (define-modify-macro incf (&optional (n 1)) +)"
 650   (declare (debug
 651             (&define name cl-lambda-list ;; should exclude &key
 652                      symbolp &optional stringp)))
 653   (if (memq '&key arglist)
 654       (error "&key not allowed in define-modify-macro"))
 655   (let ((place (make-symbol "--cl-place--")))
 656     `(cl-defmacro ,name (,place ,@arglist)
 657        ,doc
 658        (,(if (memq '&rest arglist) #'cl-list* #'list)
 659         #'cl-callf ',func ,place
 660         ,@(cl--arglist-args arglist)))))
 661
 662 ;;; Additional compatibility code.
 663 ;; For names that were clean but really aren't needed any more.
 664
 665 (define-obsolete-function-alias 'cl-macroexpand 'macroexpand "24.2")
 666 (define-obsolete-variable-alias 'cl-macro-environment
 667   'macroexpand-all-environment "24.2")
 668 (define-obsolete-function-alias 'cl-macroexpand-all 'macroexpand-all "24.2")
 669
 670 ;;; Hash tables.
 671 ;; This is just kept for compatibility with code byte-compiled by Emacs-20.
 672
 673 ;; No idea if this might still be needed.
 674 (defun cl-not-hash-table (x &optional y &rest _z)
 675   (declare (obsolete nil "24.2"))
 676   (signal 'wrong-type-argument (list 'cl-hash-table-p (or y x))))
 677
 678 (defvar cl-builtin-gethash (symbol-function 'gethash))
 679 (make-obsolete-variable 'cl-builtin-gethash nil "24.2")
 680 (defvar cl-builtin-remhash (symbol-function 'remhash))
 681 (make-obsolete-variable 'cl-builtin-remhash nil "24.2")
 682 (defvar cl-builtin-clrhash (symbol-function 'clrhash))
 683 (make-obsolete-variable 'cl-builtin-clrhash nil "24.2")
 684 (defvar cl-builtin-maphash (symbol-function 'maphash))
 685
 686 (make-obsolete-variable 'cl-builtin-maphash nil "24.2")
 687 (define-obsolete-function-alias 'cl-map-keymap 'map-keymap "24.2")
 688 (define-obsolete-function-alias 'cl-copy-tree 'copy-tree "24.2")
 689 (define-obsolete-function-alias 'cl-gethash 'gethash "24.2")
 690 (define-obsolete-function-alias 'cl-puthash 'puthash "24.2")
 691 (define-obsolete-function-alias 'cl-remhash 'remhash "24.2")
 692 (define-obsolete-function-alias 'cl-clrhash 'clrhash "24.2")
 693 (define-obsolete-function-alias 'cl-maphash 'maphash "24.2")
 694 (define-obsolete-function-alias 'cl-make-hash-table 'make-hash-table "24.2")
 695 (define-obsolete-function-alias 'cl-hash-table-p 'hash-table-p "24.2")
 696 (define-obsolete-function-alias 'cl-hash-table-count 'hash-table-count "24.2")
 697
 698 (defun cl-maclisp-member (item list)
 699   (declare (obsolete member "24.2"))
 700   (while (and list (not (equal item (car list)))) (setq list (cdr list)))
 701   list)
 702
 703 ;; Used in the expansion of the old `defstruct'.
 704 (defun cl-struct-setf-expander (x name accessor pred-form pos)
 705   (declare (obsolete nil "24.2"))
 706   (let* ((temp (make-symbol "--cl-x--")) (store (make-symbol "--cl-store--")))
 707     (list (list temp) (list x) (list store)
 708           `(progn
 709              ,@(and pred-form
 710                     (list `(or ,(cl-subst temp 'cl-x pred-form)
 711                                (error ,(format
 712                                         "%s storing a non-%s"
 713                                         accessor name)))))
 714              ,(if (eq (car (get name 'cl-struct-type)) 'vector)
 715                   `(aset ,temp ,pos ,store)
 716                 `(setcar
 717                   ,(if (<= pos 5)
 718                        (let ((xx temp))
 719                          (while (>= (setq pos (1- pos)) 0)
 720                            (setq xx `(cdr ,xx)))
 721                          xx)
 722                      `(nthcdr ,pos ,temp))
 723                   ,store)))
 724           (list accessor temp))))
 725
 726 (provide 'cl)
 727 ;;; cl.el ends here