test/automated/vc-tests.el

   1 ;;; vc-tests.el --- Tests of different backends of vc.el
   2
   3 ;; Copyright (C) 2014-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael Albinus <michael.albinus@gmx.de>
   6
   7 ;; This program is free software: you can redistribute it and/or
   8 ;; modify it under the terms of the GNU General Public License as
   9 ;; published by the Free Software Foundation, either version 3 of the
  10 ;; License, or (at your option) any later version.
  11 ;;
  12 ;; This program is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with this program.  If not, see `http://www.gnu.org/licenses/'.
  19
  20 ;;; Commentary:
  21
  22 ;; For every supported VC on the machine, different test cases are
  23 ;; generated automatically.
  24
  25 ;; Functions to be tested (see Commentary of vc.el).  Mandatory
  26 ;; functions are marked with `*', optional functions are marked with `-':
  27
  28 ;; BACKEND PROPERTIES
  29 ;;
  30 ;; * revision-granularity
  31
  32 ;; STATE-QUERYING FUNCTIONS
  33 ;;
  34 ;; * registered (file)
  35 ;; * state (file)
  36 ;; - dir-status (dir update-function)
  37 ;; - dir-status-files (dir files default-state update-function)
  38 ;; - dir-extra-headers (dir)
  39 ;; - dir-printer (fileinfo)
  40 ;; - status-fileinfo-extra (file)
  41 ;; * working-revision (file)
  42 ;; - latest-on-branch-p (file)
  43 ;; * checkout-model (files)
  44 ;; - mode-line-string (file)
  45
  46 ;; STATE-CHANGING FUNCTIONS
  47 ;;
  48 ;; * create-repo (backend)
  49 ;; * register (files &optional comment)
  50 ;; - responsible-p (file)
  51 ;; - receive-file (file rev)
  52 ;; - unregister (file)
  53 ;; * checkin (files comment)
  54 ;; * find-revision (file rev buffer)
  55 ;; * checkout (file &optional rev)
  56 ;; * revert (file &optional contents-done)
  57 ;; - rollback (files)
  58 ;; - merge-file (file rev1 rev2)
  59 ;; - merge-branch ()
  60 ;; - merge-news (file)
  61 ;; - pull (prompt)
  62 ;; - steal-lock (file &optional revision)
  63 ;; - modify-change-comment (files rev comment)
  64 ;; - mark-resolved (files)
  65 ;; - find-admin-dir (file)
  66
  67 ;; HISTORY FUNCTIONS
  68 ;;
  69 ;; * print-log (files buffer &optional shortlog start-revision limit)
  70 ;; * log-outgoing (backend remote-location)
  71 ;; * log-incoming (backend remote-location)
  72 ;; - log-view-mode ()
  73 ;; - show-log-entry (revision)
  74 ;; - comment-history (file)
  75 ;; - update-changelog (files)
  76 ;; * diff (files &optional async rev1 rev2 buffer)
  77 ;; - revision-completion-table (files)
  78 ;; - annotate-command (file buf &optional rev)
  79 ;; - annotate-time ()
  80 ;; - annotate-current-time ()
  81 ;; - annotate-extract-revision-at-line ()
  82 ;; - region-history (FILE BUFFER LFROM LTO)
  83 ;; - region-history-mode ()
  84
  85 ;; TAG SYSTEM
  86 ;;
  87 ;; - create-tag (dir name branchp)
  88 ;; - retrieve-tag (dir name update)
  89
  90 ;; MISCELLANEOUS
  91 ;;
  92 ;; - make-version-backups-p (file)
  93 ;; - root (file)
  94 ;; - ignore (file &optional directory)
  95 ;; - ignore-completion-table
  96 ;; - previous-revision (file rev)
  97 ;; - next-revision (file rev)
  98 ;; - log-edit-mode ()
  99 ;; - check-headers ()
 100 ;; - delete-file (file)
 101 ;; - rename-file (old new)
 102 ;; - find-file-hook ()
 103 ;; - extra-menu ()
 104 ;; - extra-dir-menu ()
 105 ;; - conflicted-files (dir)
 106
 107 ;;; Code:
 108
 109 (require 'ert)
 110 (require 'vc)
 111
 112 ;; The working horses.
 113
 114 (defvar vc-test--cleanup-hook nil
 115   "Functions for cleanup at the end of an ert test.
 116 Don't set it globally, the functions shall be let-bound.")
 117
 118 (defun vc-test--revision-granularity-function (backend)
 119   "Run the `vc-revision-granularity' backend function."
 120   (funcall (intern (downcase (format "vc-%s-revision-granularity" backend)))))
 121
 122 (defun vc-test--create-repo-function (backend)
 123   "Run the `vc-create-repo' backend function.
 124 For backends which dont support it, it is emulated."
 125
 126   (cond
 127    ((eq backend 'CVS)
 128     (let ((tmp-dir
 129            (expand-file-name
 130             (make-temp-name "vc-test") temporary-file-directory)))
 131       (make-directory (expand-file-name "module" tmp-dir) 'parents)
 132       (make-directory (expand-file-name "CVSROOT" tmp-dir) 'parents)
 133       (shell-command-to-string (format "cvs -Q -d:local:%s co module" tmp-dir))
 134       (rename-file "module/CVS" default-directory)
 135       (delete-directory "module" 'recursive)
 136       ;; We must cleanup the "remote" CVS repo as well.
 137       (add-hook 'vc-test--cleanup-hook
 138                 `(lambda () (delete-directory ,tmp-dir 'recursive)))))
 139
 140    ((eq backend 'Arch)
 141     (let ((archive-name (format "%s--%s" user-mail-address (random))))
 142       (when (string-match
 143              "no arch user id set" (shell-command-to-string "tla my-id"))
 144         (shell-command-to-string
 145          (format "tla my-id \"<%s>\"" user-mail-address)))
 146       (shell-command-to-string
 147        (format "tla make-archive %s %s" archive-name default-directory))
 148       (shell-command-to-string
 149        (format "tla my-default-archive %s" archive-name))))
 150
 151    ((eq backend 'Mtn)
 152     (let ((archive-name "foo.mtn"))
 153       (shell-command-to-string
 154        (format
 155         "mtn db init --db=%s"
 156         (expand-file-name archive-name default-directory)))
 157       (shell-command-to-string
 158        (format "mtn --db=%s --branch=foo setup ." archive-name))))
 159
 160    (t (vc-create-repo backend))))
 161
 162 (defun vc-test--create-repo (backend)
 163   "Create a test repository in `default-directory', a temporary directory."
 164
 165   (let ((vc-handled-backends `(,backend))
 166         (default-directory
 167           (file-name-as-directory
 168            (expand-file-name
 169             (make-temp-name "vc-test") temporary-file-directory)))
 170         vc-test--cleanup-hook)
 171
 172     (unwind-protect
 173         (progn
 174           ;; Cleanup.
 175           (add-hook
 176            'vc-test--cleanup-hook
 177            `(lambda () (delete-directory ,default-directory 'recursive)))
 178
 179           ;; Check the revision granularity.
 180           (should (memq (vc-test--revision-granularity-function backend)
 181                  '(file repository)))
 182
 183           ;; Create empty repository.
 184           (make-directory default-directory)
 185           (should (file-directory-p default-directory))
 186           (vc-test--create-repo-function backend))
 187
 188       ;; Save exit.
 189       (ignore-errors (run-hooks 'vc-test--cleanup-hook)))))
 190
 191 ;; Why isn't there `vc-unregister'?
 192 (defun vc-test--unregister-function (backend file)
 193   "Run the `vc-unregister' backend function.
 194 For backends which dont support it, `vc-not-supported' is signalled."
 195
 196   (let ((symbol (intern (downcase (format "vc-%s-unregister" backend)))))
 197     (if (functionp symbol)
 198         (funcall symbol file)
 199       ;; CVS, SVN, SCCS, SRC and Mtn are not supported.
 200       (signal 'vc-not-supported (list 'unregister backend)))))
 201
 202 (defun vc-test--register (backend)
 203   "Register and unregister a file."
 204
 205   (let ((vc-handled-backends `(,backend))
 206         (default-directory
 207           (file-name-as-directory
 208            (expand-file-name
 209             (make-temp-name "vc-test") temporary-file-directory)))
 210         vc-test--cleanup-hook)
 211
 212     (unwind-protect
 213         (progn
 214           ;; Cleanup.
 215           (add-hook
 216            'vc-test--cleanup-hook
 217            `(lambda () (delete-directory ,default-directory 'recursive)))
 218
 219           ;; Create empty repository.
 220           (make-directory default-directory)
 221           (vc-test--create-repo-function backend)
 222
 223           (let ((tmp-name1 (expand-file-name "foo" default-directory))
 224                 (tmp-name2 "bla"))
 225             ;; Register files.  Check for it.
 226             (write-region "foo" nil tmp-name1 nil 'nomessage)
 227             (should (file-exists-p tmp-name1))
 228             (should-not (vc-registered tmp-name1))
 229             (write-region "bla" nil tmp-name2 nil 'nomessage)
 230             (should (file-exists-p tmp-name2))
 231             (should-not (vc-registered tmp-name2))
 232             (vc-register
 233              (list backend (list tmp-name1 tmp-name2)))
 234             (should (file-exists-p tmp-name1))
 235             (should (vc-registered tmp-name1))
 236             (should (file-exists-p tmp-name2))
 237             (should (vc-registered tmp-name2))
 238
 239             ;; Unregister the files.
 240             (condition-case err
 241                 (progn
 242                   (vc-test--unregister-function backend tmp-name1)
 243                   (should-not (vc-registered tmp-name1))
 244                   (vc-test--unregister-function backend tmp-name2)
 245                   (should-not (vc-registered tmp-name2)))
 246               ;; CVS, SVN, SCCS, SRC and Mtn are not supported.
 247               (vc-not-supported (message "%s" (error-message-string err))))
 248             (should (file-exists-p tmp-name1))
 249             (should (file-exists-p tmp-name2))))
 250
 251       ;; Save exit.
 252       (ignore-errors (run-hooks 'vc-test--cleanup-hook)))))
 253
 254 ;; `vc-state' returns different results for different backends.  So we
 255 ;; don't check with `should', but print the results for analysis.
 256 (defun vc-test--state (backend)
 257   "Check the different states of a file."
 258
 259   (let ((vc-handled-backends `(,backend))
 260         (default-directory
 261           (file-name-as-directory
 262            (expand-file-name
 263             (make-temp-name "vc-test") temporary-file-directory)))
 264         vc-test--cleanup-hook errors)
 265
 266     (unwind-protect
 267         (progn
 268           ;; Cleanup.
 269           (add-hook
 270            'vc-test--cleanup-hook
 271            `(lambda () (delete-directory ,default-directory 'recursive)))
 272
 273           ;; Create empty repository.
 274           (make-directory default-directory)
 275           (vc-test--create-repo-function backend)
 276
 277           (message "%s" (vc-state default-directory backend))
 278           ;(should (eq (vc-state default-directory backend) 'up-to-date))
 279
 280           (let ((tmp-name (expand-file-name "foo" default-directory)))
 281             ;; Check for initial state.
 282             (message "%s" (vc-state tmp-name backend))
 283             ;(should (eq (vc-state tmp-name backend) 'unregistered))
 284
 285             ;; Write a new file.  Check for state.
 286             (write-region "foo" nil tmp-name nil 'nomessage)
 287             (message "%s" (vc-state tmp-name backend))
 288             ;(should (eq (vc-state tmp-name backend) 'unregistered))
 289
 290             ;; Register a file.  Check for state.
 291             (vc-register
 292              (list backend (list (file-name-nondirectory tmp-name))))
 293             (message "%s" (vc-state tmp-name backend))
 294             ;(should (eq (vc-state tmp-name backend) 'added))
 295
 296             ;; Unregister the file.  Check for state.
 297             (condition-case nil
 298                 (progn
 299                   (vc-test--unregister-function backend tmp-name)
 300                   (message "%s" (vc-state tmp-name backend))
 301                   );(should (eq (vc-state tmp-name backend) 'unregistered)))
 302               (vc-not-supported (message "%s" 'unsupported)))))
 303
 304       ;; Save exit.
 305       (ignore-errors (run-hooks 'vc-test--cleanup-hook)))))
 306
 307 (defun vc-test--working-revision (backend)
 308   "Check the working revision of a repository."
 309
 310   (let ((vc-handled-backends `(,backend))
 311         (default-directory
 312           (file-name-as-directory
 313            (expand-file-name
 314             (make-temp-name "vc-test") temporary-file-directory)))
 315         vc-test--cleanup-hook errors)
 316
 317     (unwind-protect
 318         (progn
 319           ;; Cleanup.
 320           (add-hook
 321            'vc-test--cleanup-hook
 322            `(lambda () (delete-directory ,default-directory 'recursive)))
 323
 324           ;; Create empty repository.
 325           (make-directory default-directory)
 326           (vc-test--create-repo-function backend)
 327
 328           (should
 329            (member
 330             (vc-working-revision default-directory backend) '("0" "master")))
 331
 332           (let ((tmp-name (expand-file-name "foo" default-directory)))
 333             ;; Check for initial state.
 334             (should
 335              (member (vc-working-revision tmp-name backend) '("0" "master")))
 336
 337             ;; Write a new file.  Check for state.
 338             (write-region "foo" nil tmp-name nil 'nomessage)
 339             (should
 340              (member (vc-working-revision tmp-name backend) '("0" "master")))
 341
 342             ;; Register a file.  Check for state.
 343             (vc-register
 344              (list backend (list (file-name-nondirectory tmp-name))))
 345             (should
 346              (member (vc-working-revision tmp-name backend) '("0" "master")))
 347
 348             ;; Unregister the file.  Check for working-revision.
 349             (condition-case nil
 350                 (progn
 351                   (vc-test--unregister-function backend tmp-name)
 352                   (should
 353                    (member
 354                     (vc-working-revision tmp-name backend) '("0" "master"))))
 355               (vc-not-supported (message "%s" 'unsupported)))))
 356
 357       ;; Save exit.
 358       (ignore-errors (run-hooks 'vc-test--cleanup-hook)))))
 359
 360 ;; Create the test cases.
 361
 362 (defun vc-test--rcs-enabled ()
 363   (executable-find "rcs"))
 364
 365 (defun vc-test--cvs-enabled ()
 366   (executable-find "cvs"))
 367
 368 (defvar vc-svn-program)
 369 (defun vc-test--svn-enabled ()
 370   (executable-find vc-svn-program))
 371
 372 (defun vc-test--sccs-enabled ()
 373   (executable-find "sccs"))
 374
 375 (defvar vc-src-program)
 376 (defun vc-test--src-enabled ()
 377   (executable-find vc-src-program))
 378
 379 (defvar vc-bzr-program)
 380 (defun vc-test--bzr-enabled ()
 381   (executable-find vc-bzr-program))
 382
 383 (defvar vc-git-program)
 384 (defun vc-test--git-enabled ()
 385   (executable-find vc-git-program))
 386
 387 (defvar vc-hg-program)
 388 (defun vc-test--hg-enabled ()
 389   (executable-find vc-hg-program))
 390
 391 (defvar vc-mtn-program)
 392 (defun vc-test--mtn-enabled ()
 393   (executable-find vc-mtn-program))
 394
 395 (defvar vc-arch-program)
 396 (defun vc-test--arch-enabled ()
 397   (executable-find vc-arch-program))
 398
 399
 400 ;; There are too many failed test cases yet.  We suppress them on hydra.
 401 (if (getenv "NIX_STORE")
 402     (ert-deftest vc-test ()
 403       "Dummy test case for hydra."
 404       (ert-pass))
 405
 406   ;; Create the test cases.
 407   (dolist (backend vc-handled-backends)
 408     (let ((backend-string (downcase (symbol-name backend))))
 409       (require (intern (format "vc-%s" backend-string)))
 410       (eval
 411        ;; Check, whether the backend is supported.
 412        `(when (funcall ',(intern (format "vc-test--%s-enabled" backend-string)))
 413
 414           (ert-deftest
 415               ,(intern (format "vc-test-%s00-create-repo" backend-string)) ()
 416             ,(format "Check `vc-create-repo' for the %s backend." backend-string)
 417             (vc-test--create-repo ',backend))
 418
 419           (ert-deftest
 420               ,(intern (format "vc-test-%s01-register" backend-string)) ()
 421             ,(format
 422               "Check `vc-register' and `vc-registered' for the %s backend."
 423               backend-string)
 424             (skip-unless
 425              (ert-test-passed-p
 426               (ert-test-most-recent-result
 427                (ert-get-test
 428                 ',(intern
 429                    (format "vc-test-%s00-create-repo" backend-string))))))
 430             (vc-test--register ',backend))
 431
 432           (ert-deftest
 433               ,(intern (format "vc-test-%s02-state" backend-string)) ()
 434             ,(format "Check `vc-state' for the %s backend." backend-string)
 435             (skip-unless
 436              (ert-test-passed-p
 437               (ert-test-most-recent-result
 438                (ert-get-test
 439                 ',(intern
 440                    (format "vc-test-%s01-register" backend-string))))))
 441             (vc-test--state ',backend))
 442
 443           (ert-deftest
 444               ,(intern (format "vc-test-%s03-working-revision" backend-string)) ()
 445             ,(format "Check `vc-working-revision' for the %s backend." backend-string)
 446             (skip-unless
 447              (ert-test-passed-p
 448               (ert-test-most-recent-result
 449                (ert-get-test
 450                 ',(intern
 451                    (format "vc-test-%s01-register" backend-string))))))
 452             (vc-test--working-revision ',backend)))))))
 453
 454 (provide 'vc-tests)
 455 ;;; vc-tests.el ends here