lisp/url/url-cookie.el

   1 ;;; url-cookie.el --- URL cookie support
   2
   3 ;; Copyright (C) 1996-1999, 2004-2015 Free Software Foundation, Inc.
   4
   5 ;; Keywords: comm, data, processes, hypermedia
   6
   7 ;; This file is part of GNU Emacs.
   8 ;;
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (require 'url-util)
  27 (require 'url-parse)
  28 (require 'url-domsuf)
  29
  30 (eval-when-compile (require 'cl-lib))
  31
  32 (defgroup url-cookie nil
  33   "URL cookies."
  34   :prefix "url-"
  35   :prefix "url-cookie-"
  36   :group 'url)
  37
  38 ;; A cookie is stored internally as a vector of 7 slots
  39 ;; [ url-cookie NAME VALUE EXPIRES LOCALPART DOMAIN SECURE ]
  40
  41 (cl-defstruct (url-cookie
  42             (:constructor url-cookie-create)
  43             (:copier nil)
  44             (:type vector)
  45             :named)
  46   name value expires localpart domain secure)
  47
  48 (defvar url-cookie-storage nil         "Where cookies are stored.")
  49 (defvar url-cookie-secure-storage nil  "Where secure cookies are stored.")
  50 (defcustom url-cookie-file nil
  51   "File where cookies are stored on disk."
  52   :type '(choice (const :tag "Default" :value nil) file)
  53   :group 'url-file
  54   :group 'url-cookie)
  55
  56 (defcustom url-cookie-confirmation nil
  57   "If non-nil, confirmation by the user is required to accept HTTP cookies."
  58   :type 'boolean
  59   :group 'url-cookie)
  60
  61 (defcustom url-cookie-multiple-line nil
  62   "If nil, HTTP requests put all cookies for the server on one line.
  63 Some web servers, such as http://www.hotmail.com/, only accept cookies
  64 when they are on one line.  This is broken behavior, but just try
  65 telling Microsoft that."
  66   :type 'boolean
  67   :group 'url-cookie)
  68
  69 (defvar url-cookies-changed-since-last-save nil
  70   "Whether the cookies list has changed since the last save operation.")
  71
  72 (defun url-cookie-parse-file (&optional fname)
  73   "Load FNAME, default `url-cookie-file'."
  74   ;; It's completely normal for the cookies file not to exist yet.
  75   (load (or fname url-cookie-file) t t))
  76
  77 (defun url-cookie-clean-up (&optional secure)
  78   (let ((var (if secure 'url-cookie-secure-storage 'url-cookie-storage))
  79         new new-cookies)
  80     (dolist (cur (symbol-value var))
  81       (setq new-cookies nil)
  82       (dolist (cur-cookie (cdr cur))
  83         (or (not (url-cookie-p cur-cookie))
  84             (url-cookie-expired-p cur-cookie)
  85             (null (url-cookie-expires cur-cookie))
  86             (setq new-cookies (cons cur-cookie new-cookies))))
  87       (when new-cookies
  88         (setcdr cur new-cookies)
  89         (setq new (cons cur new))))
  90     (set var new)))
  91
  92 (defun url-cookie-write-file (&optional fname)
  93   (when url-cookies-changed-since-last-save
  94     (or fname (setq fname (expand-file-name url-cookie-file)))
  95     (if (condition-case nil
  96             (progn
  97               (url-make-private-file fname)
  98               nil)
  99           (error t))
 100         (message "Error accessing cookie file `%s'" fname)
 101     (url-cookie-clean-up)
 102     (url-cookie-clean-up t)
 103     (with-temp-buffer
 104       (insert ";; Emacs-W3 HTTP cookies file\n"
 105               ";; Automatically generated file!!! DO NOT EDIT!!!\n\n"
 106               "(setq url-cookie-storage\n '")
 107       (pp url-cookie-storage (current-buffer))
 108       (insert ")\n(setq url-cookie-secure-storage\n '")
 109       (pp url-cookie-secure-storage (current-buffer))
 110       (insert ")\n")
 111       (insert "\f\n;; Local Variables:\n"
 112               ";; version-control: never\n"
 113               ";; no-byte-compile: t\n"
 114               ";; End:\n")
 115       (set (make-local-variable 'version-control) 'never)
 116       (write-file fname))
 117     (setq url-cookies-changed-since-last-save nil))))
 118
 119 (defun url-cookie-store (name value &optional expires domain localpart secure)
 120   "Store a cookie."
 121   (let ((storage (if secure url-cookie-secure-storage url-cookie-storage))
 122         tmp found-domain)
 123     ;; First, look for a matching domain.
 124     (if (setq found-domain (assoc domain storage))
 125         ;; Need to either stick the new cookie in existing domain storage
 126         ;; or possibly replace an existing cookie if the names match.
 127         (unless (dolist (cur (setq storage (cdr found-domain)) tmp)
 128                   (and (equal localpart (url-cookie-localpart cur))
 129                        (equal name (url-cookie-name cur))
 130                        (progn
 131                          (setf (url-cookie-expires cur) expires)
 132                          (setf (url-cookie-value cur) value)
 133                          (setq tmp t))))
 134           ;; New cookie.
 135           (setcdr found-domain (cons
 136                                 (url-cookie-create :name name
 137                                                    :value value
 138                                                    :expires expires
 139                                                    :domain domain
 140                                                    :localpart localpart
 141                                                    :secure secure)
 142                                 (cdr found-domain))))
 143       ;; Need to add a new top-level domain.
 144       (setq tmp (url-cookie-create :name name
 145                                    :value value
 146                                    :expires expires
 147                                    :domain domain
 148                                    :localpart localpart
 149                                    :secure secure))
 150       (cond (storage
 151              (setcdr storage (cons (list domain tmp) (cdr storage))))
 152             (secure
 153              (setq url-cookie-secure-storage (list (list domain tmp))))
 154             (t
 155              (setq url-cookie-storage (list (list domain tmp))))))))
 156
 157 (defun url-cookie-expired-p (cookie)
 158   "Return non-nil if COOKIE is expired."
 159   (let ((exp (url-cookie-expires cookie)))
 160     (and (> (length exp) 0)
 161          (condition-case ()
 162              (> (float-time) (float-time (date-to-time exp)))
 163            (error nil)))))
 164
 165 (defun url-cookie-retrieve (host &optional localpart secure)
 166   "Retrieve all cookies for a specified HOST and LOCALPART."
 167   (let ((storage (if secure
 168                      (append url-cookie-secure-storage url-cookie-storage)
 169                    url-cookie-storage))
 170         (case-fold-search t)
 171         cookies retval localpart-match)
 172     (dolist (cur storage)
 173       (setq cookies (cdr cur))
 174       (if (and (car cur)
 175                (string-match
 176                 (concat "^.*"
 177                         (regexp-quote
 178                          ;; Remove the dot from wildcard domains
 179                          ;; before matching.
 180                          (if (eq ?. (aref (car cur) 0))
 181                              (substring (car cur) 1)
 182                            (car cur)))
 183                         "$") host))
 184           ;; The domains match - a possible hit!
 185           (dolist (cur cookies)
 186             (and (if (and (stringp
 187                            (setq localpart-match (url-cookie-localpart cur)))
 188                           (stringp localpart))
 189                      (string-match (concat "^" (regexp-quote localpart-match))
 190                                    localpart)
 191                    (equal localpart localpart-match))
 192                  (not (url-cookie-expired-p cur))
 193                  (setq retval (cons cur retval))))))
 194     retval))
 195
 196 (defun url-cookie-generate-header-lines (host localpart secure)
 197   (let ((cookies (url-cookie-retrieve host localpart secure))
 198         retval chunk)
 199     ;; Have to sort this for sending most specific cookies first.
 200     (setq cookies (and cookies
 201                        (sort cookies
 202                              (lambda (x y)
 203                                (> (length (url-cookie-localpart x))
 204                                   (length (url-cookie-localpart y)))))))
 205     (dolist (cur cookies)
 206       (setq chunk (format "%s=%s" (url-cookie-name cur) (url-cookie-value cur))
 207             retval (if (and url-cookie-multiple-line
 208                             (< 80 (+ (length retval) (length chunk) 4)))
 209                        (concat retval "\r\nCookie: " chunk)
 210                      (if retval
 211                          (concat retval "; " chunk)
 212                        (concat "Cookie: " chunk)))))
 213     (if retval
 214         (concat retval "\r\n")
 215       "")))
 216
 217 (defcustom url-cookie-trusted-urls nil
 218   "A list of regular expressions matching URLs to always accept cookies from."
 219   :type '(repeat regexp)
 220   :group 'url-cookie)
 221
 222 (defcustom url-cookie-untrusted-urls nil
 223   "A list of regular expressions matching URLs to never accept cookies from."
 224   :type '(repeat regexp)
 225   :group 'url-cookie)
 226
 227 (defun url-cookie-host-can-set-p (host domain)
 228   (let ((last nil)
 229         (case-fold-search t))
 230     (if (string= host domain)   ; Apparently netscape lets you do this
 231         t
 232       ;; Remove the dot from wildcard domains before matching.
 233       (when (eq ?. (aref domain 0))
 234         (setq domain (substring domain 1)))
 235       (and (url-domsuf-cookie-allowed-p domain)
 236            ;; Need to check and make sure the host is actually _in_ the
 237            ;; domain it wants to set a cookie for though.
 238            (string-match (concat (regexp-quote domain)
 239                                  "$") host)))))
 240
 241 (defun url-cookie-handle-set-cookie (str)
 242   (setq url-cookies-changed-since-last-save t)
 243   (let* ((args (url-parse-args str t))
 244          (case-fold-search t)
 245          (secure (and (assoc-string "secure" args t) t))
 246          (domain (or (cdr-safe (assoc-string "domain" args t))
 247                      (url-host url-current-object)))
 248          (current-url (url-view-url t))
 249          (trusted url-cookie-trusted-urls)
 250          (untrusted url-cookie-untrusted-urls)
 251          (expires (cdr-safe (assoc-string "expires" args t)))
 252          (localpart (or (cdr-safe (assoc-string "path" args t))
 253                         (file-name-directory
 254                          (url-filename url-current-object))))
 255          (rest nil))
 256     (dolist (this args)
 257       (or (member (downcase (car this)) '("secure" "domain" "expires" "path"))
 258           (setq rest (cons this rest))))
 259
 260     ;; Sometimes we get dates that the timezone package cannot handle very
 261     ;; gracefully - take care of this here, instead of in url-cookie-expired-p
 262     ;; to speed things up.
 263     (and expires
 264          (string-match
 265           (concat "^[^,]+, +\\(..\\)-\\(...\\)-\\(..\\) +"
 266                   "\\(..:..:..\\) +\\[*\\([^\]]+\\)\\]*$")
 267           expires)
 268          (setq expires (concat (match-string 1 expires) " "
 269                                (match-string 2 expires) " "
 270                                (match-string 3 expires) " "
 271                                (match-string 4 expires) " ["
 272                                (match-string 5 expires) "]")))
 273
 274     ;; This one is for older Emacs/XEmacs variants that don't
 275     ;; understand this format without tenths of a second in it.
 276     ;; Wednesday, 30-Dec-2037 16:00:00 GMT
 277     ;;       - vs -
 278     ;; Wednesday, 30-Dec-2037 16:00:00.00 GMT
 279     (and expires
 280          (string-match
 281           "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\(\\.[0-9]+\\)*[ \t]+\\([-+a-zA-Z0-9]+\\)"
 282           expires)
 283          (setq expires (concat (match-string 1 expires) "-"     ; day
 284                                (match-string 2 expires) "-"     ; month
 285                                (match-string 3 expires) " "     ; year
 286                                (match-string 4 expires) ".00 " ; hour:minutes:seconds
 287                                (match-string 6 expires)))) ":" ; timezone
 288
 289     (while (consp trusted)
 290       (if (string-match (car trusted) current-url)
 291           (setq trusted (- (match-end 0) (match-beginning 0)))
 292         (pop trusted)))
 293     (while (consp untrusted)
 294       (if (string-match (car untrusted) current-url)
 295           (setq untrusted (- (match-end 0) (match-beginning 0)))
 296         (pop untrusted)))
 297     (and trusted untrusted
 298          ;; Choose the more specific match.
 299          (set (if (> trusted untrusted) 'untrusted 'trusted) nil))
 300     (cond
 301      (untrusted
 302       ;; The site was explicitly marked as untrusted by the user.
 303       nil)
 304      ((or (eq url-privacy-level 'paranoid)
 305           (and (listp url-privacy-level) (memq 'cookies url-privacy-level)))
 306       ;; User never wants cookies.
 307       nil)
 308      ((and url-cookie-confirmation
 309            (not trusted)
 310            (save-window-excursion
 311              (with-output-to-temp-buffer "*Cookie Warning*"
 312                (dolist (x rest)
 313                  (princ (format "%s - %s" (car x) (cdr x)))))
 314              (prog1
 315                  (not (funcall url-confirmation-func
 316                                (format "Allow %s to set these cookies? "
 317                                        (url-host url-current-object))))
 318                (if (get-buffer "*Cookie Warning*")
 319                    (kill-buffer "*Cookie Warning*")))))
 320       ;; User wants to be asked, and declined.
 321       nil)
 322      ((url-cookie-host-can-set-p (url-host url-current-object) domain)
 323       ;; Cookie is accepted by the user, and passes our security checks.
 324       (dolist (cur rest)
 325         (url-cookie-store (car cur) (cdr cur) expires domain localpart secure)))
 326      (t
 327       (url-lazy-message "%s tried to set a cookie for domain %s - rejected."
 328                         (url-host url-current-object) domain)))))
 329
 330 (defvar url-cookie-timer nil)
 331
 332 (defcustom url-cookie-save-interval 3600
 333   "The number of seconds between automatic saves of cookies.
 334 Default is 1 hour.  Note that if you change this variable outside of
 335 the `customize' interface after `url-do-setup' has been run, you need
 336 to run the `url-cookie-setup-save-timer' function manually."
 337   :set #'(lambda (var val)
 338            (set-default var val)
 339            (if (bound-and-true-p url-setup-done)
 340                (url-cookie-setup-save-timer)))
 341   :type 'integer
 342   :group 'url-cookie)
 343
 344 (defun url-cookie-setup-save-timer ()
 345   "Reset the cookie saver timer."
 346   (interactive)
 347   (ignore-errors (cancel-timer url-cookie-timer))
 348   (setq url-cookie-timer nil)
 349   (if url-cookie-save-interval
 350       (setq url-cookie-timer (run-at-time url-cookie-save-interval
 351                                           url-cookie-save-interval
 352                                           #'url-cookie-write-file))))
 353
 354 ;;; Mode for listing and editing cookies.
 355
 356 (defun url-cookie-list ()
 357   "Display a buffer listing the current URL cookies, if there are any.
 358 Use \\<url-cookie-mode-map>\\\[url-cookie-delete] to remove cookies."
 359   (interactive)
 360   (when (and (null url-cookie-secure-storage)
 361              (null url-cookie-storage))
 362     (error "No cookies are defined"))
 363
 364   (pop-to-buffer "*url cookies*")
 365   (let ((inhibit-read-only t)
 366         (domains (sort
 367                   (copy-sequence
 368                    (append url-cookie-secure-storage
 369                            url-cookie-storage))
 370                   (lambda (e1 e2)
 371                     (string< (car e1) (car e2)))))
 372         (domain-length 0)
 373         start name format domain)
 374     (erase-buffer)
 375     (url-cookie-mode)
 376     (dolist (elem domains)
 377       (setq domain-length (max domain-length (length (car elem)))))
 378     (setq format (format "%%-%ds %%-20s %%s" domain-length)
 379           header-line-format
 380           (concat " " (format format "Domain" "Name" "Value")))
 381     (dolist (elem domains)
 382       (setq domain (car elem))
 383       (dolist (cookie (sort (copy-sequence (cdr elem))
 384                             (lambda (c1 c2)
 385                               (string< (url-cookie-name c1)
 386                                        (url-cookie-name c2)))))
 387         (setq start (point)
 388               name (url-cookie-name cookie))
 389         (when (> (length name) 20)
 390           (setq name (substring name 0 20)))
 391         (insert (format format domain name
 392                         (url-cookie-value cookie))
 393                 "\n")
 394         (setq domain "")
 395         (put-text-property start (1+ start) 'url-cookie cookie)))
 396     (goto-char (point-min))))
 397
 398 (defun url-cookie-delete ()
 399   "Delete the cookie on the current line."
 400   (interactive)
 401   (let ((cookie (get-text-property (line-beginning-position) 'url-cookie))
 402         (inhibit-read-only t)
 403         variable)
 404     (unless cookie
 405       (error "No cookie on the current line"))
 406     (setq variable (if (url-cookie-secure cookie)
 407                        'url-cookie-secure-storage
 408                      'url-cookie-storage))
 409     (let* ((list (symbol-value variable))
 410            (elem (assoc (url-cookie-domain cookie) list)))
 411       (setq elem (delq cookie elem))
 412       (when (zerop (length (cdr elem)))
 413         (setq list (delq elem list)))
 414       (set variable list))
 415     (setq url-cookies-changed-since-last-save t)
 416     (url-cookie-write-file)
 417     (delete-region (line-beginning-position)
 418                    (progn
 419                      (forward-line 1)
 420                      (point)))))
 421
 422 (defun url-cookie-quit ()
 423   "Kill the current buffer."
 424   (interactive)
 425   (kill-buffer (current-buffer)))
 426
 427 (defvar url-cookie-mode-map
 428   (let ((map (make-sparse-keymap)))
 429     (suppress-keymap map)
 430     (define-key map "q" 'url-cookie-quit)
 431     (define-key map [delete] 'url-cookie-delete)
 432     (define-key map [(control k)] 'url-cookie-delete)
 433     map))
 434
 435 (define-derived-mode url-cookie-mode nil "URL Cookie"
 436   "Mode for listing cookies.
 437
 438 \\{url-cookie-mode-map}"
 439   (buffer-disable-undo)
 440   (setq buffer-read-only t
 441         truncate-lines t))
 442
 443 (provide 'url-cookie)
 444
 445 ;;; url-cookie.el ends here