| blob | 490dfbbb8abd45e7333c61b205ec748ca4732b4f |
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003
7 dnl Free Software Foundation, Inc.
8 dnl
9 dnl This file is part of GNU Emacs.
10 dnl
11 dnl GNU Emacs is free software; you can redistribute it and/or modify
12 dnl it under the terms of the GNU General Public License as published by
13 dnl the Free Software Foundation; either version 2, or (at your option)
14 dnl any later version.
15 dnl
16 dnl GNU Emacs is distributed in the hope that it will be useful,
17 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
18 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19 dnl GNU General Public License for more details.
20 dnl
21 dnl You should have received a copy of the GNU General Public License
22 dnl along with GNU Emacs; see the file COPYING. If not, write to the
23 dnl Free Software Foundation, Inc., 59 Temple Place - Suite 330,
24 dnl Boston, MA 02111-1307, USA.
26 AC_PREREQ(2.54)dnl
27 AC_INIT(src/lisp.h)
28 AC_CONFIG_HEADER(src/config.h:src/config.in)
30 dnl Support for --program-prefix, --program-suffix and
31 dnl --program-transform-name options
32 AC_ARG_PROGRAM
34 lispdir='${datadir}/emacs/${version}/lisp'
35 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
36 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
37 lisppath='${locallisppath}:${lispdir}'
38 etcdir='${datadir}/emacs/${version}/etc'
39 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
40 docdir='${datadir}/emacs/${version}/etc'
41 gamedir='${localstatedir}/games/emacs'
43 gameuser=games
45 AC_ARG_WITH(gcc,
46 [ --without-gcc don't use GCC to compile Emacs if GCC is found])
47 AC_ARG_WITH(pop,
48 [ --without-pop don't support POP mail retrieval with movemail],
49 [if test "$withval" = yes; then
50 AC_DEFINE(MAIL_USE_POP)
51 else :
52 fi],
53 AC_DEFINE(MAIL_USE_POP))
54 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
55 AC_ARG_WITH(kerberos,
56 [ --with-kerberos support Kerberos-authenticated POP],
57 [AC_DEFINE(KERBEROS)])
58 AH_TEMPLATE(KERBEROS,
59 [Define to support Kerberos-authenticated POP mail retrieval.])dnl
60 AC_ARG_WITH(kerberos5,
61 [ --with-kerberos5 support Kerberos version 5 authenticated POP],
62 [if test "${with_kerberos5+set}" = set; then
63 if test "${with_kerberos+set}" != set; then
64 with_kerberos=yes
65 AC_DEFINE(KERBEROS)
66 fi
67 fi
68 AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])])
69 AC_ARG_WITH(hesiod,
70 [ --with-hesiod support Hesiod to get the POP server host],
71 [AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])])
73 AC_ARG_WITH(sound,
74 [ --without-sound don't compile with sound support])
76 dnl This should be the last --with option, because --with-x is
77 dnl added later on when we find the path of X, and it's best to
78 dnl keep them together visually.
79 AC_ARG_WITH(x-toolkit,
80 [ --with-x-toolkit=KIT use an X toolkit
81 (KIT = yes/lucid/athena/motif/gtk/no)],
82 [ case "${withval}" in
83 y | ye | yes ) val=athena ;;
84 n | no ) val=no ;;
85 l | lu | luc | luci | lucid ) val=lucid ;;
86 a | at | ath | athe | athen | athena ) val=athena ;;
87 m | mo | mot | moti | motif ) val=motif ;;
88 g | gt | gtk ) val=gtk ;;
89 dnl These don't currently work.
90 dnl o | op | ope | open | open- | open-l | open-lo \
91 dnl | open-loo | open-look ) val=open-look ;;
92 * )
93 dnl AC_MSG_ERROR([the `--with-x-toolkit' option is supposed to have a value
94 dnl which is `yes', `no', `lucid', `athena', `motif' or `open-look'.])
95 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid\;
96 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
97 Currently, `yes', `athena' and `lucid' are synonyms.])
98 ;;
99 esac
100 with_x_toolkit=$val
101 ])
102 AC_ARG_WITH(xpm,
103 [ --with-xpm use -lXpm for displaying XPM images])
104 AC_ARG_WITH(jpeg,
105 [ --with-jpeg use -ljpeg for displaying JPEG images])
106 AC_ARG_WITH(tiff,
107 [ --with-tiff use -ltiff for displaying TIFF images])
108 AC_ARG_WITH(gif,
109 [ --with-gif use -lungif for displaying GIF images])
110 AC_ARG_WITH(png,
111 [ --with-png use -lpng for displaying PNG images])
112 AC_ARG_WITH(gtk,
113 [ --with-gtk use GTK (same as --with-x-toolkit=gtk)])
114 AC_ARG_WITH(pkg-config-prog,
115 [ --with-pkg-config-prog Path to pkg-config to use for finding GTK])
116 AC_ARG_WITH(toolkit-scroll-bars,
117 [ --without-toolkit-scroll-bars
118 don't use Motif or Xaw3d scroll bars])
119 AC_ARG_WITH(xim,
120 [ --without-xim don't use X11 XIM])
121 AC_ARG_WITH(carbon,
122 [ --without-carbon don't use Carbon GUI on Mac OS X])
123 AC_ARG_ENABLE(carbon-app,
124 [[ --enable-carbon-app[=DIR] [DIR=/Application]
125 specify install directory for Emacs.app on Mac OS X]],
126 [ carbon_appdir_x=${enableval}])
128 #### Make srcdir absolute, if it isn't already. It's important to
129 #### avoid running the path through pwd unnecessarily, since pwd can
130 #### give you automounter prefixes, which can go away. We do all this
131 #### so Emacs can find its files when run uninstalled.
132 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
133 unset CDPATH
134 case "${srcdir}" in
135 /* ) ;;
136 . )
137 ## We may be able to use the $PWD environment variable to make this
138 ## absolute. But sometimes PWD is inaccurate.
139 ## Note: we used to use ${PWD} at the end instead of `pwd`,
140 ## but that tested only for a well-formed and valid PWD,
141 ## it did not object when PWD was well-formed and valid but just wrong.
142 if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`" ;
143 then
144 srcdir="$PWD"
145 else
146 srcdir="`(cd ${srcdir}; pwd)`"
147 fi
148 ;;
149 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
150 esac
152 #### Check if the source directory already has a configured system in it.
153 if test `pwd` != `(cd ${srcdir} && pwd)` \
154 && test -f "${srcdir}/src/config.h" ; then
155 AC_MSG_WARN([[The directory tree `${srcdir}' is being used
156 as a build directory right now; it has been configured in its own
157 right. To configure in another directory as well, you MUST
158 use GNU make. If you do not have GNU make, then you must
159 now do `make distclean' in ${srcdir},
160 and then run $0 again.]])
162 [extrasub='/^VPATH[ ]*=/c\
163 vpath %.c $(srcdir)\
164 vpath %.h $(srcdir)\
165 vpath %.y $(srcdir)\
166 vpath %.l $(srcdir)\
167 vpath %.s $(srcdir)\
168 vpath %.in $(srcdir)\
169 vpath %.texi $(srcdir)']
170 fi
172 #### Given the configuration name, set machfile and opsysfile to the
173 #### names of the m/*.h and s/*.h files we should use.
175 ### Canonicalize the configuration name.
177 AC_CANONICAL_HOST
178 canonical=$host
179 configuration=${host_alias-$host}
181 dnl This used to use changequote, but, apart from `changequote is evil'
182 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
183 dnl the great gob of text. Thus it's not processed for possible expansion.
184 dnl Just make sure the brackets remain balanced.
185 [
187 ### If you add support for a new configuration, add code to this
188 ### switch statement to recognize your configuration name and select
189 ### the appropriate operating system and machine description files.
191 ### You would hope that you could choose an m/*.h file pretty much
192 ### based on the machine portion of the configuration name, and an s-
193 ### file based on the operating system portion. However, it turns out
194 ### that each m/*.h file is pretty manufacturer-specific - for
195 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
196 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
197 ### machines. So we basically have to have a special case for each
198 ### configuration name.
199 ###
200 ### As far as handling version numbers on operating systems is
201 ### concerned, make sure things will fail in a fixable way. If
202 ### /etc/MACHINES doesn't say anything about version numbers, be
203 ### prepared to handle anything reasonably. If version numbers
204 ### matter, be sure /etc/MACHINES says something about it.
205 ###
206 ### Eric Raymond says we should accept strings like "sysvr4" to mean
207 ### "System V Release 4"; he writes, "The old convention encouraged
208 ### confusion between `system' and `release' levels'."
210 machine='' opsys='' unported=no
211 case "${canonical}" in
213 ## FreeBSD ports
214 *-*-freebsd* )
215 opsys=freebsd
216 case "${canonical}" in
217 alpha*-*-freebsd*) machine=alpha ;;
218 i[3456]86-*-freebsd*) machine=intel386 ;;
219 esac
220 ;;
222 ## NetBSD ports
223 *-*-netbsd* )
224 opsys=netbsd
225 if test -f /usr/lib/crti.o; then]
226 AC_DEFINE(HAVE_CRTIN)
227 [ fi
229 case "${canonical}" in
230 alpha*-*-netbsd*) machine=alpha ;;
231 i[3456]86-*-netbsd*) machine=intel386 ;;
232 m68k-*-netbsd*)
233 # This is somewhat bogus.
234 machine=hp9000s300 ;;
235 powerpc-apple-netbsd*) machine=macppc ;;
236 mips-*-netbsd*) machine=pmax ;;
237 mipsel-*-netbsd*) machine=pmax ;;
238 mipseb-*-netbsd*) machine=pmax ;;
239 ns32k-*-netbsd*) machine=ns32000 ;;
240 powerpc-*-netbsd*) machine=macppc ;;
241 sparc*-*-netbsd*) machine=sparc ;;
242 vax-*-netbsd*) machine=vax ;;
243 arm-*-netbsd*) machine=arm ;;
244 esac
245 ;;
247 ## OpenBSD ports
248 *-*-openbsd* )
249 opsys=openbsd
250 case "${canonical}" in
251 alpha*-*-openbsd*) machine=alpha ;;
252 i386-*-openbsd*) machine=intel386 ;;
253 m68k-*-openbsd*) machine=hp9000s300 ;;
254 mipsel-*-openbsd*) machine=pmax ;;
255 ns32k-*-openbsd*) machine=ns32000 ;;
256 sparc-*-openbsd*) machine=sparc ;;
257 vax-*-openbsd*) machine=vax ;;
258 esac
259 ;;
261 ## Acorn RISCiX:
262 arm-acorn-riscix1.1* )
263 machine=acorn opsys=riscix1-1
264 ;;
265 arm-acorn-riscix1.2* | arm-acorn-riscix )
266 ## This name is riscix12 instead of riscix1.2
267 ## to avoid a file name conflict on MSDOS.
268 machine=acorn opsys=riscix12
269 ;;
271 ## BSDI ports
272 *-*-bsdi* )
273 opsys=bsdi
274 case "${canonical}" in
275 i[345]86-*-bsdi*) machine=intel386 ;;
276 sparc-*-bsdi*) machine=sparc ;;
277 powerpc-*-bsdi*) machine=macppc ;;
278 esac
279 case "${canonical}" in
280 *-*-bsd386* | *-*-bsdi1* ) opsys=bsd386 ;;
281 *-*-bsdi2.0* ) opsys=bsdos2 ;;
282 *-*-bsdi2* ) opsys=bsdos2-1 ;;
283 *-*-bsdi3* ) opsys=bsdos3 ;;
284 *-*-bsdi[45]* ) opsys=bsdos4 ;;
285 esac
286 ;;
288 ## Alliant machines
289 ## Strictly speaking, we need the version of the alliant operating
290 ## system to choose the right machine file, but currently the
291 ## configuration name doesn't tell us enough to choose the right
292 ## one; we need to give alliants their own operating system name to
293 ## do this right. When someone cares, they can help us.
294 fx80-alliant-* )
295 machine=alliant4 opsys=bsd4-2
296 ;;
297 i860-alliant-* )
298 machine=alliant-2800 opsys=bsd4-3
299 ;;
301 ## Alpha (DEC) machines.
302 alpha*-dec-osf* )
303 machine=alpha opsys=osf1
304 # This is needed to find X11R6.1 libraries for certain tests.
305 NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
306 GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
307 # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
308 # due to non-traditional preprocessing with the current compiler
309 # defaults. OSF 4 can also have that compiler version, and there
310 # seems always to have been a usable /usr/bin/cpp.
311 NON_GNU_CPP=/usr/bin/cpp
312 case "${canonical}" in
313 alpha*-dec-osf[5-9]*)
314 opsys=osf5-0 ;;
315 esac
316 ;;
318 alpha*-*-linux-gnu* )
319 machine=alpha opsys=gnu-linux
320 ;;
322 arm*-*-linux-gnu* )
323 machine=arm opsys=gnu-linux
324 ;;
326 ppc-*-linux | \
327 powerpc-*-linux* )
328 machine=macppc opsys=gnu-linux
329 ;;
331 ## Altos 3068
332 m68*-altos-sysv* )
333 machine=altos opsys=usg5-2
334 ;;
336 ## Amdahl UTS
337 580-amdahl-sysv* )
338 machine=amdahl opsys=usg5-2-2
339 ;;
341 ## Apollo, Domain/OS
342 m68*-apollo-* )
343 machine=apollo opsys=bsd4-3
344 ;;
346 ## AT&T 3b2, 3b5, 3b15, 3b20
347 we32k-att-sysv* )
348 machine=att3b opsys=usg5-2-2
349 ;;
351 ## AT&T 3b1 - The Mighty Unix PC!
352 m68*-att-sysv* )
353 machine=7300 opsys=usg5-2-2
354 ;;
356 ## Bull dpx20
357 rs6000-bull-bosx* )
358 machine=ibmrs6000 opsys=aix3-2
359 ;;
361 ## Bull dpx2
362 m68*-bull-sysv3* )
363 machine=dpx2 opsys=usg5-3
364 ;;
366 ## Bull sps7
367 m68*-bull-sysv2* )
368 machine=sps7 opsys=usg5-2
369 ;;
371 ## CCI 5/32, 6/32 -- see "Tahoe".
373 ## Celerity
374 ## I don't know what configuration name to use for this; config.sub
375 ## doesn't seem to know anything about it. Hey, Celerity users, get
376 ## in touch with us!
377 celerity-celerity-bsd* )
378 machine=celerity opsys=bsd4-2
379 ;;
381 ## Clipper
382 ## What operating systems does this chip run that Emacs has been
383 ## tested on?
384 clipper-* )
385 machine=clipper
386 ## We'll use the catch-all code at the bottom to guess the
387 ## operating system.
388 ;;
390 ## Compaq Nonstop
391 mips-compaq-nonstopux* )
392 machine=nonstopux opsys=nonstopux
393 ;;
395 ## Convex
396 *-convex-bsd* | *-convex-convexos* )
397 machine=convex opsys=bsd4-3
398 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
399 NON_GNU_CPP="cc -E -P"
400 ;;
402 ## Cubix QBx/386
403 i[3456]86-cubix-sysv* )
404 machine=intel386 opsys=usg5-3
405 ;;
407 ## Cydra 5
408 cydra*-cydrome-sysv* )
409 machine=cydra5 opsys=usg5-3
410 ;;
412 ## Data General AViiON Machines
413 ## DG changed naming conventions with the release of 5.4.4.10, they
414 ## dropped the initial 5.4 but left the intervening R. Because of the
415 ## R this shouldn't conflict with older versions of the OS (which I
416 ## think were named like dgux4.*). In addition, DG new AViiONs series
417 ## uses either Motorola M88k or Intel Pentium CPUs.
418 m88k-dg-dguxR4.* | m88k-dg-dgux4* )
419 machine=aviion opsys=dgux4
420 ;;
421 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
422 ## This name is dgux5-4-3 instead of dgux5-4r3
423 ## to avoid a file name conflict on MSDOS.
424 machine=aviion opsys=dgux5-4-3
425 ;;
426 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
427 machine=aviion opsys=dgux5-4r2
428 ;;
429 m88k-dg-dgux* )
430 machine=aviion opsys=dgux
431 ;;
433 ## Data General AViiON Intel (x86) Machines
434 ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
435 ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
436 i[345]86-dg-dguxR4* )
437 machine=aviion-intel opsys=dgux4
438 ;;
440 ## DECstations
441 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
442 machine=pmax opsys=bsd4-2
443 ;;
444 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
445 machine=pmax opsys=bsd4-3
446 ;;
447 mips-dec-ultrix* )
448 machine=pmax opsys=ultrix4-3
449 ;;
450 mips-dec-osf* )
451 machine=pmax opsys=osf1
452 ;;
453 mips-dec-mach_bsd4.3* )
454 machine=pmax opsys=mach-bsd4-3
455 ;;
457 ## Motorola Delta machines
458 m68k-motorola-sysv* | m68000-motorola-sysv* )
459 machine=delta opsys=usg5-3
460 if test -z "`type gnucc | grep 'not found'`"
461 then
462 if test -s /etc/167config
463 then CC="gnucc -m68040"
464 else CC="gnucc -m68881"
465 fi
466 else
467 if test -z "`type gcc | grep 'not found'`"
468 then CC=gcc
469 else CC=cc
470 fi
471 fi
472 ;;
473 m88k-motorola-sysv4* )
474 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
475 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
476 # I hope there are not other 4.0 versions for this machine
477 # which really need usg5-4 instead.
478 machine=delta88k opsys=usg5-4-2
479 ;;
480 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
481 machine=delta88k opsys=usg5-3
482 ;;
484 ## Dual machines
485 m68*-dual-sysv* )
486 machine=dual opsys=usg5-2
487 ;;
488 m68*-dual-uniplus* )
489 machine=dual opsys=unipl5-2
490 ;;
492 ## Elxsi 6400
493 elxsi-elxsi-sysv* )
494 machine=elxsi opsys=usg5-2
495 ;;
497 ## Encore machines
498 ns16k-encore-bsd* )
499 machine=ns16000 opsys=umax
500 ;;
502 ## The GEC 63 - apparently, this port isn't really finished yet.
503 # I'm sure we finished off the last of the machines, though. -- fx
505 ## Gould Power Node and NP1
506 pn-gould-bsd4.2* )
507 machine=gould opsys=bsd4-2
508 ;;
509 pn-gould-bsd4.3* )
510 machine=gould opsys=bsd4-3
511 ;;
512 np1-gould-bsd* )
513 machine=gould-np1 opsys=bsd4-3
514 ;;
516 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
517 ## as far as Emacs is concerned).
518 m88k-harris-cxux* )
519 # Build needs to be different on 7.0 and later releases
520 case "`uname -r`" in
521 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
522 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
523 esac
524 NON_GNU_CPP="/lib/cpp"
525 ;;
526 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
527 m68k-harris-cxux* )
528 machine=nh3000 opsys=cxux
529 ;;
530 ## Harris power pc NightHawk running Power UNIX (Series 6000)
531 powerpc-harris-powerunix )
532 machine=nh6000 opsys=powerunix
533 NON_GNU_CPP="cc -Xo -E -P"
534 ;;
535 ## SR2001/SR2201 running HI-UX/MPP
536 hppa1.1-hitachi-hiuxmpp* )
537 machine=sr2k opsys=hiuxmpp
538 ;;
539 hppa1.1-hitachi-hiuxwe2* )
540 machine=sr2k opsys=hiuxwe2
541 ;;
542 ## Honeywell XPS100
543 xps*-honeywell-sysv* )
544 machine=xps100 opsys=usg5-2
545 ;;
547 ## HP 9000 series 200 or 300
548 m68*-hp-bsd* )
549 machine=hp9000s300 opsys=bsd4-3
550 ;;
551 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
552 m68*-hp-hpux* )
553 case "`uname -r`" in
554 ## Someone's system reports A.B8.05 for this.
555 ## I wonder what other possibilities there are.
556 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
557 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
558 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
559 *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
560 *) machine=hp9000s300 opsys=hpux ;;
561 esac
562 ;;
564 ## HP 9000 series 700 and 800, running HP/UX
565 hppa*-hp-hpux7* )
566 machine=hp800 opsys=hpux
567 ;;
568 hppa*-hp-hpux8* )
569 machine=hp800 opsys=hpux8
570 ;;
571 hppa*-hp-hpux9shr* )
572 machine=hp800 opsys=hpux9shr
573 ;;
574 hppa*-hp-hpux9* )
575 machine=hp800 opsys=hpux9
576 ;;
577 hppa*-hp-hpux10.2* )
578 machine=hp800 opsys=hpux10-20
579 ;;
580 hppa*-hp-hpux10* )
581 machine=hp800 opsys=hpux10
582 ;;
583 hppa*-hp-hpux1[1-9]* )
584 machine=hp800 opsys=hpux11
585 ;;
587 hppa*-*-linux-gnu* )
588 machine=hp800 opsys=gnu-linux
589 ;;
591 ## HP 9000 series 700 and 800, running HP/UX
592 hppa*-hp-hpux* )
593 ## Cross-compilation? Nah!
594 case "`uname -r`" in
595 ## Someone's system reports A.B8.05 for this.
596 ## I wonder what other possibilities there are.
597 *.B8.* ) machine=hp800 opsys=hpux8 ;;
598 *.08.* ) machine=hp800 opsys=hpux8 ;;
599 *.09.* ) machine=hp800 opsys=hpux9 ;;
600 *) machine=hp800 opsys=hpux10 ;;
601 esac
602 ;;
603 hppa*-*-nextstep* )
604 machine=hp800 opsys=nextstep
605 ;;
607 ## Orion machines
608 orion-orion-bsd* )
609 machine=orion opsys=bsd4-2
610 ;;
611 clipper-orion-bsd* )
612 machine=orion105 opsys=bsd4-2
613 ;;
615 ## IBM machines
616 i[3456]86-ibm-aix1.1* )
617 machine=ibmps2-aix opsys=usg5-2-2
618 ;;
619 i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
620 machine=ibmps2-aix opsys=usg5-3
621 ;;
622 i370-ibm-aix*)
623 machine=ibm370aix opsys=usg5-3
624 ;;
625 s390-*-linux-gnu* )
626 machine=ibms390 opsys=gnu-linux
627 ;;
628 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
629 machine=ibmrs6000 opsys=aix3-1
630 ;;
631 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
632 machine=ibmrs6000 opsys=aix3-2-5
633 ;;
634 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
635 machine=ibmrs6000 opsys=aix4-1
636 ;;
637 rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2* )
638 machine=ibmrs6000 opsys=aix4-2
639 ;;
640 rs6000-ibm-aix5* | powerpc-ibm-aix5* )
641 machine=ibmrs6000 opsys=aix4-2
642 ;;
643 rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0* )
644 machine=ibmrs6000 opsys=aix4
645 ;;
646 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
647 machine=ibmrs6000 opsys=aix4-1
648 ;;
649 rs6000-ibm-aix* | powerpc-ibm-aix* )
650 machine=ibmrs6000 opsys=aix3-2
651 ;;
652 romp-ibm-bsd4.3* )
653 machine=ibmrt opsys=bsd4-3
654 ;;
655 romp-ibm-bsd4.2* )
656 machine=ibmrt opsys=bsd4-2
657 ;;
658 romp-ibm-aos4.3* )
659 machine=ibmrt opsys=bsd4-3
660 ;;
661 romp-ibm-aos4.2* )
662 machine=ibmrt opsys=bsd4-2
663 ;;
664 romp-ibm-aos* )
665 machine=ibmrt opsys=bsd4-3
666 ;;
667 romp-ibm-bsd* )
668 machine=ibmrt opsys=bsd4-3
669 ;;
670 romp-ibm-aix* )
671 machine=ibmrt-aix opsys=usg5-2-2
672 ;;
674 ## Integrated Solutions `Optimum V'
675 m68*-isi-bsd4.2* )
676 machine=isi-ov opsys=bsd4-2
677 ;;
678 m68*-isi-bsd4.3* )
679 machine=isi-ov opsys=bsd4-3
680 ;;
682 ## Intel 386 machines where we do care about the manufacturer
683 i[3456]86-intsys-sysv* )
684 machine=is386 opsys=usg5-2-2
685 ;;
687 ## Prime EXL
688 i[3456]86-prime-sysv* )
689 machine=i386 opsys=usg5-3
690 ;;
692 ## Sequent Symmetry running Dynix
693 i[3456]86-sequent-bsd* )
694 machine=symmetry opsys=bsd4-3
695 ;;
697 ## Sequent Symmetry running ptx 4, which is a modified SVR4.
698 i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
699 machine=sequent-ptx opsys=ptx4
700 NON_GNU_CPP=/lib/cpp
701 ;;
703 ## Sequent Symmetry running DYNIX/ptx
704 ## Use the old cpp rather than the newer ANSI one.
705 i[3456]86-sequent-ptx* )
706 machine=sequent-ptx opsys=ptx
707 NON_GNU_CPP="/lib/cpp"
708 ;;
710 ## ncr machine running svr4.3.
711 i[3456]86-ncr-sysv4.3 )
712 machine=ncr386 opsys=usg5-4-3
713 ;;
715 ## Unspecified sysv on an ncr machine defaults to svr4.2.
716 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
717 i[3456]86-ncr-sysv* )
718 machine=ncr386 opsys=usg5-4-2
719 ;;
721 ## Intel Paragon OSF/1
722 i860-intel-osf1* )
723 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
724 ;;
726 ## Intel 860
727 i860-*-sysv4* )
728 machine=i860 opsys=usg5-4
729 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
730 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
731 ;;
733 ## Macintosh PowerPC
734 powerpc*-*-linux-gnu* )
735 machine=macppc opsys=gnu-linux
736 ;;
738 ## Masscomp machines
739 m68*-masscomp-rtu* )
740 machine=masscomp opsys=rtu
741 ;;
743 ## Megatest machines
744 m68*-megatest-bsd* )
745 machine=mega68 opsys=bsd4-2
746 ;;
748 ## Workstations sold by MIPS
749 ## This is not necessarily all workstations using the MIPS processor -
750 ## Irises are produced by SGI, and DECstations by DEC.
752 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
753 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
754 ## it gives for choosing between the alternatives seems to be "Use
755 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
756 ## the BSD world." I'll assume that these are instructions for
757 ## handling two odd situations, and that every other situation
758 ## should use mips.h and usg5-2-2, they being listed first.
759 mips-mips-usg* )
760 machine=mips4
761 ## Fall through to the general code at the bottom to decide on the OS.
762 ;;
763 mips-mips-riscos4* )
764 machine=mips4 opsys=bsd4-3
765 NON_GNU_CC="cc -systype bsd43"
766 NON_GNU_CPP="cc -systype bsd43 -E"
767 ;;
768 mips-mips-riscos5* )
769 machine=mips4 opsys=riscos5
770 NON_GNU_CC="cc -systype bsd43"
771 NON_GNU_CPP="cc -systype bsd43 -E"
772 ;;
773 mips-mips-bsd* )
774 machine=mips opsys=bsd4-3
775 ;;
776 mips-mips-* )
777 machine=mips opsys=usg5-2-2
778 ;;
780 ## NeXT
781 m68*-next-* | m68k-*-nextstep* )
782 machine=m68k opsys=nextstep
783 ;;
785 ## The complete machine from National Semiconductor
786 ns32k-ns-genix* )
787 machine=ns32000 opsys=usg5-2
788 ;;
790 ## NCR machines
791 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
792 machine=tower32 opsys=usg5-2-2
793 ;;
794 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
795 machine=tower32v3 opsys=usg5-3
796 ;;
798 ## NEC EWS4800
799 mips-nec-sysv4*)
800 machine=ews4800 opsys=ux4800
801 ;;
803 ## Nixdorf Targon 31
804 m68*-nixdorf-sysv* )
805 machine=targon31 opsys=usg5-2-2
806 ;;
808 ## Nu (TI or LMI)
809 m68*-nu-sysv* )
810 machine=nu opsys=usg5-2
811 ;;
813 ## Plexus
814 m68*-plexus-sysv* )
815 machine=plexus opsys=usg5-2
816 ;;
818 ## Pyramid machines
819 ## I don't really have any idea what sort of processor the Pyramid has,
820 ## so I'm assuming it is its own architecture.
821 pyramid-pyramid-bsd* )
822 machine=pyramid opsys=bsd4-2
823 ;;
825 ## Sequent Balance
826 ns32k-sequent-bsd4.2* )
827 machine=sequent opsys=bsd4-2
828 ;;
829 ns32k-sequent-bsd4.3* )
830 machine=sequent opsys=bsd4-3
831 ;;
833 ## Siemens Nixdorf
834 mips-siemens-sysv* | mips-sni-sysv*)
835 machine=mips-siemens opsys=usg5-4
836 NON_GNU_CC=/usr/ccs/bin/cc
837 NON_GNU_CPP=/usr/ccs/lib/cpp
838 ;;
840 ## Silicon Graphics machines
841 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
842 m68*-sgi-iris3.5* )
843 machine=irist opsys=iris3-5
844 ;;
845 m68*-sgi-iris3.6* | m68*-sgi-iris*)
846 machine=irist opsys=iris3-6
847 ;;
848 ## Iris 4D
849 mips-sgi-irix3* )
850 machine=iris4d opsys=irix3-3
851 ;;
852 mips-sgi-irix4* )
853 machine=iris4d opsys=irix4-0
854 ;;
855 mips-sgi-irix6.5 )
856 machine=iris4d opsys=irix6-5
857 # Without defining _LANGUAGE_C, things get masked out in the headers
858 # so that, for instance, grepping for `free' in stdlib.h fails and
859 # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
860 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
861 NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
862 ;;
863 mips-sgi-irix6* )
864 machine=iris4d opsys=irix6-0
865 # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
866 # but presumably it does no harm.
867 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
868 # -32 probably isn't necessary in later v.6s -- anyone know which?
869 NON_GCC_TEST_OPTIONS=-32
870 ;;
871 mips-sgi-irix5.[01]* )
872 machine=iris4d opsys=irix5-0
873 ;;
874 mips-sgi-irix5* | mips-sgi-irix* )
875 machine=iris4d opsys=irix5-2
876 ;;
878 ## SONY machines
879 m68*-sony-bsd4.2* )
880 machine=news opsys=bsd4-2
881 ;;
882 m68*-sony-bsd4.3* )
883 machine=news opsys=bsd4-3
884 ;;
885 m68*-sony-newsos3* | m68*-sony-news3*)
886 machine=news opsys=bsd4-3
887 ;;
888 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
889 machine=news-risc opsys=bsd4-3
890 ;;
891 mips-sony-newsos6* )
892 machine=news-r6 opsys=newsos6
893 ;;
894 mips-sony-news* )
895 machine=news-risc opsys=newsos5
896 ;;
898 ## Stride
899 m68*-stride-sysv* )
900 machine=stride opsys=usg5-2
901 ;;
903 ## Suns
904 sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
905 machine=sparc opsys=gnu-linux
906 ;;
908 *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
909 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
910 | rs6000-*-solaris2*)
911 case "${canonical}" in
912 m68*-sunos1* ) machine=sun1 ;;
913 m68*-sunos2* ) machine=sun2 ;;
914 m68* ) machine=sun3 ;;
915 i[3456]86-sun-sunos[34]* ) machine=sun386 ;;
916 i[3456]86-*-* ) machine=intel386 ;;
917 powerpcle* ) machine=powerpcle ;;
918 powerpc* | rs6000* ) machine=ibmrs6000 ;;
919 sparc* ) machine=sparc ;;
920 * ) unported=yes ;;
921 esac
922 case "${canonical}" in
923 ## The Sun386 didn't get past 4.0.
924 i[3456]86-*-sunos4 ) opsys=sunos4-0 ;;
925 *-sunos4.0* ) opsys=sunos4-0 ;;
926 *-sunos4.1.[3-9]*noshare )
927 ## This name is sunos413 instead of sunos4-1-3
928 ## to avoid a file name conflict on MSDOS.
929 opsys=sunos413
930 NON_GNU_CPP=/usr/lib/cpp
931 NON_GCC_TEST_OPTIONS=-Bstatic
932 GCC_TEST_OPTIONS=-static
933 ;;
934 *-sunos4.1.[3-9]* | *-sunos4shr*)
935 opsys=sunos4shr
936 NON_GNU_CPP=/usr/lib/cpp
937 ;;
938 *-sunos4* | *-sunos )
939 opsys=sunos4-1
940 NON_GCC_TEST_OPTIONS=-Bstatic
941 GCC_TEST_OPTIONS=-static
942 ;;
943 *-sunos5.3* | *-solaris2.3* )
944 opsys=sol2-3
945 NON_GNU_CPP=/usr/ccs/lib/cpp
946 ;;
947 *-sunos5.4* | *-solaris2.4* )
948 opsys=sol2-4
949 NON_GNU_CPP=/usr/ccs/lib/cpp
950 RANLIB="ar -ts"
951 ;;
952 *-sunos5.5* | *-solaris2.5* )
953 opsys=sol2-5
954 NON_GNU_CPP=/usr/ccs/lib/cpp
955 RANLIB="ar -ts"
956 ;;
957 *-sunos5.6* | *-solaris2.6* )
958 opsys=sol2-6
959 NON_GNU_CPP=/usr/ccs/lib/cpp
960 RANLIB="ar -ts"
961 ;;
962 *-sunos5* | *-solaris* )
963 opsys=sol2-6
964 NON_GNU_CPP=/usr/ccs/lib/cpp
965 ;;
966 * ) opsys=bsd4-2 ;;
967 esac
968 ## Watch out for a compiler that we know will not work.
969 case "${canonical}" in
970 *-solaris* | *-sunos5* )
971 if [ "x$CC" = x/usr/ucb/cc ]; then
972 ## /usr/ucb/cc doesn't work;
973 ## we should find some other compiler that does work.
974 unset CC
975 fi
976 ;;
977 *) ;;
978 esac
979 ;;
980 sparc-*-nextstep* )
981 machine=sparc opsys=nextstep
982 ;;
984 ## Tadpole 68k
985 m68*-tadpole-sysv* )
986 machine=tad68k opsys=usg5-3
987 ;;
989 ## Tahoe machines
990 tahoe-tahoe-bsd4.2* )
991 machine=tahoe opsys=bsd4-2
992 ;;
993 tahoe-tahoe-bsd4.3* )
994 machine=tahoe opsys=bsd4-3
995 ;;
997 ## Tandem Integrity S2
998 mips-tandem-sysv* )
999 machine=tandem-s2 opsys=usg5-3
1000 ;;
1002 ## Tektronix XD88
1003 m88k-tektronix-sysv3* )
1004 machine=tekxd88 opsys=usg5-3
1005 ;;
1007 ## Tektronix 16000 box (6130?)
1008 ns16k-tektronix-bsd* )
1009 machine=ns16000 opsys=bsd4-2
1010 ;;
1011 ## Tektronix 4300
1012 ## src/m/tek4300.h hints that this is a m68k machine.
1013 m68*-tektronix-bsd* )
1014 machine=tek4300 opsys=bsd4-3
1015 ;;
1017 ## Titan P2 or P3
1018 ## We seem to have lost the machine-description file titan.h!
1019 titan-titan-sysv* )
1020 machine=titan opsys=usg5-3
1021 ;;
1023 ## Ustation E30 (SS5E)
1024 m68*-unisys-uniplus* )
1025 machine=ustation opsystem=unipl5-2
1026 ;;
1028 ## Vaxen.
1029 vax-dec-* )
1030 machine=vax
1031 case "${canonical}" in
1032 *-bsd4.1* ) opsys=bsd4-1 ;;
1033 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
1034 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
1035 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
1036 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
1037 *-vms* ) opsys=vms ;;
1038 * ) unported=yes
1039 esac
1040 ;;
1042 ## Whitechapel MG1
1043 ns16k-whitechapel-* )
1044 machine=mg1
1045 ## We don't know what sort of OS runs on these; we'll let the
1046 ## operating system guessing code below try.
1047 ;;
1049 ## Wicat
1050 m68*-wicat-sysv* )
1051 machine=wicat opsys=usg5-2
1052 ;;
1054 ## IA-64
1055 ia64*-*-linux* )
1056 machine=ia64 opsys=gnu-linux
1057 ;;
1059 ## Intel 386 machines where we don't care about the manufacturer
1060 i[3456]86-*-* )
1061 machine=intel386
1062 case "${canonical}" in
1063 *-cygwin ) opsys=cygwin ;;
1064 *-lynxos* ) opsys=lynxos ;;
1065 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
1066 *-isc2.2* ) opsys=isc2-2 ;;
1067 *-isc4.0* ) opsys=isc4-0 ;;
1068 *-isc4.* ) opsys=isc4-1
1069 GCC_TEST_OPTIONS=-posix
1070 NON_GCC_TEST_OPTIONS=-Xp
1071 ;;
1072 *-isc* ) opsys=isc3-0 ;;
1073 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
1074 *-esix* ) opsys=esix ;;
1075 *-xenix* ) opsys=xenix ;;
1076 *-linux-gnu* ) opsys=gnu-linux ;;
1077 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
1078 *-sco3.2v5* ) opsys=sco5
1079 NON_GNU_CPP=/lib/cpp
1080 # Prevent -belf from being passed to $CPP.
1081 # /lib/cpp does not accept it.
1082 OVERRIDE_CPPFLAGS=" "
1083 ;;
1084 *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1085 *-sysv5uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1086 *-sysv5OpenUNIX* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1087 *-386bsd* ) opsys=386bsd ;;
1088 *-nextstep* ) opsys=nextstep ;;
1089 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1090 esac
1091 ;;
1093 ## m68k Linux-based GNU system
1094 m68k-*-linux-gnu* )
1095 machine=m68k opsys=gnu-linux
1096 ;;
1098 ## Mips Linux-based GNU system
1099 mips-*-linux-gnu* | mipsel-*-linux-gnu* )
1100 machine=mips opsys=gnu-linux
1101 ;;
1103 ## UXP/DS
1104 sparc-fujitsu-sysv4* )
1105 machine=sparc opsys=uxpds
1106 NON_GNU_CPP=/usr/ccs/lib/cpp
1107 RANLIB="ar -ts"
1108 ;;
1110 ## UXP/V
1111 f301-fujitsu-uxpv4.1)
1112 machine=f301 opsys=uxpv
1113 ;;
1115 ## Darwin / Mac OS X
1116 powerpc-apple-darwin* )
1117 machine=powermac opsys=darwin
1118 # Define CPP as follows to make autoconf work correctly.
1119 CPP="cc -E -traditional-cpp"
1120 ;;
1122 ## AMD x86-64 Linux-based GNU system
1123 x86_64-*-linux-gnu* )
1124 machine=amdx86-64 opsys=gnu-linux
1125 ;;
1127 * )
1128 unported=yes
1129 ;;
1130 esac
1132 ### If the code above didn't choose an operating system, just choose
1133 ### an operating system based on the configuration name. You really
1134 ### only want to use this when you have no idea what the right
1135 ### operating system is; if you know what operating systems a machine
1136 ### runs, it's cleaner to make it explicit in the case statement
1137 ### above.
1138 if test x"${opsys}" = x; then
1139 case "${canonical}" in
1140 *-gnu* ) opsys=gnu ;;
1141 *-bsd4.[01] ) opsys=bsd4-1 ;;
1142 *-bsd4.2 ) opsys=bsd4-2 ;;
1143 *-bsd4.3 ) opsys=bsd4-3 ;;
1144 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
1145 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
1146 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
1147 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
1148 *-sysv4.2uw* ) opsys=unixware ;;
1149 *-sysv5uw* ) opsys=unixware ;;
1150 *-sysv5OpenUNIX* ) opsys=unixware ;;
1151 *-sysv4.1* | *-sysvr4.1* )
1152 NON_GNU_CPP=/usr/lib/cpp
1153 opsys=usg5-4 ;;
1154 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1155 if [ x$NON_GNU_CPP = x ]; then
1156 if [ -f /usr/ccs/lib/cpp ]; then
1157 NON_GNU_CPP=/usr/ccs/lib/cpp
1158 else
1159 NON_GNU_CPP=/lib/cpp
1160 fi
1161 fi
1162 opsys=usg5-4-2 ;;
1163 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
1164 * )
1165 unported=yes
1166 ;;
1167 esac
1168 fi
1170 ]
1172 if test $unported = yes; then
1173 AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
1174 Check `etc/MACHINES' for recognized configuration names.])
1175 fi
1177 machfile="m/${machine}.h"
1178 opsysfile="s/${opsys}.h"
1181 #### Choose a compiler.
1182 test -n "$CC" && cc_specified=yes
1184 # Save the value of CFLAGS that the user specified.
1185 SPECIFIED_CFLAGS="$CFLAGS"
1187 case ${with_gcc} in
1188 "yes" ) CC="gcc" GCC=yes ;;
1189 "no" ) : ${CC=cc} ;;
1190 * )
1191 esac
1192 AC_PROG_CC
1194 # On Suns, sometimes $CPP names a directory.
1195 if test -n "$CPP" && test -d "$CPP"; then
1196 CPP=
1197 fi
1199 #### Some systems specify a CPP to use unless we are using GCC.
1200 #### Now that we know whether we are using GCC, we can decide whether
1201 #### to use that one.
1202 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1203 then
1204 CPP="$NON_GNU_CPP"
1205 fi
1207 #### Some systems specify a CC to use unless we are using GCC.
1208 #### Now that we know whether we are using GCC, we can decide whether
1209 #### to use that one.
1210 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1211 test x$cc_specified != xyes
1212 then
1213 CC="$NON_GNU_CC"
1214 fi
1216 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1217 then
1218 CC="$CC $GCC_TEST_OPTIONS"
1219 fi
1221 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1222 then
1223 CC="$CC $NON_GCC_TEST_OPTIONS"
1224 fi
1226 #### Some other nice autoconf tests.
1228 dnl checks for programs
1229 AC_PROG_LN_S
1230 AC_PROG_CPP
1231 AC_PROG_INSTALL
1232 if test "x$RANLIB" = x; then
1233 AC_PROG_RANLIB
1234 fi
1235 AC_PATH_PROG(INSTALL_INFO, install-info)
1236 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
1237 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
1239 dnl Add our options to ac_link now, after it is set up.
1241 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1242 then
1243 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1244 fi
1246 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1247 then
1248 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1249 fi
1251 dnl checks for Unix variants
1252 AC_AIX
1254 #### Extract some information from the operating system and machine files.
1256 AC_CHECKING([the machine- and system-dependent files to find out
1257 - which libraries the lib-src programs will want, and
1258 - whether the GNU malloc routines are usable])
1260 ### First figure out CFLAGS (which we use for running the compiler here)
1261 ### and REAL_CFLAGS (which we use for real compilation).
1262 ### The two are the same except on a few systems, where they are made
1263 ### different to work around various lossages. For example,
1264 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1265 ### as implying static linking.
1267 ### If the CFLAGS env var is specified, we use that value
1268 ### instead of the default.
1270 ### It's not important that this name contain the PID; you can't run
1271 ### two configures in the same directory and have anything work
1272 ### anyway.
1273 tempcname="conftest.c"
1275 echo '
1276 #include "'${srcdir}'/src/'${opsysfile}'"
1277 #include "'${srcdir}'/src/'${machfile}'"
1278 #ifndef LIBS_MACHINE
1279 #define LIBS_MACHINE
1280 #endif
1281 #ifndef LIBS_SYSTEM
1282 #define LIBS_SYSTEM
1283 #endif
1284 #ifndef C_SWITCH_SYSTEM
1285 #define C_SWITCH_SYSTEM
1286 #endif
1287 #ifndef C_SWITCH_MACHINE
1288 #define C_SWITCH_MACHINE
1289 #endif
1290 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1291 configure___ c_switch_system=C_SWITCH_SYSTEM
1292 configure___ c_switch_machine=C_SWITCH_MACHINE
1294 #ifndef LIB_X11_LIB
1295 #define LIB_X11_LIB -lX11
1296 #endif
1298 #ifndef LIBX11_MACHINE
1299 #define LIBX11_MACHINE
1300 #endif
1302 #ifndef LIBX11_SYSTEM
1303 #define LIBX11_SYSTEM
1304 #endif
1305 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1307 #ifdef UNEXEC
1308 configure___ unexec=UNEXEC
1309 #else
1310 configure___ unexec=unexec.o
1311 #endif
1313 #ifdef SYSTEM_MALLOC
1314 configure___ system_malloc=yes
1315 #else
1316 configure___ system_malloc=no
1317 #endif
1319 #ifdef USE_MMAP_FOR_BUFFERS
1320 configure___ use_mmap_for_buffers=yes
1321 #else
1322 configure___ use_mmap_for_buffers=no
1323 #endif
1325 #ifndef C_DEBUG_SWITCH
1326 #define C_DEBUG_SWITCH -g
1327 #endif
1329 #ifndef C_OPTIMIZE_SWITCH
1330 #ifdef __GNUC__
1331 #define C_OPTIMIZE_SWITCH -O2
1332 #else
1333 #define C_OPTIMIZE_SWITCH -O
1334 #endif
1335 #endif
1337 #ifndef LD_SWITCH_MACHINE
1338 #define LD_SWITCH_MACHINE
1339 #endif
1341 #ifndef LD_SWITCH_SYSTEM
1342 #define LD_SWITCH_SYSTEM
1343 #endif
1345 #ifndef LD_SWITCH_X_SITE_AUX
1346 #define LD_SWITCH_X_SITE_AUX
1347 #endif
1349 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1350 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1352 #ifdef THIS_IS_CONFIGURE
1354 /* Get the CFLAGS for tests in configure. */
1355 #ifdef __GNUC__
1356 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1357 #else
1358 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1359 #endif
1361 #else /* not THIS_IS_CONFIGURE */
1363 /* Get the CFLAGS for real compilation. */
1364 #ifdef __GNUC__
1365 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1366 #else
1367 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1368 #endif
1370 #endif /* not THIS_IS_CONFIGURE */
1371 ' > ${tempcname}
1373 # The value of CPP is a quoted variable reference, so we need to do this
1374 # to get its actual value...
1375 CPP=`eval "echo $CPP"`
1376 [eval `${CPP} -Isrc ${tempcname} \
1377 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1378 if test "x$SPECIFIED_CFLAGS" = x; then
1379 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1380 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1381 else
1382 REAL_CFLAGS="$CFLAGS"
1383 fi]
1384 rm ${tempcname}
1386 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1388 ### Make sure subsequent tests use flags consistent with the build flags.
1390 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1391 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1392 else
1393 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1394 fi
1396 dnl For AC_FUNC_GETLOADAVG, at least:
1397 AC_CONFIG_LIBOBJ_DIR(src)
1399 AC_GNU_SOURCE
1401 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1402 AC_SYS_LARGEFILE
1404 if test "${with_sound}" != "no"; then
1405 # Sound support for GNU/Linux and the free BSDs.
1406 AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1407 # Emulation library used on NetBSD.
1408 AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1409 AC_SUBST(LIBSOUND)
1410 fi
1412 dnl checks for header files
1413 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1414 linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1415 termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1416 sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h)
1417 dnl On Solaris 8 there's a compilation warning for term.h because
1418 dnl it doesn't define `bool'.
1419 AC_CHECK_HEADERS(term.h, , , -)
1420 AC_HEADER_STDC
1421 AC_HEADER_TIME
1422 AC_CHECK_DECLS([sys_siglist])
1423 if test $ac_cv_have_decl_sys_siglist != yes; then
1424 # For Tru64, at least:
1425 AC_CHECK_DECLS([__sys_siglist])
1426 if test $ac_cv_have_decl___sys_siglist = yes; then
1427 AC_DEFINE(sys_siglist, __sys_siglist,
1428 [Define to any substitute for sys_siglist.])
1429 fi
1430 fi
1431 AC_HEADER_SYS_WAIT
1433 dnl Some systems have utime.h but don't declare the struct anyplace.
1434 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1435 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1436 #include <sys/time.h>
1437 #include <time.h>
1438 #else
1439 #ifdef HAVE_SYS_TIME_H
1440 #include <sys/time.h>
1441 #else
1442 #include <time.h>
1443 #endif
1444 #endif
1445 #ifdef HAVE_UTIME_H
1446 #include <utime.h>
1447 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1448 emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1449 if test $emacs_cv_struct_utimbuf = yes; then
1450 AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1451 fi
1453 dnl checks for typedefs
1454 AC_TYPE_SIGNAL
1456 dnl Check for speed_t typedef.
1457 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1458 [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1459 emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1460 if test $emacs_cv_speed_t = yes; then
1461 AC_DEFINE(HAVE_SPEED_T, 1,
1462 [Define to 1 if `speed_t' is declared by <termios.h>.])
1463 fi
1465 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1466 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1467 #include <sys/time.h>
1468 #include <time.h>
1469 #else
1470 #ifdef HAVE_SYS_TIME_H
1471 #include <sys/time.h>
1472 #else
1473 #include <time.h>
1474 #endif
1475 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1476 emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1477 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1478 if test $emacs_cv_struct_timeval = yes; then
1479 AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1480 fi
1482 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1483 AC_TRY_COMPILE([#include <math.h>],
1484 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1485 emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1486 HAVE_EXCEPTION=$emacs_cv_struct_exception
1487 if test $emacs_cv_struct_exception != yes; then
1488 AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1489 fi
1491 dnl checks for structure members
1492 AC_STRUCT_TM
1493 AC_STRUCT_TIMEZONE
1494 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1495 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1496 [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1497 [#include <time.h>])
1499 dnl checks for compiler characteristics
1501 dnl Testing __STDC__ to determine prototype support isn't good enough.
1502 dnl DEC C, for instance, doesn't define it with default options, and
1503 dnl is used on 64-bit systems (OSF Alphas). Similarly for volatile
1504 dnl and void *.
1505 AC_C_PROTOTYPES
1506 AC_C_VOLATILE
1507 AC_C_CONST
1508 dnl This isn't useful because we can't turn on use of `inline' unless
1509 dnl the compiler groks `extern inline'.
1510 dnl AC_C_INLINE
1511 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1512 [AC_TRY_COMPILE(, [void * foo;],
1513 emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1514 if test $emacs_cv_void_star = yes; then
1515 AC_DEFINE(POINTER_TYPE, void)
1516 else
1517 AC_DEFINE(POINTER_TYPE, char)
1518 fi
1519 AH_TEMPLATE(POINTER_TYPE,
1520 [Define as `void' if your compiler accepts `void *'; otherwise
1521 define as `char'.])dnl
1523 dnl This could be used for targets which can have both byte sexes.
1524 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1525 dnl AC_C_BIGENDIAN
1527 dnl check for Make feature
1528 AC_PROG_MAKE_SET
1530 dnl checks for operating system services
1531 AC_SYS_LONG_FILE_NAMES
1533 #### Choose a window system.
1535 AC_PATH_X
1536 if test "$no_x" = yes; then
1537 window_system=none
1538 else
1539 window_system=x11
1540 fi
1542 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1543 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1544 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1545 x_default_search_path=""
1546 for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1547 x_search_path="\
1548 ${x_library}/X11/%L/%T/%N%C%S:\
1549 ${x_library}/X11/%l/%T/%N%C%S:\
1550 ${x_library}/X11/%T/%N%C%S:\
1551 ${x_library}/X11/%L/%T/%N%S:\
1552 ${x_library}/X11/%l/%T/%N%S:\
1553 ${x_library}/X11/%T/%N%S"
1554 if test x"${x_default_search_path}" = x; then
1555 x_default_search_path=${x_search_path}
1556 else
1557 x_default_search_path="${x_search_path}:${x_default_search_path}"
1558 fi
1559 done
1560 fi
1561 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1562 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1563 fi
1565 if test x"${x_includes}" = x; then
1566 bitmapdir=/usr/include/X11/bitmaps
1567 else
1568 # accumulate include directories that have X11 bitmap subdirectories
1569 bmd_acc="dummyval"
1570 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1571 if test -d "${bmd}/X11/bitmaps"; then
1572 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1573 fi
1574 if test -d "${bmd}/bitmaps"; then
1575 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1576 fi
1577 done
1578 if test ${bmd_acc} != "dummyval"; then
1579 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1580 fi
1581 fi
1583 case "${window_system}" in
1584 x11 )
1585 HAVE_X_WINDOWS=yes
1586 HAVE_X11=yes
1587 case "${with_x_toolkit}" in
1588 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1589 motif ) USE_X_TOOLKIT=MOTIF ;;
1590 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1591 gtk ) with_gtk=yes
1592 dnl Dont set this for GTK. A lot of tests below assumes Xt when
1593 dnl USE_X_TOOLKIT is set.
1594 USE_X_TOOLKIT=none ;;
1595 no ) USE_X_TOOLKIT=none ;;
1596 dnl If user did not say whether to use a toolkit,
1597 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1598 * ) USE_X_TOOLKIT=maybe ;;
1599 esac
1600 ;;
1601 none )
1602 HAVE_X_WINDOWS=no
1603 HAVE_X11=no
1604 USE_X_TOOLKIT=none
1605 ;;
1606 esac
1608 ### If we're using X11, we should use the X menu package.
1609 HAVE_MENUS=no
1610 case ${HAVE_X11} in
1611 yes ) HAVE_MENUS=yes ;;
1612 esac
1614 if test "${opsys}" = "hpux9"; then
1615 case "${x_libraries}" in
1616 *X11R4* )
1617 opsysfile="s/hpux9-x11r4.h"
1618 ;;
1619 esac
1620 fi
1622 if test "${opsys}" = "hpux9shr"; then
1623 case "${x_libraries}" in
1624 *X11R4* )
1625 opsysfile="s/hpux9shxr4.h"
1626 ;;
1627 esac
1628 fi
1630 ### Compute the unexec source name from the object name.
1631 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1633 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1634 # Assume not, until told otherwise.
1635 GNU_MALLOC=yes
1636 doug_lea_malloc=yes
1637 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1638 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1639 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1640 emacs_cv_var___after_morecore_hook,
1641 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1642 emacs_cv_var___after_morecore_hook=yes,
1643 emacs_cv_var___after_morecore_hook=no)])
1644 if test $emacs_cv_var___after_morecore_hook = no; then
1645 doug_lea_malloc=no
1646 fi
1647 if test "${system_malloc}" = "yes"; then
1648 GNU_MALLOC=no
1649 GNU_MALLOC_reason="
1650 (The GNU allocators don't work with this system configuration.)"
1651 fi
1652 if test "$doug_lea_malloc" = "yes" ; then
1653 if test "$GNU_MALLOC" = yes ; then
1654 GNU_MALLOC_reason="
1655 (Using Doug Lea's new malloc from the GNU C Library.)"
1656 fi
1657 AC_DEFINE(DOUG_LEA_MALLOC, 1,
1658 [Define to 1 if you are using the GNU C Library.])
1659 fi
1661 if test x"${REL_ALLOC}" = x; then
1662 REL_ALLOC=${GNU_MALLOC}
1663 fi
1665 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1666 dnl the system configuration file (s/*.h) to turn the use of mmap
1667 dnl in the relocating allocator on.
1669 AC_FUNC_MMAP
1670 if test $use_mmap_for_buffers = yes; then
1671 REL_ALLOC=no
1672 fi
1674 LIBS="$libsrc_libs $LIBS"
1676 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1677 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1678 AC_CHECK_LIB(dnet, dnet_ntoa)
1679 dnl This causes -lresolv to get used in subsequent tests,
1680 dnl which causes failures on some systems such as HPUX 9.
1681 dnl AC_CHECK_LIB(resolv, gethostbyname)
1683 dnl FIXME replace main with a function we actually want from this library.
1684 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1686 AC_CHECK_LIB(pthreads, cma_open)
1688 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1689 if test -d /usr/X386/include; then
1690 HAVE_XFREE386=yes
1691 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1692 else
1693 HAVE_XFREE386=no
1694 fi
1695 AC_MSG_RESULT($HAVE_XFREE386)
1697 dnl Check for need for bigtoc support on IBM AIX
1699 case ${host_os} in
1700 aix*)
1701 AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1702 case $GCC in
1703 yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1704 *) gdb_cv_bigtoc=-bbigtoc ;;
1705 esac
1707 LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1708 AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1709 ])
1710 ;;
1711 esac
1713 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1714 # used for the tests that follow. We set them back to REAL_CFLAGS and
1715 # REAL_CPPFLAGS later on.
1717 REAL_CPPFLAGS="$CPPFLAGS"
1719 if test "${HAVE_X11}" = "yes"; then
1720 DEFS="$C_SWITCH_X_SITE $DEFS"
1721 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1722 LIBS="$LIBX $LIBS"
1723 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1724 CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1726 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1727 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1728 # but it's more convenient here to set LD_RUN_PATH
1729 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1730 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1731 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1732 export LD_RUN_PATH
1733 fi
1735 if test "${opsys}" = "gnu-linux"; then
1736 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1737 AC_TRY_LINK([],
1738 [XOpenDisplay ("foo");],
1739 [xlinux_first_failure=no],
1740 [xlinux_first_failure=yes])
1741 if test "${xlinux_first_failure}" = "yes"; then
1742 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1743 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1744 OLD_CPPFLAGS="$CPPFLAGS"
1745 OLD_LIBS="$LIBS"
1746 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1747 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1748 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1749 LIBS="$LIBS -b i486-linuxaout"
1750 AC_TRY_LINK([],
1751 [XOpenDisplay ("foo");],
1752 [xlinux_second_failure=no],
1753 [xlinux_second_failure=yes])
1754 if test "${xlinux_second_failure}" = "yes"; then
1755 # If we get the same failure with -b, there is no use adding -b.
1756 # So take it out. This plays safe.
1757 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1758 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1759 CPPFLAGS="$OLD_CPPFLAGS"
1760 LIBS="$OLD_LIBS"
1761 AC_MSG_RESULT(no)
1762 else
1763 AC_MSG_RESULT(yes)
1764 fi
1765 else
1766 AC_MSG_RESULT(no)
1767 fi
1768 fi
1770 # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1771 # header files included from there.
1772 AC_MSG_CHECKING(for Xkb)
1773 AC_TRY_LINK([#include <X11/Xlib.h>
1774 #include <X11/XKBlib.h>],
1775 [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1776 emacs_xkb=yes, emacs_xkb=no)
1777 AC_MSG_RESULT($emacs_xkb)
1778 if test $emacs_xkb = yes; then
1779 AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1780 fi
1782 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1783 XScreenNumberOfScreen XSetWMProtocols)
1784 fi
1786 if test "${window_system}" = "x11"; then
1787 AC_MSG_CHECKING(X11 version 6)
1788 AC_CACHE_VAL(emacs_cv_x11_version_6,
1789 [AC_TRY_LINK([#include <X11/Xlib.h>],
1790 [#if XlibSpecificationRelease < 6
1791 fail;
1792 #endif
1793 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1794 if test $emacs_cv_x11_version_6 = yes; then
1795 AC_MSG_RESULT(6 or newer)
1796 AC_DEFINE(HAVE_X11R6, 1,
1797 [Define to 1 if you have the X11R6 or newer version of Xlib.])
1798 else
1799 AC_MSG_RESULT(before 6)
1800 fi
1801 fi
1803 if test "${window_system}" = "x11"; then
1804 AC_MSG_CHECKING(X11 version 5)
1805 AC_CACHE_VAL(emacs_cv_x11_version_5,
1806 [AC_TRY_LINK([#include <X11/Xlib.h>],
1807 [#if XlibSpecificationRelease < 5
1808 fail;
1809 #endif
1810 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no)])
1811 if test $emacs_cv_x11_version_5 = yes; then
1812 AC_MSG_RESULT(5 or newer)
1813 HAVE_X11R5=yes
1814 AC_DEFINE(HAVE_X11R5, 1,
1815 [Define to 1 if you have the X11R5 or newer version of Xlib.])
1816 else
1817 HAVE_X11R5=no
1818 AC_MSG_RESULT(before 5)
1819 fi
1820 fi
1822 dnl This function defintion taken from Gnome 2.0
1823 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1824 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1825 dnl also defines GSTUFF_PKG_ERRORS on error
1826 AC_DEFUN(PKG_CHECK_MODULES, [
1827 succeeded=no
1829 if test -z "$PKG_CONFIG"; then
1830 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1831 fi
1833 if test "$PKG_CONFIG" = "no" ; then
1834 echo "*** The pkg-config script could not be found. Make sure it is"
1835 echo "*** in your path, or give the full path to pkg-config with"
1836 echo "*** the PKG_CONFIG environment variable or --with-pkg-config-prog."
1837 echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1838 else
1839 PKG_CONFIG_MIN_VERSION=0.9.0
1840 if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1841 AC_MSG_CHECKING(for $2)
1843 if $PKG_CONFIG --exists "$2" ; then
1844 AC_MSG_RESULT(yes)
1845 succeeded=yes
1847 AC_MSG_CHECKING($1_CFLAGS)
1848 $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1849 AC_MSG_RESULT($$1_CFLAGS)
1851 AC_MSG_CHECKING($1_LIBS)
1852 $1_LIBS=`$PKG_CONFIG --libs "$2"`
1853 AC_MSG_RESULT($$1_LIBS)
1854 else
1855 $1_CFLAGS=""
1856 $1_LIBS=""
1857 ## If we have a custom action on failure, don't print errors, but
1858 ## do set a variable so people can do so.
1859 $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1860 ifelse([$4], ,echo $$1_PKG_ERRORS,)
1861 fi
1863 AC_SUBST($1_CFLAGS)
1864 AC_SUBST($1_LIBS)
1865 else
1866 echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1867 echo "*** See http://www.freedesktop.org/software/pkgconfig"
1868 fi
1869 fi
1871 if test $succeeded = yes; then
1872 ifelse([$3], , :, [$3])
1873 else
1874 ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
1875 fi
1876 ])
1878 HAVE_GTK=no
1879 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "gtk"; then
1880 if test "$USE_X_TOOLKIT" != "none" && test "$USE_X_TOOLKIT" != "maybe"; then
1881 AC_MSG_ERROR([Conflicting options, --with-gtk is incompatible with --with-x-toolkit=${with_x_toolkit}]);
1882 fi
1883 GLIB_REQUIRED=2.0.1
1884 GTK_REQUIRED=2.0.1
1885 GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1887 dnl Check if --with-pkg-config-prog has been given.
1888 if test "X${with_pkg_config_prog}" != X; then
1889 PKG_CONFIG="${with_pkg_config_prog}"
1890 fi
1891 dnl Checks for libraries.
1892 PKG_CHECK_MODULES(GTK, $GTK_MODULES)
1893 AC_SUBST(GTK_CFLAGS)
1894 AC_SUBST(GTK_LIBS)
1895 C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1896 HAVE_GTK=yes
1897 AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
1898 USE_X_TOOLKIT=none
1900 dnl GTK scrollbars resembles toolkit scrollbars alot, so to avoid
1901 dnl a lot if #ifdef:s, say we have toolkit scrollbars.
1902 with_toolkit_scroll_bars=yes
1903 fi
1905 dnl Do not put whitespace before the #include statements below.
1906 dnl Older compilers (eg sunos4 cc) choke on it.
1907 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1908 if test x"${HAVE_X11R5}" = xyes; then
1909 AC_MSG_CHECKING(X11 version 5 with Xaw)
1910 AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
1911 [AC_TRY_LINK([
1912 #include <X11/Intrinsic.h>
1913 #include <X11/Xaw/Simple.h>],
1914 [],
1915 emacs_cv_x11_version_5_with_xaw=yes,
1916 emacs_cv_x11_version_5_with_xaw=no)])
1917 if test $emacs_cv_x11_version_5_with_xaw = yes; then
1918 AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
1919 USE_X_TOOLKIT=LUCID
1920 else
1921 AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
1922 USE_X_TOOLKIT=none
1923 fi
1924 else
1925 USE_X_TOOLKIT=none
1926 fi
1927 fi
1929 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1931 if test "${USE_X_TOOLKIT}" != "none"; then
1932 AC_MSG_CHECKING(X11 toolkit version)
1933 AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1934 [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1935 [#if XtSpecificationRelease < 6
1936 fail;
1937 #endif
1938 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1939 HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1940 if test $emacs_cv_x11_toolkit_version_6 = yes; then
1941 AC_MSG_RESULT(6 or newer)
1942 AC_DEFINE(HAVE_X11XTR6, 1,
1943 [Define to 1 if you have the X11R6 or newer version of Xt.])
1944 else
1945 AC_MSG_RESULT(before 6)
1946 fi
1948 dnl If using toolkit, check whether libXmu.a exists.
1949 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1950 OLDLIBS="$LIBS"
1951 if test x$HAVE_X11XTR6 = xyes; then
1952 LIBS="-lXt -lSM -lICE $LIBS"
1953 else
1954 LIBS="-lXt $LIBS"
1955 fi
1956 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1957 test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1958 fi
1960 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1961 if test "${HAVE_X11}" = "yes"; then
1962 if test "${USE_X_TOOLKIT}" != "none"; then
1963 AC_CHECK_LIB(Xext, XShapeQueryExtension)
1964 fi
1965 fi
1967 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1968 AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1969 # We put this in CFLAGS temporarily to precede other -I options
1970 # that might be in CFLAGS temporarily.
1971 # We put this in CPPFLAGS where it precedes the other -I options.
1972 OLD_CPPFLAGS=$CPPFLAGS
1973 OLD_CFLAGS=$CFLAGS
1974 CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1975 CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1976 [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1977 [int x = 5;],
1978 emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1979 if test $emacs_cv_lesstif = yes; then
1980 # Make sure this -I option remains in CPPFLAGS after it is set
1981 # back to REAL_CPPFLAGS.
1982 # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1983 # have those other -I options anyway. Ultimately, having this
1984 # directory ultimately in CPPFLAGS will be enough.
1985 REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1986 LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1987 else
1988 CFLAGS=$OLD_CFLAGS
1989 CPPFLAGS=$OLD_CPPFLAGS
1990 fi
1991 AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1992 [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1993 [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1994 int x = 5;
1995 #else
1996 Motif version prior to 2.1.
1997 #endif],
1998 emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1999 HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
2000 if test $emacs_cv_motif_version_2_1 = yes; then
2001 HAVE_LIBXP=no
2002 AC_DEFINE(HAVE_MOTIF_2_1, 1,
2003 [Define to 1 if you have Motif 2.1 or newer.])
2004 AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
2005 if test ${HAVE_LIBXP} = yes; then
2006 AC_DEFINE(HAVE_LIBXP, 1,
2007 [Define to 1 if you have the Xp library (-lXp).])
2008 fi
2009 fi
2010 fi
2012 ### Is -lXaw3d available?
2013 HAVE_XAW3D=no
2014 if test "${HAVE_X11}" = "yes"; then
2015 if test "${USE_X_TOOLKIT}" != "none"; then
2016 dnl Fixme: determine what Scrollbar.h needs to avoid compilation
2017 dnl errors from the test without the `-'.
2018 AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
2019 [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes)], , -)
2020 if test "${HAVE_XAW3D}" = "yes"; then
2021 AC_DEFINE(HAVE_XAW3D, 1,
2022 [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2023 fi
2024 fi
2025 fi
2027 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2028 dnl using Motif or Xaw3d is available, and unless
2029 dnl --with-toolkit-scroll-bars=no was specified.
2031 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2032 [Define to 1 if we should use toolkit scroll bars.])dnl
2033 USE_TOOLKIT_SCROLL_BARS=no
2034 if test "${with_toolkit_scroll_bars}" != "no"; then
2035 if test "${USE_X_TOOLKIT}" != "none"; then
2036 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2037 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2038 HAVE_XAW3D=no
2039 USE_TOOLKIT_SCROLL_BARS=yes
2040 elif test "${HAVE_XAW3D}" = "yes"; then
2041 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2042 USE_TOOLKIT_SCROLL_BARS=yes
2043 fi
2044 elif test "${HAVE_GTK}" = "yes"; then
2045 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2046 USE_TOOLKIT_SCROLL_BARS=yes
2047 fi
2048 fi
2050 dnl Don't use X11 input methods if user specifies he doesn't want it
2051 dnl with `--with-xim=no'.
2053 if test "${with_xim}" != "no"; then
2054 AC_DEFINE(USE_XIM, 1,
2055 [Define to 1 if we should use XIM, if it is available.])
2056 late_CFLAGS=$CFLAGS
2057 if test "$GCC" = yes; then
2058 CFLAGS="$CFLAGS --pedantic-errors"
2059 fi
2060 AC_TRY_COMPILE([
2061 #include <X11/Xlib.h>
2062 #include <X11/Xresource.h>],
2063 [Display *display;
2064 XrmDatabase db;
2065 char *res_name;
2066 char *res_class;
2067 XIMProc callback;
2068 XPointer *client_data;
2069 #ifndef __GNUC__
2070 /* If we're not using GCC, it's probably not XFree86, and this is
2071 probably right, but we can't use something like --pedantic-errors. */
2072 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2073 char*, XIMProc, XPointer*);
2074 #endif
2075 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2076 client_data);],
2077 [emacs_cv_arg6_star=yes])
2078 AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2079 [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2080 either XPointer or XPointer*.])dnl
2081 if test "$emacs_cv_arg6_star" = yes; then
2082 AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2083 else
2084 AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2085 fi
2086 CFLAGS=$late_CFLAGS
2087 fi
2089 ### Use -lXpm if available, unless `--with-xpm=no'.
2090 HAVE_XPM=no
2091 if test "${HAVE_X11}" = "yes"; then
2092 if test "${with_xpm}" != "no"; then
2093 AC_CHECK_HEADER(X11/xpm.h,
2094 AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
2095 if test "${HAVE_XPM}" = "yes"; then
2096 AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2097 AC_EGREP_CPP(no_return_alloc_pixels,
2098 [#include "X11/xpm.h"
2099 #ifndef XpmReturnAllocPixels
2100 no_return_alloc_pixels
2101 #endif
2102 ], HAVE_XPM=no, HAVE_XPM=yes)
2104 if test "${HAVE_XPM}" = "yes"; then
2105 AC_MSG_RESULT(yes)
2106 else
2107 AC_MSG_RESULT(no)
2108 fi
2109 fi
2110 fi
2112 if test "${HAVE_XPM}" = "yes"; then
2113 AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2114 fi
2115 fi
2117 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2118 HAVE_JPEG=no
2119 if test "${HAVE_X11}" = "yes"; then
2120 if test "${with_jpeg}" != "no"; then
2121 dnl Checking for jpeglib.h can lose because of a redefinition of
2122 dnl HAVE_STDLIB_H.
2123 AC_CHECK_HEADER(jerror.h,
2124 AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes))
2125 fi
2127 AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2128 if test "${HAVE_JPEG}" = "yes"; then
2129 AC_DEFINE(HAVE_JPEG)
2130 AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2131 [#include <jpeglib.h>
2132 version=JPEG_LIB_VERSION
2133 ],
2134 AC_DEFINE(HAVE_JPEG),
2135 [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2136 HAVE_JPEG=no])
2137 fi
2138 fi
2140 ### Use -lpng if available, unless `--with-png=no'.
2141 HAVE_PNG=no
2142 if test "${HAVE_X11}" = "yes"; then
2143 if test "${with_png}" != "no"; then
2144 AC_CHECK_HEADER(png.h,
2145 AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm))
2146 fi
2148 if test "${HAVE_PNG}" = "yes"; then
2149 AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2150 fi
2151 fi
2153 ### Use -ltiff if available, unless `--with-tiff=no'.
2154 HAVE_TIFF=no
2155 if test "${HAVE_X11}" = "yes"; then
2156 if test "${with_tiff}" != "no"; then
2157 AC_CHECK_HEADER(tiffio.h,
2158 tifflibs="-lz -lm"
2159 # At least one tiff package requires the jpeg library.
2160 if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2161 AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
2162 fi
2164 if test "${HAVE_TIFF}" = "yes"; then
2165 AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2166 fi
2167 fi
2169 ### Use -lgif if available, unless `--with-gif=no'.
2170 HAVE_GIF=no
2171 if test "${HAVE_X11}" = "yes"; then
2172 if test "${with_gif}" != "no"; then
2173 AC_CHECK_HEADER(gif_lib.h,
2174 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2175 # Earlier versions can crash Emacs.
2176 AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes))
2177 fi
2179 if test "${HAVE_GIF}" = "yes"; then
2180 AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have the ungif library (-lungif).])
2181 fi
2182 fi
2184 ### Use Mac OS X Carbon API to implement GUI.
2185 HAVE_CARBON=no
2186 if test "${with_carbon}" != "no"; then
2187 AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
2188 fi
2190 if test "${HAVE_CARBON}" = "yes"; then
2191 AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2192 window_system=mac
2193 ## Specify the install directory
2194 carbon_appdir=
2195 if test "${carbon_appdir_x}" != ""; then
2196 case ${carbon_appdir_x} in
2197 y | ye | yes) carbon_appdir=/Applications ;;
2198 * ) carbon_appdir=${carbon_appdir_x} ;;
2199 esac
2200 fi
2201 # We also have mouse menus.
2202 HAVE_MENUS=yes
2203 fi
2205 ### Use session management (-lSM -lICE) if available
2206 HAVE_X_SM=no
2207 if test "${HAVE_X11}" = "yes"; then
2208 AC_CHECK_HEADER(X11/SM/SMlib.h,
2209 AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, -lICE))
2211 if test "${HAVE_X_SM}" = "yes"; then
2212 AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2213 case "$LIBS" in
2214 *-lSM*) ;;
2215 *) LIBS="-lSM -lICE $LIBS" ;;
2216 esac
2217 fi
2218 fi
2220 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2221 AC_CACHE_CHECK(whether netdb declares h_errno,
2222 emacs_cv_netdb_declares_h_errno,
2223 [AC_TRY_LINK([#include <netdb.h>],
2224 [return h_errno;],
2225 emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2226 if test $emacs_cv_netdb_declares_h_errno = yes; then
2227 AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2228 fi
2230 AC_FUNC_ALLOCA
2232 # fmod, logb, and frexp are found in -lm on most systems.
2233 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2234 AC_CHECK_LIB(m, sqrt)
2236 # Check for mail-locking functions in a "mail" library. Probably this should
2237 # have the same check as for liblockfile below.
2238 AC_CHECK_LIB(mail, maillock)
2239 dnl Debian, at least:
2240 AC_CHECK_LIB(lockfile, maillock)
2241 # If we have the shared liblockfile, assume we must use it for mail
2242 # locking (e.g. Debian). If we couldn't link against liblockfile
2243 # (no liblockfile.a installed), ensure that we don't need to.
2244 if test "$ac_cv_lib_lockfile_maillock" = no; then
2245 dnl This works for files generally, not just executables.
2246 dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf?
2247 AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2248 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2249 if test $ac_cv_prog_liblockfile = yes; then
2250 AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2251 This probably means that movemail could lose mail.
2252 There may be a `development' package to install containing liblockfile.])
2253 else :
2254 fi
2255 fi
2256 AC_CHECK_FUNCS(touchlock)
2257 AC_CHECK_HEADERS(maillock.h)
2259 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2260 rename closedir mkdir rmdir sysinfo \
2261 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
2262 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2263 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2264 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2265 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2266 gai_strerror mkstemp getline getdelim mremap memmove fsync bzero \
2267 memset memcmp memmove difftime memcpy mempcpy mblen mbrlen posix_memalign)
2269 AC_CHECK_HEADERS(sys/un.h)
2271 AC_FUNC_MKTIME
2272 if test "$ac_cv_func_working_mktime" = no; then
2273 AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2274 fi
2276 AC_FUNC_GETLOADAVG
2278 AC_FUNC_FSEEKO
2280 AC_FUNC_GETPGRP
2282 AC_FUNC_STRFTIME
2284 # UNIX98 PTYs.
2285 AC_CHECK_FUNCS(grantpt)
2287 # PTY-related GNU extensions.
2288 AC_CHECK_FUNCS(getpt)
2290 # Check this now, so that we will NOT find the above functions in ncurses.
2291 # That is because we have not set up to link ncurses in lib-src.
2292 # It's better to believe a function is not available
2293 # than to expect to find it in ncurses.
2294 AC_CHECK_LIB(ncurses, tparm)
2296 # Do we need the Hesiod library to provide the support routines?
2297 if test "$with_hesiod" = yes ; then
2298 # Don't set $LIBS here -- see comments above.
2299 resolv=no
2300 AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2301 [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2302 [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2303 if test "$resolv" = yes ; then
2304 RESOLVLIB=-lresolv
2305 AC_DEFINE(HAVE_LIBRESOLV, 1,
2306 [Define to 1 if you have the resolv library (-lresolv).])
2307 else
2308 RESOLVLIB=
2309 fi
2310 AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2311 AC_DEFINE(HAVE_LIBHESIOD, 1,
2312 [Define to 1 if you have the hesiod library (-lhesiod).]),
2313 :, $RESOLVLIB)])
2314 fi
2316 # These tell us which Kerberos-related libraries to use.
2317 if test "${with_kerberos+set}" = set; then
2318 AC_CHECK_LIB(com_err, com_err)
2319 AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2320 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2321 AC_CHECK_LIB(krb5, krb5_init_context)
2322 if test "${with_kerberos5+set}" != set; then
2323 AC_CHECK_LIB(des425, des_cbc_encrypt,,
2324 AC_CHECK_LIB(des, des_cbc_encrypt))
2325 AC_CHECK_LIB(krb4, krb_get_cred,,
2326 AC_CHECK_LIB(krb, krb_get_cred))
2327 fi
2329 if test "${with_kerberos5+set}" = set; then
2330 AC_CHECK_HEADERS(krb5.h)
2331 else
2332 AC_CHECK_HEADERS(des.h,,
2333 [AC_CHECK_HEADERS(kerberosIV/des.h,,
2334 [AC_CHECK_HEADERS(kerberos/des.h)])])
2335 AC_CHECK_HEADERS(krb.h,,
2336 [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2337 [AC_CHECK_HEADERS(kerberos/krb.h)])])
2338 fi
2339 AC_CHECK_HEADERS(com_err.h)
2340 fi
2342 # Solaris requires -lintl if you want strerror (which calls dgettext)
2343 # to return localized messages.
2344 AC_CHECK_LIB(intl, dgettext)
2346 AC_MSG_CHECKING(whether localtime caches TZ)
2347 AC_CACHE_VAL(emacs_cv_localtime_cache,
2348 [if test x$ac_cv_func_tzset = xyes; then
2349 AC_TRY_RUN([#include <time.h>
2350 extern char **environ;
2351 unset_TZ ()
2352 {
2353 char **from, **to;
2354 for (to = from = environ; (*to = *from); from++)
2355 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2356 to++;
2357 }
2358 char TZ_GMT0[] = "TZ=GMT0";
2359 char TZ_PST8[] = "TZ=PST8";
2360 main()
2361 {
2362 time_t now = time ((time_t *) 0);
2363 int hour_GMT0, hour_unset;
2364 if (putenv (TZ_GMT0) != 0)
2365 exit (1);
2366 hour_GMT0 = localtime (&now)->tm_hour;
2367 unset_TZ ();
2368 hour_unset = localtime (&now)->tm_hour;
2369 if (putenv (TZ_PST8) != 0)
2370 exit (1);
2371 if (localtime (&now)->tm_hour == hour_GMT0)
2372 exit (1);
2373 unset_TZ ();
2374 if (localtime (&now)->tm_hour != hour_unset)
2375 exit (1);
2376 exit (0);
2377 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2378 [# If we have tzset, assume the worst when cross-compiling.
2379 emacs_cv_localtime_cache=yes])
2380 else
2381 # If we lack tzset, report that localtime does not cache TZ,
2382 # since we can't invalidate the cache if we don't have tzset.
2383 emacs_cv_localtime_cache=no
2384 fi])dnl
2385 AC_MSG_RESULT($emacs_cv_localtime_cache)
2386 if test $emacs_cv_localtime_cache = yes; then
2387 AC_DEFINE(LOCALTIME_CACHE, 1,
2388 [Define to 1 if localtime caches TZ.])
2389 fi
2391 if test "x$HAVE_TIMEVAL" = xyes; then
2392 AC_CHECK_FUNCS(gettimeofday)
2393 if test $ac_cv_func_gettimeofday = yes; then
2394 AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2395 emacs_cv_gettimeofday_two_arguments,
2396 [AC_TRY_COMPILE([
2397 #ifdef TIME_WITH_SYS_TIME
2398 #include <sys/time.h>
2399 #include <time.h>
2400 #else
2401 #ifdef HAVE_SYS_TIME_H
2402 #include <sys/time.h>
2403 #else
2404 #include <time.h>
2405 #endif
2406 #endif],
2407 [struct timeval time;
2408 gettimeofday (&time, 0);],
2409 emacs_cv_gettimeofday_two_arguments=yes,
2410 emacs_cv_gettimeofday_two_arguments=no)])
2411 if test $emacs_cv_gettimeofday_two_arguments = no; then
2412 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2413 [Define to 1 if gettimeofday accepts only one argument.])
2414 fi
2415 fi
2416 fi
2418 # This defines (or not) HAVE_TZNAME and HAVE_TM_ZONE.
2419 AC_STRUCT_TIMEZONE
2421 dnl Note that AC_STRUCT_TIMEZONE doesn't do what you might expect.
2422 if test "$ac_cv_func_gettimeofday" = yes; then
2423 AC_CACHE_CHECK([for struct timezone], emacs_cv_struct_timezone,
2424 [AC_TRY_COMPILE([#include <sys/time.h>],
2425 [struct timezone tz;],
2426 dnl It may be that we can't call gettimeofday with a non-null pointer,
2427 dnl even though we have struct timezone (e.g. HPUX). In that case
2428 dnl we'll lie about struct timezone.
2429 [AC_TRY_RUN([
2430 #ifdef TIME_WITH_SYS_TIME
2431 #include <sys/time.h>
2432 #include <time.h>
2433 #else
2434 #ifdef HAVE_SYS_TIME_H
2435 #include <sys/time.h>
2436 #else
2437 #include <time.h>
2438 #endif
2439 #endif
2440 main () {
2441 struct timeval time;
2442 struct timezone dummy;
2443 exit (gettimeofday (&time, &dummy));
2444 }],
2445 emacs_cv_struct_timezone=yes,
2446 emacs_cv_struct_timezone=no, emacs_cv_struct_timezone=yes)],
2447 emacs_cv_struct_timezone=no)])
2448 fi
2450 ok_so_far=yes
2451 AC_CHECK_FUNC(socket, , ok_so_far=no)
2452 if test $ok_so_far = yes; then
2453 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2454 fi
2455 if test $ok_so_far = yes; then
2456 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2457 fi
2458 if test $ok_so_far = yes; then
2459 dnl Fixme: Not used. Should this be HAVE_SOCKETS?
2460 AC_DEFINE(HAVE_INET_SOCKETS, 1,
2461 [Define to 1 if you have inet sockets.])
2462 fi
2464 if test -f /usr/lpp/X11/bin/smt.exp; then
2465 AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2466 [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2467 fi
2469 AC_MSG_CHECKING(whether system supports dynamic ptys)
2470 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2471 AC_MSG_RESULT(yes)
2472 AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2473 else
2474 AC_MSG_RESULT(no)
2475 fi
2477 AC_FUNC_FORK
2479 dnl Adapted from Haible's version.
2480 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2481 [AC_TRY_LINK([#include <langinfo.h>],
2482 [char* cs = nl_langinfo(CODESET);],
2483 emacs_cv_langinfo_codeset=yes,
2484 emacs_cv_langinfo_codeset=no)
2485 ])
2486 if test $emacs_cv_langinfo_codeset = yes; then
2487 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2488 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2489 fi
2491 AC_CHECK_TYPES(size_t)
2493 AC_TYPE_MBSTATE_T
2495 dnl Restrict could probably be used effectively other than in regex.c.
2496 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2497 [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2498 emacs_cv_c_restrict=yes,
2499 [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2500 emacs_cv_c_restrict=__restrict,
2501 emacs_cv_c_restrict=no)])])
2502 case "$emacs_cv_c_restrict" in
2503 yes) emacs_restrict=restrict;;
2504 no) emacs_restrict="";;
2505 *) emacs_restrict="$emacs_cv_c_restrict";;
2506 esac
2507 if test "$emacs_restrict" != __restrict; then
2508 AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2509 [Define to compiler's equivalent of C99 restrict keyword.
2510 Don't define if equivalent is `__restrict'.])
2511 fi
2513 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2514 [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2515 emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2516 if test "$emacs_cv_c_restrict_arr" = yes; then
2517 AC_DEFINE(__restrict_arr, __restrict,
2518 [Define to compiler's equivalent of C99 restrict keyword in array
2519 declarations. Define as empty for no equivalent.])
2520 fi
2522 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2523 dnl how the tty code is related to POSIX and/or other versions of termios.
2524 dnl The following looks like a useful start.
2525 dnl
2526 dnl AC_SYS_POSIX_TERMIOS
2527 dnl if test $ac_cv_sys_posix_termios = yes; then
2528 dnl AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2529 dnl and macros for terminal control.])
2530 dnl AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2531 dnl fi
2533 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used. (Needs libobj replacement.)
2535 # Set up the CFLAGS for real compilation, so we can substitute it.
2536 CFLAGS="$REAL_CFLAGS"
2537 CPPFLAGS="$REAL_CPPFLAGS"
2539 #### Find out which version of Emacs this is.
2540 [version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
2541 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2542 if test x"${version}" = x; then
2543 AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2544 fi
2546 ### Specify what sort of things we'll be editing into Makefile and config.h.
2547 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2548 AC_SUBST(version)
2549 AC_SUBST(configuration)
2550 AC_SUBST(canonical)
2551 AC_SUBST(srcdir)
2552 AC_SUBST(prefix)
2553 AC_SUBST(exec_prefix)
2554 AC_SUBST(bindir)
2555 AC_SUBST(datadir)
2556 AC_SUBST(sharedstatedir)
2557 AC_SUBST(libexecdir)
2558 AC_SUBST(mandir)
2559 AC_SUBST(infodir)
2560 AC_SUBST(lispdir)
2561 AC_SUBST(locallisppath)
2562 AC_SUBST(lisppath)
2563 AC_SUBST(x_default_search_path)
2564 AC_SUBST(etcdir)
2565 AC_SUBST(archlibdir)
2566 AC_SUBST(docdir)
2567 AC_SUBST(bitmapdir)
2568 AC_SUBST(gamedir)
2569 AC_SUBST(gameuser)
2570 AC_SUBST(c_switch_system)
2571 AC_SUBST(c_switch_machine)
2572 AC_SUBST(LD_SWITCH_X_SITE)
2573 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2574 AC_SUBST(C_SWITCH_X_SITE)
2575 AC_SUBST(CFLAGS)
2576 AC_SUBST(X_TOOLKIT_TYPE)
2577 AC_SUBST(machfile)
2578 AC_SUBST(opsysfile)
2579 AC_SUBST(GETLOADAVG_LIBS)
2580 AC_SUBST(carbon_appdir)
2582 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}",
2583 [Define to the canonical Emacs configuration name.])
2584 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2585 [Define to the options passed to configure.])
2586 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}",
2587 [Define to the used machine dependent file.])
2588 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2589 [Define to the used os dependent file.])
2590 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2591 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2592 may need to deal with X Windows. For instance, if you've defined
2593 HAVE_X_WINDOWS above and your X libraries aren't in a place that
2594 your loader can find on its own, you might want to add "-L/..." or
2595 something similar.])
2596 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2597 [Define LD_SWITCH_X_SITE_AUX with an -R option
2598 in case it's needed (for Solaris, for example).])
2599 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE},
2600 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2601 may need to deal with X Windows. For instance, if you've defined
2602 HAVE_X_WINDOWS above and your X include files aren't in a place
2603 that your compiler can find on its own, you might want to add
2604 "-I/..." or something similar.])
2605 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC},
2606 [Define to the unexec source file name.])
2608 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2609 AC_DEFINE(HAVE_X_WINDOWS, 1,
2610 [Define to 1 if you want to use the X window system.])
2611 fi
2612 if test "${USE_X_TOOLKIT}" != "none" ; then
2613 AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2614 fi
2615 if test "${HAVE_X11}" = "yes" ; then
2616 AC_DEFINE(HAVE_X11, 1,
2617 [Define to 1 if you want to use version 11 of X windows.
2618 Otherwise, Emacs expects to use version 10.])
2619 fi
2620 if test "${HAVE_XFREE386}" = "yes" ; then
2621 AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
2622 fi
2623 if test "${HAVE_MENUS}" = "yes" ; then
2624 AC_DEFINE(HAVE_MENUS, 1,
2625 [Define to 1 if you have mouse menus.
2626 (This is automatic if you use X, but the option to specify it remains.)
2627 It is also defined with other window systems that support xmenu.c.])
2628 fi
2629 if test "${GNU_MALLOC}" = "yes" ; then
2630 AC_DEFINE(GNU_MALLOC, 1,
2631 [Define to 1 if you want to use the GNU memory allocator.])
2632 fi
2633 if test "${REL_ALLOC}" = "yes" ; then
2634 AC_DEFINE(REL_ALLOC, 1,
2635 [Define REL_ALLOC if you want to use the relocating allocator for
2636 buffer space.])
2637 fi
2639 AH_TOP([/* GNU Emacs site configuration template file.
2640 Copyright (C) 1988, 93, 94, 99, 2000, 2002 Free Software Foundation, Inc.
2642 This file is part of GNU Emacs.
2644 GNU Emacs is free software; you can redistribute it and/or modify
2645 it under the terms of the GNU General Public License as published by
2646 the Free Software Foundation; either version 2, or (at your option)
2647 any later version.
2649 GNU Emacs is distributed in the hope that it will be useful,
2650 but WITHOUT ANY WARRANTY; without even the implied warranty of
2651 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
2652 GNU General Public License for more details.
2654 You should have received a copy of the GNU General Public License
2655 along with GNU Emacs; see the file COPYING. If not, write to the
2656 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
2657 Boston, MA 02111-1307, USA. */
2660 /* No code in Emacs #includes config.h twice, but some bits of code
2661 intended to work with other packages as well (like gmalloc.c)
2662 think they can include it as many times as they like. */
2663 #ifndef EMACS_CONFIG_H
2664 #define EMACS_CONFIG_H
2665 ])dnl
2667 AH_BOTTOM([
2668 /* If we're using any sort of window system, define some consequences. */
2669 #ifdef HAVE_X_WINDOWS
2670 #define HAVE_WINDOW_SYSTEM
2671 #define MULTI_KBOARD
2672 #define HAVE_MOUSE
2673 #endif
2675 /* If we're using the Carbon API on Mac OS X, define a few more
2676 variables as well. */
2677 #ifdef HAVE_CARBON
2678 #define HAVE_WINDOW_SYSTEM
2679 #define HAVE_MOUSE
2680 #endif
2682 /* Define USER_FULL_NAME to return a string
2683 that is the user's full name.
2684 It can assume that the variable `pw'
2685 points to the password file entry for this user.
2687 At some sites, the pw_gecos field contains
2688 the user's full name. If neither this nor any other
2689 field contains the right thing, use pw_name,
2690 giving the user's login name, since that is better than nothing. */
2691 #define USER_FULL_NAME pw->pw_gecos
2693 /* Define AMPERSAND_FULL_NAME if you use the convention
2694 that & in the full name stands for the login id. */
2695 /* Turned on June 1996 supposing nobody will mind it. */
2696 #define AMPERSAND_FULL_NAME
2698 /* We have blockinput.h. */
2699 #define DO_BLOCK_INPUT
2701 /* Define HAVE_SOUND if we have sound support. We know it works
2702 and compiles only on the specified platforms. For others,
2703 it probably doesn't make sense to try. */
2705 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2706 #ifdef HAVE_MACHINE_SOUNDCARD_H
2707 #define HAVE_SOUND 1
2708 #endif
2709 #ifdef HAVE_SYS_SOUNDCARD_H
2710 #define HAVE_SOUND 1
2711 #endif
2712 #ifdef HAVE_SOUNDCARD_H
2713 #define HAVE_SOUND 1
2714 #endif
2715 #endif /* __FreeBSD__ || __NetBSD__ || __linux__ */
2717 /* If using GNU, then support inline function declarations. */
2718 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2719 generally, because even if non-gcc compilers accept `inline', they
2720 may reject `extern inline'. */
2721 #ifdef __GNUC__
2722 #define INLINE __inline__
2723 #else
2724 #define INLINE
2725 #endif
2727 /* Include the os and machine dependent files. */
2728 #include config_opsysfile
2729 #include config_machfile
2731 /* Load in the conversion definitions if this system
2732 needs them and the source file being compiled has not
2733 said to inhibit this. There should be no need for you
2734 to alter these lines. */
2736 #ifdef SHORTNAMES
2737 #ifndef NO_SHORTNAMES
2738 #include "../shortnames/remap.h"
2739 #endif /* not NO_SHORTNAMES */
2740 #endif /* SHORTNAMES */
2742 /* If no remapping takes place, static variables cannot be dumped as
2743 pure, so don't worry about the `static' keyword. */
2744 #ifdef NO_REMAP
2745 #undef static
2746 #endif
2748 /* Define `subprocesses' should be defined if you want to
2749 have code for asynchronous subprocesses
2750 (as used in M-x compile and M-x shell).
2751 These do not work for some USG systems yet;
2752 for the ones where they work, the s/SYSTEM.h file defines this flag. */
2754 #ifndef VMS
2755 #ifndef USG
2756 /* #define subprocesses */
2757 #endif
2758 #endif
2760 /* SIGTYPE is the macro we actually use. */
2761 #ifndef SIGTYPE
2762 #define SIGTYPE RETSIGTYPE
2763 #endif
2765 #ifdef emacs /* Don't do this for lib-src. */
2766 /* Tell regex.c to use a type compatible with Emacs. */
2767 #define RE_TRANSLATE_TYPE Lisp_Object
2768 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2769 #define RE_TRANSLATE_P(TBL) (XFASTINT (TBL) != 0)
2770 #endif
2772 /* Avoid link-time collision with system mktime if we will use our own. */
2773 #if ! HAVE_MKTIME || BROKEN_MKTIME
2774 #define mktime emacs_mktime
2775 #endif
2777 #define my_strftime nstrftime /* for strftime.c */
2779 /* The rest of the code currently tests the CPP symbol BSTRING.
2780 Override any claims made by the system-description files.
2781 Note that on some SCO version it is possible to have bcopy and not bcmp. */
2782 #undef BSTRING
2783 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2784 #define BSTRING
2785 #endif
2787 /* Some of the files of Emacs which are intended for use with other
2788 programs assume that if you have a config.h file, you must declare
2789 the type of getenv.
2791 This declaration shouldn't appear when alloca.s or Makefile.in
2792 includes config.h. */
2793 #ifndef NOT_C_CODE
2794 extern char *getenv ();
2795 #endif
2797 /* These default definitions are good for almost all machines.
2798 The exceptions override them in m/MACHINE.h. */
2800 #ifndef BITS_PER_CHAR
2801 #define BITS_PER_CHAR 8
2802 #endif
2804 #ifndef BITS_PER_SHORT
2805 #define BITS_PER_SHORT 16
2806 #endif
2808 /* Note that lisp.h uses this in a preprocessor conditional, so it
2809 would not work to use sizeof. That being so, we do all of them
2810 without sizeof, for uniformity's sake. */
2811 #ifndef BITS_PER_INT
2812 #define BITS_PER_INT 32
2813 #endif
2815 #ifndef BITS_PER_LONG
2816 #ifdef _LP64
2817 #define BITS_PER_LONG 64
2818 #else
2819 #define BITS_PER_LONG 32
2820 #endif
2821 #endif
2823 /* Define if the compiler supports function prototypes. It may do so
2824 but not define __STDC__ (e.g. DEC C by default) or may define it as
2825 zero. */
2826 #undef PROTOTYPES
2827 /* For mktime.c: */
2828 #ifndef __P
2829 # if defined PROTOTYPES
2830 # define __P(args) args
2831 # else
2832 # define __P(args) ()
2833 # endif /* GCC. */
2834 #endif /* __P */
2836 /* Don't include "string.h" or <stdlib.h> in non-C code. */
2837 #ifndef NOT_C_CODE
2838 #ifdef HAVE_STRING_H
2839 #include "string.h"
2840 #endif
2841 #ifdef HAVE_STRINGS_H
2842 #include "strings.h" /* May be needed for bcopy & al. */
2843 #endif
2844 #ifdef HAVE_STDLIB_H
2845 #include <stdlib.h>
2846 #endif
2847 #ifndef __GNUC__
2848 # ifdef HAVE_ALLOCA_H
2849 # include <alloca.h>
2850 # else /* AIX files deal with #pragma. */
2851 # ifndef alloca /* predefined by HP cc +Olibcalls */
2852 char *alloca ();
2853 # endif
2854 # endif /* HAVE_ALLOCA_H */
2855 #endif /* __GNUC__ */
2856 #ifndef HAVE_SIZE_T
2857 typedef unsigned size_t;
2858 #endif
2859 #endif /* NOT_C_CODE */
2861 /* Define HAVE_X_I18N if we have usable i18n support. */
2863 #ifdef HAVE_X11R6
2864 #define HAVE_X_I18N
2865 #elif defined HAVE_X11R5 && !defined X11R5_INHIBIT_I18N
2866 #define HAVE_X_I18N
2867 #endif
2869 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support. */
2871 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2872 #define HAVE_X11R6_XIM
2873 #endif
2875 /* Should we enable expensive run-time checking of data types? */
2876 #undef ENABLE_CHECKING
2878 #if defined __GNUC__ && (__GNUC__ > 2 \
2879 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2880 #define NO_RETURN __attribute__ ((__noreturn__))
2881 #else
2882 #define NO_RETURN /* nothing */
2883 #endif
2885 /* These won't be used automatically yet. We also need to know, at least,
2886 that the stack is continuous. */
2887 #ifdef __GNUC__
2888 # ifndef GC_SETJMP_WORKS
2889 /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2890 see NON_SAVING_SETJMP in the target descriptions. */
2891 /* Exceptions (see NON_SAVING_SETJMP in target description) are ns32k,
2892 SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2893 Fixme: Deal with ns32k, SVR3. */
2894 # define GC_SETJMP_WORKS 1
2895 # endif
2896 # ifndef GC_LISP_OBJECT_ALIGNMENT
2897 # define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2898 # endif
2899 #endif
2901 #ifndef HAVE_BCOPY
2902 #define bcopy(a,b,s) memcpy (b,a,s)
2903 #endif
2904 #ifndef HAVE_BZERO
2905 #define bzero(a,s) memset (a,0,s)
2906 #endif
2907 #ifndef HAVE_BCMP
2908 #define BCMP memcmp
2909 #endif
2911 #endif /* EMACS_CONFIG_H */
2913 /*
2914 Local Variables:
2915 mode: c
2916 End:
2917 */
2918 ])dnl
2920 #### Report on what we decided to do.
2921 #### Report GTK as a toolkit, even if it doesn't use Xt.
2922 #### It makes printing result more understandable as using GTK sets
2923 #### toolkit_scroll_bars to yes by default.
2924 if test "${HAVE_GTK}" = "yes"; then
2925 USE_X_TOOLKIT=GTK
2926 fi
2928 echo "
2929 Configured for \`${canonical}'.
2931 Where should the build process find the source code? ${srcdir}
2932 What operating system and machine description files should Emacs use?
2933 \`${opsysfile}' and \`${machfile}'
2934 What compiler should emacs be built with? ${CC} ${CFLAGS}
2935 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
2936 Should Emacs use a relocating allocator for buffers? ${REL_ALLOC}
2937 Should Emacs use mmap(2) for buffer allocation? $use_mmap_for_buffers
2938 What window system should Emacs use? ${window_system}
2939 What toolkit should Emacs use? ${USE_X_TOOLKIT}"
2941 if test -n "${x_includes}"; then
2942 echo " Where do we find X Windows header files? ${x_includes}"
2943 else
2944 echo " Where do we find X Windows header files? Standard dirs"
2945 fi
2946 if test -n "${x_libraries}"; then
2947 echo " Where do we find X Windows libraries? ${x_libraries}"
2948 else
2949 echo " Where do we find X Windows libraries? Standard dirs"
2950 fi
2952 echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}"
2953 echo " Does Emacs use -lXpm? ${HAVE_XPM}"
2954 echo " Does Emacs use -ljpeg? ${HAVE_JPEG}"
2955 echo " Does Emacs use -ltiff? ${HAVE_TIFF}"
2956 echo " Does Emacs use -lungif? ${HAVE_GIF}"
2957 echo " Does Emacs use -lpng? ${HAVE_PNG}"
2958 echo " Does Emacs use X toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}"
2959 echo
2961 # Remove any trailing slashes in these variables.
2962 [test "${prefix}" != NONE &&
2963 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2964 test "${exec_prefix}" != NONE &&
2965 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
2967 ## Check if the C preprocessor will convert `..' to `. .'. If so, set
2968 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2969 ## from Makefile.c can correctly provide the arg `-traditional' to the
2970 ## C preprocessor.
2972 AC_EGREP_CPP(yes..yes,
2973 [yes..yes],
2974 CPP_NEED_TRADITIONAL=no,
2975 CPP_NEED_TRADITIONAL=yes)
2977 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2978 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
2979 lisp/Makefile lispref/Makefile lispintro/Makefile leim/Makefile, [
2981 ### Make the necessary directories, if they don't exist.
2982 for dir in etc lisp ; do
2983 test -d ${dir} || mkdir ${dir}
2984 done
2986 # Build src/Makefile from ${srcdir}/src/Makefile.c
2987 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2988 # This must be done after src/config.h is built, since we rely on that file.
2990 # Now get this: Some word that is part of the ${srcdir} directory name
2991 # or the ${configuration} value might, just might, happen to be an
2992 # identifier like `sun4' or `i386' or something, and be predefined by
2993 # the C preprocessor to some helpful value like 1, or maybe the empty
2994 # string. Needless to say consequent macro substitutions are less
2995 # than conducive to the makefile finding the correct directory.
2996 [undefs="`echo $top_srcdir $configuration $canonical |
2997 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
2998 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
2999 `"]
3001 echo creating src/epaths.h
3002 ${MAKE-make} epaths-force
3004 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3005 # `..' to `. .' unless invoked with -traditional
3007 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3008 CPPFLAGS="$CPPFLAGS -traditional"
3009 fi
3011 echo creating lib-src/Makefile
3012 ( cd lib-src
3013 rm -f junk.c junk1.c junk2.c
3014 sed -e '/start of cpp stuff/q' \
3015 < Makefile.c > junk1.c
3016 sed -e '1,/start of cpp stuff/d'\
3017 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3018 < Makefile.c > junk.c
3019 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3020 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
3021 cat junk1.c junk2.c > Makefile.new
3022 rm -f junk.c junk1.c junk2.c
3023 chmod 444 Makefile.new
3024 mv -f Makefile.new Makefile
3025 )
3027 echo creating src/Makefile
3028 ( cd src
3029 rm -f junk.c junk1.c junk2.c
3030 sed -e '/start of cpp stuff/q' \
3031 < Makefile.c > junk1.c
3032 sed -e '1,/start of cpp stuff/d'\
3033 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3034 < Makefile.c > junk.c
3035 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3036 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
3037 cat junk1.c junk2.c > Makefile.new
3038 rm -f junk.c junk1.c junk2.c
3039 chmod 444 Makefile.new
3040 mv -f Makefile.new Makefile
3041 )
3043 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3044 echo creating src/.gdbinit
3045 echo source $srcdir/src/.gdbinit > src/.gdbinit
3046 fi
3048 # This is how we know whether to re-run configure in certain cases.
3049 touch src/config.stamp
3051 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])