lisp/userlock.el

   1 ;;; userlock.el --- handle file access contention between multiple users
   2
   3 ;; Copyright (C) 1985-1986, 2001-2013 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This file is autoloaded to handle certain conditions
  27 ;; detected by the file-locking code within Emacs.
  28 ;; The two entry points are `ask-user-about-lock' and
  29 ;; `ask-user-about-supersession-threat'.
  30
  31 ;;; Code:
  32
  33 (define-error 'file-locked "File is locked" 'file-error)
  34
  35 ;;;###autoload
  36 (defun ask-user-about-lock (file opponent)
  37   "Ask user what to do when he wants to edit FILE but it is locked by OPPONENT.
  38 This function has a choice of three things to do:
  39   do (signal 'file-locked (list FILE OPPONENT))
  40     to refrain from editing the file
  41   return t (grab the lock on the file)
  42   return nil (edit the file even though it is locked).
  43 You can redefine this function to choose among those three alternatives
  44 in any way you like."
  45   (discard-input)
  46   (save-window-excursion
  47     (let (answer short-opponent short-file)
  48       (setq short-file
  49             (if (> (length file) 22)
  50                 (concat "..." (substring file (- (length file) 22)))
  51               file))
  52       (setq short-opponent
  53             (if (> (length opponent) 25)
  54                 (save-match-data
  55                   (string-match " (pid [0-9]+)" opponent)
  56                   (concat (substring opponent 0 13) "..."
  57                           (match-string 0 opponent)))
  58               opponent))
  59       (while (null answer)
  60         (message "%s locked by %s: (s, q, p, ?)? "
  61                  short-file short-opponent)
  62         (let ((tem (let ((inhibit-quit t)
  63                          (cursor-in-echo-area t))
  64                      (prog1 (downcase (read-char))
  65                             (setq quit-flag nil)))))
  66           (if (= tem help-char)
  67               (ask-user-about-lock-help)
  68             (setq answer (assoc tem '((?s . t)
  69                                       (?q . yield)
  70                                       (?\C-g . yield)
  71                                       (?p . nil)
  72                                       (?? . help))))
  73             (cond ((null answer)
  74                    (beep)
  75                    (message "Please type q, s, or p; or ? for help")
  76                    (sit-for 3))
  77                   ((eq (cdr answer) 'help)
  78                    (ask-user-about-lock-help)
  79                    (setq answer nil))
  80                   ((eq (cdr answer) 'yield)
  81                    (signal 'file-locked (list file opponent)))))))
  82       (cdr answer))))
  83
  84 (defun ask-user-about-lock-help ()
  85   (with-output-to-temp-buffer "*Help*"
  86     (princ "It has been detected that you want to modify a file that someone else has
  87 already started modifying in Emacs.
  88
  89 You can <s>teal the file; the other user becomes the
  90   intruder if (s)he ever unmodifies the file and then changes it again.
  91 You can <p>roceed; you edit at your own (and the other user's) risk.
  92 You can <q>uit; don't modify this file.")
  93     (with-current-buffer standard-output
  94       (help-mode))))
  95
  96 (define-error 'file-supersession nil 'file-error)
  97
  98 ;;;###autoload
  99 (defun ask-user-about-supersession-threat (fn)
 100   "Ask a user who is about to modify an obsolete buffer what to do.
 101 This function has two choices: it can return, in which case the modification
 102 of the buffer will proceed, or it can (signal 'file-supersession (file)),
 103 in which case the proposed buffer modification will not be made.
 104
 105 You can rewrite this to use any criterion you like to choose which one to do.
 106 The buffer in question is current when this function is called."
 107   (discard-input)
 108   (save-window-excursion
 109     (let ((prompt
 110            (format "%s changed on disk; \
 111 really edit the buffer? (y, n, r or C-h) "
 112                    (file-name-nondirectory fn)))
 113           (choices '(?y ?n ?r ?? ?\C-h))
 114           answer)
 115       (while (null answer)
 116         (setq answer (read-char-choice prompt choices))
 117         (cond ((memq answer '(?? ?\C-h))
 118                (ask-user-about-supersession-help)
 119                (setq answer nil))
 120               ((eq answer ?r)
 121                ;; Ask for confirmation if buffer modified
 122                (revert-buffer nil (not (buffer-modified-p)))
 123                (signal 'file-supersession
 124                        (list "File reverted" fn)))
 125               ((eq answer ?n)
 126                (signal 'file-supersession
 127                        (list "File changed on disk" fn)))))
 128       (message
 129        "File on disk now will become a backup file if you save these changes.")
 130       (setq buffer-backed-up nil))))
 131
 132 (defun ask-user-about-supersession-help ()
 133   (with-output-to-temp-buffer "*Help*"
 134     (princ "You want to modify a buffer whose disk file has changed
 135 since you last read it in or saved it with this buffer.
 136
 137 If you say `y' to go ahead and modify this buffer,
 138 you risk ruining the work of whoever rewrote the file.
 139 If you say `r' to revert, the contents of the buffer are refreshed
 140 from the file on disk.
 141 If you say `n', the change you started to make will be aborted.
 142
 143 Usually, you should type `n' and then `M-x revert-buffer',
 144 to get the latest version of the file, then make the change again.")
 145     (with-current-buffer standard-output
 146       (help-mode))))
 147
 148 ;;; userlock.el ends here