lisp/mail/metamail.el

   1 ;;; metamail.el --- Metamail interface for GNU Emacs
   2
   3 ;; Copyright (C) 1993, 1996  Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu UMEDA <umerin@mse.kyutech.ac.jp>
   6 ;; Version: $Id: metamail.el,v 1.14 2000/11/12 00:22:02 fx Exp $
   7 ;; Keywords: mail, news, mime, multimedia
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Note: Metamail does not have all the options which are compatible with
  29 ;; the environment variables.  For that reason, metamail.el has to
  30 ;; hack the environment variables.  In addition, there is no way to
  31 ;; display all header fields without extra informative body messages
  32 ;; which are suppressed by the "-q" option.
  33
  34 ;; The idea of using metamail to process MIME messages is from
  35 ;; gnus-mime.el by Spike <Spike@world.std.com>.
  36
  37 ;;; Code:
  38
  39 (defgroup metamail nil
  40   "Metamail interface for Emacs."
  41   :group 'mail
  42   :group 'hypermedia
  43   :group 'processes)
  44
  45 (defcustom metamail-program-name "metamail"
  46   "*Metamail program name."
  47   :type 'string
  48   :group 'metamail)
  49
  50 (defcustom metamail-mailer-name "emacs"
  51   "*Mailer name set to MM_MAILER environment variable."
  52   :type 'string
  53   :group 'metamail)
  54
  55 (defvar metamail-environment '("KEYHEADS=*" "MM_QUIET=1")
  56   "*Environment variables passed to `metamail'.
  57 It must be a list of strings that have the format ENVVARNAME=VALUE.
  58 It is not expected to be altered globally by `set' or `setq'.
  59 Instead, change its value temporary using `let' or `let*' form.")
  60
  61 (defcustom metamail-switches '("-x" "-d" "-z")
  62   "*Switches for `metamail' program.
  63 `-z' is required to remove zap file.
  64 It is not expected to be altered globally by `set' or `setq'.
  65 Instead, change its value temporary using `let' or `let*' form.
  66 `-m MAILER' argument is automatically generated from the
  67 `metamail-mailer-name' variable."
  68   :type '(repeat (string :tag "Switch"))
  69   :group 'metamail)
  70
  71 ;;;###autoload
  72 (defun metamail-interpret-header ()
  73   "Interpret a header part of a MIME message in current buffer.
  74 Its body part is not interpreted at all."
  75   (interactive)
  76   (save-excursion
  77     (let* ((buffer-read-only nil)
  78            (metamail-switches           ;Inhibit processing an empty body.
  79             (append metamail-switches '("-c" "text/plain" "-E" "7bit")))
  80            (end (progn
  81                   (goto-char (point-min))
  82                   (search-forward "\n\n" nil 'move)
  83                   ;; An extra newline is inserted by metamail if there
  84                   ;; is no body part.  So, insert a dummy body by
  85                   ;; itself.
  86                   (insert "\n")
  87                   (point))))
  88       (metamail-region (point-min) end nil nil 'nodisplay)
  89       ;; Remove an extra newline inserted by myself.
  90       (goto-char (point-min))
  91       (if (search-forward "\n\n\n" nil t)
  92           (delete-char -1))
  93       )))
  94
  95 ;;;###autoload
  96 (defun metamail-interpret-body (&optional viewmode nodisplay)
  97   "Interpret a body part of a MIME message in current buffer.
  98 Optional argument VIEWMODE specifies the value of the
  99 EMACS_VIEW_MODE environment variable (defaulted to 1).
 100 Optional argument NODISPLAY non-nil means buffer is not
 101 redisplayed as output is inserted.
 102 Its header part is not interpreted at all."
 103   (interactive "p")
 104   (save-excursion
 105     (let ((contype nil)
 106           (encoding nil)
 107           (end (progn
 108                  (goto-char (point-min))
 109                  (search-forward "\n\n" nil t)
 110                  (point))))
 111       ;; Find Content-Type and Content-Transfer-Encoding from the header.
 112       (save-restriction
 113         (narrow-to-region (point-min) end)
 114         (setq contype
 115               (or (mail-fetch-field "Content-Type") "text/plain"))
 116         (setq encoding
 117               (or (mail-fetch-field "Content-Transfer-Encoding") "7bit")))
 118       ;; Interpret the body part only.
 119       (let ((metamail-switches          ;Process body part only.
 120              (append metamail-switches
 121                      (list "-b" "-c" contype "-E" encoding))))
 122         (metamail-region end (point-max) viewmode nil nodisplay))
 123       ;; Mode specific hack.
 124       (cond ((eq major-mode 'rmail-mode)
 125              ;; Adjust the marker of this message if in Rmail mode buffer.
 126              (set-marker (aref rmail-message-vector (1+ rmail-current-message))
 127                          (point-max))))
 128       )))
 129
 130 ;;;###autoload
 131 (defun metamail-buffer (&optional viewmode buffer nodisplay)
 132   "Process current buffer through `metamail'.
 133 Optional argument VIEWMODE specifies the value of the
 134 EMACS_VIEW_MODE environment variable (defaulted to 1).
 135 Optional argument BUFFER specifies a buffer to be filled (nil
 136 means current).
 137 Optional argument NODISPLAY non-nil means buffer is not
 138 redisplayed as output is inserted."
 139   (interactive "p")
 140   (metamail-region (point-min) (point-max) viewmode buffer nodisplay))
 141
 142 ;;;###autoload
 143 (defun metamail-region (beg end &optional viewmode buffer nodisplay)
 144   "Process current region through 'metamail'.
 145 Optional argument VIEWMODE specifies the value of the
 146 EMACS_VIEW_MODE environment variable (defaulted to 1).
 147 Optional argument BUFFER specifies a buffer to be filled (nil
 148 means current).
 149 Optional argument NODISPLAY non-nil means buffer is not
 150 redisplayed as output is inserted."
 151   (interactive "r\np")
 152   (let ((curbuf (current-buffer))
 153         (buffer-read-only nil)
 154         (metafile (make-temp-file "metamail"))
 155         (option-environment
 156          (list (format "EMACS_VIEW_MODE=%d"
 157                        (if (numberp viewmode) viewmode 1)))))
 158     (save-excursion
 159       ;; Gee!  Metamail does not ouput to stdout if input comes from
 160       ;; stdin.
 161       (let ((selective-display nil))    ;Disable ^M to nl translation.
 162         (write-region beg end metafile nil 'nomessage))
 163       (if buffer
 164           (set-buffer buffer))
 165       (setq buffer-read-only nil)
 166       ;; Clear destination buffer.
 167       (if (eq curbuf (current-buffer))
 168           (delete-region beg end)
 169         (delete-region (point-min) (point-max)))
 170       ;; We have to pass the environment variable KEYHEADS to display
 171       ;; all header fields.  Metamail should have an optional argument
 172       ;; to pass such information directly.
 173       (let ((process-environment
 174              (append process-environment
 175                      metamail-environment option-environment))
 176             (coding-system-for-read 'undecided))
 177         (apply (function call-process)
 178                metamail-program-name
 179                nil
 180                t                        ;Output to current buffer
 181                (not nodisplay)          ;Force redisplay
 182                (append metamail-switches
 183                        (list "-m" (or metamail-mailer-name "emacs"))
 184                        (list metafile))))
 185       ;; `metamail' may not delete the temporary file!
 186       (condition-case error
 187           (delete-file metafile)
 188         (error nil))
 189       )))
 190
 191 (provide 'metamail)
 192
 193 ;;; metamail.el ends here