m4/c-strtod.m4

   1 # c-strtod.m4 serial 16
   2
   3 # Copyright (C) 2004-2006, 2009-2018 Free Software Foundation, Inc.
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # Written by Paul Eggert.
   9
  10 AC_DEFUN([gl_C99_STRTOLD],
  11 [
  12   AC_CACHE_CHECK([whether strtold conforms to C99],
  13     [gl_cv_func_c99_strtold],
  14     [AC_LINK_IFELSE(
  15        [AC_LANG_PROGRAM(
  16           [[/* On HP-UX before 11.23, strtold returns a struct instead of
  17                 long double.  Reject implementations like that, by requiring
  18                 compatibility with the C99 prototype.  */
  19              #include <stdlib.h>
  20              static long double (*p) (char const *, char **) = strtold;
  21              static long double
  22              test (char const *nptr, char **endptr)
  23              {
  24                long double r;
  25                r = strtold (nptr, endptr);
  26                return r;
  27              }]],
  28            [[return test ("1.0", NULL) != 1 || p ("1.0", NULL) != 1;]])],
  29        [gl_cv_func_c99_strtold=yes],
  30        [gl_cv_func_c99_strtold=no])])
  31   if test $gl_cv_func_c99_strtold = yes; then
  32     AC_DEFINE([HAVE_C99_STRTOLD], [1], [Define to 1 if strtold conforms to C99.])
  33   fi
  34 ])
  35
  36 dnl Prerequisites of lib/c-strtod.c.
  37 AC_DEFUN([gl_C_STRTOD],
  38 [
  39   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  40
  41   AC_CHECK_HEADERS_ONCE([xlocale.h])
  42   dnl We can't use AC_CHECK_FUNC here, because strtod_l() is defined as a
  43   dnl static inline function when compiling for Android 7.1 or older.
  44   AC_CACHE_CHECK([for strtod_l], [gl_cv_func_strtod_l],
  45     [AC_LINK_IFELSE(
  46        [AC_LANG_PROGRAM(
  47           [[#include <stdlib.h>
  48             #include <locale.h>
  49             #if HAVE_XLOCALE_H
  50             # include <xlocale.h>
  51             #endif
  52             locale_t loc;
  53           ]],
  54           [[char *end;
  55             return strtod_l("0",&end,loc) < 0.0;
  56           ]])
  57        ],
  58        [gl_cv_func_strtod_l=yes],
  59        [gl_cv_func_strtod_l=no])
  60     ])
  61   if test $gl_cv_func_strtod_l = yes; then
  62     HAVE_STRTOD_L=1
  63   else
  64     HAVE_STRTOD_L=0
  65   fi
  66   AC_DEFINE_UNQUOTED([HAVE_STRTOD_L], [$HAVE_STRTOD_L],
  67     [Define to 1 if the system has the 'strtod_l' function.])
  68 ])
  69
  70 dnl Prerequisites of lib/c-strtold.c.
  71 AC_DEFUN([gl_C_STRTOLD],
  72 [
  73   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  74   AC_REQUIRE([gl_C99_STRTOLD])
  75   AC_CHECK_FUNCS([strtold_l])
  76 ])