lisp/play/cookie1.el

   1 ;;; cookie1.el --- retrieve random phrases from fortune cookie files
   2
   3 ;; Copyright (C) 1993, 2001-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   6 ;; Maintainer: FSF
   7 ;; Keywords: games, extensions
   8 ;; Created: Mon Mar 22 17:06:26 1993
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Support for random cookie fetches from phrase files, used for such
  28 ;; critical applications as emulating Zippy the Pinhead and confounding
  29 ;; the NSA Trunk Trawler.
  30 ;;
  31 ;; The two entry points are `cookie' and `cookie-insert'.  The helper
  32 ;; function `shuffle-vector' may be of interest to programmers.
  33 ;;
  34 ;; The code expects phrase files to be in one of two formats:
  35 ;;
  36 ;; * ITS-style LINS format (strings terminated by ASCII 0 characters,
  37 ;; leading whitespace ignored).
  38 ;;
  39 ;; * UNIX fortune file format (quotes terminated by %% on a line by itself).
  40 ;;
  41 ;; Everything up to the first delimiter is treated as a comment.  Other
  42 ;; formats could be supported by adding alternates to the regexp
  43 ;; `cookie-delimiter'.
  44 ;;
  45 ;; strfile(1) is the program used to compile the files for fortune(6).
  46 ;; In order to achieve total compatibility with strfile(1), cookie files
  47 ;; should start with two consecutive delimiters (and no comment).
  48 ;;
  49 ;; This code derives from Steve Strassmann's 1987 spook.el package, but
  50 ;; has been generalized so that it supports multiple simultaneous
  51 ;; cookie databases and fortune files.  It is intended to be called
  52 ;; from other packages such as yow.el and spook.el.
  53
  54 ;;; Code:
  55
  56 ; Randomize the seed in the random number generator.
  57 (random t)
  58
  59 (defconst cookie-delimiter "\n%%\n\\|\n%\n\\|\0"
  60   "Delimiter used to separate cookie file entries.")
  61
  62 (defvar cookie-cache (make-vector 511 0)
  63   "Cache of cookie files that have already been snarfed.")
  64
  65 ;;;###autoload
  66 (defun cookie (phrase-file startmsg endmsg)
  67   "Return a random phrase from PHRASE-FILE.
  68 When the phrase file is read in, display STARTMSG at the beginning
  69 of load, ENDMSG at the end."
  70   (let ((cookie-vector (cookie-snarf phrase-file startmsg endmsg)))
  71     (shuffle-vector cookie-vector)
  72     (aref cookie-vector 0)))
  73
  74 ;;;###autoload
  75 (defun cookie-insert (phrase-file &optional count startmsg endmsg)
  76   "Insert random phrases from PHRASE-FILE; COUNT of them.
  77 When the phrase file is read in, display STARTMSG at the beginning
  78 of load, ENDMSG at the end."
  79   (let ((cookie-vector (cookie-snarf phrase-file startmsg endmsg)))
  80     (shuffle-vector cookie-vector)
  81     (let ((start (point)))
  82       (insert ?\n)
  83       (cookie1 (min (- (length cookie-vector) 1) (or count 1)) cookie-vector)
  84       (insert ?\n)
  85       (fill-region-as-paragraph start (point) nil))))
  86
  87 (defun cookie1 (arg cookie-vec)
  88   "Inserts a cookie phrase ARG times."
  89   (cond ((zerop arg) t)
  90         (t (insert (aref cookie-vec arg))
  91            (insert " ")
  92            (cookie1 (1- arg) cookie-vec))))
  93
  94 ;;;###autoload
  95 (defun cookie-snarf (phrase-file startmsg endmsg)
  96   "Reads in the PHRASE-FILE, returns it as a vector of strings.
  97 Emit STARTMSG and ENDMSG before and after.  Caches the result; second
  98 and subsequent calls on the same file won't go to disk."
  99   (or (file-readable-p phrase-file)
 100       (error "Cannot read file `%s'" phrase-file))
 101   (let ((sym (intern-soft phrase-file cookie-cache)))
 102     (and sym (not (equal (symbol-function sym)
 103                          (nth 5 (file-attributes phrase-file))))
 104          (yes-or-no-p (concat phrase-file
 105                               " has changed.  Read new contents? "))
 106          (setq sym nil))
 107     (if sym
 108         (symbol-value sym)
 109       (setq sym (intern phrase-file cookie-cache))
 110       (message "%s" startmsg)
 111       (save-excursion
 112         (let ((buf (generate-new-buffer "*cookie*"))
 113               (result nil))
 114           (set-buffer buf)
 115           (fset sym (nth 5 (file-attributes phrase-file)))
 116           (insert-file-contents (expand-file-name phrase-file))
 117           (re-search-forward cookie-delimiter)
 118           (while (progn (skip-chars-forward " \t\n\r\f") (not (eobp)))
 119             (let ((beg (point)))
 120               (re-search-forward cookie-delimiter)
 121               (setq result (cons (buffer-substring beg (match-beginning 0))
 122                                  result))))
 123           (kill-buffer buf)
 124           (message "%s" endmsg)
 125           (set sym (apply 'vector result)))))))
 126
 127 (defun read-cookie (prompt phrase-file startmsg endmsg &optional require-match)
 128   "Prompt with PROMPT and read with completion among cookies in PHRASE-FILE.
 129 STARTMSG and ENDMSG are passed along to `cookie-snarf'.
 130 Optional fifth arg REQUIRE-MATCH non-nil forces a matching cookie."
 131   ;; Make sure the cookies are in the cache.
 132   (or (intern-soft phrase-file cookie-cache)
 133       (cookie-snarf phrase-file startmsg endmsg))
 134   (completing-read prompt
 135                    (let ((sym (intern phrase-file cookie-cache)))
 136                      ;; We cache the alist form of the cookie in a property.
 137                      (or (get sym 'completion-alist)
 138                          (let* ((alist nil)
 139                                 (vec (cookie-snarf phrase-file
 140                                                    startmsg endmsg))
 141                                 (i (length vec)))
 142                            (while (>= (setq i (1- i)) 0)
 143                              (setq alist (cons (list (aref vec i)) alist)))
 144                            (put sym 'completion-alist alist))))
 145                    nil require-match nil nil))
 146
 147 ; Thanks to Ian G Batten <BattenIG@CS.BHAM.AC.UK>
 148 ; [of the University of Birmingham Computer Science Department]
 149 ; for the iterative version of this shuffle.
 150 ;
 151 ;;;###autoload
 152 (defun shuffle-vector (vector)
 153   "Randomly permute the elements of VECTOR (all permutations equally likely)."
 154   (let ((i 0)
 155         j
 156         temp
 157         (len (length vector)))
 158     (while (< i len)
 159       (setq j (+ i (random (- len i))))
 160       (setq temp (aref vector i))
 161       (aset vector i (aref vector j))
 162       (aset vector j temp)
 163       (setq i (1+ i))))
 164   vector)
 165
 166 (provide 'cookie1)
 167
 168 ;;; cookie1.el ends here