lisp/find-dired.el

   1 ;;; find-dired.el --- run a `find' command and dired the output
   2
   3 ;; Copyright (C) 1992, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: Roland McGrath <roland@gnu.org>,
   6 ;;         Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;; Maintainer: FSF
   8 ;; Keywords: unix
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Code:
  28
  29 (require 'dired)
  30
  31 (defgroup find-dired nil
  32   "Run a `find' command and dired the output."
  33   :group 'dired
  34   :prefix "find-")
  35
  36 ;; find's -ls corresponds to these switches.
  37 ;; Note -b, at least GNU find quotes spaces etc. in filenames
  38 ;;;###autoload
  39 (defcustom find-ls-option
  40   (if (eq system-type 'berkeley-unix) '("-ls" . "-gilsb")
  41     '("-exec ls -ld {} \\;" . "-ld"))
  42   "*Description of the option to `find' to produce an `ls -l'-type listing.
  43 This is a cons of two strings (FIND-OPTION . LS-SWITCHES).  FIND-OPTION
  44 gives the option (or options) to `find' that produce the desired output.
  45 LS-SWITCHES is a list of `ls' switches to tell dired how to parse the output."
  46   :type '(cons (string :tag "Find Option")
  47                (string :tag "Ls Switches"))
  48   :group 'find-dired)
  49
  50 ;;;###autoload
  51 (defcustom find-grep-options
  52   (if (or (eq system-type 'berkeley-unix)
  53           (string-match "solaris2" system-configuration)
  54           (string-match "irix" system-configuration))
  55       "-s" "-q")
  56   "*Option to grep to be as silent as possible.
  57 On Berkeley systems, this is `-s'; on Posix, and with GNU grep, `-q' does it.
  58 On other systems, the closest you can come is to use `-l'."
  59   :type 'string
  60   :group 'find-dired)
  61
  62 (defvar find-args nil
  63   "Last arguments given to `find' by \\[find-dired].")
  64
  65 ;; History of find-args values entered in the minibuffer.
  66 (defvar find-args-history nil)
  67
  68 ;;;###autoload
  69 (defun find-dired (dir args)
  70   "Run `find' and go into Dired mode on a buffer of the output.
  71 The command run (after changing into DIR) is
  72
  73     find . \\( ARGS \\) -ls
  74
  75 except that the variable `find-ls-option' specifies what to use
  76 as the final argument."
  77   (interactive (list (read-file-name "Run find in directory: " nil "" t)
  78                      (read-string "Run find (with args): " find-args
  79                                   '(find-args-history . 1))))
  80   (let ((dired-buffers dired-buffers))
  81     ;; Expand DIR ("" means default-directory), and make sure it has a
  82     ;; trailing slash.
  83     (setq dir (abbreviate-file-name
  84                (file-name-as-directory (expand-file-name dir))))
  85     ;; Check that it's really a directory.
  86     (or (file-directory-p dir)
  87         (error "find-dired needs a directory: %s" dir))
  88     (switch-to-buffer (get-buffer-create "*Find*"))
  89     (widen)
  90     (kill-all-local-variables)
  91     (setq buffer-read-only nil)
  92     (erase-buffer)
  93     (setq default-directory dir
  94           find-args args                ; save for next interactive call
  95           args (concat "find . "
  96                        (if (string= args "")
  97                            ""
  98                          (concat "\\( " args " \\) "))
  99                        (car find-ls-option)))
 100     ;; The next statement will bomb in classic dired (no optional arg allowed)
 101     (dired-mode dir (cdr find-ls-option))
 102     ;; This really should rerun the find command, but I don't
 103     ;; have time for that.
 104     (use-local-map (append (make-sparse-keymap) (current-local-map)))
 105     (define-key (current-local-map) "g" 'undefined)
 106     ;; Set subdir-alist so that Tree Dired will work:
 107     (if (fboundp 'dired-simple-subdir-alist)
 108         ;; will work even with nested dired format (dired-nstd.el,v 1.15
 109         ;; and later)
 110         (dired-simple-subdir-alist)
 111       ;; else we have an ancient tree dired (or classic dired, where
 112       ;; this does no harm)
 113       (set (make-local-variable 'dired-subdir-alist)
 114            (list (cons default-directory (point-min-marker)))))
 115     (setq buffer-read-only nil)
 116     ;; Subdir headlerline must come first because the first marker in
 117     ;; subdir-alist points there.
 118     (insert "  " dir ":\n")
 119     ;; Make second line a ``find'' line in analogy to the ``total'' or
 120     ;; ``wildcard'' line.
 121     (insert "  " args "\n")
 122     ;; Start the find process.
 123     (let ((proc (start-process-shell-command "find" (current-buffer) args)))
 124       (set-process-filter proc (function find-dired-filter))
 125       (set-process-sentinel proc (function find-dired-sentinel))
 126       ;; Initialize the process marker; it is used by the filter.
 127       (move-marker (process-mark proc) 1 (current-buffer)))
 128     (setq mode-line-process '(":%s"))))
 129
 130 ;;;###autoload
 131 (defun find-name-dired (dir pattern)
 132   "Search DIR recursively for files matching the globbing pattern PATTERN,
 133 and run dired on those files.
 134 PATTERN is a shell wildcard (not an Emacs regexp) and need not be quoted.
 135 The command run (after changing into DIR) is
 136
 137     find . -name 'PATTERN' -ls"
 138   (interactive
 139    "DFind-name (directory): \nsFind-name (filename wildcard): ")
 140   (find-dired dir (concat "-name '" pattern "'")))
 141
 142 ;; This functionality suggested by
 143 ;; From: oblanc@watcgl.waterloo.edu (Olivier Blanc)
 144 ;; Subject: find-dired, lookfor-dired
 145 ;; Date: 10 May 91 17:50:00 GMT
 146 ;; Organization: University of Waterloo
 147
 148 (defalias 'lookfor-dired 'find-grep-dired)
 149 ;;;###autoload
 150 (defun find-grep-dired (dir args)
 151   "Find files in DIR containing a regexp ARG and start Dired on output.
 152 The command run (after changing into DIR) is
 153
 154     find . -exec grep -s ARG {} \\\; -ls
 155
 156 Thus ARG can also contain additional grep options."
 157   (interactive "DFind-grep (directory): \nsFind-grep (grep regexp): ")
 158   ;; find -exec doesn't allow shell i/o redirections in the command,
 159   ;; or we could use `grep -l >/dev/null'
 160   ;; We use -type f, not ! -type d, to avoid getting screwed
 161   ;; by FIFOs and devices.  I'm not sure what's best to do
 162   ;; about symlinks, so as far as I know this is not wrong.
 163   (find-dired dir
 164               (concat "-type f -exec grep " find-grep-options " "
 165                       args " {} \\\; ")))
 166
 167 (defun find-dired-filter (proc string)
 168   ;; Filter for \\[find-dired] processes.
 169   (let ((buf (process-buffer proc)))
 170     (if (buffer-name buf)               ; not killed?
 171         (save-excursion
 172           (set-buffer buf)
 173           (save-restriction
 174             (widen)
 175             (save-excursion
 176               (let ((buffer-read-only nil)
 177                     (end (point-max)))
 178                 (goto-char end)
 179                 (insert string)
 180                 (goto-char end)
 181                 (or (looking-at "^")
 182                     (forward-line 1))
 183                 (while (looking-at "^")
 184                   (insert "  ")
 185                   (forward-line 1))
 186                 ;; Convert ` ./FILE' to ` FILE'
 187                 ;; This would lose if the current chunk of output
 188                 ;; starts or ends within the ` ./', so back up a bit:
 189                 (goto-char (- end 3))   ; no error if < 0
 190                 (while (search-forward " ./" nil t)
 191                   (delete-region (point) (- (point) 2)))
 192                 ;; Find all the complete lines in the unprocessed
 193                 ;; output and process it to add text properties.
 194                 (goto-char end)
 195                 (if (search-backward "\n" (process-mark proc) t)
 196                     (progn
 197                       (dired-insert-set-properties (process-mark proc)
 198                                                    (1+ (point)))
 199                       (move-marker (process-mark proc) (1+ (point)))))
 200                 ))))
 201       ;; The buffer has been killed.
 202       (delete-process proc))))
 203
 204 (defun find-dired-sentinel (proc state)
 205   ;; Sentinel for \\[find-dired] processes.
 206   (let ((buf (process-buffer proc)))
 207     (if (buffer-name buf)
 208         (save-excursion
 209           (set-buffer buf)
 210           (let ((buffer-read-only nil))
 211             (save-excursion
 212               (goto-char (point-max))
 213               (insert "\nfind " state)
 214               (forward-char -1)         ;Back up before \n at end of STATE.
 215               (insert " at " (substring (current-time-string) 0 19))
 216               (forward-char 1)
 217               (setq mode-line-process
 218                     (concat ":"
 219                             (symbol-name (process-status proc))))
 220               ;; Since the buffer and mode line will show that the
 221               ;; process is dead, we can delete it now.  Otherwise it
 222               ;; will stay around until M-x list-processes.
 223               (delete-process proc)
 224               (force-mode-line-update)))
 225           (message "find-dired %s finished." (current-buffer))))))
 226 \f
 227 (provide 'find-dired)
 228
 229 ;;; find-dired.el ends here