lisp/x-dnd.el

   1 ;;; x-dnd.el --- drag and drop support for X.
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   4
   5 ;; Author: Jan Dj\e,Ad\e(Brv <jan.h.d@swipnet.se>
   6 ;; Maintainer: FSF
   7 ;; Keywords: window, drag, drop
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file provides the drop part only.  Currently supported protocols
  29 ;; are XDND, Motif and the old KDE 1.x protocol.
  30
  31 ;;; Code:
  32
  33 (require 'dnd)
  34
  35 ;;; Customizable variables
  36 (defcustom x-dnd-test-function 'x-dnd-default-test-function
  37   "The function drag and drop uses to determine if to accept or reject a drop.
  38 The function takes three arguments, WINDOW ACTION and TYPES.
  39 WINDOW is where the mouse is when the function is called.  WINDOW may be a
  40 frame if the mouse isn't over a real window (i.e. menu bar, tool bar or
  41 scroll bar).  ACTION is the suggested action from the drag and drop source,
  42 one of the symbols move, copy link or ask.  TYPES is a list of available types
  43 for the drop.
  44
  45 The function shall return nil to reject the drop or a cons with two values,
  46 the wanted action as car and the wanted type as cdr.  The wanted action
  47 can be copy, move, link, ask or private.
  48 The default value for this variable is `x-dnd-default-test-function'."
  49   :version "22.1"
  50   :type 'symbol
  51   :group 'x)
  52
  53
  54
  55 (defcustom x-dnd-types-alist
  56   '(
  57     ("text/uri-list" . x-dnd-handle-uri-list)
  58     ("text/x-moz-url" . x-dnd-handle-moz-url)
  59     ("_NETSCAPE_URL" . x-dnd-handle-uri-list)
  60     ("FILE_NAME" . x-dnd-handle-file-name)
  61     ("UTF8_STRING" . x-dnd-insert-utf8-text)
  62     ("text/plain;charset=UTF-8" . x-dnd-insert-utf8-text)
  63     ("text/plain;charset=utf-8" . x-dnd-insert-utf8-text)
  64     ("text/unicode" . x-dnd-insert-utf16-text)
  65     ("text/plain" . dnd-insert-text)
  66     ("COMPOUND_TEXT" . x-dnd-insert-ctext)
  67     ("STRING" . dnd-insert-text)
  68     ("TEXT"   . dnd-insert-text)
  69     )
  70   "Which function to call to handle a drop of that type.
  71 If the type for the drop is not present, or the function is nil,
  72 the drop is rejected.  The function takes three arguments, WINDOW, ACTION
  73 and DATA.  WINDOW is where the drop occurred, ACTION is the action for
  74 this drop (copy, move, link, private or ask) as determined by a previous
  75 call to `x-dnd-test-function'.  DATA is the drop data.
  76 The function shall return the action used (copy, move, link or private) if drop
  77 is successful, nil if not."
  78   :version "22.1"
  79   :type 'alist
  80   :group 'x)
  81
  82 (defcustom x-dnd-known-types
  83   '("text/uri-list"
  84     "text/x-moz-url"
  85     "_NETSCAPE_URL"
  86     "FILE_NAME"
  87     "UTF8_STRING"
  88     "text/plain;charset=UTF-8"
  89     "text/plain;charset=utf-8"
  90     "text/unicode"
  91     "text/plain"
  92     "COMPOUND_TEXT"
  93     "STRING"
  94     "TEXT"
  95     )
  96   "The types accepted by default for dropped data.
  97 The types are chosen in the order they appear in the list."
  98   :version "22.1"
  99   :type '(repeat string)
 100   :group 'x
 101 )
 102
 103 ;; Internal variables
 104
 105 (defvar x-dnd-current-state nil
 106   "The current state for a drop.
 107 This is an alist with one entry for each display.  The value for each display
 108 is a vector that contains the state for drag and drop for that display.
 109 Elements in the vector are:
 110 Last buffer drag was in,
 111 last window drag was in,
 112 types available for drop,
 113 the action suggested by the source,
 114 the type we want for the drop,
 115 the action we want for the drop,
 116 any protocol specific data.")
 117
 118 (defvar x-dnd-empty-state [nil nil nil nil nil nil nil])
 119
 120
 121
 122 (defun x-dnd-init-frame (&optional frame)
 123   "Setup drag and drop for FRAME (i.e. create appropriate properties)."
 124   (x-register-dnd-atom "DndProtocol" frame)
 125   (x-register-dnd-atom "_MOTIF_DRAG_AND_DROP_MESSAGE" frame)
 126   (x-register-dnd-atom "XdndEnter" frame)
 127   (x-register-dnd-atom "XdndPosition" frame)
 128   (x-register-dnd-atom "XdndLeave" frame)
 129   (x-register-dnd-atom "XdndDrop" frame)
 130   (x-dnd-init-xdnd-for-frame frame)
 131   (x-dnd-init-motif-for-frame frame))
 132
 133 (defun x-dnd-get-state-cons-for-frame (frame-or-window)
 134   "Return the entry in x-dnd-current-state for a frame or window."
 135   (let* ((frame (if (framep frame-or-window) frame-or-window
 136                   (window-frame frame-or-window)))
 137          (display (frame-parameter frame 'display)))
 138     (if (not (assoc display x-dnd-current-state))
 139         (push (cons display (copy-sequence x-dnd-empty-state))
 140               x-dnd-current-state))
 141     (assoc display x-dnd-current-state)))
 142
 143 (defun x-dnd-get-state-for-frame (frame-or-window)
 144   "Return the state in x-dnd-current-state for a frame or window."
 145   (cdr (x-dnd-get-state-cons-for-frame frame-or-window)))
 146
 147 (defun x-dnd-default-test-function (window action types)
 148   "The default test function for drag and drop.
 149 WINDOW is where the mouse is when this function is called.  It may be a frame
 150 if the mouse is over the menu bar, scroll bar or tool bar.
 151 ACTION is the suggested action from the source, and TYPES are the
 152 types the drop data can have.  This function only accepts drops with
 153 types in `x-dnd-known-types'.  It always returns the action private."
 154   (let ((type (x-dnd-choose-type types)))
 155     (when type (cons 'private type))))
 156
 157
 158 (defun x-dnd-current-type (frame-or-window)
 159   "Return the type we want the DND data to be in for the current drop.
 160 FRAME-OR-WINDOW is the frame or window that the mouse is over."
 161   (aref (x-dnd-get-state-for-frame frame-or-window) 4))
 162
 163 (defun x-dnd-forget-drop (frame-or-window)
 164   "Remove all state for the last drop.
 165 FRAME-OR-WINDOW is the frame or window that the mouse is over."
 166   (setcdr (x-dnd-get-state-cons-for-frame frame-or-window)
 167           (copy-sequence x-dnd-empty-state)))
 168
 169 (defun x-dnd-maybe-call-test-function (window action)
 170   "Call `x-dnd-test-function' if something has changed.
 171 WINDOW is the window the mouse is over.  ACTION is the suggested
 172 action from the source.  If nothing has changed, return the last
 173 action and type we got from `x-dnd-test-function'."
 174   (let ((buffer (when (window-live-p window)
 175                   (window-buffer window)))
 176         (current-state (x-dnd-get-state-for-frame window)))
 177     (when (or (not (equal buffer (aref current-state 0)))
 178               (not (equal window (aref current-state 1)))
 179               (not (equal action (aref current-state 3))))
 180       (save-excursion
 181         (when buffer (set-buffer buffer))
 182         (let* ((action-type (funcall x-dnd-test-function
 183                                      window
 184                                      action
 185                                      (aref current-state 2)))
 186                (handler (cdr (assoc (cdr action-type) x-dnd-types-alist))))
 187           ;; Ignore action-type if we have no handler.
 188           (setq current-state
 189                 (x-dnd-save-state window
 190                                   action
 191                                   (when handler action-type)))))))
 192   (let ((current-state (x-dnd-get-state-for-frame window)))
 193     (cons (aref current-state 5)
 194           (aref current-state 4))))
 195
 196 (defun x-dnd-save-state (window action action-type &optional types extra-data)
 197   "Save the state of the current drag and drop.
 198 WINDOW is the window the mouse is over.  ACTION is the action suggested
 199 by the source.  ACTION-TYPE is the result of calling `x-dnd-test-function'.
 200 If given, TYPES are the types for the drop data that the source supports.
 201 EXTRA-DATA is data needed for a specific protocol."
 202   (let ((current-state (x-dnd-get-state-for-frame window)))
 203     (aset current-state 5 (car action-type))
 204     (aset current-state 4 (cdr action-type))
 205     (aset current-state 3 action)
 206     (when types (aset current-state 2 types))
 207     (when extra-data (aset current-state 6 extra-data))
 208     (aset current-state 1 window)
 209     (aset current-state 0 (and (window-live-p window) (window-buffer window)))
 210     (setcdr (x-dnd-get-state-cons-for-frame window) current-state)))
 211
 212
 213 (defun x-dnd-handle-moz-url (window action data)
 214   "Handle one item of type text/x-moz-url.
 215 WINDOW is the window where the drop happened.  ACTION is ignored.
 216 DATA is the moz-url, which is formatted as two strings separated by \r\n.
 217 The first string is the URL, the second string is the title of that URL.
 218 DATA is encoded in utf-16.  Decode the URL and call `x-dnd-handle-uri-list'."
 219   ;; Mozilla and applications based on it (Galeon for example) uses
 220   ;; text/unicode, but it is impossible to tell if it is le or be.  Use what
 221   ;; the machine Emacs runs on use.  This looses if dropping between machines
 222   ;; with different endian, but it is the best we can do.
 223   (let* ((coding (if (eq (byteorder) ?B) 'utf-16be 'utf-16le))
 224          (string (decode-coding-string data coding))
 225          (strings (split-string string "[\r\n]" t))
 226          ;; Can one drop more than one moz-url ??  Assume not.
 227          (url (car strings))
 228          (title (car (cdr strings))))
 229     (x-dnd-handle-uri-list window action url)))
 230
 231 (defun x-dnd-insert-utf8-text (window action text)
 232   "Decode the UTF-8 text and insert it at point.
 233 TEXT is the text as a string, WINDOW is the window where the drop happened."
 234   (dnd-insert-text window action (decode-coding-string text 'utf-8)))
 235
 236 (defun x-dnd-insert-utf16-text (window action text)
 237   "Decode the UTF-16 text and insert it at point.
 238 TEXT is the text as a string, WINDOW is the window where the drop happened."
 239   ;; See comment in x-dnd-handle-moz-url about coding.
 240   (let ((coding (if (eq (byteorder) ?B) 'utf-16be 'utf-16le)))
 241     (dnd-insert-text window action (decode-coding-string text coding))))
 242
 243 (defun x-dnd-insert-ctext (window action text)
 244   "Decode the compound text and insert it at point.
 245 TEXT is the text as a string, WINDOW is the window where the drop happened."
 246   (dnd-insert-text window action
 247                    (decode-coding-string text
 248                                          'compound-text-with-extensions)))
 249
 250 (defun x-dnd-handle-uri-list (window action string)
 251   "Split an uri-list into separate URIs and call `dnd-handle-one-url'.
 252 WINDOW is the window where the drop happened.
 253 STRING is the uri-list as a string.  The URIs are separated by \r\n."
 254   (let ((uri-list (split-string string "[\0\r\n]" t))
 255         retval)
 256     (dolist (bf uri-list)
 257       ;; If one URL is handeled, treat as if the whole drop succeeded.
 258       (let ((did-action (dnd-handle-one-url window action bf)))
 259         (when did-action (setq retval did-action))))
 260     retval))
 261
 262 (defun x-dnd-handle-file-name (window action string)
 263   "Convert file names to URLs and call `dnd-handle-one-url'.
 264 WINDOW is the window where the drop happened.
 265 STRING is the file names as a string, separated by nulls."
 266   (let ((uri-list (split-string string "[\0\r\n]" t))
 267         (coding (and default-enable-multibyte-characters
 268                      (or file-name-coding-system
 269                          default-file-name-coding-system)))
 270         retval)
 271     (dolist (bf uri-list)
 272       ;; If one URL is handeled, treat as if the whole drop succeeded.
 273       (if coding (setq bf (encode-coding-string bf coding)))
 274       (let* ((file-uri (concat "file://"
 275                                (mapconcat 'url-hexify-string
 276                                           (split-string bf "/") "/")))
 277              (did-action (dnd-handle-one-url window action file-uri)))
 278         (when did-action (setq retval did-action))))
 279     retval))
 280
 281
 282 (defun x-dnd-choose-type (types &optional known-types)
 283   "Choose which type we want to receive for the drop.
 284 TYPES are the types the source of the drop offers, a vector of type names
 285 as strings or symbols.  Select among the types in `x-dnd-known-types' or
 286 KNOWN-TYPES if given,  and return that type name.
 287 If no suitable type is found, return nil."
 288   (let* ((known-list (or known-types x-dnd-known-types))
 289          (first-known-type (car known-list))
 290          (types-array types)
 291          (found (when first-known-type
 292                   (catch 'done
 293                     (dotimes (i (length types-array))
 294                       (let* ((type (aref types-array i))
 295                              (typename (if (symbolp type)
 296                                            (symbol-name type) type)))
 297                         (when (equal first-known-type typename)
 298                           (throw 'done first-known-type))))
 299                     nil))))
 300
 301     (if (and (not found) (cdr known-list))
 302         (x-dnd-choose-type types (cdr known-list))
 303       found)))
 304
 305 (defun x-dnd-drop-data (event frame window data type)
 306   "Drop one data item onto a frame.
 307 EVENT is the client message for the drop, FRAME is the frame the drop occurred
 308 on.  WINDOW is the window of FRAME where the drop happened.  DATA is the data
 309 received from the source, and type is the type for DATA, see
 310 `x-dnd-types-alist').
 311
 312 Returns the action used (move, copy, link, private) if drop was successful,
 313 nil if not."
 314   (let* ((type-info (assoc type x-dnd-types-alist))
 315          (handler (cdr type-info))
 316          (state (x-dnd-get-state-for-frame frame))
 317          (action (aref state 5))
 318          (w (posn-window (event-start event))))
 319     (when handler
 320       (if (and (window-live-p w)
 321                (not (window-minibuffer-p w))
 322                (not (window-dedicated-p w)))
 323           ;; If dropping in an ordinary window which we could use,
 324           ;; let dnd-open-file-other-window specify what to do.
 325           (progn
 326             (when (not mouse-yank-at-point)
 327               (goto-char (posn-point (event-start event))))
 328             (funcall handler window action data))
 329         ;; If we can't display the file here,
 330         ;; make a new window for it.
 331         (let ((dnd-open-file-other-window t))
 332           (select-frame frame)
 333           (funcall handler window action data))))))
 334
 335 (defun x-dnd-handle-drag-n-drop-event (event)
 336   "Receive drag and drop events (X client messages).
 337 Currently XDND, Motif and old KDE 1.x protocols are recognized."
 338   (interactive "e")
 339   (let* ((client-message (car (cdr (cdr event))))
 340          (window (posn-window (event-start event)))
 341          (message-atom (aref client-message 0))
 342          (frame (aref client-message 1))
 343          (format (aref client-message 2))
 344          (data (aref client-message 3)))
 345
 346     (cond ((equal "DndProtocol" message-atom)   ; Old KDE 1.x.
 347            (x-dnd-handle-old-kde event frame window message-atom format data))
 348
 349           ((equal "_MOTIF_DRAG_AND_DROP_MESSAGE" message-atom)  ; Motif
 350            (x-dnd-handle-motif event frame window message-atom format data))
 351
 352           ((and (> (length message-atom) 4)     ; XDND protocol.
 353                 (equal "Xdnd" (substring message-atom 0 4)))
 354            (x-dnd-handle-xdnd event frame window message-atom format data)))))
 355
 356
 357 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 358 ;;;  Old KDE protocol.  Only dropping of files.
 359
 360 (defun x-dnd-handle-old-kde (event frame window message format data)
 361   "Open the files in a KDE 1.x drop."
 362   (let ((values (x-window-property "DndSelection" frame nil 0 t)))
 363     (x-dnd-handle-uri-list window 'private
 364                            (replace-regexp-in-string "\0$" "" values))))
 365 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 366
 367
 368
 369 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 370 ;;;  XDND protocol.
 371
 372 (defvar x-dnd-xdnd-to-action
 373   '(("XdndActionPrivate" . private)
 374     ("XdndActionCopy" . copy)
 375     ("XdndActionMove" . move)
 376     ("XdndActionLink" . link)
 377     ("XdndActionAsk" . ask))
 378   "Mapping from XDND action types to lisp symbols.")
 379
 380 (defun x-dnd-init-xdnd-for-frame (frame)
 381   "Set the XdndAware property for FRAME to indicate that we do XDND."
 382   (x-change-window-property "XdndAware"
 383                             '(5)        ;; The version of XDND we support.
 384                             frame "ATOM" 32 t))
 385
 386 (defun x-dnd-get-drop-width-height (frame w accept)
 387   "Return the widht/height to be sent in a XDndStatus message.
 388 FRAME is the frame and W is the window where the drop happened.
 389 If ACCEPT is nil return 0 (empty rectangle),
 390 otherwise if W is a window, return its widht/height,
 391 otherwise return the frame width/height."
 392   (if accept
 393       (if (windowp w)   ;; w is not a window if dropping on the menu bar,
 394                         ;; scroll bar or tool bar.
 395           (let ((edges (window-inside-pixel-edges w)))
 396             (cons
 397              (- (nth 2 edges) (nth 0 edges))    ;; right - left
 398              (- (nth 3 edges) (nth 1 edges))))  ;; bottom - top
 399         (cons (frame-pixel-width frame)
 400               (frame-pixel-height frame)))
 401     0))
 402
 403 (defun x-dnd-get-drop-x-y (frame w)
 404   "Return the x/y coordinates to be sent in a XDndStatus message.
 405 Coordinates are required to be absolute.
 406 FRAME is the frame and W is the window where the drop happened.
 407 If W is a window, return its absolute corrdinates,
 408 otherwise return the frame coordinates."
 409   (let* ((frame-left (frame-parameter frame 'left))
 410          ;; If the frame is outside the display, frame-left looks like
 411          ;; '(0 -16).  Extract the -16.
 412          (frame-real-left (if (consp frame-left) (car (cdr frame-left))
 413                             frame-left))
 414          (frame-top (frame-parameter frame 'top))
 415          (frame-real-top (if (consp frame-top) (car (cdr frame-top))
 416                            frame-top)))
 417     (if (windowp w)
 418         (let ((edges (window-inside-pixel-edges w)))
 419           (cons
 420            (+ frame-real-left (nth 0 edges))
 421            (+ frame-real-top (nth 1 edges))))
 422       (cons frame-real-left frame-real-top))))
 423
 424 (defun x-dnd-handle-xdnd (event frame window message format data)
 425   "Receive one XDND event (client message) and send the appropriate reply.
 426 EVENT is the client message.  FRAME is where the mouse is now.
 427 WINDOW is the window within FRAME where the mouse is now.
 428 FORMAT is 32 (not used).  MESSAGE is the data part of an XClientMessageEvent."
 429   (cond ((equal "XdndEnter" message)
 430          (let* ((flags (aref data 1))
 431                 (version (and (consp flags) (ash (car flags) -8)))
 432                 (more-than-3 (and (consp flags) (cdr flags)))
 433                 (dnd-source (aref data 0)))
 434            (if version  ;; If flags is bad, version will be nil.
 435                (x-dnd-save-state
 436                 window nil nil
 437                 (if (> more-than-3 0)
 438                     (x-window-property "XdndTypeList"
 439                                        frame "AnyPropertyType"
 440                                        dnd-source nil t)
 441                   (vector (x-get-atom-name (aref data 2))
 442                           (x-get-atom-name (aref data 3))
 443                           (x-get-atom-name (aref data 4))))))))
 444
 445         ((equal "XdndPosition" message)
 446          (let* ((x (car (aref data 2)))
 447                 (y (cdr (aref data 2)))
 448                 (action (x-get-atom-name (aref data 4)))
 449                 (dnd-source (aref data 0))
 450                 (dnd-time (aref data 3))
 451                 (action-type (x-dnd-maybe-call-test-function
 452                               window
 453                               (cdr (assoc action x-dnd-xdnd-to-action))))
 454                 (reply-action (car (rassoc (car action-type)
 455                                            x-dnd-xdnd-to-action)))
 456                 (accept ;; 1 = accept, 0 = reject
 457                  (if (and reply-action action-type) 1 0))
 458                 (list-to-send
 459                  (list (string-to-number
 460                         (frame-parameter frame 'outer-window-id))
 461                        accept ;; 1 = Accept, 0 = reject.
 462                        (x-dnd-get-drop-x-y frame window)
 463                        (x-dnd-get-drop-width-height
 464                         frame window (eq accept 1))
 465                        (or reply-action 0)
 466                        )))
 467            (x-send-client-message
 468             frame dnd-source frame "XdndStatus" 32 list-to-send)
 469            ))
 470
 471         ((equal "XdndLeave" message)
 472          (x-dnd-forget-drop window))
 473
 474         ((equal "XdndDrop" message)
 475          (if (windowp window) (select-window window))
 476          (let* ((dnd-source (aref data 0))
 477                 (value (and (x-dnd-current-type window)
 478                             (x-get-selection-internal
 479                              'XdndSelection
 480                              (intern (x-dnd-current-type window)))))
 481                 success action ret-action)
 482
 483            (setq action (if value
 484                             (condition-case info
 485                                 (x-dnd-drop-data event frame window value
 486                                                  (x-dnd-current-type window))
 487                               (error
 488                                (message "Error: %s" info)
 489                                nil))))
 490
 491            (setq success (if action 1 0))
 492            (setq ret-action
 493                  (if (eq success 1)
 494                      (or (car (rassoc action x-dnd-xdnd-to-action))
 495                          "XdndActionPrivate")
 496                    0))
 497
 498            (x-send-client-message
 499             frame dnd-source frame "XdndFinished" 32
 500             (list (string-to-number (frame-parameter frame 'outer-window-id))
 501                   success       ;; 1 = Success, 0 = Error
 502                   (if success "XdndActionPrivate" 0)
 503                   ))
 504            (x-dnd-forget-drop window)))
 505
 506         (t (error "Unknown XDND message %s %s" message data))))
 507
 508 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 509 ;;;  Motif protocol.
 510
 511 (defun x-dnd-init-motif-for-frame (frame)
 512   "Set _MOTIF_DRAG_RECEIVER_INFO  for FRAME to indicate that we do Motif DND."
 513   (x-change-window-property "_MOTIF_DRAG_RECEIVER_INFO"
 514                             (list
 515                              (byteorder)
 516                              0                  ; The Motif DND version.
 517                              5                  ; We want drag dynamic.
 518                              0 0 0 0 0 0 0
 519                              0 0 0 0 0 0)       ; Property must be 16 bytes.
 520                             frame "_MOTIF_DRAG_RECEIVER_INFO" 8 t))
 521
 522 (defun x-dnd-get-motif-value (data offset size byteorder)
 523   (cond ((eq size 2)
 524          (if (eq byteorder ?l)
 525              (+ (ash (aref data (1+ offset)) 8)
 526                 (aref data offset))
 527            (+ (ash (aref data offset) 8)
 528               (aref data (1+ offset)))))
 529
 530         ((eq size 4)
 531          (if (eq byteorder ?l)
 532              (cons (+ (ash (aref data (+ 3 offset)) 8)
 533                       (aref data (+ 2 offset)))
 534                    (+ (ash (aref data (1+ offset)) 8)
 535                       (aref data offset)))
 536            (cons (+ (ash (aref data offset) 8)
 537                     (aref data (1+ offset)))
 538                  (+ (ash (aref data (+ 2 offset)) 8)
 539                     (aref data (+ 3 offset))))))))
 540
 541 (defun x-dnd-motif-value-to-list (value size byteorder)
 542   (let ((bytes (cond ((eq size 2)
 543                       (list (logand (lsh value -8) ?\xff)
 544                             (logand value ?\xff)))
 545
 546                      ((eq size 4)
 547                       (if (consp value)
 548                           (list (logand (lsh (car value) -8) ?\xff)
 549                                 (logand (car value) ?\xff)
 550                                 (logand (lsh (cdr value) -8) ?\xff)
 551                                 (logand (cdr value) ?\xff))
 552                         (list (logand (lsh value -24) ?\xff)
 553                               (logand (lsh value -16) ?\xff)
 554                               (logand (lsh value -8) ?\xff)
 555                               (logand value ?\xff)))))))
 556     (if (eq byteorder ?l)
 557         (reverse bytes)
 558       bytes)))
 559
 560
 561 (defvar x-dnd-motif-message-types
 562   '((0 . XmTOP_LEVEL_ENTER)
 563     (1 . XmTOP_LEVEL_LEAVE)
 564     (2 . XmDRAG_MOTION)
 565     (3 . XmDROP_SITE_ENTER)
 566     (4 . XmDROP_SITE_LEAVE)
 567     (5 . XmDROP_START)
 568     (6 . XmDROP_FINISH)
 569     (7 . XmDRAG_DROP_FINISH)
 570     (8 . XmOPERATION_CHANGED))
 571   "Mapping from numbers to Motif DND message types.")
 572
 573 (defvar x-dnd-motif-to-action
 574   '((1 . move)
 575     (2 . copy)
 576     (3 . link)  ; Both 3 and 4 has been seen as link.
 577     (4 . link)
 578     (2 . private)) ; Motif does not have private, so use copy for private.
 579   "Mapping from number to operation for Motif DND.")
 580
 581 (defun x-dnd-handle-motif (event frame window message-atom format data)
 582   (let* ((message-type (cdr (assoc (aref data 0) x-dnd-motif-message-types)))
 583          (source-byteorder (aref data 1))
 584          (my-byteorder (byteorder))
 585          (source-flags (x-dnd-get-motif-value data 2 2 source-byteorder))
 586          (source-action (cdr (assoc (logand ?\xF source-flags)
 587                                     x-dnd-motif-to-action))))
 588
 589     (cond ((eq message-type 'XmTOP_LEVEL_ENTER)
 590            (let* ((dnd-source (x-dnd-get-motif-value
 591                                data 8 4 source-byteorder))
 592                   (selection-atom (x-dnd-get-motif-value
 593                                    data 12 4 source-byteorder))
 594                   (atom-name (x-get-atom-name selection-atom))
 595                   (types (when atom-name
 596                            (x-get-selection-internal (intern atom-name)
 597                                                      'TARGETS))))
 598              (x-dnd-forget-drop frame)
 599              (when types (x-dnd-save-state window nil nil
 600                                            types
 601                                            dnd-source))))
 602
 603           ;; Can not forget drop here, LEAVE comes before DROP_START and
 604           ;; we need the state in DROP_START.
 605           ((eq message-type 'XmTOP_LEVEL_LEAVE)
 606            nil)
 607
 608           ((eq message-type 'XmDRAG_MOTION)
 609            (let* ((state (x-dnd-get-state-for-frame frame))
 610                   (timestamp (x-dnd-motif-value-to-list
 611                               (x-dnd-get-motif-value data 4 4
 612                                                      source-byteorder)
 613                               4 my-byteorder))
 614                   (x (x-dnd-motif-value-to-list
 615                       (x-dnd-get-motif-value data 8 2 source-byteorder)
 616                       2 my-byteorder))
 617                   (y (x-dnd-motif-value-to-list
 618                       (x-dnd-get-motif-value data 10 2 source-byteorder)
 619                       2 my-byteorder))
 620                   (dnd-source (aref state 6))
 621                   (first-move (not (aref state 3)))
 622                   (action-type (x-dnd-maybe-call-test-function
 623                                 window
 624                                 source-action))
 625                   (reply-action (car (rassoc (car action-type)
 626                                              x-dnd-motif-to-action)))
 627                   (reply-flags
 628                    (x-dnd-motif-value-to-list
 629                     (if reply-action
 630                         (+ reply-action
 631                            ?\x30        ; 30:  valid drop site
 632                            ?\x700)      ; 700: can do copy, move or link
 633                       ?\x30)            ; 30:  drop site, but noop.
 634                     2 my-byteorder))
 635                   (reply (append
 636                           (list
 637                            (+ ?\x80     ; 0x80 indicates a reply.
 638                               (if first-move
 639                                   3     ; First time, reply is SITE_ENTER.
 640                                 2))     ; Not first time, reply is DRAG_MOTION.
 641                            my-byteorder)
 642                           reply-flags
 643                           timestamp
 644                           x
 645                           y)))
 646              (x-send-client-message frame
 647                                     dnd-source
 648                                     frame
 649                                     "_MOTIF_DRAG_AND_DROP_MESSAGE"
 650                                     8
 651                                     reply)))
 652
 653           ((eq message-type 'XmOPERATION_CHANGED)
 654            (let* ((state (x-dnd-get-state-for-frame frame))
 655                   (timestamp (x-dnd-motif-value-to-list
 656                               (x-dnd-get-motif-value data 4 4 source-byteorder)
 657                               4 my-byteorder))
 658                   (dnd-source (aref state 6))
 659                   (action-type (x-dnd-maybe-call-test-function
 660                                 window
 661                                 source-action))
 662                   (reply-action (car (rassoc (car action-type)
 663                                              x-dnd-motif-to-action)))
 664                   (reply-flags
 665                    (x-dnd-motif-value-to-list
 666                     (if reply-action
 667                         (+ reply-action
 668                            ?\x30        ; 30:  valid drop site
 669                            ?\x700)      ; 700: can do copy, move or link
 670                       ?\x30)            ; 30:  drop site, but noop
 671                     2 my-byteorder))
 672                   (reply (append
 673                           (list
 674                            (+ ?\x80     ; 0x80 indicates a reply.
 675                               8)        ; 8 is OPERATION_CHANGED
 676                            my-byteorder)
 677                           reply-flags
 678                           timestamp)))
 679              (x-send-client-message frame
 680                                     dnd-source
 681                                     frame
 682                                     "_MOTIF_DRAG_AND_DROP_MESSAGE"
 683                                     8
 684                                     reply)))
 685
 686           ((eq message-type 'XmDROP_START)
 687            (let* ((x (x-dnd-motif-value-to-list
 688                       (x-dnd-get-motif-value data 8 2 source-byteorder)
 689                       2 my-byteorder))
 690                   (y (x-dnd-motif-value-to-list
 691                       (x-dnd-get-motif-value data 10 2 source-byteorder)
 692                       2 my-byteorder))
 693                   (selection-atom (x-dnd-get-motif-value
 694                                    data 12 4 source-byteorder))
 695                   (atom-name (x-get-atom-name selection-atom))
 696                   (dnd-source (x-dnd-get-motif-value
 697                                data 16 4 source-byteorder))
 698                   (action-type (x-dnd-maybe-call-test-function
 699                                 window
 700                                 source-action))
 701                   (reply-action (car (rassoc (car action-type)
 702                                              x-dnd-motif-to-action)))
 703                   (reply-flags
 704                    (x-dnd-motif-value-to-list
 705                     (if reply-action
 706                         (+ reply-action
 707                            ?\x30        ; 30:  valid drop site
 708                            ?\x700)      ; 700: can do copy, move or link
 709                       (+ ?\x30          ; 30:  drop site, but noop.
 710                          ?\x200))       ; 200: drop cancel.
 711                     2 my-byteorder))
 712                   (reply (append
 713                           (list
 714                            (+ ?\x80     ; 0x80 indicates a reply.
 715                               5)        ; DROP_START.
 716                            my-byteorder)
 717                           reply-flags
 718                           x
 719                           y))
 720                   (timestamp (x-dnd-get-motif-value
 721                               data 4 4 source-byteorder))
 722                   action)
 723
 724              (x-send-client-message frame
 725                                     dnd-source
 726                                     frame
 727                                     "_MOTIF_DRAG_AND_DROP_MESSAGE"
 728                                     8
 729                                     reply)
 730              (setq action
 731                    (when (and reply-action atom-name)
 732                      (let* ((value (x-get-selection-internal
 733                                     (intern atom-name)
 734                                     (intern (x-dnd-current-type window)))))
 735                        (when value
 736                          (condition-case info
 737                              (x-dnd-drop-data event frame window value
 738                                               (x-dnd-current-type window))
 739                            (error
 740                             (message "Error: %s" info)
 741                             nil))))))
 742              (x-get-selection-internal
 743               (intern atom-name)
 744               (if action 'XmTRANSFER_SUCCESS 'XmTRANSFER_FAILURE)
 745               timestamp)
 746              (x-dnd-forget-drop frame)))
 747
 748           (t (error "Unknown Motif DND message %s %s" message-atom data)))))
 749
 750
 751 ;;;
 752
 753 (provide 'x-dnd)
 754
 755 ;;; arch-tag: b621fb7e-50da-4323-850b-5fc71ae64621
 756 ;;; x-dnd.el ends here