lisp/eshell/em-prompt.el

   1 ;;; em-prompt.el --- command prompts
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008, 2009, 2010, 2011  Free Software Foundation, Inc.
   5
   6 ;; Author: John Wiegley <johnw@gnu.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Most of the prompt navigation commands of `comint-mode' are
  26 ;; supported, such as C-c C-n, C-c C-p, etc.
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'eshell))
  31
  32 ;;;###autoload
  33 (eshell-defgroup eshell-prompt nil
  34   "This module provides command prompts, and navigation between them,
  35 as is common with most shells."
  36   :tag "Command prompts"
  37   :group 'eshell-module)
  38
  39 ;;; User Variables:
  40
  41 (defcustom eshell-prompt-load-hook '(eshell-prompt-initialize)
  42   "*A list of functions to call when loading `eshell-prompt'."
  43   :type 'hook
  44   :group 'eshell-prompt)
  45
  46 (defcustom eshell-prompt-function
  47   (function
  48    (lambda ()
  49      (concat (abbreviate-file-name (eshell/pwd))
  50              (if (= (user-uid) 0) " # " " $ "))))
  51   "A function that returns the Eshell prompt string.
  52 Make sure to update `eshell-prompt-regexp' so that it will match your
  53 prompt."
  54   :type 'function
  55   :group 'eshell-prompt)
  56
  57 (defcustom eshell-prompt-regexp "^[^#$\n]* [#$] "
  58   "*A regexp which fully matches your eshell prompt.
  59 This setting is important, since it affects how eshell will interpret
  60 the lines that are passed to it.
  61 If this variable is changed, all Eshell buffers must be exited and
  62 re-entered for it to take effect."
  63   :type 'regexp
  64   :group 'eshell-prompt)
  65
  66 (defcustom eshell-highlight-prompt t
  67   "*If non-nil, Eshell should highlight the prompt."
  68   :type 'boolean
  69   :group 'eshell-prompt)
  70
  71 (defface eshell-prompt
  72   '((((class color) (background light)) (:foreground "Red" :bold t))
  73     (((class color) (background dark)) (:foreground "Pink" :bold t))
  74     (t (:bold t)))
  75   "*The face used to highlight prompt strings.
  76 For highlighting other kinds of strings -- similar to shell mode's
  77 behavior -- simply use an output filer which changes text properties."
  78   :group 'eshell-prompt)
  79 (define-obsolete-face-alias 'eshell-prompt-face 'eshell-prompt "22.1")
  80
  81 (defcustom eshell-before-prompt-hook nil
  82   "*A list of functions to call before outputting the prompt."
  83   :type 'hook
  84   :options '(eshell-begin-on-new-line)
  85   :group 'eshell-prompt)
  86
  87 (defcustom eshell-after-prompt-hook nil
  88   "*A list of functions to call after outputting the prompt.
  89 Note that if `eshell-scroll-show-maximum-output' is non-nil, then
  90 setting `eshell-show-maximum-output' here won't do much.  It depends
  91 on whether the user wants the resizing to happen while output is
  92 arriving, or after."
  93   :type 'hook
  94   :options '(eshell-show-maximum-output)
  95   :group 'eshell-prompt)
  96
  97 ;;; Functions:
  98
  99 (defun eshell-prompt-initialize ()
 100   "Initialize the prompting code."
 101   (unless eshell-non-interactive-p
 102     (add-hook 'eshell-post-command-hook 'eshell-emit-prompt nil t)
 103
 104     (make-local-variable 'eshell-prompt-regexp)
 105     (if eshell-prompt-regexp
 106         (set (make-local-variable 'paragraph-start) eshell-prompt-regexp))
 107
 108     (set (make-local-variable 'eshell-skip-prompt-function)
 109          'eshell-skip-prompt)
 110
 111     (define-key eshell-command-map [(control ?n)] 'eshell-next-prompt)
 112     (define-key eshell-command-map [(control ?p)] 'eshell-previous-prompt)))
 113
 114 (defun eshell-emit-prompt ()
 115   "Emit a prompt if eshell is being used interactively."
 116   (run-hooks 'eshell-before-prompt-hook)
 117   (if (not eshell-prompt-function)
 118       (set-marker eshell-last-output-end (point))
 119     (let ((prompt (funcall eshell-prompt-function)))
 120       (and eshell-highlight-prompt
 121            (add-text-properties 0 (length prompt)
 122                                 '(read-only t
 123                                   face eshell-prompt
 124                                   rear-nonsticky (face read-only))
 125                                 prompt))
 126       (eshell-interactive-print prompt)))
 127   (run-hooks 'eshell-after-prompt-hook))
 128
 129 (defun eshell-backward-matching-input (regexp arg)
 130   "Search backward through buffer for match for REGEXP.
 131 Matches are searched for on lines that match `eshell-prompt-regexp'.
 132 With prefix argument N, search for Nth previous match.
 133 If N is negative, find the next or Nth next match."
 134   (interactive (eshell-regexp-arg "Backward input matching (regexp): "))
 135   (let* ((re (concat eshell-prompt-regexp ".*" regexp))
 136          (pos (save-excursion (end-of-line (if (> arg 0) 0 1))
 137                               (if (re-search-backward re nil t arg)
 138                                   (point)))))
 139     (if (null pos)
 140         (progn (message "Not found")
 141                (ding))
 142       (goto-char pos)
 143       (eshell-bol))))
 144
 145 (defun eshell-forward-matching-input (regexp arg)
 146   "Search forward through buffer for match for REGEXP.
 147 Matches are searched for on lines that match `eshell-prompt-regexp'.
 148 With prefix argument N, search for Nth following match.
 149 If N is negative, find the previous or Nth previous match."
 150   (interactive (eshell-regexp-arg "Forward input matching (regexp): "))
 151   (eshell-backward-matching-input regexp (- arg)))
 152
 153 (defun eshell-next-prompt (n)
 154   "Move to end of Nth next prompt in the buffer.
 155 See `eshell-prompt-regexp'."
 156   (interactive "p")
 157   (forward-paragraph n)
 158   (eshell-skip-prompt))
 159
 160 (defun eshell-previous-prompt (n)
 161   "Move to end of Nth previous prompt in the buffer.
 162 See `eshell-prompt-regexp'."
 163   (interactive "p")
 164   (eshell-next-prompt (- (1+ n))))
 165
 166 (defun eshell-skip-prompt ()
 167   "Skip past the text matching regexp `eshell-prompt-regexp'.
 168 If this takes us past the end of the current line, don't skip at all."
 169   (let ((eol (line-end-position)))
 170     (if (and (looking-at eshell-prompt-regexp)
 171              (<= (match-end 0) eol))
 172         (goto-char (match-end 0)))))
 173
 174 (provide 'em-prompt)
 175
 176 ;; Local Variables:
 177 ;; generated-autoload-file: "esh-groups.el"
 178 ;; End:
 179
 180 ;; arch-tag: 01c1574b-ce70-4e89-bc38-e6619f61e208
 181 ;;; em-prompt.el ends here