test/automated/map-tests.el

   1 ;;; map-tests.el --- Tests for map.el  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Petton <nicolas@petton.fr>
   6 ;; Maintainer: emacs-devel@gnu.org
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Tests for map.el
  26
  27 ;;; Code:
  28
  29 (require 'ert)
  30 (require 'map)
  31
  32 (defmacro with-maps-do (var &rest body)
  33   "Successively bind VAR to an alist, vector and hash-table.
  34 Each map is built from the following alist data:
  35 '((0 . 3) (1 . 4) (2 . 5)).
  36 Evaluate BODY for each created map.
  37
  38 \(fn (var map) body)"
  39   (declare (indent 1) (debug t))
  40   (let ((alist (make-symbol "alist"))
  41         (vec (make-symbol "vec"))
  42         (ht (make-symbol "ht")))
  43    `(let ((,alist (list (cons 0 3)
  44                         (cons 1 4)
  45                         (cons 2 5)))
  46           (,vec (vector 3 4 5))
  47           (,ht (make-hash-table)))
  48       (puthash 0 3 ,ht)
  49       (puthash 1 4 ,ht)
  50       (puthash 2 5 ,ht)
  51       (dolist (,var (list ,alist ,vec ,ht))
  52         ,@body))))
  53
  54 (ert-deftest test-map-elt ()
  55   (with-maps-do map
  56     (should (= 3 (map-elt map 0)))
  57     (should (= 4 (map-elt map 1)))
  58     (should (= 5 (map-elt map 2)))
  59     (should (null (map-elt map -1)))
  60     (should (null (map-elt map 4)))))
  61
  62 (ert-deftest test-map-elt-default ()
  63   (with-maps-do map
  64     (should (= 5 (map-elt map 7 5)))))
  65
  66 (ert-deftest test-map-elt-with-nil-value ()
  67   (should (null (map-elt '((a . 1)
  68                            (b))
  69                          'b
  70                          '2))))
  71
  72 (ert-deftest test-map-put ()
  73   (with-maps-do map
  74     (setf (map-elt map 2) 'hello)
  75     (should (eq (map-elt map 2) 'hello)))
  76   (with-maps-do map
  77     (map-put map 2 'hello)
  78     (should (eq (map-elt map 2) 'hello)))
  79   (let ((ht (make-hash-table)))
  80     (setf (map-elt ht 2) 'a)
  81     (should (eq (map-elt ht 2)
  82                 'a)))
  83   (let ((alist '((0 . a) (1 . b) (2 . c))))
  84     (setf (map-elt alist 2) 'a)
  85     (should (eq (map-elt alist 2)
  86                 'a)))
  87   (let ((vec [3 4 5]))
  88    (should-error (setf (map-elt vec 3) 6))))
  89
  90 (ert-deftest test-map-put-return-value ()
  91   (let ((ht (make-hash-table)))
  92     (should (eq (map-put ht 'a 'hello) ht))))
  93
  94 (ert-deftest test-map-delete ()
  95   (with-maps-do map
  96     (map-delete map 1)
  97     (should (null (map-elt map 1))))
  98   (with-maps-do map
  99     (map-delete map -2)
 100     (should (null (map-elt map -2)))))
 101
 102 (ert-deftest test-map-delete-return-value ()
 103   (let ((ht (make-hash-table)))
 104     (should (eq (map-delete ht 'a) ht))))
 105
 106 (ert-deftest test-map-nested-elt ()
 107   (let ((vec [a b [c d [e f]]]))
 108     (should (eq (map-nested-elt vec '(2 2 0)) 'e)))
 109   (let ((alist '((a . 1)
 110                  (b . ((c . 2)
 111                        (d . 3)
 112                        (e . ((f . 4)
 113                              (g . 5))))))))
 114     (should (eq (map-nested-elt alist '(b e f))
 115                 4)))
 116   (let ((ht (make-hash-table)))
 117     (setf (map-elt ht 'a) 1)
 118     (setf (map-elt ht 'b) (make-hash-table))
 119     (setf (map-elt (map-elt ht 'b) 'c) 2)
 120     (should (eq (map-nested-elt ht '(b c))
 121                 2))))
 122
 123 (ert-deftest test-map-nested-elt-default ()
 124   (let ((vec [a b [c d]]))
 125     (should (null (map-nested-elt vec '(2 3))))
 126     (should (null (map-nested-elt vec '(2 1 1))))
 127     (should (= 4 (map-nested-elt vec '(2 1 1) 4)))))
 128
 129 (ert-deftest test-map-p ()
 130   (should (map-p nil))
 131   (should (map-p '((a . b) (c . d))))
 132   (should (map-p '(a b c d)))
 133   (should (map-p []))
 134   (should (map-p [1 2 3]))
 135   (should (map-p (make-hash-table)))
 136   (should (map-p "hello"))
 137   (should (not (map-p 1)))
 138   (should (not (map-p 'hello))))
 139
 140 (ert-deftest test-map-keys ()
 141   (with-maps-do map
 142     (should (equal (map-keys map) '(0 1 2))))
 143   (should (null (map-keys nil)))
 144   (should (null (map-keys []))))
 145
 146 (ert-deftest test-map-values ()
 147   (with-maps-do map
 148     (should (equal (map-values map) '(3 4 5)))))
 149
 150 (ert-deftest test-map-pairs ()
 151   (with-maps-do map
 152     (should (equal (map-pairs map) '((0 . 3)
 153                                      (1 . 4)
 154                                      (2 . 5))))))
 155
 156 (ert-deftest test-map-length ()
 157   (let ((ht (make-hash-table)))
 158     (puthash 'a 1 ht)
 159     (puthash 'b 2 ht)
 160     (puthash 'c 3 ht)
 161     (puthash 'd 4 ht)
 162     (should (= 0 (map-length nil)))
 163     (should (= 0 (map-length [])))
 164     (should (= 0 (map-length (make-hash-table))))
 165     (should (= 5 (map-length [0 1 2 3 4])))
 166     (should (= 2 (map-length '((a . 1) (b . 2)))))
 167     (should (= 4 (map-length ht)))))
 168
 169 (ert-deftest test-map-copy ()
 170   (with-maps-do map
 171     (let ((copy (map-copy map)))
 172       (should (equal (map-keys map) (map-keys copy)))
 173       (should (equal (map-values map) (map-values copy)))
 174       (should (not (eq map copy))))))
 175
 176 (ert-deftest test-map-apply ()
 177   (with-maps-do map
 178     (should (equal (map-apply (lambda (k v) (cons (int-to-string k) v))
 179                               map)
 180                    '(("0" . 3) ("1" . 4) ("2" . 5)))))
 181   (let ((vec [a b c]))
 182     (should (equal (map-apply (lambda (k v) (cons (1+ k) v))
 183                               vec)
 184                    '((1 . a)
 185                      (2 . b)
 186                      (3 . c))))))
 187
 188 (ert-deftest test-map-keys-apply ()
 189   (with-maps-do map
 190     (should (equal (map-keys-apply (lambda (k) (int-to-string k))
 191                                    map)
 192                    '("0" "1" "2"))))
 193   (let ((vec [a b c]))
 194     (should (equal (map-keys-apply (lambda (k) (1+ k))
 195                                    vec)
 196                    '(1 2 3)))))
 197
 198 (ert-deftest test-map-values-apply ()
 199   (with-maps-do map
 200     (should (equal (map-values-apply (lambda (v) (1+ v))
 201                                      map)
 202                    '(4 5 6))))
 203   (let ((vec [a b c]))
 204     (should (equal (map-values-apply (lambda (v) (symbol-name v))
 205                                      vec)
 206                    '("a" "b" "c")))))
 207
 208 (ert-deftest test-map-filter ()
 209   (with-maps-do map
 210     (should (equal (map-keys (map-filter (lambda (_k v)
 211                                            (<= 4 v))
 212                                          map))
 213                    '(1 2)))
 214     (should (null (map-filter (lambda (k _v)
 215                                 (eq 'd k))
 216                               map))))
 217   (should (null (map-filter (lambda (_k v)
 218                               (eq 3 v))
 219                             [1 2 4 5])))
 220   (should (equal (map-filter (lambda (k _v)
 221                                (eq 3 k))
 222                              [1 2 4 5])
 223                  '((3 . 5)))))
 224
 225 (ert-deftest test-map-remove ()
 226   (with-maps-do map
 227     (should (equal (map-keys (map-remove (lambda (_k v)
 228                                            (>= v 4))
 229                                          map))
 230                    '(0)))
 231     (should (equal (map-keys (map-remove (lambda (k _v)
 232                                            (eq 'd k))
 233                                          map))
 234                    (map-keys map))))
 235   (should (equal (map-remove (lambda (_k v)
 236                                (eq 3 v))
 237                              [1 2 4 5])
 238                  '((0 . 1)
 239                    (1 . 2)
 240                    (2 . 4)
 241                    (3 . 5))))
 242   (should (null (map-remove (lambda (k _v)
 243                               (>= k 0))
 244                             [1 2 4 5]))))
 245
 246 (ert-deftest test-map-empty-p ()
 247   (should (map-empty-p nil))
 248   (should (not (map-empty-p '((a . b) (c . d)))))
 249   (should (map-empty-p []))
 250   (should (not (map-empty-p [1 2 3])))
 251   (should (map-empty-p (make-hash-table)))
 252   (should (not (map-empty-p "hello")))
 253   (should (map-empty-p "")))
 254
 255 (ert-deftest test-map-contains-key-p ()
 256   (should (map-contains-key-p '((a . 1) (b . 2)) 'a))
 257   (should (not (map-contains-key-p '((a . 1) (b . 2)) 'c)))
 258   (should (map-contains-key-p '(("a" . 1)) "a"))
 259   (should (not (map-contains-key-p '(("a" . 1)) "a" #'eq)))
 260   (should (map-contains-key-p [a b c] 2))
 261   (should (not (map-contains-key-p [a b c] 3))))
 262
 263 (ert-deftest test-map-some-p ()
 264   (with-maps-do map
 265     (should (equal (map-some-p (lambda (k _v)
 266                                  (eq 1 k))
 267                                map)
 268                    (cons 1 4)))
 269     (should (not (map-some-p (lambda (k _v)
 270                                (eq 'd k))
 271                              map))))
 272   (let ((vec [a b c]))
 273     (should (equal (map-some-p (lambda (k _v)
 274                                  (> k 1))
 275                                vec)
 276                    (cons 2 'c)))
 277     (should (not (map-some-p (lambda (k _v)
 278                                (> k 3))
 279                              vec)))))
 280
 281 (ert-deftest test-map-every-p ()
 282   (with-maps-do map
 283     (should (map-every-p (lambda (k _v)
 284                            k)
 285                          map))
 286     (should (not (map-every-p (lambda (_k _v)
 287                                 nil)
 288                               map))))
 289   (let ((vec [a b c]))
 290     (should (map-every-p (lambda (k _v)
 291                            (>= k 0))
 292                          vec))
 293     (should (not (map-every-p (lambda (k _v)
 294                                 (> k 3))
 295                               vec)))))
 296
 297 (ert-deftest test-map-into ()
 298   (let* ((alist '((a . 1) (b . 2)))
 299          (ht (map-into alist 'hash-table)))
 300     (should (hash-table-p ht))
 301     (should (equal (map-into (map-into alist 'hash-table) 'list)
 302                    alist))
 303     (should (listp (map-into ht 'list)))
 304     (should (equal (map-keys (map-into (map-into ht 'list) 'hash-table))
 305                    (map-keys ht)))
 306     (should (equal (map-values (map-into (map-into ht 'list) 'hash-table))
 307                    (map-values ht)))
 308     (should (null (map-into nil 'list)))
 309     (should (map-empty-p (map-into nil 'hash-table)))
 310     (should-error (map-into [1 2 3] 'string))))
 311
 312 (ert-deftest test-map-let ()
 313   (map-let (foo bar baz) '((foo . 1) (bar . 2))
 314     (should (= foo 1))
 315     (should (= bar 2))
 316     (should (null baz)))
 317   (map-let (('foo a)
 318             ('bar b)
 319             ('baz c))
 320       '((foo . 1) (bar . 2))
 321     (should (= a 1))
 322     (should (= b 2))
 323     (should (null c))))
 324
 325 (provide 'map-tests)
 326 ;;; map-tests.el ends here