lisp/vc-cvs.el

   1 ;;; vc-cvs.el --- non-resident support for CVS version-control
   2
   3 ;; Copyright (C) 1995, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author:      FSF (see vc.el for full credits)
   7 ;; Maintainer:  Andre Spiegel <spiegel@gnu.org>
   8
   9 ;; $Id$
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;;; Code:
  31
  32 (eval-when-compile (require 'cl) (require 'vc))
  33
  34 ;; Clear up the cache to force vc-call to check again and discover
  35 ;; new functions when we reload this file.
  36 (put 'CVS 'vc-functions nil)
  37
  38 ;;;
  39 ;;; Customization options
  40 ;;;
  41
  42 (defcustom vc-cvs-global-switches nil
  43   "*Global switches to pass to any CVS command."
  44   :type '(choice (const :tag "None" nil)
  45                  (string :tag "Argument String")
  46                  (repeat :tag "Argument List"
  47                          :value ("")
  48                          string))
  49   :version "22.1"
  50   :group 'vc)
  51
  52 (defcustom vc-cvs-register-switches nil
  53   "*Extra switches for registering a file into CVS.
  54 A string or list of strings passed to the checkin program by
  55 \\[vc-register]."
  56   :type '(choice (const :tag "None" nil)
  57                  (string :tag "Argument String")
  58                  (repeat :tag "Argument List"
  59                          :value ("")
  60                          string))
  61   :version "21.1"
  62   :group 'vc)
  63
  64 (defcustom vc-cvs-diff-switches nil
  65   "*A string or list of strings specifying extra switches for cvs diff under VC."
  66     :type '(choice (const :tag "None" nil)
  67                  (string :tag "Argument String")
  68                  (repeat :tag "Argument List"
  69                          :value ("")
  70                          string))
  71   :version "21.1"
  72   :group 'vc)
  73
  74 (defcustom vc-cvs-header (or (cdr (assoc 'CVS vc-header-alist)) '("\$Id\$"))
  75   "*Header keywords to be inserted by `vc-insert-headers'."
  76   :version "21.1"
  77   :type '(repeat string)
  78   :group 'vc)
  79
  80 (defcustom vc-cvs-use-edit t
  81   "*Non-nil means to use `cvs edit' to \"check out\" a file.
  82 This is only meaningful if you don't use the implicit checkout model
  83 \(i.e. if you have $CVSREAD set)."
  84   :type 'boolean
  85   :version "21.1"
  86   :group 'vc)
  87
  88 (defcustom vc-cvs-stay-local t
  89   "*Non-nil means use local operations when possible for remote repositories.
  90 This avoids slow queries over the network and instead uses heuristics
  91 and past information to determine the current status of a file.
  92
  93 The value can also be a regular expression or list of regular
  94 expressions to match against the host name of a repository; then VC
  95 only stays local for hosts that match it.  Alternatively, the value
  96 can be a list of regular expressions where the first element is the
  97 symbol `except'; then VC always stays local except for hosts matched
  98 by these regular expressions."
  99   :type '(choice (const :tag "Always stay local" t)
 100                 (const :tag "Don't stay local" nil)
 101                  (list :format "\nExamine hostname and %v" :tag "Examine hostname ..."
 102                        (set :format "%v" :inline t (const :format "%t" :tag "don't" except))
 103                        (regexp :format " stay local,\n%t: %v" :tag "if it matches")
 104                        (repeat :format "%v%i\n" :inline t (regexp :tag "or"))))
 105   :version "21.1"
 106   :group 'vc)
 107
 108 (defcustom vc-cvs-sticky-date-format-string "%c"
 109   "*Format string for mode-line display of sticky date.
 110 Format is according to `format-time-string'.  Only used if
 111 `vc-cvs-sticky-tag-display' is t."
 112   :type '(string)
 113   :version "22.1"
 114   :group 'vc)
 115
 116 (defcustom vc-cvs-sticky-tag-display t
 117   "*Specify the mode-line display of sticky tags.
 118 Value t means default display, nil means no display at all.  If the
 119 value is a function or macro, it is called with the sticky tag and
 120 its' type as parameters, in that order.  TYPE can have three different
 121 values: `symbolic-name' (TAG is a string), `revision-number' (TAG is a
 122 string) and `date' (TAG is a date as returned by `encode-time').  The
 123 return value of the function or macro will be displayed as a string.
 124
 125 Here's an example that will display the formatted date for sticky
 126 dates and the word \"Sticky\" for sticky tag names and revisions.
 127
 128   (lambda (tag type)
 129     (cond ((eq type 'date) (format-time-string
 130                               vc-cvs-sticky-date-format-string tag))
 131           ((eq type 'revision-number) \"Sticky\")
 132           ((eq type 'symbolic-name) \"Sticky\")))
 133
 134 Here's an example that will abbreviate to the first character only,
 135 any text before the first occurrence of `-' for sticky symbolic tags.
 136 If the sticky tag is a revision number, the word \"Sticky\" is
 137 displayed.  Date and time is displayed for sticky dates.
 138
 139    (lambda (tag type)
 140      (cond ((eq type 'date) (format-time-string \"%Y%m%d %H:%M\" tag))
 141            ((eq type 'revision-number) \"Sticky\")
 142            ((eq type 'symbolic-name)
 143             (condition-case nil
 144                 (progn
 145                   (string-match \"\\\\([^-]*\\\\)\\\\(.*\\\\)\" tag)
 146                   (concat (substring (match-string 1 tag) 0 1) \":\"
 147                           (substring (match-string 2 tag) 1 nil)))
 148               (error tag)))))       ; Fall-back to given tag name.
 149
 150 See also variable `vc-cvs-sticky-date-format-string'."
 151   :type '(choice boolean function)
 152   :version "22.1"
 153   :group 'vc)
 154
 155 ;;;
 156 ;;; Internal variables
 157 ;;;
 158
 159
 160 ;;;
 161 ;;; State-querying functions
 162 ;;;
 163
 164 ;;;###autoload (defun vc-cvs-registered (f)
 165 ;;;###autoload   (when (file-readable-p (expand-file-name
 166 ;;;###autoload                    "CVS/Entries" (file-name-directory f)))
 167 ;;;###autoload       (load "vc-cvs")
 168 ;;;###autoload       (vc-cvs-registered f)))
 169
 170 (defun vc-cvs-registered (file)
 171   "Check if FILE is CVS registered."
 172   (let ((dirname (or (file-name-directory file) ""))
 173         (basename (file-name-nondirectory file))
 174         ;; make sure that the file name is searched case-sensitively
 175         (case-fold-search nil))
 176     (if (file-readable-p (expand-file-name "CVS/Entries" dirname))
 177         (with-temp-buffer
 178           (vc-cvs-get-entries dirname)
 179           (goto-char (point-min))
 180           (cond
 181            ((re-search-forward
 182              ;; CVS-removed files are not taken under VC control.
 183              (concat "^/" (regexp-quote basename) "/[^/-]") nil t)
 184             (beginning-of-line)
 185             (vc-cvs-parse-entry file)
 186             t)
 187            (t nil)))
 188       nil)))
 189
 190 (defun vc-cvs-state (file)
 191   "CVS-specific version of `vc-state'."
 192   (if (vc-stay-local-p file)
 193       (let ((state (vc-file-getprop file 'vc-state)))
 194         ;; If we should stay local, use the heuristic but only if
 195         ;; we don't have a more precise state already available.
 196         (if (memq state '(up-to-date edited nil))
 197             (vc-cvs-state-heuristic file)
 198           state))
 199     (with-temp-buffer
 200       (cd (file-name-directory file))
 201       (vc-cvs-command t 0 file "status")
 202       (vc-cvs-parse-status t))))
 203
 204 (defun vc-cvs-state-heuristic (file)
 205   "CVS-specific state heuristic."
 206   ;; If the file has not changed since checkout, consider it `up-to-date'.
 207   ;; Otherwise consider it `edited'.
 208   (let ((checkout-time (vc-file-getprop file 'vc-checkout-time))
 209         (lastmod (nth 5 (file-attributes file))))
 210     (if (equal checkout-time lastmod)
 211         'up-to-date
 212       'edited)))
 213
 214 (defun vc-cvs-dir-state (dir)
 215   "Find the CVS state of all files in DIR."
 216   ;; if DIR is not under CVS control, don't do anything.
 217   (when (file-readable-p (expand-file-name "CVS/Entries" dir))
 218     (if (vc-stay-local-p dir)
 219         (vc-cvs-dir-state-heuristic dir)
 220       (let ((default-directory dir))
 221         ;; Don't specify DIR in this command, the default-directory is
 222         ;; enough.  Otherwise it might fail with remote repositories.
 223         (with-temp-buffer
 224           (vc-cvs-command t 0 nil "status" "-l")
 225           (goto-char (point-min))
 226           (while (re-search-forward "^=+\n\\([^=\n].*\n\\|\n\\)+" nil t)
 227             (narrow-to-region (match-beginning 0) (match-end 0))
 228             (vc-cvs-parse-status)
 229             (goto-char (point-max))
 230             (widen)))))))
 231
 232 (defun vc-cvs-workfile-version (file)
 233   "CVS-specific version of `vc-workfile-version'."
 234   ;; There is no need to consult RCS headers under CVS, because we
 235   ;; get the workfile version for free when we recognize that a file
 236   ;; is registered in CVS.
 237   (vc-cvs-registered file)
 238   (vc-file-getprop file 'vc-workfile-version))
 239
 240 (defun vc-cvs-checkout-model (file)
 241   "CVS-specific version of `vc-checkout-model'."
 242   (if (getenv "CVSREAD")
 243       'announce
 244     (let ((attrib (file-attributes file)))
 245       (if (and attrib ;; don't check further if FILE doesn't exist
 246                ;; If the file is not writable (despite CVSREAD being
 247                ;; undefined), this is probably because the file is being
 248                ;; "watched" by other developers.
 249                ;; (If vc-mistrust-permissions was t, we actually shouldn't
 250                ;; trust this, but there is no other way to learn this from CVS
 251                ;; at the moment (version 1.9).)
 252                (string-match "r-..-..-." (nth 8 attrib)))
 253           'announce
 254         'implicit))))
 255
 256 (defun vc-cvs-mode-line-string (file)
 257   "Return string for placement into the modeline for FILE.
 258 Compared to the default implementation, this function does two things:
 259 Handle the special case of a CVS file that is added but not yet
 260 committed and support display of sticky tags."
 261   (let ((sticky-tag (vc-file-getprop file 'vc-cvs-sticky-tag))
 262         (string (if (string= (vc-workfile-version file) "0")
 263                     ;; A file that is added but not yet committed.
 264                     "CVS @@"
 265                   (vc-default-mode-line-string 'CVS file))))
 266     (if (zerop (length sticky-tag))
 267         string
 268       (concat string "[" sticky-tag "]"))))
 269
 270 (defun vc-cvs-dired-state-info (file)
 271   "CVS-specific version of `vc-dired-state-info'."
 272   (let ((cvs-state (vc-state file)))
 273     (cond ((eq cvs-state 'edited)
 274            (if (equal (vc-workfile-version file) "0")
 275                "(added)" "(modified)"))
 276           ((eq cvs-state 'needs-patch) "(patch)")
 277           ((eq cvs-state 'needs-merge) "(merge)"))))
 278
 279
 280 ;;;
 281 ;;; State-changing functions
 282 ;;;
 283
 284 (defun vc-cvs-create-repo ()
 285   "Create a new CVS repository."
 286   (error "Creation of CVS repositories is not supported."))
 287
 288 (defun vc-cvs-register (files &optional rev comment)
 289   "Register FILES into the CVS version-control system.
 290 COMMENT can be used to provide an initial description of FILES.
 291
 292 `vc-register-switches' and `vc-cvs-register-switches' are passed to
 293 the CVS command (in that order)."
 294   (when (and (not (vc-cvs-responsible-p file))
 295                (vc-cvs-could-register file))
 296       ;; Register the directory if needed.
 297       (vc-cvs-register (directory-file-name (file-name-directory file))))
 298     (apply 'vc-cvs-command nil 0 files
 299            "add"
 300            (and comment (string-match "[^\t\n ]" comment)
 301                 (concat "-m" comment))
 302            (vc-switches 'CVS 'register)))
 303
 304 (defun vc-cvs-responsible-p (file)
 305   "Return non-nil if CVS thinks it is responsible for FILE."
 306   (file-directory-p (expand-file-name "CVS"
 307                                       (if (file-directory-p file)
 308                                           file
 309                                         (file-name-directory file)))))
 310
 311 (defun vc-cvs-could-register (file)
 312   "Return non-nil if FILE could be registered in CVS.
 313 This is only possible if CVS is managing FILE's directory or one of
 314 its parents."
 315   (let ((dir file))
 316     (while (and (stringp dir)
 317                 (not (equal dir (setq dir (file-name-directory dir))))
 318                 dir)
 319       (setq dir (if (file-directory-p
 320                      (expand-file-name "CVS/Entries" dir))
 321                     t (directory-file-name dir))))
 322     (eq dir t)))
 323
 324 (defun vc-cvs-checkin (files rev comment)
 325   "CVS-specific version of `vc-backend-checkin'."
 326   (unless (or (not rev) (vc-cvs-valid-version-number-p rev))
 327     (if (not (vc-cvs-valid-symbolic-tag-name-p rev))
 328         (error "%s is not a valid symbolic tag name" rev)
 329       ;; If the input revison is a valid symbolic tag name, we create it
 330       ;; as a branch, commit and switch to it.
 331       (apply 'vc-cvs-command nil 0 files "tag" "-b" (list rev))
 332       (apply 'vc-cvs-command nil 0 files "update" "-r" (list rev))
 333       (vc-file-setprop file 'vc-cvs-sticky-tag rev)))
 334   (let ((status (apply 'vc-cvs-command nil 1 file
 335                        "ci" (if rev (concat "-r" rev))
 336                        (concat "-m" comment)
 337                        (vc-switches 'CVS 'checkin))))
 338     (set-buffer "*vc*")
 339     (goto-char (point-min))
 340     (when (not (zerop status))
 341       ;; Check checkin problem.
 342       (cond
 343        ((re-search-forward "Up-to-date check failed" nil t)
 344         (vc-file-setprop file 'vc-state 'needs-merge)
 345         (error (substitute-command-keys
 346                 (concat "Up-to-date check failed: "
 347                         "type \\[vc-next-action] to merge in changes"))))
 348        (t
 349         (pop-to-buffer (current-buffer))
 350         (goto-char (point-min))
 351         (shrink-window-if-larger-than-buffer)
 352         (error "Check-in failed"))))
 353     ;; Single-file commit?  Then update the version by parsing the buffer.
 354     ;; Otherwise we can't necessarily tell what goes with what; clear
 355     ;; its properties so they have to be refetched.
 356     (if (= (length files) 1)
 357         (vc-file-setprop
 358          (car files) 'vc-workfile-version
 359          (vc-parse-buffer "^\\(new\\|initial\\) revision: \\([0-9.]+\\)" 2))
 360       (mapc (lambda (file) (vc-file-clearprops file)) files))
 361     ;; Anyway, forget the checkout model of the file, because we might have
 362     ;; guessed wrong when we found the file.  After commit, we can
 363     ;; tell it from the permissions of the file (see
 364     ;; vc-cvs-checkout-model).
 365     (mapc (lambda (file) (vc-file-setprop file 'vc-checkout-model nil))
 366           files)
 367
 368     ;; if this was an explicit check-in (does not include creation of
 369     ;; a branch), remove the sticky tag.
 370     (if (and rev (not (vc-cvs-valid-symbolic-tag-name-p rev)))
 371         (vc-cvs-command nil 0 files "update" "-A"))))
 372
 373 (defun vc-cvs-find-version (file rev buffer)
 374   (apply 'vc-cvs-command
 375          buffer 0 file
 376          "-Q"                           ; suppress diagnostic output
 377          "update"
 378          (and rev (not (string= rev ""))
 379               (concat "-r" rev))
 380          "-p"
 381          (vc-switches 'CVS 'checkout)))
 382
 383 (defun vc-cvs-checkout (file &optional editable rev)
 384   "Checkout a revision of FILE into the working area.
 385 EDITABLE non-nil means that the file should be writable.
 386 REV is the revision to check out."
 387   (message "Checking out %s..." file)
 388   ;; Change buffers to get local value of vc-checkout-switches.
 389   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 390     (if (and (file-exists-p file) (not rev))
 391         ;; If no revision was specified, just make the file writable
 392         ;; if necessary (using `cvs-edit' if requested).
 393         (and editable (not (eq (vc-cvs-checkout-model file) 'implicit))
 394              (if vc-cvs-use-edit
 395                  (vc-cvs-command nil 0 file "edit")
 396                (set-file-modes file (logior (file-modes file) 128))
 397                (if (equal file buffer-file-name) (toggle-read-only -1))))
 398       ;; Check out a particular version (or recreate the file).
 399       (vc-file-setprop file 'vc-workfile-version nil)
 400       (apply 'vc-cvs-command nil 0 file
 401              (and editable "-w")
 402              "update"
 403              (when rev
 404                (unless (eq rev t)
 405                  ;; default for verbose checkout: clear the
 406                  ;; sticky tag so that the actual update will
 407                  ;; get the head of the trunk
 408                  (if (string= rev "")
 409                      "-A"
 410                    (concat "-r" rev))))
 411              (vc-switches 'CVS 'checkout)))
 412     (vc-mode-line file))
 413   (message "Checking out %s...done" file))
 414
 415 (defun vc-cvs-delete-file (file)
 416   (vc-cvs-command nil 0 file "remove" "-f")
 417   (vc-cvs-command nil 0 file "commit" "-mRemoved."))
 418
 419 (defun vc-cvs-revert (file &optional contents-done)
 420   "Revert FILE to the version on which it was based."
 421   (vc-default-revert 'CVS file contents-done)
 422   (unless (eq (vc-checkout-model file) 'implicit)
 423     (if vc-cvs-use-edit
 424         (vc-cvs-command nil 0 file "unedit")
 425       ;; Make the file read-only by switching off all w-bits
 426       (set-file-modes file (logand (file-modes file) 3950)))))
 427
 428 (defun vc-cvs-merge (file first-version &optional second-version)
 429   "Merge changes into current working copy of FILE.
 430 The changes are between FIRST-VERSION and SECOND-VERSION."
 431   (vc-cvs-command nil 0 file
 432                  "update" "-kk"
 433                  (concat "-j" first-version)
 434                  (concat "-j" second-version))
 435   (vc-file-setprop file 'vc-state 'edited)
 436   (with-current-buffer (get-buffer "*vc*")
 437     (goto-char (point-min))
 438     (if (re-search-forward "conflicts during merge" nil t)
 439         1                               ; signal error
 440       0)))                              ; signal success
 441
 442 (defun vc-cvs-merge-news (file)
 443   "Merge in any new changes made to FILE."
 444   (message "Merging changes into %s..." file)
 445   ;; (vc-file-setprop file 'vc-workfile-version nil)
 446   (vc-file-setprop file 'vc-checkout-time 0)
 447   (vc-cvs-command nil 0 file "update")
 448   ;; Analyze the merge result reported by CVS, and set
 449   ;; file properties accordingly.
 450   (with-current-buffer (get-buffer "*vc*")
 451     (goto-char (point-min))
 452     ;; get new workfile version
 453     (if (re-search-forward
 454          "^Merging differences between [0-9.]* and \\([0-9.]*\\) into" nil t)
 455         (vc-file-setprop file 'vc-workfile-version (match-string 1))
 456       (vc-file-setprop file 'vc-workfile-version nil))
 457     ;; get file status
 458     (prog1
 459         (if (eq (buffer-size) 0)
 460             0 ;; there were no news; indicate success
 461           (if (re-search-forward
 462                (concat "^\\([CMUP] \\)?"
 463                        (regexp-quote (file-name-nondirectory file))
 464                        "\\( already contains the differences between \\)?")
 465                nil t)
 466               (cond
 467                ;; Merge successful, we are in sync with repository now
 468                ((or (match-string 2)
 469                     (string= (match-string 1) "U ")
 470                     (string= (match-string 1) "P "))
 471                 (vc-file-setprop file 'vc-state 'up-to-date)
 472                 (vc-file-setprop file 'vc-checkout-time
 473                                  (nth 5 (file-attributes file)))
 474                 0);; indicate success to the caller
 475                ;; Merge successful, but our own changes are still in the file
 476                ((string= (match-string 1) "M ")
 477                 (vc-file-setprop file 'vc-state 'edited)
 478                 0);; indicate success to the caller
 479                ;; Conflicts detected!
 480                (t
 481                 (vc-file-setprop file 'vc-state 'edited)
 482                 1);; signal the error to the caller
 483                )
 484             (pop-to-buffer "*vc*")
 485             (error "Couldn't analyze cvs update result")))
 486       (message "Merging changes into %s...done" file))))
 487
 488
 489 ;;;
 490 ;;; History functions
 491 ;;;
 492
 493 (defun vc-cvs-print-log (files &optional buffer)
 494   "Get change log associated with FILE."
 495   (vc-cvs-command
 496    buffer
 497    (if (and (vc-stay-local-p files) (fboundp 'start-process)) 'async 0)
 498    files "log"))
 499
 500 (defun vc-cvs-wash-log ()
 501   "Remove all non-comment information from log output."
 502   (vc-call-backend 'RCS 'wash-log)
 503   nil)
 504
 505 (defun vc-cvs-diff (files &optional oldvers newvers buffer)
 506   "Get a difference report using CVS between two versions of FILE."
 507     (let* ((async (and (not vc-disable-async-diff)
 508                        (vc-stay-local-p files)
 509                        (fboundp 'start-process)))
 510            (status (apply 'vc-cvs-command (or buffer "*vc-diff*")
 511                           (if async 'async 1)
 512                           file "diff"
 513                           (and oldvers (concat "-r" oldvers))
 514                           (and newvers (concat "-r" newvers))
 515                           (vc-switches 'CVS 'diff))))
 516       (if async 1 status)))             ; async diff, pessimistic assumption
 517
 518 (defun vc-cvs-diff-tree (dir &optional rev1 rev2)
 519   "Diff all files at and below DIR."
 520   (with-current-buffer "*vc-diff*"
 521     (setq default-directory dir)
 522     (if (vc-stay-local-p dir)
 523         ;; local diff: do it filewise, and only for files that are modified
 524         (vc-file-tree-walk
 525          dir
 526          (lambda (f)
 527            (vc-exec-after
 528             `(let ((coding-system-for-read (vc-coding-system-for-diff ',f)))
 529                ;; possible optimization: fetch the state of all files
 530                ;; in the tree via vc-cvs-dir-state-heuristic
 531                (unless (vc-up-to-date-p ',f)
 532                  (message "Looking at %s" ',f)
 533                  (vc-diff-internal ',f ',rev1 ',rev2))))))
 534       ;; cvs diff: use a single call for the entire tree
 535       (let ((coding-system-for-read
 536              (or coding-system-for-read 'undecided)))
 537         (apply 'vc-cvs-command "*vc-diff*" 1 nil "diff"
 538                (and rev1 (concat "-r" rev1))
 539                (and rev2 (concat "-r" rev2))
 540                (vc-switches 'CVS 'diff))))))
 541
 542 (defconst vc-cvs-annotate-first-line-re "^[0-9]")
 543
 544 (defun vc-cvs-annotate-process-filter (process string)
 545   (setq string (concat (process-get process 'output) string))
 546   (if (not (string-match vc-cvs-annotate-first-line-re string))
 547       ;; Still waiting for the first real line.
 548       (process-put process 'output string)
 549     (let ((vc-filter (process-get process 'vc-filter)))
 550       (set-process-filter process vc-filter)
 551       (funcall vc-filter process (substring string (match-beginning 0))))))
 552
 553 (defun vc-cvs-annotate-command (file buffer &optional version)
 554   "Execute \"cvs annotate\" on FILE, inserting the contents in BUFFER.
 555 Optional arg VERSION is a version to annotate from."
 556   (vc-cvs-command buffer
 557                   (if (and (vc-stay-local-p file) (fboundp 'start-process))
 558                       'async 0)
 559                   file "annotate"
 560                   (if version (concat "-r" version)))
 561   ;; Strip the leading few lines.
 562   (let ((proc (get-buffer-process buffer)))
 563     (if proc
 564         ;; If running asynchronously, use a process filter.
 565         (progn
 566           (process-put proc 'vc-filter (process-filter proc))
 567           (set-process-filter proc 'vc-cvs-annotate-process-filter))
 568       (with-current-buffer buffer
 569         (goto-char (point-min))
 570         (re-search-forward vc-cvs-annotate-first-line-re)
 571         (delete-region (point-min) (1- (point)))))))
 572
 573 (defun vc-cvs-annotate-current-time ()
 574   "Return the current time, based at midnight of the current day, and
 575 encoded as fractional days."
 576   (vc-annotate-convert-time
 577    (apply 'encode-time 0 0 0 (nthcdr 3 (decode-time (current-time))))))
 578
 579 (defun vc-cvs-annotate-time ()
 580   "Return the time of the next annotation (as fraction of days)
 581 systime, or nil if there is none."
 582   (let* ((bol (point))
 583          (cache (get-text-property bol 'vc-cvs-annotate-time))
 584          buffer-read-only)
 585     (cond
 586      (cache)
 587      ((looking-at
 588        "^\\S-+\\s-+\\S-+\\s-+\\([0-9]+\\)-\\(\\sw+\\)-\\([0-9]+\\)): ")
 589       (let ((day (string-to-number (match-string 1)))
 590             (month (cdr (assq (intern (match-string 2))
 591                               '((Jan .  1) (Feb .  2) (Mar .  3)
 592                                 (Apr .  4) (May .  5) (Jun .  6)
 593                                 (Jul .  7) (Aug .  8) (Sep .  9)
 594                                 (Oct . 10) (Nov . 11) (Dec . 12)))))
 595             (year (let ((tmp (string-to-number (match-string 3))))
 596                     ;; Years 0..68 are 2000..2068.
 597                     ;; Years 69..99 are 1969..1999.
 598                     (+ (cond ((> 69 tmp) 2000)
 599                              ((> 100 tmp) 1900)
 600                              (t 0))
 601                        tmp))))
 602         (put-text-property
 603          bol (1+ bol) 'vc-cvs-annotate-time
 604          (setq cache (cons
 605                       ;; Position at end makes for nicer overlay result.
 606                       (match-end 0)
 607                       (vc-annotate-convert-time
 608                        (encode-time 0 0 0 day month year))))))))
 609     (when cache
 610       (goto-char (car cache))           ; fontify from here to eol
 611       (cdr cache))))                    ; days (float)
 612
 613 (defun vc-cvs-annotate-extract-revision-at-line ()
 614   (save-excursion
 615     (beginning-of-line)
 616     (if (re-search-forward "^\\([0-9]+\\.[0-9]+\\(\\.[0-9]+\\)*\\) +("
 617                            (line-end-position) t)
 618         (match-string-no-properties 1)
 619       nil)))
 620
 621 ;;;
 622 ;;; Snapshot system
 623 ;;;
 624
 625 (defun vc-cvs-create-snapshot (dir name branchp)
 626   "Assign to DIR's current version a given NAME.
 627 If BRANCHP is non-nil, the name is created as a branch (and the current
 628 workspace is immediately moved to that new branch)."
 629   (vc-cvs-command nil 0 dir "tag" "-c" (if branchp "-b") name)
 630   (when branchp (vc-cvs-command nil 0 dir "update" "-r" name)))
 631
 632 (defun vc-cvs-retrieve-snapshot (dir name update)
 633   "Retrieve a snapshot at and below DIR.
 634 NAME is the name of the snapshot; if it is empty, do a `cvs update'.
 635 If UPDATE is non-nil, then update (resynch) any affected buffers."
 636   (with-current-buffer (get-buffer-create "*vc*")
 637     (let ((default-directory dir)
 638           (sticky-tag))
 639       (erase-buffer)
 640       (if (or (not name) (string= name ""))
 641           (vc-cvs-command t 0 nil "update")
 642         (vc-cvs-command t 0 nil "update" "-r" name)
 643         (setq sticky-tag name))
 644       (when update
 645         (goto-char (point-min))
 646         (while (not (eobp))
 647           (if (looking-at "\\([CMUP]\\) \\(.*\\)")
 648               (let* ((file (expand-file-name (match-string 2) dir))
 649                      (state (match-string 1))
 650                      (buffer (find-buffer-visiting file)))
 651                 (when buffer
 652                   (cond
 653                    ((or (string= state "U")
 654                         (string= state "P"))
 655                     (vc-file-setprop file 'vc-state 'up-to-date)
 656                     (vc-file-setprop file 'vc-workfile-version nil)
 657                     (vc-file-setprop file 'vc-checkout-time
 658                                      (nth 5 (file-attributes file))))
 659                    ((or (string= state "M")
 660                         (string= state "C"))
 661                     (vc-file-setprop file 'vc-state 'edited)
 662                     (vc-file-setprop file 'vc-workfile-version nil)
 663                     (vc-file-setprop file 'vc-checkout-time 0)))
 664                   (vc-file-setprop file 'vc-cvs-sticky-tag sticky-tag)
 665                   (vc-resynch-buffer file t t))))
 666           (forward-line 1))))))
 667
 668
 669 ;;;
 670 ;;; Miscellaneous
 671 ;;;
 672
 673 (defalias 'vc-cvs-make-version-backups-p 'vc-stay-local-p
 674   "Return non-nil if version backups should be made for FILE.")
 675
 676 (defun vc-cvs-check-headers ()
 677   "Check if the current file has any headers in it."
 678   (save-excursion
 679     (goto-char (point-min))
 680     (re-search-forward "\\$[A-Za-z\300-\326\330-\366\370-\377]+\
 681 \\(: [\t -#%-\176\240-\377]*\\)?\\$" nil t)))
 682
 683
 684 ;;;
 685 ;;; Internal functions
 686 ;;;
 687
 688 (defun vc-cvs-command (buffer okstatus files &rest flags)
 689   "A wrapper around `vc-do-command' for use in vc-cvs.el.
 690 The difference to vc-do-command is that this function always invokes `cvs',
 691 and that it passes `vc-cvs-global-switches' to it before FLAGS."
 692   (apply 'vc-do-command buffer okstatus "cvs" files
 693          (if (stringp vc-cvs-global-switches)
 694              (cons vc-cvs-global-switches flags)
 695            (append vc-cvs-global-switches
 696                    flags))))
 697
 698 (defalias 'vc-cvs-stay-local-p 'vc-stay-local-p)  ;Back-compatibility.
 699
 700 (defun vc-cvs-repository-hostname (dirname)
 701   "Hostname of the CVS server associated to workarea DIRNAME."
 702   (let ((rootname (expand-file-name "CVS/Root" dirname)))
 703     (when (file-readable-p rootname)
 704       (with-temp-buffer
 705         (let ((coding-system-for-read
 706                (or file-name-coding-system
 707                    default-file-name-coding-system)))
 708           (vc-insert-file rootname))
 709         (goto-char (point-min))
 710         (nth 2 (vc-cvs-parse-root
 711                 (buffer-substring (point)
 712                                   (line-end-position))))))))
 713
 714 (defun vc-cvs-parse-root (root)
 715   "Split CVS ROOT specification string into a list of fields.
 716 A CVS root specification of the form
 717   [:METHOD:][[USER@]HOSTNAME:]/path/to/repository
 718 is converted to a normalized record with the following structure:
 719   \(METHOD USER HOSTNAME CVS-ROOT).
 720 The default METHOD for a CVS root of the form
 721   /path/to/repository
 722 is `local'.
 723 The default METHOD for a CVS root of the form
 724   [USER@]HOSTNAME:/path/to/repository
 725 is `ext'.
 726 For an empty string, nil is returned (invalid CVS root)."
 727   ;; Split CVS root into colon separated fields (0-4).
 728   ;; The `x:' makes sure, that leading colons are not lost;
 729   ;; `HOST:/PATH' is then different from `:METHOD:/PATH'.
 730   (let* ((root-list (cdr (split-string (concat "x:" root) ":")))
 731          (len (length root-list))
 732          ;; All syntactic varieties will get a proper METHOD.
 733          (root-list
 734           (cond
 735            ((= len 0)
 736             ;; Invalid CVS root
 737             nil)
 738            ((= len 1)
 739             ;; Simple PATH => method `local'
 740             (cons "local"
 741                   (cons nil root-list)))
 742            ((= len 2)
 743             ;; [USER@]HOST:PATH => method `ext'
 744             (and (not (equal (car root-list) ""))
 745                  (cons "ext" root-list)))
 746            ((= len 3)
 747             ;; :METHOD:PATH
 748             (cons (cadr root-list)
 749                   (cons nil (cddr root-list))))
 750            (t
 751             ;; :METHOD:[USER@]HOST:PATH
 752             (cdr root-list)))))
 753     (if root-list
 754         (let ((method (car root-list))
 755               (uhost (or (cadr root-list) ""))
 756               (root (nth 2 root-list))
 757               user host)
 758           ;; Split USER@HOST
 759           (if (string-match "\\(.*\\)@\\(.*\\)" uhost)
 760               (setq user (match-string 1 uhost)
 761                     host (match-string 2 uhost))
 762             (setq host uhost))
 763           ;; Remove empty HOST
 764           (and (equal host "")
 765                (setq host))
 766           ;; Fix windows style CVS root `:local:C:\\project\\cvs\\some\\dir'
 767           (and host
 768                (equal method "local")
 769                (setq root (concat host ":" root) host))
 770           ;; Normalize CVS root record
 771           (list method user host root)))))
 772
 773 (defun vc-cvs-parse-status (&optional full)
 774   "Parse output of \"cvs status\" command in the current buffer.
 775 Set file properties accordingly.  Unless FULL is t, parse only
 776 essential information."
 777   (let (file status)
 778     (goto-char (point-min))
 779     (if (re-search-forward "^File: " nil t)
 780         (cond
 781          ((looking-at "no file") nil)
 782          ((re-search-forward "\\=\\([^ \t]+\\)" nil t)
 783           (setq file (expand-file-name (match-string 1)))
 784           (vc-file-setprop file 'vc-backend 'CVS)
 785           (if (not (re-search-forward "\\=[ \t]+Status: \\(.*\\)" nil t))
 786               (setq status "Unknown")
 787             (setq status (match-string 1)))
 788           (if (and full
 789                    (re-search-forward
 790                     "\\(RCS Version\\|RCS Revision\\|Repository revision\\):\
 791 \[\t ]+\\([0-9.]+\\)"
 792                     nil t))
 793               (vc-file-setprop file 'vc-latest-version (match-string 2)))
 794           (vc-file-setprop
 795            file 'vc-state
 796            (cond
 797             ((string-match "Up-to-date" status)
 798              (vc-file-setprop file 'vc-checkout-time
 799                               (nth 5 (file-attributes file)))
 800              'up-to-date)
 801             ((string-match "Locally Modified" status)             'edited)
 802             ((string-match "Needs Merge" status)                  'needs-merge)
 803             ((string-match "Needs \\(Checkout\\|Patch\\)" status) 'needs-patch)
 804             (t 'edited))))))))
 805
 806 (defun vc-cvs-dir-state-heuristic (dir)
 807   "Find the CVS state of all files in DIR, using only local information."
 808   (with-temp-buffer
 809     (vc-cvs-get-entries dir)
 810     (goto-char (point-min))
 811     (while (not (eobp))
 812       ;; CVS-removed files are not taken under VC control.
 813       (when (looking-at "/\\([^/]*\\)/[^/-]")
 814         (let ((file (expand-file-name (match-string 1) dir)))
 815           (unless (vc-file-getprop file 'vc-state)
 816             (vc-cvs-parse-entry file t))))
 817       (forward-line 1))))
 818
 819 (defun vc-cvs-get-entries (dir)
 820   "Insert the CVS/Entries file from below DIR into the current buffer.
 821 This function ensures that the correct coding system is used for that,
 822 which may not be the one that is used for the files' contents.
 823 CVS/Entries should only be accessed through this function."
 824   (let ((coding-system-for-read (or file-name-coding-system
 825                                     default-file-name-coding-system)))
 826     (vc-insert-file (expand-file-name "CVS/Entries" dir))))
 827
 828 (defun vc-cvs-valid-symbolic-tag-name-p (tag)
 829   "Return non-nil if TAG is a valid symbolic tag name."
 830   ;; According to the CVS manual, a valid symbolic tag must start with
 831   ;; an uppercase or lowercase letter and can contain uppercase and
 832   ;; lowercase letters, digits, `-', and `_'.
 833   (and (string-match "^[a-zA-Z]" tag)
 834        (not (string-match "[^a-z0-9A-Z-_]" tag))))
 835
 836 (defun vc-cvs-valid-version-number-p (tag)
 837   "Return non-nil if TAG is a valid version number."
 838   (and (string-match "^[0-9]" tag)
 839        (not (string-match "[^0-9.]" tag))))
 840
 841 (defun vc-cvs-parse-sticky-tag (match-type match-tag)
 842   "Parse and return the sticky tag as a string.
 843 `match-data' is protected."
 844   (let ((data (match-data))
 845         (tag)
 846         (type (cond ((string= match-type "D") 'date)
 847                     ((string= match-type "T")
 848                      (if (vc-cvs-valid-symbolic-tag-name-p match-tag)
 849                          'symbolic-name
 850                        'revision-number))
 851                     (t nil))))
 852     (unwind-protect
 853         (progn
 854           (cond
 855            ;; Sticky Date tag.  Convert to a proper date value (`encode-time')
 856            ((eq type 'date)
 857             (string-match
 858              "\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)"
 859              match-tag)
 860             (let* ((year-tmp (string-to-number (match-string 1 match-tag)))
 861                    (month    (string-to-number (match-string 2 match-tag)))
 862                    (day      (string-to-number (match-string 3 match-tag)))
 863                    (hour     (string-to-number (match-string 4 match-tag)))
 864                    (min      (string-to-number (match-string 5 match-tag)))
 865                    (sec      (string-to-number (match-string 6 match-tag)))
 866                    ;; Years 0..68 are 2000..2068.
 867                    ;; Years 69..99 are 1969..1999.
 868                    (year (+ (cond ((> 69 year-tmp) 2000)
 869                                   ((> 100 year-tmp) 1900)
 870                                   (t 0))
 871                             year-tmp)))
 872               (setq tag (encode-time sec min hour day month year))))
 873            ;; Sticky Tag name or revision number
 874            ((eq type 'symbolic-name) (setq tag match-tag))
 875            ((eq type 'revision-number) (setq tag match-tag))
 876            ;; Default is no sticky tag at all
 877            (t nil))
 878           (cond ((eq vc-cvs-sticky-tag-display nil) nil)
 879                 ((eq vc-cvs-sticky-tag-display t)
 880                  (cond ((eq type 'date) (format-time-string
 881                                          vc-cvs-sticky-date-format-string
 882                                          tag))
 883                        ((eq type 'symbolic-name) tag)
 884                        ((eq type 'revision-number) tag)
 885                        (t nil)))
 886                 ((functionp vc-cvs-sticky-tag-display)
 887                  (funcall vc-cvs-sticky-tag-display tag type))
 888                 (t nil)))
 889
 890       (set-match-data data))))
 891
 892 (defun vc-cvs-parse-entry (file &optional set-state)
 893   "Parse a line from CVS/Entries.
 894 Compare modification time to that of the FILE, set file properties
 895 accordingly.  However, `vc-state' is set only if optional arg SET-STATE
 896 is non-nil."
 897   (cond
 898    ;; entry for a "locally added" file (not yet committed)
 899    ((looking-at "/[^/]+/0/")
 900     (vc-file-setprop file 'vc-checkout-time 0)
 901     (vc-file-setprop file 'vc-workfile-version "0")
 902     (if set-state (vc-file-setprop file 'vc-state 'edited)))
 903    ;; normal entry
 904    ((looking-at
 905      (concat "/[^/]+"
 906              ;; revision
 907              "/\\([^/]*\\)"
 908              ;; timestamp and optional conflict field
 909              "/\\([^/]*\\)/"
 910              ;; options
 911              "\\([^/]*\\)/"
 912              ;; sticky tag
 913              "\\(.\\|\\)" ;Sticky tag type (date or tag name, could be empty)
 914              "\\(.*\\)"))               ;Sticky tag
 915     (vc-file-setprop file 'vc-workfile-version (match-string 1))
 916     (vc-file-setprop file 'vc-cvs-sticky-tag
 917                      (vc-cvs-parse-sticky-tag (match-string 4)
 918                                               (match-string 5)))
 919     ;; Compare checkout time and modification time.
 920     ;; This is intentionally different from the algorithm that CVS uses
 921     ;; (which is based on textual comparison), because there can be problems
 922     ;; generating a time string that looks exactly like the one from CVS.
 923     (let ((mtime (nth 5 (file-attributes file))))
 924       (require 'parse-time)
 925       (let ((parsed-time
 926              (parse-time-string (concat (match-string 2) " +0000"))))
 927         (cond ((and (not (string-match "\\+" (match-string 2)))
 928                     (car parsed-time)
 929                     (equal mtime (apply 'encode-time parsed-time)))
 930                (vc-file-setprop file 'vc-checkout-time mtime)
 931                (if set-state (vc-file-setprop file 'vc-state 'up-to-date)))
 932               (t
 933                (vc-file-setprop file 'vc-checkout-time 0)
 934                (if set-state (vc-file-setprop file 'vc-state 'edited)))))))))
 935
 936 ;; Completion of revision names.
 937 ;; Just so I don't feel like I'm duplicating code from pcl-cvs, I'll use
 938 ;; `cvs log' so I can list all the revision numbers rather than only
 939 ;; tag names.
 940
 941 (defun vc-cvs-revision-table (file)
 942   (let ((default-directory (file-name-directory file))
 943         (res nil))
 944     (with-temp-buffer
 945       (vc-cvs-command t nil file "log")
 946       (goto-char (point-min))
 947       (when (re-search-forward "^symbolic names:\n" nil t)
 948         (while (looking-at "^   \\(.*\\): \\(.*\\)")
 949           (push (cons (match-string 1) (match-string 2)) res)
 950           (forward-line 1)))
 951       (while (re-search-forward "^revision \\([0-9.]+\\)" nil t)
 952         (push (match-string 1) res))
 953       res)))
 954
 955 (defun vc-cvs-revision-completion-table (file)
 956   (lexical-let ((file file)
 957                 table)
 958     (setq table (lazy-completion-table
 959                  table (lambda () (vc-cvs-revision-table file))))
 960     table))
 961
 962
 963 (provide 'vc-cvs)
 964
 965 ;; arch-tag: 60e1402a-aa53-4607-927a-cf74f144b432
 966 ;;; vc-cvs.el ends here