lisp/help.el

   1 ;;; help.el --- help commands for Emacs
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2015 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This code implements GNU Emacs's built-in help system, the one invoked by
  28 ;; `M-x help-for-help'.
  29
  30 ;;; Code:
  31
  32 ;; Get the macro make-help-screen when this is compiled,
  33 ;; or run interpreted, but not when the compiled code is loaded.
  34 (eval-when-compile (require 'help-macro))
  35
  36 ;; This makes `with-output-to-temp-buffer' buffers use `help-mode'.
  37 (add-hook 'temp-buffer-setup-hook 'help-mode-setup)
  38 (add-hook 'temp-buffer-show-hook 'help-mode-finish)
  39
  40 ;; `help-window-point-marker' is a marker you can move to a valid
  41 ;; position of the buffer shown in the help window in order to override
  42 ;; the standard positioning mechanism (`point-min') chosen by
  43 ;; `with-output-to-temp-buffer' and `with-temp-buffer-window'.
  44 ;; `with-help-window' has this point nowhere before exiting.  Currently
  45 ;; used by `view-lossage' to assert that the last keystrokes are always
  46 ;; visible.
  47 (defvar help-window-point-marker (make-marker)
  48   "Marker to override default `window-point' in help windows.")
  49
  50 (defvar help-window-old-frame nil
  51   "Frame selected at the time `with-help-window' is invoked.")
  52
  53 (defvar help-map
  54   (let ((map (make-sparse-keymap)))
  55     (define-key map (char-to-string help-char) 'help-for-help)
  56     (define-key map [help] 'help-for-help)
  57     (define-key map [f1] 'help-for-help)
  58     (define-key map "." 'display-local-help)
  59     (define-key map "?" 'help-for-help)
  60
  61     (define-key map "\C-a" 'about-emacs)
  62     (define-key map "\C-c" 'describe-copying)
  63     (define-key map "\C-d" 'view-emacs-debugging)
  64     (define-key map "\C-e" 'view-external-packages)
  65     (define-key map "\C-f" 'view-emacs-FAQ)
  66     (define-key map "\C-m" 'view-order-manuals)
  67     (define-key map "\C-n" 'view-emacs-news)
  68     (define-key map "\C-o" 'describe-distribution)
  69     (define-key map "\C-p" 'view-emacs-problems)
  70     (define-key map "\C-t" 'view-emacs-todo)
  71     (define-key map "\C-w" 'describe-no-warranty)
  72
  73     ;; This does not fit the pattern, but it is natural given the C-\ command.
  74     (define-key map "\C-\\" 'describe-input-method)
  75
  76     (define-key map "C" 'describe-coding-system)
  77     (define-key map "F" 'Info-goto-emacs-command-node)
  78     (define-key map "I" 'describe-input-method)
  79     (define-key map "K" 'Info-goto-emacs-key-command-node)
  80     (define-key map "L" 'describe-language-environment)
  81     (define-key map "S" 'info-lookup-symbol)
  82
  83     (define-key map "a" 'apropos-command)
  84     (define-key map "b" 'describe-bindings)
  85     (define-key map "c" 'describe-key-briefly)
  86     (define-key map "d" 'apropos-documentation)
  87     (define-key map "e" 'view-echo-area-messages)
  88     (define-key map "f" 'describe-function)
  89     (define-key map "g" 'describe-gnu-project)
  90     (define-key map "h" 'view-hello-file)
  91
  92     (define-key map "i" 'info)
  93     (define-key map "4i" 'info-other-window)
  94
  95     (define-key map "k" 'describe-key)
  96     (define-key map "l" 'view-lossage)
  97     (define-key map "m" 'describe-mode)
  98     (define-key map "o" 'describe-symbol)
  99     (define-key map "n" 'view-emacs-news)
 100     (define-key map "p" 'finder-by-keyword)
 101     (define-key map "P" 'describe-package)
 102     (define-key map "r" 'info-emacs-manual)
 103     (define-key map "s" 'describe-syntax)
 104     (define-key map "t" 'help-with-tutorial)
 105     (define-key map "w" 'where-is)
 106     (define-key map "v" 'describe-variable)
 107     (define-key map "q" 'help-quit)
 108     map)
 109   "Keymap for characters following the Help key.")
 110
 111 (define-key global-map (char-to-string help-char) 'help-command)
 112 (define-key global-map [help] 'help-command)
 113 (define-key global-map [f1] 'help-command)
 114 (fset 'help-command help-map)
 115
 116 ;; insert-button makes the action nil if it is not store somewhere
 117 (defvar help-button-cache nil)
 118
 119 \f
 120 (defun help-quit ()
 121   "Just exit from the Help command's command loop."
 122   (interactive)
 123   nil)
 124
 125 (defvar help-return-method nil
 126   "What to do to \"exit\" the help buffer.
 127 This is a list
 128  (WINDOW . t)              delete the selected window (and possibly its frame,
 129                            see `quit-window'), go to WINDOW.
 130  (WINDOW . quit-window)    do quit-window, then select WINDOW.
 131  (WINDOW BUF START POINT)  display BUF at START, POINT, then select WINDOW.")
 132
 133 (define-obsolete-function-alias 'print-help-return-message 'help-print-return-message "23.2")
 134 (defun help-print-return-message (&optional function)
 135   "Display or return message saying how to restore windows after help command.
 136 This function assumes that `standard-output' is the help buffer.
 137 It computes a message, and applies the optional argument FUNCTION to it.
 138 If FUNCTION is nil, it applies `message', thus displaying the message.
 139 In addition, this function sets up `help-return-method', which see, that
 140 specifies what to do when the user exits the help buffer.
 141
 142 Do not call this in the scope of `with-help-window'."
 143   (and (not (get-buffer-window standard-output))
 144        (let ((first-message
 145               (cond ((or
 146                       pop-up-frames
 147                       (special-display-p (buffer-name standard-output)))
 148                      (setq help-return-method (cons (selected-window) t))
 149                      ;; If the help output buffer is a special display buffer,
 150                      ;; don't say anything about how to get rid of it.
 151                      ;; First of all, the user will do that with the window
 152                      ;; manager, not with Emacs.
 153                      ;; Secondly, the buffer has not been displayed yet,
 154                      ;; so we don't know whether its frame will be selected.
 155                      nil)
 156                     ((not (one-window-p t))
 157                      (setq help-return-method
 158                            (cons (selected-window) 'quit-window))
 159                      "Type \\[display-buffer] RET to restore the other window.")
 160                     (pop-up-windows
 161                      (setq help-return-method (cons (selected-window) t))
 162                      "Type \\[delete-other-windows] to remove help window.")
 163                     (t
 164                      (setq help-return-method
 165                            (list (selected-window) (window-buffer)
 166                                  (window-start) (window-point)))
 167                      "Type \\[switch-to-buffer] RET to remove help window."))))
 168          (funcall (or function 'message)
 169                   (concat
 170                    (if first-message
 171                        (substitute-command-keys first-message))
 172                    (if first-message "  ")
 173                    ;; If the help buffer will go in a separate frame,
 174                    ;; it's no use mentioning a command to scroll, so don't.
 175                    (if (or pop-up-windows
 176                            (special-display-p (buffer-name standard-output)))
 177                        nil
 178                      (if (same-window-p (buffer-name standard-output))
 179                          ;; Say how to scroll this window.
 180                          (substitute-command-keys
 181                           "\\[scroll-up] to scroll the help.")
 182                        ;; Say how to scroll some other window.
 183                        (substitute-command-keys
 184                         "\\[scroll-other-window] to scroll the help."))))))))
 185
 186 ;; So keyboard macro definitions are documented correctly
 187 (fset 'defining-kbd-macro (symbol-function 'start-kbd-macro))
 188
 189 (defalias 'help 'help-for-help-internal)
 190 ;; find-function can find this.
 191 (defalias 'help-for-help 'help-for-help-internal)
 192 ;; It can't find this, but nobody will look.
 193 (make-help-screen help-for-help-internal
 194   (purecopy "Type a help option: [abcCdefFgiIkKlLmnprstvw.] C-[cdefmnoptw] or ?")
 195   ;; Don't purecopy this one, because it's not evaluated (it's
 196   ;; directly used as a docstring in a function definition, so it'll
 197   ;; be moved to the DOC file anyway: no need for purecopying it).
 198   "You have typed %THIS-KEY%, the help character.  Type a Help option:
 199 \(Use SPC or DEL to scroll through this text.  Type \\<help-map>\\[help-quit] to exit the Help command.)
 200
 201 a PATTERN   Show commands whose name matches the PATTERN (a list of words
 202               or a regexp).  See also the `apropos' command.
 203 b           Display all key bindings.
 204 c KEYS      Display the command name run by the given key sequence.
 205 C CODING    Describe the given coding system, or RET for current ones.
 206 d PATTERN   Show a list of functions, variables, and other items whose
 207               documentation matches the PATTERN (a list of words or a regexp).
 208 e           Go to the *Messages* buffer which logs echo-area messages.
 209 f FUNCTION  Display documentation for the given function.
 210 F COMMAND   Show the Emacs manual's section that describes the command.
 211 g           Display information about the GNU project.
 212 h           Display the HELLO file which illustrates various scripts.
 213 i           Start the Info documentation reader: read included manuals.
 214 I METHOD    Describe a specific input method, or RET for current.
 215 k KEYS      Display the full documentation for the key sequence.
 216 K KEYS      Show the Emacs manual's section for the command bound to KEYS.
 217 l           Show last 300 input keystrokes (lossage).
 218 L LANG-ENV  Describes a specific language environment, or RET for current.
 219 m           Display documentation of current minor modes and current major mode,
 220               including their special commands.
 221 n           Display news of recent Emacs changes.
 222 o SYMBOL    Display the given function or variable's documentation and value.
 223 p TOPIC     Find packages matching a given topic keyword.
 224 P PACKAGE   Describe the given Emacs Lisp package.
 225 r           Display the Emacs manual in Info mode.
 226 s           Display contents of current syntax table, plus explanations.
 227 S SYMBOL    Show the section for the given symbol in the Info manual
 228               for the programming language used in this buffer.
 229 t           Start the Emacs learn-by-doing tutorial.
 230 v VARIABLE  Display the given variable's documentation and value.
 231 w COMMAND   Display which keystrokes invoke the given command (where-is).
 232 .           Display any available local help at point in the echo area.
 233
 234 C-a         Information about Emacs.
 235 C-c         Emacs copying permission (GNU General Public License).
 236 C-d         Instructions for debugging GNU Emacs.
 237 C-e         External packages and information about Emacs.
 238 C-f         Emacs FAQ.
 239 C-m         How to order printed Emacs manuals.
 240 C-n         News of recent Emacs changes.
 241 C-o         Emacs ordering and distribution information.
 242 C-p         Info about known Emacs problems.
 243 C-t         Emacs TODO list.
 244 C-w         Information on absence of warranty for GNU Emacs."
 245   help-map)
 246
 247 \f
 248
 249 (defun function-called-at-point ()
 250   "Return a function around point or else called by the list containing point.
 251 If that doesn't give a function, return nil."
 252   (with-syntax-table emacs-lisp-mode-syntax-table
 253     (or (condition-case ()
 254             (save-excursion
 255               (or (not (zerop (skip-syntax-backward "_w")))
 256                   (eq (char-syntax (following-char)) ?w)
 257                   (eq (char-syntax (following-char)) ?_)
 258                   (forward-sexp -1))
 259               (skip-chars-forward "'")
 260               (let ((obj (read (current-buffer))))
 261                 (and (symbolp obj) (fboundp obj) obj)))
 262           (error nil))
 263         (condition-case ()
 264             (save-excursion
 265               (save-restriction
 266                 (narrow-to-region (max (point-min)
 267                                        (- (point) 1000)) (point-max))
 268                 ;; Move up to surrounding paren, then after the open.
 269                 (backward-up-list 1)
 270                 (forward-char 1)
 271                 ;; If there is space here, this is probably something
 272                 ;; other than a real Lisp function call, so ignore it.
 273                 (if (looking-at "[ \t]")
 274                     (error "Probably not a Lisp function call"))
 275                 (let ((obj (read (current-buffer))))
 276                   (and (symbolp obj) (fboundp obj) obj))))
 277           (error nil))
 278         (let* ((str (find-tag-default))
 279                (sym (if str (intern-soft str))))
 280           (if (and sym (fboundp sym))
 281               sym
 282             (save-match-data
 283               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 284                 (setq sym (intern-soft (match-string 1 str)))
 285                 (and (fboundp sym) sym))))))))
 286
 287 \f
 288 ;;; `User' help functions
 289
 290 (defun view-help-file (file &optional dir)
 291   (view-file (expand-file-name file (or dir data-directory)))
 292   (goto-address-mode 1)
 293   (goto-char (point-min)))
 294
 295 (defun describe-distribution ()
 296   "Display info on how to obtain the latest version of GNU Emacs."
 297   (interactive)
 298   (view-help-file "DISTRIB"))
 299
 300 (defun describe-copying ()
 301   "Display info on how you may redistribute copies of GNU Emacs."
 302   (interactive)
 303   (view-help-file "COPYING"))
 304
 305 ;; Maybe this command should just be removed.
 306 (defun describe-gnu-project ()
 307   "Browse online information on the GNU project."
 308   (interactive)
 309   (browse-url "http://www.gnu.org/gnu/thegnuproject.html"))
 310
 311 (define-obsolete-function-alias 'describe-project 'describe-gnu-project "22.2")
 312
 313 (defun describe-no-warranty ()
 314   "Display info on all the kinds of warranty Emacs does NOT have."
 315   (interactive)
 316   (describe-copying)
 317   (let (case-fold-search)
 318     (search-forward "Disclaimer of Warranty")
 319     (forward-line 0)
 320     (recenter 0)))
 321
 322 (defun describe-prefix-bindings ()
 323   "Describe the bindings of the prefix used to reach this command.
 324 The prefix described consists of all but the last event
 325 of the key sequence that ran this command."
 326   (interactive)
 327   (let ((key (this-command-keys)))
 328     (describe-bindings
 329      (if (stringp key)
 330          (substring key 0 (1- (length key)))
 331        (let ((prefix (make-vector (1- (length key)) nil))
 332              (i 0))
 333          (while (< i (length prefix))
 334            (aset prefix i (aref key i))
 335            (setq i (1+ i)))
 336          prefix)))))
 337 ;; Make C-h after a prefix, when not specifically bound,
 338 ;; run describe-prefix-bindings.
 339 (setq prefix-help-command 'describe-prefix-bindings)
 340
 341 (defun view-emacs-news (&optional version)
 342   "Display info on recent changes to Emacs.
 343 With argument, display info only for the selected version."
 344   (interactive "P")
 345   (unless version
 346     (setq version emacs-major-version))
 347   (when (consp version)
 348     (let* ((all-versions
 349             (let (res)
 350               (mapc
 351                (lambda (file)
 352                  (with-temp-buffer
 353                    (insert-file-contents
 354                     (expand-file-name file data-directory))
 355                    (while (re-search-forward
 356                            (if (member file '("NEWS.18" "NEWS.1-17"))
 357                                "Changes in \\(?:Emacs\\|version\\)?[ \t]*\\([0-9]+\\(?:\\.[0-9]+\\)?\\)"
 358                              "^\* [^0-9\n]*\\([0-9]+\\.[0-9]+\\)") nil t)
 359                      (setq res (cons (match-string-no-properties 1) res)))))
 360                (cons "NEWS"
 361                      (directory-files data-directory nil
 362                                       "^NEWS\\.[0-9][-0-9]*$" nil)))
 363               (sort (delete-dups res) #'string>)))
 364            (current (car all-versions)))
 365       (setq version (completing-read
 366                      (format "Read NEWS for the version (default %s): " current)
 367                      all-versions nil nil nil nil current))
 368       (if (integerp (string-to-number version))
 369           (setq version (string-to-number version))
 370         (unless (or (member version all-versions)
 371                     (<= (string-to-number version) (string-to-number current)))
 372           (error "No news about version %s" version)))))
 373   (when (integerp version)
 374     (cond ((<= version 12)
 375            (setq version (format "1.%d" version)))
 376           ((<= version 18)
 377            (setq version (format "%d" version)))
 378           ((> version emacs-major-version)
 379            (error "No news about Emacs %d (yet)" version))))
 380   (let* ((vn (if (stringp version)
 381                  (string-to-number version)
 382                version))
 383          (file (cond
 384                 ((>= vn emacs-major-version) "NEWS")
 385                 ((< vn 18) "NEWS.1-17")
 386                 (t (format "NEWS.%d" vn))))
 387          res)
 388     (view-file (expand-file-name file data-directory))
 389     (widen)
 390     (goto-char (point-min))
 391     (when (stringp version)
 392       (when (re-search-forward
 393              (concat (if (< vn 19)
 394                          "Changes in Emacs[ \t]*"
 395                        "^\* [^0-9\n]*") version "$")
 396              nil t)
 397         (beginning-of-line)
 398         (narrow-to-region
 399          (point)
 400          (save-excursion
 401            (while (and (setq res
 402                              (re-search-forward
 403                               (if (< vn 19)
 404                                   "Changes in \\(?:Emacs\\|version\\)?[ \t]*\\([0-9]+\\(?:\\.[0-9]+\\)?\\)"
 405                                 "^\* [^0-9\n]*\\([0-9]+\\.[0-9]+\\)") nil t))
 406                        (equal (match-string-no-properties 1) version)))
 407            (or res (goto-char (point-max)))
 408            (beginning-of-line)
 409            (point)))))))
 410
 411 (defun view-emacs-todo (&optional _arg)
 412   "Display the Emacs TODO list."
 413   (interactive "P")
 414   (view-help-file "TODO"))
 415
 416 (define-obsolete-function-alias 'view-todo 'view-emacs-todo "22.2")
 417
 418
 419 (defun view-echo-area-messages ()
 420   "View the log of recent echo-area messages: the `*Messages*' buffer.
 421 The number of messages retained in that buffer
 422 is specified by the variable `message-log-max'."
 423   (interactive)
 424   (with-current-buffer (messages-buffer)
 425     (goto-char (point-max))
 426     (display-buffer (current-buffer))))
 427
 428 (defun view-order-manuals ()
 429   "Display information on how to buy printed copies of Emacs manuals."
 430   (interactive)
 431 ;;  (view-help-file "ORDERS")
 432   (info "(emacs)Printed Books"))
 433
 434 (defun view-emacs-FAQ ()
 435   "Display the Emacs Frequently Asked Questions (FAQ) file."
 436   (interactive)
 437   ;; (find-file-read-only (expand-file-name "FAQ" data-directory))
 438   (info "(efaq)"))
 439
 440 (defun view-emacs-problems ()
 441   "Display info on known problems with Emacs and possible workarounds."
 442   (interactive)
 443   (view-help-file "PROBLEMS"))
 444
 445 (defun view-emacs-debugging ()
 446   "Display info on how to debug Emacs problems."
 447   (interactive)
 448   (view-help-file "DEBUG"))
 449
 450 ;; This used to visit MORE.STUFF; maybe it should just be removed.
 451 (defun view-external-packages ()
 452   "Display info on where to get more Emacs packages."
 453   (interactive)
 454   (info "(efaq)Packages that do not come with Emacs"))
 455
 456 (defun view-lossage ()
 457   "Display last few input keystrokes and the commands run.
 458
 459 To record all your input, use `open-dribble-file'."
 460   (interactive)
 461   (help-setup-xref (list #'view-lossage)
 462                    (called-interactively-p 'interactive))
 463   (with-help-window (help-buffer)
 464     (princ " ")
 465     (princ (mapconcat (lambda (key)
 466                         (cond
 467                          ((and (consp key) (null (car key)))
 468                           (format "[%s]\n" (if (symbolp (cdr key)) (cdr key)
 469                                            "anonymous-command")))
 470                          ((or (integerp key) (symbolp key) (listp key))
 471                           (single-key-description key))
 472                          (t
 473                           (prin1-to-string key nil))))
 474                       (recent-keys 'include-cmds)
 475                       " "))
 476     (with-current-buffer standard-output
 477       (goto-char (point-min))
 478       (while (not (eobp))
 479         (move-to-column 50)
 480         (unless (eolp)
 481           (fill-region (line-beginning-position) (line-end-position)))
 482         (forward-line 1))
 483       ;; jidanni wants to see the last keystrokes immediately.
 484       (set-marker help-window-point-marker (point)))))
 485
 486 \f
 487 ;; Key bindings
 488
 489 (defun describe-bindings (&optional prefix buffer)
 490   "Display a buffer showing a list of all defined keys, and their definitions.
 491 The keys are displayed in order of precedence.
 492
 493 The optional argument PREFIX, if non-nil, should be a key sequence;
 494 then we display only bindings that start with that prefix.
 495 The optional argument BUFFER specifies which buffer's bindings
 496 to display (default, the current buffer).  BUFFER can be a buffer
 497 or a buffer name."
 498   (interactive)
 499   (or buffer (setq buffer (current-buffer)))
 500   (help-setup-xref (list #'describe-bindings prefix buffer)
 501                    (called-interactively-p 'interactive))
 502   (with-help-window (help-buffer)
 503     ;; Be aware that `describe-buffer-bindings' puts its output into
 504     ;; the current buffer.
 505     (with-current-buffer (help-buffer)
 506       (describe-buffer-bindings buffer prefix))))
 507
 508 ;; This function used to be in keymap.c.
 509 (defun describe-bindings-internal (&optional menus prefix)
 510   "Show a list of all defined keys, and their definitions.
 511 We put that list in a buffer, and display the buffer.
 512
 513 The optional argument MENUS, if non-nil, says to mention menu bindings.
 514 \(Ordinarily these are omitted from the output.)
 515 The optional argument PREFIX, if non-nil, should be a key sequence;
 516 then we display only bindings that start with that prefix."
 517   (declare (obsolete describe-buffer-bindings "24.4"))
 518   (let ((buf (current-buffer)))
 519     (with-help-window (help-buffer)
 520       ;; Be aware that `describe-buffer-bindings' puts its output into
 521       ;; the current buffer.
 522       (with-current-buffer (help-buffer)
 523         (describe-buffer-bindings buf prefix menus)))))
 524
 525 (defun where-is (definition &optional insert)
 526   "Print message listing key sequences that invoke the command DEFINITION.
 527 Argument is a command definition, usually a symbol with a function definition.
 528 If INSERT (the prefix arg) is non-nil, insert the message in the buffer."
 529   (interactive
 530    (let ((fn (function-called-at-point))
 531          (enable-recursive-minibuffers t)
 532          val)
 533      (setq val (completing-read
 534                 (if fn
 535                     (format "Where is command (default %s): " fn)
 536                   "Where is command: ")
 537                 obarray 'commandp t nil nil
 538                 (and fn (symbol-name fn))))
 539      (list (unless (equal val "") (intern val))
 540            current-prefix-arg)))
 541   (unless definition (error "No command"))
 542   (let ((func (indirect-function definition))
 543         (defs nil)
 544         (standard-output (if insert (current-buffer) standard-output)))
 545     ;; In DEFS, find all symbols that are aliases for DEFINITION.
 546     (mapatoms (lambda (symbol)
 547                 (and (fboundp symbol)
 548                      (not (eq symbol definition))
 549                      (eq func (condition-case ()
 550                                   (indirect-function symbol)
 551                                 (error symbol)))
 552                      (push symbol defs))))
 553     ;; Look at all the symbols--first DEFINITION,
 554     ;; then its aliases.
 555     (dolist (symbol (cons definition defs))
 556       (let* ((remapped (command-remapping symbol))
 557              (keys (where-is-internal
 558                     symbol overriding-local-map nil nil remapped))
 559              (keys (mapconcat 'key-description keys ", "))
 560              string)
 561         (setq string
 562               (if insert
 563                   (if (> (length keys) 0)
 564                       (if remapped
 565                           (format "%s (%s) (remapped from %s)"
 566                                   keys remapped symbol)
 567                         (format "%s (%s)" keys symbol))
 568                     (format "M-x %s RET" symbol))
 569                 (if (> (length keys) 0)
 570                     (if remapped
 571                         (format "%s is remapped to %s which is on %s"
 572                                 symbol remapped keys)
 573                       (format "%s is on %s" symbol keys))
 574                   ;; If this is the command the user asked about,
 575                   ;; and it is not on any key, say so.
 576                   ;; For other symbols, its aliases, say nothing
 577                   ;; about them unless they are on keys.
 578                   (if (eq symbol definition)
 579                       (format "%s is not on any key" symbol)))))
 580         (when string
 581           (unless (eq symbol definition)
 582             (princ ";\n its alias "))
 583           (princ string)))))
 584   nil)
 585
 586 (defun help-key-description (key untranslated)
 587   (let ((string (key-description key)))
 588     (if (or (not untranslated)
 589             (and (eq (aref untranslated 0) ?\e) (not (eq (aref key 0) ?\e))))
 590         string
 591       (let ((otherstring (key-description untranslated)))
 592         (if (equal string otherstring)
 593             string
 594           (format "%s (translated from %s)" string otherstring))))))
 595
 596 (defun describe-key-briefly (&optional key insert untranslated)
 597   "Print the name of the function KEY invokes.  KEY is a string.
 598 If INSERT (the prefix arg) is non-nil, insert the message in the buffer.
 599 If non-nil, UNTRANSLATED is a vector of the untranslated events.
 600 It can also be a number in which case the untranslated events from
 601 the last key hit are used.
 602
 603 If KEY is a menu item or a tool-bar button that is disabled, this command
 604 temporarily enables it to allow getting help on disabled items and buttons."
 605   (interactive
 606    (let ((enable-disabled-menus-and-buttons t)
 607          (cursor-in-echo-area t)
 608          saved-yank-menu)
 609      (unwind-protect
 610          (let (key)
 611            ;; If yank-menu is empty, populate it temporarily, so that
 612            ;; "Select and Paste" menu can generate a complete event.
 613            (when (null (cdr yank-menu))
 614              (setq saved-yank-menu (copy-sequence yank-menu))
 615              (menu-bar-update-yank-menu "(any string)" nil))
 616            (setq key (read-key-sequence "Describe key (or click or menu item): "))
 617            ;; Clear the echo area message (Bug#7014).
 618            (message nil)
 619            ;; If KEY is a down-event, read and discard the
 620            ;; corresponding up-event.  Note that there are also
 621            ;; down-events on scroll bars and mode lines: the actual
 622            ;; event then is in the second element of the vector.
 623            (and (vectorp key)
 624                 (let ((last-idx (1- (length key))))
 625                   (and (eventp (aref key last-idx))
 626                        (memq 'down (event-modifiers (aref key last-idx)))))
 627                 (read-event))
 628            (list
 629             key
 630             (if current-prefix-arg (prefix-numeric-value current-prefix-arg))
 631             1))
 632        ;; Put yank-menu back as it was, if we changed it.
 633        (when saved-yank-menu
 634          (setq yank-menu (copy-sequence saved-yank-menu))
 635          (fset 'yank-menu (cons 'keymap yank-menu))))))
 636   (if (numberp untranslated)
 637       (setq untranslated (this-single-command-raw-keys)))
 638   (let* ((event (if (and (symbolp (aref key 0))
 639                          (> (length key) 1)
 640                          (consp (aref key 1)))
 641                     (aref key 1)
 642                   (aref key 0)))
 643          (modifiers (event-modifiers event))
 644          (standard-output (if insert (current-buffer) standard-output))
 645          (mouse-msg (if (or (memq 'click modifiers) (memq 'down modifiers)
 646                             (memq 'drag modifiers)) " at that spot" ""))
 647          (defn (key-binding key t))
 648          key-desc)
 649     ;; Handle the case where we faked an entry in "Select and Paste" menu.
 650     (if (and (eq defn nil)
 651              (stringp (aref key (1- (length key))))
 652              (eq (key-binding (substring key 0 -1)) 'yank-menu))
 653         (setq defn 'menu-bar-select-yank))
 654     ;; Don't bother user with strings from (e.g.) the select-paste menu.
 655     (if (stringp (aref key (1- (length key))))
 656         (aset key (1- (length key)) "(any string)"))
 657     (if (and (> (length untranslated) 0)
 658              (stringp (aref untranslated (1- (length untranslated)))))
 659         (aset untranslated (1- (length untranslated)) "(any string)"))
 660     ;; Now describe the key, perhaps as changed.
 661     (setq key-desc (help-key-description key untranslated))
 662     (if (or (null defn) (integerp defn) (equal defn 'undefined))
 663         (princ (format "%s%s is undefined" key-desc mouse-msg))
 664       (princ (format "%s%s runs the command %S" key-desc mouse-msg defn)))))
 665
 666 (defun help--key-binding-keymap (key &optional accept-default no-remap position)
 667   "Return a keymap holding a binding for KEY within current keymaps.
 668 The effect of the arguments KEY, ACCEPT-DEFAULT, NO-REMAP and
 669 POSITION is as documented in the function `key-binding'."
 670   (let* ((active-maps (current-active-maps t position))
 671          map found)
 672     ;; We loop over active maps like key-binding does.
 673     (while (and
 674             (not found)
 675             (setq map (pop active-maps)))
 676       (setq found (lookup-key map key accept-default))
 677       (when (integerp found)
 678         ;; The first `found' characters of KEY were found but not the
 679         ;; whole sequence.
 680         (setq found nil)))
 681     (when found
 682       (if (and (symbolp found)
 683                (not no-remap)
 684                (command-remapping found))
 685           ;; The user might want to know in which map the binding is
 686           ;; found, or in which map the remapping is found.  The
 687           ;; default is to show the latter.
 688           (help--key-binding-keymap (vector 'remap found))
 689         map))))
 690
 691 (defun help--binding-locus (key position)
 692   "Describe in which keymap KEY is defined.
 693 Return a symbol pointing to that keymap if one exists ; otherwise
 694 return nil.  The argument POSITION is as documented in the
 695 function `key-binding'."
 696   (let ((map (help--key-binding-keymap key t nil position)))
 697     (when map
 698       (catch 'found
 699         (let ((advertised-syms (nconc
 700                                 (list 'overriding-terminal-local-map
 701                                       'overriding-local-map)
 702                                 (delq nil
 703                                       (mapcar
 704                                        (lambda (mode-and-map)
 705                                          (let ((mode (car mode-and-map)))
 706                                            (when (symbol-value mode)
 707                                              (intern-soft
 708                                               (format "%s-map" mode)))))
 709                                        minor-mode-map-alist))
 710                                 (list 'global-map
 711                                       (intern-soft (format "%s-map" major-mode)))))
 712               found)
 713           ;; Look into these advertised symbols first.
 714           (dolist (sym advertised-syms)
 715             (when (and
 716                    (boundp sym)
 717                    (eq map (symbol-value sym)))
 718               (throw 'found sym)))
 719           ;; Only look in other symbols otherwise.
 720           (mapatoms
 721            (lambda (x)
 722              (when (and (boundp x)
 723                         ;; Avoid let-bound symbols.
 724                         (special-variable-p x)
 725                         (eq (symbol-value x) map))
 726                (throw 'found x))))
 727           nil)))))
 728
 729 (defun describe-key (&optional key untranslated up-event)
 730   "Display documentation of the function invoked by KEY.
 731 KEY can be any kind of a key sequence; it can include keyboard events,
 732 mouse events, and/or menu events.  When calling from a program,
 733 pass KEY as a string or a vector.
 734
 735 If non-nil, UNTRANSLATED is a vector of the corresponding untranslated events.
 736 It can also be a number, in which case the untranslated events from
 737 the last key sequence entered are used.
 738 UP-EVENT is the up-event that was discarded by reading KEY, or nil.
 739
 740 If KEY is a menu item or a tool-bar button that is disabled, this command
 741 temporarily enables it to allow getting help on disabled items and buttons."
 742   (interactive
 743    (let ((enable-disabled-menus-and-buttons t)
 744          (cursor-in-echo-area t)
 745          saved-yank-menu)
 746      (unwind-protect
 747          (let (key)
 748            ;; If yank-menu is empty, populate it temporarily, so that
 749            ;; "Select and Paste" menu can generate a complete event.
 750            (when (null (cdr yank-menu))
 751              (setq saved-yank-menu (copy-sequence yank-menu))
 752              (menu-bar-update-yank-menu "(any string)" nil))
 753            (setq key (read-key-sequence "Describe key (or click or menu item): "))
 754            (list
 755             key
 756             (prefix-numeric-value current-prefix-arg)
 757             ;; If KEY is a down-event, read and include the
 758             ;; corresponding up-event.  Note that there are also
 759             ;; down-events on scroll bars and mode lines: the actual
 760             ;; event then is in the second element of the vector.
 761             (and (vectorp key)
 762                  (let ((last-idx (1- (length key))))
 763                    (and (eventp (aref key last-idx))
 764                         (memq 'down (event-modifiers (aref key last-idx)))))
 765                  (or (and (eventp (aref key 0))
 766                           (memq 'down (event-modifiers (aref key 0)))
 767                           ;; However, for the C-down-mouse-2 popup
 768                           ;; menu, there is no subsequent up-event.  In
 769                           ;; this case, the up-event is the next
 770                           ;; element in the supplied vector.
 771                           (= (length key) 1))
 772                      (and (> (length key) 1)
 773                           (eventp (aref key 1))
 774                           (memq 'down (event-modifiers (aref key 1)))))
 775                  (read-event))))
 776        ;; Put yank-menu back as it was, if we changed it.
 777        (when saved-yank-menu
 778          (setq yank-menu (copy-sequence saved-yank-menu))
 779          (fset 'yank-menu (cons 'keymap yank-menu))))))
 780   (if (numberp untranslated)
 781       (setq untranslated (this-single-command-raw-keys)))
 782   (let* ((event (aref key (if (and (symbolp (aref key 0))
 783                                    (> (length key) 1)
 784                                    (consp (aref key 1)))
 785                               1
 786                             0)))
 787          (modifiers (event-modifiers event))
 788          (mouse-msg (if (or (memq 'click modifiers) (memq 'down modifiers)
 789                             (memq 'drag modifiers)) " at that spot" ""))
 790          (defn (key-binding key t))
 791          key-locus key-locus-up key-locus-up-tricky
 792          defn-up defn-up-tricky ev-type
 793          mouse-1-remapped mouse-1-tricky)
 794
 795     ;; Handle the case where we faked an entry in "Select and Paste" menu.
 796     (when (and (eq defn nil)
 797                (stringp (aref key (1- (length key))))
 798                (eq (key-binding (substring key 0 -1)) 'yank-menu))
 799       (setq defn 'menu-bar-select-yank))
 800     (if (or (null defn) (integerp defn) (equal defn 'undefined))
 801         (message "%s%s is undefined"
 802                  (help-key-description key untranslated) mouse-msg)
 803       (help-setup-xref (list #'describe-function defn)
 804                        (called-interactively-p 'interactive))
 805       ;; Don't bother user with strings from (e.g.) the select-paste menu.
 806       (when (stringp (aref key (1- (length key))))
 807         (aset key (1- (length key)) "(any string)"))
 808       (when (and untranslated
 809                  (stringp (aref untranslated (1- (length untranslated)))))
 810         (aset untranslated (1- (length untranslated))
 811               "(any string)"))
 812       ;; Need to do this before erasing *Help* buffer in case event
 813       ;; is a mouse click in an existing *Help* buffer.
 814       (when up-event
 815         (setq ev-type (event-basic-type up-event))
 816         (let ((sequence (vector up-event)))
 817           (when (and (eq ev-type 'mouse-1)
 818                      mouse-1-click-follows-link
 819                      (not (eq mouse-1-click-follows-link 'double))
 820                      (setq mouse-1-remapped
 821                            (mouse-on-link-p (event-start up-event))))
 822             (setq mouse-1-tricky (and (integerp mouse-1-click-follows-link)
 823                                       (> mouse-1-click-follows-link 0)))
 824             (cond ((stringp mouse-1-remapped)
 825                    (setq sequence mouse-1-remapped))
 826                   ((vectorp mouse-1-remapped)
 827                    (setcar up-event (elt mouse-1-remapped 0)))
 828                   (t (setcar up-event 'mouse-2))))
 829           (setq defn-up (key-binding sequence nil nil (event-start up-event)))
 830           (setq key-locus-up (help--binding-locus sequence (event-start up-event)))
 831           (when mouse-1-tricky
 832             (setq sequence (vector up-event))
 833             (aset sequence 0 'mouse-1)
 834             (setq defn-up-tricky (key-binding sequence nil nil (event-start up-event)))
 835             (setq key-locus-up-tricky (help--binding-locus sequence (event-start up-event))))))
 836       (setq key-locus (help--binding-locus key (event-start event)))
 837       (with-help-window (help-buffer)
 838         (princ (help-key-description key untranslated))
 839         (princ (format "%s runs the command %S%s, which is "
 840                        mouse-msg defn (if key-locus
 841                                           (format " (found in %s)" key-locus)
 842                                         "")))
 843         (describe-function-1 defn)
 844         (when up-event
 845           (unless (or (null defn-up)
 846                       (integerp defn-up)
 847                       (equal defn-up 'undefined))
 848             (princ (format "
 849
 850 ----------------- up-event %s----------------
 851
 852 %s%s%s runs the command %S%s, which is "
 853                            (if mouse-1-tricky "(short click) " "")
 854                            (key-description (vector up-event))
 855                            mouse-msg
 856                            (if mouse-1-remapped
 857                                " is remapped to <mouse-2>, which" "")
 858                            defn-up (if key-locus-up
 859                                        (format " (found in %s)" key-locus-up)
 860                                      "")))
 861             (describe-function-1 defn-up))
 862           (unless (or (null defn-up-tricky)
 863                       (integerp defn-up-tricky)
 864                       (eq defn-up-tricky 'undefined))
 865             (princ (format "
 866
 867 ----------------- up-event (long click) ----------------
 868
 869 Pressing <%S>%s for longer than %d milli-seconds
 870 runs the command %S%s, which is "
 871                            ev-type mouse-msg
 872                            mouse-1-click-follows-link
 873                            defn-up-tricky (if key-locus-up-tricky
 874                                               (format " (found in %s)" key-locus-up-tricky)
 875                                             "")))
 876             (describe-function-1 defn-up-tricky)))))))
 877 \f
 878 (defun describe-mode (&optional buffer)
 879   "Display documentation of current major mode and minor modes.
 880 A brief summary of the minor modes comes first, followed by the
 881 major mode description.  This is followed by detailed
 882 descriptions of the minor modes, each on a separate page.
 883
 884 For this to work correctly for a minor mode, the mode's indicator
 885 variable \(listed in `minor-mode-alist') must also be a function
 886 whose documentation describes the minor mode.
 887
 888 If called from Lisp with a non-nil BUFFER argument, display
 889 documentation for the major and minor modes of that buffer."
 890   (interactive "@")
 891   (unless buffer (setq buffer (current-buffer)))
 892   (help-setup-xref (list #'describe-mode buffer)
 893                    (called-interactively-p 'interactive))
 894   ;; For the sake of help-do-xref and help-xref-go-back,
 895   ;; don't switch buffers before calling `help-buffer'.
 896   (with-help-window (help-buffer)
 897     (with-current-buffer buffer
 898       (let (minor-modes)
 899         ;; Older packages do not register in minor-mode-list but only in
 900         ;; minor-mode-alist.
 901         (dolist (x minor-mode-alist)
 902           (setq x (car x))
 903           (unless (memq x minor-mode-list)
 904             (push x minor-mode-list)))
 905         ;; Find enabled minor mode we will want to mention.
 906         (dolist (mode minor-mode-list)
 907           ;; Document a minor mode if it is listed in minor-mode-alist,
 908           ;; non-nil, and has a function definition.
 909           (let ((fmode (or (get mode :minor-mode-function) mode)))
 910             (and (boundp mode) (symbol-value mode)
 911                  (fboundp fmode)
 912                  (let ((pretty-minor-mode
 913                         (if (string-match "\\(\\(-minor\\)?-mode\\)?\\'"
 914                                           (symbol-name fmode))
 915                             (capitalize
 916                              (substring (symbol-name fmode)
 917                                         0 (match-beginning 0)))
 918                           fmode)))
 919                    (push (list fmode pretty-minor-mode
 920                                (format-mode-line (assq mode minor-mode-alist)))
 921                          minor-modes)))))
 922         (setq minor-modes
 923               (sort minor-modes
 924                     (lambda (a b) (string-lessp (cadr a) (cadr b)))))
 925         (when minor-modes
 926           (princ "Enabled minor modes:\n")
 927           (make-local-variable 'help-button-cache)
 928           (with-current-buffer standard-output
 929             (dolist (mode minor-modes)
 930               (let ((mode-function (nth 0 mode))
 931                     (pretty-minor-mode (nth 1 mode))
 932                     (indicator (nth 2 mode)))
 933                 (add-text-properties 0 (length pretty-minor-mode)
 934                                      '(face bold) pretty-minor-mode)
 935                 (save-excursion
 936                   (goto-char (point-max))
 937                   (princ "\n\f\n")
 938                   (push (point-marker) help-button-cache)
 939                   ;; Document the minor modes fully.
 940                   (insert pretty-minor-mode)
 941                   (princ (format " minor mode (%s):\n"
 942                                  (if (zerop (length indicator))
 943                                      "no indicator"
 944                                    (format "indicator%s"
 945                                            indicator))))
 946                   (princ (documentation mode-function)))
 947                 (insert-button pretty-minor-mode
 948                                'action (car help-button-cache)
 949                                'follow-link t
 950                                'help-echo "mouse-2, RET: show full information")
 951                 (newline)))
 952             (forward-line -1)
 953             (fill-paragraph nil)
 954             (forward-line 1))
 955
 956           (princ "\n(Information about these minor modes follows the major mode info.)\n\n"))
 957         ;; Document the major mode.
 958         (let ((mode mode-name))
 959           (with-current-buffer standard-output
 960             (let ((start (point)))
 961               (insert (format-mode-line mode nil nil buffer))
 962               (add-text-properties start (point) '(face bold)))))
 963         (princ " mode")
 964         (let* ((mode major-mode)
 965                (file-name (find-lisp-object-file-name mode nil)))
 966           (when file-name
 967             (princ (concat (substitute-command-keys " defined in ‘")
 968                            (file-name-nondirectory file-name)
 969                            (substitute-command-keys "’")))
 970             ;; Make a hyperlink to the library.
 971             (with-current-buffer standard-output
 972               (save-excursion
 973                 (re-search-backward (substitute-command-keys "‘\\([^‘’]+\\)’")
 974                                     nil t)
 975                 (help-xref-button 1 'help-function-def mode file-name)))))
 976         (princ ":\n")
 977         (princ (documentation major-mode)))))
 978   ;; For the sake of IELM and maybe others
 979   nil)
 980
 981
 982 (defun describe-minor-mode (minor-mode)
 983   "Display documentation of a minor mode given as MINOR-MODE.
 984 MINOR-MODE can be a minor mode symbol or a minor mode indicator string
 985 appeared on the mode-line."
 986   (interactive (list (completing-read
 987                       "Minor mode: "
 988                               (nconc
 989                                (describe-minor-mode-completion-table-for-symbol)
 990                                (describe-minor-mode-completion-table-for-indicator)
 991                                ))))
 992   (if (symbolp minor-mode)
 993       (setq minor-mode (symbol-name minor-mode)))
 994   (let ((symbols (describe-minor-mode-completion-table-for-symbol))
 995         (indicators (describe-minor-mode-completion-table-for-indicator)))
 996     (cond
 997      ((member minor-mode symbols)
 998       (describe-minor-mode-from-symbol (intern minor-mode)))
 999      ((member minor-mode indicators)
1000       (describe-minor-mode-from-indicator minor-mode))
1001      (t
1002       (error "No such minor mode: %s" minor-mode)))))
1003
1004 ;; symbol
1005 (defun describe-minor-mode-completion-table-for-symbol ()
1006   ;; In order to list up all minor modes, minor-mode-list
1007   ;; is used here instead of minor-mode-alist.
1008   (delq nil (mapcar 'symbol-name minor-mode-list)))
1009
1010 (defun describe-minor-mode-from-symbol (symbol)
1011   "Display documentation of a minor mode given as a symbol, SYMBOL"
1012   (interactive (list (intern (completing-read
1013                               "Minor mode symbol: "
1014                               (describe-minor-mode-completion-table-for-symbol)))))
1015   (if (fboundp symbol)
1016       (describe-function symbol)
1017     (describe-variable symbol)))
1018
1019 ;; indicator
1020 (defun describe-minor-mode-completion-table-for-indicator ()
1021   (delq nil
1022         (mapcar (lambda (x)
1023                   (let ((i (format-mode-line x)))
1024                     ;; remove first space if existed
1025                     (cond
1026                      ((= 0 (length i))
1027                       nil)
1028                      ((eq (aref i 0) ?\s)
1029                       (substring i 1))
1030                      (t
1031                       i))))
1032                 minor-mode-alist)))
1033
1034 (defun describe-minor-mode-from-indicator (indicator)
1035   "Display documentation of a minor mode specified by INDICATOR.
1036 If you call this function interactively, you can give indicator which
1037 is currently activated with completion."
1038   (interactive (list
1039                 (completing-read
1040                  "Minor mode indicator: "
1041                  (describe-minor-mode-completion-table-for-indicator))))
1042   (let ((minor-mode (lookup-minor-mode-from-indicator indicator)))
1043     (if minor-mode
1044         (describe-minor-mode-from-symbol minor-mode)
1045       (error "Cannot find minor mode for `%s'" indicator))))
1046
1047 (defun lookup-minor-mode-from-indicator (indicator)
1048   "Return a minor mode symbol from its indicator on the mode line."
1049   ;; remove first space if existed
1050   (if (and (< 0 (length indicator))
1051            (eq (aref indicator 0) ?\s))
1052       (setq indicator (substring indicator 1)))
1053   (let ((minor-modes minor-mode-alist)
1054         result)
1055     (while minor-modes
1056       (let* ((minor-mode (car (car minor-modes)))
1057              (anindicator (format-mode-line
1058                            (car (cdr (car minor-modes))))))
1059         ;; remove first space if existed
1060         (if (and (stringp anindicator)
1061                  (> (length anindicator) 0)
1062                  (eq (aref anindicator 0) ?\s))
1063             (setq anindicator (substring anindicator 1)))
1064         (if (equal indicator anindicator)
1065             (setq result minor-mode
1066                   minor-modes nil)
1067           (setq minor-modes (cdr minor-modes)))))
1068     result))
1069 \f
1070 ;;; Automatic resizing of temporary buffers.
1071 (defcustom temp-buffer-max-height
1072   (lambda (buffer)
1073     (if (eq (selected-window) (frame-root-window))
1074         (/ (x-display-pixel-height) (frame-char-height) 2)
1075       (/ (- (frame-height) 2) 2)))
1076   "Maximum height of a window displaying a temporary buffer.
1077 This is effective only when Temp Buffer Resize mode is enabled.
1078 The value is the maximum height (in lines) which
1079 `resize-temp-buffer-window' will give to a window displaying a
1080 temporary buffer.  It can also be a function to be called to
1081 choose the height for such a buffer.  It gets one argument, the
1082 buffer, and should return a positive integer.  At the time the
1083 function is called, the window to be resized is selected."
1084   :type '(choice integer function)
1085   :group 'help
1086   :version "24.3")
1087
1088 (defcustom temp-buffer-max-width
1089   (lambda (buffer)
1090     (if (eq (selected-window) (frame-root-window))
1091         (/ (x-display-pixel-width) (frame-char-width) 2)
1092       (/ (- (frame-width) 2) 2)))
1093   "Maximum width of a window displaying a temporary buffer.
1094 This is effective only when Temp Buffer Resize mode is enabled.
1095 The value is the maximum width (in columns) which
1096 `resize-temp-buffer-window' will give to a window displaying a
1097 temporary buffer.  It can also be a function to be called to
1098 choose the width for such a buffer.  It gets one argument, the
1099 buffer, and should return a positive integer.  At the time the
1100 function is called, the window to be resized is selected."
1101   :type '(choice integer function)
1102   :group 'help
1103   :version "24.4")
1104
1105 (define-minor-mode temp-buffer-resize-mode
1106   "Toggle auto-resizing temporary buffer windows (Temp Buffer Resize Mode).
1107 With a prefix argument ARG, enable Temp Buffer Resize mode if ARG
1108 is positive, and disable it otherwise.  If called from Lisp,
1109 enable the mode if ARG is omitted or nil.
1110
1111 When Temp Buffer Resize mode is enabled, the windows in which we
1112 show a temporary buffer are automatically resized in height to
1113 fit the buffer's contents, but never more than
1114 `temp-buffer-max-height' nor less than `window-min-height'.
1115
1116 A window is resized only if it has been specially created for the
1117 buffer.  Windows that have shown another buffer before are not
1118 resized.  A frame is resized only if `fit-frame-to-buffer' is
1119 non-nil.
1120
1121 This mode is used by `help', `apropos' and `completion' buffers,
1122 and some others."
1123   :global t :group 'help
1124   (if temp-buffer-resize-mode
1125       ;; `help-make-xrefs' may add a `back' button and thus increase the
1126       ;; text size, so `resize-temp-buffer-window' must be run *after* it.
1127       (add-hook 'temp-buffer-show-hook 'resize-temp-buffer-window 'append)
1128     (remove-hook 'temp-buffer-show-hook 'resize-temp-buffer-window)))
1129
1130 (defun resize-temp-buffer-window (&optional window)
1131   "Resize WINDOW to fit its contents.
1132 WINDOW must be a live window and defaults to the selected one.
1133 Do not resize if WINDOW was not created by `display-buffer'.
1134
1135 If WINDOW is part of a vertical combination, restrain its new
1136 size by `temp-buffer-max-height' and do not resize if its minimum
1137 accessible position is scrolled out of view.  If WINDOW is part
1138 of a horizontal combination, restrain its new size by
1139 `temp-buffer-max-width'.  In both cases, the value of the option
1140 `fit-window-to-buffer-horizontally' can inhibit resizing.
1141
1142 If WINDOW is the root window of its frame, resize the frame
1143 provided `fit-frame-to-buffer' is non-nil.
1144
1145 This function may call `preserve-window-size' to preserve the
1146 size of WINDOW."
1147   (setq window (window-normalize-window window t))
1148   (let ((height (if (functionp temp-buffer-max-height)
1149                     (with-selected-window window
1150                       (funcall temp-buffer-max-height (window-buffer)))
1151                   temp-buffer-max-height))
1152         (width (if (functionp temp-buffer-max-width)
1153                    (with-selected-window window
1154                      (funcall temp-buffer-max-width (window-buffer)))
1155                  temp-buffer-max-width))
1156         (quit-cadr (cadr (window-parameter window 'quit-restore))))
1157     ;; Resize WINDOW iff it was made by `display-buffer'.
1158     (when (or (and (eq quit-cadr 'window)
1159                    (or (and (window-combined-p window)
1160                             (not (eq fit-window-to-buffer-horizontally
1161                                      'only))
1162                             (pos-visible-in-window-p (point-min) window))
1163                        (and (window-combined-p window t)
1164                             fit-window-to-buffer-horizontally)))
1165               (and (eq quit-cadr 'frame)
1166                      fit-frame-to-buffer
1167                      (eq window (frame-root-window window))))
1168         (fit-window-to-buffer window height nil width nil t))))
1169
1170 ;;; Help windows.
1171 (defcustom help-window-select nil
1172   "Non-nil means select help window for viewing.
1173 Choices are:
1174
1175  never (nil) Select help window only if there is no other window
1176              on its frame.
1177
1178  other       Select help window if and only if it appears on the
1179              previously selected frame, that frame contains at
1180              least two other windows and the help window is
1181              either new or showed a different buffer before.
1182
1183  always (t)  Always select the help window.
1184
1185 If this option is non-nil and the help window appears on another
1186 frame, then give that frame input focus too.  Note also that if
1187 the help window appears on another frame, it may get selected and
1188 its frame get input focus even if this option is nil.
1189
1190 This option has effect if and only if the help window was created
1191 by `with-help-window'."
1192   :type '(choice (const :tag "never (nil)" nil)
1193                  (const :tag "other" other)
1194                  (const :tag "always (t)" t))
1195   :group 'help
1196   :version "23.1")
1197
1198 (defcustom help-enable-auto-load t
1199   "Whether Help commands can perform autoloading.
1200 If non-nil, whenever \\[describe-function] is called for an
1201 autoloaded function whose docstring contains any key substitution
1202 construct (see `substitute-command-keys'), the library is loaded,
1203 so that the documentation can show the right key bindings."
1204   :type 'boolean
1205   :group 'help
1206   :version "24.3")
1207
1208 (defun help-window-display-message (quit-part window &optional scroll)
1209   "Display message telling how to quit and scroll help window.
1210 QUIT-PART is a string telling how to quit the help window WINDOW.
1211 Optional argument SCROLL non-nil means tell how to scroll WINDOW.
1212 SCROLL equal `other' means tell how to scroll the \"other\"
1213 window."
1214   (let ((scroll-part
1215          (cond
1216           ;; If we don't have QUIT-PART we probably reuse a window
1217           ;; showing the same buffer so we don't show any message.
1218           ((not quit-part) nil)
1219           ((pos-visible-in-window-p
1220             (with-current-buffer (window-buffer window)
1221               (point-max)) window t)
1222            ;; Buffer end is at least partially visible, no need to talk
1223            ;; about scrolling.
1224            ".")
1225           ((eq scroll 'other)
1226            ", \\[scroll-other-window] to scroll help.")
1227           (scroll ", \\[scroll-up] to scroll help."))))
1228     (message "%s"
1229      (substitute-command-keys (concat quit-part scroll-part)))))
1230
1231 (defun help-window-setup (window &optional value)
1232   "Set up help window WINDOW for `with-help-window'.
1233 WINDOW is the window used for displaying the help buffer.
1234 Return VALUE."
1235   (let* ((help-buffer (when (window-live-p window)
1236                         (window-buffer window)))
1237          (help-setup (when (window-live-p window)
1238                        (car (window-parameter window 'quit-restore))))
1239          (frame (window-frame window)))
1240
1241     (when help-buffer
1242       ;; Handle `help-window-point-marker'.
1243       (when (eq (marker-buffer help-window-point-marker) help-buffer)
1244         (set-window-point window help-window-point-marker)
1245         ;; Reset `help-window-point-marker'.
1246         (set-marker help-window-point-marker nil))
1247
1248       ;; If the help window appears on another frame, select it if
1249       ;; `help-window-select' is non-nil and give that frame input focus
1250       ;; too.  See also Bug#19012.
1251       (when (and help-window-select
1252                  (frame-live-p help-window-old-frame)
1253                  (not (eq frame help-window-old-frame)))
1254         (select-window window)
1255         (select-frame-set-input-focus frame))
1256
1257       (cond
1258        ((or (eq window (selected-window))
1259             ;; If the help window is on the selected frame, select
1260             ;; it if `help-window-select' is t or `help-window-select'
1261             ;; is 'other, the frame contains at least three windows, and
1262             ;; the help window did show another buffer before.  See also
1263             ;; Bug#11039.
1264             (and (eq frame (selected-frame))
1265                  (or (eq help-window-select t)
1266                      (and (eq help-window-select 'other)
1267                           (> (length (window-list nil 'no-mini)) 2)
1268                           (not (eq help-setup 'same))))
1269                  (select-window window)))
1270         ;; The help window is or gets selected ...
1271         (help-window-display-message
1272          (cond
1273           ((eq help-setup 'window)
1274            ;; ... and is new, ...
1275            "Type \"q\" to delete help window")
1276           ((eq help-setup 'frame)
1277            ;; ... on a new frame, ...
1278            "Type \"q\" to quit the help frame")
1279           ((eq help-setup 'other)
1280            ;; ... or displayed some other buffer before.
1281            "Type \"q\" to restore previous buffer"))
1282          window t))
1283        ((and (eq (window-frame window) help-window-old-frame)
1284              (= (length (window-list nil 'no-mini)) 2))
1285         ;; There are two windows on the help window's frame and the
1286         ;; other one is the selected one.
1287         (help-window-display-message
1288          (cond
1289           ((eq help-setup 'window)
1290            "Type \\[delete-other-windows] to delete the help window")
1291           ((eq help-setup 'other)
1292            "Type \"q\" in help window to restore its previous buffer"))
1293          window 'other))
1294        (t
1295         ;; The help window is not selected ...
1296         (help-window-display-message
1297          (cond
1298           ((eq help-setup 'window)
1299            ;; ... and is new, ...
1300            "Type \"q\" in help window to delete it")
1301           ((eq help-setup 'other)
1302            ;; ... or displayed some other buffer before.
1303            "Type \"q\" in help window to restore previous buffer"))
1304          window))))
1305     ;; Return VALUE.
1306     value))
1307
1308 ;; `with-help-window' is a wrapper for `with-temp-buffer-window'
1309 ;; providing the following additional twists:
1310
1311 ;; (1) It puts the buffer in `help-mode' (via `help-mode-setup') and
1312 ;;     adds cross references (via `help-mode-finish').
1313
1314 ;; (2) It issues a message telling how to scroll and quit the help
1315 ;;     window (via `help-window-setup').
1316
1317 ;; (3) An option (customizable via `help-window-select') to select the
1318 ;;     help window automatically.
1319
1320 ;; (4) A marker (`help-window-point-marker') to move point in the help
1321 ;;     window to an arbitrary buffer position.
1322 (defmacro with-help-window (buffer-name &rest body)
1323   "Display buffer named BUFFER-NAME in a help window.
1324 Evaluate the forms in BODY with standard output bound to a buffer
1325 called BUFFER-NAME (creating it if it does not exist), put that
1326 buffer in `help-mode', display the buffer in a window (see
1327 `with-temp-buffer-window' for details) and issue a message how to
1328 deal with that \"help\" window when it's no more needed.  Select
1329 the help window if the current value of the user option
1330 `help-window-select' says so.  Return last value in BODY."
1331   (declare (indent 1) (debug t))
1332   `(progn
1333      ;; Make `help-window-point-marker' point nowhere.  The only place
1334      ;; where this should be set to a buffer position is within BODY.
1335      (set-marker help-window-point-marker nil)
1336      (let ((temp-buffer-window-setup-hook
1337             (cons 'help-mode-setup temp-buffer-window-setup-hook))
1338            (temp-buffer-window-show-hook
1339             (cons 'help-mode-finish temp-buffer-window-show-hook)))
1340        (setq help-window-old-frame (selected-frame))
1341        (with-temp-buffer-window
1342         ,buffer-name nil 'help-window-setup (progn ,@body)))))
1343
1344 ;; Called from C, on encountering `help-char' when reading a char.
1345 ;; Don't print to *Help*; that would clobber Help history.
1346 (defun help-form-show ()
1347   "Display the output of a non-nil `help-form'."
1348   (let ((msg (eval help-form)))
1349     (if (stringp msg)
1350         (with-output-to-temp-buffer " *Char Help*"
1351           (princ msg)))))
1352
1353 \f
1354 (defun help--docstring-quote (string)
1355   "Return a doc string that represents STRING.
1356 The result, when formatted by ‘substitute-command-keys’, should equal STRING."
1357   (replace-regexp-in-string "['\\`]" "\\\\=\\&" string))
1358
1359 ;; The following functions used to be in help-fns.el, which is not preloaded.
1360 ;; But for various reasons, they are more widely needed, so they were
1361 ;; moved to this file, which is preloaded.  http://debbugs.gnu.org/17001
1362
1363 (defun help-split-fundoc (docstring def)
1364   "Split a function DOCSTRING into the actual doc and the usage info.
1365 Return (USAGE . DOC) or nil if there's no usage info, where USAGE info
1366 is a string describing the argument list of DEF, such as
1367 \"(apply FUNCTION &rest ARGUMENTS)\".
1368 DEF is the function whose usage we're looking for in DOCSTRING."
1369   ;; Functions can get the calling sequence at the end of the doc string.
1370   ;; In cases where `function' has been fset to a subr we can't search for
1371   ;; function's name in the doc string so we use `fn' as the anonymous
1372   ;; function name instead.
1373   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
1374     (let ((doc (unless (zerop (match-beginning 0))
1375                  (substring docstring 0 (match-beginning 0))))
1376           (usage-tail (match-string 1 docstring)))
1377       (cons (format "(%s%s"
1378                     ;; Replace `fn' with the actual function name.
1379                     (if (symbolp def)
1380                         (help--docstring-quote (format "%S" def))
1381                       'anonymous)
1382                     usage-tail)
1383             doc))))
1384
1385 (defun help-add-fundoc-usage (docstring arglist)
1386   "Add the usage info to DOCSTRING.
1387 If DOCSTRING already has a usage info, then just return it unchanged.
1388 The usage info is built from ARGLIST.  DOCSTRING can be nil.
1389 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
1390   (unless (stringp docstring) (setq docstring ""))
1391   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring)
1392           (eq arglist t))
1393       docstring
1394     (concat docstring
1395             (if (string-match "\n?\n\\'" docstring)
1396                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
1397               "\n\n")
1398             (if (and (stringp arglist)
1399                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
1400                 (concat "(fn" (match-string 1 arglist) ")")
1401               (help--make-usage-docstring 'fn arglist)))))
1402
1403 (defun help-function-arglist (def &optional preserve-names)
1404   "Return a formal argument list for the function DEF.
1405 IF PRESERVE-NAMES is non-nil, return a formal arglist that uses
1406 the same names as used in the original source code, when possible."
1407   ;; Handle symbols aliased to other symbols.
1408   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
1409   ;; If definition is a macro, find the function inside it.
1410   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
1411   (cond
1412    ((and (byte-code-function-p def) (listp (aref def 0))) (aref def 0))
1413    ((eq (car-safe def) 'lambda) (nth 1 def))
1414    ((eq (car-safe def) 'closure) (nth 2 def))
1415    ((or (and (byte-code-function-p def) (integerp (aref def 0)))
1416         (subrp def))
1417     (or (when preserve-names
1418           (let* ((doc (condition-case nil (documentation def) (error nil)))
1419                  (docargs (if doc (car (help-split-fundoc doc nil))))
1420                  (arglist (if docargs
1421                               (cdar (read-from-string (downcase docargs)))))
1422                  (valid t))
1423             ;; Check validity.
1424             (dolist (arg arglist)
1425               (unless (and (symbolp arg)
1426                            (let ((name (symbol-name arg)))
1427                              (if (eq (aref name 0) ?&)
1428                                  (memq arg '(&rest &optional))
1429                                (not (string-match "\\." name)))))
1430                 (setq valid nil)))
1431             (when valid arglist)))
1432         (let* ((args-desc (if (not (subrp def))
1433                               (aref def 0)
1434                             (let ((a (subr-arity def)))
1435                               (logior (car a)
1436                                       (if (numberp (cdr a))
1437                                           (lsh (cdr a) 8)
1438                                         (lsh 1 7))))))
1439                (max (lsh args-desc -8))
1440                (min (logand args-desc 127))
1441                (rest (logand args-desc 128))
1442                (arglist ()))
1443           (dotimes (i min)
1444             (push (intern (concat "arg" (number-to-string (1+ i)))) arglist))
1445           (when (> max min)
1446             (push '&optional arglist)
1447             (dotimes (i (- max min))
1448               (push (intern (concat "arg" (number-to-string (+ 1 i min))))
1449                     arglist)))
1450           (unless (zerop rest) (push '&rest arglist) (push 'rest arglist))
1451           (nreverse arglist))))
1452    ((and (autoloadp def) (not (eq (nth 4 def) 'keymap)))
1453     "[Arg list not available until function definition is loaded.]")
1454    (t t)))
1455
1456 (defun help--make-usage (function arglist)
1457   (cons (if (symbolp function) function 'anonymous)
1458         (mapcar (lambda (arg)
1459                   (if (not (symbolp arg)) arg
1460                     (let ((name (symbol-name arg)))
1461                       (cond
1462                        ((string-match "\\`&" name) arg)
1463                        ((string-match "\\`_." name)
1464                         (intern (upcase (substring name 1))))
1465                        (t (intern (upcase name)))))))
1466                 arglist)))
1467
1468 (define-obsolete-function-alias 'help-make-usage 'help--make-usage "25.1")
1469
1470 (defun help--make-usage-docstring (fn arglist)
1471   (help--docstring-quote (format "%S" (help--make-usage fn arglist))))
1472
1473 \f
1474 (provide 'help)
1475
1476 ;;; help.el ends here