lisp/vc/vc-mtn.el

   1 ;;; vc-mtn.el --- VC backend for Monotone  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2007-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   6 ;; Keywords: vc
   7 ;; Package: vc
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;
  27
  28 ;;; TODO:
  29
  30 ;; - The `previous-version' VC method needs to be supported, 'D' in
  31 ;;   log-view-mode uses it.
  32
  33 ;;; Code:
  34
  35 (eval-when-compile (require 'vc))
  36
  37 (defgroup vc-mtn nil
  38   "VC Monotone (mtn) backend."
  39   :version "24.1"
  40   :group 'vc)
  41
  42 (defcustom vc-mtn-diff-switches t
  43   "String or list of strings specifying switches for monotone diff under VC.
  44 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  45   :type '(choice (const :tag "Unspecified" nil)
  46                  (const :tag "None" t)
  47                  (string :tag "Argument String")
  48                  (repeat :tag "Argument List" :value ("") string))
  49   :version "23.1"
  50   :group 'vc-mtn)
  51
  52 (define-obsolete-variable-alias 'vc-mtn-command 'vc-mtn-program "23.1")
  53 (defcustom vc-mtn-program "mtn"
  54   "Name of the monotone executable."
  55   :type 'string
  56   :group 'vc-mtn)
  57
  58 ;; Clear up the cache to force vc-call to check again and discover
  59 ;; new functions when we reload this file.
  60 (put 'Mtn 'vc-functions nil)
  61
  62 (unless (executable-find vc-mtn-program)
  63   ;; vc-mtn.el is 100% non-functional without the `mtn' executable.
  64   (setq vc-handled-backends (delq 'Mtn vc-handled-backends)))
  65
  66 ;;;###autoload
  67 (defconst vc-mtn-admin-dir "_MTN" "Name of the monotone directory.")
  68 ;;;###autoload
  69 (defconst vc-mtn-admin-format (concat vc-mtn-admin-dir "/format")
  70   "Name of the monotone directory's format file.")
  71
  72 ;;;###autoload (defun vc-mtn-registered (file)
  73 ;;;###autoload   (if (vc-find-root file vc-mtn-admin-format)
  74 ;;;###autoload       (progn
  75 ;;;###autoload         (load "vc-mtn" nil t)
  76 ;;;###autoload         (vc-mtn-registered file))))
  77
  78 (defun vc-mtn-revision-granularity () 'repository)
  79 (defun vc-mtn-checkout-model (_files) 'implicit)
  80
  81 (defun vc-mtn-root (file)
  82   (setq file (if (file-directory-p file)
  83                  (file-name-as-directory file)
  84                (file-name-directory file)))
  85   (or (vc-file-getprop file 'vc-mtn-root)
  86       (vc-file-setprop file 'vc-mtn-root
  87                        (vc-find-root file vc-mtn-admin-format))))
  88
  89
  90 (defun vc-mtn-registered (file)
  91   (let ((root (vc-mtn-root file)))
  92     (when root
  93       (vc-mtn-state file))))
  94
  95 (defun vc-mtn-command (buffer okstatus files &rest flags)
  96   "A wrapper around `vc-do-command' for use in vc-mtn.el."
  97   (let ((process-environment
  98          ;; Avoid localization of messages so we can parse the output.
  99          (cons "LC_MESSAGES=C" process-environment)))
 100     (apply 'vc-do-command (or buffer "*vc*") okstatus vc-mtn-program
 101            files flags)))
 102
 103 (defun vc-mtn-state (file)
 104   ;; If `mtn' fails or returns status>0, or if the search files, just
 105   ;; return nil.
 106   (ignore-errors
 107     (with-temp-buffer
 108       (vc-mtn-command t 0 file "status")
 109       (goto-char (point-min))
 110       (re-search-forward
 111        "^  \\(?:\\(patched\\)\\|\\(added\\) \\(?:.*\\)\\)\\|no changes$")
 112       (cond  ((match-end 1) 'edited)
 113              ((match-end 2) 'added)
 114              (t 'up-to-date)))))
 115
 116 (defun vc-mtn-after-dir-status (update-function)
 117   (let (result)
 118     (goto-char (point-min))
 119     (re-search-forward "\\(?:Current b\\|B\\)ranch:  *\\(.*\\)\n?\nChanges against parent \\(.*\\)" nil t)
 120     (while (re-search-forward
 121             "^  \\(?:\\(patched  \\)\\|\\(added    \\)\\)\\(.*\\)$" nil t)
 122       (cond  ((match-end 1) (push (list (match-string 3) 'edited) result))
 123              ((match-end 2) (push (list (match-string 3) 'added) result))))
 124     (funcall update-function result)))
 125
 126 ;; -dir-status called from vc-dir, which loads vc, which loads vc-dispatcher.
 127 (declare-function vc-exec-after "vc-dispatcher" (code))
 128
 129 (defun vc-mtn-dir-status (dir update-function)
 130   (vc-mtn-command (current-buffer) 'async dir "status")
 131   (vc-exec-after
 132    `(vc-mtn-after-dir-status (quote ,update-function))))
 133
 134 (defun vc-mtn-working-revision (file)
 135   ;; If `mtn' fails or returns status>0, or if the search fails, just
 136   ;; return nil.
 137   (ignore-errors
 138     (with-temp-buffer
 139       (vc-mtn-command t 0 file "status")
 140       (goto-char (point-min))
 141       (re-search-forward "\\(?:Current b\\|B\\)ranch:  *\\(.*\\)\n?\nChanges against parent \\(.*\\)")
 142       (match-string 2))))
 143
 144 (defun vc-mtn-workfile-branch (file)
 145   ;; If `mtn' fails or returns status>0, or if the search files, just
 146   ;; return nil.
 147   (ignore-errors
 148     (with-temp-buffer
 149       (vc-mtn-command t 0 file "status")
 150       (goto-char (point-min))
 151       (re-search-forward "\\(?:Current b\\|B\\)ranch:  *\\(.*\\)\n?\nChanges against parent \\(.*\\)")
 152       (match-string 1))))
 153
 154 (defun vc-mtn-workfile-unchanged-p (file)
 155   (not (eq (vc-mtn-state file) 'edited)))
 156
 157 ;; Mode-line rewrite code copied from vc-arch.el.
 158
 159 (defcustom vc-mtn-mode-line-rewrite
 160   '(("\\`[^:/#]*[:/#]" . ""))           ;Drop the host part.
 161   "Rewrite rules to shorten Mtn's revision names on the mode-line."
 162   :type '(repeat (cons regexp string))
 163   :version "22.2"
 164   :group 'vc-mtn)
 165
 166 (defun vc-mtn-mode-line-string (file)
 167   "Return a string for `vc-mode-line' to put in the mode line for FILE."
 168   (let ((branch (vc-mtn-workfile-branch file)))
 169     (dolist (rule vc-mtn-mode-line-rewrite)
 170       (if (string-match (car rule) branch)
 171           (setq branch (replace-match (cdr rule) t nil branch))))
 172     (format "Mtn%c%s"
 173             (pcase (vc-state file)
 174               ((or `up-to-date `needs-update) ?-)
 175               (`added ?@)
 176               (_ ?:))
 177             branch)))
 178
 179 (defun vc-mtn-register (files &optional _rev _comment)
 180   (vc-mtn-command nil 0 files "add"))
 181
 182 (defun vc-mtn-responsible-p (file) (vc-mtn-root file))
 183 (defun vc-mtn-could-register (file) (vc-mtn-root file))
 184
 185 (declare-function log-edit-extract-headers "log-edit" (headers string))
 186
 187 (defun vc-mtn-checkin (files _rev comment)
 188   (apply 'vc-mtn-command nil 0 files
 189          (nconc (list "commit" "-m")
 190                 (log-edit-extract-headers '(("Author" . "--author")
 191                                             ("Date" . "--date"))
 192                                           comment))))
 193
 194 (defun vc-mtn-find-revision (file rev buffer)
 195   (vc-mtn-command buffer 0 file "cat" "-r" rev))
 196
 197 ;; (defun vc-mtn-checkout (file &optional editable rev)
 198 ;;   )
 199
 200 (defun vc-mtn-revert (file &optional contents-done)
 201   (unless contents-done
 202     (vc-mtn-command nil 0 file "revert")))
 203
 204 ;; (defun vc-mtn-rollback (files)
 205 ;;   )
 206
 207 (defun vc-mtn-print-log (files buffer &optional _shortlog start-revision limit)
 208   "Print commit logs associated with FILES into specified BUFFER.
 209 _SHORTLOG is ignored.
 210 If START-REVISION is non-nil, it is the newest revision to show.
 211 If LIMIT is non-nil, show no more than this many entries."
 212   (apply 'vc-mtn-command buffer 0 files "log"
 213          (append
 214           (when start-revision (list "--from" (format "%s" start-revision)))
 215           (when limit (list "--last" (format "%s" limit))))))
 216
 217 (defvar log-view-message-re)
 218 (defvar log-view-file-re)
 219 (defvar log-view-font-lock-keywords)
 220 (defvar log-view-per-file-logs)
 221
 222 (define-derived-mode vc-mtn-log-view-mode log-view-mode "Mtn-Log-View"
 223   ;; Don't match anything.
 224   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 225   (set (make-local-variable 'log-view-per-file-logs) nil)
 226   ;; TODO: Use a more precise regexp than "[ |/]+" to avoid false positives
 227   ;; in the ChangeLog text.
 228   (set (make-local-variable 'log-view-message-re)
 229        "^[ |/]+Revision: \\([0-9a-f]+\\)")
 230   (require 'add-log)                    ;For change-log faces.
 231   (set (make-local-variable 'log-view-font-lock-keywords)
 232        (append log-view-font-lock-keywords
 233                '(("^[ |]+Author: \\(.*\\)" (1 'change-log-email))
 234                  ("^[ |]+Date: \\(.*\\)" (1 'change-log-date-face))))))
 235
 236 ;; (defun vc-mtn-show-log-entry (revision)
 237 ;;   )
 238
 239 (autoload 'vc-switches "vc")
 240
 241 (defun vc-mtn-diff (files &optional rev1 rev2 buffer)
 242   "Get a difference report using monotone between two revisions of FILES."
 243   (apply 'vc-mtn-command (or buffer "*vc-diff*") 1 files "diff"
 244          (append
 245            (vc-switches 'mtn 'diff)
 246            (if rev1 (list "-r" rev1)) (if rev2 (list "-r" rev2)))))
 247
 248 (defun vc-mtn-annotate-command (file buf &optional rev)
 249   (apply 'vc-mtn-command buf 'async file "annotate"
 250          (if rev (list "-r" rev))))
 251
 252 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 253
 254 (defconst vc-mtn-annotate-full-re
 255   "^ *\\([0-9a-f]+\\)\\.* by [^ ]+ \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\): ")
 256 (defconst vc-mtn-annotate-any-re
 257   (concat "^\\(?: +: \\|" vc-mtn-annotate-full-re "\\)"))
 258
 259 (defun vc-mtn-annotate-time ()
 260   (when (looking-at vc-mtn-annotate-any-re)
 261     (goto-char (match-end 0))
 262     (let ((year (match-string 2)))
 263       (if (not year)
 264           ;; Look for the date on a previous line.
 265           (save-excursion
 266             (get-text-property (1- (previous-single-property-change
 267                                     (point) 'vc-mtn-time nil (point-min)))
 268                                'vc-mtn-time))
 269         (let ((time (vc-annotate-convert-time
 270                      (encode-time 0 0 0
 271                                   (string-to-number (match-string 4))
 272                                   (string-to-number (match-string 3))
 273                                   (string-to-number year)
 274                                   t))))
 275           (let ((inhibit-read-only t)
 276                 (inhibit-modification-hooks t))
 277             (put-text-property (match-beginning 0) (match-end 0)
 278                                'vc-mtn-time time))
 279           time)))))
 280
 281 (defun vc-mtn-annotate-extract-revision-at-line ()
 282   (save-excursion
 283     (when (or (looking-at vc-mtn-annotate-full-re)
 284               (re-search-backward vc-mtn-annotate-full-re nil t))
 285       (match-string 1))))
 286
 287 ;;; Revision completion.
 288
 289 (defun vc-mtn-list-tags ()
 290   (with-temp-buffer
 291     (vc-mtn-command t 0 nil "list" "tags")
 292     (goto-char (point-min))
 293     (let ((tags ()))
 294       (while (re-search-forward "^[^ ]+" nil t)
 295         (push (match-string 0) tags))
 296       tags)))
 297
 298 (defun vc-mtn-list-branches ()
 299   (with-temp-buffer
 300     (vc-mtn-command t 0 nil "list" "branches")
 301     (goto-char (point-min))
 302     (let ((branches ()))
 303       (while (re-search-forward "^.+" nil t)
 304         (push (match-string 0) branches))
 305       branches)))
 306
 307 (defun vc-mtn-list-revision-ids (prefix)
 308   (with-temp-buffer
 309     (vc-mtn-command t 0 nil "complete" "revision" prefix)
 310     (goto-char (point-min))
 311     (let ((ids ()))
 312       (while (re-search-forward "^.+" nil t)
 313         (push (match-string 0) ids))
 314       ids)))
 315
 316 (defun vc-mtn-revision-completion-table (_files)
 317   ;; What about using `files'?!?  --Stef
 318   (lambda (string pred action)
 319     (cond
 320      ;; Special chars for composite selectors.
 321      ((string-match ".*[^\\]\\(\\\\\\\\\\)*[/|;(]" string)
 322       (completion-table-with-context (substring string 0 (match-end 0))
 323                                      (vc-mtn-revision-completion-table nil)
 324                                      (substring string (match-end 0))
 325                                      pred action))
 326      ;; "Tag" selectors.
 327      ((string-match "\\`t:" string)
 328       (complete-with-action action
 329                             (mapcar (lambda (tag) (concat "t:" tag))
 330                                     (vc-mtn-list-tags))
 331                             string pred))
 332      ;; "Branch" or "Head" selectors.
 333      ((string-match "\\`[hb]:" string)
 334       (let ((prefix (match-string 0 string)))
 335         (complete-with-action action
 336                               (mapcar (lambda (tag) (concat prefix tag))
 337                                       (vc-mtn-list-branches))
 338                               string pred)))
 339      ;; "ID" selectors.
 340      ((string-match "\\`i:" string)
 341       (complete-with-action action
 342                             (mapcar (lambda (tag) (concat "i:" tag))
 343                                     (vc-mtn-list-revision-ids
 344                                      (substring string (match-end 0))))
 345                             string pred))
 346      (t
 347       (complete-with-action action
 348                             '("t:" "b:" "h:" "i:"
 349                               ;; Completion not implemented for these.
 350                               "c:" "a:" "k:" "d:" "m:" "e:" "l:" "i:" "p:"
 351                               ;; These have no arg to complete.
 352                               "u:" "w:"
 353                               ;; Selector functions.
 354                               "difference(" "lca(" "max(" "ancestors("
 355                               "descendants(" "parents(" "children("
 356                               "pick(")
 357                             string pred)))))
 358
 359
 360
 361 (provide 'vc-mtn)
 362
 363 ;;; vc-mtn.el ends here