lisp/help-mode.el

   1 ;;; help-mode.el --- `help-mode' used by *Help* buffers
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2012
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Defines `help-mode', which is the mode used by *Help* buffers, and
  28 ;; associated support machinery, such as adding hyperlinks, etc.,
  29
  30 ;;; Code:
  31
  32 (require 'button)
  33 (eval-when-compile (require 'easymenu))
  34
  35 (defvar help-mode-map
  36   (let ((map (make-sparse-keymap)))
  37     (set-keymap-parent map (make-composed-keymap button-buffer-map
  38                                                  special-mode-map))
  39     (define-key map [mouse-2] 'help-follow-mouse)
  40     (define-key map "\C-c\C-b" 'help-go-back)
  41     (define-key map "\C-c\C-f" 'help-go-forward)
  42     (define-key map [XF86Back] 'help-go-back)
  43     (define-key map [XF86Forward] 'help-go-forward)
  44     (define-key map "\C-c\C-c" 'help-follow-symbol)
  45     (define-key map "\r" 'help-follow)
  46     map)
  47   "Keymap for help mode.")
  48
  49 (easy-menu-define help-mode-menu help-mode-map
  50   "Menu for Help Mode."
  51   '("Help-Mode"
  52     ["Show Help for Symbol" help-follow-symbol
  53      :help "Show the docs for the symbol at point"]
  54     ["Previous Topic" help-go-back
  55      :help "Go back to previous topic in this help buffer"]
  56     ["Next Topic" help-go-forward
  57      :help "Go back to next topic in this help buffer"]
  58     ["Move to Previous Button" backward-button
  59      :help "Move to the Next Button in the help buffer"]
  60     ["Move to Next Button" forward-button
  61       :help "Move to the Next Button in the help buffer"]))
  62
  63 (defvar help-xref-stack nil
  64   "A stack of ways by which to return to help buffers after following xrefs.
  65 Used by `help-follow' and `help-xref-go-back'.
  66 An element looks like (POSITION FUNCTION ARGS...).
  67 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  68 (put 'help-xref-stack 'permanent-local t)
  69 (make-variable-buffer-local 'help-xref-stack)
  70
  71 (defvar help-xref-forward-stack nil
  72   "A stack used to navigate help forwards after using the back button.
  73 Used by `help-follow' and `help-xref-go-forward'.
  74 An element looks like (POSITION FUNCTION ARGS...).
  75 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  76 (put 'help-xref-forward-stack 'permanent-local t)
  77 (make-variable-buffer-local 'help-xref-forward-stack)
  78
  79 (defvar help-xref-stack-item nil
  80   "An item for `help-follow' in this buffer to push onto `help-xref-stack'.
  81 The format is (FUNCTION ARGS...).")
  82 (put 'help-xref-stack-item 'permanent-local t)
  83 (make-variable-buffer-local 'help-xref-stack-item)
  84
  85 (defvar help-xref-stack-forward-item nil
  86   "An item for `help-go-back' to push onto `help-xref-forward-stack'.
  87 The format is (FUNCTION ARGS...).")
  88 (put 'help-xref-stack-forward-item 'permanent-local t)
  89 (make-variable-buffer-local 'help-xref-stack-forward-item)
  90
  91 (setq-default help-xref-stack nil help-xref-stack-item nil)
  92 (setq-default help-xref-forward-stack nil help-xref-forward-stack-item nil)
  93
  94 (defcustom help-mode-hook nil
  95   "Hook run by `help-mode'."
  96   :type 'hook
  97   :group 'help)
  98 \f
  99 ;; Button types used by help
 100
 101 (define-button-type 'help-xref
 102   'follow-link t
 103   'action #'help-button-action)
 104
 105 (defun help-button-action (button)
 106   "Call BUTTON's help function."
 107   (help-do-xref (button-start button)
 108                 (button-get button 'help-function)
 109                 (button-get button 'help-args)))
 110
 111 ;; These 6 calls to define-button-type were generated in a dolist
 112 ;; loop, but that is bad because it means these button types don't
 113 ;; have an easily found definition.
 114
 115 (define-button-type 'help-function
 116   :supertype 'help-xref
 117   'help-function 'describe-function
 118   'help-echo (purecopy "mouse-2, RET: describe this function"))
 119
 120 (define-button-type 'help-variable
 121   :supertype 'help-xref
 122   'help-function 'describe-variable
 123   'help-echo (purecopy "mouse-2, RET: describe this variable"))
 124
 125 (define-button-type 'help-face
 126   :supertype 'help-xref
 127   'help-function 'describe-face
 128   'help-echo (purecopy "mouse-2, RET: describe this face"))
 129
 130 (define-button-type 'help-coding-system
 131   :supertype 'help-xref
 132   'help-function 'describe-coding-system
 133   'help-echo (purecopy "mouse-2, RET: describe this coding system"))
 134
 135 (define-button-type 'help-input-method
 136   :supertype 'help-xref
 137   'help-function 'describe-input-method
 138   'help-echo (purecopy "mouse-2, RET: describe this input method"))
 139
 140 (define-button-type 'help-character-set
 141   :supertype 'help-xref
 142   'help-function 'describe-character-set
 143   'help-echo (purecopy "mouse-2, RET: describe this character set"))
 144
 145 ;; Make some more idiosyncratic button types.
 146
 147 (define-button-type 'help-symbol
 148   :supertype 'help-xref
 149   'help-function #'help-xref-interned
 150   'help-echo (purecopy "mouse-2, RET: describe this symbol"))
 151
 152 (define-button-type 'help-back
 153   :supertype 'help-xref
 154   'help-function #'help-xref-go-back
 155   'help-echo (purecopy "mouse-2, RET: go back to previous help buffer"))
 156
 157 (define-button-type 'help-forward
 158   :supertype 'help-xref
 159   'help-function #'help-xref-go-forward
 160   'help-echo (purecopy "mouse-2, RET: move forward to next help buffer"))
 161
 162 (define-button-type 'help-info-variable
 163   :supertype 'help-xref
 164   ;; the name of the variable is put before the argument to Info
 165   'help-function (lambda (_a v) (info v))
 166   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 167
 168 (define-button-type 'help-info
 169   :supertype 'help-xref
 170   'help-function #'info
 171   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 172
 173 (define-button-type 'help-url
 174   :supertype 'help-xref
 175   'help-function #'browse-url
 176   'help-echo (purecopy "mouse-2, RET: view this URL in a browser"))
 177
 178 (define-button-type 'help-customize-variable
 179   :supertype 'help-xref
 180   'help-function (lambda (v)
 181                    (customize-variable v))
 182   'help-echo (purecopy "mouse-2, RET: customize variable"))
 183
 184 (define-button-type 'help-customize-face
 185   :supertype 'help-xref
 186   'help-function (lambda (v)
 187                    (customize-face v))
 188   'help-echo (purecopy "mouse-2, RET: customize face"))
 189
 190 (define-button-type 'help-function-def
 191   :supertype 'help-xref
 192   'help-function (lambda (fun file)
 193                    (require 'find-func)
 194                    (when (eq file 'C-source)
 195                      (setq file
 196                            (help-C-file-name (indirect-function fun) 'fun)))
 197                    ;; Don't use find-function-noselect because it follows
 198                    ;; aliases (which fails for built-in functions).
 199                    (let ((location
 200                           (find-function-search-for-symbol fun nil file)))
 201                      (pop-to-buffer (car location))
 202                      (if (cdr location)
 203                          (goto-char (cdr location))
 204                        (message "Unable to find location in file"))))
 205   'help-echo (purecopy "mouse-2, RET: find function's definition"))
 206
 207 (define-button-type 'help-function-cmacro
 208   :supertype 'help-xref
 209   'help-function (lambda (fun file)
 210                    (setq file (locate-library file t))
 211                    (if (and file (file-readable-p file))
 212                        (progn
 213                          (pop-to-buffer (find-file-noselect file))
 214                          (goto-char (point-min))
 215                          (if (re-search-forward
 216                               (format "^[ \t]*(define-compiler-macro[ \t]+%s"
 217                                       (regexp-quote (symbol-name fun))) nil t)
 218                              (forward-line 0)
 219                            (message "Unable to find location in file")))
 220                      (message "Unable to find file")))
 221   'help-echo (purecopy "mouse-2, RET: find function's compiler macro"))
 222
 223 (define-button-type 'help-variable-def
 224   :supertype 'help-xref
 225   'help-function (lambda (var &optional file)
 226                    (when (eq file 'C-source)
 227                      (setq file (help-C-file-name var 'var)))
 228                    (let ((location (find-variable-noselect var file)))
 229                      (pop-to-buffer (car location))
 230                      (if (cdr location)
 231                        (goto-char (cdr location))
 232                        (message "Unable to find location in file"))))
 233   'help-echo (purecopy "mouse-2, RET: find variable's definition"))
 234
 235 (define-button-type 'help-face-def
 236   :supertype 'help-xref
 237   'help-function (lambda (fun file)
 238                    (require 'find-func)
 239                    ;; Don't use find-function-noselect because it follows
 240                    ;; aliases (which fails for built-in functions).
 241                    (let ((location
 242                           (find-function-search-for-symbol fun 'defface file)))
 243                      (pop-to-buffer (car location))
 244                      (if (cdr location)
 245                          (goto-char (cdr location))
 246                        (message "Unable to find location in file"))))
 247   'help-echo (purecopy "mouse-2, RET: find face's definition"))
 248
 249 (define-button-type 'help-package
 250   :supertype 'help-xref
 251   'help-function 'describe-package
 252   'help-echo (purecopy "mouse-2, RET: Describe package"))
 253
 254 (define-button-type 'help-package-def
 255   :supertype 'help-xref
 256   'help-function (lambda (file) (dired file))
 257   'help-echo (purecopy "mouse-2, RET: visit package directory"))
 258
 259 (define-button-type 'help-theme-def
 260   :supertype 'help-xref
 261   'help-function 'find-file
 262   'help-echo (purecopy "mouse-2, RET: visit theme file"))
 263
 264 (define-button-type 'help-theme-edit
 265   :supertype 'help-xref
 266   'help-function 'customize-create-theme
 267   'help-echo (purecopy "mouse-2, RET: edit this theme file"))
 268
 269 (define-button-type 'help-dir-local-var-def
 270   :supertype 'help-xref
 271   'help-function (lambda (var &optional file)
 272                    ;; FIXME: this should go to the point where the
 273                    ;; local variable was defined.
 274                    (find-file file))
 275   'help-echo (purecopy "mouse-2, RET: open directory-local variables file"))
 276
 277 \f
 278 (defvar bookmark-make-record-function)
 279
 280 ;;;###autoload
 281 (define-derived-mode help-mode special-mode "Help"
 282   "Major mode for viewing help text and navigating references in it.
 283 Entry to this mode runs the normal hook `help-mode-hook'.
 284 Commands:
 285 \\{help-mode-map}"
 286   (set (make-local-variable 'revert-buffer-function)
 287        'help-mode-revert-buffer)
 288   (set (make-local-variable 'bookmark-make-record-function)
 289        'help-bookmark-make-record))
 290
 291 ;;;###autoload
 292 (defun help-mode-setup ()
 293   (help-mode)
 294   (setq buffer-read-only nil))
 295
 296 ;;;###autoload
 297 (defun help-mode-finish ()
 298   (when (eq major-mode 'help-mode)
 299     (setq buffer-read-only t)
 300     (save-excursion
 301       (goto-char (point-min))
 302       (let ((inhibit-read-only t))
 303         (when (re-search-forward "^This [^[:space:]]+ is advised.$" nil t)
 304           (put-text-property (match-beginning 0)
 305                              (match-end 0)
 306                              'face 'font-lock-warning-face))))
 307
 308     (help-make-xrefs (current-buffer))))
 309 \f
 310 ;; Grokking cross-reference information in doc strings and
 311 ;; hyperlinking it.
 312
 313 ;; This may have some scope for extension and the same or something
 314 ;; similar should be done for widget doc strings, which currently use
 315 ;; another mechanism.
 316
 317 (defvar help-back-label (purecopy "[back]")
 318   "Label to use by `help-make-xrefs' for the go-back reference.")
 319
 320 (defvar help-forward-label (purecopy "[forward]")
 321   "Label to use by `help-make-xrefs' for the go-forward reference.")
 322
 323 (defconst help-xref-symbol-regexp
 324   (purecopy (concat "\\(\\<\\(\\(variable\\|option\\)\\|"  ; Link to var
 325                     "\\(function\\|command\\)\\|"          ; Link to function
 326                     "\\(face\\)\\|"                        ; Link to face
 327                     "\\(symbol\\|program\\|property\\)\\|" ; Don't link
 328                     "\\(source \\(?:code \\)?\\(?:of\\|for\\)\\)\\)"
 329                     "[ \t\n]+\\)?"
 330                     ;; Note starting with word-syntax character:
 331                     "`\\(\\sw\\(\\sw\\|\\s_\\)+\\)'"))
 332   "Regexp matching doc string references to symbols.
 333
 334 The words preceding the quoted symbol can be used in doc strings to
 335 distinguish references to variables, functions and symbols.")
 336
 337 (defvar help-xref-mule-regexp nil
 338   "Regexp matching doc string references to MULE-related keywords.
 339
 340 It is usually nil, and is temporarily bound to an appropriate regexp
 341 when help commands related to multilingual environment (e.g.,
 342 `describe-coding-system') are invoked.")
 343
 344
 345 (defconst help-xref-info-regexp
 346   (purecopy "\\<[Ii]nfo[ \t\n]+\\(node\\|anchor\\)[ \t\n]+`\\([^']+\\)'")
 347   "Regexp matching doc string references to an Info node.")
 348
 349 (defconst help-xref-url-regexp
 350   (purecopy "\\<[Uu][Rr][Ll][ \t\n]+`\\([^']+\\)'")
 351   "Regexp matching doc string references to a URL.")
 352
 353 ;;;###autoload
 354 (defun help-setup-xref (item interactive-p)
 355   "Invoked from commands using the \"*Help*\" buffer to install some xref info.
 356
 357 ITEM is a (FUNCTION . ARGS) pair appropriate for recreating the help
 358 buffer after following a reference.  INTERACTIVE-P is non-nil if the
 359 calling command was invoked interactively.  In this case the stack of
 360 items for help buffer \"back\" buttons is cleared.
 361
 362 This should be called very early, before the output buffer is cleared,
 363 because we want to record the \"previous\" position of point so we can
 364 restore it properly when going back."
 365   (with-current-buffer (help-buffer)
 366     (when help-xref-stack-item
 367       (push (cons (point) help-xref-stack-item) help-xref-stack)
 368       (setq help-xref-forward-stack nil))
 369     (when interactive-p
 370       (let ((tail (nthcdr 10 help-xref-stack)))
 371         ;; Truncate the stack.
 372         (if tail (setcdr tail nil))))
 373     (setq help-xref-stack-item item)))
 374
 375 (defvar help-xref-following nil
 376   "Non-nil when following a help cross-reference.")
 377
 378 ;;;###autoload
 379 (defun help-buffer ()
 380   "Return the name of a buffer for inserting help.
 381 If `help-xref-following' is non-nil, this is the name of the
 382 current buffer.  Signal an error if this buffer is not derived
 383 from `help-mode'.
 384 Otherwise, return \"*Help*\", creating a buffer with that name if
 385 it does not already exist."
 386   (buffer-name                          ;for with-output-to-temp-buffer
 387    (if (not help-xref-following)
 388        (get-buffer-create "*Help*")
 389      (unless (derived-mode-p 'help-mode)
 390        (error "Current buffer is not in Help mode"))
 391      (current-buffer))))
 392
 393 ;;;###autoload
 394 (defun help-make-xrefs (&optional buffer)
 395   "Parse and hyperlink documentation cross-references in the given BUFFER.
 396
 397 Find cross-reference information in a buffer and activate such cross
 398 references for selection with `help-follow'.  Cross-references have
 399 the canonical form `...'  and the type of reference may be
 400 disambiguated by the preceding word(s) used in
 401 `help-xref-symbol-regexp'.  Faces only get cross-referenced if
 402 preceded or followed by the word `face'.  Variables without
 403 variable documentation do not get cross-referenced, unless
 404 preceded by the word `variable' or `option'.
 405
 406 If the variable `help-xref-mule-regexp' is non-nil, find also
 407 cross-reference information related to multilingual environment
 408 \(e.g., coding-systems).  This variable is also used to disambiguate
 409 the type of reference as the same way as `help-xref-symbol-regexp'.
 410
 411 A special reference `back' is made to return back through a stack of
 412 help buffers.  Variable `help-back-label' specifies the text for
 413 that."
 414   (interactive "b")
 415   (with-current-buffer (or buffer (current-buffer))
 416     (save-excursion
 417       (goto-char (point-min))
 418       ;; Skip the header-type info, though it might be useful to parse
 419       ;; it at some stage (e.g. "function in `library'").
 420       (forward-paragraph)
 421       (let ((old-modified (buffer-modified-p)))
 422         (let ((stab (syntax-table))
 423               (case-fold-search t)
 424               (inhibit-read-only t))
 425           (set-syntax-table emacs-lisp-mode-syntax-table)
 426           ;; The following should probably be abstracted out.
 427           (unwind-protect
 428               (progn
 429                 ;; Info references
 430                 (save-excursion
 431                   (while (re-search-forward help-xref-info-regexp nil t)
 432                     (let ((data (match-string 2)))
 433                       (save-match-data
 434                         (unless (string-match "^([^)]+)" data)
 435                           (setq data (concat "(emacs)" data)))
 436                         (setq data ;; possible newlines if para filled
 437                               (replace-regexp-in-string "[ \t\n]+" " " data t t)))
 438                       (help-xref-button 2 'help-info data))))
 439                 ;; URLs
 440                 (save-excursion
 441                   (while (re-search-forward help-xref-url-regexp nil t)
 442                     (let ((data (match-string 1)))
 443                       (help-xref-button 1 'help-url data))))
 444                 ;; Mule related keywords.  Do this before trying
 445                 ;; `help-xref-symbol-regexp' because some of Mule
 446                 ;; keywords have variable or function definitions.
 447                 (if help-xref-mule-regexp
 448                     (save-excursion
 449                       (while (re-search-forward help-xref-mule-regexp nil t)
 450                         (let* ((data (match-string 7))
 451                                (sym (intern-soft data)))
 452                           (cond
 453                            ((match-string 3) ; coding system
 454                             (and sym (coding-system-p sym)
 455                                  (help-xref-button 6 'help-coding-system sym)))
 456                            ((match-string 4) ; input method
 457                             (and (assoc data input-method-alist)
 458                                  (help-xref-button 7 'help-input-method data)))
 459                            ((or (match-string 5) (match-string 6)) ; charset
 460                             (and sym (charsetp sym)
 461                                  (help-xref-button 7 'help-character-set sym)))
 462                            ((assoc data input-method-alist)
 463                             (help-xref-button 7 'help-character-set data))
 464                            ((and sym (coding-system-p sym))
 465                             (help-xref-button 7 'help-coding-system sym))
 466                            ((and sym (charsetp sym))
 467                             (help-xref-button 7 'help-character-set sym)))))))
 468                 ;; Quoted symbols
 469                 (save-excursion
 470                   (while (re-search-forward help-xref-symbol-regexp nil t)
 471                     (let* ((data (match-string 8))
 472                            (sym (intern-soft data)))
 473                       (if sym
 474                           (cond
 475                            ((match-string 3) ; `variable' &c
 476                             (and (or (boundp sym) ; `variable' doesn't ensure
 477                                         ; it's actually bound
 478                                      (get sym 'variable-documentation))
 479                                  (help-xref-button 8 'help-variable sym)))
 480                            ((match-string 4) ; `function' &c
 481                             (and (fboundp sym) ; similarly
 482                                  (help-xref-button 8 'help-function sym)))
 483                            ((match-string 5) ; `face'
 484                             (and (facep sym)
 485                                  (help-xref-button 8 'help-face sym)))
 486                            ((match-string 6)) ; nothing for `symbol'
 487                            ((match-string 7)
 488                             ;; this used:
 489                             ;; #'(lambda (arg)
 490                             ;;     (let ((location
 491                             ;;            (find-function-noselect arg)))
 492                             ;;       (pop-to-buffer (car location))
 493                             ;;  (goto-char (cdr location))))
 494                             (help-xref-button 8 'help-function-def sym))
 495                            ((and
 496                              (facep sym)
 497                              (save-match-data (looking-at "[ \t\n]+face\\W")))
 498                             (help-xref-button 8 'help-face sym))
 499                            ((and (or (boundp sym)
 500                                      (get sym 'variable-documentation))
 501                                  (fboundp sym))
 502                             ;; We can't intuit whether to use the
 503                             ;; variable or function doc -- supply both.
 504                             (help-xref-button 8 'help-symbol sym))
 505                            ((and
 506                              (or (boundp sym)
 507                                  (get sym 'variable-documentation))
 508                              (condition-case err
 509                                  (or
 510                                   (documentation-property
 511                                    sym 'variable-documentation)
 512                                   (documentation-property
 513                                    (indirect-variable sym)
 514                                    'variable-documentation))
 515                                (error (message "No doc found: %S" err) nil)))
 516                             (help-xref-button 8 'help-variable sym))
 517                            ((fboundp sym)
 518                             (help-xref-button 8 'help-function sym)))))))
 519                 ;; An obvious case of a key substitution:
 520                 (save-excursion
 521                   (while (re-search-forward
 522                           ;; Assume command name is only word and symbol
 523                           ;; characters to get things like `use M-x foo->bar'.
 524                           ;; Command required to end with word constituent
 525                           ;; to avoid `.' at end of a sentence.
 526                           "\\<M-x\\s-+\\(\\sw\\(\\sw\\|\\s_\\)*\\sw\\)" nil t)
 527                     (let ((sym (intern-soft (match-string 1))))
 528                       (if (fboundp sym)
 529                           (help-xref-button 1 'help-function sym)))))
 530                 ;; Look for commands in whole keymap substitutions:
 531                 (save-excursion
 532                   ;; Make sure to find the first keymap.
 533                   (goto-char (point-min))
 534                   ;; Find a header and the column at which the command
 535                   ;; name will be found.
 536
 537                   ;; If the keymap substitution isn't the last thing in
 538                   ;; the doc string, and if there is anything on the same
 539                   ;; line after it, this code won't recognize the end of it.
 540                   (while (re-search-forward "^key +binding\n\\(-+ +\\)-+\n\n"
 541                                             nil t)
 542                     (let ((col (- (match-end 1) (match-beginning 1))))
 543                       (while
 544                           (and (not (eobp))
 545                                ;; Stop at a pair of blank lines.
 546                                (not (looking-at "\n\\s-*\n")))
 547                         ;; Skip a single blank line.
 548                         (and (eolp) (forward-line))
 549                         (end-of-line)
 550                         (skip-chars-backward "^ \t\n")
 551                         (if (and (>= (current-column) col)
 552                                  (looking-at "\\(\\sw\\|\\s_\\)+$"))
 553                             (let ((sym (intern-soft (match-string 0))))
 554                               (if (fboundp sym)
 555                                   (help-xref-button 0 'help-function sym))))
 556                         (forward-line))))))
 557             (set-syntax-table stab))
 558           ;; Delete extraneous newlines at the end of the docstring
 559           (goto-char (point-max))
 560           (while (and (not (bobp)) (bolp))
 561             (delete-char -1))
 562           (insert "\n")
 563           (when (or help-xref-stack help-xref-forward-stack)
 564             (insert "\n"))
 565           ;; Make a back-reference in this buffer if appropriate.
 566           (when help-xref-stack
 567             (help-insert-xref-button help-back-label 'help-back
 568                                      (current-buffer)))
 569           ;; Make a forward-reference in this buffer if appropriate.
 570           (when help-xref-forward-stack
 571             (when help-xref-stack
 572               (insert "\t"))
 573             (help-insert-xref-button help-forward-label 'help-forward
 574                                      (current-buffer)))
 575           (when (or help-xref-stack help-xref-forward-stack)
 576             (insert "\n")))
 577         (set-buffer-modified-p old-modified)))))
 578
 579 ;;;###autoload
 580 (defun help-xref-button (match-number type &rest args)
 581   "Make a hyperlink for cross-reference text previously matched.
 582 MATCH-NUMBER is the subexpression of interest in the last matched
 583 regexp.  TYPE is the type of button to use.  Any remaining arguments are
 584 passed to the button's help-function when it is invoked.
 585 See `help-make-xrefs'."
 586   ;; Don't mung properties we've added specially in some instances.
 587   (unless (button-at (match-beginning match-number))
 588     (make-text-button (match-beginning match-number)
 589                       (match-end match-number)
 590                       'type type 'help-args args)))
 591
 592 ;;;###autoload
 593 (defun help-insert-xref-button (string type &rest args)
 594   "Insert STRING and make a hyperlink from cross-reference text on it.
 595 TYPE is the type of button to use.  Any remaining arguments are passed
 596 to the button's help-function when it is invoked.
 597 See `help-make-xrefs'."
 598   (unless (button-at (point))
 599     (insert-text-button string 'type type 'help-args args)))
 600
 601 ;;;###autoload
 602 (defun help-xref-on-pp (from to)
 603   "Add xrefs for symbols in `pp's output between FROM and TO."
 604   (if (> (- to from) 5000) nil
 605     (with-syntax-table emacs-lisp-mode-syntax-table
 606       (save-excursion
 607         (save-restriction
 608           (narrow-to-region from to)
 609           (goto-char (point-min))
 610           (condition-case nil
 611               (while (not (eobp))
 612                 (cond
 613                  ((looking-at "\"") (forward-sexp 1))
 614                  ((looking-at "#<") (search-forward ">" nil 'move))
 615                  ((looking-at "\\(\\(\\sw\\|\\s_\\)+\\)")
 616                   (let* ((sym (intern-soft (match-string 1)))
 617                          (type (cond ((fboundp sym) 'help-function)
 618                                      ((or (memq sym '(t nil))
 619                                           (keywordp sym))
 620                                       nil)
 621                                      ((and sym
 622                                            (or (boundp sym)
 623                                                (get sym
 624                                                     'variable-documentation)))
 625                                       'help-variable))))
 626                     (when type (help-xref-button 1 type sym)))
 627                   (goto-char (match-end 1)))
 628                  (t (forward-char 1))))
 629             (error nil)))))))
 630
 631 \f
 632 ;; Additional functions for (re-)creating types of help buffers.
 633 (defun help-xref-interned (symbol)
 634   "Follow a hyperlink which appeared to be an arbitrary interned SYMBOL.
 635 Both variable, function and face documentation are extracted into a single
 636 help buffer."
 637   (with-current-buffer (help-buffer)
 638     ;; Push the previous item on the stack before clobbering the output buffer.
 639     (help-setup-xref nil nil)
 640     (let ((facedoc (when (facep symbol)
 641                      ;; Don't record the current entry in the stack.
 642                      (setq help-xref-stack-item nil)
 643                      (describe-face symbol)))
 644           (fdoc (when (fboundp symbol)
 645                   ;; Don't record the current entry in the stack.
 646                   (setq help-xref-stack-item nil)
 647                   (describe-function symbol)))
 648           (sdoc (when (or (boundp symbol)
 649                           (get symbol 'variable-documentation))
 650                   ;; Don't record the current entry in the stack.
 651                   (setq help-xref-stack-item nil)
 652                   (describe-variable symbol))))
 653       (cond
 654        (sdoc
 655         ;; We now have a help buffer on the variable.
 656         ;; Insert the function and face text before it.
 657         (when (or fdoc facedoc)
 658           (goto-char (point-min))
 659           (let ((inhibit-read-only t))
 660             (when fdoc
 661               (insert fdoc "\n\n")
 662               (when facedoc
 663                 (insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
 664                         " is also a " "face." "\n\n")))
 665             (when facedoc
 666               (insert facedoc "\n\n"))
 667             (insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
 668                     " is also a " "variable." "\n\n"))
 669           ;; Don't record the `describe-variable' item in the stack.
 670           (setq help-xref-stack-item nil)
 671           (help-setup-xref (list #'help-xref-interned symbol) nil)))
 672        (fdoc
 673         ;; We now have a help buffer on the function.
 674         ;; Insert face text before it.
 675         (when facedoc
 676           (goto-char (point-max))
 677           (let ((inhibit-read-only t))
 678             (insert "\n\n" (make-string 30 ?-) "\n\n" (symbol-name symbol)
 679                     " is also a " "face." "\n\n" facedoc))
 680           ;; Don't record the `describe-function' item in the stack.
 681           (setq help-xref-stack-item nil)
 682           (help-setup-xref (list #'help-xref-interned symbol) nil)))))))
 683
 684 \f
 685 ;; Navigation/hyperlinking with xrefs
 686
 687 (defun help-xref-go-back (buffer)
 688   "From BUFFER, go back to previous help buffer text using `help-xref-stack'."
 689   (let (item position method args)
 690     (with-current-buffer buffer
 691       (push (cons (point) help-xref-stack-item) help-xref-forward-stack)
 692       (when help-xref-stack
 693         (setq item (pop help-xref-stack)
 694               ;; Clear the current item so that it won't get pushed
 695               ;; by the function we're about to call.  TODO: We could also
 696               ;; push it onto a "forward" stack and add a `forw' button.
 697               help-xref-stack-item nil
 698               position (car item)
 699               method (cadr item)
 700               args (cddr item))))
 701     (apply method args)
 702     (with-current-buffer buffer
 703       (if (get-buffer-window buffer)
 704           (set-window-point (get-buffer-window buffer) position)
 705         (goto-char position)))))
 706
 707 (defun help-xref-go-forward (buffer)
 708   "From BUFFER, go forward to next help buffer."
 709   (let (item position method args)
 710     (with-current-buffer buffer
 711       (push (cons (point) help-xref-stack-item) help-xref-stack)
 712       (when help-xref-forward-stack
 713         (setq item (pop help-xref-forward-stack)
 714               ;; Clear the current item so that it won't get pushed
 715               ;; by the function we're about to call.  TODO: We could also
 716               ;; push it onto a "forward" stack and add a `forw' button.
 717               help-xref-stack-item nil
 718               position (car item)
 719               method (cadr item)
 720               args (cddr item))))
 721     (apply method args)
 722     (with-current-buffer buffer
 723       (if (get-buffer-window buffer)
 724           (set-window-point (get-buffer-window buffer) position)
 725         (goto-char position)))))
 726
 727 (defun help-go-back ()
 728   "Go back to previous topic in this help buffer."
 729   (interactive)
 730   (if help-xref-stack
 731       (help-xref-go-back (current-buffer))
 732     (error "No previous help buffer")))
 733
 734 (defun help-go-forward ()
 735   "Go back to next topic in this help buffer."
 736   (interactive)
 737   (if help-xref-forward-stack
 738       (help-xref-go-forward (current-buffer))
 739     (error "No next help buffer")))
 740
 741 (defun help-do-xref (_pos function args)
 742   "Call the help cross-reference function FUNCTION with args ARGS.
 743 Things are set up properly so that the resulting help-buffer has
 744 a proper [back] button."
 745   ;; There is a reference at point.  Follow it.
 746   (let ((help-xref-following t))
 747     (apply function args)))
 748
 749 ;; The doc string is meant to explain what buttons do.
 750 (defun help-follow-mouse ()
 751   "Follow the cross-reference that you click on."
 752   (interactive)
 753   (error "No cross-reference here"))
 754
 755 ;; The doc string is meant to explain what buttons do.
 756 (defun help-follow ()
 757   "Follow cross-reference at point.
 758
 759 For the cross-reference format, see `help-make-xrefs'."
 760   (interactive)
 761   (error "No cross-reference here"))
 762
 763 (defun help-follow-symbol (&optional pos)
 764   "In help buffer, show docs for symbol at POS, defaulting to point.
 765 Show all docs for that symbol as either a variable, function or face."
 766   (interactive "d")
 767   (unless pos
 768     (setq pos (point)))
 769   ;; check if the symbol under point is a function, variable or face
 770   (let ((sym
 771          (intern
 772           (save-excursion
 773             (goto-char pos) (skip-syntax-backward "w_")
 774             (buffer-substring (point)
 775                               (progn (skip-syntax-forward "w_")
 776                                      (point)))))))
 777     (when (or (boundp sym)
 778               (get sym 'variable-documentation)
 779               (fboundp sym) (facep sym))
 780       (help-do-xref pos #'help-xref-interned (list sym)))))
 781
 782 (defun help-mode-revert-buffer (_ignore-auto noconfirm)
 783   (when (or noconfirm (yes-or-no-p "Revert help buffer? "))
 784     (let ((pos (point))
 785           (item help-xref-stack-item)
 786           ;; Pretend there is no current item to add to the history.
 787           (help-xref-stack-item nil)
 788           ;; Use the current buffer.
 789           (help-xref-following t))
 790       (apply (car item) (cdr item))
 791       (goto-char pos))))
 792
 793 (defun help-insert-string (string)
 794   "Insert STRING to the help buffer and install xref info for it.
 795 This function can be used to restore the old contents of the help buffer
 796 when going back to the previous topic in the xref stack.  It is needed
 797 in case when it is impossible to recompute the old contents of the
 798 help buffer by other means."
 799   (setq help-xref-stack-item (list #'help-insert-string string))
 800   (with-output-to-temp-buffer (help-buffer)
 801     (insert string)))
 802
 803 \f
 804 ;; Bookmark support
 805
 806 (declare-function bookmark-prop-get "bookmark" (bookmark prop))
 807 (declare-function bookmark-make-record-default "bookmark"
 808                   (&optional no-file no-context posn))
 809
 810 (defun help-bookmark-make-record ()
 811   "Create and return a help-mode bookmark record.
 812 Implements `bookmark-make-record-function' for help-mode buffers."
 813   (unless (car help-xref-stack-item)
 814     (error "Cannot create bookmark - help command not known"))
 815   `(,@(bookmark-make-record-default 'NO-FILE 'NO-CONTEXT)
 816       (help-fn     . ,(car help-xref-stack-item))
 817       (help-args   . ,(cdr help-xref-stack-item))
 818       (position    . ,(point))
 819       (handler     . help-bookmark-jump)))
 820
 821 ;;;###autoload
 822 (defun help-bookmark-jump (bookmark)
 823   "Jump to help-mode bookmark BOOKMARK.
 824 Handler function for record returned by `help-bookmark-make-record'.
 825 BOOKMARK is a bookmark name or a bookmark record."
 826   (let ((help-fn    (bookmark-prop-get bookmark 'help-fn))
 827         (help-args  (bookmark-prop-get bookmark 'help-args))
 828         (position   (bookmark-prop-get bookmark 'position)))
 829     (apply help-fn help-args)
 830     (pop-to-buffer "*Help*")
 831     (goto-char position)))
 832
 833
 834 (provide 'help-mode)
 835
 836 ;;; help-mode.el ends here