lisp/gnus/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2
   3 ;; Copyright (C) 1995-2017 Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'message)
  32 (require 'gnus-art)
  33 (require 'gnus-util)
  34
  35 (defcustom gnus-post-method 'current
  36   "Preferred method for posting USENET news.
  37
  38 If this variable is `current' (which is the default), Gnus will use
  39 the \"current\" select method when posting.  If it is `native', Gnus
  40 will use the native select method when posting.
  41
  42 This method will not be used in mail groups and the like, only in
  43 \"real\" newsgroups.
  44
  45 If not `native' nor `current', the value must be a valid method as discussed
  46 in the documentation of `gnus-select-method'.  It can also be a list of
  47 methods.  If that is the case, the user will be queried for what select
  48 method to use when posting."
  49   :group 'gnus-group-foreign
  50   :link '(custom-manual "(gnus)Posting Server")
  51   :type `(choice (const native)
  52                  (const current)
  53                  (sexp :tag "Methods" ,gnus-select-method)))
  54
  55 (defcustom gnus-outgoing-message-group nil
  56   "All outgoing messages will be put in this group.
  57 If you want to store all your outgoing mail and articles in the group
  58 \"nnml:archive\", you set this variable to that value.  This variable
  59 can also be a list of group names.
  60
  61 If you want to have greater control over what group to put each
  62 message in, you can set this variable to a function that checks the
  63 current newsgroup name and then returns a suitable group name (or list
  64 of names)."
  65   :group 'gnus-message
  66   :type '(choice (const nil)
  67                  (function)
  68                  (string :tag "Group")
  69                  (repeat :tag "List of groups" (string :tag "Group"))))
  70
  71 (make-obsolete-variable 'gnus-outgoing-message-group 'gnus-message-archive-group "24.1")
  72
  73 (defcustom gnus-mailing-list-groups nil
  74   "If non-nil a regexp matching groups that are really mailing lists.
  75 This is useful when you're reading a mailing list that has been
  76 gatewayed to a newsgroup, and you want to followup to an article in
  77 the group."
  78   :group 'gnus-message
  79   :type '(choice (regexp)
  80                  (const nil)))
  81
  82 (defcustom gnus-add-to-list nil
  83   "If non-nil, add a `to-list' parameter automatically."
  84   :group 'gnus-message
  85   :type 'boolean)
  86
  87 (defcustom gnus-crosspost-complaint
  88   "Hi,
  89
  90 You posted the article below with the following Newsgroups header:
  91
  92 Newsgroups: %s
  93
  94 The %s group, at least, was an inappropriate recipient
  95 of this message.  Please trim your Newsgroups header to exclude this
  96 group before posting in the future.
  97
  98 Thank you.
  99
 100 "
 101   "Format string to be inserted when complaining about crossposts.
 102 The first %s will be replaced by the Newsgroups header;
 103 the second with the current group name."
 104   :group 'gnus-message
 105   :type 'string)
 106
 107 (defcustom gnus-message-setup-hook nil
 108   "Hook run after setting up a message buffer."
 109   :group 'gnus-message
 110   :options '(message-remove-blank-cited-lines)
 111   :type 'hook)
 112
 113 (defcustom gnus-bug-create-help-buffer t
 114   "Should we create the *Gnus Help Bug* buffer?"
 115   :group 'gnus-message
 116   :type 'boolean)
 117
 118 (defcustom gnus-posting-styles nil
 119   "Alist of styles to use when posting.
 120 See Info node `(gnus)Posting Styles'."
 121   :group 'gnus-message
 122   :link '(custom-manual "(gnus)Posting Styles")
 123   :type '(repeat (cons (choice (regexp)
 124                                (variable)
 125                                (list (const header)
 126                                      (string :tag "Header")
 127                                      (regexp :tag "Regexp"))
 128                                (function)
 129                                (sexp))
 130                        (repeat (list
 131                                 (choice (const signature)
 132                                         (const signature-file)
 133                                         (const organization)
 134                                         (const address)
 135                                         (const x-face-file)
 136                                         (const name)
 137                                         (const body)
 138                                         (symbol)
 139                                         (string :tag "Header"))
 140                                 (choice (string)
 141                                         (function)
 142                                         (variable)
 143                                         (sexp)))))))
 144
 145 (defcustom gnus-gcc-mark-as-read nil
 146   "If non-nil, automatically mark Gcc articles as read."
 147   :version "22.1"
 148   :group 'gnus-message
 149   :type 'boolean)
 150
 151 (make-obsolete-variable 'gnus-inews-mark-gcc-as-read
 152                         'gnus-gcc-mark-as-read "Emacs 22.1")
 153
 154 (defcustom gnus-gcc-externalize-attachments nil
 155   "Should local-file attachments be included as external parts in Gcc copies?
 156 If it is `all', attach files as external parts;
 157 if a regexp and matches the Gcc group name, attach files as external parts;
 158 if nil, attach files as normal parts."
 159   :version "22.1"
 160   :group 'gnus-message
 161   :type '(choice (const nil :tag "None")
 162                  (const all :tag "Any")
 163                  (string :tag "Regexp")))
 164
 165 (defcustom gnus-gcc-self-resent-messages 'no-gcc-self
 166   "Like `gcc-self' group parameter, only for unmodified resent messages.
 167 Applied to messages sent by `gnus-summary-resend-message'.  Non-nil
 168 value of this variable takes precedence over any existing Gcc header.
 169
 170 If this is `none', no Gcc copy will be made.  If this is t, messages
 171 resent will be Gcc'd to the current group.  If this is a string, it
 172 specifies a group to which resent messages will be Gcc'd.  If this is
 173 nil, Gcc will be done according to existing Gcc header(s), if any.
 174 If this is `no-gcc-self', resent messages will be Gcc'd to groups that
 175 existing Gcc header specifies, except for the current group."
 176   :version "24.3"
 177   :group 'gnus-message
 178   :type '(choice (const none) (const t) string (const nil)
 179                  (const no-gcc-self)))
 180
 181 (gnus-define-group-parameter
 182  posting-charset-alist
 183  :type list
 184  :function-document
 185  "Return the permitted unencoded charsets for posting of GROUP."
 186  :variable gnus-group-posting-charset-alist
 187  :variable-default
 188   '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 189     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 190     (message-this-is-mail nil nil)
 191     (message-this-is-news nil t))
 192  :variable-document
 193   "Alist of regexps and permitted unencoded charsets for posting.
 194 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 195 TEST is either a regular expression matching the newsgroup header or a
 196 variable to query,
 197 HEADER is the charset which may be left unencoded in the header (nil
 198 means encode all charsets),
 199 BODY-LIST is a list of charsets which may be encoded using 8bit
 200 content-transfer encoding in the body, or one of the special values
 201 nil (always encode using quoted-printable) or t (always use 8bit).
 202
 203 Note that any value other than nil for HEADER infringes some RFCs, so
 204 use this option with care."
 205  :variable-group gnus-charset
 206  :variable-type
 207  '(repeat (list :tag "Permitted unencoded charsets"
 208                 (choice :tag "Where"
 209                         (regexp :tag "Group")
 210                         (const :tag "Mail message" :value message-this-is-mail)
 211                         (const :tag "News article" :value message-this-is-news))
 212                 (choice :tag "Header"
 213                         (const :tag "None" nil)
 214                         (symbol :tag "Charset"))
 215                 (choice :tag "Body"
 216                         (const :tag "Any" :value t)
 217                         (const :tag "None" :value nil)
 218                         (repeat :tag "Charsets"
 219                                 (symbol :tag "Charset")))))
 220  :parameter-type '(choice :tag "Permitted unencoded charsets"
 221                           :value nil
 222                           (repeat (symbol)))
 223  :parameter-document       "\
 224 List of charsets that are permitted to be unencoded.")
 225
 226 (defcustom gnus-debug-files
 227   '("gnus.el" "gnus-sum.el" "gnus-group.el"
 228     "gnus-art.el" "gnus-start.el" "gnus-async.el"
 229     "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 230     "gnus-agent.el" "gnus-cache.el" "gnus-srvr.el"
 231     "mm-util.el" "mm-decode.el" "nnmail.el" "message.el")
 232   "Files whose variables will be reported in `gnus-bug'."
 233   :version "22.1"
 234   :group 'gnus-message
 235   :type '(repeat (string :tag "File")))
 236
 237 (defcustom gnus-debug-exclude-variables
 238   '(mm-mime-mule-charset-alist
 239     nnmail-split-fancy message-minibuffer-local-map)
 240   "Variables that should not be reported in `gnus-bug'."
 241   :version "22.1"
 242   :group 'gnus-message
 243   :type '(repeat (symbol :tag "Variable")))
 244
 245 (defcustom gnus-discouraged-post-methods
 246   '(nndraft nnml nnimap nnmaildir nnmh nnfolder nndir)
 247   "A list of back ends that are not used in \"real\" newsgroups.
 248 This variable is used only when `gnus-post-method' is `current'."
 249   :version "22.1"
 250   :group 'gnus-group-foreign
 251   :type '(repeat (symbol :tag "Back end")))
 252
 253 (defcustom gnus-message-replysign
 254   nil
 255   "Automatically sign replies to signed messages.
 256 See also the `mml-default-sign-method' variable."
 257   :group 'gnus-message
 258   :type 'boolean)
 259
 260 (defcustom gnus-message-replyencrypt t
 261   "Automatically encrypt replies to encrypted messages.
 262 See also the `mml-default-encrypt-method' variable."
 263   :version "24.1"
 264   :group 'gnus-message
 265   :type 'boolean)
 266
 267 (defcustom gnus-message-replysignencrypted
 268   t
 269   "Setting this causes automatically encrypted messages to also be signed."
 270   :group 'gnus-message
 271   :type 'boolean)
 272
 273 (defcustom gnus-confirm-mail-reply-to-news (and gnus-novice-user
 274                                                 (not gnus-expert-user))
 275   "If non-nil, Gnus requests confirmation when replying to news.
 276 This is done because new users often reply by mistake when reading
 277 news.
 278 This can also be a function receiving the group name as the only
 279 parameter, which should return non-nil if a confirmation is needed; or
 280 a regexp, in which case a confirmation is asked for if the group name
 281 matches the regexp."
 282   :version "23.1" ;; No Gnus (default changed)
 283   :group 'gnus-message
 284   :type '(choice (const :tag "No" nil)
 285                  (const :tag "Yes" t)
 286                  (regexp :tag "If group matches regexp")
 287                  (function :tag "If function evaluates to non-nil")))
 288
 289 (defcustom gnus-confirm-treat-mail-like-news
 290   nil
 291   "If non-nil, Gnus will treat mail like news with regard to confirmation
 292 when replying by mail.  See the `gnus-confirm-mail-reply-to-news' variable
 293 for fine-tuning this.
 294 If nil, Gnus will never ask for confirmation if replying to mail."
 295   :version "22.1"
 296   :group 'gnus-message
 297   :type 'boolean)
 298
 299 (defcustom gnus-summary-resend-default-address t
 300   "If non-nil, Gnus tries to suggest a default address to resend to.
 301 If nil, the address field will always be empty after invoking
 302 `gnus-summary-resend-message'."
 303   :version "22.1"
 304   :group 'gnus-message
 305   :type 'boolean)
 306
 307 (defcustom gnus-message-highlight-citation
 308   t ;; gnus-treat-highlight-citation ;; gnus-cite dependency
 309   "Enable highlighting of different citation levels in message-mode."
 310   :version "23.1" ;; No Gnus
 311   :group 'gnus-cite
 312   :group 'gnus-message
 313   :type 'boolean)
 314
 315 (defcustom gnus-gcc-pre-body-encode-hook nil
 316   "A hook called before encoding the body of the Gcc copy of a message.
 317 The current buffer (when the hook is run) contains the message
 318 including the message header.  Changes made to the message will
 319 only affect the Gcc copy, but not the original message."
 320   :group 'gnus-message
 321   :version "24.3"
 322   :type 'hook)
 323
 324 (defcustom gnus-gcc-post-body-encode-hook nil
 325     "A hook called after encoding the body of the Gcc copy of a message.
 326 The current buffer (when the hook is run) contains the message
 327 including the message header.  Changes made to the message will
 328 only affect the Gcc copy, but not the original message."
 329   :group 'gnus-message
 330   :version "24.3"
 331   :type 'hook)
 332
 333 (autoload 'gnus-message-citation-mode "gnus-cite" nil t)
 334
 335 ;;; Internal variables.
 336
 337 (defvar gnus-inhibit-posting-styles nil
 338   "Inhibit the use of posting styles.")
 339
 340 (defvar gnus-article-yanked-articles nil)
 341 (defvar gnus-message-buffer "*Mail Gnus*")
 342 (defvar gnus-article-copy nil)
 343 (defvar gnus-check-before-posting nil)
 344 (defvar gnus-last-posting-server nil)
 345 (defvar gnus-message-group-art nil)
 346
 347 (defvar gnus-msg-force-broken-reply-to nil)
 348
 349 (defconst gnus-bug-message
 350   "Sending a bug report to the Gnus Towers.
 351 ========================================
 352
 353 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 354 be sent to the Gnus Bug Exterminators.
 355
 356 The thing near the bottom of the buffer is how the environment
 357 settings will be included in the mail.  Please do not delete that.
 358 They will tell the Bug People what your environment is, so that it
 359 will be easier to locate the bugs.
 360
 361 If you have found a bug that makes Emacs go \"beep\", set
 362 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 363 and include the backtrace in your bug report.
 364
 365 Please describe the bug in annoying, painstaking detail.
 366
 367 Thank you for your help in stamping out bugs.
 368 ")
 369
 370 (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 371
 372 \f
 373 ;;;
 374 ;;; Gnus Posting Functions
 375 ;;;
 376
 377 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 378   "p" gnus-summary-post-news
 379   "i" gnus-summary-news-other-window
 380   "f" gnus-summary-followup
 381   "F" gnus-summary-followup-with-original
 382   "c" gnus-summary-cancel-article
 383   "s" gnus-summary-supersede-article
 384   "r" gnus-summary-reply
 385   "y" gnus-summary-yank-message
 386   "R" gnus-summary-reply-with-original
 387   "L" gnus-summary-reply-to-list-with-original
 388   "w" gnus-summary-wide-reply
 389   "W" gnus-summary-wide-reply-with-original
 390   "v" gnus-summary-very-wide-reply
 391   "V" gnus-summary-very-wide-reply-with-original
 392   "n" gnus-summary-followup-to-mail
 393   "N" gnus-summary-followup-to-mail-with-original
 394   "m" gnus-summary-mail-other-window
 395   "u" gnus-uu-post-news
 396   "\M-c" gnus-summary-mail-crosspost-complaint
 397   "Br" gnus-summary-reply-broken-reply-to
 398   "BR" gnus-summary-reply-broken-reply-to-with-original
 399   "om" gnus-summary-mail-forward
 400   "op" gnus-summary-post-forward
 401   "Om" gnus-uu-digest-mail-forward
 402   "Op" gnus-uu-digest-post-forward)
 403
 404 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 405   "b" gnus-summary-resend-bounced-mail
 406   ;; "c" gnus-summary-send-draft
 407   "r" gnus-summary-resend-message
 408   "e" gnus-summary-resend-message-edit)
 409
 410 ;;; Internal functions.
 411
 412 (defun gnus-inews-make-draft (articles)
 413   `(lambda ()
 414      (gnus-inews-make-draft-meta-information
 415       ,(gnus-group-decoded-name gnus-newsgroup-name) ',articles)))
 416
 417 (autoload 'nnir-article-number "nnir" nil nil 'macro)
 418 (autoload 'nnir-article-group "nnir" nil nil 'macro)
 419 (autoload 'gnus-nnir-group-p "nnir")
 420
 421
 422 (defvar gnus-article-reply nil)
 423 (defmacro gnus-setup-message (config &rest forms)
 424   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 425         (winconf-name (make-symbol "gnus-setup-message-winconf-name"))
 426         (buffer (make-symbol "gnus-setup-message-buffer"))
 427         (article (make-symbol "gnus-setup-message-article"))
 428         (yanked (make-symbol "gnus-setup-yanked-articles"))
 429         (group (make-symbol "gnus-setup-message-group")))
 430     `(let ((,winconf (current-window-configuration))
 431            (,winconf-name gnus-current-window-configuration)
 432            (,buffer (buffer-name (current-buffer)))
 433            (,article (if (and (gnus-nnir-group-p gnus-newsgroup-name)
 434                               gnus-article-reply)
 435                          (nnir-article-number (or (car-safe gnus-article-reply)
 436                                                   gnus-article-reply))
 437                        gnus-article-reply))
 438            (,yanked gnus-article-yanked-articles)
 439            (,group (if (and (gnus-nnir-group-p gnus-newsgroup-name)
 440                             gnus-article-reply)
 441                        (nnir-article-group (or (car-safe gnus-article-reply)
 442                                                gnus-article-reply))
 443                      gnus-newsgroup-name))
 444            (message-header-setup-hook
 445             (copy-sequence message-header-setup-hook))
 446            (mbl mml-buffer-list)
 447            (message-mode-hook (copy-sequence message-mode-hook)))
 448        (setq mml-buffer-list nil)
 449        (add-hook 'message-header-setup-hook (lambda ()
 450                                               (gnus-inews-insert-gcc ,group)))
 451        ;; message-newsreader and message-mailer were formerly set in
 452        ;; gnus-inews-add-send-actions, but this is too late when
 453        ;; message-generate-headers-first is used. --ansel
 454        (add-hook 'message-mode-hook
 455                  (lambda nil
 456                    (setq message-newsreader
 457                          (setq message-mailer (gnus-extended-version)))))
 458        ;; #### FIXME: for a reason that I did not manage to identify yet,
 459        ;; the variable `gnus-newsgroup-name' does not honor a dynamically
 460        ;; scoped or setq'ed value from a caller like `C-u gnus-summary-mail'.
 461        ;; After evaluation of @forms below, it gets the value we actually want
 462        ;; to override, and the posting styles are used. For that reason, I've
 463        ;; added an optional argument to `gnus-configure-posting-styles' to
 464        ;; make sure that the correct value for the group name is used. -- drv
 465        (add-hook 'message-mode-hook
 466                  (if (memq ,config '(reply-yank reply))
 467                      (lambda ()
 468                        (gnus-configure-posting-styles ,group))
 469                    (lambda ()
 470                      ;; There may be an old " *gnus article copy*" buffer.
 471                      (let (gnus-article-copy)
 472                        (gnus-configure-posting-styles ,group)))))
 473        (gnus-alist-pull ',(intern gnus-draft-meta-information-header)
 474                   message-required-headers)
 475        (when (and ,group
 476                   (not (string= ,group "")))
 477          (push (cons
 478                 (intern gnus-draft-meta-information-header)
 479                 (gnus-inews-make-draft (or ,yanked ,article)))
 480                message-required-headers))
 481        (unwind-protect
 482            (progn
 483              ,@forms)
 484          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config
 485                                       ,yanked ,winconf-name)
 486          (setq gnus-message-buffer (current-buffer))
 487          (set (make-local-variable 'gnus-message-group-art)
 488               (cons ,group ,article))
 489          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 490          ;; Enable highlighting of different citation levels
 491          (when gnus-message-highlight-citation
 492            (gnus-message-citation-mode 1))
 493          (gnus-run-hooks 'gnus-message-setup-hook)
 494          (if (eq major-mode 'message-mode)
 495              (let ((mbl1 mml-buffer-list))
 496                (setq mml-buffer-list mbl)  ;; Global value
 497                (set (make-local-variable 'mml-buffer-list) mbl1);; Local value
 498                (add-hook 'change-major-mode-hook 'mml-destroy-buffers nil t)
 499                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 500            (mml-destroy-buffers)
 501            (setq mml-buffer-list mbl)))
 502        (message-hide-headers)
 503        (gnus-add-buffer)
 504        (gnus-configure-windows ,config t)
 505        (run-hooks 'post-command-hook)
 506        (set-buffer-modified-p nil))))
 507
 508 (defun gnus-inews-make-draft-meta-information (group articles)
 509   (when (numberp articles)
 510     (setq articles (list articles)))
 511   (concat "(\"" group "\""
 512           (if articles
 513               (concat " "
 514                       (mapconcat
 515                        (lambda (elem)
 516                          (number-to-string
 517                           (if (consp elem)
 518                               (car elem)
 519                             elem)))
 520                        articles " "))
 521             "")
 522           ")"))
 523
 524 ;;;###autoload
 525 (defun gnus-msg-mail (&optional to subject other-headers continue
 526                                 switch-action yank-action send-actions
 527                                 return-action)
 528   "Start editing a mail message to be sent.
 529 Like `message-mail', but with Gnus paraphernalia, particularly the
 530 Gcc: header for archiving purposes.
 531 If Gnus isn't running, a plain `message-mail' setup is used
 532 instead."
 533   (interactive)
 534   (if (not (gnus-alive-p))
 535       (progn
 536         (message "Gnus not running; using plain Message mode")
 537         (message-mail to subject other-headers continue
 538                       nil yank-action send-actions return-action))
 539     (let ((buf (current-buffer))
 540           ;; Don't use posting styles corresponding to any existing group.
 541           (group-name gnus-newsgroup-name)
 542           mail-buf)
 543       (unwind-protect
 544           (progn
 545             (setq gnus-newsgroup-name "")
 546             (gnus-setup-message 'message
 547               (message-mail to subject other-headers continue
 548                             nil yank-action send-actions return-action)))
 549         (with-current-buffer buf
 550           (setq gnus-newsgroup-name group-name)))
 551       (when switch-action
 552         (setq mail-buf (current-buffer))
 553         (switch-to-buffer buf)
 554         (apply switch-action mail-buf nil))
 555       ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 556       t)))
 557
 558 ;;;###autoload
 559 (defun gnus-button-mailto (address)
 560   "Mail to ADDRESS."
 561   (set-buffer (gnus-copy-article-buffer))
 562   (gnus-setup-message 'message
 563     (message-reply address)))
 564
 565 ;;;###autoload
 566 (defun gnus-button-reply (&optional to-address wide)
 567   "Like `message-reply'."
 568   (interactive)
 569   (gnus-setup-message 'message
 570     (message-reply to-address wide)))
 571
 572 ;;;###autoload
 573 (define-mail-user-agent 'gnus-user-agent
 574   'gnus-msg-mail 'message-send-and-exit
 575   'message-kill-buffer 'message-send-hook)
 576
 577 (defun gnus-setup-posting-charset (group)
 578   (let ((alist gnus-group-posting-charset-alist)
 579         (group (or group ""))
 580         elem)
 581     (when group
 582       (catch 'found
 583         (while (setq elem (pop alist))
 584           (when (or (and (stringp (car elem))
 585                          (string-match (car elem) group))
 586                     (and (functionp (car elem))
 587                          (funcall (car elem) group))
 588                     (and (symbolp (car elem))
 589                          (symbol-value (car elem))))
 590             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 591
 592 (defun gnus-inews-add-send-actions (winconf buffer article
 593                                             &optional config yanked
 594                                             winconf-name)
 595   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 596                                  'gnus-inews-do-gcc) nil t)
 597   (when gnus-agent
 598     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 599   (setq message-post-method
 600         `(lambda (&optional arg)
 601            (gnus-post-method arg ,gnus-newsgroup-name)))
 602   (message-add-action
 603    `(progn
 604       (setq gnus-current-window-configuration ',winconf-name)
 605       (when (gnus-buffer-exists-p ,buffer)
 606         (set-window-configuration ,winconf)))
 607    'exit 'postpone 'kill)
 608   (let ((to-be-marked (cond
 609                        (yanked
 610                         (mapcar
 611                          (lambda (x) (if (listp x) (car x) x)) yanked))
 612                        (article (if (listp article) article (list article)))
 613                        (t nil))))
 614     (message-add-action
 615      `(when (gnus-buffer-exists-p ,buffer)
 616         (with-current-buffer ,buffer
 617           ,(when to-be-marked
 618              (if (eq config 'forward)
 619                  `(gnus-summary-mark-article-as-forwarded ',to-be-marked)
 620                `(gnus-summary-mark-article-as-replied ',to-be-marked)))))
 621      'send)))
 622
 623 (put 'gnus-setup-message 'lisp-indent-function 1)
 624 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 625
 626 ;;; Post news commands of Gnus group mode and summary mode
 627
 628 (defun gnus-group-mail (&optional arg)
 629   "Start composing a mail.
 630 If ARG, use the group under the point to find a posting style.
 631 If ARG is 1, prompt for a group name to find the posting style."
 632   (interactive "P")
 633   ;; We can't `let' gnus-newsgroup-name here, since that leads
 634   ;; to local variables leaking.
 635   (let ((group gnus-newsgroup-name)
 636         ;; make sure last viewed article doesn't affect posting styles:
 637         (gnus-article-copy)
 638         (buffer (current-buffer)))
 639     (unwind-protect
 640         (progn
 641           (setq gnus-newsgroup-name
 642                 (if arg
 643                     (if (= 1 (prefix-numeric-value arg))
 644                         (gnus-group-completing-read
 645                          "Use posting style of group"
 646                          nil (gnus-read-active-file-p))
 647                       (gnus-group-group-name))
 648                   ""))
 649           ;; #### see comment in gnus-setup-message -- drv
 650           (gnus-setup-message 'message (message-mail)))
 651       (with-current-buffer buffer
 652         (setq gnus-newsgroup-name group)))))
 653
 654 (defun gnus-group-news (&optional arg)
 655   "Start composing a news.
 656 If ARG, post to group under point.
 657 If ARG is 1, prompt for group name to post to.
 658
 659 This function prepares a news even when using mail groups.  This is useful
 660 for posting messages to mail groups without actually sending them over the
 661 network.  The corresponding back end must have a 'request-post method."
 662   (interactive "P")
 663   ;; We can't `let' gnus-newsgroup-name here, since that leads
 664   ;; to local variables leaking.
 665   (let ((group gnus-newsgroup-name)
 666         ;; make sure last viewed article doesn't affect posting styles:
 667         (gnus-article-copy)
 668         (buffer (current-buffer)))
 669     (unwind-protect
 670         (progn
 671           (setq gnus-newsgroup-name
 672                 (if arg
 673                     (if (= 1 (prefix-numeric-value arg))
 674                         (gnus-group-completing-read "Use group"
 675                                                     nil
 676                                                     (gnus-read-active-file-p))
 677                       (gnus-group-group-name))
 678                   ""))
 679           ;; #### see comment in gnus-setup-message -- drv
 680           (gnus-setup-message 'message
 681             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 682       (with-current-buffer buffer
 683         (setq gnus-newsgroup-name group)))))
 684
 685 (defun gnus-group-post-news (&optional arg)
 686   "Start composing a message (a news by default).
 687 If ARG, post to group under point.  If ARG is 1, prompt for group name.
 688 Depending on the selected group, the message might be either a mail or
 689 a news."
 690   (interactive "P")
 691   ;; Bind this variable here to make message mode hooks work ok.
 692   (let ((gnus-newsgroup-name
 693          (if arg
 694              (if (= 1 (prefix-numeric-value arg))
 695                  (gnus-group-completing-read "Newsgroup" nil
 696                                              (gnus-read-active-file-p))
 697                (or (gnus-group-group-name) ""))
 698            ""))
 699         ;; make sure last viewed article doesn't affect posting styles:
 700         (gnus-article-copy))
 701     (gnus-post-news 'post gnus-newsgroup-name nil nil nil nil
 702                     (string= gnus-newsgroup-name ""))))
 703
 704 (defun gnus-summary-mail-other-window (&optional arg)
 705   "Start composing a mail in another window.
 706 Use the posting of the current group by default.
 707 If ARG, don't do that.  If ARG is 1, prompt for group name to find the
 708 posting style."
 709   (interactive "P")
 710   ;; We can't `let' gnus-newsgroup-name here, since that leads
 711   ;; to local variables leaking.
 712   (let ((group gnus-newsgroup-name)
 713         ;; make sure last viewed article doesn't affect posting styles:
 714         (gnus-article-copy)
 715         (buffer (current-buffer)))
 716     (unwind-protect
 717         (progn
 718           (setq gnus-newsgroup-name
 719                 (if arg
 720                     (if (= 1 (prefix-numeric-value arg))
 721                         (gnus-group-completing-read "Use group"
 722                                                     nil
 723                                                     (gnus-read-active-file-p))
 724                       "")
 725                   gnus-newsgroup-name))
 726           ;; #### see comment in gnus-setup-message -- drv
 727           (gnus-setup-message 'message (message-mail)))
 728       (with-current-buffer buffer
 729         (setq gnus-newsgroup-name group)))))
 730
 731 (defun gnus-summary-news-other-window (&optional arg)
 732   "Start composing a news in another window.
 733 Post to the current group by default.
 734 If ARG, don't do that.  If ARG is 1, prompt for group name to post to.
 735
 736 This function prepares a news even when using mail groups.  This is useful
 737 for posting messages to mail groups without actually sending them over the
 738 network.  The corresponding back end must have a 'request-post method."
 739   (interactive "P")
 740   ;; We can't `let' gnus-newsgroup-name here, since that leads
 741   ;; to local variables leaking.
 742   (let ((group gnus-newsgroup-name)
 743         ;; make sure last viewed article doesn't affect posting styles:
 744         (gnus-article-copy)
 745         (buffer (current-buffer)))
 746     (unwind-protect
 747         (progn
 748           (setq gnus-newsgroup-name
 749                 (if arg
 750                     (if (= 1 (prefix-numeric-value arg))
 751                         (gnus-group-completing-read "Use group"
 752                                                     nil
 753                                                     (gnus-read-active-file-p))
 754                       "")
 755                   gnus-newsgroup-name))
 756           ;; #### see comment in gnus-setup-message -- drv
 757           (gnus-setup-message 'message
 758             (progn
 759               (message-news (gnus-group-real-name gnus-newsgroup-name))
 760               (set (make-local-variable 'gnus-discouraged-post-methods)
 761                    (remove
 762                     (car (gnus-find-method-for-group gnus-newsgroup-name))
 763                     gnus-discouraged-post-methods)))))
 764       (with-current-buffer buffer
 765         (setq gnus-newsgroup-name group)))))
 766
 767 (defun gnus-summary-post-news (&optional arg)
 768   "Start composing a message.  Post to the current group by default.
 769 If ARG, don't do that.  If ARG is 1, prompt for a group name to post to.
 770 Depending on the selected group, the message might be either a mail or
 771 a news."
 772   (interactive "P")
 773   ;; Bind this variable here to make message mode hooks work ok.
 774   (let ((gnus-newsgroup-name
 775          (if arg
 776              (if (= 1 (prefix-numeric-value arg))
 777                  (gnus-group-completing-read "Newsgroup" nil
 778                                              (gnus-read-active-file-p))
 779                "")
 780            gnus-newsgroup-name))
 781         ;; make sure last viewed article doesn't affect posting styles:
 782         (gnus-article-copy))
 783     (gnus-post-news 'post gnus-newsgroup-name)))
 784
 785
 786 (defun gnus-summary-followup (yank &optional force-news)
 787   "Compose a followup to an article.
 788 If prefix argument YANK is non-nil, the original article is yanked
 789 automatically.
 790 YANK is a list of elements, where the car of each element is the
 791 article number, and the cdr is the string to be yanked."
 792   (interactive
 793    (list (and current-prefix-arg
 794               (gnus-summary-work-articles 1))))
 795   (when yank
 796     (gnus-summary-goto-subject
 797      (if (listp (car yank))
 798          (caar yank)
 799        (car yank))))
 800   (save-window-excursion
 801     (gnus-summary-select-article))
 802   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 803         (gnus-newsgroup-name gnus-newsgroup-name))
 804     ;; Send a followup.
 805     (gnus-post-news nil gnus-newsgroup-name
 806                     headers gnus-article-buffer
 807                     yank nil force-news)
 808     (gnus-summary-handle-replysign)))
 809
 810 (defun gnus-summary-followup-with-original (n &optional force-news)
 811   "Compose a followup to an article and include the original article.
 812 The text in the region will be yanked.  If the region isn't
 813 active, the entire article will be yanked."
 814   (interactive "P")
 815   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 816
 817 (defun gnus-summary-followup-to-mail (&optional arg)
 818   "Followup to the current mail message via news."
 819   (interactive
 820    (list (and current-prefix-arg
 821               (gnus-summary-work-articles 1))))
 822   (gnus-summary-followup arg t))
 823
 824 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 825   "Followup to the current mail message via news."
 826   (interactive "P")
 827   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 828
 829 (defun gnus-inews-yank-articles (articles)
 830   (let (beg article yank-string)
 831     (message-goto-body)
 832     (while (setq article (pop articles))
 833       (when (listp article)
 834         (setq yank-string (nth 1 article)
 835               article (nth 0 article)))
 836       (save-window-excursion
 837         (set-buffer gnus-summary-buffer)
 838         (gnus-summary-select-article nil nil nil article)
 839         (gnus-summary-remove-process-mark article))
 840       (gnus-copy-article-buffer nil yank-string)
 841       (let ((message-reply-buffer gnus-article-copy)
 842             (message-reply-headers
 843              ;; The headers are decoded.
 844              (with-current-buffer gnus-article-copy
 845                (save-restriction
 846                  (nnheader-narrow-to-headers)
 847                  (nnheader-parse-naked-head)))))
 848         (message-yank-original)
 849         (message-exchange-point-and-mark)
 850         (setq beg (or beg (mark t))))
 851       (when articles
 852         (insert "\n")))
 853     (push-mark)
 854     (goto-char beg)))
 855
 856 (defun gnus-summary-cancel-article (&optional n symp)
 857   "Cancel an article you posted.
 858 Uses the process-prefix convention.  If given the symbolic
 859 prefix `a', cancel using the standard posting method; if not
 860 post using the current select method."
 861   (interactive (gnus-interactive "P\ny"))
 862   (let ((message-post-method
 863          `(lambda (arg)
 864             (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name)))
 865         (custom-address user-mail-address))
 866     (dolist (article (gnus-summary-work-articles n))
 867       (when (gnus-summary-select-article t nil nil article)
 868         ;; Pretend that we're doing a followup so that we can see what
 869         ;; the From header would have ended up being.
 870         (save-window-excursion
 871           (save-excursion
 872             (gnus-summary-followup nil)
 873             (let ((from (message-fetch-field "from")))
 874               (when from
 875                 (setq custom-address
 876                       (car (mail-header-parse-address from)))))
 877             (kill-buffer (current-buffer))))
 878         ;; Now cancel the article using the From header we got.
 879         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 880                 (let ((user-mail-address (or custom-address user-mail-address)))
 881                   (message-cancel-news)))
 882           (gnus-summary-mark-as-read article gnus-canceled-mark)
 883           (gnus-cache-remove-article 1))
 884         (gnus-article-hide-headers-if-wanted))
 885       (gnus-summary-remove-process-mark article))))
 886
 887 (defun gnus-summary-supersede-article ()
 888   "Compose an article that will supersede a previous article.
 889 This is done simply by taking the old article and adding a Supersedes
 890 header line with the old Message-ID."
 891   (interactive)
 892   (let ((article (gnus-summary-article-number))
 893         (mail-parse-charset gnus-newsgroup-charset))
 894     (gnus-setup-message 'reply-yank
 895       (gnus-summary-select-article t)
 896       (set-buffer gnus-original-article-buffer)
 897       (message-supersede)
 898       (push
 899        `((lambda ()
 900            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 901              (with-current-buffer ,gnus-summary-buffer
 902                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 903                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 904        message-send-actions)
 905       ;; Add Gcc header.
 906       (gnus-inews-insert-gcc))))
 907
 908 \f
 909
 910 (defun gnus-copy-article-buffer (&optional article-buffer yank-string)
 911   ;; make a copy of the article buffer with all text properties removed
 912   ;; this copy is in the buffer gnus-article-copy.
 913   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 914   ;; this buffer should be passed to all mail/news reply/post routines.
 915   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 916   (with-current-buffer gnus-article-copy
 917     (mm-enable-multibyte))
 918   (let ((article-buffer (or article-buffer gnus-article-buffer))
 919         end beg)
 920     (if (not (and (get-buffer article-buffer)
 921                   (gnus-buffer-exists-p article-buffer)))
 922         (error "Can't find any article buffer")
 923       (with-current-buffer article-buffer
 924         (let ((gnus-newsgroup-charset (or gnus-article-charset
 925                                           gnus-newsgroup-charset))
 926               (inhibit-read-only t)
 927               (gnus-newsgroup-ignored-charsets
 928                (or gnus-article-ignored-charsets
 929                    gnus-newsgroup-ignored-charsets)))
 930           (save-restriction
 931             ;; Copy over the (displayed) article buffer, delete
 932             ;; hidden text and remove text properties.
 933             (widen)
 934             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 935             (set-buffer gnus-article-copy)
 936             (when yank-string
 937               (message-goto-body)
 938               (delete-region (point) (point-max))
 939               (insert yank-string))
 940             (gnus-article-delete-text-of-type 'annotation)
 941             (gnus-article-delete-text-of-type 'multipart)
 942             (gnus-remove-text-with-property 'gnus-prev)
 943             (gnus-remove-text-with-property 'gnus-next)
 944             (gnus-remove-text-with-property 'gnus-decoration)
 945             (insert
 946              (prog1
 947                  (buffer-substring-no-properties (point-min) (point-max))
 948                (erase-buffer)))
 949             ;; Find the original headers.
 950             (set-buffer gnus-original-article-buffer)
 951             (goto-char (point-min))
 952             (while (looking-at message-unix-mail-delimiter)
 953               (forward-line 1))
 954             (let ((mail-header-separator ""))
 955               (setq beg (point)
 956                     end (or (message-goto-body)
 957                             ;; There may be just a header.
 958                             (point-max))))
 959             ;; Delete the headers from the displayed articles.
 960             (set-buffer gnus-article-copy)
 961             (let ((mail-header-separator ""))
 962               (delete-region (goto-char (point-min))
 963                              (or (message-goto-body) (point-max))))
 964             ;; Insert the original article headers.
 965             (insert-buffer-substring gnus-original-article-buffer beg end)
 966             ;; Decode charsets.
 967             (let ((gnus-article-decode-hook
 968                    (delq 'article-decode-charset
 969                          (copy-sequence gnus-article-decode-hook)))
 970                   (rfc2047-quote-decoded-words-containing-tspecials t))
 971               (run-hooks 'gnus-article-decode-hook)))))
 972       gnus-article-copy)))
 973
 974 (defun gnus-post-news (post &optional group header article-buffer yank subject
 975                             force-news)
 976   (when article-buffer
 977     (gnus-copy-article-buffer))
 978   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 979         (gnus-article-yanked-articles yank)
 980         (add-to-list gnus-add-to-list))
 981     (gnus-setup-message (cond (yank 'reply-yank)
 982                               (article-buffer 'reply)
 983                               (t 'message))
 984       (let* ((group (or group gnus-newsgroup-name))
 985              (charset (gnus-group-name-charset nil group))
 986              (pgroup group)
 987              to-address to-group mailing-list to-list
 988              newsgroup-p)
 989         (when group
 990           (setq to-address (gnus-parameter-to-address group)
 991                 to-group (gnus-group-find-parameter group 'to-group)
 992                 to-list (gnus-parameter-to-list group)
 993                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 994                 mailing-list (when gnus-mailing-list-groups
 995                                (string-match gnus-mailing-list-groups group))
 996                 group (gnus-group-name-decode (gnus-group-real-name group)
 997                                               charset)))
 998         (if (or (and to-group
 999                      (gnus-news-group-p to-group))
1000                 newsgroup-p
1001                 force-news
1002                 (and (gnus-news-group-p
1003                       (or pgroup gnus-newsgroup-name)
1004                       (or header gnus-current-article))
1005                      (not mailing-list)
1006                      (not to-list)
1007                      (not to-address)))
1008             ;; This is news.
1009             (if post
1010                 (message-news
1011                  (or to-group
1012                      (and (not (gnus-virtual-group-p pgroup)) group)))
1013               (set-buffer gnus-article-copy)
1014               (gnus-msg-treat-broken-reply-to)
1015               (message-followup (if (or newsgroup-p force-news)
1016                                     (if (save-restriction
1017                                           (article-narrow-to-head)
1018                                           (message-fetch-field "newsgroups"))
1019                                         nil
1020                                       "")
1021                                   to-group)))
1022           ;; The is mail.
1023           (if post
1024               (progn
1025                 (message-mail (or to-address to-list))
1026                 ;; Arrange for mail groups that have no `to-address' to
1027                 ;; get that when the user sends off the mail.
1028                 (when (and (not to-list)
1029                            (not to-address)
1030                            add-to-list)
1031                   (push (list 'gnus-inews-add-to-address pgroup)
1032                         message-send-actions)))
1033             (set-buffer gnus-article-copy)
1034             (gnus-msg-treat-broken-reply-to)
1035             (message-wide-reply to-address)))
1036         (when yank
1037           (gnus-inews-yank-articles yank))))))
1038
1039 (defun gnus-msg-treat-broken-reply-to (&optional force)
1040   "Remove the Reply-to header if broken-reply-to."
1041   (when (or force
1042             (gnus-group-find-parameter
1043              gnus-newsgroup-name 'broken-reply-to))
1044     (save-restriction
1045       (message-narrow-to-head)
1046       (message-remove-header "reply-to"))))
1047
1048 (defun gnus-post-method (arg group &optional silent)
1049   "Return the posting method based on GROUP and ARG.
1050 If SILENT, don't prompt the user."
1051   (let ((gnus-post-method (or (gnus-parameter-post-method group)
1052                               gnus-post-method))
1053         (group-method (gnus-find-method-for-group group)))
1054     (cond
1055      ;; If the group-method is nil (which shouldn't happen) we use
1056      ;; the default method.
1057      ((null group-method)
1058       (or (and (listp gnus-post-method) ;If not current/native/nil
1059                (not (listp (car gnus-post-method))) ; and not a list of methods
1060                gnus-post-method)        ;then use it.
1061           gnus-select-method
1062           message-post-method))
1063      ;; We want the inverse of the default
1064      ((and arg (not (eq arg 0)))
1065       (if (eq gnus-post-method 'current)
1066           gnus-select-method
1067         group-method))
1068      ;; We query the user for a post method.
1069      ((or arg
1070           (and (listp gnus-post-method)
1071                (listp (car gnus-post-method))))
1072       (let* ((methods
1073               ;; Collect all methods we know about.
1074               (append
1075                (when (listp gnus-post-method)
1076                  (if (listp (car gnus-post-method))
1077                      gnus-post-method
1078                    (list gnus-post-method)))
1079                gnus-secondary-select-methods
1080                (mapcar 'cdr gnus-server-alist)
1081                (mapcar 'car gnus-opened-servers)
1082                (list gnus-select-method)
1083                (list group-method)))
1084              method-alist post-methods method)
1085         ;; Weed out all mail methods.
1086         (while methods
1087           (setq method (gnus-server-get-method "" (pop methods)))
1088           (when (and (or (gnus-method-option-p method 'post)
1089                          (gnus-method-option-p method 'post-mail))
1090                      (not (member method post-methods)))
1091             (push method post-methods)))
1092         ;; Create a name-method alist.
1093         (setq method-alist
1094               (mapcar
1095                (lambda (m)
1096                  (if (equal (cadr m) "")
1097                      (list (symbol-name (car m)) m)
1098                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
1099                post-methods))
1100         ;; Query the user.
1101         (cadr
1102          (assoc
1103           (setq gnus-last-posting-server
1104                 (if (and silent
1105                          gnus-last-posting-server)
1106                     ;; Just use the last value.
1107                     gnus-last-posting-server
1108                   (gnus-completing-read
1109                    "Posting method" (mapcar 'car method-alist) t
1110                    (cons (or gnus-last-posting-server "") 0))))
1111           method-alist))))
1112      ;; Override normal method.
1113      ((and (eq gnus-post-method 'current)
1114            (not (memq (car group-method) gnus-discouraged-post-methods))
1115            (gnus-get-function group-method 'request-post t))
1116       (assert (not arg))
1117       group-method)
1118      ;; Use gnus-post-method.
1119      ((listp gnus-post-method)          ;A method...
1120       (assert (not (listp (car gnus-post-method)))) ;... not a list of methods.
1121       gnus-post-method)
1122      ;; Use the normal select method (nil or native).
1123      (t gnus-select-method))))
1124
1125 \f
1126
1127 (defun gnus-extended-version ()
1128   "Stringified Gnus version and Emacs version.
1129 See the variable `gnus-user-agent'."
1130   (interactive)
1131   (if (stringp gnus-user-agent)
1132       gnus-user-agent
1133     ;; `gnus-user-agent' is a list:
1134     (let* ((float-output-format nil)
1135            (gnus-v
1136             (when (memq 'gnus gnus-user-agent)
1137               (concat "Gnus/"
1138                       (replace-regexp-in-string
1139                        "0+\\'" ""
1140                        (format "%1.8f" (gnus-continuum-version gnus-version)))
1141                       " (" gnus-version ")")))
1142            (emacs-v (gnus-emacs-version)))
1143       (concat gnus-v (when (and gnus-v emacs-v) " ")
1144               emacs-v))))
1145
1146 \f
1147 ;;;
1148 ;;; Gnus Mail Functions
1149 ;;;
1150
1151 ;;; Mail reply commands of Gnus summary mode
1152
1153 (defun gnus-summary-reply (&optional yank wide very-wide)
1154   "Start composing a mail reply to the current message.
1155 If prefix argument YANK is non-nil, the original article is yanked
1156 automatically.
1157 If WIDE, make a wide reply.
1158 If VERY-WIDE, make a very wide reply."
1159   (interactive
1160    (list (and current-prefix-arg
1161               (gnus-summary-work-articles 1))))
1162   ;; Allow user to require confirmation before replying by mail to the
1163   ;; author of a news article (or mail message).
1164   (when (or (not (or (gnus-news-group-p gnus-newsgroup-name)
1165                      gnus-confirm-treat-mail-like-news))
1166             (not (cond ((stringp gnus-confirm-mail-reply-to-news)
1167                         (string-match gnus-confirm-mail-reply-to-news
1168                                       gnus-newsgroup-name))
1169                        ((functionp gnus-confirm-mail-reply-to-news)
1170                         (funcall gnus-confirm-mail-reply-to-news
1171                                  gnus-newsgroup-name))
1172                        (t gnus-confirm-mail-reply-to-news)))
1173             (if (or wide very-wide)
1174                 t ;; Ignore gnus-confirm-mail-reply-to-news for wide and very
1175                   ;; wide replies.
1176               (y-or-n-p "Really reply by mail to article author? ")))
1177     (let* ((article
1178             (if (listp (car yank))
1179                 (caar yank)
1180               (car yank)))
1181            (gnus-article-reply (or article (gnus-summary-article-number)))
1182            (gnus-article-yanked-articles yank)
1183            (headers ""))
1184       ;; Stripping headers should be specified with mail-yank-ignored-headers.
1185       (when yank
1186         (gnus-summary-goto-subject article))
1187       (gnus-setup-message (if yank 'reply-yank 'reply)
1188         (if (not very-wide)
1189             (gnus-summary-select-article)
1190           (dolist (article very-wide)
1191             (gnus-summary-select-article nil nil nil article)
1192             (with-current-buffer (gnus-copy-article-buffer)
1193               (gnus-msg-treat-broken-reply-to)
1194               (save-restriction
1195                 (message-narrow-to-head)
1196                 (setq headers (concat headers (buffer-string)))))))
1197         (set-buffer (gnus-copy-article-buffer))
1198         (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
1199         (save-restriction
1200           (message-narrow-to-head)
1201           (when very-wide
1202             (erase-buffer)
1203             (insert headers))
1204           (goto-char (point-max)))
1205         (mml-quote-region (point) (point-max))
1206         (message-reply nil wide)
1207         (when yank
1208           (gnus-inews-yank-articles yank))
1209         (gnus-summary-handle-replysign)))))
1210
1211 (defun gnus-summary-handle-replysign ()
1212   "Check the various replysign variables and take action accordingly."
1213   (when (or gnus-message-replysign gnus-message-replyencrypt)
1214     (let (signed encrypted)
1215       (with-current-buffer gnus-article-buffer
1216         (setq signed (memq 'signed gnus-article-wash-types))
1217         (setq encrypted (memq 'encrypted gnus-article-wash-types)))
1218       (cond ((and gnus-message-replyencrypt encrypted)
1219              (mml-secure-message mml-default-encrypt-method
1220                                  (if gnus-message-replysignencrypted
1221                                      'signencrypt
1222                                    'encrypt)))
1223             ((and gnus-message-replysign signed)
1224              (mml-secure-message mml-default-sign-method 'sign))))))
1225
1226 (defun gnus-summary-reply-with-original (n &optional wide)
1227   "Start composing a reply mail to the current message.
1228 The original article will be yanked."
1229   (interactive "P")
1230   (gnus-summary-reply (gnus-summary-work-articles n) wide))
1231
1232 (defun gnus-summary-reply-to-list-with-original (n &optional wide)
1233   "Start composing a reply mail to the current message.
1234 The reply goes only to the mailing list.
1235 The original article will be yanked."
1236   (interactive "P")
1237   (let ((message-reply-to-function
1238          (lambda nil
1239            `((To . ,(gnus-mailing-list-followup-to))))))
1240     (gnus-summary-reply (gnus-summary-work-articles n) wide)))
1241
1242 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
1243   "Like `gnus-summary-reply' except removing reply-to field.
1244 If prefix argument YANK is non-nil, the original article is yanked
1245 automatically.
1246 If WIDE, make a wide reply.
1247 If VERY-WIDE, make a very wide reply."
1248   (interactive
1249    (list (and current-prefix-arg
1250               (gnus-summary-work-articles 1))))
1251   (let ((gnus-msg-force-broken-reply-to t))
1252     (gnus-summary-reply yank wide very-wide)))
1253
1254 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
1255   "Like `gnus-summary-reply-with-original' except removing reply-to field.
1256 The original article will be yanked."
1257   (interactive "P")
1258   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
1259
1260 (defun gnus-summary-wide-reply (&optional yank)
1261   "Start composing a wide reply mail to the current message.
1262 If prefix argument YANK is non-nil, the original article is yanked
1263 automatically."
1264   (interactive
1265    (list (and current-prefix-arg
1266               (gnus-summary-work-articles 1))))
1267   (gnus-summary-reply yank t))
1268
1269 (defun gnus-summary-wide-reply-with-original (n)
1270   "Start composing a wide reply mail to the current message.
1271 The original article will be yanked.
1272 Uses the process/prefix convention."
1273   (interactive "P")
1274   (gnus-summary-reply-with-original n t))
1275
1276 (defun gnus-summary-very-wide-reply (&optional yank)
1277   "Start composing a very wide reply mail to the current message.
1278 If prefix argument YANK is non-nil, the original article is yanked
1279 automatically."
1280   (interactive
1281    (list (and current-prefix-arg
1282               (gnus-summary-work-articles 1))))
1283   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
1284
1285 (defun gnus-summary-very-wide-reply-with-original (n)
1286   "Start composing a very wide reply mail to the current message.
1287 The original article will be yanked."
1288   (interactive "P")
1289   (gnus-summary-reply
1290    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
1291
1292 (defun gnus-summary-mail-forward (&optional arg post)
1293   "Forward the current message(s) to another user.
1294 If process marks exist, forward all marked messages;
1295 if ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
1296 if ARG is 1, decode the message and forward directly inline;
1297 if ARG is 2, forward message as an rfc822 MIME section;
1298 if ARG is 3, decode message and forward as an rfc822 MIME section;
1299 if ARG is 4, forward message directly inline;
1300 otherwise, use flipped `message-forward-as-mime'.
1301 If POST, post instead of mail.
1302 For the \"inline\" alternatives, also see the variable
1303 `message-forward-ignored-headers'."
1304   (interactive "P")
1305   (if (cdr (gnus-summary-work-articles nil))
1306       ;; Process marks are given.
1307       (gnus-uu-digest-mail-forward nil post)
1308     ;; No process marks.
1309     (let ((message-forward-as-mime message-forward-as-mime)
1310           (message-forward-show-mml message-forward-show-mml))
1311       (cond
1312        ((null arg))
1313        ((eq arg 1)
1314         (setq message-forward-as-mime nil
1315               message-forward-show-mml t))
1316        ((eq arg 2)
1317         (setq message-forward-as-mime t
1318               message-forward-show-mml nil))
1319        ((eq arg 3)
1320         (setq message-forward-as-mime t
1321               message-forward-show-mml t))
1322        ((eq arg 4)
1323         (setq message-forward-as-mime nil
1324               message-forward-show-mml nil))
1325        (t
1326         (setq message-forward-as-mime (not message-forward-as-mime))))
1327       (let* ((gnus-article-reply (gnus-summary-article-number))
1328              (gnus-article-yanked-articles (list gnus-article-reply)))
1329         (gnus-setup-message 'forward
1330           (gnus-summary-select-article)
1331           (let ((mail-parse-charset
1332                  (or (and (gnus-buffer-live-p gnus-article-buffer)
1333                           (with-current-buffer gnus-article-buffer
1334                             gnus-article-charset))
1335                      gnus-newsgroup-charset))
1336                 (mail-parse-ignored-charsets
1337                  gnus-newsgroup-ignored-charsets))
1338             (set-buffer gnus-original-article-buffer)
1339             (message-forward post)))))))
1340
1341 (defun gnus-summary-resend-message-insert-gcc ()
1342   "Insert Gcc header according to `gnus-gcc-self-resent-messages'."
1343   (gnus-inews-insert-gcc)
1344   (let ((gcc (mapcar
1345               (lambda (group)
1346                 (encode-coding-string
1347                  group
1348                  (gnus-group-name-charset (gnus-inews-group-method group)
1349                                           group)))
1350               (message-unquote-tokens
1351                (message-tokenize-header (mail-fetch-field "gcc" nil t)
1352                                         " ,"))))
1353         (self (with-current-buffer gnus-summary-buffer
1354                 gnus-gcc-self-resent-messages)))
1355     (message-remove-header "gcc")
1356     (when gcc
1357       (goto-char (point-max))
1358       (cond ((eq self 'none))
1359             ((eq self t)
1360              (insert "Gcc: \"" gnus-newsgroup-name "\"\n"))
1361             ((stringp self)
1362              (insert "Gcc: "
1363                      (encode-coding-string
1364                       (if (string-match " " self)
1365                           (concat "\"" self "\"")
1366                         self)
1367                       (gnus-group-name-charset (gnus-inews-group-method self)
1368                                                self))
1369                      "\n"))
1370             ((null self)
1371              (insert "Gcc: " (mapconcat 'identity gcc ", ") "\n"))
1372             ((eq self 'no-gcc-self)
1373              (when (setq gcc (delete
1374                               gnus-newsgroup-name
1375                               (delete (concat "\"" gnus-newsgroup-name "\"")
1376                                       gcc)))
1377                (insert "Gcc: " (mapconcat 'identity gcc ", ") "\n")))))))
1378
1379 (defun gnus-summary-resend-message (address n)
1380   "Resend the current article to ADDRESS."
1381   (interactive
1382    (list (message-read-from-minibuffer
1383           "Resend message(s) to: "
1384           (when (and gnus-summary-resend-default-address
1385                      (gnus-buffer-live-p gnus-original-article-buffer))
1386             ;; If some other article is currently selected, the
1387             ;; initial-contents is wrong. Whatever, it is just the
1388             ;; initial-contents.
1389             (with-current-buffer gnus-original-article-buffer
1390               (nnmail-fetch-field "to"))))
1391          current-prefix-arg))
1392   (let ((message-header-setup-hook (copy-sequence message-header-setup-hook))
1393         (message-sent-hook (copy-sequence message-sent-hook))
1394         ;; Honor posting-style for `name' and `address' in Resent-From header.
1395         (styles (gnus-group-find-parameter gnus-newsgroup-name
1396                                            'posting-style t))
1397         (user-full-name user-full-name)
1398         (user-mail-address user-mail-address)
1399         tem)
1400     (dolist (style styles)
1401       (when (stringp (cadr style))
1402         (setcdr style (list (decode-coding-string (cadr style) 'utf-8)))))
1403     (dolist (style (if styles
1404                        (append gnus-posting-styles (list (cons ".*" styles)))
1405                      gnus-posting-styles))
1406       (when (and (stringp (car style))
1407                  (string-match (pop style) gnus-newsgroup-name))
1408         (when (setq tem (cadr (assq 'name style)))
1409           (setq user-full-name tem))
1410         (when (setq tem (cadr (assq 'address style)))
1411           (setq user-mail-address tem))))
1412     ;; `gnus-summary-resend-message-insert-gcc' must run last.
1413     (add-hook 'message-header-setup-hook
1414               'gnus-summary-resend-message-insert-gcc t)
1415     (add-hook 'message-sent-hook
1416               `(lambda ()
1417                  (let ((rfc2047-encode-encoded-words nil))
1418                    ,(if gnus-agent
1419                         '(gnus-agent-possibly-do-gcc)
1420                       '(gnus-inews-do-gcc)))))
1421     (dolist (article (gnus-summary-work-articles n))
1422       (gnus-summary-select-article nil nil nil article)
1423       (with-current-buffer gnus-original-article-buffer
1424         (let ((gnus-gcc-externalize-attachments nil)
1425               (message-inhibit-body-encoding t))
1426           (message-resend address)))
1427       (gnus-summary-mark-article-as-forwarded article))))
1428
1429 ;; From: Matthieu Moy <Matthieu.Moy@imag.fr>
1430 (defun gnus-summary-resend-message-edit ()
1431   "Resend an article that has already been sent.
1432 A new buffer will be created to allow the user to modify body and
1433 contents of the message, and then, everything will happen as when
1434 composing a new message."
1435   (interactive)
1436   (let ((mail-parse-charset gnus-newsgroup-charset))
1437     (gnus-setup-message 'reply-yank
1438       (gnus-summary-select-article t)
1439       (set-buffer gnus-original-article-buffer)
1440       (let ((cur (current-buffer))
1441             (to (message-fetch-field "to")))
1442         ;; Get a normal message buffer.
1443         (message-pop-to-buffer (message-buffer-name "Resend" to))
1444         (insert-buffer-substring cur)
1445         (mime-to-mml)
1446         (message-narrow-to-head-1)
1447         ;; Gnus will generate a new one when sending.
1448         (message-remove-header "Message-ID")
1449         ;; Remove unwanted headers.
1450         (message-remove-header message-ignored-resent-headers t)
1451         (goto-char (point-max))
1452         (insert mail-header-separator)
1453         ;; Add Gcc header.
1454         (gnus-inews-insert-gcc)
1455         (goto-char (point-min))
1456         (when (re-search-forward "^To:\\|^Newsgroups:" nil 'move)
1457           (forward-char 1))
1458         (widen)))))
1459
1460 (defun gnus-summary-post-forward (&optional arg)
1461   "Forward the current article to a newsgroup.
1462 See `gnus-summary-mail-forward' for ARG."
1463   (interactive "P")
1464   (gnus-summary-mail-forward arg t))
1465
1466 (defun gnus-summary-mail-crosspost-complaint (n)
1467   "Send a complaint about crossposting to the current article(s)."
1468   (interactive "P")
1469   (dolist (article (gnus-summary-work-articles n))
1470     (set-buffer gnus-summary-buffer)
1471     (gnus-summary-goto-subject article)
1472     (let ((group (gnus-group-real-name gnus-newsgroup-name))
1473           newsgroups followup-to)
1474       (gnus-summary-select-article)
1475       (set-buffer gnus-original-article-buffer)
1476       (if (and (<= (length (message-tokenize-header
1477                             (setq newsgroups
1478                                   (mail-fetch-field "newsgroups"))
1479                             ", "))
1480                    1)
1481                (or (not (setq followup-to (mail-fetch-field "followup-to")))
1482                    (not (member group (message-tokenize-header
1483                                        followup-to ", ")))))
1484           (if followup-to
1485               (gnus-message 1 "Followup-to restricted")
1486             (gnus-message 1 "Not a crossposted article"))
1487         (set-buffer gnus-summary-buffer)
1488         (gnus-summary-reply-with-original 1)
1489         (set-buffer gnus-message-buffer)
1490         (message-goto-body)
1491         (insert (format gnus-crosspost-complaint newsgroups group))
1492         (message-goto-subject)
1493         (re-search-forward " *$")
1494         (replace-match " (crosspost notification)" t t)
1495         (deactivate-mark)
1496         (when (gnus-y-or-n-p "Send this complaint? ")
1497           (message-send-and-exit))))))
1498
1499 (defun gnus-inews-add-to-address (group)
1500   (let ((to-address (mail-fetch-field "to")))
1501     (when (and to-address
1502                (gnus-alive-p))
1503       ;; This mail group doesn't have a `to-list', so we add one
1504       ;; here.  Magic!
1505       (when (gnus-y-or-n-p
1506              (format "Do you want to add this as `to-list': %s? " to-address))
1507         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1508
1509 (defun gnus-article-mail (yank)
1510   "Send a reply to the address near point.
1511 If YANK is non-nil, include the original article."
1512   (interactive "P")
1513   (let ((address
1514          (buffer-substring
1515           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1516           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1517     (when address
1518       (gnus-msg-mail address)
1519       (when yank
1520         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1521
1522 (defvar nntp-server-type)
1523 (defun gnus-bug ()
1524   "Send a bug report to the Gnus maintainers."
1525   (interactive)
1526   (unless (gnus-alive-p)
1527     (error "Gnus has been shut down"))
1528   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1529     (unless (message-mail-user-agent)
1530       (when gnus-bug-create-help-buffer
1531         (switch-to-buffer "*Gnus Help Bug*")
1532         (erase-buffer)
1533         (insert gnus-bug-message)
1534         (goto-char (point-min)))
1535       (message-pop-to-buffer "*Gnus Bug*"))
1536     (let ((message-this-is-mail t))
1537       (message-setup `((To . ,gnus-maintainer)
1538                        (Subject . ""))))
1539     (when gnus-bug-create-help-buffer
1540       (push `(gnus-bug-kill-buffer) message-send-actions))
1541     (goto-char (point-min))
1542     (message-goto-body)
1543     (insert "\n\n\n\n\n")
1544     (insert (gnus-version) "\n"
1545             (emacs-version) "\n")
1546     (when (and (boundp 'nntp-server-type)
1547                (stringp nntp-server-type))
1548       (insert nntp-server-type))
1549     (goto-char (point-min))
1550     (search-forward "Subject: " nil t)
1551     (message "")))
1552
1553 (defun gnus-bug-kill-buffer ()
1554   (when (get-buffer "*Gnus Help Bug*")
1555     (kill-buffer "*Gnus Help Bug*")))
1556
1557 (defun gnus-summary-yank-message (buffer n)
1558   "Yank the current article into a composed message."
1559   (interactive
1560    (list (gnus-completing-read "Buffer" (message-buffers) t)
1561          current-prefix-arg))
1562   (gnus-summary-iterate n
1563     (let ((gnus-inhibit-treatment t))
1564       (gnus-summary-select-article))
1565     (with-current-buffer buffer
1566       (message-yank-buffer gnus-article-buffer))))
1567
1568 ;;; Treatment of rejected articles.
1569 ;;; Bounced mail.
1570
1571 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1572   "Re-mail the current message.
1573 This only makes sense if the current message is a bounce message that
1574 contains some mail you have written which has been bounced back to
1575 you.
1576 If FETCH, try to fetch the article that this is a reply to, if indeed
1577 this is a reply."
1578   (interactive "P")
1579   (gnus-summary-select-article t)
1580   (let (summary-buffer parent)
1581     (if fetch
1582         (progn
1583           (setq summary-buffer (current-buffer))
1584           (set-buffer gnus-original-article-buffer)
1585           (article-goto-body)
1586           (when (re-search-forward "^References:\n?" nil t)
1587             (while (memq (char-after) '(?\t ? ))
1588               (forward-line 1))
1589             (skip-chars-backward "\t\n ")
1590             (setq parent
1591                   (gnus-parent-id (buffer-substring (match-end 0) (point))))))
1592       (set-buffer gnus-original-article-buffer))
1593     (gnus-setup-message 'compose-bounce
1594       (message-bounce)
1595       ;; Add Gcc header.
1596       (gnus-inews-insert-gcc)
1597       ;; If there are references, we fetch the article we answered to.
1598       (when parent
1599         (with-current-buffer summary-buffer
1600           (gnus-summary-refer-article parent)
1601           (gnus-summary-show-all-headers))))))
1602
1603 ;;; Gcc handling.
1604
1605 (defun gnus-inews-group-method (group)
1606   (cond
1607    ;; If the group doesn't exist, we assume
1608    ;; it's an archive group...
1609    ((and (null (gnus-get-info group))
1610          (eq (car (gnus-server-to-method gnus-message-archive-method))
1611              (car (gnus-server-to-method (gnus-group-method group)))))
1612     gnus-message-archive-method)
1613    ;; Use the method.
1614    ((gnus-info-method (gnus-get-info group))
1615     (gnus-info-method (gnus-get-info group)))
1616    ;; Find the method.
1617    (t (gnus-server-to-method (gnus-group-method group)))))
1618
1619 ;; Do Gcc handling, which copied the message over to some group.
1620 (defun gnus-inews-do-gcc (&optional gcc)
1621   (interactive)
1622   (save-excursion
1623     (save-restriction
1624       (message-narrow-to-headers)
1625       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1626             (cur (current-buffer))
1627             groups group method group-art options
1628             mml-externalize-attachments)
1629         (when gcc
1630           (message-remove-header "gcc")
1631           (widen)
1632           (setq groups (message-unquote-tokens
1633                         (message-tokenize-header gcc " ,")))
1634           ;; Copy the article over to some group(s).
1635           (while (setq group (pop groups))
1636             (setq method (gnus-inews-group-method group)
1637                   group (encode-coding-string
1638                          group
1639                          (gnus-group-name-charset method group)))
1640             (unless (gnus-check-server method)
1641               (error "Can't open server %s" (if (stringp method) method
1642                                               (car method))))
1643             (unless (gnus-request-group group t method)
1644               (gnus-request-create-group group method))
1645             (setq mml-externalize-attachments
1646                   (if (stringp gnus-gcc-externalize-attachments)
1647                       (string-match gnus-gcc-externalize-attachments group)
1648                     gnus-gcc-externalize-attachments))
1649             (save-excursion
1650               (nnheader-set-temp-buffer " *acc*")
1651               (setq message-options (with-current-buffer cur message-options))
1652               (insert-buffer-substring cur)
1653               (run-hooks 'gnus-gcc-pre-body-encode-hook)
1654               (message-encode-message-body)
1655               (run-hooks 'gnus-gcc-post-body-encode-hook)
1656               (save-restriction
1657                 (message-narrow-to-headers)
1658                 (let* ((newsgroups-field (save-restriction
1659                                            (message-narrow-to-headers-or-head)
1660                                            (message-fetch-field "Newsgroups")))
1661                        (followup-field (save-restriction
1662                                          (message-narrow-to-headers-or-head)
1663                                          (message-fetch-field "Followup-To")))
1664                        ;; BUG: We really need to get the charset for
1665                        ;; each name in the Newsgroups and Followup-To
1666                        ;; lines to allow crossposting between group
1667                        ;; names with incompatible character sets.
1668                        ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2001-10-08.
1669                        (group-field-charset
1670                         (gnus-group-name-charset
1671                          method (or newsgroups-field "")))
1672                        (followup-field-charset
1673                         (gnus-group-name-charset
1674                          method (or followup-field "")))
1675                        (rfc2047-header-encoding-alist
1676                         (append
1677                          (when group-field-charset
1678                            (list (cons "Newsgroups" group-field-charset)))
1679                          (when followup-field-charset
1680                            (list (cons "Followup-To" followup-field-charset)))
1681                          rfc2047-header-encoding-alist)))
1682                   (mail-encode-encoded-word-buffer)))
1683               (goto-char (point-min))
1684               (when (re-search-forward
1685                      (concat "^" (regexp-quote mail-header-separator) "$")
1686                      nil t)
1687                 (replace-match "" t t ))
1688               (when (or (not (gnus-check-backend-function
1689                               'request-accept-article group))
1690                         (not (setq group-art
1691                                    (gnus-request-accept-article
1692                                     group method t t))))
1693                 (gnus-message 1 "Couldn't store article in group %s: %s"
1694                               group (gnus-status-message method)))
1695               (when (stringp method)
1696                 (setq method (gnus-server-to-method method)))
1697               (when (and (listp method)
1698                          (gnus-native-method-p method))
1699                 (setq group (gnus-group-short-name group)))
1700               (when (and group-art
1701                          ;; FIXME: Should gcc-mark-as-read work when
1702                          ;; Gnus is not running?
1703                          (gnus-alive-p))
1704                 (if (or gnus-gcc-mark-as-read
1705                         (and (boundp 'gnus-inews-mark-gcc-as-read)
1706                              (symbol-value 'gnus-inews-mark-gcc-as-read)))
1707                     (gnus-group-mark-article-read group (cdr group-art))
1708                   (with-current-buffer gnus-group-buffer
1709                     (let ((gnus-group-marked (list group))
1710                           (gnus-get-new-news-hook nil)
1711                           (inhibit-read-only t))
1712                       (gnus-group-get-new-news-this-group nil t)))))
1713               (setq options message-options)
1714               (with-current-buffer cur (setq message-options options))
1715               (kill-buffer (current-buffer)))))))))
1716
1717 (defun gnus-inews-insert-gcc (&optional group)
1718   "Insert the Gcc to say where the article is to be archived."
1719   (let* ((group (or group gnus-newsgroup-name))
1720          (group (when group (gnus-group-decoded-name group)))
1721          (var (or gnus-outgoing-message-group gnus-message-archive-group))
1722          (gcc-self-val
1723           (and group (not (gnus-virtual-group-p group))
1724                (gnus-group-find-parameter group 'gcc-self t)))
1725          (gcc-self-get (lambda (gcc-self-val group)
1726                          (if (stringp gcc-self-val)
1727                              (if (string-match " " gcc-self-val)
1728                                  (concat "\"" gcc-self-val "\"")
1729                                gcc-self-val)
1730                            ;; In nndoc groups, we use the parent group name
1731                            ;; instead of the current group.
1732                            (let ((group (or (gnus-group-find-parameter
1733                                              gnus-newsgroup-name 'parent-group)
1734                                             group)))
1735                              (if (string-match " " group)
1736                                  (concat "\"" group "\"")
1737                                group)))))
1738          result
1739          (groups
1740           (cond
1741            ((null gnus-message-archive-method)
1742             ;; Ignore.
1743             nil)
1744            ((stringp var)
1745             ;; Just a single group.
1746             (list var))
1747            ((null var)
1748             ;; We don't want this.
1749             nil)
1750            ((and (listp var) (stringp (car var)))
1751             ;; A list of groups.
1752             var)
1753            ((functionp var)
1754             ;; A function.
1755             (funcall var group))
1756            (group
1757             ;; An alist of regexps/functions/forms.
1758             (while (and var
1759                         (not
1760                          (setq result
1761                                (cond
1762                                 ((and group
1763                                       (stringp (caar var)))
1764                                  ;; Regexp.
1765                                  (when (string-match (caar var) group)
1766                                    (cdar var)))
1767                                 ((and group
1768                                       (functionp (car var)))
1769                                  ;; Function.
1770                                  (funcall (car var) group))
1771                                 (t
1772                                  (eval (car var)))))))
1773               (setq var (cdr var)))
1774             result)))
1775          name)
1776     (when (and (or groups gcc-self-val)
1777                (gnus-alive-p))
1778       (when (stringp groups)
1779         (setq groups (list groups)))
1780       (save-excursion
1781         (save-restriction
1782           (message-narrow-to-headers)
1783           (goto-char (point-max))
1784           (insert "Gcc: ")
1785           (if gcc-self-val
1786               ;; Use the `gcc-self' param value instead.
1787               (progn
1788                 (insert (if (listp gcc-self-val)
1789                             (mapconcat (lambda (val)
1790                                          (funcall gcc-self-get val group))
1791                                        gcc-self-val ", ")
1792                             (funcall gcc-self-get gcc-self-val group)))
1793                 (if (not (eq gcc-self-val 'none))
1794                     (insert "\n")
1795                   (gnus-delete-line)))
1796             ;; Use the list of groups.
1797             (while (setq name (pop groups))
1798               (let ((str (if (string-match ":" name)
1799                              name
1800                            (gnus-group-prefixed-name
1801                             name gnus-message-archive-method))))
1802                 (insert (if (string-match " " str)
1803                             (concat "\"" str "\"")
1804                           str)))
1805               (when groups
1806                 (insert " ")))
1807             (insert "\n")))))))
1808
1809 (defun gnus-mailing-list-followup-to ()
1810   "Look at the headers in the current buffer and return a Mail-Followup-To address."
1811   (let ((x-been-there (gnus-fetch-original-field "x-beenthere"))
1812         (list-post (gnus-fetch-original-field "list-post")))
1813     (when (and list-post
1814                (string-match "mailto:\\([^>]+\\)" list-post))
1815       (setq list-post (match-string 1 list-post)))
1816     (or list-post
1817         x-been-there)))
1818
1819 ;;; Posting styles.
1820
1821 (defun gnus-configure-posting-styles (&optional group-name)
1822   "Configure posting styles according to `gnus-posting-styles'."
1823   (unless gnus-inhibit-posting-styles
1824     (let ((group (or group-name gnus-newsgroup-name ""))
1825           (styles (if (gnus-buffer-live-p gnus-summary-buffer)
1826                       (with-current-buffer gnus-summary-buffer
1827                         gnus-posting-styles)
1828                     gnus-posting-styles))
1829           style match attribute value v results matched-string
1830           filep name address element)
1831       ;; If the group has a posting-style parameter, add it at the end with a
1832       ;; regexp matching everything, to be sure it takes precedence over all
1833       ;; the others.
1834       (when gnus-newsgroup-name
1835         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1836           (when tmp-style
1837             (dolist (style tmp-style)
1838               (when (stringp (cadr style))
1839                 (setcdr style (list (decode-coding-string (cadr style)
1840                                                           'utf-8)))))
1841             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1842       ;; Go through all styles and look for matches.
1843       (dolist (style styles)
1844         (setq match (pop style))
1845         (goto-char (point-min))
1846         (when (cond
1847                ((stringp match)
1848                 ;; Regexp string match on the group name.
1849                 (when (string-match match group)
1850                   (setq matched-string group)
1851                   t))
1852                ((eq match 'header)
1853                 ;; Obsolete format of header match.
1854                 (and (gnus-buffer-live-p gnus-article-copy)
1855                      (with-current-buffer gnus-article-copy
1856                        (save-restriction
1857                          (nnheader-narrow-to-headers)
1858                          (let ((header (message-fetch-field (pop style))))
1859                            (and header
1860                                 (string-match (pop style) header)))))))
1861                ((or (symbolp match)
1862                     (functionp match))
1863                 (cond
1864                  ((functionp match)
1865                   ;; Function to be called.
1866                   (funcall match))
1867                  ((boundp match)
1868                   ;; Variable to be checked.
1869                   (symbol-value match))))
1870                ((listp match)
1871                 (cond
1872                  ((eq (car match) 'header)
1873                   ;; New format of header match.
1874                   (and (gnus-buffer-live-p gnus-article-copy)
1875                        (with-current-buffer gnus-article-copy
1876                          (save-restriction
1877                            (nnheader-narrow-to-headers)
1878                            (let ((header (message-fetch-field (nth 1 match))))
1879                              (and header
1880                                   (string-match (nth 2 match) header)
1881                                   (setq matched-string header)))))))
1882                  (t
1883                   ;; This is a form to be evalled.
1884                   (eval match)))))
1885           ;; We have a match, so we set the variables.
1886           (dolist (attribute style)
1887             (setq element (pop attribute)
1888                   filep nil)
1889             (setq value
1890                   (cond
1891                    ((eq (car attribute) :file)
1892                     (setq filep t)
1893                     (cadr attribute))
1894                    ((eq (car attribute) :value)
1895                     (cadr attribute))
1896                    (t
1897                     (car attribute))))
1898             ;; We get the value.
1899             (setq v
1900                   (cond
1901                    ((stringp value)
1902                     (if (and matched-string
1903                              (string-match-p "\\\\[&[:digit:]]" value)
1904                              (match-beginning 1))
1905                         (match-substitute-replacement value nil nil
1906                                                       matched-string)
1907                       value))
1908                    ((or (symbolp value)
1909                         (functionp value))
1910                     (cond ((functionp value)
1911                            (funcall value))
1912                           ((boundp value)
1913                            (symbol-value value))))
1914                    ((listp value)
1915                     (eval value))))
1916             ;; Translate obsolescent value.
1917             (cond
1918              ((eq element 'signature-file)
1919               (setq element 'signature
1920                     filep t))
1921              ((eq element 'x-face-file)
1922               (setq element 'x-face
1923                     filep t)))
1924             ;; Post-processing for the signature posting-style:
1925             (and (eq element 'signature) filep
1926                  message-signature-directory
1927                  ;; don't actually use the signature directory
1928                  ;; if message-signature-file contains a path.
1929                  (not (file-name-directory v))
1930                  (setq v (nnheader-concat message-signature-directory v)))
1931             ;; Get the contents of file elems.
1932             (when (and filep v)
1933               (setq v (with-temp-buffer
1934                         (insert-file-contents v)
1935                         (buffer-substring
1936                          (point-min)
1937                          (progn
1938                            (goto-char (point-max))
1939                            (if (zerop (skip-chars-backward "\n"))
1940                                (point)
1941                              (1+ (point))))))))
1942             (setq results (delq (assoc element results) results))
1943             (push (cons element v) results))))
1944       ;; Now we have all the styles, so we insert them.
1945       (setq name (assq 'name results)
1946             address (assq 'address results))
1947       (setq results (delq name (delq address results)))
1948       (setq results (sort results (lambda (x y)
1949                                     (string-lessp (car x) (car y)))))
1950       (dolist (result results)
1951         (add-hook 'message-setup-hook
1952                   (cond
1953                    ((eq 'eval (car result))
1954                     'ignore)
1955                    ((eq 'body (car result))
1956                     `(lambda ()
1957                        (save-excursion
1958                          (message-goto-body)
1959                          (insert ,(cdr result)))))
1960                    ((eq 'signature (car result))
1961                     (set (make-local-variable 'message-signature) nil)
1962                     (set (make-local-variable 'message-signature-file) nil)
1963                     (if (not (cdr result))
1964                         'ignore
1965                       `(lambda ()
1966                          (save-excursion
1967                            (let ((message-signature ,(cdr result)))
1968                              (when message-signature
1969                                (message-insert-signature)))))))
1970                    (t
1971                     (let ((header
1972                            (if (symbolp (car result))
1973                                (capitalize (symbol-name (car result)))
1974                              (car result))))
1975                       `(lambda ()
1976                          (save-excursion
1977                            (message-remove-header ,header)
1978                            (let ((value ,(cdr result)))
1979                              (when value
1980                                (message-goto-eoh)
1981                                (insert ,header ": " value)
1982                                (unless (bolp)
1983                                  (insert "\n")))))))))
1984                   nil 'local))
1985       (when (or name address)
1986         (add-hook 'message-setup-hook
1987                   `(lambda ()
1988                      (set (make-local-variable 'user-mail-address)
1989                           ,(or (cdr address) user-mail-address))
1990                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1991                            (user-mail-address
1992                             ,(or (cdr address) user-mail-address)))
1993                        (save-excursion
1994                          (message-remove-header "From")
1995                          (message-goto-eoh)
1996                          (insert "From: " (message-make-from) "\n"))))
1997                   nil 'local)))))
1998
1999 (provide 'gnus-msg)
2000
2001 ;;; gnus-msg.el ends here