lisp/saveplace.el

   1 ;;; saveplace.el --- automatically save place in files.
   2
   3 ;; Copyright (C) 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Karl Fogel <kfogel@cs.oberlin.edu>
   6 ;; Maintainer: FSF
   7 ;; Created: July, 1993
   8 ;; Version: 1.2
   9 ;; Keywords: bookmarks, placeholders
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; Automatically save place in files, so that visiting them later
  31 ;; (even during a different Emacs session) automatically moves point
  32 ;; to the saved position, when the file is first found.  Uses the
  33 ;; value of buffer-local variable save-place to determine whether to
  34 ;; save position or not.
  35 ;;
  36 ;; Thanks to Stefan Schoef, who sent a patch with the
  37 ;; `save-place-version-control' stuff in it.
  38
  39 ;;; Code:
  40
  41 ;; this is what I was using during testing:
  42 ;; (define-key ctl-x-map "p" 'toggle-save-place)
  43
  44 (defvar save-place-alist nil
  45   "Alist of saved places to go back to when revisiting files.
  46 Each element looks like (FILENAME . POSITION);
  47 visiting file FILENAME goes automatically to position POSITION
  48 rather than the beginning of the buffer.
  49 This alist is saved between Emacs sessions.")
  50
  51 (defvar save-place nil
  52   "*Non-nil means automatically save place in each file.
  53 This means when you visit a file, point goes to the last place
  54 where it was when you previously visited the same file.
  55 This variable is automatically buffer-local.
  56
  57 If you wish your place in any file to always be automatically saved,
  58 simply put this in your `~/.emacs' file:
  59
  60 \(setq-default save-place t\)")
  61
  62 (make-variable-buffer-local 'save-place)
  63
  64 (defvar save-place-file (convert-standard-filename "~/.emacs-places")
  65   "*Name of the file that records `save-place-alist' value.")
  66
  67 (defvar save-place-version-control 'nospecial
  68   "*Controls whether to make numbered backups of master save-place file.
  69 It can have four values: t, nil, `never', and `nospecial'.  The first
  70 three have the same meaning that they do for the variable
  71 `version-control', and the final value `nospecial' means just use the
  72 value of `version-control'.")
  73
  74 (defvar save-place-loaded nil
  75   "Non-nil means that the `save-place-file' has been loaded.")
  76
  77 (defvar save-place-limit nil
  78   "Maximum number of entries to retain in the list; nil means no limit.")
  79
  80 (defun toggle-save-place (&optional parg)
  81   "Toggle whether to save your place in this file between sessions.
  82 If this mode is enabled, point is recorded when you kill the buffer
  83 or exit Emacs.  Visiting this file again will go to that position,
  84 even in a later Emacs session.
  85
  86 If called with a prefix arg, the mode is enabled if and only if
  87 the argument is positive.
  88
  89 To save places automatically in all files, put this in your `.emacs' file:
  90
  91 \(setq-default save-place t\)"
  92   (interactive "P")
  93   (if (not buffer-file-name)
  94       (message "Buffer `%s' not visiting a file" (buffer-name))
  95     (if (and save-place (or (not parg) (<= parg 0)))
  96         (progn
  97           (message "No place will be saved in this file")
  98           (setq save-place nil))
  99       (message "Place will be saved")
 100       (setq save-place t))))
 101
 102 (defun save-place-to-alist ()
 103   ;; put filename and point in a cons box and then cons that onto the
 104   ;; front of the save-place-alist, if save-place is non-nil.
 105   ;; Otherwise, just delete that file from the alist.
 106   ;; first check to make sure alist has been loaded in from the master
 107   ;; file.  If not, do so, then feel free to modify the alist.  It
 108   ;; will be saved again when Emacs is killed.
 109   (or save-place-loaded (load-save-place-alist-from-file))
 110   (if buffer-file-name
 111       (progn
 112         (let ((cell (assoc buffer-file-name save-place-alist)))
 113           (if cell
 114               (setq save-place-alist (delq cell save-place-alist))))
 115         (if save-place
 116             (setq save-place-alist
 117                   (cons (cons buffer-file-name
 118                               (if (not (eq major-mode 'hexl-mode))
 119                                   (point)
 120                                 (1+ (hexl-current-address))))
 121                         save-place-alist))))))
 122
 123 (defun save-place-alist-to-file ()
 124   (let ((file (expand-file-name save-place-file)))
 125     (save-excursion
 126       (message "Saving places to %s..." file)
 127       (set-buffer (get-buffer-create " *Saved Places*"))
 128       (delete-region (point-min) (point-max))
 129       (if (file-readable-p file)
 130           (insert-file-contents file))
 131       (delete-region (point-min) (point-max))
 132       (goto-char (point-min))
 133       (print save-place-alist (current-buffer))
 134       (let ((version-control
 135              (cond
 136               ((null save-place-version-control) nil)
 137               ((eq 'never save-place-version-control) 'never)
 138               ((eq 'nospecial save-place-version-control) version-control)
 139               (t
 140                t))))
 141         (write-file file)
 142         (kill-buffer (current-buffer))
 143         (message "Saving places to %s...done" file)))))
 144
 145 (defun load-save-place-alist-from-file ()
 146   (if (not save-place-loaded)
 147       (progn
 148         (setq save-place-loaded t)
 149         (let ((file (expand-file-name save-place-file)))
 150           ;; make sure that the alist does not get overwritten, and then
 151           ;; load it if it exists:
 152           (if (file-readable-p file)
 153               (save-excursion
 154                 (message "Loading places from %s..." save-place-file)
 155                 ;; don't want to use find-file because we have been
 156                 ;; adding hooks to it.
 157                 (set-buffer (get-buffer-create " *Saved Places*"))
 158                 (delete-region (point-min) (point-max))
 159                 (insert-file-contents file)
 160                 (goto-char (point-min))
 161                 (setq save-place-alist
 162                       (car (read-from-string
 163                             (buffer-substring (point-min) (point-max)))))
 164
 165                 ;; If there is a limit, and we're over it, then we'll
 166                 ;; have to truncate the end of the list:
 167                 (if save-place-limit
 168                     (if (<= save-place-limit 0)
 169                         ;; Zero gets special cased.  I'm not thrilled
 170                         ;; with this, but the loop for >= 1 is tight.
 171                         (setq save-place-alist nil)
 172                       ;; Else the limit is >= 1, so enforce it by
 173                       ;; counting and then `setcdr'ing.
 174                       (let ((s save-place-alist)
 175                             (count 1))
 176                         (while s
 177                           (if (>= count save-place-limit)
 178                               (setcdr s nil)
 179                             (setq count (1+ count)))
 180                           (setq s (cdr s))))))
 181
 182                 (kill-buffer (current-buffer))
 183                 (message "Loading places from %s...done" file)
 184                 t)
 185             t)
 186           nil))))
 187
 188 (defun save-places-to-alist ()
 189   ;; go through buffer-list, saving places to alist if save-place is
 190   ;; non-nil, deleting them from alist if it is nil.
 191   (let ((buf-list (buffer-list)))
 192     (while buf-list
 193       ;; put this into a save-excursion in case someone is counting on
 194       ;; another function in kill-emacs-hook to act on the last buffer
 195       ;; they were in:
 196       (save-excursion
 197         (set-buffer (car buf-list))
 198         ;; save-place checks buffer-file-name too, but we can avoid
 199         ;; overhead of function call by checking here too.
 200         (and buffer-file-name (save-place-to-alist))
 201         (setq buf-list (cdr buf-list))))))
 202
 203 (defun save-place-find-file-hook ()
 204   (or save-place-loaded (load-save-place-alist-from-file))
 205   (let ((cell (assoc buffer-file-name save-place-alist)))
 206     (if cell
 207         (progn
 208           (or after-find-file-from-revert-buffer
 209               (goto-char (cdr cell)))
 210           ;; and make sure it will be saved again for later
 211           (setq save-place t)))))
 212
 213 (defun save-place-kill-emacs-hook ()
 214   (if save-place-loaded
 215       (progn
 216         (save-places-to-alist)
 217         (save-place-alist-to-file))))
 218
 219 (add-hook 'find-file-hooks 'save-place-find-file-hook t)
 220
 221 (add-hook 'kill-emacs-hook 'save-place-kill-emacs-hook)
 222
 223 (add-hook 'kill-buffer-hook 'save-place-to-alist)
 224
 225 (provide 'saveplace) ; why not...
 226
 227 ;;; saveplace.el ends here
 228