lisp/vc/log-edit.el

   1 ;;; log-edit.el --- Major mode for editing CVS commit messages -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 1999-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   6 ;; Keywords: pcl-cvs cvs commit log vc
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Todo:
  26
  27 ;; - Move in VC's code
  28 ;; - Add compatibility for VC's hook variables
  29
  30 ;;; Code:
  31
  32 (eval-when-compile (require 'cl))
  33 (require 'add-log)                      ; for all the ChangeLog goodies
  34 (require 'pcvs-util)
  35 (require 'ring)
  36
  37 ;;;;
  38 ;;;; Global Variables
  39 ;;;;
  40
  41 (defgroup log-edit nil
  42   "Major mode for editing RCS and CVS commit messages."
  43   :group 'pcl-cvs
  44   :group 'vc                            ; It's used by VC.
  45   :version "21.1"
  46   :prefix "log-edit-")
  47
  48 ;; compiler pacifiers
  49 (defvar cvs-buffer)
  50
  51 \f
  52 ;; The main keymap
  53
  54 (easy-mmode-defmap log-edit-mode-map
  55   `(("\C-c\C-c" . log-edit-done)
  56     ("\C-c\C-a" . log-edit-insert-changelog)
  57     ("\C-c\C-d" . log-edit-show-diff)
  58     ("\C-c\C-f" . log-edit-show-files)
  59     ("\M-n"     . log-edit-next-comment)
  60     ("\M-p"     . log-edit-previous-comment)
  61     ("\M-r"     . log-edit-comment-search-backward)
  62     ("\M-s"     . log-edit-comment-search-forward)
  63     ("\C-c?"    . log-edit-mode-help))
  64   "Keymap for the `log-edit-mode' (to edit version control log messages)."
  65   :group 'log-edit)
  66
  67 ;; Compatibility with old names.  Should we bother ?
  68 (defvar vc-log-mode-map log-edit-mode-map)
  69 (defvar vc-log-entry-mode vc-log-mode-map)
  70
  71 (easy-menu-define log-edit-menu log-edit-mode-map
  72   "Menu used for `log-edit-mode'."
  73   '("Log-Edit"
  74     ["Done" log-edit-done
  75      :help "Exit log-edit and proceed with the actual action."]
  76     "--"
  77     ["Insert ChangeLog" log-edit-insert-changelog
  78      :help "Insert a log message by looking at the ChangeLog"]
  79     ["Add to ChangeLog" log-edit-add-to-changelog
  80      :help "Insert this log message into the appropriate ChangeLog file"]
  81     "--"
  82     ["Show diff" log-edit-show-diff
  83      :help "Show the diff for the files to be committed."]
  84     ["List files" log-edit-show-files
  85      :help "Show the list of relevant files."]
  86     "--"
  87     ["Previous comment"         log-edit-previous-comment
  88      :help "Cycle backwards through comment history"]
  89     ["Next comment"             log-edit-next-comment
  90      :help "Cycle forwards through comment history."]
  91     ["Search comment forward"   log-edit-comment-search-forward
  92      :help "Search forwards through comment history for a substring match of str"]
  93     ["Search comment backward"  log-edit-comment-search-backward
  94      :help "Search backwards through comment history for substring match of str"]))
  95
  96 (defcustom log-edit-confirm 'changed
  97   "If non-nil, `log-edit-done' will request confirmation.
  98 If 'changed, only request confirmation if the list of files has
  99   changed since the beginning of the log-edit session."
 100   :group 'log-edit
 101   :type '(choice (const changed) (const t) (const nil)))
 102
 103 (defcustom log-edit-keep-buffer nil
 104   "If non-nil, don't hide the buffer after `log-edit-done'."
 105   :group 'log-edit
 106   :type 'boolean)
 107
 108 (defvar cvs-commit-buffer-require-final-newline t)
 109 (make-obsolete-variable 'cvs-commit-buffer-require-final-newline
 110                         'log-edit-require-final-newline
 111                         "21.1")
 112
 113 (defcustom log-edit-require-final-newline
 114   cvs-commit-buffer-require-final-newline
 115   "Enforce a newline at the end of commit log messages.
 116 Enforce it silently if t, query if non-nil and don't do anything if nil."
 117   :group 'log-edit
 118   :type '(choice (const ask) (const t) (const nil)))
 119
 120 (defcustom log-edit-setup-invert nil
 121   "Non-nil means `log-edit' should invert the meaning of its SETUP arg.
 122 If SETUP is 'force, this variable has no effect."
 123   :group 'log-edit
 124   :type 'boolean)
 125
 126 (defcustom log-edit-hook '(log-edit-insert-cvs-template
 127                            log-edit-show-files
 128                            log-edit-insert-changelog)
 129   "Hook run at the end of `log-edit'."
 130   :group 'log-edit
 131   :type '(hook :options (log-edit-insert-changelog
 132                          log-edit-insert-cvs-rcstemplate
 133                          log-edit-insert-cvs-template
 134                          log-edit-insert-filenames)))
 135
 136 (defcustom log-edit-mode-hook (if (boundp 'vc-log-mode-hook) vc-log-mode-hook)
 137   "Hook run when entering `log-edit-mode'."
 138   :group 'log-edit
 139   :type 'hook)
 140
 141 (defcustom log-edit-done-hook nil
 142   "Hook run before doing the actual commit.
 143 This hook can be used to cleanup the message, enforce various
 144 conventions, or to allow recording the message in some other database,
 145 such as a bug-tracking system.  The list of files about to be committed
 146 can be obtained from `log-edit-files'."
 147   :group 'log-edit
 148   :type '(hook :options (log-edit-set-common-indentation
 149                          log-edit-add-to-changelog)))
 150
 151 (defcustom log-edit-strip-single-file-name nil
 152   "If non-nil, remove file name from single-file log entries."
 153   :type 'boolean
 154   :safe 'booleanp
 155   :group 'log-edit
 156   :version "24.1")
 157
 158 (defvar cvs-changelog-full-paragraphs t)
 159 (make-obsolete-variable 'cvs-changelog-full-paragraphs
 160                         'log-edit-changelog-full-paragraphs
 161                         "21.1")
 162
 163 (defvar log-edit-changelog-full-paragraphs cvs-changelog-full-paragraphs
 164   "*If non-nil, include full ChangeLog paragraphs in the log.
 165 This may be set in the ``local variables'' section of a ChangeLog, to
 166 indicate the policy for that ChangeLog.
 167
 168 A ChangeLog paragraph is a bunch of log text containing no blank lines;
 169 a paragraph usually describes a set of changes with a single purpose,
 170 but perhaps spanning several functions in several files.  Changes in
 171 different paragraphs are unrelated.
 172
 173 You could argue that the log entry for a file should contain the
 174 full ChangeLog paragraph mentioning the change to the file, even though
 175 it may mention other files, because that gives you the full context you
 176 need to understand the change.  This is the behavior you get when this
 177 variable is set to t.
 178
 179 On the other hand, you could argue that the log entry for a change
 180 should contain only the text for the changes which occurred in that
 181 file, because the log is per-file.  This is the behavior you get
 182 when this variable is set to nil.")
 183
 184 ;;;; Internal global or buffer-local vars
 185
 186 (defconst log-edit-files-buf "*log-edit-files*")
 187 (defvar log-edit-initial-files nil)
 188 (defvar log-edit-callback nil)
 189 (defvar log-edit-diff-function nil)
 190 (defvar log-edit-listfun nil)
 191
 192 (defvar log-edit-parent-buffer nil)
 193
 194 ;;; Originally taken from VC-Log mode
 195
 196 (defconst log-edit-maximum-comment-ring-size 32
 197   "Maximum number of saved comments in the comment ring.")
 198 (defvar log-edit-comment-ring (make-ring log-edit-maximum-comment-ring-size))
 199 (defvar log-edit-comment-ring-index nil)
 200 (defvar log-edit-last-comment-match "")
 201
 202 (defun log-edit-new-comment-index (stride len)
 203   "Return the comment index STRIDE elements from the current one.
 204 LEN is the length of `log-edit-comment-ring'."
 205   (mod (cond
 206         (log-edit-comment-ring-index (+ log-edit-comment-ring-index stride))
 207         ;; Initialize the index on the first use of this command
 208         ;; so that the first M-p gets index 0, and the first M-n gets
 209         ;; index -1.
 210         ((> stride 0) (1- stride))
 211         (t stride))
 212        len))
 213
 214 (defun log-edit-previous-comment (arg)
 215   "Cycle backwards through comment history.
 216 With a numeric prefix ARG, go back ARG comments."
 217   (interactive "*p")
 218   (let ((len (ring-length log-edit-comment-ring)))
 219     (if (<= len 0)
 220         (progn (message "Empty comment ring") (ding))
 221       ;; Don't use `erase-buffer' because we don't want to `widen'.
 222       (delete-region (point-min) (point-max))
 223       (setq log-edit-comment-ring-index (log-edit-new-comment-index arg len))
 224       (message "Comment %d" (1+ log-edit-comment-ring-index))
 225       (insert (ring-ref log-edit-comment-ring log-edit-comment-ring-index)))))
 226
 227 (defun log-edit-next-comment (arg)
 228   "Cycle forwards through comment history.
 229 With a numeric prefix ARG, go forward ARG comments."
 230   (interactive "*p")
 231   (log-edit-previous-comment (- arg)))
 232
 233 (defun log-edit-comment-search-backward (str &optional stride)
 234   "Search backwards through comment history for substring match of STR.
 235 If the optional argument STRIDE is present, that is a step-width to use
 236 when going through the comment ring."
 237   ;; Why substring rather than regexp ?   -sm
 238   (interactive
 239    (list (read-string "Comment substring: " nil nil log-edit-last-comment-match)))
 240   (unless stride (setq stride 1))
 241   (if (string= str "")
 242       (setq str log-edit-last-comment-match)
 243     (setq log-edit-last-comment-match str))
 244   (let* ((str (regexp-quote str))
 245          (len (ring-length log-edit-comment-ring))
 246          (n (log-edit-new-comment-index stride len)))
 247     (while (progn (when (or (>= n len) (< n 0)) (error "Not found"))
 248                   (not (string-match str (ring-ref log-edit-comment-ring n))))
 249       (setq n (+ n stride)))
 250     (setq log-edit-comment-ring-index n)
 251     (log-edit-previous-comment 0)))
 252
 253 (defun log-edit-comment-search-forward (str)
 254   "Search forwards through comment history for a substring match of STR."
 255   (interactive
 256    (list (read-string "Comment substring: " nil nil log-edit-last-comment-match)))
 257   (log-edit-comment-search-backward str -1))
 258
 259 (defun log-edit-comment-to-change-log (&optional whoami file-name)
 260   "Enter last VC comment into the change log for the current file.
 261 WHOAMI (interactive prefix) non-nil means prompt for user name
 262 and site.  FILE-NAME is the name of the change log; if nil, use
 263 `change-log-default-name'.
 264
 265 This may be useful as a `log-edit-checkin-hook' to update change logs
 266 automatically."
 267   (interactive (if current-prefix-arg
 268                    (list current-prefix-arg
 269                          (prompt-for-change-log-name))))
 270   (let (;; Extract the comment first so we get any error before doing anything.
 271         (comment (ring-ref log-edit-comment-ring 0))
 272         ;; Don't let add-change-log-entry insert a defun name.
 273         (add-log-current-defun-function 'ignore)
 274         end)
 275     ;; Call add-log to do half the work.
 276     (add-change-log-entry whoami file-name t t)
 277     ;; Insert the VC comment, leaving point before it.
 278     (setq end (save-excursion (insert comment) (point-marker)))
 279     (if (looking-at "\\s *\\s(")
 280         ;; It starts with an open-paren, as in "(foo): Frobbed."
 281         ;; So remove the ": " add-log inserted.
 282         (delete-char -2))
 283     ;; Canonicalize the white space between the file name and comment.
 284     (just-one-space)
 285     ;; Indent rest of the text the same way add-log indented the first line.
 286     (let ((indentation (current-indentation)))
 287       (save-excursion
 288         (while (< (point) end)
 289           (forward-line 1)
 290           (indent-to indentation))
 291         (setq end (point))))
 292     ;; Fill the inserted text, preserving open-parens at bol.
 293     (let ((paragraph-start (concat paragraph-start "\\|\\s *\\s(")))
 294       (beginning-of-line)
 295       (fill-region (point) end))
 296     ;; Canonicalize the white space at the end of the entry so it is
 297     ;; separated from the next entry by a single blank line.
 298     (skip-syntax-forward " " end)
 299     (delete-char (- (skip-syntax-backward " ")))
 300     (or (eobp) (looking-at "\n\n")
 301         (insert "\n"))))
 302
 303 ;; Compatibility with old names.
 304 (define-obsolete-variable-alias 'vc-comment-ring 'log-edit-comment-ring "22.1")
 305 (define-obsolete-variable-alias 'vc-comment-ring-index 'log-edit-comment-ring-index "22.1")
 306 (define-obsolete-function-alias 'vc-previous-comment 'log-edit-previous-comment "22.1")
 307 (define-obsolete-function-alias 'vc-next-comment 'log-edit-next-comment "22.1")
 308 (define-obsolete-function-alias 'vc-comment-search-reverse 'log-edit-comment-search-backward "22.1")
 309 (define-obsolete-function-alias 'vc-comment-search-forward 'log-edit-comment-search-forward "22.1")
 310 (define-obsolete-function-alias 'vc-comment-to-change-log 'log-edit-comment-to-change-log "22.1")
 311
 312 ;;;
 313 ;;; Actual code
 314 ;;;
 315
 316 (defface log-edit-summary '((t :inherit font-lock-function-name-face))
 317   "Face for the summary in `log-edit-mode' buffers.")
 318
 319 (defface log-edit-header '((t :inherit font-lock-keyword-face))
 320   "Face for the headers in `log-edit-mode' buffers.")
 321
 322 (defface log-edit-unknown-header '((t :inherit font-lock-comment-face))
 323   "Face for unknown headers in `log-edit-mode' buffers.")
 324
 325 (defvar log-edit-headers-alist '(("Summary" . log-edit-summary)
 326                                  ("Fixes") ("Author"))
 327   "AList of known headers and the face to use to highlight them.")
 328
 329 (defconst log-edit-header-contents-regexp
 330   "[ \t]*\\(.*\\(\n[ \t].*\\)*\\)\n?")
 331
 332 (defun log-edit-match-to-eoh (_limit)
 333   ;; FIXME: copied from message-match-to-eoh.
 334   (let ((start (point)))
 335     (rfc822-goto-eoh)
 336     ;; Typical situation: some temporary change causes the header to be
 337     ;; incorrect, so EOH comes earlier than intended: the last lines of the
 338     ;; intended headers are now not considered part of the header any more,
 339     ;; so they don't have the multiline property set.  When the change is
 340     ;; completed and the header has its correct shape again, the lack of the
 341     ;; multiline property means we won't rehighlight the last lines of
 342     ;; the header.
 343     (if (< (point) start)
 344         nil                             ;No header within start..limit.
 345       ;; Here we disregard LIMIT so that we may extend the area again.
 346       (set-match-data (list start (point)))
 347       (point))))
 348
 349 (defvar log-edit-font-lock-keywords
 350   ;; Copied/inspired by message-font-lock-keywords.
 351   `((log-edit-match-to-eoh
 352      (,(concat "^\\(\\([a-z]+\\):\\)" log-edit-header-contents-regexp)
 353       (progn (goto-char (match-beginning 0)) (match-end 0)) nil
 354       (1 (if (assoc (match-string 2) log-edit-headers-alist)
 355              'log-edit-header
 356            'log-edit-unknown-header)
 357          nil lax)
 358       ;; From `log-edit-header-contents-regexp':
 359       (3 (or (cdr (assoc (match-string 2) log-edit-headers-alist))
 360              'log-edit-header)
 361          nil lax)))))
 362
 363 ;;;###autoload
 364 (defun log-edit (callback &optional setup params buffer mode &rest _ignore)
 365   "Setup a buffer to enter a log message.
 366 \\<log-edit-mode-map>The buffer will be put in mode MODE or `log-edit-mode'
 367 if MODE is nil.
 368 If SETUP is non-nil, the buffer is then erased and `log-edit-hook' is run.
 369 Mark and point will be set around the entire contents of the buffer so
 370 that it is easy to kill the contents of the buffer with \\[kill-region].
 371 Once you're done editing the message, pressing \\[log-edit-done] will call
 372 `log-edit-done' which will end up calling CALLBACK to do the actual commit.
 373
 374 PARAMS if non-nil is an alist.  Possible keys and associated values:
 375  `log-edit-listfun' -- function taking no arguments that returns the list of
 376  files that are concerned by the current operation (using relative names);
 377  `log-edit-diff-function' -- function taking no arguments that
 378  displays a diff of the files concerned by the current operation.
 379
 380 If BUFFER is non-nil `log-edit' will jump to that buffer, use it to edit the
 381 log message and go back to the current buffer when done.  Otherwise, it
 382 uses the current buffer."
 383   (let ((parent (current-buffer)))
 384     (if buffer (pop-to-buffer buffer))
 385     (when (and log-edit-setup-invert (not (eq setup 'force)))
 386       (setq setup (not setup)))
 387     (when setup
 388       (erase-buffer)
 389       (insert "Summary: \nAuthor: ")
 390       (save-excursion (insert "\n\n")))
 391     (if mode
 392         (funcall mode)
 393       (log-edit-mode))
 394     (set (make-local-variable 'log-edit-callback) callback)
 395     (if (listp params)
 396         (dolist (crt params)
 397           (set (make-local-variable (car crt)) (cdr crt)))
 398       ;; For backward compatibility with log-edit up to version 22.2
 399       ;; accept non-list PARAMS to mean `log-edit-list'.
 400       (set (make-local-variable 'log-edit-listfun) params))
 401
 402     (if buffer (set (make-local-variable 'log-edit-parent-buffer) parent))
 403     (set (make-local-variable 'log-edit-initial-files) (log-edit-files))
 404     (when setup (run-hooks 'log-edit-hook))
 405     (goto-char (point-min)) (push-mark (point-max))
 406     (message "%s" (substitute-command-keys
 407               "Press \\[log-edit-done] when you are done editing."))))
 408
 409 (define-derived-mode log-edit-mode text-mode "Log-Edit"
 410   "Major mode for editing version-control log messages.
 411 When done editing the log entry, just type \\[log-edit-done] which
 412 will trigger the actual commit of the file(s).
 413 Several other handy support commands are provided of course and
 414 the package from which this is used might also provide additional
 415 commands (under C-x v for VC, for example).
 416
 417 \\{log-edit-mode-map}"
 418   (set (make-local-variable 'font-lock-defaults)
 419        '(log-edit-font-lock-keywords t t))
 420   (make-local-variable 'log-edit-comment-ring-index)
 421   (hack-dir-local-variables-non-file-buffer))
 422
 423 (defun log-edit-hide-buf (&optional buf where)
 424   (when (setq buf (get-buffer (or buf log-edit-files-buf)))
 425     (let ((win (get-buffer-window buf where)))
 426       (if win (ignore-errors (delete-window win))))
 427     (bury-buffer buf)))
 428
 429 (defun log-edit-done ()
 430   "Finish editing the log message and commit the files.
 431 If you want to abort the commit, simply delete the buffer."
 432   (interactive)
 433   ;; Clean up empty headers.
 434   (goto-char (point-min))
 435   (while (looking-at (concat "^[a-z]*:" log-edit-header-contents-regexp))
 436     (let ((beg (match-beginning 0)))
 437       (goto-char (match-end 0))
 438       (if (string-match "\\`[ \n\t]*\\'" (match-string 1))
 439           (delete-region beg (point)))))
 440   ;; Get rid of leading empty lines.
 441   (goto-char (point-min))
 442   (when (looking-at "\\([ \t]*\n\\)+")
 443     (delete-region (match-beginning 0) (match-end 0)))
 444   ;; Get rid of trailing empty lines
 445   (goto-char (point-max))
 446   (skip-syntax-backward " ")
 447   (when (equal (char-after) ?\n) (forward-char 1))
 448   (delete-region (point) (point-max))
 449   ;; Check for final newline
 450   (if (and (> (point-max) (point-min))
 451            (/= (char-before (point-max)) ?\n)
 452            (or (eq log-edit-require-final-newline t)
 453                (and log-edit-require-final-newline
 454                     (y-or-n-p
 455                      (format "Buffer %s does not end in newline.  Add one? "
 456                              (buffer-name))))))
 457       (save-excursion
 458         (goto-char (point-max))
 459         (insert ?\n)))
 460   (let ((comment (buffer-string)))
 461     (when (or (ring-empty-p log-edit-comment-ring)
 462               (not (equal comment (ring-ref log-edit-comment-ring 0))))
 463       (ring-insert log-edit-comment-ring comment)))
 464   (let ((win (get-buffer-window log-edit-files-buf)))
 465     (if (and log-edit-confirm
 466              (not (and (eq log-edit-confirm 'changed)
 467                        (equal (log-edit-files) log-edit-initial-files)))
 468              (progn
 469                (log-edit-show-files)
 470                (not (y-or-n-p "Really commit? "))))
 471         (progn (when (not win) (log-edit-hide-buf))
 472                (message "Oh, well!  Later maybe?"))
 473       (run-hooks 'log-edit-done-hook)
 474       (log-edit-hide-buf)
 475       (unless (or log-edit-keep-buffer (not log-edit-parent-buffer))
 476         (cvs-bury-buffer (current-buffer) log-edit-parent-buffer))
 477       (call-interactively log-edit-callback))))
 478
 479 (defun log-edit-files ()
 480   "Return the list of files that are about to be committed."
 481   (ignore-errors (funcall log-edit-listfun)))
 482
 483 (defun log-edit-mode-help ()
 484   "Provide help for the `log-edit-mode-map'."
 485   (interactive)
 486   (if (eq last-command 'log-edit-mode-help)
 487       (describe-function major-mode)
 488     (message "%s"
 489      (substitute-command-keys
 490       "Type `\\[log-edit-done]' to finish commit.  Try `\\[describe-function] log-edit-done' for more help."))))
 491
 492 (defcustom log-edit-common-indent 0
 493   "Minimum indentation to use in `log-edit-set-common-indentation'."
 494   :group 'log-edit
 495   :type 'integer)
 496
 497 (defun log-edit-set-common-indentation ()
 498   "(Un)Indent the current buffer rigidly to `log-edit-common-indent'."
 499   (save-excursion
 500     (let ((common (point-max)))
 501       (rfc822-goto-eoh)
 502       (while (< (point) (point-max))
 503         (if (not (looking-at "^[ \t]*$"))
 504             (setq common (min common (current-indentation))))
 505         (forward-line 1))
 506       (rfc822-goto-eoh)
 507       (indent-rigidly (point) (point-max)
 508                       (- log-edit-common-indent common)))))
 509
 510 (defun log-edit-show-diff ()
 511   "Show the diff for the files to be committed."
 512   (interactive)
 513   (if (functionp log-edit-diff-function)
 514       (funcall log-edit-diff-function)
 515     (error "Diff functionality has not been setup")))
 516
 517 (defun log-edit-show-files ()
 518   "Show the list of files to be committed."
 519   (interactive)
 520   (let* ((files (log-edit-files))
 521          (buf (get-buffer-create log-edit-files-buf)))
 522     (with-current-buffer buf
 523       (log-edit-hide-buf buf 'all)
 524       (setq buffer-read-only nil)
 525       (erase-buffer)
 526       (cvs-insert-strings files)
 527       (setq buffer-read-only t)
 528       (goto-char (point-min))
 529       (save-selected-window
 530         (cvs-pop-to-buffer-same-frame buf)
 531         (shrink-window-if-larger-than-buffer)
 532         (selected-window)))))
 533
 534 (defun log-edit-empty-buffer-p ()
 535   "Return non-nil if the buffer is \"empty\"."
 536   (or (= (point-min) (point-max))
 537       (save-excursion
 538         (goto-char (point-min))
 539         (while (and (looking-at "^\\([a-zA-Z]+: \\)?$")
 540                     (zerop (forward-line 1))))
 541         (eobp))))
 542
 543 (defun log-edit-insert-cvs-template ()
 544   "Insert the template specified by the CVS administrator, if any.
 545 This simply uses the local CVS/Template file."
 546   (interactive)
 547   (when (or (called-interactively-p 'interactive)
 548             (log-edit-empty-buffer-p))
 549     ;; Should the template take precedence over an empty Summary:,
 550     ;; ie should we first erase the buffer?
 551     (when (file-readable-p "CVS/Template")
 552       (goto-char (point-max))
 553       (insert-file-contents "CVS/Template"))))
 554
 555 (defun log-edit-insert-cvs-rcstemplate ()
 556   "Insert the rcstemplate from the CVS repository.
 557 This contacts the repository to get the rcstemplate file and
 558 can thus take some time."
 559   (interactive)
 560   (when (or (called-interactively-p 'interactive)
 561             (log-edit-empty-buffer-p))
 562     (when (file-readable-p "CVS/Root")
 563       (goto-char (point-max))
 564       ;; Ignore the stderr stuff, even if it's an error.
 565       (call-process "cvs" nil '(t nil) nil
 566                     "checkout" "-p" "CVSROOT/rcstemplate"))))
 567
 568 (defun log-edit-insert-filenames ()
 569   "Insert the list of files that are to be committed."
 570   (interactive)
 571   (insert "Affected files:  \n"
 572           (mapconcat 'identity (log-edit-files) "  \n")))
 573
 574 (defun log-edit-add-to-changelog ()
 575   "Insert this log message into the appropriate ChangeLog file."
 576   (interactive)
 577   ;; Yuck!
 578   (unless (string= (buffer-string) (ring-ref log-edit-comment-ring 0))
 579     (ring-insert log-edit-comment-ring (buffer-string)))
 580   (dolist (f (log-edit-files))
 581     (let ((buffer-file-name (expand-file-name f)))
 582       (save-excursion
 583         (log-edit-comment-to-change-log)))))
 584
 585 (defvar log-edit-changelog-use-first nil)
 586
 587 (defvar log-edit-rewrite-fixes nil
 588   "Rule to rewrite bug numbers into Fixes: headers.
 589 The value should be of the form (REGEXP . REPLACEMENT)
 590 where REGEXP should match the expression referring to a bug number
 591 in the text, and REPLACEMENT is an expression to pass to `replace-match'
 592 to build the Fixes: header.")
 593 (put 'log-edit-rewrite-fixes 'safe-local-variable
 594      (lambda (v) (and (stringp (car-safe v)) (stringp (cdr v)))))
 595
 596 (defun log-edit-add-field (field value)
 597   (rfc822-goto-eoh)
 598   (if (save-excursion (re-search-backward (concat "^" field ":\\([ \t]*\\)$")
 599                                           nil t))
 600       (replace-match (concat " " value) t t nil 1)
 601     (insert field ": " value "\n" (if (looking-at "\n") "" "\n"))))
 602
 603 (defun log-edit-insert-changelog (&optional use-first)
 604   "Insert a log message by looking at the ChangeLog.
 605 The idea is to write your ChangeLog entries first, and then use this
 606 command to commit your changes.
 607
 608 To select default log text, we:
 609 - find the ChangeLog entries for the files to be checked in,
 610 - verify that the top entry in the ChangeLog is on the current date
 611   and by the current user; if not, we don't provide any default text,
 612 - search the ChangeLog entry for paragraphs containing the names of
 613   the files we're checking in, and finally
 614 - use those paragraphs as the log text.
 615
 616 If the optional prefix arg USE-FIRST is given (via \\[universal-argument]),
 617 or if the command is repeated a second time in a row, use the first log entry
 618 regardless of user name or time."
 619   (interactive "P")
 620   (let ((eoh (save-excursion (rfc822-goto-eoh) (point))))
 621     (when (<= (point) eoh)
 622       (goto-char eoh)
 623       (if (looking-at "\n") (forward-char 1))))
 624   (let ((author
 625          (let ((log-edit-changelog-use-first
 626                 (or use-first (eq last-command 'log-edit-insert-changelog))))
 627            (log-edit-insert-changelog-entries (log-edit-files)))))
 628     (log-edit-set-common-indentation)
 629     ;; Add an Author: field if appropriate.
 630     (when author (log-edit-add-field "Author" author))
 631     ;; Add a Fixes: field if applicable.
 632     (when (consp log-edit-rewrite-fixes)
 633       (rfc822-goto-eoh)
 634       (when (re-search-forward (car log-edit-rewrite-fixes) nil t)
 635         (let ((start (match-beginning 0))
 636               (end (match-end 0))
 637               (fixes (match-substitute-replacement
 638                       (cdr log-edit-rewrite-fixes))))
 639           (delete-region start end)
 640           (log-edit-add-field "Fixes" fixes))))
 641     (and log-edit-strip-single-file-name
 642          (progn (rfc822-goto-eoh)
 643                 (if (looking-at "\n") (forward-char 1))
 644                 (looking-at "\\*\\s-+"))
 645          (let ((start (point)))
 646            (forward-line 1)
 647            (when (not (re-search-forward "^\\*\\s-+" nil t))
 648              (goto-char start)
 649              (skip-chars-forward "^():")
 650              (skip-chars-forward ": ")
 651              (delete-region start (point)))))
 652     (goto-char (point-min))))
 653
 654 ;;;;
 655 ;;;; functions for getting commit message from ChangeLog a file...
 656 ;;;; Courtesy Jim Blandy
 657 ;;;;
 658
 659 (defun log-edit-narrow-changelog ()
 660   "Narrow to the top page of the current buffer, a ChangeLog file.
 661 Actually, the narrowed region doesn't include the date line.
 662 A \"page\" in a ChangeLog file is the area between two dates."
 663   (or (eq major-mode 'change-log-mode)
 664       (error "log-edit-narrow-changelog: current buffer isn't a ChangeLog"))
 665
 666   (goto-char (point-min))
 667
 668   ;; Skip date line and subsequent blank lines.
 669   (forward-line 1)
 670   (if (looking-at "[ \t\n]*\n")
 671       (goto-char (match-end 0)))
 672
 673   (let ((start (point)))
 674     (forward-page 1)
 675     (narrow-to-region start (point))
 676     (goto-char (point-min))))
 677
 678 (defun log-edit-changelog-paragraph ()
 679   "Return the bounds of the ChangeLog paragraph containing point.
 680 If we are between paragraphs, return the previous paragraph."
 681   (beginning-of-line)
 682   (if (looking-at "^[ \t]*$")
 683       (skip-chars-backward " \t\n" (point-min)))
 684   (list (progn
 685           (if (re-search-backward "^[ \t]*\n" nil 'or-to-limit)
 686               (goto-char (match-end 0)))
 687           (point))
 688         (if (re-search-forward "^[ \t\n]*$" nil t)
 689             (match-beginning 0)
 690           (point-max))))
 691
 692 (defun log-edit-changelog-subparagraph ()
 693   "Return the bounds of the ChangeLog subparagraph containing point.
 694 A subparagraph is a block of non-blank lines beginning with an asterisk.
 695 If we are between sub-paragraphs, return the previous subparagraph."
 696     (end-of-line)
 697     (if (search-backward "*" nil t)
 698         (list (progn (beginning-of-line) (point))
 699               (progn
 700                 (forward-line 1)
 701                 (if (re-search-forward "^[ \t]*[\n*]" nil t)
 702                     (match-beginning 0)
 703                   (point-max))))
 704     (list (point) (point))))
 705
 706 (defun log-edit-changelog-entry ()
 707   "Return the bounds of the ChangeLog entry containing point.
 708 The variable `log-edit-changelog-full-paragraphs' decides whether an
 709 \"entry\" is a paragraph or a subparagraph; see its documentation string
 710 for more details."
 711   (save-excursion
 712     (if log-edit-changelog-full-paragraphs
 713         (log-edit-changelog-paragraph)
 714       (log-edit-changelog-subparagraph))))
 715
 716 (defvar user-full-name)
 717 (defvar user-mail-address)
 718
 719 (defvar log-edit-author)                ;Dynamically scoped.
 720
 721 (defun log-edit-changelog-ours-p ()
 722   "See if ChangeLog entry at point is for the current user, today.
 723 Return non-nil if it is."
 724   ;; Code adapted from add-change-log-entry.
 725   (let ((name (or (and (boundp 'add-log-full-name) add-log-full-name)
 726                   (and (fboundp 'user-full-name) (user-full-name))
 727                   (and (boundp 'user-full-name) user-full-name)))
 728         (mail (or (and (boundp 'add-log-mailing-address) add-log-mailing-address)
 729                   ;;(and (fboundp 'user-mail-address) (user-mail-address))
 730                   (and (boundp 'user-mail-address) user-mail-address)))
 731         (time (or (and (boundp 'add-log-time-format)
 732                        (functionp add-log-time-format)
 733                        (funcall add-log-time-format))
 734                   (format-time-string "%Y-%m-%d"))))
 735     (if (null log-edit-changelog-use-first)
 736         (looking-at (regexp-quote (format "%s  %s  <%s>" time name mail)))
 737       ;; Check the author, to potentially add it as a "Author: " header.
 738       (when (looking-at "[^ \t]")
 739         (when (and (boundp 'log-edit-author)
 740                    (not (looking-at (format ".+  .+  <%s>"
 741                                             (regexp-quote mail))))
 742                    (looking-at ".+  \\(.+  <.+>\\)"))
 743           (let ((author (replace-regexp-in-string "  " " "
 744                                                   (match-string 1))))
 745             (unless (and log-edit-author
 746                          (string-match (regexp-quote author) log-edit-author))
 747               (setq log-edit-author
 748                     (if log-edit-author
 749                         (concat log-edit-author ", " author)
 750                       author)))))
 751         t))))
 752
 753 (defun log-edit-changelog-entries (file)
 754   "Return the ChangeLog entries for FILE, and the ChangeLog they came from.
 755 The return value looks like this:
 756   (LOGBUFFER (ENTRYSTART ENTRYEND) ...)
 757 where LOGBUFFER is the name of the ChangeLog buffer, and each
 758 \(ENTRYSTART . ENTRYEND\) pair is a buffer region."
 759   (let ((changelog-file-name
 760          (let ((default-directory
 761                  (file-name-directory (expand-file-name file)))
 762                (visiting-buffer (find-buffer-visiting file)))
 763            ;; If there is a buffer visiting FILE, and it has a local
 764            ;; value for `change-log-default-name', use that.
 765            (if (and visiting-buffer
 766                     (local-variable-p 'change-log-default-name
 767                                       visiting-buffer))
 768                (with-current-buffer visiting-buffer
 769                  change-log-default-name)
 770              ;; `find-change-log' uses `change-log-default-name' if set
 771              ;; and sets it before exiting, so we need to work around
 772              ;; that memoizing which is undesired here
 773              (setq change-log-default-name nil)
 774              (find-change-log)))))
 775     (with-current-buffer (find-file-noselect changelog-file-name)
 776       (unless (eq major-mode 'change-log-mode) (change-log-mode))
 777       (goto-char (point-min))
 778       (if (looking-at "\\s-*\n") (goto-char (match-end 0)))
 779       (if (not (log-edit-changelog-ours-p))
 780           (list (current-buffer))
 781         (save-restriction
 782           (log-edit-narrow-changelog)
 783           (goto-char (point-min))
 784
 785           ;; Search for the name of FILE relative to the ChangeLog.  If that
 786           ;; doesn't occur anywhere, they're not using full relative
 787           ;; filenames in the ChangeLog, so just look for FILE; we'll accept
 788           ;; some false positives.
 789           (let ((pattern (file-relative-name
 790                           file (file-name-directory changelog-file-name))))
 791             (if (or (string= pattern "")
 792                     (not (save-excursion
 793                            (search-forward pattern nil t))))
 794                 (setq pattern (file-name-nondirectory file)))
 795
 796             (setq pattern (concat "\\(^\\|[^[:alnum:]]\\)"
 797                                   (regexp-quote pattern)
 798                                   "\\($\\|[^[:alnum:]]\\)"))
 799
 800             (let (texts
 801                   (pos (point)))
 802               (while (and (not (eobp)) (re-search-forward pattern nil t))
 803                 (let ((entry (log-edit-changelog-entry)))
 804                   (if (< (elt entry 1) (max (1+ pos) (point)))
 805                       ;; This is not relevant, actually.
 806                       nil
 807                     (push entry texts))
 808                   ;; Make sure we make progress.
 809                   (setq pos (max (1+ pos) (elt entry 1)))
 810                   (goto-char pos)))
 811
 812               (cons (current-buffer) texts))))))))
 813
 814 (defun log-edit-changelog-insert-entries (buffer beg end &rest files)
 815   "Insert the text from BUFFER between BEG and END.
 816 Rename relative filenames in the ChangeLog entry as FILES."
 817   (let ((opoint (point))
 818         (log-name (buffer-file-name buffer))
 819         (case-fold-search nil)
 820         bound)
 821     (insert-buffer-substring buffer beg end)
 822     (setq bound (point-marker))
 823     (when log-name
 824       (dolist (f files)
 825         (save-excursion
 826           (goto-char opoint)
 827           (when (re-search-forward
 828                  (concat "\\(^\\|[ \t]\\)\\("
 829                          (file-relative-name f (file-name-directory log-name))
 830                          "\\)[, :\n]")
 831                  bound t)
 832             (replace-match f t t nil 2)))))
 833     ;; Eliminate tabs at the beginning of the line.
 834     (save-excursion
 835       (goto-char opoint)
 836       (while (re-search-forward "^\\(\t+\\)" bound t)
 837         (replace-match "")))))
 838
 839 (defun log-edit-insert-changelog-entries (files)
 840   "Given a list of files FILES, insert the ChangeLog entries for them."
 841   (let ((log-entries nil)
 842         (log-edit-author nil))
 843     ;; Note that any ChangeLog entry can apply to more than one file.
 844     ;; Here we construct a log-entries list with elements of the form
 845     ;;   ((LOGBUFFER ENTRYSTART ENTRYEND) FILE1 FILE2...)
 846     (dolist (file files)
 847       (let* ((entries (log-edit-changelog-entries file))
 848              (buf (car entries))
 849              key entry)
 850         (dolist (region (cdr entries))
 851           (setq key (cons buf region))
 852           (if (setq entry (assoc key log-entries))
 853               (setcdr entry (append (cdr entry) (list file)))
 854             (push (list key file) log-entries)))))
 855     ;; Now map over log-entries, and extract the strings.
 856     (dolist (log-entry (nreverse log-entries))
 857       (apply 'log-edit-changelog-insert-entries
 858              (append (car log-entry) (cdr log-entry)))
 859       (insert "\n"))
 860     log-edit-author))
 861
 862 (defun log-edit-extract-headers (headers comment)
 863   "Extract headers from COMMENT to form command line arguments.
 864 HEADERS should be an alist with elements of the form (HEADER . CMDARG)
 865 associating header names to the corresponding cmdline option name and the
 866 result is then a list of the form (MSG CMDARG1 HDRTEXT1 CMDARG2 HDRTEXT2...).
 867 where MSG is the remaining text from STRING.
 868 If \"Summary\" is not in HEADERS, then the \"Summary\" header is extracted
 869 anyway and put back as the first line of MSG."
 870   (with-temp-buffer
 871     (insert comment)
 872     (rfc822-goto-eoh)
 873     (narrow-to-region (point-min) (point))
 874     (let ((case-fold-search t)
 875           (summary ())
 876           (res ()))
 877       (dolist (header (if (assoc "Summary" headers) headers
 878                         (cons '("Summary" . t) headers)))
 879         (goto-char (point-min))
 880         (while (re-search-forward (concat "^" (car header)
 881                                           ":" log-edit-header-contents-regexp)
 882                                   nil t)
 883           (if (eq t (cdr header))
 884               (setq summary (match-string 1))
 885             (push (match-string 1) res)
 886             (push (or (cdr header) (car header)) res))
 887           (replace-match "" t t)))
 888       ;; Remove header separator if the header is empty.
 889       (widen)
 890       (goto-char (point-min))
 891       (when (looking-at "\\([ \t]*\n\\)+")
 892         (delete-region (match-beginning 0) (match-end 0)))
 893       (if summary (insert summary "\n"))
 894       (cons (buffer-string) res))))
 895
 896 (provide 'log-edit)
 897
 898 ;;; log-edit.el ends here