lisp/gnus/sieve-manage.el

   1 ;;; sieve-manage.el --- Implementation of the managesieve protocol in elisp
   2
   3 ;; Copyright (C) 2001-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <simon@josefsson.org>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;; This library provides an elisp API for the managesieve network
  25 ;; protocol.
  26 ;;
  27 ;; It uses the SASL library for authentication, which means it
  28 ;; supports DIGEST-MD5, CRAM-MD5, SCRAM-MD5, NTLM, PLAIN and LOGIN
  29 ;; methods.  STARTTLS is not well tested, but should be easy to get to
  30 ;; work if someone wants.
  31 ;;
  32 ;; The API should be fairly obvious for anyone familiar with the
  33 ;; managesieve protocol, interface functions include:
  34 ;;
  35 ;; `sieve-manage-open'
  36 ;; open connection to managesieve server, returning a buffer to be
  37 ;; used by all other API functions.
  38 ;;
  39 ;; `sieve-manage-opened'
  40 ;; check if a server is open or not
  41 ;;
  42 ;; `sieve-manage-close'
  43 ;; close a server connection.
  44 ;;
  45 ;; `sieve-manage-listscripts'
  46 ;; `sieve-manage-deletescript'
  47 ;; `sieve-manage-getscript'
  48 ;; performs managesieve protocol actions
  49 ;;
  50 ;; and that's it.  Example of a managesieve session in *scratch*:
  51 ;;
  52 ;; (with-current-buffer (sieve-manage-open "mail.example.com")
  53 ;;   (sieve-manage-authenticate)
  54 ;;   (sieve-manage-listscripts))
  55 ;;
  56 ;; => ((active . "main") "vacation")
  57 ;;
  58 ;; References:
  59 ;;
  60 ;; draft-martin-managesieve-02.txt,
  61 ;; "A Protocol for Remotely Managing Sieve Scripts",
  62 ;; by Tim Martin.
  63 ;;
  64 ;; Release history:
  65 ;;
  66 ;; 2001-10-31 Committed to Oort Gnus.
  67 ;; 2002-07-27 Added DELETESCRIPT.  Suggested by Ned Ludd.
  68 ;; 2002-08-03 Use SASL library.
  69
  70 ;;; Code:
  71
  72 ;; For Emacs <22.2 and XEmacs.
  73 (eval-and-compile
  74   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  75
  76 (if (locate-library "password-cache")
  77     (require 'password-cache)
  78   (require 'password))
  79
  80 (eval-when-compile
  81   (require 'cl)                         ; caddr
  82   (require 'sasl)
  83   (require 'starttls))
  84 (autoload 'sasl-find-mechanism "sasl")
  85 (autoload 'starttls-open-stream "starttls")
  86 (autoload 'auth-source-search "auth-source")
  87
  88 ;; User customizable variables:
  89
  90 (defgroup sieve-manage nil
  91   "Low-level Managesieve protocol issues."
  92   :group 'mail
  93   :prefix "sieve-")
  94
  95 (defcustom sieve-manage-log "*sieve-manage-log*"
  96   "Name of buffer for managesieve session trace."
  97   :type 'string
  98   :group 'sieve-manage)
  99
 100 (defcustom sieve-manage-server-eol "\r\n"
 101   "The EOL string sent from the server."
 102   :type 'string
 103   :group 'sieve-manage)
 104
 105 (defcustom sieve-manage-client-eol "\r\n"
 106   "The EOL string we send to the server."
 107   :type 'string
 108   :group 'sieve-manage)
 109
 110 (defcustom sieve-manage-streams '(network starttls shell)
 111   "Priority of streams to consider when opening connection to server."
 112   :group 'sieve-manage)
 113
 114 (defcustom sieve-manage-stream-alist
 115   '((network   sieve-manage-network-p          sieve-manage-network-open)
 116     (shell     sieve-manage-shell-p            sieve-manage-shell-open)
 117     (starttls  sieve-manage-starttls-p         sieve-manage-starttls-open))
 118   "Definition of network streams.
 119
 120 \(NAME CHECK OPEN)
 121
 122 NAME names the stream, CHECK is a function returning non-nil if the
 123 server support the stream and OPEN is a function for opening the
 124 stream."
 125   :group 'sieve-manage)
 126
 127 (defcustom sieve-manage-authenticators '(digest-md5
 128                                          cram-md5
 129                                          scram-md5
 130                                          ntlm
 131                                          plain
 132                                          login)
 133   "Priority of authenticators to consider when authenticating to server."
 134   :group 'sieve-manage)
 135
 136 (defcustom sieve-manage-authenticator-alist
 137   '((cram-md5   sieve-manage-cram-md5-p       sieve-manage-cram-md5-auth)
 138     (digest-md5 sieve-manage-digest-md5-p     sieve-manage-digest-md5-auth)
 139     (scram-md5  sieve-manage-scram-md5-p      sieve-manage-scram-md5-auth)
 140     (ntlm       sieve-manage-ntlm-p           sieve-manage-ntlm-auth)
 141     (plain      sieve-manage-plain-p          sieve-manage-plain-auth)
 142     (login      sieve-manage-login-p          sieve-manage-login-auth))
 143   "Definition of authenticators.
 144
 145 \(NAME CHECK AUTHENTICATE)
 146
 147 NAME names the authenticator.  CHECK is a function returning non-nil if
 148 the server support the authenticator and AUTHENTICATE is a function
 149 for doing the actual authentication."
 150   :group 'sieve-manage)
 151
 152 (defcustom sieve-manage-default-port 2000
 153   "Default port number or service name for managesieve protocol."
 154   :type 'integer
 155   :group 'sieve-manage)
 156
 157 (defcustom sieve-manage-default-stream 'network
 158   "Default stream type to use for `sieve-manage'.
 159 Must be a name of a stream in `sieve-manage-stream-alist'."
 160   :type 'symbol
 161   :group 'sieve-manage)
 162
 163 ;; Internal variables:
 164
 165 (defconst sieve-manage-local-variables '(sieve-manage-server
 166                                          sieve-manage-port
 167                                          sieve-manage-auth
 168                                          sieve-manage-stream
 169                                          sieve-manage-process
 170                                          sieve-manage-client-eol
 171                                          sieve-manage-server-eol
 172                                          sieve-manage-capability))
 173 (defconst sieve-manage-coding-system-for-read 'binary)
 174 (defconst sieve-manage-coding-system-for-write 'binary)
 175 (defvar sieve-manage-stream nil)
 176 (defvar sieve-manage-auth nil)
 177 (defvar sieve-manage-server nil)
 178 (defvar sieve-manage-port nil)
 179 (defvar sieve-manage-state 'closed
 180   "Managesieve state.
 181 Valid states are `closed', `initial', `nonauth', and `auth'.")
 182 (defvar sieve-manage-process nil)
 183 (defvar sieve-manage-capability nil)
 184
 185 ;; Internal utility functions
 186
 187 (defmacro sieve-manage-disable-multibyte ()
 188   "Enable multibyte in the current buffer."
 189   (unless (featurep 'xemacs)
 190     '(set-buffer-multibyte nil)))
 191
 192 (defun sieve-manage-erase (&optional p buffer)
 193   (let ((buffer (or buffer (current-buffer))))
 194     (and sieve-manage-log
 195          (with-current-buffer (get-buffer-create sieve-manage-log)
 196            (sieve-manage-disable-multibyte)
 197            (buffer-disable-undo)
 198            (goto-char (point-max))
 199            (insert-buffer-substring buffer (with-current-buffer buffer
 200                                              (point-min))
 201                                     (or p (with-current-buffer buffer
 202                                             (point-max)))))))
 203   (delete-region (point-min) (or p (point-max))))
 204
 205 (defun sieve-manage-open-1 (buffer)
 206   (with-current-buffer buffer
 207     (sieve-manage-erase)
 208     (setq sieve-manage-state 'initial
 209           sieve-manage-process
 210           (condition-case ()
 211               (funcall (nth 2 (assq sieve-manage-stream
 212                                     sieve-manage-stream-alist))
 213                        "sieve" buffer sieve-manage-server sieve-manage-port)
 214             ((error quit) nil)))
 215     (when sieve-manage-process
 216       (while (and (eq sieve-manage-state 'initial)
 217                   (memq (process-status sieve-manage-process) '(open run)))
 218         (message "Waiting for response from %s..." sieve-manage-server)
 219         (accept-process-output sieve-manage-process 1))
 220       (message "Waiting for response from %s...done" sieve-manage-server)
 221       (and (memq (process-status sieve-manage-process) '(open run))
 222            sieve-manage-process))))
 223
 224 ;; Streams
 225
 226 (defun sieve-manage-network-p (buffer)
 227   t)
 228
 229 (defun sieve-manage-network-open (name buffer server port)
 230   (let* ((port (or port sieve-manage-default-port))
 231          (coding-system-for-read sieve-manage-coding-system-for-read)
 232          (coding-system-for-write sieve-manage-coding-system-for-write)
 233          (process (open-network-stream name buffer server port)))
 234     (when process
 235       (while (and (memq (process-status process) '(open run))
 236                   (set-buffer buffer) ;; XXX "blue moon" nntp.el bug
 237                   (goto-char (point-min))
 238                   (not (sieve-manage-parse-greeting-1)))
 239         (accept-process-output process 1)
 240         (sit-for 1))
 241       (sieve-manage-erase nil buffer)
 242       (when (memq (process-status process) '(open run))
 243         process))))
 244
 245 (defun sieve-manage-starttls-p (buffer)
 246   (condition-case ()
 247       (progn
 248         (require 'starttls)
 249         (call-process "starttls"))
 250     (error nil)))
 251
 252 (defun sieve-manage-starttls-open (name buffer server port)
 253   (let* ((port (or port sieve-manage-default-port))
 254          (coding-system-for-read sieve-manage-coding-system-for-read)
 255          (coding-system-for-write sieve-manage-coding-system-for-write)
 256          (process (starttls-open-stream name buffer server port))
 257          done)
 258     (when process
 259       (while (and (memq (process-status process) '(open run))
 260                   (set-buffer buffer) ;; XXX "blue moon" nntp.el bug
 261                   (goto-char (point-min))
 262                   (not (sieve-manage-parse-greeting-1)))
 263         (accept-process-output process 1)
 264         (sit-for 1))
 265       (sieve-manage-erase nil buffer)
 266       (sieve-manage-send "STARTTLS")
 267       (starttls-negotiate process))
 268     (when (memq (process-status process) '(open run))
 269       process)))
 270
 271 ;; Authenticators
 272 (defun sieve-sasl-auth (buffer mech)
 273   "Login to server using the SASL MECH method."
 274   (message "sieve: Authenticating using %s..." mech)
 275   (with-current-buffer buffer
 276     (let* ((auth-info (auth-source-search :host sieve-manage-server
 277                                           :port "sieve"
 278                                           :max 1
 279                                           :create t))
 280            (user-name (or (plist-get (nth 0 auth-info) :user) ""))
 281            (user-password (or (plist-get (nth 0 auth-info) :secret) ""))
 282            (user-password (if (functionp user-password)
 283                               (funcall user-password)
 284                             user-password))
 285            (client (sasl-make-client (sasl-find-mechanism (list mech))
 286                                      user-name "sieve" sieve-manage-server))
 287            (sasl-read-passphrase
 288             ;; We *need* to copy the password, because sasl will modify it
 289             ;; somehow.
 290             `(lambda (prompt) ,(copy-sequence user-password)))
 291            (step (sasl-next-step client nil))
 292            (tag (sieve-manage-send
 293                  (concat
 294                   "AUTHENTICATE \""
 295                   mech
 296                   "\""
 297                   (and (sasl-step-data step)
 298                        (concat
 299                         " \""
 300                         (base64-encode-string
 301                          (sasl-step-data step)
 302                          'no-line-break)
 303                         "\"")))))
 304            data rsp)
 305       (catch 'done
 306         (while t
 307           (setq rsp nil)
 308           (goto-char (point-min))
 309           (while (null (or (progn
 310                              (setq rsp (sieve-manage-is-string))
 311                              (if (not (and rsp (looking-at
 312                                                 sieve-manage-server-eol)))
 313                                  (setq rsp nil)
 314                                (goto-char (match-end 0))
 315                                rsp))
 316                            (setq rsp (sieve-manage-is-okno))))
 317             (accept-process-output sieve-manage-process 1)
 318             (goto-char (point-min)))
 319           (sieve-manage-erase)
 320           (when (sieve-manage-ok-p rsp)
 321             (when (and (cadr rsp)
 322                        (string-match "^SASL \"\\([^\"]+\\)\"" (cadr rsp)))
 323               (sasl-step-set-data
 324                step (base64-decode-string (match-string 1 (cadr rsp)))))
 325             (if (and (setq step (sasl-next-step client step))
 326                      (setq data (sasl-step-data step)))
 327                 ;; We got data for server but it's finished
 328                 (error "Server not ready for SASL data: %s" data)
 329               ;; The authentication process is finished.
 330               (throw 'done t)))
 331           (unless (stringp rsp)
 332             (error "Server aborted SASL authentication: %s" (caddr rsp)))
 333           (sasl-step-set-data step (base64-decode-string rsp))
 334           (setq step (sasl-next-step client step))
 335           (sieve-manage-send
 336            (if (sasl-step-data step)
 337                (concat "\""
 338                        (base64-encode-string (sasl-step-data step)
 339                                              'no-line-break)
 340                        "\"")
 341              ""))))
 342       (message "sieve: Login using %s...done" mech))))
 343
 344 (defun sieve-manage-cram-md5-p (buffer)
 345   (sieve-manage-capability "SASL" "CRAM-MD5" buffer))
 346
 347 (defun sieve-manage-cram-md5-auth (buffer)
 348   "Login to managesieve server using the CRAM-MD5 SASL method."
 349   (sieve-sasl-auth buffer "CRAM-MD5"))
 350
 351 (defun sieve-manage-digest-md5-p (buffer)
 352   (sieve-manage-capability "SASL" "DIGEST-MD5" buffer))
 353
 354 (defun sieve-manage-digest-md5-auth (buffer)
 355   "Login to managesieve server using the DIGEST-MD5 SASL method."
 356   (sieve-sasl-auth buffer "DIGEST-MD5"))
 357
 358 (defun sieve-manage-scram-md5-p (buffer)
 359   (sieve-manage-capability "SASL" "SCRAM-MD5" buffer))
 360
 361 (defun sieve-manage-scram-md5-auth (buffer)
 362   "Login to managesieve server using the SCRAM-MD5 SASL method."
 363   (sieve-sasl-auth buffer "SCRAM-MD5"))
 364
 365 (defun sieve-manage-ntlm-p (buffer)
 366   (sieve-manage-capability "SASL" "NTLM" buffer))
 367
 368 (defun sieve-manage-ntlm-auth (buffer)
 369   "Login to managesieve server using the NTLM SASL method."
 370   (sieve-sasl-auth buffer "NTLM"))
 371
 372 (defun sieve-manage-plain-p (buffer)
 373   (sieve-manage-capability "SASL" "PLAIN" buffer))
 374
 375 (defun sieve-manage-plain-auth (buffer)
 376   "Login to managesieve server using the PLAIN SASL method."
 377   (sieve-sasl-auth buffer "PLAIN"))
 378
 379 (defun sieve-manage-login-p (buffer)
 380   (sieve-manage-capability "SASL" "LOGIN" buffer))
 381
 382 (defun sieve-manage-login-auth (buffer)
 383   "Login to managesieve server using the LOGIN SASL method."
 384   (sieve-sasl-auth buffer "LOGIN"))
 385
 386 ;; Managesieve API
 387
 388 (defun sieve-manage-open (server &optional port stream auth buffer)
 389   "Open a network connection to a managesieve SERVER (string).
 390 Optional argument PORT is port number (integer) on remote server.
 391 Optional argument STREAM is any of `sieve-manage-streams' (a symbol).
 392 Optional argument AUTH indicates authenticator to use, see
 393 `sieve-manage-authenticators' for available authenticators.
 394 If nil, chooses the best stream the server is capable of.
 395 Optional argument BUFFER is buffer (buffer, or string naming buffer)
 396 to work in."
 397   (or port (setq port sieve-manage-default-port))
 398   (setq buffer (or buffer (format " *sieve* %s:%s" server port)))
 399   (with-current-buffer (get-buffer-create buffer)
 400     (mapc 'make-local-variable sieve-manage-local-variables)
 401     (sieve-manage-disable-multibyte)
 402     (buffer-disable-undo)
 403     (setq sieve-manage-server (or server sieve-manage-server))
 404     (setq sieve-manage-port port)
 405     (setq sieve-manage-stream (or stream sieve-manage-stream))
 406     (message "sieve: Connecting to %s..." sieve-manage-server)
 407     (if (let ((sieve-manage-stream
 408                (or sieve-manage-stream sieve-manage-default-stream)))
 409           (sieve-manage-open-1 buffer))
 410         ;; Choose stream.
 411         (let (stream-changed)
 412           (message "sieve: Connecting to %s...done" sieve-manage-server)
 413           (when (null sieve-manage-stream)
 414             (let ((streams sieve-manage-streams))
 415               (while (setq stream (pop streams))
 416                 (if (funcall (nth 1 (assq stream
 417                                           sieve-manage-stream-alist)) buffer)
 418                     (setq stream-changed
 419                           (not (eq (or sieve-manage-stream
 420                                        sieve-manage-default-stream)
 421                                    stream))
 422                           sieve-manage-stream stream
 423                           streams nil)))
 424               (unless sieve-manage-stream
 425                 (error "Couldn't figure out a stream for server"))))
 426           (when stream-changed
 427             (message "sieve: Reconnecting with stream `%s'..."
 428                      sieve-manage-stream)
 429             (sieve-manage-close buffer)
 430             (if (sieve-manage-open-1 buffer)
 431                 (message "sieve: Reconnecting with stream `%s'...done"
 432                          sieve-manage-stream)
 433               (message "sieve: Reconnecting with stream `%s'...failed"
 434                        sieve-manage-stream))
 435             (setq sieve-manage-capability nil))
 436           (if (sieve-manage-opened buffer)
 437               ;; Choose authenticator
 438               (when (and (null sieve-manage-auth)
 439                          (not (eq sieve-manage-state 'auth)))
 440                 (let ((auths sieve-manage-authenticators))
 441                   (while (setq auth (pop auths))
 442                     (if (funcall (nth 1 (assq
 443                                          auth
 444                                          sieve-manage-authenticator-alist))
 445                                  buffer)
 446                         (setq sieve-manage-auth auth
 447                               auths nil)))
 448                   (unless sieve-manage-auth
 449                     (error "Couldn't figure out authenticator for server"))))))
 450       (message "sieve: Connecting to %s...failed" sieve-manage-server))
 451     (when (sieve-manage-opened buffer)
 452       (sieve-manage-erase)
 453       buffer)))
 454
 455 (defun sieve-manage-authenticate (&optional buffer)
 456   "Authenticate on server in BUFFER.
 457 Return `sieve-manage-state' value."
 458   (with-current-buffer (or buffer (current-buffer))
 459     (if (eq sieve-manage-state 'nonauth)
 460         (when (funcall (nth 2 (assq sieve-manage-auth
 461                                     sieve-manage-authenticator-alist))
 462                        (current-buffer))
 463           (setq sieve-manage-state 'auth))
 464       sieve-manage-state)))
 465
 466 (defun sieve-manage-opened (&optional buffer)
 467   "Return non-nil if connection to managesieve server in BUFFER is open.
 468 If BUFFER is nil then the current buffer is used."
 469   (and (setq buffer (get-buffer (or buffer (current-buffer))))
 470        (buffer-live-p buffer)
 471        (with-current-buffer buffer
 472          (and sieve-manage-process
 473               (memq (process-status sieve-manage-process) '(open run))))))
 474
 475 (defun sieve-manage-close (&optional buffer)
 476   "Close connection to managesieve server in BUFFER.
 477 If BUFFER is nil, the current buffer is used."
 478   (with-current-buffer (or buffer (current-buffer))
 479     (when (sieve-manage-opened)
 480       (sieve-manage-send "LOGOUT")
 481       (sit-for 1))
 482     (when (and sieve-manage-process
 483                (memq (process-status sieve-manage-process) '(open run)))
 484       (delete-process sieve-manage-process))
 485     (setq sieve-manage-process nil)
 486     (sieve-manage-erase)
 487     t))
 488
 489 (defun sieve-manage-capability (&optional name value buffer)
 490   "Check if capability NAME of server BUFFER match VALUE.
 491 If it does, return the server value of NAME. If not returns nil.
 492 If VALUE is nil, do not check VALUE and return server value.
 493 If NAME is nil, return the full server list of capabilities."
 494   (with-current-buffer (or buffer (current-buffer))
 495     (if (null name)
 496         sieve-manage-capability
 497       (let ((server-value (cadr (assoc name sieve-manage-capability))))
 498         (when (or (null value)
 499                   (and server-value
 500                        (string-match value server-value)))
 501           server-value)))))
 502
 503 (defun sieve-manage-listscripts (&optional buffer)
 504   (with-current-buffer (or buffer (current-buffer))
 505     (sieve-manage-send "LISTSCRIPTS")
 506     (sieve-manage-parse-listscripts)))
 507
 508 (defun sieve-manage-havespace (name size &optional buffer)
 509   (with-current-buffer (or buffer (current-buffer))
 510     (sieve-manage-send (format "HAVESPACE \"%s\" %s" name size))
 511     (sieve-manage-parse-okno)))
 512
 513 (defun sieve-manage-putscript (name content &optional buffer)
 514   (with-current-buffer (or buffer (current-buffer))
 515     (sieve-manage-send (format "PUTSCRIPT \"%s\" {%d+}%s%s" name
 516                                ;; Here we assume that the coding-system will
 517                                ;; replace each char with a single byte.
 518                                ;; This is always the case if `content' is
 519                                ;; a unibyte string.
 520                                (length content)
 521                                sieve-manage-client-eol content))
 522     (sieve-manage-parse-okno)))
 523
 524 (defun sieve-manage-deletescript (name &optional buffer)
 525   (with-current-buffer (or buffer (current-buffer))
 526     (sieve-manage-send (format "DELETESCRIPT \"%s\"" name))
 527     (sieve-manage-parse-okno)))
 528
 529 (defun sieve-manage-getscript (name output-buffer &optional buffer)
 530   (with-current-buffer (or buffer (current-buffer))
 531     (sieve-manage-send (format "GETSCRIPT \"%s\"" name))
 532     (let ((script (sieve-manage-parse-string)))
 533       (sieve-manage-parse-crlf)
 534       (with-current-buffer output-buffer
 535         (insert script))
 536       (sieve-manage-parse-okno))))
 537
 538 (defun sieve-manage-setactive (name &optional buffer)
 539   (with-current-buffer (or buffer (current-buffer))
 540     (sieve-manage-send (format "SETACTIVE \"%s\"" name))
 541     (sieve-manage-parse-okno)))
 542
 543 ;; Protocol parsing routines
 544
 545 (defun sieve-manage-ok-p (rsp)
 546   (string= (downcase (or (car-safe rsp) "")) "ok"))
 547
 548 (defsubst sieve-manage-forward ()
 549   (or (eobp) (forward-char)))
 550
 551 (defun sieve-manage-is-okno ()
 552   (when (looking-at (concat
 553                      "^\\(OK\\|NO\\)\\( (\\([^)]+\\))\\)?\\( \\(.*\\)\\)?"
 554                      sieve-manage-server-eol))
 555     (let ((status (match-string 1))
 556           (resp-code (match-string 3))
 557           (response (match-string 5)))
 558       (when response
 559         (goto-char (match-beginning 5))
 560         (setq response (sieve-manage-is-string)))
 561       (list status resp-code response))))
 562
 563 (defun sieve-manage-parse-okno ()
 564   (let (rsp)
 565     (while (null rsp)
 566       (accept-process-output (get-buffer-process (current-buffer)) 1)
 567       (goto-char (point-min))
 568       (setq rsp (sieve-manage-is-okno)))
 569     (sieve-manage-erase)
 570     rsp))
 571
 572 (defun sieve-manage-parse-capability-1 ()
 573   "Accept a managesieve greeting."
 574   (let (str)
 575     (while (setq str (sieve-manage-is-string))
 576       (if (eq (char-after) ? )
 577           (progn
 578             (sieve-manage-forward)
 579             (push (list str (sieve-manage-is-string))
 580                   sieve-manage-capability))
 581         (push (list str) sieve-manage-capability))
 582       (forward-line)))
 583   (when (re-search-forward (concat "^OK.*" sieve-manage-server-eol) nil t)
 584     (setq sieve-manage-state 'nonauth)))
 585
 586 (defalias 'sieve-manage-parse-greeting-1 'sieve-manage-parse-capability-1)
 587
 588 (defun sieve-manage-is-string ()
 589   (cond ((looking-at "\"\\([^\"]+\\)\"")
 590          (prog1
 591              (match-string 1)
 592            (goto-char (match-end 0))))
 593         ((looking-at (concat "{\\([0-9]+\\+?\\)}" sieve-manage-server-eol))
 594          (let ((pos (match-end 0))
 595                (len (string-to-number (match-string 1))))
 596            (if (< (point-max) (+ pos len))
 597                nil
 598              (goto-char (+ pos len))
 599              (buffer-substring pos (+ pos len)))))))
 600
 601 (defun sieve-manage-parse-string ()
 602   (let (rsp)
 603     (while (null rsp)
 604       (accept-process-output (get-buffer-process (current-buffer)) 1)
 605       (goto-char (point-min))
 606       (setq rsp (sieve-manage-is-string)))
 607     (sieve-manage-erase (point))
 608     rsp))
 609
 610 (defun sieve-manage-parse-crlf ()
 611   (when (looking-at sieve-manage-server-eol)
 612     (sieve-manage-erase (match-end 0))))
 613
 614 (defun sieve-manage-parse-listscripts ()
 615   (let (tmp rsp data)
 616     (while (null rsp)
 617       (while (null (or (setq rsp (sieve-manage-is-okno))
 618                        (setq tmp (sieve-manage-is-string))))
 619         (accept-process-output (get-buffer-process (current-buffer)) 1)
 620         (goto-char (point-min)))
 621       (when tmp
 622         (while (not (looking-at (concat "\\( ACTIVE\\)?"
 623                                         sieve-manage-server-eol)))
 624           (accept-process-output (get-buffer-process (current-buffer)) 1)
 625           (goto-char (point-min)))
 626         (if (match-string 1)
 627             (push (cons 'active tmp) data)
 628           (push tmp data))
 629         (goto-char (match-end 0))
 630         (setq tmp nil)))
 631     (sieve-manage-erase)
 632     (if (sieve-manage-ok-p rsp)
 633         data
 634       rsp)))
 635
 636 (defun sieve-manage-send (cmdstr)
 637   (setq cmdstr (concat cmdstr sieve-manage-client-eol))
 638   (and sieve-manage-log
 639        (with-current-buffer (get-buffer-create sieve-manage-log)
 640          (sieve-manage-disable-multibyte)
 641          (buffer-disable-undo)
 642          (goto-char (point-max))
 643          (insert cmdstr)))
 644   (process-send-string sieve-manage-process cmdstr))
 645
 646 (provide 'sieve-manage)
 647
 648 ;; sieve-manage.el ends here