lisp/play/dissociate.el

   1 ;;; dissociate.el --- scramble text amusingly for Emacs
   2
   3 ;; Copyright (C) 1985, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: games
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; The single entry point, `dissociated-press', applies a travesty
  27 ;; generator to the current buffer.  The results can be quite amusing.
  28
  29 ;;; Code:
  30
  31 ;;;###autoload
  32 (defun dissociated-press (&optional arg)
  33   "Dissociate the text of the current buffer.
  34 Output goes in buffer named *Dissociation*,
  35 which is redisplayed each time text is added to it.
  36 Every so often the user must say whether to continue.
  37 If ARG is positive, require ARG chars of continuity.
  38 If ARG is negative, require -ARG words of continuity.
  39 Default is 2."
  40   (interactive "P")
  41   (setq arg (if arg (prefix-numeric-value arg) 2))
  42   (let* ((inbuf (current-buffer))
  43          (outbuf (get-buffer-create "*Dissociation*"))
  44          (move-function (if (> arg 0) 'forward-char 'forward-word))
  45          (move-amount (if (> arg 0) arg (- arg)))
  46          (search-function (if (> arg 0) 'search-forward 'word-search-forward))
  47          (last-query-point 0))
  48     (if (= (point-max) (point-min))
  49         (error "The buffer contains no text to start from"))
  50     (switch-to-buffer outbuf)
  51     (erase-buffer)
  52     (while
  53       (save-excursion
  54         (goto-char last-query-point)
  55         (vertical-motion (- (window-height) 4))
  56         (or (= (point) (point-max))
  57             (and (progn (goto-char (point-max))
  58                         (y-or-n-p "Continue dissociation? "))
  59                  (progn
  60                    (message "")
  61                    (recenter 1)
  62                    (setq last-query-point (point-max))
  63                    t))))
  64       (let (start end)
  65         (with-current-buffer inbuf
  66          (setq start (point))
  67          (if (eq move-function 'forward-char)
  68              (progn
  69                (setq end (+ start (+ move-amount (random 16))))
  70                (if (> end (point-max))
  71                    (setq end (+ 1 move-amount (random 16))))
  72                (goto-char end))
  73            (funcall move-function
  74                     (+ move-amount (random 16))))
  75          (setq end (point)))
  76         (let ((opoint (point)))
  77           (insert-buffer-substring inbuf start end)
  78           (save-excursion
  79            (goto-char opoint)
  80            (end-of-line)
  81            (and (> (current-column) fill-column)
  82                 (do-auto-fill)))))
  83       (with-current-buffer inbuf
  84        (if (eobp)
  85            (goto-char (point-min))
  86          (let ((overlap
  87                 (buffer-substring (prog1 (point)
  88                                          (funcall move-function
  89                                                   (- move-amount)))
  90                                   (point))))
  91            (goto-char (1+ (random (1- (point-max)))))
  92            (or (funcall search-function overlap nil t)
  93                (let ((opoint (point)))
  94                  (goto-char 1)
  95                  (funcall search-function overlap opoint t))))))
  96       (sit-for 0))))
  97
  98 (random t)
  99
 100 (provide 'dissociate)
 101
 102 ;; arch-tag: 90d197d1-409b-45c5-a0b5-fbfb2e06334f
 103 ;;; dissociate.el ends here