| blob | 294ff8eac39ecdee14ac2cd85ec7bbeb2a2f7656 |
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001
7 dnl Free Software Foundation, Inc.
8 dnl
9 dnl This file is part of GNU Emacs.
10 dnl
11 dnl GNU Emacs is free software; you can redistribute it and/or modify
12 dnl it under the terms of the GNU General Public License as published by
13 dnl the Free Software Foundation; either version 2, or (at your option)
14 dnl any later version.
15 dnl
16 dnl GNU Emacs is distributed in the hope that it will be useful,
17 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
18 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19 dnl GNU General Public License for more details.
20 dnl
21 dnl You should have received a copy of the GNU General Public License
22 dnl along with GNU Emacs; see the file COPYING. If not, write to the
23 dnl Free Software Foundation, Inc., 59 Temple Place - Suite 330,
24 dnl Boston, MA 02111-1307, USA.
26 AC_PREREQ(2.8)dnl
27 AC_INIT(src/lisp.h)
28 AC_CONFIG_HEADER(src/config.h:src/config.in)
30 lispdir='${datadir}/emacs/${version}/lisp'
31 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
32 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
33 lisppath='${locallisppath}:${lispdir}'
34 etcdir='${datadir}/emacs/${version}/etc'
35 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
36 docdir='${datadir}/emacs/${version}/etc'
38 AC_ARG_WITH(gcc,
39 [ --without-gcc don't use GCC to compile Emacs if GCC is found])
40 AC_ARG_WITH(pop,
41 [ --without-pop don't support POP mail retrieval with movemail],
42 [if test "$withval" = yes; then
43 AC_DEFINE(MAIL_USE_POP)
44 else :
45 fi],
46 AC_DEFINE(MAIL_USE_POP))
47 AC_ARG_WITH(kerberos,
48 [ --with-kerberos support Kerberos-authenticated POP],
49 [AC_DEFINE(KERBEROS)])
50 AC_ARG_WITH(kerberos5,
51 [ --with-kerberos5 support Kerberos version 5 authenticated POP],
52 [if test "${with_kerberos5+set}" = set; then
53 if test "${with_kerberos+set}" != set; then
54 with_kerberos=yes
55 AC_DEFINE(KERBEROS)
56 fi
57 fi
58 AC_DEFINE(KERBEROS5)])
59 AC_ARG_WITH(hesiod,
60 [ --with-hesiod support Hesiod to get the POP server host],
61 [AC_DEFINE(HESIOD)])
62 dnl This should be the last --with option, because --with-x is
63 dnl added later on when we find the path of X, and it's best to
64 dnl keep them together visually.
65 AC_ARG_WITH(x-toolkit,
66 [ --with-x-toolkit=KIT use an X toolkit (KIT = yes/lucid/athena/motif/no)],
67 [ case "${withval}" in
68 y | ye | yes ) val=athena ;;
69 n | no ) val=no ;;
70 l | lu | luc | luci | lucid ) val=lucid ;;
71 a | at | ath | athe | athen | athena ) val=athena ;;
72 m | mo | mot | moti | motif ) val=motif ;;
73 dnl These don't currently work.
74 dnl o | op | ope | open | open- | open-l | open-lo \
75 dnl | open-loo | open-look ) val=open-look ;;
76 * )
77 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
78 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
79 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
80 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
81 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
82 ;;
83 esac
84 with_x_toolkit=$val
85 ])
86 AC_ARG_WITH(xpm,
87 [ --with-xpm use -lXpm for displaying XPM images])
88 AC_ARG_WITH(jpeg,
89 [ --with-jpeg use -ljpeg for displaying JPEG images])
90 AC_ARG_WITH(tiff,
91 [ --with-tiff use -ltiff for displaying TIFF images])
92 AC_ARG_WITH(gif,
93 [ --with-gif use -lungif for displaying GIF images])
94 AC_ARG_WITH(png,
95 [ --with-png use -lpng for displaying PNG images])
96 AC_ARG_WITH(toolkit-scroll-bars,
97 [ --without-toolkit-scroll-bars
98 don't use Motif or Xaw3d scroll bars])
99 AC_ARG_WITH(xim,
100 [ --without-xim don't use X11 XIM])
102 #### Make srcdir absolute, if it isn't already. It's important to
103 #### avoid running the path through pwd unnecessarily, since pwd can
104 #### give you automounter prefixes, which can go away. We do all this
105 #### so Emacs can find its files when run uninstalled.
106 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
107 unset CDPATH
108 case "${srcdir}" in
109 /* ) ;;
110 . )
111 ## We may be able to use the $PWD environment variable to make this
112 ## absolute. But sometimes PWD is inaccurate.
113 if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".${PWD}" ;
114 then
115 srcdir="$PWD"
116 else
117 srcdir="`(cd ${srcdir}; pwd)`"
118 fi
119 ;;
120 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
121 esac
123 #### Check if the source directory already has a configured system in it.
124 if test `pwd` != `(cd ${srcdir} && pwd)` \
125 && test -f "${srcdir}/src/config.h" ; then
126 AC_MSG_WARN([The directory tree \`${srcdir}' is being used
127 as a build directory right now; it has been configured in its own
128 right. To configure in another directory as well, you MUST
129 use GNU make. If you do not have GNU make, then you must
130 now do \`make distclean' in ${srcdir},
131 and then run $0 again.])
133 changequote(, )dnl
134 extrasub='/^VPATH[ ]*=/c\
135 changequote([, ])dnl
136 vpath %.c $(srcdir)\
137 vpath %.h $(srcdir)\
138 vpath %.y $(srcdir)\
139 vpath %.l $(srcdir)\
140 vpath %.s $(srcdir)\
141 vpath %.in $(srcdir)\
142 vpath %.texi $(srcdir)'
143 fi
145 #### Given the configuration name, set machfile and opsysfile to the
146 #### names of the m/*.h and s/*.h files we should use.
148 ### Canonicalize the configuration name.
150 AC_CANONICAL_HOST
151 canonical=$host
152 configuration=$host_alias
154 changequote(, )dnl
156 ### If you add support for a new configuration, add code to this
157 ### switch statement to recognize your configuration name and select
158 ### the appropriate operating system and machine description files.
160 ### You would hope that you could choose an m/*.h file pretty much
161 ### based on the machine portion of the configuration name, and an s-
162 ### file based on the operating system portion. However, it turns out
163 ### that each m/*.h file is pretty manufacturer-specific - for
164 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
165 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
166 ### machines. So we basically have to have a special case for each
167 ### configuration name.
168 ###
169 ### As far as handling version numbers on operating systems is
170 ### concerned, make sure things will fail in a fixable way. If
171 ### /etc/MACHINES doesn't say anything about version numbers, be
172 ### prepared to handle anything reasonably. If version numbers
173 ### matter, be sure /etc/MACHINES says something about it.
174 ###
175 ### Eric Raymond says we should accept strings like "sysvr4" to mean
176 ### "System V Release 4"; he writes, "The old convention encouraged
177 ### confusion between `system' and `release' levels'."
179 machine='' opsys='' unported=no
180 case "${canonical}" in
182 ## NetBSD ports
183 *-*-netbsd* )
184 opsys=netbsd
185 case "${canonical}" in
186 alpha*-*-netbsd*) machine=alpha ;;
187 i[3456]86-*-netbsd*) machine=intel386 ;;
188 m68k-*-netbsd*)
189 # This is somewhat bogus.
190 machine=hp9000s300 ;;
191 powerpc-apple-netbsd*) machine=macppc ;;
192 mips-*-netbsd*) machine=pmax ;;
193 mipsel-*-netbsd*) machine=pmax ;;
194 ns32k-*-netbsd*) machine=ns32000 ;;
195 powerpc-*-netbsd*) machine=macppc ;;
196 sparc*-*-netbsd*) machine=sparc ;;
197 vax-*-netbsd*) machine=vax ;;
198 arm-*-netbsd*) machine=arm ;;
199 esac
200 ;;
202 ## OpenBSD ports
203 *-*-openbsd* )
204 opsys=openbsd
205 case "${canonical}" in
206 alpha*-*-openbsd*) machine=alpha ;;
207 i386-*-openbsd*) machine=intel386 ;;
208 m68k-*-openbsd*) machine=hp9000s300 ;;
209 mipsel-*-openbsd*) machine=pmax ;;
210 ns32k-*-openbsd*) machine=ns32000 ;;
211 sparc-*-openbsd*) machine=sparc ;;
212 vax-*-openbsd*) machine=vax ;;
213 esac
214 ;;
216 ## Acorn RISCiX:
217 arm-acorn-riscix1.1* )
218 machine=acorn opsys=riscix1-1
219 ;;
220 arm-acorn-riscix1.2* | arm-acorn-riscix )
221 ## This name is riscix12 instead of riscix1.2
222 ## to avoid a file name conflict on MSDOS.
223 machine=acorn opsys=riscix12
224 ;;
226 ## BSDI ports
227 *-*-bsdi* )
228 opsys=bsdi
229 case "${canonical}" in
230 i[345]86-*-bsdi*) machine=intel386 ;;
231 sparc-*-bsdi*) machine=sparc ;;
232 powerpc-*-bsdi*) machine=macppc ;;
233 esac
234 case "${canonical}" in
235 *-*-bsd386* | *-*-bsdi1* ) opsys=bsd386 ;;
236 *-*-bsdi2.0* ) opsys=bsdos2 ;;
237 *-*-bsdi2* ) opsys=bsdos2-1 ;;
238 *-*-bsdi3* ) opsys=bsdos3 ;;
239 *-*-bsdi[45]* ) opsys=bsdos4 ;;
240 esac
241 ;;
243 ## Alliant machines
244 ## Strictly speaking, we need the version of the alliant operating
245 ## system to choose the right machine file, but currently the
246 ## configuration name doesn't tell us enough to choose the right
247 ## one; we need to give alliants their own operating system name to
248 ## do this right. When someone cares, they can help us.
249 fx80-alliant-* )
250 machine=alliant4 opsys=bsd4-2
251 ;;
252 i860-alliant-* )
253 machine=alliant-2800 opsys=bsd4-3
254 ;;
256 ## Alpha (DEC) machines.
257 alpha*-dec-osf* )
258 machine=alpha opsys=osf1
259 # This is needed to find X11R6.1 libraries for certain tests.
260 NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
261 GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
262 # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
263 # due to non-traditional preprocessing with the current compiler
264 # defaults. OSF 4 can also have that compiler version, and there
265 # seems always to have been a usable /usr/bin/cpp.
266 NON_GNU_CPP=/usr/bin/cpp
267 case "${canonical}" in
268 alpha*-dec-osf[5-9]*)
269 opsys=osf5-0 ;;
270 esac
271 ;;
273 alpha*-*-linux-gnu* )
274 machine=alpha opsys=gnu-linux
275 ;;
277 arm*-*-linux-gnu* )
278 machine=arm opsys=gnu-linux
279 ;;
281 ppc-*-linux | \
282 powerpc-*-linux* )
283 machine=macppc opsys=gnu-linux
284 ;;
286 ## Altos 3068
287 m68*-altos-sysv* )
288 machine=altos opsys=usg5-2
289 ;;
291 ## Amdahl UTS
292 580-amdahl-sysv* )
293 machine=amdahl opsys=usg5-2-2
294 ;;
296 ## Apollo, Domain/OS
297 m68*-apollo-* )
298 machine=apollo opsys=bsd4-3
299 ;;
301 ## AT&T 3b2, 3b5, 3b15, 3b20
302 we32k-att-sysv* )
303 machine=att3b opsys=usg5-2-2
304 ;;
306 ## AT&T 3b1 - The Mighty Unix PC!
307 m68*-att-sysv* )
308 machine=7300 opsys=usg5-2-2
309 ;;
311 ## Bull dpx20
312 rs6000-bull-bosx* )
313 machine=ibmrs6000 opsys=aix3-2
314 ;;
316 ## Bull dpx2
317 m68*-bull-sysv3* )
318 machine=dpx2 opsys=usg5-3
319 ;;
321 ## Bull sps7
322 m68*-bull-sysv2* )
323 machine=sps7 opsys=usg5-2
324 ;;
326 ## CCI 5/32, 6/32 -- see "Tahoe".
328 ## Celerity
329 ## I don't know what configuration name to use for this; config.sub
330 ## doesn't seem to know anything about it. Hey, Celerity users, get
331 ## in touch with us!
332 celerity-celerity-bsd* )
333 machine=celerity opsys=bsd4-2
334 ;;
336 ## Clipper
337 ## What operating systems does this chip run that Emacs has been
338 ## tested on?
339 clipper-* )
340 machine=clipper
341 ## We'll use the catch-all code at the bottom to guess the
342 ## operating system.
343 ;;
345 ## Convex
346 *-convex-bsd* | *-convex-convexos* )
347 machine=convex opsys=bsd4-3
348 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
349 NON_GNU_CPP="cc -E -P"
350 ;;
352 ## Cubix QBx/386
353 i[3456]86-cubix-sysv* )
354 machine=intel386 opsys=usg5-3
355 ;;
357 ## Cydra 5
358 cydra*-cydrome-sysv* )
359 machine=cydra5 opsys=usg5-3
360 ;;
362 ## Data General AViiON Machines
363 ## DG changed naming conventions with the release of 5.4.4.10, they
364 ## dropped the initial 5.4 but left the intervening R. Because of the
365 ## R this shouldn't conflict with older versions of the OS (which I
366 ## think were named like dgux4.*). In addition, DG new AViiONs series
367 ## uses either Motorola M88k or Intel Pentium CPUs.
368 m88k-dg-dguxR4.* | m88k-dg-dgux4* )
369 machine=aviion opsys=dgux4
370 ;;
371 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
372 ## This name is dgux5-4-3 instead of dgux5-4r3
373 ## to avoid a file name conflict on MSDOS.
374 machine=aviion opsys=dgux5-4-3
375 ;;
376 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
377 machine=aviion opsys=dgux5-4r2
378 ;;
379 m88k-dg-dgux* )
380 machine=aviion opsys=dgux
381 ;;
383 ## Data General AViiON Intel (x86) Machines
384 ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
385 ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
386 i[345]86-dg-dguxR4* )
387 machine=aviion-intel opsys=dgux4
388 ;;
390 ## DECstations
391 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
392 machine=pmax opsys=bsd4-2
393 ;;
394 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
395 machine=pmax opsys=bsd4-3
396 ;;
397 mips-dec-ultrix* )
398 machine=pmax opsys=ultrix4-3
399 ;;
400 mips-dec-osf* )
401 machine=pmax opsys=osf1
402 ;;
403 mips-dec-mach_bsd4.3* )
404 machine=pmax opsys=mach-bsd4-3
405 ;;
407 ## Motorola Delta machines
408 m68k-motorola-sysv* | m68000-motorola-sysv* )
409 machine=delta opsys=usg5-3
410 if test -z "`type gnucc | grep 'not found'`"
411 then
412 if test -s /etc/167config
413 then CC="gnucc -m68040"
414 else CC="gnucc -m68881"
415 fi
416 else
417 if test -z "`type gcc | grep 'not found'`"
418 then CC=gcc
419 else CC=cc
420 fi
421 fi
422 ;;
423 m88k-motorola-sysv4* )
424 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
425 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
426 # I hope there are not other 4.0 versions for this machine
427 # which really need usg5-4 instead.
428 machine=delta88k opsys=usg5-4-2
429 ;;
430 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
431 machine=delta88k opsys=usg5-3
432 ;;
434 ## Dual machines
435 m68*-dual-sysv* )
436 machine=dual opsys=usg5-2
437 ;;
438 m68*-dual-uniplus* )
439 machine=dual opsys=unipl5-2
440 ;;
442 ## Elxsi 6400
443 elxsi-elxsi-sysv* )
444 machine=elxsi opsys=usg5-2
445 ;;
447 ## Encore machines
448 ns16k-encore-bsd* )
449 machine=ns16000 opsys=umax
450 ;;
452 ## The GEC 63 - apparently, this port isn't really finished yet.
453 # I'm sure we finished off the last of the machines, though. -- fx
455 ## Gould Power Node and NP1
456 pn-gould-bsd4.2* )
457 machine=gould opsys=bsd4-2
458 ;;
459 pn-gould-bsd4.3* )
460 machine=gould opsys=bsd4-3
461 ;;
462 np1-gould-bsd* )
463 machine=gould-np1 opsys=bsd4-3
464 ;;
466 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
467 ## as far as Emacs is concerned).
468 m88k-harris-cxux* )
469 # Build needs to be different on 7.0 and later releases
470 case "`uname -r`" in
471 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
472 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
473 esac
474 NON_GNU_CPP="/lib/cpp"
475 ;;
476 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
477 m68k-harris-cxux* )
478 machine=nh3000 opsys=cxux
479 ;;
480 ## Harris power pc NightHawk running Power UNIX (Series 6000)
481 powerpc-harris-powerunix )
482 machine=nh6000 opsys=powerunix
483 NON_GNU_CPP="cc -Xo -E -P"
484 ;;
485 ## SR2001/SR2201 running HI-UX/MPP
486 hppa1.1-hitachi-hiuxmpp* )
487 machine=sr2k opsys=hiuxmpp
488 ;;
489 hppa1.1-hitachi-hiuxwe2* )
490 machine=sr2k opsys=hiuxwe2
491 ;;
492 ## Honeywell XPS100
493 xps*-honeywell-sysv* )
494 machine=xps100 opsys=usg5-2
495 ;;
497 ## HP 9000 series 200 or 300
498 m68*-hp-bsd* )
499 machine=hp9000s300 opsys=bsd4-3
500 ;;
501 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
502 m68*-hp-hpux* )
503 case "`uname -r`" in
504 ## Someone's system reports A.B8.05 for this.
505 ## I wonder what other possibilities there are.
506 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
507 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
508 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
509 *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
510 *) machine=hp9000s300 opsys=hpux ;;
511 esac
512 ;;
514 ## HP 9000 series 700 and 800, running HP/UX
515 hppa*-hp-hpux7* )
516 machine=hp800 opsys=hpux
517 ;;
518 hppa*-hp-hpux8* )
519 machine=hp800 opsys=hpux8
520 ;;
521 hppa*-hp-hpux9shr* )
522 machine=hp800 opsys=hpux9shr
523 ;;
524 hppa*-hp-hpux9* )
525 machine=hp800 opsys=hpux9
526 ;;
528 hppa*-hp-hpux10* )
529 machine=hp800 opsys=hpux10
530 ;;
531 hppa*-hp-hpux1[1-9]* )
532 machine=hp800 opsys=hpux11
533 ;;
535 ## HP 9000 series 700 and 800, running HP/UX
536 hppa*-hp-hpux* )
537 ## Cross-compilation? Nah!
538 case "`uname -r`" in
539 ## Someone's system reports A.B8.05 for this.
540 ## I wonder what other possibilities there are.
541 *.B8.* ) machine=hp800 opsys=hpux8 ;;
542 *.08.* ) machine=hp800 opsys=hpux8 ;;
543 *.09.* ) machine=hp800 opsys=hpux9 ;;
544 *) machine=hp800 opsys=hpux10 ;;
545 esac
546 ;;
547 hppa*-*-nextstep* )
548 machine=hp800 opsys=nextstep
549 ;;
551 ## Orion machines
552 orion-orion-bsd* )
553 machine=orion opsys=bsd4-2
554 ;;
555 clipper-orion-bsd* )
556 machine=orion105 opsys=bsd4-2
557 ;;
559 ## IBM machines
560 i[3456]86-ibm-aix1.1* )
561 machine=ibmps2-aix opsys=usg5-2-2
562 ;;
563 i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
564 machine=ibmps2-aix opsys=usg5-3
565 ;;
566 i370-ibm-aix*)
567 machine=ibm370aix opsys=usg5-3
568 ;;
569 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
570 machine=ibmrs6000 opsys=aix3-1
571 ;;
572 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
573 machine=ibmrs6000 opsys=aix3-2-5
574 ;;
575 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
576 machine=ibmrs6000 opsys=aix4-1
577 ;;
578 rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2* )
579 machine=ibmrs6000 opsys=aix4-2
580 ;;
581 rs6000-ibm-aix5.1* | powerpc-ibm-aix5.1* )
582 machine=ibmrs6000 opsys=aix4-2
583 ;;
584 rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0* )
585 machine=ibmrs6000 opsys=aix4
586 ;;
587 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
588 machine=ibmrs6000 opsys=aix4-1
589 ;;
590 rs6000-ibm-aix* | powerpc-ibm-aix* )
591 machine=ibmrs6000 opsys=aix3-2
592 ;;
593 romp-ibm-bsd4.3* )
594 machine=ibmrt opsys=bsd4-3
595 ;;
596 romp-ibm-bsd4.2* )
597 machine=ibmrt opsys=bsd4-2
598 ;;
599 romp-ibm-aos4.3* )
600 machine=ibmrt opsys=bsd4-3
601 ;;
602 romp-ibm-aos4.2* )
603 machine=ibmrt opsys=bsd4-2
604 ;;
605 romp-ibm-aos* )
606 machine=ibmrt opsys=bsd4-3
607 ;;
608 romp-ibm-bsd* )
609 machine=ibmrt opsys=bsd4-3
610 ;;
611 romp-ibm-aix* )
612 machine=ibmrt-aix opsys=usg5-2-2
613 ;;
615 ## Integrated Solutions `Optimum V'
616 m68*-isi-bsd4.2* )
617 machine=isi-ov opsys=bsd4-2
618 ;;
619 m68*-isi-bsd4.3* )
620 machine=isi-ov opsys=bsd4-3
621 ;;
623 ## Intel 386 machines where we do care about the manufacturer
624 i[3456]86-intsys-sysv* )
625 machine=is386 opsys=usg5-2-2
626 ;;
628 ## Prime EXL
629 i[3456]86-prime-sysv* )
630 machine=i386 opsys=usg5-3
631 ;;
633 ## Sequent Symmetry running Dynix
634 i[3456]86-sequent-bsd* )
635 machine=symmetry opsys=bsd4-3
636 ;;
638 ## Sequent Symmetry running ptx 4, which is a modified SVR4.
639 i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
640 machine=sequent-ptx opsys=ptx4
641 NON_GNU_CPP=/lib/cpp
642 ;;
644 ## Sequent Symmetry running DYNIX/ptx
645 ## Use the old cpp rather than the newer ANSI one.
646 i[3456]86-sequent-ptx* )
647 machine=sequent-ptx opsys=ptx
648 NON_GNU_CPP="/lib/cpp"
649 ;;
651 ## ncr machine running svr4.3.
652 i[3456]86-ncr-sysv4.3 )
653 machine=ncr386 opsys=usg5-4-3
654 ;;
656 ## Unspecified sysv on an ncr machine defaults to svr4.2.
657 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
658 i[3456]86-ncr-sysv* )
659 machine=ncr386 opsys=usg5-4-2
660 ;;
662 ## Intel Paragon OSF/1
663 i860-intel-osf1* )
664 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
665 ;;
667 ## Intel 860
668 i860-*-sysv4* )
669 machine=i860 opsys=usg5-4
670 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
671 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
672 ;;
674 ## Macintosh PowerPC
675 powerpc*-*-linux-gnu* )
676 machine=macppc opsys=gnu-linux
677 ;;
679 ## Masscomp machines
680 m68*-masscomp-rtu* )
681 machine=masscomp opsys=rtu
682 ;;
684 ## Megatest machines
685 m68*-megatest-bsd* )
686 machine=mega68 opsys=bsd4-2
687 ;;
689 ## Workstations sold by MIPS
690 ## This is not necessarily all workstations using the MIPS processor -
691 ## Irises are produced by SGI, and DECstations by DEC.
693 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
694 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
695 ## it gives for choosing between the alternatives seems to be "Use
696 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
697 ## the BSD world." I'll assume that these are instructions for
698 ## handling two odd situations, and that every other situation
699 ## should use mips.h and usg5-2-2, they being listed first.
700 mips-mips-usg* )
701 machine=mips4
702 ## Fall through to the general code at the bottom to decide on the OS.
703 ;;
704 mips-mips-riscos4* )
705 machine=mips4 opsys=bsd4-3
706 NON_GNU_CC="cc -systype bsd43"
707 NON_GNU_CPP="cc -systype bsd43 -E"
708 ;;
709 mips-mips-riscos5* )
710 machine=mips4 opsys=riscos5
711 NON_GNU_CC="cc -systype bsd43"
712 NON_GNU_CPP="cc -systype bsd43 -E"
713 ;;
714 mips-mips-bsd* )
715 machine=mips opsys=bsd4-3
716 ;;
717 mips-mips-* )
718 machine=mips opsys=usg5-2-2
719 ;;
721 ## NeXT
722 m68*-next-* | m68k-*-nextstep* )
723 machine=m68k opsys=nextstep
724 ;;
726 ## The complete machine from National Semiconductor
727 ns32k-ns-genix* )
728 machine=ns32000 opsys=usg5-2
729 ;;
731 ## NCR machines
732 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
733 machine=tower32 opsys=usg5-2-2
734 ;;
735 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
736 machine=tower32v3 opsys=usg5-3
737 ;;
739 ## NEC EWS4800
740 mips-nec-sysv4*)
741 machine=ews4800 opsys=ux4800
742 ;;
744 ## Nixdorf Targon 31
745 m68*-nixdorf-sysv* )
746 machine=targon31 opsys=usg5-2-2
747 ;;
749 ## Nu (TI or LMI)
750 m68*-nu-sysv* )
751 machine=nu opsys=usg5-2
752 ;;
754 ## Plexus
755 m68*-plexus-sysv* )
756 machine=plexus opsys=usg5-2
757 ;;
759 ## PowerPC reference platform
760 powerpcle-*-solaris2* )
761 machine=prep
762 opsys=sol2-5
763 ;;
765 ## Pyramid machines
766 ## I don't really have any idea what sort of processor the Pyramid has,
767 ## so I'm assuming it is its own architecture.
768 pyramid-pyramid-bsd* )
769 machine=pyramid opsys=bsd4-2
770 ;;
772 ## Sequent Balance
773 ns32k-sequent-bsd4.2* )
774 machine=sequent opsys=bsd4-2
775 ;;
776 ns32k-sequent-bsd4.3* )
777 machine=sequent opsys=bsd4-3
778 ;;
780 ## Siemens Nixdorf
781 mips-siemens-sysv* | mips-sni-sysv*)
782 machine=mips-siemens opsys=usg5-4
783 NON_GNU_CC=/usr/ccs/bin/cc
784 NON_GNU_CPP=/usr/ccs/lib/cpp
785 ;;
787 ## Silicon Graphics machines
788 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
789 m68*-sgi-iris3.5* )
790 machine=irist opsys=iris3-5
791 ;;
792 m68*-sgi-iris3.6* | m68*-sgi-iris*)
793 machine=irist opsys=iris3-6
794 ;;
795 ## Iris 4D
796 mips-sgi-irix3* )
797 machine=iris4d opsys=irix3-3
798 ;;
799 mips-sgi-irix4* )
800 machine=iris4d opsys=irix4-0
801 ;;
802 mips-sgi-irix6.5 )
803 machine=iris4d opsys=irix6-5
804 # Without defining _LANGUAGE_C, things get masked out in the headers
805 # so that, for instance, grepping for `free' in stdlib.h fails and
806 # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
807 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
808 NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
809 ;;
810 mips-sgi-irix6* )
811 machine=iris4d opsys=irix6-0
812 # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
813 # but presumably it does no harm.
814 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
815 # -32 probably isn't necessary in later v.6s -- anyone know which?
816 NON_GCC_TEST_OPTIONS=-32
817 ;;
818 mips-sgi-irix5.[01]* )
819 machine=iris4d opsys=irix5-0
820 ;;
821 mips-sgi-irix5* | mips-sgi-irix* )
822 machine=iris4d opsys=irix5-2
823 ;;
825 ## SONY machines
826 m68*-sony-bsd4.2* )
827 machine=news opsys=bsd4-2
828 ;;
829 m68*-sony-bsd4.3* )
830 machine=news opsys=bsd4-3
831 ;;
832 m68*-sony-newsos3* | m68*-sony-news3*)
833 machine=news opsys=bsd4-3
834 ;;
835 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
836 machine=news-risc opsys=bsd4-3
837 ;;
838 mips-sony-newsos6* )
839 machine=news-r6 opsys=newsos6
840 ;;
841 mips-sony-news* )
842 machine=news-risc opsys=newsos5
843 ;;
845 ## Stride
846 m68*-stride-sysv* )
847 machine=stride opsys=usg5-2
848 ;;
850 ## Suns
851 sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
852 machine=sparc opsys=gnu-linux
853 ;;
855 *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
856 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
857 | rs6000-*-solaris2*)
858 case "${canonical}" in
859 m68*-sunos1* ) machine=sun1 ;;
860 m68*-sunos2* ) machine=sun2 ;;
861 m68* ) machine=sun3 ;;
862 i[3456]86-sun-sunos[34]* ) machine=sun386 ;;
863 i[3456]86-*-* ) machine=intel386 ;;
864 powerpcle* ) machine=powerpcle ;;
865 powerpc* | rs6000* ) machine=ibmrs6000 ;;
866 sparc* ) machine=sparc ;;
867 * ) unported=yes ;;
868 esac
869 case "${canonical}" in
870 ## The Sun386 didn't get past 4.0.
871 i[3456]86-*-sunos4 ) opsys=sunos4-0 ;;
872 *-sunos4.0* ) opsys=sunos4-0 ;;
873 *-sunos4.1.[3-9]*noshare )
874 ## This name is sunos413 instead of sunos4-1-3
875 ## to avoid a file name conflict on MSDOS.
876 opsys=sunos413
877 NON_GNU_CPP=/usr/lib/cpp
878 NON_GCC_TEST_OPTIONS=-Bstatic
879 GCC_TEST_OPTIONS=-static
880 ;;
881 *-sunos4.1.[3-9]* | *-sunos4shr*)
882 opsys=sunos4shr
883 NON_GNU_CPP=/usr/lib/cpp
884 ;;
885 *-sunos4* | *-sunos )
886 opsys=sunos4-1
887 NON_GCC_TEST_OPTIONS=-Bstatic
888 GCC_TEST_OPTIONS=-static
889 ;;
890 *-sunos5.3* | *-solaris2.3* )
891 opsys=sol2-3
892 NON_GNU_CPP=/usr/ccs/lib/cpp
893 ;;
894 *-sunos5.4* | *-solaris2.4* )
895 opsys=sol2-4
896 NON_GNU_CPP=/usr/ccs/lib/cpp
897 RANLIB="ar -ts"
898 ;;
899 *-sunos5.5* | *-solaris2.5* )
900 opsys=sol2-5
901 NON_GNU_CPP=/usr/ccs/lib/cpp
902 RANLIB="ar -ts"
903 ;;
904 *-sunos5* | *-solaris* )
905 opsys=sol2-5
906 NON_GNU_CPP=/usr/ccs/lib/cpp
907 ;;
908 * ) opsys=bsd4-2 ;;
909 esac
910 ## Watch out for a compiler that we know will not work.
911 case "${canonical}" in
912 *-solaris* | *-sunos5* )
913 if [ "x$CC" = x/usr/ucb/cc ]; then
914 ## /usr/ucb/cc doesn't work;
915 ## we should find some other compiler that does work.
916 unset CC
917 fi
918 ;;
919 *) ;;
920 esac
921 ;;
922 sparc-*-nextstep* )
923 machine=sparc opsys=nextstep
924 ;;
926 ## Tadpole 68k
927 m68*-tadpole-sysv* )
928 machine=tad68k opsys=usg5-3
929 ;;
931 ## Tahoe machines
932 tahoe-tahoe-bsd4.2* )
933 machine=tahoe opsys=bsd4-2
934 ;;
935 tahoe-tahoe-bsd4.3* )
936 machine=tahoe opsys=bsd4-3
937 ;;
939 ## Tandem Integrity S2
940 mips-tandem-sysv* )
941 machine=tandem-s2 opsys=usg5-3
942 ;;
944 ## Tektronix XD88
945 m88k-tektronix-sysv3* )
946 machine=tekxd88 opsys=usg5-3
947 ;;
949 ## Tektronix 16000 box (6130?)
950 ns16k-tektronix-bsd* )
951 machine=ns16000 opsys=bsd4-2
952 ;;
953 ## Tektronix 4300
954 ## src/m/tek4300.h hints that this is a m68k machine.
955 m68*-tektronix-bsd* )
956 machine=tek4300 opsys=bsd4-3
957 ;;
959 ## Titan P2 or P3
960 ## We seem to have lost the machine-description file titan.h!
961 titan-titan-sysv* )
962 machine=titan opsys=usg5-3
963 ;;
965 ## Ustation E30 (SS5E)
966 m68*-unisys-uniplus* )
967 machine=ustation opsystem=unipl5-2
968 ;;
970 ## Vaxen.
971 vax-dec-* )
972 machine=vax
973 case "${canonical}" in
974 *-bsd4.1* ) opsys=bsd4-1 ;;
975 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
976 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
977 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
978 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
979 *-vms* ) opsys=vms ;;
980 * ) unported=yes
981 esac
982 ;;
984 ## Whitechapel MG1
985 ns16k-whitechapel-* )
986 machine=mg1
987 ## We don't know what sort of OS runs on these; we'll let the
988 ## operating system guessing code below try.
989 ;;
991 ## Wicat
992 m68*-wicat-sysv* )
993 machine=wicat opsys=usg5-2
994 ;;
996 ## IA-64
997 ia64*-*-linux* )
998 machine=ia64 opsys=gnu-linux
999 ;;
1001 ## Intel 386 machines where we don't care about the manufacturer
1002 i[3456]86-*-* )
1003 machine=intel386
1004 case "${canonical}" in
1005 *-lynxos* ) opsys=lynxos ;;
1006 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
1007 *-isc2.2* ) opsys=isc2-2 ;;
1008 *-isc4.0* ) opsys=isc4-0 ;;
1009 *-isc4.* ) opsys=isc4-1
1010 GCC_TEST_OPTIONS=-posix
1011 NON_GCC_TEST_OPTIONS=-Xp
1012 ;;
1013 *-isc* ) opsys=isc3-0 ;;
1014 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
1015 *-esix* ) opsys=esix ;;
1016 *-xenix* ) opsys=xenix ;;
1017 *-linux-gnu* ) opsys=gnu-linux ;;
1018 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
1019 *-sco3.2v5* ) opsys=sco5
1020 NON_GNU_CPP=/lib/cpp
1021 # Prevent -belf from being passed to $CPP.
1022 # /lib/cpp does not accept it.
1023 OVERRIDE_CPPFLAGS=" "
1024 ;;
1025 *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1026 *-386bsd* ) opsys=386bsd ;;
1027 *-freebsd* ) opsys=freebsd ;;
1028 *-nextstep* ) opsys=nextstep ;;
1029 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1030 esac
1031 ;;
1033 ## m68k Linux-based GNU system
1034 m68k-*-linux-gnu* )
1035 machine=m68k opsys=gnu-linux
1036 ;;
1038 ## Mips Linux-based GNU system
1039 mips-*-linux-gnu* )
1040 machine=mips opsys=gnu-linux
1041 ;;
1043 ## UXP/DS
1044 sparc-fujitsu-sysv4* )
1045 machine=sparc opsys=uxpds
1046 NON_GNU_CPP=/usr/ccs/lib/cpp
1047 RANLIB="ar -ts"
1048 ;;
1050 ## UXP/V
1051 f301-fujitsu-uxpv4.1)
1052 machine=f301 opsys=uxpv
1053 ;;
1055 * )
1056 unported=yes
1057 ;;
1058 esac
1060 ### If the code above didn't choose an operating system, just choose
1061 ### an operating system based on the configuration name. You really
1062 ### only want to use this when you have no idea what the right
1063 ### operating system is; if you know what operating systems a machine
1064 ### runs, it's cleaner to make it explicit in the case statement
1065 ### above.
1066 if test x"${opsys}" = x; then
1067 case "${canonical}" in
1068 *-gnu* ) opsys=gnu ;;
1069 *-bsd4.[01] ) opsys=bsd4-1 ;;
1070 *-bsd4.2 ) opsys=bsd4-2 ;;
1071 *-bsd4.3 ) opsys=bsd4-3 ;;
1072 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
1073 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
1074 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
1075 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
1076 *-sysv4.2uw* ) opsys=unixware ;;
1077 *-sysv4.1* | *-sysvr4.1* )
1078 NON_GNU_CPP=/usr/lib/cpp
1079 opsys=usg5-4 ;;
1080 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1081 if [ x$NON_GNU_CPP = x ]; then
1082 if [ -f /usr/ccs/lib/cpp ]; then
1083 NON_GNU_CPP=/usr/ccs/lib/cpp
1084 else
1085 NON_GNU_CPP=/lib/cpp
1086 fi
1087 fi
1088 opsys=usg5-4-2 ;;
1089 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
1090 * )
1091 unported=yes
1092 ;;
1093 esac
1094 fi
1096 changequote([, ])dnl
1098 if test $unported = yes; then
1099 AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
1100 Check \`etc/MACHINES' for recognized configuration names.])
1101 fi
1103 machfile="m/${machine}.h"
1104 opsysfile="s/${opsys}.h"
1107 #### Choose a compiler.
1108 test -n "$CC" && cc_specified=yes
1110 # Save the value of CFLAGS that the user specified.
1111 SPECIFIED_CFLAGS="$CFLAGS"
1113 case ${with_gcc} in
1114 "yes" ) CC="gcc" GCC=yes ;;
1115 "no" ) : ${CC=cc} ;;
1116 * ) AC_PROG_CC
1117 esac
1119 # On Suns, sometimes $CPP names a directory.
1120 if test -n "$CPP" && test -d "$CPP"; then
1121 CPP=
1122 fi
1124 #### Some systems specify a CPP to use unless we are using GCC.
1125 #### Now that we know whether we are using GCC, we can decide whether
1126 #### to use that one.
1127 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1128 then
1129 CPP="$NON_GNU_CPP"
1130 fi
1132 #### Some systems specify a CC to use unless we are using GCC.
1133 #### Now that we know whether we are using GCC, we can decide whether
1134 #### to use that one.
1135 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1136 test x$cc_specified != xyes
1137 then
1138 CC="$NON_GNU_CC"
1139 fi
1141 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1142 then
1143 CC="$CC $GCC_TEST_OPTIONS"
1144 fi
1146 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1147 then
1148 CC="$CC $NON_GCC_TEST_OPTIONS"
1149 fi
1151 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1152 then
1153 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1154 fi
1156 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1157 then
1158 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1159 fi
1161 #### Some other nice autoconf tests. If you add a test here which
1162 #### should make an entry in src/config.h, don't forget to add an
1163 #### #undef clause to src/config.h.in for autoconf to modify.
1165 dnl checks for programs
1166 AC_PROG_LN_S
1167 AC_PROG_CPP
1168 AC_PROG_INSTALL
1169 AC_PROG_YACC
1170 if test "x$RANLIB" = x; then
1171 AC_PROG_RANLIB
1172 fi
1174 dnl checks for Unix variants
1175 AC_AIX
1177 #### Extract some information from the operating system and machine files.
1179 AC_CHECKING([the machine- and system-dependent files to find out
1180 - which libraries the lib-src programs will want, and
1181 - whether the GNU malloc routines are usable])
1183 ### First figure out CFLAGS (which we use for running the compiler here)
1184 ### and REAL_CFLAGS (which we use for real compilation).
1185 ### The two are the same except on a few systems, where they are made
1186 ### different to work around various lossages. For example,
1187 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1188 ### as implying static linking.
1190 ### If the CFLAGS env var is specified, we use that value
1191 ### instead of the default.
1193 ### It's not important that this name contain the PID; you can't run
1194 ### two configures in the same directory and have anything work
1195 ### anyway.
1196 tempcname="conftest.c"
1198 echo '
1199 #include "'${srcdir}'/src/'${opsysfile}'"
1200 #include "'${srcdir}'/src/'${machfile}'"
1201 #ifndef LIBS_MACHINE
1202 #define LIBS_MACHINE
1203 #endif
1204 #ifndef LIBS_SYSTEM
1205 #define LIBS_SYSTEM
1206 #endif
1207 #ifndef C_SWITCH_SYSTEM
1208 #define C_SWITCH_SYSTEM
1209 #endif
1210 #ifndef C_SWITCH_MACHINE
1211 #define C_SWITCH_MACHINE
1212 #endif
1213 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1214 configure___ c_switch_system=C_SWITCH_SYSTEM
1215 configure___ c_switch_machine=C_SWITCH_MACHINE
1217 #ifndef LIB_X11_LIB
1218 #define LIB_X11_LIB -lX11
1219 #endif
1221 #ifndef LIBX11_MACHINE
1222 #define LIBX11_MACHINE
1223 #endif
1225 #ifndef LIBX11_SYSTEM
1226 #define LIBX11_SYSTEM
1227 #endif
1228 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1230 #ifdef UNEXEC
1231 configure___ unexec=UNEXEC
1232 #else
1233 configure___ unexec=unexec.o
1234 #endif
1236 #ifdef SYSTEM_MALLOC
1237 configure___ system_malloc=yes
1238 #else
1239 configure___ system_malloc=no
1240 #endif
1242 #ifdef USE_MMAP_FOR_BUFFERS
1243 configure___ use_mmap_for_buffers=yes
1244 #else
1245 configure___ use_mmap_for_buffers=no
1246 #endif
1248 #ifndef C_DEBUG_SWITCH
1249 #define C_DEBUG_SWITCH -g
1250 #endif
1252 #ifndef C_OPTIMIZE_SWITCH
1253 #ifdef __GNUC__
1254 #define C_OPTIMIZE_SWITCH -O2
1255 #else
1256 #define C_OPTIMIZE_SWITCH -O
1257 #endif
1258 #endif
1260 #ifndef LD_SWITCH_MACHINE
1261 #define LD_SWITCH_MACHINE
1262 #endif
1264 #ifndef LD_SWITCH_SYSTEM
1265 #define LD_SWITCH_SYSTEM
1266 #endif
1268 #ifndef LD_SWITCH_X_SITE_AUX
1269 #define LD_SWITCH_X_SITE_AUX
1270 #endif
1272 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1273 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1275 #ifdef THIS_IS_CONFIGURE
1277 /* Get the CFLAGS for tests in configure. */
1278 #ifdef __GNUC__
1279 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1280 #else
1281 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1282 #endif
1284 #else /* not THIS_IS_CONFIGURE */
1286 /* Get the CFLAGS for real compilation. */
1287 #ifdef __GNUC__
1288 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1289 #else
1290 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1291 #endif
1293 #endif /* not THIS_IS_CONFIGURE */
1294 ' > ${tempcname}
1296 # The value of CPP is a quoted variable reference, so we need to do this
1297 # to get its actual value...
1298 CPP=`eval "echo $CPP"`
1299 changequote(, )dnl
1300 eval `${CPP} -Isrc ${tempcname} \
1301 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1302 if test "x$SPECIFIED_CFLAGS" = x; then
1303 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1304 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1305 else
1306 REAL_CFLAGS="$CFLAGS"
1307 fi
1308 changequote([, ])dnl
1309 rm ${tempcname}
1311 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1313 ### Make sure subsequent tests use flags consistent with the build flags.
1315 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1316 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1317 else
1318 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1319 fi
1321 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1322 AC_SYS_LARGEFILE
1324 # Sound support for GNU/Linux and the free BSDs.
1325 AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1326 # Emulation library used on NetBSD.
1327 AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1328 AC_SUBST(LIBSOUND)
1330 dnl checks for header files
1331 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1332 linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1333 termcap.h stdio_ext.h fcntl.h term.h strings.h pwd.h)
1334 AC_HEADER_STDC
1335 AC_HEADER_TIME
1336 AC_DECL_SYS_SIGLIST
1337 AC_HEADER_SYS_WAIT
1339 dnl Some systems have utime.h but don't declare the struct anyplace.
1340 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1341 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1342 #include <sys/time.h>
1343 #include <time.h>
1344 #else
1345 #ifdef HAVE_SYS_TIME_H
1346 #include <sys/time.h>
1347 #else
1348 #include <time.h>
1349 #endif
1350 #endif
1351 #ifdef HAVE_UTIME_H
1352 #include <utime.h>
1353 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1354 emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1355 if test $emacs_cv_struct_utimbuf = yes; then
1356 AC_DEFINE(HAVE_STRUCT_UTIMBUF)
1357 fi
1359 dnl checks for typedefs
1360 AC_TYPE_SIGNAL
1362 dnl Check for speed_t typedef.
1363 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1364 AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1365 emacs_cv_speed_t=yes))
1366 if test $emacs_cv_speed_t = yes; then
1367 AC_DEFINE(HAVE_SPEED_T)
1368 fi
1370 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1371 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1372 #include <sys/time.h>
1373 #include <time.h>
1374 #else
1375 #ifdef HAVE_SYS_TIME_H
1376 #include <sys/time.h>
1377 #else
1378 #include <time.h>
1379 #endif
1380 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1381 emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1382 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1383 if test $emacs_cv_struct_timeval = yes; then
1384 AC_DEFINE(HAVE_TIMEVAL)
1385 fi
1387 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1388 AC_TRY_COMPILE([#include <math.h>],
1389 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1390 emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1391 HAVE_EXCEPTION=$emacs_cv_struct_exception
1392 if test $emacs_cv_struct_exception != yes; then
1393 AC_DEFINE(NO_MATHERR)
1394 fi
1396 dnl checks for structure members
1397 AC_STRUCT_TM
1398 AC_STRUCT_TIMEZONE
1399 AC_CACHE_CHECK(for tm_gmtoff in struct tm, emacs_cv_tm_gmtoff,
1400 AC_TRY_LINK([#include <time.h>], [struct tm t; t.tm_gmtoff = 0],
1401 emacs_cv_tm_gmtoff=yes,
1402 emacs_cv_tm_gmtoff=no))
1403 if test $emacs_cv_tm_gmtoff = yes; then
1404 AC_DEFINE(HAVE_TM_GMTOFF)
1405 fi
1407 dnl checks for compiler characteristics
1409 dnl Testing __STDC__ to determine prototype support isn't good enough.
1410 dnl DEC C, for instance, doesn't define it with default options, and
1411 dnl is used on 64-bit systems (OSF Alphas). Similarly for volatile
1412 dnl and void *.
1413 AC_C_PROTOTYPES
1414 AC_C_VOLATILE
1415 AC_C_CONST
1416 dnl This isn't useful because we can't turn on use of `inline' unless
1417 dnl the compiler groks `extern inline'.
1418 dnl AC_C_INLINE
1419 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1420 [AC_TRY_COMPILE(, [void * foo;],
1421 emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1422 if test $emacs_cv_void_star = yes; then
1423 AC_DEFINE(POINTER_TYPE, void)
1424 else
1425 AC_DEFINE(POINTER_TYPE, char)
1426 fi
1428 dnl check for Make feature
1429 AC_PROG_MAKE_SET
1431 dnl checks for operating system services
1432 AC_SYS_LONG_FILE_NAMES
1434 #### Choose a window system.
1436 AC_PATH_X
1437 if test "$no_x" = yes; then
1438 window_system=none
1439 else
1440 window_system=x11
1441 fi
1443 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1444 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1445 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1446 x_default_search_path=""
1447 for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1448 x_search_path="\
1449 ${x_library}/X11/%L/%T/%N%C%S:\
1450 ${x_library}/X11/%l/%T/%N%C%S:\
1451 ${x_library}/X11/%T/%N%C%S:\
1452 ${x_library}/X11/%L/%T/%N%S:\
1453 ${x_library}/X11/%l/%T/%N%S:\
1454 ${x_library}/X11/%T/%N%S"
1455 if test x"${x_default_search_path}" = x; then
1456 x_default_search_path=${x_search_path}
1457 else
1458 x_default_search_path="${x_search_path}:${x_default_search_path}"
1459 fi
1460 done
1461 fi
1462 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1463 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1464 fi
1466 if test x"${x_includes}" = x; then
1467 bitmapdir=/usr/include/X11/bitmaps
1468 else
1469 # accumulate include directories that have X11 bitmap subdirectories
1470 bmd_acc="dummyval"
1471 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1472 if test -d "${bmd}/X11/bitmaps"; then
1473 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1474 fi
1475 if test -d "${bmd}/bitmaps"; then
1476 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1477 fi
1478 done
1479 if test ${bmd_acc} != "dummyval"; then
1480 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1481 fi
1482 fi
1484 case "${window_system}" in
1485 x11 )
1486 HAVE_X_WINDOWS=yes
1487 HAVE_X11=yes
1488 case "${with_x_toolkit}" in
1489 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1490 motif ) USE_X_TOOLKIT=MOTIF ;;
1491 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1492 no ) USE_X_TOOLKIT=none ;;
1493 dnl If user did not say whether to use a toolkit,
1494 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1495 * ) USE_X_TOOLKIT=maybe ;;
1496 esac
1497 ;;
1498 none )
1499 HAVE_X_WINDOWS=no
1500 HAVE_X11=no
1501 USE_X_TOOLKIT=none
1502 ;;
1503 esac
1505 ### If we're using X11, we should use the X menu package.
1506 HAVE_MENUS=no
1507 case ${HAVE_X11} in
1508 yes ) HAVE_MENUS=yes ;;
1509 esac
1511 if test "${opsys}" = "hpux9"; then
1512 case "${x_libraries}" in
1513 *X11R4* )
1514 opsysfile="s/hpux9-x11r4.h"
1515 ;;
1516 esac
1517 fi
1519 if test "${opsys}" = "hpux9shr"; then
1520 case "${x_libraries}" in
1521 *X11R4* )
1522 opsysfile="s/hpux9shxr4.h"
1523 ;;
1524 esac
1525 fi
1527 ### Compute the unexec source name from the object name.
1528 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1530 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1531 # Assume not, until told otherwise.
1532 GNU_MALLOC=yes
1533 doug_lea_malloc=yes
1534 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1535 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1536 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1537 emacs_cv_var___after_morecore_hook,
1538 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1539 emacs_cv_var___after_morecore_hook=yes,
1540 emacs_cv_var___after_morecore_hook=no))
1541 if test $emacs_cv_var___after_morecore_hook = no; then
1542 doug_lea_malloc=no
1543 fi
1544 if test "${system_malloc}" = "yes"; then
1545 GNU_MALLOC=no
1546 GNU_MALLOC_reason="
1547 (The GNU allocators don't work with this system configuration.)"
1548 fi
1549 if test "$doug_lea_malloc" = "yes" ; then
1550 if test "$GNU_MALLOC" = yes ; then
1551 GNU_MALLOC_reason="
1552 (Using Doug Lea's new malloc from the GNU C Library.)"
1553 fi
1554 AC_DEFINE(DOUG_LEA_MALLOC)
1555 fi
1557 if test x"${REL_ALLOC}" = x; then
1558 REL_ALLOC=${GNU_MALLOC}
1559 fi
1561 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1562 dnl the system configuration file (s/*.h) to turn the use of mmap
1563 dnl in the relocating allocator on.
1565 AC_FUNC_MMAP
1566 if test $use_mmap_for_buffers = yes; then
1567 REL_ALLOC=no
1568 fi
1570 LIBS="$libsrc_libs $LIBS"
1572 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1573 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1574 AC_CHECK_LIB(dnet, dnet_ntoa)
1575 dnl This causes -lresolv to get used in subsequent tests,
1576 dnl which causes failures on some systems such as HPUX 9.
1577 dnl AC_CHECK_LIB(resolv, gethostbyname)
1579 dnl FIXME replace main with a function we actually want from this library.
1580 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1582 AC_CHECK_LIB(pthreads, cma_open)
1584 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1585 if test -d /usr/X386/include; then
1586 HAVE_XFREE386=yes
1587 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1588 else
1589 HAVE_XFREE386=no
1590 fi
1591 AC_MSG_RESULT($HAVE_XFREE386)
1593 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1594 # for the tests that follow. We set it back to REAL_CFLAGS later on.
1596 REAL_CPPFLAGS="$CPPFLAGS"
1598 if test "${HAVE_X11}" = "yes"; then
1599 DEFS="$C_SWITCH_X_SITE $DEFS"
1600 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1601 LIBS="$LIBX $LIBS"
1602 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1603 CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1605 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1606 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1607 # but it's more convenient here to set LD_RUN_PATH
1608 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1609 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1610 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1611 export LD_RUN_PATH
1612 fi
1614 if test "${opsys}" = "gnu-linux"; then
1615 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1616 AC_TRY_LINK([],
1617 [XOpenDisplay ("foo");],
1618 [xlinux_first_failure=no],
1619 [xlinux_first_failure=yes])
1620 if test "${xlinux_first_failure}" = "yes"; then
1621 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1622 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1623 OLD_CPPFLAGS="$CPPFLAGS"
1624 OLD_LIBS="$LIBS"
1625 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1626 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1627 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1628 LIBS="$LIBS -b i486-linuxaout"
1629 AC_TRY_LINK([],
1630 [XOpenDisplay ("foo");],
1631 [xlinux_second_failure=no],
1632 [xlinux_second_failure=yes])
1633 if test "${xlinux_second_failure}" = "yes"; then
1634 # If we get the same failure with -b, there is no use adding -b.
1635 # So take it out. This plays safe.
1636 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1637 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1638 CPPFLAGS="$OLD_CPPFLAGS"
1639 LIBS="$OLD_LIBS"
1640 AC_MSG_RESULT(no)
1641 else
1642 AC_MSG_RESULT(yes)
1643 fi
1644 else
1645 AC_MSG_RESULT(no)
1646 fi
1647 fi
1649 # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1650 # header files included from there.
1651 AC_MSG_CHECKING(for Xkb)
1652 AC_TRY_LINK([#include <X11/Xlib.h>
1653 #include <X11/XKBlib.h>],
1654 [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1655 emacs_xkb=yes, emacs_xkb=no)
1656 AC_MSG_RESULT($emacs_xkb)
1657 if test $emacs_xkb = yes; then
1658 AC_DEFINE(HAVE_XKBGETKEYBOARD)
1659 fi
1661 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1662 XScreenNumberOfScreen XSetWMProtocols)
1663 fi
1665 if test "${window_system}" = "x11"; then
1666 AC_MSG_CHECKING(X11 version 6)
1667 AC_CACHE_VAL(emacs_cv_x11_version_6,
1668 AC_TRY_LINK([#include <X11/Xlib.h>],
1669 [#if XlibSpecificationRelease < 6
1670 fail;
1671 #endif
1672 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no))
1673 if test $emacs_cv_x11_version_6 = yes; then
1674 AC_MSG_RESULT(6 or newer)
1675 AC_DEFINE(HAVE_X11R6)
1676 else
1677 AC_MSG_RESULT(before 6)
1678 fi
1679 fi
1681 if test "${window_system}" = "x11"; then
1682 AC_MSG_CHECKING(X11 version 5)
1683 AC_CACHE_VAL(emacs_cv_x11_version_5,
1684 AC_TRY_LINK([#include <X11/Xlib.h>],
1685 [#if XlibSpecificationRelease < 5
1686 fail;
1687 #endif
1688 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no))
1689 if test $emacs_cv_x11_version_5 = yes; then
1690 AC_MSG_RESULT(5 or newer)
1691 HAVE_X11R5=yes
1692 AC_DEFINE(HAVE_X11R5)
1693 else
1694 HAVE_X11R5=no
1695 AC_MSG_RESULT(before 5)
1696 fi
1697 fi
1699 dnl Do not put whitespace before the #include statements below.
1700 dnl Older compilers (eg sunos4 cc) choke on it.
1701 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1702 if test x"${HAVE_X11R5}" = xyes; then
1703 AC_MSG_CHECKING(X11 version 5 with Xaw)
1704 AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
1705 AC_TRY_LINK([
1706 #include <X11/Intrinsic.h>
1707 #include <X11/Xaw/Simple.h>],
1708 [],
1709 emacs_cv_x11_version_5_with_xaw=yes,
1710 emacs_cv_x11_version_5_with_xaw=no))
1711 if test $emacs_cv_x11_version_5_with_xaw = yes; then
1712 AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
1713 USE_X_TOOLKIT=LUCID
1714 else
1715 AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
1716 USE_X_TOOLKIT=none
1717 fi
1718 else
1719 USE_X_TOOLKIT=none
1720 fi
1721 fi
1723 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1725 if test "${USE_X_TOOLKIT}" != "none"; then
1726 AC_MSG_CHECKING(X11 toolkit version)
1727 AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1728 AC_TRY_LINK([#include <X11/Intrinsic.h>],
1729 [#if XtSpecificationRelease < 6
1730 fail;
1731 #endif
1732 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no))
1733 HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1734 if test $emacs_cv_x11_toolkit_version_6 = yes; then
1735 AC_MSG_RESULT(6 or newer)
1736 AC_DEFINE(HAVE_X11XTR6)
1737 else
1738 AC_MSG_RESULT(before 6)
1739 fi
1741 dnl If using toolkit, check whether libXmu.a exists.
1742 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1743 OLDLIBS="$LIBS"
1744 if test x$HAVE_X11XTR6 = xyes; then
1745 LIBS="-lXt -lSM -lICE $LIBS"
1746 else
1747 LIBS="-lXt $LIBS"
1748 fi
1749 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1750 test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1751 fi
1753 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1754 if test "${HAVE_X11}" = "yes"; then
1755 if test "${USE_X_TOOLKIT}" != "none"; then
1756 AC_CHECK_LIB(Xext, XShapeQueryExtension)
1757 fi
1758 fi
1760 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1761 AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1762 AC_TRY_COMPILE([#include <Xm/Xm.h>],
1763 [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1764 int x = 5;
1765 #else
1766 Motif version prior to 2.1.
1767 #endif],
1768 emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no))
1769 HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1770 if test $emacs_cv_motif_version_2_1 = yes; then
1771 HAVE_LIBXP=no
1772 AC_DEFINE(HAVE_MOTIF_2_1)
1773 AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1774 if test ${HAVE_LIBXP} = yes; then
1775 AC_DEFINE(HAVE_LIBXP)
1776 fi
1777 fi
1778 fi
1780 ### Is -lXaw3d available?
1781 HAVE_XAW3D=no
1782 if test "${HAVE_X11}" = "yes"; then
1783 if test "${USE_X_TOOLKIT}" != "none"; then
1784 AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
1785 AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes))
1786 if test "${HAVE_XAW3D}" = "yes"; then
1787 AC_DEFINE(HAVE_XAW3D)
1788 fi
1789 fi
1790 fi
1792 dnl Use toolkit scroll bars if configured for X toolkit and either
1793 dnl using Motif or Xaw3d is available, and unless
1794 dnl --with-toolkit-scroll-bars=no was specified.
1796 USE_TOOLKIT_SCROLL_BARS=no
1797 if test "${with_toolkit_scroll_bars}" != "no"; then
1798 if test "${USE_X_TOOLKIT}" != "none"; then
1799 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1800 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1801 HAVE_XAW3D=no
1802 USE_TOOLKIT_SCROLL_BARS=yes
1803 elif test "${HAVE_XAW3D}" = "yes"; then
1804 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1805 USE_TOOLKIT_SCROLL_BARS=yes
1806 fi
1807 fi
1808 fi
1810 dnl Don't use X11 input methods if user specifies he doesn't want it
1811 dnl with `--with-xim=no'.
1813 if test "${with_xim}" != "no"; then
1814 AC_DEFINE(USE_XIM)
1815 fi
1817 ### Use -lXpm if available, unless `--with-xpm=no'.
1818 HAVE_XPM=no
1819 if test "${HAVE_X11}" = "yes"; then
1820 if test "${with_xpm}" != "no"; then
1821 AC_CHECK_HEADER(X11/xpm.h,
1822 AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
1823 if test "${HAVE_XPM}" = "yes"; then
1824 AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1825 AC_EGREP_CPP(no_return_alloc_pixels,
1826 [#include "X11/xpm.h"
1827 #ifndef XpmReturnAllocPixels
1828 no_return_alloc_pixels
1829 #endif
1830 ], HAVE_XPM=no, HAVE_XPM=yes)
1832 if test "${HAVE_XPM}" = "yes"; then
1833 AC_MSG_RESULT(yes)
1834 else
1835 AC_MSG_RESULT(no)
1836 fi
1837 fi
1838 fi
1840 if test "${HAVE_XPM}" = "yes"; then
1841 AC_DEFINE(HAVE_XPM)
1842 fi
1843 fi
1845 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1846 HAVE_JPEG=no
1847 if test "${HAVE_X11}" = "yes"; then
1848 if test "${with_jpeg}" != "no"; then
1849 dnl Checking for jpeglib.h can lose becsue of a redefinition of
1850 dnl HAVE_STDLIB_H.
1851 AC_CHECK_HEADER(jerror.h,
1852 AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes))
1853 fi
1855 if test "${HAVE_JPEG}" = "yes"; then
1856 AC_DEFINE(HAVE_JPEG)
1857 fi
1858 fi
1860 ### Use -lpng if available, unless `--with-png=no'.
1861 HAVE_PNG=no
1862 if test "${HAVE_X11}" = "yes"; then
1863 if test "${with_png}" != "no"; then
1864 AC_CHECK_HEADER(png.h,
1865 AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm))
1866 fi
1868 if test "${HAVE_PNG}" = "yes"; then
1869 AC_DEFINE(HAVE_PNG)
1870 fi
1871 fi
1873 ### Use -ltiff if available, unless `--with-tiff=no'.
1874 HAVE_TIFF=no
1875 if test "${HAVE_X11}" = "yes"; then
1876 if test "${with_tiff}" != "no"; then
1877 AC_CHECK_HEADER(tiffio.h,
1878 tifflibs="-lz -lm"
1879 # At least one tiff package requires the jpeg library.
1880 if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
1881 AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
1882 fi
1884 if test "${HAVE_TIFF}" = "yes"; then
1885 AC_DEFINE(HAVE_TIFF)
1886 fi
1887 fi
1889 ### Use -lgif if available, unless `--with-gif=no'.
1890 HAVE_GIF=no
1891 if test "${HAVE_X11}" = "yes"; then
1892 if test "${with_gif}" != "no"; then
1893 AC_CHECK_HEADER(gif_lib.h,
1894 AC_CHECK_LIB(ungif, DGifOpen, HAVE_GIF=yes))
1895 fi
1897 if test "${HAVE_GIF}" = "yes"; then
1898 AC_DEFINE(HAVE_GIF)
1899 fi
1900 fi
1902 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1903 AC_CACHE_CHECK(whether netdb declares h_errno,
1904 emacs_cv_netdb_declares_h_errno,
1905 AC_TRY_LINK([#include <netdb.h>],
1906 [return h_errno;],
1907 emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no))
1908 if test $emacs_cv_netdb_declares_h_errno = yes; then
1909 AC_DEFINE(HAVE_H_ERRNO)
1910 fi
1912 AC_FUNC_ALLOCA
1914 # fmod, logb, and frexp are found in -lm on most systems.
1915 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
1916 AC_CHECK_LIB(m, sqrt)
1918 # Check for mail-locking functions in a "mail" library
1919 AC_CHECK_LIB(mail, maillock)
1920 dnl Debian, at least:
1921 dnl AC_CHECK_LIB(lockfile, maillock, [AC_DEFINE(HAVE_LIBMAIL)])
1922 AC_CHECK_LIB(lockfile, maillock)
1923 # If we have the shared liblockfile, assume we must use it for mail
1924 # locking (e.g. Debian). If we couldn't link against liblockfile
1925 # (no liblockfile.a installed), ensure that we don't need to.
1926 if test "$ac_cv_lib_lockfile_maillock" = no; then
1927 dnl This works for files generally, not just executables.
1928 dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf?
1929 AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
1930 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
1931 if test $ac_cv_prog_liblockfile = yes; then
1932 AC_MSG_ERROR([Shared liblockfile found but can't link against it.
1933 This probably means that movemail could lose mail.
1934 There may be a \`development' package to install containing liblockfile.])
1935 else AC_DEFINE(LIBMAIL, -llockfile)
1936 fi
1937 else :
1938 fi
1939 AC_CHECK_FUNCS(touchlock)
1940 AC_CHECK_HEADERS(maillock.h)
1942 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
1943 rename closedir mkdir rmdir sysinfo \
1944 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
1945 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
1946 utimes setrlimit setpgid getcwd getwd shutdown strftime getaddrinfo \
1947 __fpending mblen mbrlen strsignal setitimer ualarm index rindex \
1948 gai_strerror mkstemp)
1950 AC_FUNC_MKTIME
1951 if test "$ac_cv_func_working_mktime" = no; then
1952 AC_DEFINE(BROKEN_MKTIME)
1953 fi
1955 AC_FUNC_GETLOADAVG
1957 AC_FUNC_FSEEKO
1959 # UNIX98 PTYs.
1960 AC_CHECK_FUNCS(grantpt)
1962 # PTY-related GNU extensions.
1963 AC_CHECK_FUNCS(getpt)
1965 # Check this now, so that we will NOT find the above functions in ncurses.
1966 # That is because we have not set up to link ncurses in lib-src.
1967 # It's better to believe a function is not available
1968 # than to expect to find it in ncurses.
1969 AC_CHECK_LIB(ncurses, tparm)
1971 # Do we need the Hesiod library to provide the support routines?
1972 if test "$with_hesiod" = yes ; then
1973 # Don't set $LIBS here -- see comments above.
1974 resolv=no
1975 AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
1976 [AC_CHECK_LIB(resolv, res_send, resolv=yes,
1977 [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
1978 if test "$resolv" = yes ; then
1979 RESOLVLIB=-lresolv
1980 AC_DEFINE(HAVE_LIBRESOLV)
1981 else
1982 RESOLVLIB=
1983 fi
1984 AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
1985 AC_DEFINE(HAVE_LIBHESIOD), :, $RESOLVLIB)])
1986 fi
1988 # These tell us which Kerberos-related libraries to use.
1989 if test "${with_kerberos+set}" = set; then
1990 AC_CHECK_LIB(com_err, com_err)
1991 AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
1992 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
1993 AC_CHECK_LIB(krb5, krb5_init_context)
1994 if test "${with_kerberos5+set}" != set; then
1995 AC_CHECK_LIB(des425, des_cbc_encrypt,,
1996 AC_CHECK_LIB(des, des_cbc_encrypt))
1997 AC_CHECK_LIB(krb4, krb_get_cred,,
1998 AC_CHECK_LIB(krb, krb_get_cred))
1999 fi
2001 if test "${with_kerberos5+set}" = set; then
2002 AC_CHECK_HEADERS(krb5.h)
2003 else
2004 AC_CHECK_HEADERS(des.h,,
2005 AC_CHECK_HEADERS(kerberosIV/des.h,,
2006 AC_CHECK_HEADERS(kerberos/des.h)))
2007 AC_CHECK_HEADERS(krb.h,,
2008 AC_CHECK_HEADERS(kerberosIV/krb.h,,
2009 AC_CHECK_HEADERS(kerberos/krb.h)))
2010 fi
2011 AC_CHECK_HEADERS(com_err.h)
2012 fi
2014 # Solaris requires -lintl if you want strerror (which calls dgettext)
2015 # to return localized messages.
2016 AC_CHECK_LIB(intl, dgettext)
2018 AC_MSG_CHECKING(whether localtime caches TZ)
2019 AC_CACHE_VAL(emacs_cv_localtime_cache,
2020 [if test x$ac_cv_func_tzset = xyes; then
2021 AC_TRY_RUN([#include <time.h>
2022 extern char **environ;
2023 unset_TZ ()
2024 {
2025 char **from, **to;
2026 for (to = from = environ; (*to = *from); from++)
2027 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2028 to++;
2029 }
2030 char TZ_GMT0[] = "TZ=GMT0";
2031 char TZ_PST8[] = "TZ=PST8";
2032 main()
2033 {
2034 time_t now = time ((time_t *) 0);
2035 int hour_GMT0, hour_unset;
2036 if (putenv (TZ_GMT0) != 0)
2037 exit (1);
2038 hour_GMT0 = localtime (&now)->tm_hour;
2039 unset_TZ ();
2040 hour_unset = localtime (&now)->tm_hour;
2041 if (putenv (TZ_PST8) != 0)
2042 exit (1);
2043 if (localtime (&now)->tm_hour == hour_GMT0)
2044 exit (1);
2045 unset_TZ ();
2046 if (localtime (&now)->tm_hour != hour_unset)
2047 exit (1);
2048 exit (0);
2049 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2050 [# If we have tzset, assume the worst when cross-compiling.
2051 emacs_cv_localtime_cache=yes])
2052 else
2053 # If we lack tzset, report that localtime does not cache TZ,
2054 # since we can't invalidate the cache if we don't have tzset.
2055 emacs_cv_localtime_cache=no
2056 fi])dnl
2057 AC_MSG_RESULT($emacs_cv_localtime_cache)
2058 if test $emacs_cv_localtime_cache = yes; then
2059 AC_DEFINE(LOCALTIME_CACHE)
2060 fi
2062 if test "x$HAVE_TIMEVAL" = xyes; then
2063 AC_CHECK_FUNCS(gettimeofday)
2064 AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2065 emacs_cv_gettimeofday_two_arguments,
2066 AC_TRY_COMPILE([
2067 #ifdef TIME_WITH_SYS_TIME
2068 #include <sys/time.h>
2069 #include <time.h>
2070 #else
2071 #ifdef HAVE_SYS_TIME_H
2072 #include <sys/time.h>
2073 #else
2074 #include <time.h>
2075 #endif
2076 #endif],
2077 [struct timeval time;
2078 gettimeofday (&time, 0);],
2079 emacs_cv_gettimeofday_two_arguments=yes,
2080 emacs_cv_gettimeofday_two_arguments=no))
2081 if test $emacs_cv_gettimeofday_two_arguments = no; then
2082 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)
2083 fi
2084 fi
2086 dnl Note that AC_STRUCT_TIMEZONE doesn't do what you might expect.
2087 if test "$ac_cv_func_gettimeofday" = yes; then
2088 AC_CACHE_CHECK([for struct timezone], emacs_cv_struct_timezone,
2089 [AC_TRY_COMPILE([#include <sys/time.h>],
2090 [struct timezone tz;],
2091 dnl It may be that we can't call gettimeofday with a non-null pointer,
2092 dnl even though we have struct timezone (e.g. HPUX). In that case
2093 dnl we'll lie about struct timezone.
2094 [AC_TRY_RUN([
2095 #ifdef TIME_WITH_SYS_TIME
2096 #include <sys/time.h>
2097 #include <time.h>
2098 #else
2099 #ifdef HAVE_SYS_TIME_H
2100 #include <sys/time.h>
2101 #else
2102 #include <time.h>
2103 #endif
2104 #endif
2105 main () {
2106 struct timeval time;
2107 struct timezone dummy;
2108 exit (gettimeofday (&time, &dummy));
2109 }],
2110 emacs_cv_struct_timezone=yes,
2111 emacs_cv_struct_timezone=no, emacs_cv_struct_timezone=yes)],
2112 emacs_cv_struct_timezone=no)])
2113 fi
2115 ok_so_far=yes
2116 AC_CHECK_FUNC(socket, , ok_so_far=no)
2117 if test $ok_so_far = yes; then
2118 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2119 fi
2120 if test $ok_so_far = yes; then
2121 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2122 fi
2123 if test $ok_so_far = yes; then
2124 AC_DEFINE(HAVE_INET_SOCKETS)
2125 fi
2127 if test -f /usr/lpp/X11/bin/smt.exp; then
2128 AC_DEFINE(HAVE_AIX_SMT_EXP)
2129 fi
2131 AC_MSG_CHECKING(whether system supports dynamic ptys)
2132 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2133 AC_MSG_RESULT(yes)
2134 AC_DEFINE(HAVE_DEV_PTMX)
2135 else
2136 AC_MSG_RESULT(no)
2137 fi
2139 AC_FUNC_VFORK
2141 # Fixme: This should be replaced when we have autoconf 2.14.
2142 AC_SIZE_T
2144 # Set up the CFLAGS for real compilation, so we can substitute it.
2145 CFLAGS="$REAL_CFLAGS"
2146 CPPFLAGS="$REAL_CPPFLAGS"
2148 changequote(, )dnl
2149 #### Find out which version of Emacs this is.
2150 version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
2151 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
2152 changequote([, ])dnl
2153 if test x"${version}" = x; then
2154 AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
2155 fi
2157 ### Specify what sort of things we'll be editing into Makefile and config.h.
2158 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2159 AC_SUBST(version)
2160 AC_SUBST(configuration)
2161 AC_SUBST(canonical)
2162 AC_SUBST(srcdir)
2163 AC_SUBST(prefix)
2164 AC_SUBST(exec_prefix)
2165 AC_SUBST(bindir)
2166 AC_SUBST(datadir)
2167 AC_SUBST(sharedstatedir)
2168 AC_SUBST(libexecdir)
2169 AC_SUBST(mandir)
2170 AC_SUBST(infodir)
2171 AC_SUBST(lispdir)
2172 AC_SUBST(locallisppath)
2173 AC_SUBST(lisppath)
2174 AC_SUBST(x_default_search_path)
2175 AC_SUBST(etcdir)
2176 AC_SUBST(archlibdir)
2177 AC_SUBST(docdir)
2178 AC_SUBST(bitmapdir)
2179 AC_SUBST(c_switch_system)
2180 AC_SUBST(c_switch_machine)
2181 AC_SUBST(LD_SWITCH_X_SITE)
2182 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2183 AC_SUBST(C_SWITCH_X_SITE)
2184 AC_SUBST(CFLAGS)
2185 AC_SUBST(X_TOOLKIT_TYPE)
2186 AC_SUBST(machfile)
2187 AC_SUBST(opsysfile)
2188 AC_SUBST(GETLOADAVG_LIBS)
2190 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}")
2191 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
2192 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}")
2193 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
2194 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
2195 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
2196 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE})
2197 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC})
2199 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2200 AC_DEFINE(HAVE_X_WINDOWS)
2201 fi
2202 if test "${USE_X_TOOLKIT}" != "none" ; then
2203 AC_DEFINE(USE_X_TOOLKIT)
2204 fi
2205 if test "${HAVE_X11}" = "yes" ; then
2206 AC_DEFINE(HAVE_X11)
2207 fi
2208 if test "${HAVE_XFREE386}" = "yes" ; then
2209 AC_DEFINE(HAVE_XFREE386)
2210 fi
2211 if test "${HAVE_MENUS}" = "yes" ; then
2212 AC_DEFINE(HAVE_MENUS)
2213 fi
2214 if test "${GNU_MALLOC}" = "yes" ; then
2215 AC_DEFINE(GNU_MALLOC)
2216 fi
2217 if test "${REL_ALLOC}" = "yes" ; then
2218 AC_DEFINE(REL_ALLOC)
2219 fi
2221 #### Report on what we decided to do.
2222 echo "
2223 Configured for \`${canonical}'.
2225 Where should the build process find the source code? ${srcdir}
2226 What operating system and machine description files should Emacs use?
2227 \`${opsysfile}' and \`${machfile}'
2228 What compiler should emacs be built with? ${CC} ${CFLAGS}
2229 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
2230 Should Emacs use a relocating allocator for buffers? ${REL_ALLOC}
2231 Should Emacs use mmap(2) for buffer allocation? $use_mmap_for_buffers
2232 What window system should Emacs use? ${window_system}
2233 What toolkit should Emacs use? ${USE_X_TOOLKIT}"
2235 if test -n "${x_includes}"; then
2236 echo " Where do we find X Windows header files? ${x_includes}"
2237 else
2238 echo " Where do we find X Windows header files? Standard dirs"
2239 fi
2240 if test -n "${x_libraries}"; then
2241 echo " Where do we find X Windows libraries? ${x_libraries}"
2242 else
2243 echo " Where do we find X Windows libraries? Standard dirs"
2244 fi
2246 echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}"
2247 echo " Does Emacs use -lXpm? ${HAVE_XPM}"
2248 echo " Does Emacs use -ljpeg? ${HAVE_JPEG}"
2249 echo " Does Emacs use -ltiff? ${HAVE_TIFF}"
2250 echo " Does Emacs use -lungif? ${HAVE_GIF}"
2251 echo " Does Emacs use -lpng? ${HAVE_PNG}"
2252 echo " Does Emacs use X toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}"
2253 echo
2255 # Remove any trailing slashes in these variables.
2256 changequote(, )dnl
2257 test "${prefix}" != NONE &&
2258 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2259 test "${exec_prefix}" != NONE &&
2260 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
2261 changequote([, ])dnl
2263 ## Check if the C preprocessor will convert `..' to `. .'. If so, set
2264 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2265 ## from Makefile.c can correctly provide the arg `-traditional' to the
2266 ## C preprocessor.
2268 AC_EGREP_CPP(yes..yes,
2269 [yes..yes],
2270 CPP_NEED_TRADITIONAL=no,
2271 CPP_NEED_TRADITIONAL=yes)
2273 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2274 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
2275 lisp/Makefile leim/Makefile, [
2277 ### Make the necessary directories, if they don't exist.
2278 for dir in etc lisp ; do
2279 test -d ${dir} || mkdir ${dir}
2280 done
2282 # Build src/Makefile from ${srcdir}/src/Makefile.c
2283 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2284 # This must be done after src/config.h is built, since we rely on that file.
2286 changequote(, )dnl The horror, the horror.
2287 # Now get this: Some word that is part of the ${srcdir} directory name
2288 # or the ${configuration} value might, just might, happen to be an
2289 # identifier like `sun4' or `i386' or something, and be predefined by
2290 # the C preprocessor to some helpful value like 1, or maybe the empty
2291 # string. Needless to say consequent macro substitutions are less
2292 # than conducive to the makefile finding the correct directory.
2293 undefs="`echo $top_srcdir $configuration $canonical |
2294 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
2295 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
2296 `"
2297 changequote([, ])dnl
2299 echo creating src/epaths.h
2300 ${MAKE-make} epaths-force
2302 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2303 # `..' to `. .' unless invoked with -traditional
2305 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2306 CPPFLAGS="$CPPFLAGS -traditional"
2307 fi
2309 echo creating lib-src/Makefile
2310 ( cd lib-src
2311 rm -f junk.c junk1.c junk2.c
2312 sed -e '/start of cpp stuff/q' \
2313 < Makefile.c > junk1.c
2314 sed -e '1,/start of cpp stuff/d'\
2315 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2316 < Makefile.c > junk.c
2317 $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
2318 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2319 cat junk1.c junk2.c > Makefile.new
2320 rm -f junk.c junk1.c junk2.c
2321 chmod 444 Makefile.new
2322 mv -f Makefile.new Makefile
2323 )
2325 echo creating src/Makefile
2326 ( cd src
2327 rm -f junk.c junk1.c junk2.c
2328 sed -e '/start of cpp stuff/q' \
2329 < Makefile.c > junk1.c
2330 sed -e '1,/start of cpp stuff/d'\
2331 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2332 < Makefile.c > junk.c
2333 $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
2334 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2335 cat junk1.c junk2.c > Makefile.new
2336 rm -f junk.c junk1.c junk2.c
2337 chmod 444 Makefile.new
2338 mv -f Makefile.new Makefile
2339 )
2341 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
2342 echo creating src/.gdbinit
2343 echo source $top_srcdir/src/.gdbinit > src/.gdbinit
2344 fi
2346 # This is how we know whether to re-run configure in certain cases.
2347 touch src/config.stamp
2349 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])