lisp/eshell/esh-ext.el

   1 ;;; esh-ext.el --- commands external to Eshell
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author: John Wiegley <johnw@gnu.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; To force a command to invoked external, either provide an explicit
  26 ;; pathname for the command argument, or prefix the command name with
  27 ;; an asterix character.  Example:
  28 ;;
  29 ;;   grep        ; make invoke `grep' Lisp function, or `eshell/grep'
  30 ;;   /bin/grep   ; will definitely invoke /bin/grep
  31 ;;   *grep        ; will also invoke /bin/grep
  32
  33 ;;; Code:
  34
  35 (provide 'esh-ext)
  36
  37 (eval-when-compile
  38   (require 'cl)
  39   (require 'esh-cmd))
  40 (require 'esh-util)
  41
  42 (defgroup eshell-ext nil
  43   "External commands are invoked when operating system executables are
  44 loaded into memory, thus beginning a new process."
  45   :tag "External commands"
  46   :group 'eshell)
  47
  48 ;;; User Variables:
  49
  50 (defcustom eshell-ext-load-hook '(eshell-ext-initialize)
  51   "*A hook that gets run when `eshell-ext' is loaded."
  52   :type 'hook
  53   :group 'eshell-ext)
  54
  55 (defcustom eshell-binary-suffixes exec-suffixes
  56   "*A list of suffixes used when searching for executable files."
  57   :type '(repeat string)
  58   :group 'eshell-ext)
  59
  60 (defcustom eshell-force-execution nil
  61   "*If non-nil, try to execute binary files regardless of permissions.
  62 This can be useful on systems like Windows, where the operating system
  63 doesn't happen to honor the permission bits in certain cases; or in
  64 cases where you want to associate an interpreter with a particular
  65 kind of script file, but the language won't let you but a '#!'
  66 interpreter line in the file, and you don't want to make it executable
  67 since nothing else but Eshell will be able to understand
  68 `eshell-interpreter-alist'."
  69   :type 'boolean
  70   :group 'eshell-ext)
  71
  72 (defun eshell-search-path (name)
  73   "Search the environment path for NAME."
  74   (if (file-name-absolute-p name)
  75       name
  76     (let ((list (parse-colon-path (getenv "PATH")))
  77           suffixes n1 n2 file)
  78       (while list
  79         (setq n1 (concat (car list) name))
  80         (setq suffixes eshell-binary-suffixes)
  81         (while suffixes
  82           (setq n2 (concat n1 (car suffixes)))
  83           (if (and (or (file-executable-p n2)
  84                        (and eshell-force-execution
  85                             (file-readable-p n2)))
  86                    (not (file-directory-p n2)))
  87               (setq file n2 suffixes nil list nil))
  88           (setq suffixes (cdr suffixes)))
  89         (setq list (cdr list)))
  90       file)))
  91
  92 (defcustom eshell-windows-shell-file
  93   (if (eshell-under-windows-p)
  94       (if (string-match "\\(\\`cmdproxy\\|sh\\)\\.\\(com\\|exe\\)"
  95                         shell-file-name)
  96           (or (eshell-search-path "cmd.exe")
  97               (eshell-search-path "command.com"))
  98         shell-file-name))
  99   "*The name of the shell command to use for DOS/Windows batch files.
 100 This defaults to nil on non-Windows systems, where this variable is
 101 wholly ignored."
 102   :type '(choice file (const nil))
 103   :group 'eshell-ext)
 104
 105 (defsubst eshell-invoke-batch-file (&rest args)
 106   "Invoke a .BAT or .CMD file on DOS/Windows systems."
 107   ;; since CMD.EXE can't handle forward slashes in the initial
 108   ;; argument...
 109   (setcar args (subst-char-in-string ?/ ?\\ (car args)))
 110   (throw 'eshell-replace-command
 111          (eshell-parse-command eshell-windows-shell-file (cons "/c" args))))
 112
 113 (defcustom eshell-interpreter-alist
 114   (if (eshell-under-windows-p)
 115       '(("\\.\\(bat\\|cmd\\)\\'" . eshell-invoke-batch-file)))
 116   "*An alist defining interpreter substitutions.
 117 Each member is a cons cell of the form:
 118
 119   (MATCH . INTERPRETER)
 120
 121 MATCH should be a regexp, which is matched against the command name,
 122 or a function.  If either returns a non-nil value, then INTERPRETER
 123 will be used for that command.
 124
 125 If INTERPRETER is a string, it will be called as the command name,
 126 with the original command name passed as the first argument, with all
 127 subsequent arguments following.  If INTERPRETER is a function, it will
 128 be called with all of those arguments.  Note that interpreter
 129 functions should throw `eshell-replace-command' with the alternate
 130 command form, or they should return a value compatible with the
 131 possible return values of `eshell-external-command', which see."
 132   :type '(repeat (cons (choice regexp (function :tag "Predicate"))
 133                        (choice string (function :tag "Interpreter"))))
 134   :group 'eshell-ext)
 135
 136 (defcustom eshell-alternate-command-hook nil
 137   "*A hook run whenever external command lookup fails.
 138 If a functions wishes to provide an alternate command, they must throw
 139 it using the tag `eshell-replace-command'.  This is done because the
 140 substituted command need not be external at all, and therefore must be
 141 passed up to a higher level for re-evaluation.
 142
 143 Or, if the function returns a filename, that filename will be invoked
 144 with the current command arguments rather than the command specified
 145 by the user on the command line."
 146   :type 'hook
 147   :group 'eshell-ext)
 148
 149 (defcustom eshell-command-interpreter-max-length 256
 150   "*The maximum length of any command interpreter string, plus args."
 151   :type 'integer
 152   :group 'eshell-ext)
 153
 154 (defcustom eshell-explicit-command-char ?*
 155   "*If this char occurs before a command name, call it externally.
 156 That is, although `vi' may be an alias, `\vi' will always call the
 157 external version."
 158   :type 'character
 159   :group 'eshell-ext)
 160
 161 ;;; Functions:
 162
 163 (defun eshell-ext-initialize ()
 164   "Initialize the external command handling code."
 165   (add-hook 'eshell-named-command-hook 'eshell-explicit-command nil t))
 166
 167 (defun eshell-explicit-command (command args)
 168   "If a command name begins with `*', call it externally always.
 169 This bypasses all Lisp functions and aliases."
 170   (when (and (> (length command) 1)
 171              (eq (aref command 0) eshell-explicit-command-char))
 172     (let ((cmd (eshell-search-path (substring command 1))))
 173       (if cmd
 174           (or (eshell-external-command cmd args)
 175               (error "%s: external command failed" cmd))
 176         (error "%s: external command not found"
 177                (substring command 1))))))
 178
 179 (defun eshell-remote-command (handler command args)
 180   "Insert output from a remote COMMAND, using ARGS.
 181 A remote command is something that executes on a different machine.
 182 An external command simply means external to Emacs.
 183
 184 Note that this function is very crude at the moment.  It gathers up
 185 all the output from the remote command, and sends it all at once,
 186 causing the user to wonder if anything's really going on..."
 187   (let ((outbuf (generate-new-buffer " *eshell remote output*"))
 188         (errbuf (generate-new-buffer " *eshell remote error*"))
 189         (exitcode 1))
 190     (unwind-protect
 191         (progn
 192           (setq exitcode
 193                 (funcall handler 'shell-command
 194                          (mapconcat 'shell-quote-argument
 195                                     (append (list command) args) " ")
 196                          outbuf errbuf))
 197           (eshell-print (with-current-buffer outbuf (buffer-string)))
 198           (eshell-error (with-current-buffer errbuf (buffer-string))))
 199       (eshell-close-handles exitcode 'nil)
 200       (kill-buffer outbuf)
 201       (kill-buffer errbuf))))
 202
 203 (defun eshell-external-command (command args)
 204   "Insert output from an external COMMAND, using ARGS."
 205   (setq args (eshell-stringify-list (eshell-flatten-list args)))
 206   (let ((handler
 207          (unless (or (equal default-directory "/")
 208                      (and (eshell-under-windows-p)
 209                           (string-match "\\`[A-Za-z]:[/\\\\]\\'"
 210                                         default-directory)))
 211            (find-file-name-handler default-directory
 212                                    'shell-command))))
 213     (if (and handler
 214              (not (and (featurep 'xemacs)
 215                        (eq handler 'dired-handler-fn))))
 216         (eshell-remote-command handler command args))
 217     (let ((interp (eshell-find-interpreter command)))
 218       (assert interp)
 219       (if (functionp (car interp))
 220           (apply (car interp) (append (cdr interp) args))
 221         (eshell-gather-process-output
 222          (car interp) (append (cdr interp) args))))))
 223
 224 (defun eshell/addpath (&rest args)
 225   "Add a set of paths to PATH."
 226   (eshell-eval-using-options
 227    "addpath" args
 228    '((?b "begin" nil prepend "add path element at beginning")
 229      (?h "help" nil nil  "display this usage message")
 230      :usage "[-b] PATH
 231 Adds the given PATH to $PATH.")
 232    (if args
 233        (progn
 234          (if prepend
 235              (setq args (nreverse args)))
 236          (while args
 237            (setenv "PATH"
 238                    (if prepend
 239                        (concat (car args) path-separator
 240                                (getenv "PATH"))
 241                      (concat (getenv "PATH") path-separator
 242                              (car args))))
 243            (setq args (cdr args))))
 244      (let ((paths (parse-colon-path (getenv "PATH"))))
 245        (while paths
 246          (eshell-printn (car paths))
 247          (setq paths (cdr paths)))))))
 248
 249 (put 'eshell/addpath 'eshell-no-numeric-conversions t)
 250
 251 (defun eshell-script-interpreter (file)
 252   "Extract the script to run from FILE, if it has #!<interp> in it.
 253 Return nil, or a list of the form:
 254
 255   (INTERPRETER [ARGS] FILE)"
 256   (let ((maxlen eshell-command-interpreter-max-length))
 257     (if (and (file-readable-p file)
 258              (file-regular-p file))
 259         (with-temp-buffer
 260           (insert-file-contents-literally file nil 0 maxlen)
 261           (if (looking-at "#![ \t]*\\([^ \r\t\n]+\\)\\([ \t]+\\(.+\\)\\)?")
 262               (if (match-string 3)
 263                   (list (match-string 1)
 264                         (match-string 3)
 265                         file)
 266                 (list (match-string 1)
 267                       file)))))))
 268
 269 (defun eshell-find-interpreter (file &optional no-examine-p)
 270   "Find the command interpreter with which to execute FILE.
 271 If NO-EXAMINE-P is non-nil, FILE will not be inspected for a script
 272 line of the form #!<interp>."
 273   (let ((finterp
 274          (catch 'found
 275            (ignore
 276             (eshell-for possible eshell-interpreter-alist
 277               (cond
 278                ((functionp (car possible))
 279                 (and (funcall (car possible) file)
 280                      (throw 'found (cdr possible))))
 281                ((stringp (car possible))
 282                 (and (string-match (car possible) file)
 283                      (throw 'found (cdr possible))))
 284                (t
 285                 (error "Invalid interpreter-alist test"))))))))
 286     (if finterp                         ; first check
 287         (list finterp file)
 288       (let ((fullname (if (file-name-directory file) file
 289                         (eshell-search-path file)))
 290             (suffixes eshell-binary-suffixes))
 291         (if (and fullname (not (or eshell-force-execution
 292                                    (file-executable-p fullname))))
 293             (while suffixes
 294               (let ((try (concat fullname (car suffixes))))
 295                 (if (or (file-executable-p try)
 296                         (and eshell-force-execution
 297                              (file-readable-p try)))
 298                     (setq fullname try suffixes nil)
 299                   (setq suffixes (cdr suffixes))))))
 300         (cond ((not (and fullname (file-exists-p fullname)))
 301                (let ((name (or fullname file)))
 302                  (unless (setq fullname
 303                                (run-hook-with-args-until-success
 304                                 'eshell-alternate-command-hook file))
 305                    (error "%s: command not found" name))))
 306               ((not (or eshell-force-execution
 307                         (file-executable-p fullname)))
 308                (error "%s: Permission denied" fullname)))
 309         (let (interp)
 310           (unless no-examine-p
 311             (setq interp (eshell-script-interpreter fullname))
 312             (if interp
 313                 (setq interp
 314                       (cons (car (eshell-find-interpreter (car interp) t))
 315                             (cdr interp)))))
 316           (or interp (list fullname)))))))
 317
 318 ;; arch-tag: 178d4064-7e60-4745-b81f-bab5d8d7c40f
 319 ;;; esh-ext.el ends here