lisp/vc-cvs.el

   1 ;;; vc-cvs.el --- non-resident support for CVS version-control
   2
   3 ;; Copyright (C) 1995, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author:      FSF (see vc.el for full credits)
   7 ;; Maintainer:  Andre Spiegel <spiegel@gnu.org>
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl) (require 'vc))
  29
  30 ;; Clear up the cache to force vc-call to check again and discover
  31 ;; new functions when we reload this file.
  32 (put 'CVS 'vc-functions nil)
  33
  34 ;;; Properties of the backend.
  35
  36 (defun vc-cvs-revision-granularity () 'file)
  37
  38 (defun vc-cvs-checkout-model (files)
  39   "CVS-specific version of `vc-checkout-model'."
  40   (if (getenv "CVSREAD")
  41       'announce
  42     (let* ((file (if (consp files) (car files) files))
  43            (attrib (file-attributes file)))
  44       (or (vc-file-getprop file 'vc-checkout-model)
  45           (vc-file-setprop
  46            file 'vc-checkout-model
  47            (if (and attrib ;; don't check further if FILE doesn't exist
  48                     ;; If the file is not writable (despite CVSREAD being
  49                     ;; undefined), this is probably because the file is being
  50                     ;; "watched" by other developers.
  51                     ;; (If vc-mistrust-permissions was t, we actually shouldn't
  52                     ;; trust this, but there is no other way to learn this from
  53                     ;; CVS at the moment (version 1.9).)
  54                     (string-match "r-..-..-." (nth 8 attrib)))
  55                'announce
  56              'implicit))))))
  57
  58 ;;;
  59 ;;; Customization options
  60 ;;;
  61
  62 (defcustom vc-cvs-global-switches nil
  63   "Global switches to pass to any CVS command."
  64   :type '(choice (const :tag "None" nil)
  65                  (string :tag "Argument String")
  66                  (repeat :tag "Argument List"
  67                          :value ("")
  68                          string))
  69   :version "22.1"
  70   :group 'vc)
  71
  72 (defcustom vc-cvs-register-switches nil
  73   "Switches for registering a file into CVS.
  74 A string or list of strings passed to the checkin program by
  75 \\[vc-register].  If nil, use the value of `vc-register-switches'.
  76 If t, use no switches."
  77   :type '(choice (const :tag "Unspecified" nil)
  78                  (const :tag "None" t)
  79                  (string :tag "Argument String")
  80                  (repeat :tag "Argument List" :value ("") string))
  81   :version "21.1"
  82   :group 'vc)
  83
  84 (defcustom vc-cvs-diff-switches nil
  85   "String or list of strings specifying switches for CVS diff under VC.
  86 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  87   :type '(choice (const :tag "Unspecified" nil)
  88                  (const :tag "None" t)
  89                  (string :tag "Argument String")
  90                  (repeat :tag "Argument List" :value ("") string))
  91   :version "21.1"
  92   :group 'vc)
  93
  94 (defcustom vc-cvs-header (or (cdr (assoc 'CVS vc-header-alist)) '("\$Id\$"))
  95   "Header keywords to be inserted by `vc-insert-headers'."
  96   :version "21.1"
  97   :type '(repeat string)
  98   :group 'vc)
  99
 100 (defcustom vc-cvs-use-edit t
 101   "Non-nil means to use `cvs edit' to \"check out\" a file.
 102 This is only meaningful if you don't use the implicit checkout model
 103 \(i.e. if you have $CVSREAD set)."
 104   :type 'boolean
 105   :version "21.1"
 106   :group 'vc)
 107
 108 (defcustom vc-cvs-stay-local 'only-file
 109   "Non-nil means use local operations when possible for remote repositories.
 110 This avoids slow queries over the network and instead uses heuristics
 111 and past information to determine the current status of a file.
 112
 113 If value is the symbol `only-file' `vc-dir' will connect to the
 114 server, but heuristics will be used to determine the status for
 115 all other VC operations.
 116
 117 The value can also be a regular expression or list of regular
 118 expressions to match against the host name of a repository; then VC
 119 only stays local for hosts that match it.  Alternatively, the value
 120 can be a list of regular expressions where the first element is the
 121 symbol `except'; then VC always stays local except for hosts matched
 122 by these regular expressions."
 123   :type '(choice (const :tag "Always stay local" t)
 124                  (const :tag "Only for file operations" only-file)
 125                  (const :tag "Don't stay local" nil)
 126                  (list :format "\nExamine hostname and %v"
 127                        :tag "Examine hostname ..."
 128                        (set :format "%v" :inline t
 129                             (const :format "%t" :tag "don't" except))
 130                        (regexp :format " stay local,\n%t: %v"
 131                                :tag "if it matches")
 132                        (repeat :format "%v%i\n" :inline t (regexp :tag "or"))))
 133   :version "23.1"
 134   :group 'vc)
 135
 136 (defcustom vc-cvs-sticky-date-format-string "%c"
 137   "Format string for mode-line display of sticky date.
 138 Format is according to `format-time-string'.  Only used if
 139 `vc-cvs-sticky-tag-display' is t."
 140   :type '(string)
 141   :version "22.1"
 142   :group 'vc)
 143
 144 (defcustom vc-cvs-sticky-tag-display t
 145   "Specify the mode-line display of sticky tags.
 146 Value t means default display, nil means no display at all.  If the
 147 value is a function or macro, it is called with the sticky tag and
 148 its' type as parameters, in that order.  TYPE can have three different
 149 values: `symbolic-name' (TAG is a string), `revision-number' (TAG is a
 150 string) and `date' (TAG is a date as returned by `encode-time').  The
 151 return value of the function or macro will be displayed as a string.
 152
 153 Here's an example that will display the formatted date for sticky
 154 dates and the word \"Sticky\" for sticky tag names and revisions.
 155
 156   (lambda (tag type)
 157     (cond ((eq type 'date) (format-time-string
 158                               vc-cvs-sticky-date-format-string tag))
 159           ((eq type 'revision-number) \"Sticky\")
 160           ((eq type 'symbolic-name) \"Sticky\")))
 161
 162 Here's an example that will abbreviate to the first character only,
 163 any text before the first occurrence of `-' for sticky symbolic tags.
 164 If the sticky tag is a revision number, the word \"Sticky\" is
 165 displayed.  Date and time is displayed for sticky dates.
 166
 167    (lambda (tag type)
 168      (cond ((eq type 'date) (format-time-string \"%Y%m%d %H:%M\" tag))
 169            ((eq type 'revision-number) \"Sticky\")
 170            ((eq type 'symbolic-name)
 171             (condition-case nil
 172                 (progn
 173                   (string-match \"\\\\([^-]*\\\\)\\\\(.*\\\\)\" tag)
 174                   (concat (substring (match-string 1 tag) 0 1) \":\"
 175                           (substring (match-string 2 tag) 1 nil)))
 176               (error tag)))))       ; Fall-back to given tag name.
 177
 178 See also variable `vc-cvs-sticky-date-format-string'."
 179   :type '(choice boolean function)
 180   :version "22.1"
 181   :group 'vc)
 182
 183 ;;;
 184 ;;; Internal variables
 185 ;;;
 186
 187
 188 ;;;
 189 ;;; State-querying functions
 190 ;;;
 191
 192 ;;;###autoload (defun vc-cvs-registered (f)
 193 ;;;###autoload   (when (file-readable-p (expand-file-name
 194 ;;;###autoload                    "CVS/Entries" (file-name-directory f)))
 195 ;;;###autoload       (load "vc-cvs")
 196 ;;;###autoload       (vc-cvs-registered f)))
 197
 198 (defun vc-cvs-registered (file)
 199   "Check if FILE is CVS registered."
 200   (let ((dirname (or (file-name-directory file) ""))
 201         (basename (file-name-nondirectory file))
 202         ;; make sure that the file name is searched case-sensitively
 203         (case-fold-search nil))
 204     (if (file-readable-p (expand-file-name "CVS/Entries" dirname))
 205         (or (string= basename "")
 206             (with-temp-buffer
 207               (vc-cvs-get-entries dirname)
 208               (goto-char (point-min))
 209               (cond ((re-search-forward
 210                       (concat "^/" (regexp-quote basename) "/[^/]") nil t)
 211                      (beginning-of-line)
 212                      (vc-cvs-parse-entry file)
 213                      t)
 214                     (t nil))))
 215       nil)))
 216
 217 (defun vc-cvs-state (file)
 218   "CVS-specific version of `vc-state'."
 219   (if (vc-stay-local-p file 'CVS)
 220       (let ((state (vc-file-getprop file 'vc-state)))
 221         ;; If we should stay local, use the heuristic but only if
 222         ;; we don't have a more precise state already available.
 223         (if (memq state '(up-to-date edited nil))
 224             (vc-cvs-state-heuristic file)
 225           state))
 226     (with-temp-buffer
 227       (cd (file-name-directory file))
 228       (vc-cvs-command t 0 file "status")
 229       (vc-cvs-parse-status t))))
 230
 231 (defun vc-cvs-state-heuristic (file)
 232   "CVS-specific state heuristic."
 233   ;; If the file has not changed since checkout, consider it `up-to-date'.
 234   ;; Otherwise consider it `edited'.
 235   (let ((checkout-time (vc-file-getprop file 'vc-checkout-time))
 236         (lastmod (nth 5 (file-attributes file))))
 237     (cond
 238      ((equal checkout-time lastmod) 'up-to-date)
 239      ((string= (vc-working-revision file) "0") 'added)
 240      ((null checkout-time) 'unregistered)
 241      (t 'edited))))
 242
 243 (defun vc-cvs-working-revision (file)
 244   "CVS-specific version of `vc-working-revision'."
 245   ;; There is no need to consult RCS headers under CVS, because we
 246   ;; get the workfile version for free when we recognize that a file
 247   ;; is registered in CVS.
 248   (vc-cvs-registered file)
 249   (vc-file-getprop file 'vc-working-revision))
 250
 251 (defun vc-cvs-mode-line-string (file)
 252   "Return string for placement into the modeline for FILE.
 253 Compared to the default implementation, this function does two things:
 254 Handle the special case of a CVS file that is added but not yet
 255 committed and support display of sticky tags."
 256   (let* ((sticky-tag (vc-file-getprop file 'vc-cvs-sticky-tag))
 257          help-echo
 258          (string
 259           (let ((def-ml (vc-default-mode-line-string 'CVS file)))
 260             (setq help-echo
 261                   (get-text-property 0 'help-echo def-ml))
 262             def-ml)))
 263     (propertize
 264      (if (zerop (length sticky-tag))
 265          string
 266        (setq help-echo (format "%s on the '%s' branch"
 267                                help-echo sticky-tag))
 268        (concat string "[" sticky-tag "]"))
 269      'help-echo help-echo)))
 270
 271
 272 ;;;
 273 ;;; State-changing functions
 274 ;;;
 275
 276 (defun vc-cvs-register (files &optional rev comment)
 277   "Register FILES into the CVS version-control system.
 278 COMMENT can be used to provide an initial description of FILES.
 279 Passes either `vc-cvs-register-switches' or `vc-register-switches'
 280 to the CVS command."
 281   ;; Register the directories if needed.
 282   (let (dirs)
 283     (dolist (file files)
 284       (and (not (vc-cvs-responsible-p file))
 285            (vc-cvs-could-register file)
 286            (push (directory-file-name (file-name-directory file)) dirs)))
 287     (if dirs (vc-cvs-register dirs)))
 288   (apply 'vc-cvs-command nil 0 files
 289          "add"
 290          (and comment (string-match "[^\t\n ]" comment)
 291               (concat "-m" comment))
 292          (vc-switches 'CVS 'register)))
 293
 294 (defun vc-cvs-responsible-p (file)
 295   "Return non-nil if CVS thinks it is responsible for FILE."
 296   (file-directory-p (expand-file-name "CVS"
 297                                       (if (file-directory-p file)
 298                                           file
 299                                         (file-name-directory file)))))
 300
 301 (defun vc-cvs-could-register (file)
 302   "Return non-nil if FILE could be registered in CVS.
 303 This is only possible if CVS is managing FILE's directory or one of
 304 its parents."
 305   (let ((dir file))
 306     (while (and (stringp dir)
 307                 (not (equal dir (setq dir (file-name-directory dir))))
 308                 dir)
 309       (setq dir (if (file-exists-p
 310                      (expand-file-name "CVS/Entries" dir))
 311                     t
 312                   (directory-file-name dir))))
 313     (eq dir t)))
 314
 315 (defun vc-cvs-checkin (files rev comment)
 316   "CVS-specific version of `vc-backend-checkin'."
 317   (unless (or (not rev) (vc-cvs-valid-revision-number-p rev))
 318     (if (not (vc-cvs-valid-symbolic-tag-name-p rev))
 319         (error "%s is not a valid symbolic tag name" rev)
 320       ;; If the input revison is a valid symbolic tag name, we create it
 321       ;; as a branch, commit and switch to it.
 322       (apply 'vc-cvs-command nil 0 files "tag" "-b" (list rev))
 323       (apply 'vc-cvs-command nil 0 files "update" "-r" (list rev))
 324       (mapc (lambda (file) (vc-file-setprop file 'vc-cvs-sticky-tag rev))
 325             files)))
 326   (let ((status (apply 'vc-cvs-command nil 1 files
 327                        "ci" (if rev (concat "-r" rev))
 328                        (concat "-m" comment)
 329                        (vc-switches 'CVS 'checkin))))
 330     (set-buffer "*vc*")
 331     (goto-char (point-min))
 332     (when (not (zerop status))
 333       ;; Check checkin problem.
 334       (cond
 335        ((re-search-forward "Up-to-date check failed" nil t)
 336         (mapc (lambda (file) (vc-file-setprop file 'vc-state 'needs-merge))
 337               files)
 338         (error "%s" (substitute-command-keys
 339                 (concat "Up-to-date check failed: "
 340                         "type \\[vc-next-action] to merge in changes"))))
 341        (t
 342         (pop-to-buffer (current-buffer))
 343         (goto-char (point-min))
 344         (shrink-window-if-larger-than-buffer)
 345         (error "Check-in failed"))))
 346     ;; Single-file commit?  Then update the revision by parsing the buffer.
 347     ;; Otherwise we can't necessarily tell what goes with what; clear
 348     ;; its properties so they have to be refetched.
 349     (if (= (length files) 1)
 350         (vc-file-setprop
 351          (car files) 'vc-working-revision
 352          (vc-parse-buffer "^\\(new\\|initial\\) revision: \\([0-9.]+\\)" 2))
 353       (mapc 'vc-file-clearprops files))
 354     ;; Anyway, forget the checkout model of the file, because we might have
 355     ;; guessed wrong when we found the file.  After commit, we can
 356     ;; tell it from the permissions of the file (see
 357     ;; vc-cvs-checkout-model).
 358     (mapc (lambda (file) (vc-file-setprop file 'vc-checkout-model nil))
 359           files)
 360
 361     ;; if this was an explicit check-in (does not include creation of
 362     ;; a branch), remove the sticky tag.
 363     (if (and rev (not (vc-cvs-valid-symbolic-tag-name-p rev)))
 364         (vc-cvs-command nil 0 files "update" "-A"))))
 365
 366 (defun vc-cvs-find-revision (file rev buffer)
 367   (apply 'vc-cvs-command
 368          buffer 0 file
 369          "-Q"                           ; suppress diagnostic output
 370          "update"
 371          (and rev (not (string= rev ""))
 372               (concat "-r" rev))
 373          "-p"
 374          (vc-switches 'CVS 'checkout)))
 375
 376 (defun vc-cvs-checkout (file &optional editable rev)
 377   "Checkout a revision of FILE into the working area.
 378 EDITABLE non-nil means that the file should be writable.
 379 REV is the revision to check out."
 380   (message "Checking out %s..." file)
 381   ;; Change buffers to get local value of vc-checkout-switches.
 382   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 383     (if (and (file-exists-p file) (not rev))
 384         ;; If no revision was specified, just make the file writable
 385         ;; if necessary (using `cvs-edit' if requested).
 386         (and editable (not (eq (vc-cvs-checkout-model (list file)) 'implicit))
 387              (if vc-cvs-use-edit
 388                  (vc-cvs-command nil 0 file "edit")
 389                (set-file-modes file (logior (file-modes file) 128))
 390                (if (equal file buffer-file-name) (toggle-read-only -1))))
 391       ;; Check out a particular revision (or recreate the file).
 392       (vc-file-setprop file 'vc-working-revision nil)
 393       (apply 'vc-cvs-command nil 0 file
 394              (and editable "-w")
 395              "update"
 396              (when rev
 397                (unless (eq rev t)
 398                  ;; default for verbose checkout: clear the
 399                  ;; sticky tag so that the actual update will
 400                  ;; get the head of the trunk
 401                  (if (string= rev "")
 402                      "-A"
 403                    (concat "-r" rev))))
 404              (vc-switches 'CVS 'checkout)))
 405     (vc-mode-line file 'CVS))
 406   (message "Checking out %s...done" file))
 407
 408 (defun vc-cvs-delete-file (file)
 409   (vc-cvs-command nil 0 file "remove" "-f"))
 410
 411 (defun vc-cvs-revert (file &optional contents-done)
 412   "Revert FILE to the working revision on which it was based."
 413   (vc-default-revert 'CVS file contents-done)
 414   (unless (eq (vc-cvs-checkout-model (list file)) 'implicit)
 415     (if vc-cvs-use-edit
 416         (vc-cvs-command nil 0 file "unedit")
 417       ;; Make the file read-only by switching off all w-bits
 418       (set-file-modes file (logand (file-modes file) 3950)))))
 419
 420 (defun vc-cvs-merge (file first-revision &optional second-revision)
 421   "Merge changes into current working copy of FILE.
 422 The changes are between FIRST-REVISION and SECOND-REVISION."
 423   (vc-cvs-command nil 0 file
 424                  "update" "-kk"
 425                  (concat "-j" first-revision)
 426                  (concat "-j" second-revision))
 427   (vc-file-setprop file 'vc-state 'edited)
 428   (with-current-buffer (get-buffer "*vc*")
 429     (goto-char (point-min))
 430     (if (re-search-forward "conflicts during merge" nil t)
 431         (progn
 432           (vc-file-setprop file 'vc-state 'conflict)
 433           ;; signal error
 434           1)
 435       (vc-file-setprop file 'vc-state 'edited)
 436       ;; signal success
 437       0)))
 438
 439 (defun vc-cvs-merge-news (file)
 440   "Merge in any new changes made to FILE."
 441   (message "Merging changes into %s..." file)
 442   ;; (vc-file-setprop file 'vc-working-revision nil)
 443   (vc-file-setprop file 'vc-checkout-time 0)
 444   (vc-cvs-command nil nil file "update")
 445   ;; Analyze the merge result reported by CVS, and set
 446   ;; file properties accordingly.
 447   (with-current-buffer (get-buffer "*vc*")
 448     (goto-char (point-min))
 449     ;; get new working revision
 450     (if (re-search-forward
 451          "^Merging differences between [0-9.]* and \\([0-9.]*\\) into" nil t)
 452         (vc-file-setprop file 'vc-working-revision (match-string 1))
 453       (vc-file-setprop file 'vc-working-revision nil))
 454     ;; get file status
 455     (prog1
 456         (if (eq (buffer-size) 0)
 457             0 ;; there were no news; indicate success
 458           (if (re-search-forward
 459                (concat "^\\([CMUP] \\)?"
 460                        (regexp-quote (file-name-nondirectory file))
 461                        "\\( already contains the differences between \\)?")
 462                nil t)
 463               (cond
 464                ;; Merge successful, we are in sync with repository now
 465                ((or (match-string 2)
 466                     (string= (match-string 1) "U ")
 467                     (string= (match-string 1) "P "))
 468                 (vc-file-setprop file 'vc-state 'up-to-date)
 469                 (vc-file-setprop file 'vc-checkout-time
 470                                  (nth 5 (file-attributes file)))
 471                 0);; indicate success to the caller
 472                ;; Merge successful, but our own changes are still in the file
 473                ((string= (match-string 1) "M ")
 474                 (vc-file-setprop file 'vc-state 'edited)
 475                 0);; indicate success to the caller
 476                ;; Conflicts detected!
 477                (t
 478                 (vc-file-setprop file 'vc-state 'conflict)
 479                 1);; signal the error to the caller
 480                )
 481             (pop-to-buffer "*vc*")
 482             (error "Couldn't analyze cvs update result")))
 483       (message "Merging changes into %s...done" file))))
 484
 485 (defun vc-cvs-modify-change-comment (files rev comment)
 486   "Modify the change comments for FILES on a specified REV.
 487 Will fail unless you have administrative privileges on the repo."
 488   (vc-cvs-command nil 0 files "admin" (concat "-m" rev ":" comment)))
 489
 490 ;;;
 491 ;;; History functions
 492 ;;;
 493
 494 (defun vc-cvs-print-log (files &optional buffer)
 495   "Get change logs associated with FILES."
 496   ;; It's just the catenation of the individual logs.
 497   (vc-cvs-command
 498    buffer
 499    (if (vc-stay-local-p files 'CVS) 'async 0)
 500    files "log"))
 501
 502 (defun vc-cvs-comment-history (file)
 503   "Get comment history of a file."
 504   (vc-call-backend 'RCS 'comment-history file))
 505
 506 (defun vc-cvs-diff (files &optional oldvers newvers buffer)
 507   "Get a difference report using CVS between two revisions of FILE."
 508   (let* ((async (and (not vc-disable-async-diff)
 509                      (vc-stay-local-p files 'CVS)))
 510          (invoke-cvs-diff-list nil)
 511          status)
 512     ;; Look through the file list and see if any files have backups
 513     ;; that can be used to do a plain "diff" instead of "cvs diff".
 514     (dolist (file files)
 515       (let ((ov oldvers)
 516             (nv newvers))
 517         (when (or (not ov) (string-equal ov ""))
 518           (setq ov (vc-working-revision file)))
 519         (when (string-equal nv "")
 520           (setq nv nil))
 521         (let ((file-oldvers (vc-version-backup-file file ov))
 522               (file-newvers (if (not nv)
 523                                 file
 524                               (vc-version-backup-file file nv)))
 525               (coding-system-for-read (vc-coding-system-for-diff file)))
 526           (if (and file-oldvers file-newvers)
 527               (progn
 528                 ;; This used to append diff-switches and vc-diff-switches,
 529                 ;; which was consistent with the vc-diff-switches doc at that
 530                 ;; time, but not with the actual behavior of any other VC diff.
 531                 (apply 'vc-do-command (or buffer "*vc-diff*") 1 "diff" nil
 532                        ;; Not a CVS diff, does not use vc-cvs-diff-switches.
 533                        (append (vc-switches nil 'diff)
 534                                (list (file-relative-name file-oldvers)
 535                                      (file-relative-name file-newvers))))
 536                 (setq status 0))
 537             (push file invoke-cvs-diff-list)))))
 538     (when invoke-cvs-diff-list
 539       (setq status (apply 'vc-cvs-command (or buffer "*vc-diff*")
 540                           (if async 'async 1)
 541                           invoke-cvs-diff-list "diff"
 542                           (and oldvers (concat "-r" oldvers))
 543                           (and newvers (concat "-r" newvers))
 544                           (vc-switches 'CVS 'diff))))
 545     (if async 1 status))) ; async diff, pessimistic assumption
 546
 547 (defconst vc-cvs-annotate-first-line-re "^[0-9]")
 548
 549 (defun vc-cvs-annotate-process-filter (process string)
 550   (setq string (concat (process-get process 'output) string))
 551   (if (not (string-match vc-cvs-annotate-first-line-re string))
 552       ;; Still waiting for the first real line.
 553       (process-put process 'output string)
 554     (let ((vc-filter (process-get process 'vc-filter)))
 555       (set-process-filter process vc-filter)
 556       (funcall vc-filter process (substring string (match-beginning 0))))))
 557
 558 (defun vc-cvs-annotate-command (file buffer &optional revision)
 559   "Execute \"cvs annotate\" on FILE, inserting the contents in BUFFER.
 560 Optional arg REVISION is a revision to annotate from."
 561   (vc-cvs-command buffer
 562                   (if (vc-stay-local-p file 'CVS)
 563                       'async 0)
 564                   file "annotate"
 565                   (if revision (concat "-r" revision)))
 566   ;; Strip the leading few lines.
 567   (let ((proc (get-buffer-process buffer)))
 568     (if proc
 569         ;; If running asynchronously, use a process filter.
 570         (progn
 571           (process-put proc 'vc-filter (process-filter proc))
 572           (set-process-filter proc 'vc-cvs-annotate-process-filter))
 573       (with-current-buffer buffer
 574         (goto-char (point-min))
 575         (re-search-forward vc-cvs-annotate-first-line-re)
 576         (delete-region (point-min) (1- (point)))))))
 577
 578 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 579
 580 (defun vc-cvs-annotate-current-time ()
 581   "Return the current time, based at midnight of the current day, and
 582 encoded as fractional days."
 583   (vc-annotate-convert-time
 584    (apply 'encode-time 0 0 0 (nthcdr 3 (decode-time (current-time))))))
 585
 586 (defun vc-cvs-annotate-time ()
 587   "Return the time of the next annotation (as fraction of days)
 588 systime, or nil if there is none."
 589   (let* ((bol (point))
 590          (cache (get-text-property bol 'vc-cvs-annotate-time))
 591          (inhibit-read-only t)
 592          (inhibit-modification-hooks t))
 593     (cond
 594      (cache)
 595      ((looking-at
 596        "^\\S-+\\s-+\\S-+\\s-+\\([0-9]+\\)-\\(\\sw+\\)-\\([0-9]+\\)): ")
 597       (let ((day (string-to-number (match-string 1)))
 598             (month (cdr (assq (intern (match-string 2))
 599                               '((Jan .  1) (Feb .  2) (Mar .  3)
 600                                 (Apr .  4) (May .  5) (Jun .  6)
 601                                 (Jul .  7) (Aug .  8) (Sep .  9)
 602                                 (Oct . 10) (Nov . 11) (Dec . 12)))))
 603             (year (let ((tmp (string-to-number (match-string 3))))
 604                     ;; Years 0..68 are 2000..2068.
 605                     ;; Years 69..99 are 1969..1999.
 606                     (+ (cond ((> 69 tmp) 2000)
 607                              ((> 100 tmp) 1900)
 608                              (t 0))
 609                        tmp))))
 610         (put-text-property
 611          bol (1+ bol) 'vc-cvs-annotate-time
 612          (setq cache (cons
 613                       ;; Position at end makes for nicer overlay result.
 614                       ;; Don't put actual buffer pos here, but only relative
 615                       ;; distance, so we don't ever move backward in the
 616                       ;; goto-char below, even if the text is moved.
 617                       (- (match-end 0) (match-beginning 0))
 618                       (vc-annotate-convert-time
 619                        (encode-time 0 0 0 day month year))))))))
 620     (when cache
 621       (goto-char (+ bol (car cache)))   ; Fontify from here to eol.
 622       (cdr cache))))                    ; days (float)
 623
 624 (defun vc-cvs-annotate-extract-revision-at-line ()
 625   (save-excursion
 626     (beginning-of-line)
 627     (if (re-search-forward "^\\([0-9]+\\.[0-9]+\\(\\.[0-9]+\\)*\\) +("
 628                            (line-end-position) t)
 629         (match-string-no-properties 1)
 630       nil)))
 631
 632 ;;;
 633 ;;; Tag system
 634 ;;;
 635
 636 (defun vc-cvs-create-tag (dir name branchp)
 637   "Assign to DIR's current revision a given NAME.
 638 If BRANCHP is non-nil, the name is created as a branch (and the current
 639 workspace is immediately moved to that new branch)."
 640   (vc-cvs-command nil 0 dir "tag" "-c" (if branchp "-b") name)
 641   (when branchp (vc-cvs-command nil 0 dir "update" "-r" name)))
 642
 643 (defun vc-cvs-retrieve-tag (dir name update)
 644   "Retrieve a tag at and below DIR.
 645 NAME is the name of the tag; if it is empty, do a `cvs update'.
 646 If UPDATE is non-nil, then update (resynch) any affected buffers."
 647   (with-current-buffer (get-buffer-create "*vc*")
 648     (let ((default-directory dir)
 649           (sticky-tag))
 650       (erase-buffer)
 651       (if (or (not name) (string= name ""))
 652           (vc-cvs-command t 0 nil "update")
 653         (vc-cvs-command t 0 nil "update" "-r" name)
 654         (setq sticky-tag name))
 655       (when update
 656         (goto-char (point-min))
 657         (while (not (eobp))
 658           (if (looking-at "\\([CMUP]\\) \\(.*\\)")
 659               (let* ((file (expand-file-name (match-string 2) dir))
 660                      (state (match-string 1))
 661                      (buffer (find-buffer-visiting file)))
 662                 (when buffer
 663                   (cond
 664                    ((or (string= state "U")
 665                         (string= state "P"))
 666                     (vc-file-setprop file 'vc-state 'up-to-date)
 667                     (vc-file-setprop file 'vc-working-revision nil)
 668                     (vc-file-setprop file 'vc-checkout-time
 669                                      (nth 5 (file-attributes file))))
 670                    ((or (string= state "M")
 671                         (string= state "C"))
 672                     (vc-file-setprop file 'vc-state 'edited)
 673                     (vc-file-setprop file 'vc-working-revision nil)
 674                     (vc-file-setprop file 'vc-checkout-time 0)))
 675                   (vc-file-setprop file 'vc-cvs-sticky-tag sticky-tag)
 676                   (vc-resynch-buffer file t t))))
 677           (forward-line 1))))))
 678
 679
 680 ;;;
 681 ;;; Miscellaneous
 682 ;;;
 683
 684 (defun vc-cvs-make-version-backups-p (file)
 685   "Return non-nil if version backups should be made for FILE."
 686   (vc-stay-local-p file 'CVS))
 687
 688 (defun vc-cvs-check-headers ()
 689   "Check if the current file has any headers in it."
 690   (save-excursion
 691     (goto-char (point-min))
 692     (re-search-forward "\\$[A-Za-z\300-\326\330-\366\370-\377]+\
 693 \\(: [\t -#%-\176\240-\377]*\\)?\\$" nil t)))
 694
 695
 696 ;;;
 697 ;;; Internal functions
 698 ;;;
 699
 700 (defun vc-cvs-command (buffer okstatus files &rest flags)
 701   "A wrapper around `vc-do-command' for use in vc-cvs.el.
 702 The difference to vc-do-command is that this function always invokes `cvs',
 703 and that it passes `vc-cvs-global-switches' to it before FLAGS."
 704   (apply 'vc-do-command (or buffer "*vc*") okstatus "cvs" files
 705          (if (stringp vc-cvs-global-switches)
 706              (cons vc-cvs-global-switches flags)
 707            (append vc-cvs-global-switches
 708                    flags))))
 709
 710 (defun vc-cvs-stay-local-p (file)  ;Back-compatibility.
 711   (vc-stay-local-p file 'CVS))
 712
 713 (defun vc-cvs-repository-hostname (dirname)
 714   "Hostname of the CVS server associated to workarea DIRNAME."
 715   (let ((rootname (expand-file-name "CVS/Root" dirname)))
 716     (when (file-readable-p rootname)
 717       (with-temp-buffer
 718         (let ((coding-system-for-read
 719                (or file-name-coding-system
 720                    default-file-name-coding-system)))
 721           (vc-insert-file rootname))
 722         (goto-char (point-min))
 723         (nth 2 (vc-cvs-parse-root
 724                 (buffer-substring (point)
 725                                   (line-end-position))))))))
 726
 727 (defun vc-cvs-parse-uhp (path)
 728   "parse user@host/path into (user@host /path)"
 729   (if (string-match "\\([^/]+\\)\\(/.*\\)" path)
 730       (list (match-string 1 path) (match-string 2 path))
 731       (list nil path)))
 732
 733 (defun vc-cvs-parse-root (root)
 734   "Split CVS ROOT specification string into a list of fields.
 735 A CVS root specification of the form
 736   [:METHOD:][[USER@]HOSTNAME]:?/path/to/repository
 737 is converted to a normalized record with the following structure:
 738   \(METHOD USER HOSTNAME CVS-ROOT).
 739 The default METHOD for a CVS root of the form
 740   /path/to/repository
 741 is `local'.
 742 The default METHOD for a CVS root of the form
 743   [USER@]HOSTNAME:/path/to/repository
 744 is `ext'.
 745 For an empty string, nil is returned (invalid CVS root)."
 746   ;; Split CVS root into colon separated fields (0-4).
 747   ;; The `x:' makes sure, that leading colons are not lost;
 748   ;; `HOST:/PATH' is then different from `:METHOD:/PATH'.
 749   (let* ((root-list (cdr (split-string (concat "x:" root) ":")))
 750          (len (length root-list))
 751          ;; All syntactic varieties will get a proper METHOD.
 752          (root-list
 753           (cond
 754            ((= len 0)
 755             ;; Invalid CVS root
 756             nil)
 757            ((= len 1)
 758             (let ((uhp (vc-cvs-parse-uhp (car root-list))))
 759               (cons (if (car uhp) "ext" "local") uhp)))
 760            ((= len 2)
 761             ;; [USER@]HOST:PATH => method `ext'
 762             (and (not (equal (car root-list) ""))
 763                  (cons "ext" root-list)))
 764            ((= len 3)
 765             ;; :METHOD:PATH or :METHOD:USER@HOSTNAME/PATH
 766             (cons (cadr root-list)
 767                   (vc-cvs-parse-uhp (caddr root-list))))
 768            (t
 769             ;; :METHOD:[USER@]HOST:PATH
 770             (cdr root-list)))))
 771     (if root-list
 772         (let ((method (car root-list))
 773               (uhost (or (cadr root-list) ""))
 774               (root (nth 2 root-list))
 775               user host)
 776           ;; Split USER@HOST
 777           (if (string-match "\\(.*\\)@\\(.*\\)" uhost)
 778               (setq user (match-string 1 uhost)
 779                     host (match-string 2 uhost))
 780             (setq host uhost))
 781           ;; Remove empty HOST
 782           (and (equal host "")
 783                (setq host))
 784           ;; Fix windows style CVS root `:local:C:\\project\\cvs\\some\\dir'
 785           (and host
 786                (equal method "local")
 787                (setq root (concat host ":" root) host))
 788           ;; Normalize CVS root record
 789           (list method user host root)))))
 790
 791 ;; XXX: This does not work correctly for subdirectories.  "cvs status"
 792 ;; information is context sensitive, it contains lines like:
 793 ;; cvs status: Examining DIRNAME
 794 ;; and the file entries after that don't show the full path.
 795 ;; Because of this VC directory listings only show changed files
 796 ;; at the top level for CVS.
 797 (defun vc-cvs-parse-status (&optional full)
 798   "Parse output of \"cvs status\" command in the current buffer.
 799 Set file properties accordingly.  Unless FULL is t, parse only
 800 essential information. Note that this can never set the 'ignored
 801 state."
 802   (let (file status missing)
 803     (goto-char (point-min))
 804     (while (looking-at "? \\(.*\\)")
 805       (setq file (expand-file-name (match-string 1)))
 806       (vc-file-setprop file 'vc-state 'unregistered)
 807       (forward-line 1))
 808     (when (re-search-forward "^File: " nil t)
 809       (when (setq missing (looking-at "no file "))
 810         (goto-char (match-end 0)))
 811       (cond
 812        ((re-search-forward "\\=\\([^ \t]+\\)" nil t)
 813         (setq file (expand-file-name (match-string 1)))
 814         (setq status(if (re-search-forward "\\=[ \t]+Status: \\(.*\\)" nil t)
 815                         (match-string 1) "Unknown"))
 816         (when (and full
 817                    (re-search-forward
 818                     "\\(RCS Version\\|RCS Revision\\|Repository revision\\):\
 819 \[\t ]+\\([0-9.]+\\)"
 820                     nil t))
 821             (vc-file-setprop file 'vc-latest-revision (match-string 2)))
 822         (vc-file-setprop
 823          file 'vc-state
 824          (cond
 825           ((string-match "Up-to-date" status)
 826            (vc-file-setprop file 'vc-checkout-time
 827                             (nth 5 (file-attributes file)))
 828            'up-to-date)
 829           ((string-match "Locally Modified" status)             'edited)
 830           ((string-match "Needs Merge" status)                  'needs-merge)
 831           ((string-match "Needs \\(Checkout\\|Patch\\)" status)
 832            (if missing 'missing 'needs-update))
 833           ((string-match "Locally Added" status)                'added)
 834           ((string-match "Locally Removed" status)              'removed)
 835           ((string-match "File had conflicts " status)          'conflict)
 836           ((string-match "Unknown" status)                      'unregistered)
 837           (t 'edited))))))))
 838
 839 (defun vc-cvs-after-dir-status (update-function)
 840   ;; Heavily inspired by vc-cvs-parse-status. AKA a quick hack.
 841   ;; This needs a lot of testing.
 842   (let ((status nil)
 843         (status-str nil)
 844         (file nil)
 845         (result nil)
 846         (missing nil)
 847         (ignore-next nil)
 848         (subdir default-directory))
 849     (goto-char (point-min))
 850     (while
 851         ;; Look for either a file entry, an unregistered file, or a
 852         ;; directory change.
 853         (re-search-forward
 854          "\\(^=+\n\\([^=c?\n].*\n\\|\n\\)+\\)\\|\\(\\(^?? .*\n\\)+\\)\\|\\(^cvs status: \\(Examining\\|nothing\\) .*\n\\)"
 855          nil t)
 856       ;; FIXME: get rid of narrowing here.
 857       (narrow-to-region (match-beginning 0) (match-end 0))
 858       (goto-char (point-min))
 859       ;; The subdir
 860       (when (looking-at "cvs status: Examining \\(.+\\)")
 861         (setq subdir (expand-file-name (match-string 1))))
 862       ;; Unregistered files
 863       (while (looking-at "? \\(.*\\)")
 864         (setq file (file-relative-name
 865                     (expand-file-name (match-string 1) subdir)))
 866         (push (list file 'unregistered) result)
 867         (forward-line 1))
 868       (when (looking-at "cvs status: nothing known about")
 869         ;; We asked about a non existent file.  The output looks like this:
 870
 871         ;; cvs status: nothing known about `lisp/v.diff'
 872         ;; ===================================================================
 873         ;; File: no file v.diff            Status: Unknown
 874         ;;
 875         ;;    Working revision:    No entry for v.diff
 876         ;;    Repository revision: No revision control file
 877         ;;
 878
 879         ;; Due to narrowing in this iteration we only see the "cvs
 880         ;; status:" line, so just set a flag so that we can ignore the
 881         ;; file in the next iteration.
 882         (setq ignore-next t))
 883       ;; A file entry.
 884       (when (re-search-forward "^File: \\(no file \\)?\\(.*[^ \t]\\)[ \t]+Status: \\(.*\\)" nil t)
 885         (setq missing (match-string 1))
 886         (setq file (file-relative-name
 887                     (expand-file-name (match-string 2) subdir)))
 888         (setq status-str (match-string 3))
 889         (setq status
 890               (cond
 891                ((string-match "Up-to-date" status-str) 'up-to-date)
 892                ((string-match "Locally Modified" status-str) 'edited)
 893                ((string-match "Needs Merge" status-str) 'needs-merge)
 894                ((string-match "Needs \\(Checkout\\|Patch\\)" status-str)
 895                 (if missing 'missing 'needs-update))
 896                ((string-match "Locally Added" status-str) 'added)
 897                ((string-match "Locally Removed" status-str) 'removed)
 898                ((string-match "File had conflicts " status-str) 'conflict)
 899                ((string-match "Unknown" status-str) 'unregistered)
 900                (t 'edited)))
 901         (if ignore-next
 902             (setq ignore-next nil)
 903           (unless (eq status 'up-to-date)
 904             (push (list file status) result))))
 905       (goto-char (point-max))
 906       (widen))
 907     (funcall update-function result))
 908   ;; Alternative implementation: use the "update" command instead of
 909   ;; the "status" command.
 910   ;; (let ((result nil)
 911   ;;    (translation '((?? . unregistered)
 912   ;;                   (?A . added)
 913   ;;                   (?C . conflict)
 914   ;;                   (?M . edited)
 915   ;;                   (?P . needs-merge)
 916   ;;                   (?R . removed)
 917   ;;                   (?U . needs-update))))
 918   ;;   (goto-char (point-min))
 919   ;;   (while (not (eobp))
 920   ;;     (if (looking-at "^[ACMPRU?] \\(.*\\)$")
 921   ;;      (push (list (match-string 1)
 922   ;;                  (cdr (assoc (char-after) translation)))
 923   ;;            result)
 924   ;;    (cond
 925   ;;     ((looking-at "cvs update: warning: \\(.*\\) was lost")
 926   ;;      ;; Format is:
 927   ;;      ;; cvs update: warning: FILENAME was lost
 928   ;;      ;; U FILENAME
 929   ;;      (push (list (match-string 1) 'missing) result)
 930   ;;      ;; Skip the "U" line
 931   ;;      (forward-line 1))
 932   ;;     ((looking-at "cvs update: New directory `\\(.*\\)' -- ignored")
 933   ;;      (push (list (match-string 1) 'unregistered) result))))
 934   ;;     (forward-line 1))
 935   ;;   (funcall update-function result)))
 936   )
 937
 938 ;; Based on vc-cvs-dir-state-heuristic from Emacs 22.
 939 (defun vc-cvs-dir-status-heuristic (dir update-function &optional basedir)
 940   "Find the CVS state of all files in DIR, using only local information."
 941   (let (file basename status result dirlist)
 942     (with-temp-buffer
 943       (vc-cvs-get-entries dir)
 944       (goto-char (point-min))
 945       (while (not (eobp))
 946         (if (looking-at "D/\\([^/]*\\)////")
 947             (push (expand-file-name (match-string 1) dir) dirlist)
 948           ;; CVS-removed files are not taken under VC control.
 949           (when (looking-at "/\\([^/]*\\)/[^/-]")
 950             (setq basename (match-string 1)
 951                   file (expand-file-name basename dir)
 952                   status (or (vc-file-getprop file 'vc-state)
 953                              (vc-cvs-parse-entry file t)))
 954             (unless (eq status 'up-to-date)
 955               (push (list (if basedir
 956                               (file-relative-name file basedir)
 957                             basename)
 958                           status) result))))
 959         (forward-line 1)))
 960     (dolist (subdir dirlist)
 961       (setq result (append result
 962                            (vc-cvs-dir-status-heuristic subdir nil
 963                                                         (or basedir dir)))))
 964     (if basedir result
 965       (funcall update-function result))))
 966
 967 (defun vc-cvs-dir-status (dir update-function)
 968   "Create a list of conses (file . state) for DIR."
 969   ;; FIXME check all files in DIR instead?
 970   (let ((local (vc-stay-local-p dir 'CVS)))
 971     (if (and local (not (eq local 'only-file)))
 972         (vc-cvs-dir-status-heuristic dir update-function)
 973       (vc-cvs-command (current-buffer) 'async dir "-f" "status")
 974       ;; Alternative implementation: use the "update" command instead of
 975       ;; the "status" command.
 976       ;; (vc-cvs-command (current-buffer) 'async
 977       ;;                  (file-relative-name dir)
 978       ;;                  "-f" "-n" "update" "-d" "-P")
 979       (vc-exec-after
 980        `(vc-cvs-after-dir-status (quote ,update-function))))))
 981
 982 (defun vc-cvs-dir-status-files (dir files default-state update-function)
 983   "Create a list of conses (file . state) for DIR."
 984   (apply 'vc-cvs-command (current-buffer) 'async dir "-f" "status" files)
 985   (vc-exec-after
 986    `(vc-cvs-after-dir-status (quote ,update-function))))
 987
 988 (defun vc-cvs-file-to-string (file)
 989   "Read the content of FILE and return it as a string."
 990   (condition-case nil
 991       (with-temp-buffer
 992         (insert-file-contents file)
 993         (goto-char (point-min))
 994         (buffer-substring (point) (point-max)))
 995     (file-error nil)))
 996
 997 (defun vc-cvs-dir-extra-headers (dir)
 998   "Extract and represent per-directory properties of a CVS working copy."
 999   (let ((repo
1000          (condition-case nil
1001              (with-temp-buffer
1002                (insert-file-contents "CVS/Root")
1003                (goto-char (point-min))
1004                (and (looking-at ":ext:") (delete-char 5))
1005                (concat (buffer-substring (point) (1- (point-max))) "\n"))
1006            (file-error nil)))
1007         (module
1008          (condition-case nil
1009              (with-temp-buffer
1010                (insert-file-contents "CVS/Repository")
1011                (goto-char (point-min))
1012                (skip-chars-forward "^\n")
1013                (concat (buffer-substring (point-min) (point)) "\n"))
1014            (file-error nil))))
1015     (concat
1016      (cond (repo
1017             (concat (propertize "Repository : " 'face 'font-lock-type-face)
1018                     (propertize repo 'face 'font-lock-variable-name-face)))
1019            (t ""))
1020      (cond (module
1021             (concat (propertize "Module     : " 'face 'font-lock-type-face)
1022                     (propertize module 'face 'font-lock-variable-name-face)))
1023            (t ""))
1024      (if (file-readable-p "CVS/Tag")
1025          (let ((tag (vc-cvs-file-to-string "CVS/Tag")))
1026            (cond
1027             ((string-match "\\`T" tag)
1028              (concat (propertize "Tag        : " 'face 'font-lock-type-face)
1029                      (propertize (substring tag 1)
1030                                  'face 'font-lock-variable-name-face)))
1031             ((string-match "\\`D" tag)
1032              (concat (propertize "Date       : " 'face 'font-lock-type-face)
1033                      (propertize (substring tag 1)
1034                                  'face 'font-lock-variable-name-face)))
1035             (t ""))))
1036
1037      ;; In CVS, branch is a per-file property, not a per-directory property.
1038      ;; We can't really do this here without making dangerous assumptions.
1039      ;;(propertize "Branch:     " 'face 'font-lock-type-face)
1040      ;;(propertize "ADD CODE TO PRINT THE BRANCH NAME\n"
1041      ;;  'face 'font-lock-warning-face)
1042      )))
1043
1044 (defun vc-cvs-get-entries (dir)
1045   "Insert the CVS/Entries file from below DIR into the current buffer.
1046 This function ensures that the correct coding system is used for that,
1047 which may not be the one that is used for the files' contents.
1048 CVS/Entries should only be accessed through this function."
1049   (let ((coding-system-for-read (or file-name-coding-system
1050                                     default-file-name-coding-system)))
1051     (vc-insert-file (expand-file-name "CVS/Entries" dir))))
1052
1053 (defun vc-cvs-valid-symbolic-tag-name-p (tag)
1054   "Return non-nil if TAG is a valid symbolic tag name."
1055   ;; According to the CVS manual, a valid symbolic tag must start with
1056   ;; an uppercase or lowercase letter and can contain uppercase and
1057   ;; lowercase letters, digits, `-', and `_'.
1058   (and (string-match "^[a-zA-Z]" tag)
1059        (not (string-match "[^a-z0-9A-Z-_]" tag))))
1060
1061 (defun vc-cvs-valid-revision-number-p (tag)
1062   "Return non-nil if TAG is a valid revision number."
1063   (and (string-match "^[0-9]" tag)
1064        (not (string-match "[^0-9.]" tag))))
1065
1066 (defun vc-cvs-parse-sticky-tag (match-type match-tag)
1067   "Parse and return the sticky tag as a string.
1068 `match-data' is protected."
1069   (let ((data (match-data))
1070         (tag)
1071         (type (cond ((string= match-type "D") 'date)
1072                     ((string= match-type "T")
1073                      (if (vc-cvs-valid-symbolic-tag-name-p match-tag)
1074                          'symbolic-name
1075                        'revision-number))
1076                     (t nil))))
1077     (unwind-protect
1078         (progn
1079           (cond
1080            ;; Sticky Date tag.  Convert to a proper date value (`encode-time')
1081            ((eq type 'date)
1082             (string-match
1083              "\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)"
1084              match-tag)
1085             (let* ((year-tmp (string-to-number (match-string 1 match-tag)))
1086                    (month    (string-to-number (match-string 2 match-tag)))
1087                    (day      (string-to-number (match-string 3 match-tag)))
1088                    (hour     (string-to-number (match-string 4 match-tag)))
1089                    (min      (string-to-number (match-string 5 match-tag)))
1090                    (sec      (string-to-number (match-string 6 match-tag)))
1091                    ;; Years 0..68 are 2000..2068.
1092                    ;; Years 69..99 are 1969..1999.
1093                    (year (+ (cond ((> 69 year-tmp) 2000)
1094                                   ((> 100 year-tmp) 1900)
1095                                   (t 0))
1096                             year-tmp)))
1097               (setq tag (encode-time sec min hour day month year))))
1098            ;; Sticky Tag name or revision number
1099            ((eq type 'symbolic-name) (setq tag match-tag))
1100            ((eq type 'revision-number) (setq tag match-tag))
1101            ;; Default is no sticky tag at all
1102            (t nil))
1103           (cond ((eq vc-cvs-sticky-tag-display nil) nil)
1104                 ((eq vc-cvs-sticky-tag-display t)
1105                  (cond ((eq type 'date) (format-time-string
1106                                          vc-cvs-sticky-date-format-string
1107                                          tag))
1108                        ((eq type 'symbolic-name) tag)
1109                        ((eq type 'revision-number) tag)
1110                        (t nil)))
1111                 ((functionp vc-cvs-sticky-tag-display)
1112                  (funcall vc-cvs-sticky-tag-display tag type))
1113                 (t nil)))
1114
1115       (set-match-data data))))
1116
1117 (defun vc-cvs-parse-entry (file &optional set-state)
1118   "Parse a line from CVS/Entries.
1119 Compare modification time to that of the FILE, set file properties
1120 accordingly.  However, `vc-state' is set only if optional arg SET-STATE
1121 is non-nil."
1122   (cond
1123    ;; entry for a "locally added" file (not yet committed)
1124    ((looking-at "/[^/]+/0/")
1125     (vc-file-setprop file 'vc-checkout-time 0)
1126     (vc-file-setprop file 'vc-working-revision "0")
1127     (if set-state (vc-file-setprop file 'vc-state 'added)))
1128    ;; normal entry
1129    ((looking-at
1130      (concat "/[^/]+"
1131              ;; revision
1132              "/\\([^/]*\\)"
1133              ;; timestamp and optional conflict field
1134              "/\\([^/]*\\)/"
1135              ;; options
1136              "\\([^/]*\\)/"
1137              ;; sticky tag
1138              "\\(.\\|\\)" ;Sticky tag type (date or tag name, could be empty)
1139              "\\(.*\\)"))               ;Sticky tag
1140     (vc-file-setprop file 'vc-working-revision (match-string 1))
1141     (vc-file-setprop file 'vc-cvs-sticky-tag
1142                      (vc-cvs-parse-sticky-tag (match-string 4)
1143                                               (match-string 5)))
1144     ;; Compare checkout time and modification time.
1145     ;; This is intentionally different from the algorithm that CVS uses
1146     ;; (which is based on textual comparison), because there can be problems
1147     ;; generating a time string that looks exactly like the one from CVS.
1148     (let ((mtime (nth 5 (file-attributes file))))
1149       (require 'parse-time)
1150       (let ((parsed-time
1151              (parse-time-string (concat (match-string 2) " +0000"))))
1152         (cond ((and (not (string-match "\\+" (match-string 2)))
1153                     (car parsed-time)
1154                     (equal mtime (apply 'encode-time parsed-time)))
1155                (vc-file-setprop file 'vc-checkout-time mtime)
1156                (if set-state (vc-file-setprop file 'vc-state 'up-to-date)))
1157               (t
1158                (vc-file-setprop file 'vc-checkout-time 0)
1159                (if set-state (vc-file-setprop file 'vc-state 'edited)))))))))
1160
1161 ;; Completion of revision names.
1162 ;; Just so I don't feel like I'm duplicating code from pcl-cvs, I'll use
1163 ;; `cvs log' so I can list all the revision numbers rather than only
1164 ;; tag names.
1165
1166 (defun vc-cvs-revision-table (file)
1167   (let ((default-directory (file-name-directory file))
1168         (res nil))
1169     (with-temp-buffer
1170       (vc-cvs-command t nil file "log")
1171       (goto-char (point-min))
1172       (when (re-search-forward "^symbolic names:\n" nil t)
1173         (while (looking-at "^   \\(.*\\): \\(.*\\)")
1174           (push (cons (match-string 1) (match-string 2)) res)
1175           (forward-line 1)))
1176       (while (re-search-forward "^revision \\([0-9.]+\\)" nil t)
1177         (push (match-string 1) res))
1178       res)))
1179
1180 (defun vc-cvs-revision-completion-table (files)
1181   (lexical-let ((files files)
1182                 table)
1183     (setq table (lazy-completion-table
1184                  table (lambda () (vc-cvs-revision-table (car files)))))
1185     table))
1186
1187
1188 (provide 'vc-cvs)
1189
1190 ;; arch-tag: 60e1402a-aa53-4607-927a-cf74f144b432
1191 ;;; vc-cvs.el ends here