lisp/emacs-lisp/timer.el

   1 ;;; timer.el --- run a function with args at some time in future
   2
   3 ;; Copyright (C) 1996, 2001-2015 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: emacs-devel@gnu.org
   6 ;; Package: emacs
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package gives you the capability to run Emacs Lisp commands at
  26 ;; specified times in the future, either as one-shots or periodically.
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl-lib))
  31
  32 (cl-defstruct (timer
  33                (:constructor nil)
  34                (:copier nil)
  35                (:constructor timer-create ())
  36                (:type vector)
  37                (:conc-name timer--))
  38   ;; nil if the timer is active (waiting to be triggered),
  39   ;; non-nil if it is inactive ("already triggered", in theory).
  40   (triggered t)
  41   ;; Time of next trigger: for normal timers, absolute time, for idle timers,
  42   ;; time relative to idle-start.
  43   high-seconds low-seconds usecs
  44   ;; For normal timers, time between repetitions, or nil.  For idle timers,
  45   ;; non-nil iff repeated.
  46   repeat-delay
  47   function args                         ;What to do when triggered.
  48   idle-delay                            ;If non-nil, this is an idle-timer.
  49   psecs)
  50
  51 (defun timerp (object)
  52   "Return t if OBJECT is a timer."
  53   (and (vectorp object) (= (length object) 9)))
  54
  55 (defsubst timer--check (timer)
  56   (or (timerp timer) (signal 'wrong-type-argument (list #'timerp timer))))
  57
  58 (defun timer--time-setter (timer time)
  59   (timer--check timer)
  60   (setf (timer--high-seconds timer) (pop time))
  61   (let ((low time) (usecs 0) (psecs 0))
  62     (when (consp time)
  63       (setq low (pop time))
  64       (when time
  65         (setq usecs (pop time))
  66         (when time
  67           (setq psecs (car time)))))
  68     (setf (timer--low-seconds timer) low)
  69     (setf (timer--usecs timer) usecs)
  70     (setf (timer--psecs timer) psecs)
  71     time))
  72
  73 ;; Pseudo field `time'.
  74 (defun timer--time (timer)
  75   (declare (gv-setter timer--time-setter))
  76   (list (timer--high-seconds timer)
  77         (timer--low-seconds timer)
  78         (timer--usecs timer)
  79         (timer--psecs timer)))
  80
  81 (defun timer-set-time (timer time &optional delta)
  82   "Set the trigger time of TIMER to TIME.
  83 TIME must be in the internal format returned by, e.g., `current-time'.
  84 If optional third argument DELTA is a positive number, make the timer
  85 fire repeatedly that many seconds apart."
  86   (setf (timer--time timer) time)
  87   (setf (timer--repeat-delay timer) (and (numberp delta) (> delta 0) delta))
  88   timer)
  89
  90 (defun timer-set-idle-time (timer secs &optional repeat)
  91   ;; FIXME: Merge with timer-set-time.
  92   "Set the trigger idle time of TIMER to SECS.
  93 SECS may be an integer, floating point number, or the internal
  94 time format returned by, e.g., `current-idle-time'.
  95 If optional third argument REPEAT is non-nil, make the timer
  96 fire each time Emacs is idle for that many seconds."
  97   (setf (timer--time timer) (if (consp secs) secs (seconds-to-time secs)))
  98   (setf (timer--repeat-delay timer) repeat)
  99   timer)
 100
 101 (defun timer-next-integral-multiple-of-time (time secs)
 102   "Yield the next value after TIME that is an integral multiple of SECS.
 103 More precisely, the next value, after TIME, that is an integral multiple
 104 of SECS seconds since the epoch.  SECS may be a fraction."
 105   (let* ((trillion 1e12)
 106          (time-sec (+ (nth 1 time)
 107                       (* 65536.0 (nth 0 time))))
 108          (delta-sec (mod (- time-sec) secs))
 109          (next-sec (+ time-sec (ffloor delta-sec)))
 110          (next-sec-psec (ffloor (* trillion (mod delta-sec 1))))
 111          (sub-time-psec (+ (or (nth 3 time) 0)
 112                            (* 1e6 (nth 2 time))))
 113          (psec-diff (- sub-time-psec next-sec-psec)))
 114     (if (and (<= next-sec time-sec) (< 0 psec-diff))
 115         (setq next-sec-psec (+ sub-time-psec
 116                                (mod (- psec-diff) (* trillion secs)))))
 117     (setq next-sec (+ next-sec (floor next-sec-psec trillion)))
 118     (setq next-sec-psec (mod next-sec-psec trillion))
 119     (list (floor next-sec 65536)
 120           (floor (mod next-sec 65536))
 121           (floor next-sec-psec 1000000)
 122           (floor (mod next-sec-psec 1000000)))))
 123
 124 (defun timer-relative-time (time secs &optional usecs psecs)
 125   "Advance TIME by SECS seconds and optionally USECS microseconds
 126 and PSECS picoseconds.  SECS may be either an integer or a
 127 floating point number."
 128   (let ((delta secs))
 129     (if (or usecs psecs)
 130         (setq delta (time-add delta (list 0 0 (or usecs 0) (or psecs 0)))))
 131     (time-add time delta)))
 132
 133 (defun timer--time-less-p (t1 t2)
 134   "Say whether time value T1 is less than time value T2."
 135   (time-less-p (timer--time t1) (timer--time t2)))
 136
 137 (defun timer-inc-time (timer secs &optional usecs psecs)
 138   "Increment the time set in TIMER by SECS seconds, USECS microseconds,
 139 and PSECS picoseconds.  SECS may be a fraction.  If USECS or PSECS are
 140 omitted, they are treated as zero."
 141   (setf (timer--time timer)
 142         (timer-relative-time (timer--time timer) secs usecs psecs)))
 143
 144 (defun timer-set-time-with-usecs (timer time usecs &optional delta)
 145   "Set the trigger time of TIMER to TIME plus USECS.
 146 TIME must be in the internal format returned by, e.g., `current-time'.
 147 The microsecond count from TIME is ignored, and USECS is used instead.
 148 If optional fourth argument DELTA is a positive number, make the timer
 149 fire repeatedly that many seconds apart."
 150   (declare (obsolete "use `timer-set-time' and `timer-inc-time' instead."
 151                      "22.1"))
 152   (setf (timer--time timer) time)
 153   (setf (timer--usecs timer) usecs)
 154   (setf (timer--psecs timer) 0)
 155   (setf (timer--repeat-delay timer) (and (numberp delta) (> delta 0) delta))
 156   timer)
 157
 158 (defun timer-set-function (timer function &optional args)
 159   "Make TIMER call FUNCTION with optional ARGS when triggering."
 160   (timer--check timer)
 161   (setf (timer--function timer) function)
 162   (setf (timer--args timer) args)
 163   timer)
 164 \f
 165 (defun timer--activate (timer &optional triggered-p reuse-cell idle)
 166   (if (and (timerp timer)
 167            (integerp (timer--high-seconds timer))
 168            (integerp (timer--low-seconds timer))
 169            (integerp (timer--usecs timer))
 170            (integerp (timer--psecs timer))
 171            (timer--function timer))
 172       (let ((timers (if idle timer-idle-list timer-list))
 173             last)
 174         ;; Skip all timers to trigger before the new one.
 175         (while (and timers (timer--time-less-p (car timers) timer))
 176           (setq last timers
 177                 timers (cdr timers)))
 178         (if reuse-cell
 179             (progn
 180               (setcar reuse-cell timer)
 181               (setcdr reuse-cell timers))
 182           (setq reuse-cell (cons timer timers)))
 183         ;; Insert new timer after last which possibly means in front of queue.
 184         (setf (cond (last (cdr last))
 185                     (idle timer-idle-list)
 186                     (t    timer-list))
 187               reuse-cell)
 188         (setf (timer--triggered timer) triggered-p)
 189         (setf (timer--idle-delay timer) idle)
 190         nil)
 191     (error "Invalid or uninitialized timer")))
 192
 193 (defun timer-activate (timer &optional triggered-p reuse-cell)
 194   "Insert TIMER into `timer-list'.
 195 If TRIGGERED-P is t, make TIMER inactive (put it on the list, but
 196 mark it as already triggered).  To remove it, use `cancel-timer'.
 197
 198 REUSE-CELL, if non-nil, is a cons cell to reuse when inserting
 199 TIMER into `timer-list' (usually a cell removed from that list by
 200 `cancel-timer-internal'; using this reduces consing for repeat
 201 timers).  If nil, allocate a new cell."
 202   (timer--activate timer triggered-p reuse-cell nil))
 203
 204 (defun timer-activate-when-idle (timer &optional dont-wait reuse-cell)
 205   "Insert TIMER into `timer-idle-list'.
 206 This arranges to activate TIMER whenever Emacs is next idle.
 207 If optional argument DONT-WAIT is non-nil, set TIMER to activate
 208 immediately \(see below\), or at the right time, if Emacs is
 209 already idle.
 210
 211 REUSE-CELL, if non-nil, is a cons cell to reuse when inserting
 212 TIMER into `timer-idle-list' (usually a cell removed from that
 213 list by `cancel-timer-internal'; using this reduces consing for
 214 repeat timers).  If nil, allocate a new cell.
 215
 216 Using non-nil DONT-WAIT is not recommended when activating an
 217 idle timer from an idle timer handler, if the timer being
 218 activated has an idleness time that is smaller or equal to
 219 the time of the current timer.  That's because the activated
 220 timer will fire right away."
 221   (timer--activate timer (not dont-wait) reuse-cell 'idle))
 222
 223 (defalias 'disable-timeout 'cancel-timer)
 224
 225 (defun cancel-timer (timer)
 226   "Remove TIMER from the list of active timers."
 227   (timer--check timer)
 228   (setq timer-list (delq timer timer-list))
 229   (setq timer-idle-list (delq timer timer-idle-list))
 230   nil)
 231
 232 (defun cancel-timer-internal (timer)
 233   "Remove TIMER from the list of active timers or idle timers.
 234 Only to be used in this file.  It returns the cons cell
 235 that was removed from the timer list."
 236   (let ((cell1 (memq timer timer-list))
 237         (cell2 (memq timer timer-idle-list)))
 238     (if cell1
 239         (setq timer-list (delq timer timer-list)))
 240     (if cell2
 241         (setq timer-idle-list (delq timer timer-idle-list)))
 242     (or cell1 cell2)))
 243
 244 (defun cancel-function-timers (function)
 245   "Cancel all timers which would run FUNCTION.
 246 This affects ordinary timers such as are scheduled by `run-at-time',
 247 and idle timers such as are scheduled by `run-with-idle-timer'."
 248   (interactive "aCancel timers of function: ")
 249   (dolist (timer timer-list)
 250     (if (eq (timer--function timer) function)
 251         (setq timer-list (delq timer timer-list))))
 252   (dolist (timer timer-idle-list)
 253     (if (eq (timer--function timer) function)
 254         (setq timer-idle-list (delq timer timer-idle-list)))))
 255 \f
 256 ;; Record the last few events, for debugging.
 257 (defvar timer-event-last nil
 258   "Last timer that was run.")
 259 (defvar timer-event-last-1 nil
 260   "Next-to-last timer that was run.")
 261 (defvar timer-event-last-2 nil
 262   "Third-to-last timer that was run.")
 263
 264 (defcustom timer-max-repeats 10
 265   "Maximum number of times to repeat a timer, if many repeats are delayed.
 266 Timer invocations can be delayed because Emacs is suspended or busy,
 267 or because the system's time changes.  If such an occurrence makes it
 268 appear that many invocations are overdue, this variable controls
 269 how many will really happen."
 270   :type 'integer
 271   :group 'internal)
 272
 273 (defun timer-until (timer time)
 274   "Calculate number of seconds from when TIMER will run, until TIME.
 275 TIMER is a timer, and stands for the time when its next repeat is scheduled.
 276 TIME is a time-list."
 277   (- (float-time time) (float-time (timer--time timer))))
 278
 279 (defun timer-event-handler (timer)
 280   "Call the handler for the timer TIMER.
 281 This function is called, by name, directly by the C code."
 282   (setq timer-event-last-2 timer-event-last-1)
 283   (setq timer-event-last-1 timer-event-last)
 284   (setq timer-event-last timer)
 285   (let ((inhibit-quit t))
 286     (timer--check timer)
 287     (let ((retrigger nil)
 288           (cell
 289            ;; Delete from queue.  Record the cons cell that was used.
 290            (cancel-timer-internal timer)))
 291       ;; If `cell' is nil, it means the timer was already canceled, so we
 292       ;; shouldn't be running it at all.  This can happen for example with the
 293       ;; following scenario (bug#17392):
 294       ;; - we run timers, starting with A (and remembering the rest as (B C)).
 295       ;; - A runs and a does a sit-for.
 296       ;; - during sit-for we run timer D which cancels timer B.
 297       ;; - timer A finally finishes, so we move on to timers B and C.
 298       (when cell
 299         ;; Re-schedule if requested.
 300         (if (timer--repeat-delay timer)
 301             (if (timer--idle-delay timer)
 302                 (timer-activate-when-idle timer nil cell)
 303               (timer-inc-time timer (timer--repeat-delay timer) 0)
 304               ;; If real time has jumped forward,
 305               ;; perhaps because Emacs was suspended for a long time,
 306               ;; limit how many times things get repeated.
 307               (if (and (numberp timer-max-repeats)
 308                        (< 0 (timer-until timer nil)))
 309                   (let ((repeats (/ (timer-until timer nil)
 310                                     (timer--repeat-delay timer))))
 311                     (if (> repeats timer-max-repeats)
 312                         (timer-inc-time timer (* (timer--repeat-delay timer)
 313                                                  repeats)))))
 314               ;; Place it back on the timer-list before running
 315               ;; timer--function, so it can cancel-timer itself.
 316               (timer-activate timer t cell)
 317               (setq retrigger t)))
 318         ;; Run handler.
 319         (condition-case-unless-debug err
 320             ;; Timer functions should not change the current buffer.
 321             ;; If they do, all kinds of nasty surprises can happen,
 322             ;; and it can be hellish to track down their source.
 323             (save-current-buffer
 324               (apply (timer--function timer) (timer--args timer)))
 325           (error (message "Error running timer%s: %S"
 326                           (if (symbolp (timer--function timer))
 327                               (format " `%s'" (timer--function timer)) "")
 328                           err)))
 329         (when (and retrigger
 330                    ;; If the timer's been canceled, don't "retrigger" it
 331                    ;; since it might still be in the copy of timer-list kept
 332                    ;; by keyboard.c:timer_check (bug#14156).
 333                    (memq timer timer-list))
 334           (setf (timer--triggered timer) nil))))))
 335
 336 ;; This function is incompatible with the one in levents.el.
 337 (defun timeout-event-p (event)
 338   "Non-nil if EVENT is a timeout event."
 339   (and (listp event) (eq (car event) 'timer-event)))
 340 \f
 341
 342 (declare-function diary-entry-time "diary-lib" (s))
 343
 344 (defun run-at-time (time repeat function &rest args)
 345   "Perform an action at time TIME.
 346 Repeat the action every REPEAT seconds, if REPEAT is non-nil.
 347 TIME should be one of: a string giving an absolute time like
 348 \"11:23pm\" (the acceptable formats are those recognized by
 349 `diary-entry-time'; note that such times are interpreted as times
 350 today, even if in the past); a string giving a relative time like
 351 \"2 hours 35 minutes\" (the acceptable formats are those
 352 recognized by `timer-duration'); nil meaning now; a number of
 353 seconds from now; a value from `encode-time'; or t (with non-nil
 354 REPEAT) meaning the next integral multiple of REPEAT.  REPEAT may
 355 be an integer or floating point number.  The action is to call
 356 FUNCTION with arguments ARGS.
 357
 358 This function returns a timer object which you can use in `cancel-timer'."
 359   (interactive "sRun at time: \nNRepeat interval: \naFunction: ")
 360
 361   (or (null repeat)
 362       (and (numberp repeat) (< 0 repeat))
 363       (error "Invalid repetition interval"))
 364
 365   ;; Special case: nil means "now" and is useful when repeating.
 366   (if (null time)
 367       (setq time (current-time)))
 368
 369   ;; Special case: t means the next integral multiple of REPEAT.
 370   (if (and (eq time t) repeat)
 371       (setq time (timer-next-integral-multiple-of-time (current-time) repeat)))
 372
 373   ;; Handle numbers as relative times in seconds.
 374   (if (numberp time)
 375       (setq time (timer-relative-time nil time)))
 376
 377   ;; Handle relative times like "2 hours 35 minutes"
 378   (if (stringp time)
 379       (let ((secs (timer-duration time)))
 380         (if secs
 381             (setq time (timer-relative-time nil secs)))))
 382
 383   ;; Handle "11:23pm" and the like.  Interpret it as meaning today
 384   ;; which admittedly is rather stupid if we have passed that time
 385   ;; already.  (Though only Emacs hackers hack Emacs at that time.)
 386   (if (stringp time)
 387       (progn
 388         (require 'diary-lib)
 389         (let ((hhmm (diary-entry-time time))
 390               (now (decode-time)))
 391           (if (>= hhmm 0)
 392               (setq time
 393                     (encode-time 0 (% hhmm 100) (/ hhmm 100) (nth 3 now)
 394                                  (nth 4 now) (nth 5 now) (nth 8 now)))))))
 395
 396   (or (consp time)
 397       (error "Invalid time format"))
 398
 399   (let ((timer (timer-create)))
 400     (timer-set-time timer time repeat)
 401     (timer-set-function timer function args)
 402     (timer-activate timer)
 403     timer))
 404
 405 (defun run-with-timer (secs repeat function &rest args)
 406   "Perform an action after a delay of SECS seconds.
 407 Repeat the action every REPEAT seconds, if REPEAT is non-nil.
 408 SECS and REPEAT may be integers or floating point numbers.
 409 The action is to call FUNCTION with arguments ARGS.
 410
 411 This function returns a timer object which you can use in `cancel-timer'."
 412   (interactive "sRun after delay (seconds): \nNRepeat interval: \naFunction: ")
 413   (apply 'run-at-time secs repeat function args))
 414
 415 (defun add-timeout (secs function object &optional repeat)
 416   "Add a timer to run SECS seconds from now, to call FUNCTION on OBJECT.
 417 If REPEAT is non-nil, repeat the timer every REPEAT seconds.
 418 This function is for compatibility; see also `run-with-timer'."
 419   (run-with-timer secs repeat function object))
 420
 421 (defun run-with-idle-timer (secs repeat function &rest args)
 422   "Perform an action the next time Emacs is idle for SECS seconds.
 423 The action is to call FUNCTION with arguments ARGS.
 424 SECS may be an integer, a floating point number, or the internal
 425 time format returned by, e.g., `current-idle-time'.
 426 If Emacs is currently idle, and has been idle for N seconds (N < SECS),
 427 then it will call FUNCTION in SECS - N seconds from now.  Using
 428 SECS <= N is not recommended if this function is invoked from an idle
 429 timer, because FUNCTION will then be called immediately.
 430
 431 If REPEAT is non-nil, do the action each time Emacs has been idle for
 432 exactly SECS seconds (that is, only once for each time Emacs becomes idle).
 433
 434 This function returns a timer object which you can use in `cancel-timer'."
 435   (interactive
 436    (list (read-from-minibuffer "Run after idle (seconds): " nil nil t)
 437          (y-or-n-p "Repeat each time Emacs is idle? ")
 438          (intern (completing-read "Function: " obarray 'fboundp t))))
 439   (let ((timer (timer-create)))
 440     (timer-set-function timer function args)
 441     (timer-set-idle-time timer secs repeat)
 442     (timer-activate-when-idle timer t)
 443     timer))
 444 \f
 445 (defvar with-timeout-timers nil
 446   "List of all timers used by currently pending `with-timeout' calls.")
 447
 448 (defmacro with-timeout (list &rest body)
 449   "Run BODY, but if it doesn't finish in SECONDS seconds, give up.
 450 If we give up, we run the TIMEOUT-FORMS and return the value of the last one.
 451 The timeout is checked whenever Emacs waits for some kind of external
 452 event (such as keyboard input, input from subprocesses, or a certain time);
 453 if the program loops without waiting in any way, the timeout will not
 454 be detected.
 455 \n(fn (SECONDS TIMEOUT-FORMS...) BODY)"
 456   (declare (indent 1) (debug ((form body) body)))
 457   (let ((seconds (car list))
 458         (timeout-forms (cdr list))
 459         (timeout (make-symbol "timeout")))
 460     `(let ((-with-timeout-value-
 461             (catch ',timeout
 462               (let* ((-with-timeout-timer-
 463                       (run-with-timer ,seconds nil
 464                                       (lambda () (throw ',timeout ',timeout))))
 465                      (with-timeout-timers
 466                          (cons -with-timeout-timer- with-timeout-timers)))
 467                 (unwind-protect
 468                     (progn ,@body)
 469                   (cancel-timer -with-timeout-timer-))))))
 470        ;; It is tempting to avoid the `if' altogether and instead run
 471        ;; timeout-forms in the timer, just before throwing `timeout'.
 472        ;; But that would mean that timeout-forms are run in the deeper
 473        ;; dynamic context of the timer, with inhibit-quit set etc...
 474        (if (eq -with-timeout-value- ',timeout)
 475            (progn ,@timeout-forms)
 476          -with-timeout-value-))))
 477
 478 (defun with-timeout-suspend ()
 479   "Stop the clock for `with-timeout'.  Used by debuggers.
 480 The idea is that the time you spend in the debugger should not
 481 count against these timeouts.
 482
 483 The value is a list that the debugger can pass to `with-timeout-unsuspend'
 484 when it exits, to make these timers start counting again."
 485   (mapcar (lambda (timer)
 486             (cancel-timer timer)
 487             (list timer (time-subtract (timer--time timer) nil)))
 488           with-timeout-timers))
 489
 490 (defun with-timeout-unsuspend (timer-spec-list)
 491   "Restart the clock for `with-timeout'.
 492 The argument should be a value previously returned by `with-timeout-suspend'."
 493   (dolist (elt timer-spec-list)
 494     (let ((timer (car elt))
 495           (delay (cadr elt)))
 496       (timer-set-time timer (time-add nil delay))
 497       (timer-activate timer))))
 498
 499 (defun y-or-n-p-with-timeout (prompt seconds default-value)
 500   "Like (y-or-n-p PROMPT), with a timeout.
 501 If the user does not answer after SECONDS seconds, return DEFAULT-VALUE."
 502   (with-timeout (seconds default-value)
 503     (y-or-n-p prompt)))
 504 \f
 505 (defconst timer-duration-words
 506   (list (cons "microsec" 0.000001)
 507         (cons "microsecond" 0.000001)
 508         (cons "millisec" 0.001)
 509         (cons "millisecond" 0.001)
 510         (cons "sec" 1)
 511         (cons "second" 1)
 512         (cons "min" 60)
 513         (cons "minute" 60)
 514         (cons "hour" (* 60 60))
 515         (cons "day" (* 24 60 60))
 516         (cons "week" (* 7 24 60 60))
 517         (cons "fortnight" (* 14 24 60 60))
 518         (cons "month" (* 30 24 60 60))    ; Approximation
 519         (cons "year" (* 365.25 24 60 60)) ; Approximation
 520         )
 521   "Alist mapping temporal words to durations in seconds.")
 522
 523 (defun timer-duration (string)
 524   "Return number of seconds specified by STRING, or nil if parsing fails."
 525   (let ((secs 0)
 526         (start 0)
 527         (case-fold-search t))
 528     (while (string-match
 529             "[ \t]*\\([0-9.]+\\)?[ \t]*\\([a-z]+[a-rt-z]\\)s?[ \t]*"
 530             string start)
 531       (let ((count (if (match-beginning 1)
 532                        (string-to-number (match-string 1 string))
 533                      1))
 534             (itemsize (cdr (assoc (match-string 2 string)
 535                                   timer-duration-words))))
 536         (if itemsize
 537             (setq start (match-end 0)
 538                   secs (+ secs (* count itemsize)))
 539           (setq secs nil
 540                 start (length string)))))
 541     (if (= start (length string))
 542         secs
 543       (if (string-match-p "\\`[0-9.]+\\'" string)
 544           (string-to-number string)))))
 545
 546 (defun internal-timer-start-idle ()
 547   "Mark all idle-time timers as once again candidates for running."
 548   (dolist (timer timer-idle-list)
 549     (if (timerp timer) ;; FIXME: Why test?
 550         (setf (timer--triggered timer) nil))))
 551 \f
 552 (provide 'timer)
 553
 554 ;;; timer.el ends here