lisp/xml.el

   1 ;;; xml.el --- XML parser
   2
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Emmanuel Briot  <briot@gnat.com>
   7 ;; Maintainer: Mark A. Hershberger <mah@everybody.org>
   8 ;; Keywords: xml, data
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This file contains a somewhat incomplete non-validating XML parser.  It
  30 ;; parses a file, and returns a list that can be used internally by
  31 ;; any other Lisp libraries.
  32
  33 ;;; FILE FORMAT
  34
  35 ;; The document type declaration may either be ignored or (optionally)
  36 ;; parsed, but currently the parsing will only accept element
  37 ;; declarations.  The XML file is assumed to be well-formed.  In case
  38 ;; of error, the parsing stops and the XML file is shown where the
  39 ;; parsing stopped.
  40 ;;
  41 ;; It also knows how to ignore comments and processing instructions.
  42 ;;
  43 ;; The XML file should have the following format:
  44 ;;    <node1 attr1="name1" attr2="name2" ...>value
  45 ;;       <node2 attr3="name3" attr4="name4">value2</node2>
  46 ;;       <node3 attr5="name5" attr6="name6">value3</node3>
  47 ;;    </node1>
  48 ;; Of course, the name of the nodes and attributes can be anything.  There can
  49 ;; be any number of attributes (or none), as well as any number of children
  50 ;; below the nodes.
  51 ;;
  52 ;; There can be only top level node, but with any number of children below.
  53
  54 ;;; LIST FORMAT
  55
  56 ;; The functions `xml-parse-file', `xml-parse-region' and
  57 ;; `xml-parse-tag' return a list with the following format:
  58 ;;
  59 ;;    xml-list   ::= (node node ...)
  60 ;;    node       ::= (qname attribute-list . child_node_list)
  61 ;;    child_node_list ::= child_node child_node ...
  62 ;;    child_node ::= node | string
  63 ;;    qname      ::= (:namespace-uri . "name") | "name"
  64 ;;    attribute_list ::= ((qname . "value") (qname . "value") ...)
  65 ;;                       | nil
  66 ;;    string     ::= "..."
  67 ;;
  68 ;; Some macros are provided to ease the parsing of this list.
  69 ;; Whitespace is preserved.  Fixme: There should be a tree-walker that
  70 ;; can remove it.
  71
  72 ;; TODO:
  73 ;;  * xml:base, xml:space support
  74 ;;  * more complete DOCTYPE parsing
  75 ;;  * pi support
  76
  77 ;;; Code:
  78
  79 ;; Note that {buffer-substring,match-string}-no-properties were
  80 ;; formerly used in several places, but that removes composition info.
  81
  82 ;;*******************************************************************
  83 ;;**
  84 ;;**  Macros to parse the list
  85 ;;**
  86 ;;*******************************************************************
  87
  88 (defconst xml-undefined-entity "?"
  89   "What to substitute for undefined entities")
  90
  91 (defvar xml-entity-alist
  92   '(("lt"   . "<")
  93     ("gt"   . ">")
  94     ("apos" . "'")
  95     ("quot" . "\"")
  96     ("amp"  . "&"))
  97   "The defined entities.  Entities are added to this when the DTD is parsed.")
  98
  99 (defvar xml-sub-parser nil
 100   "Dynamically set this to a non-nil value if you want to parse an XML fragment.")
 101
 102 (defvar xml-validating-parser nil
 103   "Set to non-nil to get validity checking.")
 104
 105 (defsubst xml-node-name (node)
 106   "Return the tag associated with NODE.
 107 Without namespace-aware parsing, the tag is a symbol.
 108
 109 With namespace-aware parsing, the tag is a cons of a string
 110 representing the uri of the namespace with the local name of the
 111 tag.  For example,
 112
 113     <foo>
 114
 115 would be represented by
 116
 117     '(\"\" . \"foo\")."
 118
 119   (car node))
 120
 121 (defsubst xml-node-attributes (node)
 122   "Return the list of attributes of NODE.
 123 The list can be nil."
 124   (nth 1 node))
 125
 126 (defsubst xml-node-children (node)
 127   "Return the list of children of NODE.
 128 This is a list of nodes, and it can be nil."
 129   (cddr node))
 130
 131 (defun xml-get-children (node child-name)
 132   "Return the children of NODE whose tag is CHILD-NAME.
 133 CHILD-NAME should match the value returned by `xml-node-name'."
 134   (let ((match ()))
 135     (dolist (child (xml-node-children node))
 136       (if (and (listp child)
 137                (equal (xml-node-name child) child-name))
 138           (push child match)))
 139     (nreverse match)))
 140
 141 (defun xml-get-attribute-or-nil (node attribute)
 142   "Get from NODE the value of ATTRIBUTE.
 143 Return nil if the attribute was not found.
 144
 145 See also `xml-get-attribute'."
 146   (cdr (assoc attribute (xml-node-attributes node))))
 147
 148 (defsubst xml-get-attribute (node attribute)
 149   "Get from NODE the value of ATTRIBUTE.
 150 An empty string is returned if the attribute was not found.
 151
 152 See also `xml-get-attribute-or-nil'."
 153   (or (xml-get-attribute-or-nil node attribute) ""))
 154
 155 ;;*******************************************************************
 156 ;;**
 157 ;;**  Creating the list
 158 ;;**
 159 ;;*******************************************************************
 160
 161 ;;;###autoload
 162 (defun xml-parse-file (file &optional parse-dtd parse-ns)
 163   "Parse the well-formed XML file FILE.
 164 If FILE is already visited, use its buffer and don't kill it.
 165 Returns the top node with all its children.
 166 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped.
 167 If PARSE-NS is non-nil, then QNAMES are expanded."
 168   (let ((keep))
 169     (if (get-file-buffer file)
 170         (progn
 171           (set-buffer (get-file-buffer file))
 172           (setq keep (point)))
 173       (let (auto-mode-alist)            ; no need for xml-mode
 174         (find-file file)))
 175
 176     (let ((xml (xml-parse-region (point-min)
 177                                  (point-max)
 178                                  (current-buffer)
 179                                  parse-dtd parse-ns)))
 180       (if keep
 181           (goto-char keep)
 182         (kill-buffer (current-buffer)))
 183       xml)))
 184
 185
 186 (defvar xml-name-re)
 187 (defvar xml-entity-value-re)
 188 (defvar xml-att-def-re)
 189 (let* ((start-chars (concat "[:alpha:]:_"))
 190        (name-chars  (concat "-[:digit:]." start-chars))
 191        ;;[3]    S          ::=          (#x20 | #x9 | #xD | #xA)+
 192        (whitespace  "[ \t\n\r]"))
 193   ;;[4] NameStartChar ::= ":" | [A-Z] | "_" | [a-z] | [#xC0-#xD6]
 194   ;;                      | [#xD8-#xF6] | [#xF8-#x2FF] | [#x370-#x37D] | [#x37F-#x1FFF]
 195   ;;                      | [#x200C-#x200D] | [#x2070-#x218F] | [#x2C00-#x2FEF] | [#x3001-#xD7FF]
 196   ;;                      | [#xF900-#xFDCF] | [#xFDF0-#xFFFD] | [#x10000-#xEFFFF]
 197   (defvar xml-name-start-char-re (concat "[" start-chars "]"))
 198   ;;[4a] NameChar       ::= NameStartChar | "-" | "." | [0-9] | #xB7 | [#x0300-#x036F] | [#x203F-#x2040]
 199   (defvar xml-name-char-re       (concat "[" name-chars  "]"))
 200   ;;[5] Name     ::= NameStartChar (NameChar)*
 201   (defvar xml-name-re            (concat xml-name-start-char-re xml-name-char-re "*"))
 202   ;;[6] Names    ::= Name (#x20 Name)*
 203   (defvar xml-names-re           (concat xml-name-re "\\(?: " xml-name-re "\\)*"))
 204   ;;[7] Nmtoken ::= (NameChar)+
 205   (defvar xml-nmtoken-re         (concat xml-name-char-re "+"))
 206   ;;[8] Nmtokens ::= Nmtoken (#x20 Nmtoken)*
 207   (defvar xml-nmtokens-re        (concat xml-nmtoken-re "\\(?: " xml-name-re "\\)*"))
 208   ;;[66] CharRef ::= '&#' [0-9]+ ';' | '&#x' [0-9a-fA-F]+ ';'
 209   (defvar xml-char-ref-re        "\\(?:&#[0-9]+;\\|&#x[0-9a-fA-F]+;\\)")
 210   ;;[68] EntityRef   ::= '&' Name ';'
 211   (defvar xml-entity-ref         (concat "&" xml-name-re ";"))
 212   ;;[69] PEReference ::= '%' Name ';'
 213   (defvar xml-pe-reference-re    (concat "%" xml-name-re ";"))
 214   ;;[67] Reference   ::= EntityRef | CharRef
 215   (defvar xml-reference-re       (concat "\\(?:" xml-entity-ref "\\|" xml-char-ref-re "\\)"))
 216   ;;[10]        AttValue           ::=          '"' ([^<&"] | Reference)* '"' |  "'" ([^<&'] | Reference)* "'"
 217   (defvar xml-att-value-re    (concat "\\(?:\"\\(?:[^&\"]\\|" xml-reference-re "\\)*\"\\|"
 218                                       "'\\(?:[^&']\\|" xml-reference-re "\\)*'\\)"))
 219   ;;[56]        TokenizedType      ::=          'ID'       [VC: ID] [VC: One ID per Element Type] [VC: ID Attribute Default]
 220   ;;                                            | 'IDREF'    [VC: IDREF]
 221   ;;                                                  | 'IDREFS'   [VC: IDREF]
 222   ;;                                            | 'ENTITY'   [VC: Entity Name]
 223   ;;                                            | 'ENTITIES' [VC: Entity Name]
 224   ;;                                            | 'NMTOKEN'  [VC: Name Token]
 225   ;;                                            | 'NMTOKENS' [VC: Name Token]
 226   (defvar xml-tokenized-type-re "\\(?:ID\\|IDREF\\|IDREFS\\|ENTITY\\|ENTITIES\\|NMTOKEN\\|NMTOKENS\\)")
 227   ;;[58]        NotationType       ::=          'NOTATION' S '(' S? Name (S? '|' S? Name)* S? ')'
 228   (defvar xml-notation-type-re (concat "\\(?:NOTATION" whitespace "(" whitespace "*" xml-name-re
 229                                        "\\(?:" whitespace "*|" whitespace "*" xml-name-re "\\)*" whitespace "*)\\)"))
 230   ;;[59]        Enumeration        ::=          '(' S? Nmtoken (S? '|' S? Nmtoken)* S? ')'      [VC: Enumeration] [VC: No Duplicate Tokens]
 231   (defvar xml-enumeration-re (concat "\\(?:(" whitespace "*" xml-nmtoken-re
 232                                      "\\(?:" whitespace "*|" whitespace "*" xml-nmtoken-re "\\)*"
 233                                      whitespace ")\\)"))
 234   ;;[57]        EnumeratedType     ::=          NotationType | Enumeration
 235   (defvar xml-enumerated-type-re (concat "\\(?:" xml-notation-type-re "\\|" xml-enumeration-re "\\)"))
 236   ;;[54]        AttType    ::=          StringType | TokenizedType | EnumeratedType
 237   ;;[55]        StringType         ::=          'CDATA'
 238   (defvar xml-att-type-re (concat "\\(?:CDATA\\|" xml-tokenized-type-re "\\|" xml-notation-type-re"\\|" xml-enumerated-type-re "\\)"))
 239   ;;[60]        DefaultDecl        ::=          '#REQUIRED' | '#IMPLIED' | (('#FIXED' S)? AttValue)
 240   (defvar xml-default-decl-re (concat "\\(?:#REQUIRED\\|#IMPLIED\\|\\(?:#FIXED" whitespace "\\)*" xml-att-value-re "\\)"))
 241   ;;[53]        AttDef     ::=          S Name S AttType S DefaultDecl
 242   (defvar xml-att-def-re         (concat "\\(?:" whitespace "*" xml-name-re
 243                                          whitespace "*" xml-att-type-re
 244                                          whitespace "*" xml-default-decl-re "\\)"))
 245   ;;[9] EntityValue ::= '"' ([^%&"] | PEReference | Reference)* '"'
 246   ;;               |  "'" ([^%&'] | PEReference | Reference)* "'"
 247   (defvar xml-entity-value-re    (concat "\\(?:\"\\(?:[^%&\"]\\|" xml-pe-reference-re
 248                                          "\\|" xml-reference-re "\\)*\"\\|'\\(?:[^%&']\\|"
 249                                          xml-pe-reference-re "\\|" xml-reference-re "\\)*'\\)")))
 250 ;;[75] ExternalID ::= 'SYSTEM' S SystemLiteral
 251 ;;                 | 'PUBLIC' S PubidLiteral S SystemLiteral
 252 ;;[76] NDataDecl ::=    S 'NDATA' S
 253 ;;[73] EntityDef  ::= EntityValue| (ExternalID NDataDecl?)
 254 ;;[71] GEDecl     ::= '<!ENTITY' S Name S EntityDef S? '>'
 255 ;;[74] PEDef      ::= EntityValue | ExternalID
 256 ;;[72] PEDecl     ::= '<!ENTITY' S '%' S Name S PEDef S? '>'
 257 ;;[70] EntityDecl ::= GEDecl | PEDecl
 258
 259 ;; Note that this is setup so that we can do whitespace-skipping with
 260 ;; `(skip-syntax-forward " ")', inter alia.  Previously this was slow
 261 ;; compared with `re-search-forward', but that has been fixed.  Also
 262 ;; note that the standard syntax table contains other characters with
 263 ;; whitespace syntax, like NBSP, but they are invalid in contexts in
 264 ;; which we might skip whitespace -- specifically, they're not
 265 ;; NameChars [XML 4].
 266
 267 (defvar xml-syntax-table
 268   (let ((table (make-syntax-table)))
 269     ;; Get space syntax correct per XML [3].
 270     (dotimes (c 31)
 271       (modify-syntax-entry c "." table)) ; all are space in standard table
 272     (dolist (c '(?\t ?\n ?\r))           ; these should be space
 273       (modify-syntax-entry c " " table))
 274     ;; For skipping attributes.
 275     (modify-syntax-entry ?\" "\"" table)
 276     (modify-syntax-entry ?' "\"" table)
 277     ;; Non-alnum name chars should be symbol constituents (`-' and `_'
 278     ;; are OK by default).
 279     (modify-syntax-entry ?. "_" table)
 280     (modify-syntax-entry ?: "_" table)
 281     ;; XML [89]
 282     (unless (featurep 'xemacs)
 283       (dolist (c '(#x00B7 #x02D0 #x02D1 #x0387 #x0640 #x0E46 #x0EC6 #x3005
 284                           #x3031 #x3032 #x3033 #x3034 #x3035 #x309D #x309E #x30FC
 285                           #x30FD #x30FE))
 286         (modify-syntax-entry (decode-char 'ucs c) "w" table)))
 287     ;; Fixme: rest of [4]
 288     table)
 289   "Syntax table used by `xml-parse-region'.")
 290
 291 ;; XML [5]
 292 ;; Note that [:alpha:] matches all multibyte chars with word syntax.
 293 (eval-and-compile
 294   (defconst xml-name-regexp "[[:alpha:]_:][[:alnum:]._:-]*"))
 295
 296 ;; Fixme:  This needs re-writing to deal with the XML grammar properly, i.e.
 297 ;;   document    ::=    prolog element Misc*
 298 ;;   prolog    ::=    XMLDecl? Misc* (doctypedecl Misc*)?
 299
 300 ;;;###autoload
 301 (defun xml-parse-region (beg end &optional buffer parse-dtd parse-ns)
 302   "Parse the region from BEG to END in BUFFER.
 303 If BUFFER is nil, it defaults to the current buffer.
 304 Returns the XML list for the region, or raises an error if the region
 305 is not well-formed XML.
 306 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped,
 307 and returned as the first element of the list.
 308 If PARSE-NS is non-nil, then QNAMES are expanded."
 309   (save-excursion
 310     (if buffer
 311         (set-buffer buffer))
 312     (save-restriction
 313       (narrow-to-region beg end)
 314       ;; Use fixed syntax table to ensure regexp char classes and syntax
 315       ;; specs DTRT.
 316       (with-syntax-table (standard-syntax-table)
 317         (let ((case-fold-search nil)    ; XML is case-sensitive.
 318               xml result dtd)
 319           (goto-char (point-min))
 320           (while (not (eobp))
 321             (if (search-forward "<" nil t)
 322                 (progn
 323                   (forward-char -1)
 324                   (setq result (xml-parse-tag parse-dtd parse-ns))
 325                   (if (and xml result (not xml-sub-parser))
 326                       ;;  translation of rule [1] of XML specifications
 327                       (error "XML: (Not Well-Formed) Only one root tag allowed")
 328                     (cond
 329                      ((null result))
 330                      ((and (listp (car result))
 331                            parse-dtd)
 332                       (setq dtd (car result))
 333                       (if (cdr result)  ; possible leading comment
 334                           (add-to-list 'xml (cdr result))))
 335                      (t
 336                       (add-to-list 'xml result)))))
 337               (goto-char (point-max))))
 338           (if parse-dtd
 339               (cons dtd (nreverse xml))
 340             (nreverse xml)))))))
 341
 342 (defun xml-maybe-do-ns (name default xml-ns)
 343   "Perform any namespace expansion.
 344 NAME is the name to perform the expansion on.
 345 DEFAULT is the default namespace.  XML-NS is a cons of namespace
 346 names to uris.  When namespace-aware parsing is off, then XML-NS
 347 is nil.
 348
 349 During namespace-aware parsing, any name without a namespace is
 350 put into the namespace identified by DEFAULT.  nil is used to
 351 specify that the name shouldn't be given a namespace."
 352   (if (consp xml-ns)
 353       (let* ((nsp (string-match ":" name))
 354              (lname (if nsp (substring name (match-end 0)) name))
 355              (prefix (if nsp (substring name 0 (match-beginning 0)) default))
 356              (special (and (string-equal lname "xmlns") (not prefix)))
 357              ;; Setting default to nil will insure that there is not
 358              ;; matching cons in xml-ns.  In which case we
 359              (ns (or (cdr (assoc (if special "xmlns" prefix)
 360                                  xml-ns))
 361                      "")))
 362         (cons ns (if special "" lname)))
 363     (intern name)))
 364
 365 (defun xml-parse-fragment (&optional parse-dtd parse-ns)
 366   "Parse xml-like fragments."
 367   (let ((xml-sub-parser t)
 368         children)
 369     (while (not (eobp))
 370       (let ((bit (xml-parse-tag
 371                   parse-dtd parse-ns)))
 372         (if children
 373             (setq children (append (list bit) children))
 374           (if (stringp bit)
 375               (setq children (list bit))
 376             (setq children bit)))))
 377     (reverse children)))
 378
 379 (defun xml-parse-tag (&optional parse-dtd parse-ns)
 380   "Parse the tag at point.
 381 If PARSE-DTD is non-nil, the DTD of the document, if any, is parsed and
 382 returned as the first element in the list.
 383 If PARSE-NS is non-nil, then QNAMES are expanded.
 384 Returns one of:
 385  - a list : the matching node
 386  - nil    : the point is not looking at a tag.
 387  - a pair : the first element is the DTD, the second is the node."
 388   (let ((xml-validating-parser (or parse-dtd xml-validating-parser))
 389         (xml-ns (if (consp parse-ns)
 390                     parse-ns
 391                   (if parse-ns
 392                       (list
 393                        ;; Default for empty prefix is no namespace
 394                        (cons ""      "")
 395                        ;; "xml" namespace
 396                        (cons "xml"   "http://www.w3.org/XML/1998/namespace")
 397                        ;; We need to seed the xmlns namespace
 398                        (cons "xmlns" "http://www.w3.org/2000/xmlns/"))))))
 399     (cond
 400      ;; Processing instructions (like the <?xml version="1.0"?> tag at the
 401      ;; beginning of a document).
 402      ((looking-at "<\\?")
 403       (search-forward "?>")
 404       (skip-syntax-forward " ")
 405       (xml-parse-tag parse-dtd xml-ns))
 406      ;;  Character data (CDATA) sections, in which no tag should be interpreted
 407      ((looking-at "<!\\[CDATA\\[")
 408       (let ((pos (match-end 0)))
 409         (unless (search-forward "]]>" nil t)
 410           (error "XML: (Not Well Formed) CDATA section does not end anywhere in the document"))
 411         (concat
 412          (buffer-substring pos (match-beginning 0))
 413          (xml-parse-string))))
 414      ;;  DTD for the document
 415      ((looking-at "<!DOCTYPE")
 416       (let ((dtd (xml-parse-dtd parse-ns)))
 417         (skip-syntax-forward " ")
 418         (if xml-validating-parser
 419             (cons dtd (xml-parse-tag nil xml-ns))
 420           (xml-parse-tag nil xml-ns))))
 421      ;;  skip comments
 422      ((looking-at "<!--")
 423       (search-forward "-->")
 424       nil)
 425      ;;  end tag
 426      ((looking-at "</")
 427       '())
 428      ;;  opening tag
 429      ((looking-at "<\\([^/>[:space:]]+\\)")
 430       (goto-char (match-end 1))
 431
 432       ;; Parse this node
 433       (let* ((node-name (match-string 1))
 434              ;; Parse the attribute list.
 435              (attrs (xml-parse-attlist xml-ns))
 436              children pos)
 437
 438         ;; add the xmlns:* attrs to our cache
 439         (when (consp xml-ns)
 440           (dolist (attr attrs)
 441             (when (and (consp (car attr))
 442                        (equal "http://www.w3.org/2000/xmlns/"
 443                               (caar attr)))
 444               (push (cons (cdar attr) (cdr attr))
 445                     xml-ns))))
 446
 447         (setq children (list attrs (xml-maybe-do-ns node-name "" xml-ns)))
 448
 449         ;; is this an empty element ?
 450         (if (looking-at "/>")
 451             (progn
 452               (forward-char 2)
 453               (nreverse children))
 454
 455           ;; is this a valid start tag ?
 456           (if (eq (char-after) ?>)
 457               (progn
 458                 (forward-char 1)
 459                 ;;  Now check that we have the right end-tag. Note that this
 460                 ;;  one might contain spaces after the tag name
 461                 (let ((end (concat "</" node-name "\\s-*>")))
 462                   (while (not (looking-at end))
 463                     (cond
 464                      ((looking-at "</")
 465                       (error "XML: (Not Well-Formed) Invalid end tag (expecting %s) at pos %d"
 466                              node-name (point)))
 467                      ((= (char-after) ?<)
 468                       (let ((tag (xml-parse-tag nil xml-ns)))
 469                         (when tag
 470                           (push tag children))))
 471                      (t
 472                       (let ((expansion (xml-parse-string)))
 473                         (setq children
 474                               (if (stringp expansion)
 475                                   (if (stringp (car children))
 476                                       ;; The two strings were separated by a comment.
 477                                       (setq children (append (list (concat (car children) expansion))
 478                                                              (cdr children)))
 479                                     (setq children (append (list expansion) children)))
 480                                 (setq children (append expansion children))))))))
 481
 482                   (goto-char (match-end 0))
 483                   (nreverse children)))
 484             ;;  This was an invalid start tag (Expected ">", but didn't see it.)
 485             (error "XML: (Well-Formed) Couldn't parse tag: %s"
 486                    (buffer-substring (- (point) 10) (+ (point) 1)))))))
 487      (t ;; (Not one of PI, CDATA, Comment, End tag, or Start tag)
 488       (unless xml-sub-parser            ; Usually, we error out.
 489         (error "XML: (Well-Formed) Invalid character"))
 490
 491       ;; However, if we're parsing incrementally, then we need to deal
 492       ;; with stray CDATA.
 493       (xml-parse-string)))))
 494
 495 (defun xml-parse-string ()
 496   "Parse the next whatever.  Could be a string, or an element."
 497   (let* ((pos (point))
 498          (string (progn (if (search-forward "<" nil t)
 499                             (forward-char -1)
 500                           (goto-char (point-max)))
 501                         (buffer-substring pos (point)))))
 502     ;; Clean up the string.  As per XML specifications, the XML
 503     ;; processor should always pass the whole string to the
 504     ;; application.  But \r's should be replaced:
 505     ;; http://www.w3.org/TR/2000/REC-xml-20001006#sec-line-ends
 506     (setq pos 0)
 507     (while (string-match "\r\n?" string pos)
 508       (setq string (replace-match "\n" t t string))
 509       (setq pos (1+ (match-beginning 0))))
 510
 511     (xml-substitute-special string)))
 512
 513 (defun xml-parse-attlist (&optional xml-ns)
 514   "Return the attribute-list after point.
 515 Leave point at the first non-blank character after the tag."
 516   (let ((attlist ())
 517         end-pos name)
 518     (skip-syntax-forward " ")
 519     (while (looking-at (eval-when-compile
 520                          (concat "\\(" xml-name-regexp "\\)\\s-*=\\s-*")))
 521       (setq end-pos (match-end 0))
 522       (setq name (xml-maybe-do-ns (match-string 1) nil xml-ns))
 523       (goto-char end-pos)
 524
 525       ;; See also: http://www.w3.org/TR/2000/REC-xml-20001006#AVNormalize
 526
 527       ;; Do we have a string between quotes (or double-quotes),
 528       ;;  or a simple word ?
 529       (if (looking-at "\"\\([^\"]*\\)\"")
 530           (setq end-pos (match-end 0))
 531         (if (looking-at "'\\([^']*\\)'")
 532             (setq end-pos (match-end 0))
 533           (error "XML: (Not Well-Formed) Attribute values must be given between quotes")))
 534
 535       ;; Each attribute must be unique within a given element
 536       (if (assoc name attlist)
 537           (error "XML: (Not Well-Formed) Each attribute must be unique within an element"))
 538
 539       ;; Multiple whitespace characters should be replaced with a single one
 540       ;; in the attributes
 541       (let ((string (match-string 1))
 542             (pos 0))
 543         (replace-regexp-in-string "\\s-\\{2,\\}" " " string)
 544         (let ((expansion (xml-substitute-special string)))
 545           (unless (stringp expansion)
 546                                         ; We say this is the constraint.  It is acctually that
 547                                         ; external entities nor "<" can be in an attribute value.
 548             (error "XML: (Not Well-Formed) Entities in attributes cannot expand into elements"))
 549           (push (cons name expansion) attlist)))
 550
 551       (goto-char end-pos)
 552       (skip-syntax-forward " "))
 553     (nreverse attlist)))
 554
 555 ;;*******************************************************************
 556 ;;**
 557 ;;**  The DTD (document type declaration)
 558 ;;**  The following functions know how to skip or parse the DTD of
 559 ;;**  a document
 560 ;;**
 561 ;;*******************************************************************
 562
 563 ;; Fixme: This fails at least if the DTD contains conditional sections.
 564
 565 (defun xml-skip-dtd ()
 566   "Skip the DTD at point.
 567 This follows the rule [28] in the XML specifications."
 568   (let ((xml-validating-parser nil))
 569     (xml-parse-dtd)))
 570
 571 (defun xml-parse-dtd (&optional parse-ns)
 572   "Parse the DTD at point."
 573   (forward-char (eval-when-compile (length "<!DOCTYPE")))
 574   (skip-syntax-forward " ")
 575   (if (and (looking-at ">")
 576            xml-validating-parser)
 577       (error "XML: (Validity) Invalid DTD (expecting name of the document)"))
 578
 579   ;;  Get the name of the document
 580   (looking-at xml-name-regexp)
 581   (let ((dtd (list (match-string 0) 'dtd))
 582         type element end-pos)
 583     (goto-char (match-end 0))
 584
 585     (skip-syntax-forward " ")
 586     ;; XML [75]
 587     (cond ((looking-at "PUBLIC\\s-+")
 588            (goto-char (match-end 0))
 589            (unless (or (re-search-forward
 590                         "\\=\"\\([[:space:][:alnum:]-'()+,./:=?;!*#@$_%]*\\)\""
 591                         nil t)
 592                        (re-search-forward
 593                         "\\='\\([[:space:][:alnum:]-()+,./:=?;!*#@$_%]*\\)'"
 594                         nil t))
 595              (error "XML: Missing Public ID"))
 596            (let ((pubid (match-string 1)))
 597              (skip-syntax-forward " ")
 598              (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
 599                          (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
 600                (error "XML: Missing System ID"))
 601              (push (list pubid (match-string 1) 'public) dtd)))
 602           ((looking-at "SYSTEM\\s-+")
 603            (goto-char (match-end 0))
 604            (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
 605                        (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
 606              (error "XML: Missing System ID"))
 607            (push (list (match-string 1) 'system) dtd)))
 608     (skip-syntax-forward " ")
 609     (if (eq ?> (char-after))
 610         (forward-char)
 611       (if (not (eq (char-after) ?\[))
 612           (error "XML: Bad DTD")
 613         (forward-char)
 614         ;;  Parse the rest of the DTD
 615         ;;  Fixme: Deal with NOTATION, PIs.
 616         (while (not (looking-at "\\s-*\\]"))
 617           (skip-syntax-forward " ")
 618           (cond
 619
 620            ;;  Translation of rule [45] of XML specifications
 621            ((looking-at
 622              "<!ELEMENT\\s-+\\([[:alnum:].%;]+\\)\\s-+\\([^>]+\\)>")
 623
 624             (setq element (match-string 1)
 625                   type    (match-string-no-properties 2))
 626             (setq end-pos (match-end 0))
 627
 628             ;;  Translation of rule [46] of XML specifications
 629             (cond
 630              ((string-match "^EMPTY[ \t\n\r]*$" type) ;; empty declaration
 631               (setq type 'empty))
 632              ((string-match "^ANY[ \t\n\r]*$" type) ;; any type of contents
 633               (setq type 'any))
 634              ((string-match "^(\\(.*\\))[ \t\n\r]*$" type) ;; children ([47])
 635               (setq type (xml-parse-elem-type (match-string 1 type))))
 636              ((string-match "^%[^;]+;[ \t\n\r]*$" type) ;; substitution
 637               nil)
 638              (t
 639               (if xml-validating-parser
 640                   (error "XML: (Validity) Invalid element type in the DTD"))))
 641
 642             ;;  rule [45]: the element declaration must be unique
 643             (if (and (assoc element dtd)
 644                      xml-validating-parser)
 645                 (error "XML: (Validity) Element declarations must be unique in a DTD (<%s>)"
 646                        element))
 647
 648             ;;  Store the element in the DTD
 649             (push (list element type) dtd)
 650             (goto-char end-pos))
 651
 652            ;; Translation of rule [52] of XML specifications
 653            ((looking-at (concat "<!ATTLIST[ \t\n\r]*\\(" xml-name-re
 654                                 "\\)[ \t\n\r]*\\(" xml-att-def-re
 655                                 "\\)*[ \t\n\r]*>"))
 656
 657             ;; We don't do anything with ATTLIST currently
 658             (goto-char (match-end 0)))
 659
 660            ((looking-at "<!--")
 661             (search-forward "-->"))
 662            ((looking-at (concat "<!ENTITY[ \t\n\r]*\\(" xml-name-re
 663                                 "\\)[ \t\n\r]*\\(" xml-entity-value-re
 664                                 "\\)[ \t\n\r]*>"))
 665             (let ((name  (match-string 1))
 666                   (value (substring (match-string 2) 1
 667                                     (- (length (match-string 2)) 1))))
 668               (goto-char (match-end 0))
 669               (setq xml-entity-alist
 670                     (append xml-entity-alist
 671                             (list (cons name
 672                                         (with-temp-buffer
 673                                           (insert value)
 674                                           (goto-char (point-min))
 675                                           (xml-parse-fragment
 676                                            xml-validating-parser
 677                                            parse-ns))))))))
 678            ((or (looking-at (concat "<!ENTITY[ \t\n\r]+\\(" xml-name-re
 679                                     "\\)[ \t\n\r]+SYSTEM[ \t\n\r]+"
 680                                     "\\(\"[^\"]*\"\\|'[^']*'\\)[ \t\n\r]*>"))
 681                 (looking-at (concat "<!ENTITY[ \t\n\r]+\\(" xml-name-re
 682                                     "\\)[ \t\n\r]+PUBLIC[ \t\n\r]+"
 683                                     "\"[- \r\na-zA-Z0-9'()+,./:=?;!*#@$_%]*\""
 684                                     "\\|'[- \r\na-zA-Z0-9()+,./:=?;!*#@$_%]*'"
 685                                     "[ \t\n\r]+\\(\"[^\"]*\"\\|'[^']*'\\)"
 686                                     "[ \t\n\r]*>")))
 687             (let ((name  (match-string 1))
 688                   (file  (substring (match-string 2) 1
 689                                     (- (length (match-string 2)) 1))))
 690               (goto-char (match-end 0))
 691               (setq xml-entity-alist
 692                     (append xml-entity-alist
 693                             (list (cons name (with-temp-buffer
 694                                                (insert-file-contents file)
 695                                                (goto-char (point-min))
 696                                                (xml-parse-fragment
 697                                                 xml-validating-parser
 698                                                 parse-ns))))))))
 699            ;; skip parameter entity declarations
 700            ((or (looking-at (concat "<!ENTITY[ \t\n\r]+%[ \t\n\r]+\\(" xml-name-re
 701                                     "\\)[ \t\n\r]+SYSTEM[ \t\n\r]+"
 702                                     "\\(\"[^\"]*\"\\|'[^']*'\\)[ \t\n\r]*>"))
 703                 (looking-at (concat "<!ENTITY[ \t\n\r]+"
 704                                     "%[ \t\n\r]+"
 705                                     "\\(" xml-name-re "\\)[ \t\n\r]+"
 706                                     "PUBLIC[ \t\n\r]+"
 707                                     "\\(\"[- \r\na-zA-Z0-9'()+,./:=?;!*#@$_%]*\""
 708                                     "\\|'[- \r\na-zA-Z0-9()+,./:=?;!*#@$_%]*'\\)[ \t\n\r]+"
 709                                     "\\(\"[^\"]+\"\\|'[^']+'\\)"
 710                                     "[ \t\n\r]*>")))
 711             (goto-char (match-end 0)))
 712            ;; skip parameter entities
 713            ((looking-at (concat "%" xml-name-re ";"))
 714             (goto-char (match-end 0)))
 715            (t
 716             (when xml-validating-parser
 717               (error "XML: (Validity) Invalid DTD item"))))))
 718       (if (looking-at "\\s-*]>")
 719           (goto-char (match-end 0))))
 720     (nreverse dtd)))
 721
 722 (defun xml-parse-elem-type (string)
 723   "Convert element type STRING into a Lisp structure."
 724
 725   (let (elem modifier)
 726     (if (string-match "(\\([^)]+\\))\\([+*?]?\\)" string)
 727         (progn
 728           (setq elem     (match-string 1 string)
 729                 modifier (match-string 2 string))
 730           (if (string-match "|" elem)
 731               (setq elem (cons 'choice
 732                                (mapcar 'xml-parse-elem-type
 733                                        (split-string elem "|"))))
 734             (if (string-match "," elem)
 735                 (setq elem (cons 'seq
 736                                  (mapcar 'xml-parse-elem-type
 737                                          (split-string elem ",")))))))
 738       (if (string-match "[ \t\n\r]*\\([^+*?]+\\)\\([+*?]?\\)" string)
 739           (setq elem     (match-string 1 string)
 740                 modifier (match-string 2 string))))
 741
 742     (if (and (stringp elem) (string= elem "#PCDATA"))
 743         (setq elem 'pcdata))
 744
 745     (cond
 746      ((string= modifier "+")
 747       (list '+ elem))
 748      ((string= modifier "*")
 749       (list '* elem))
 750      ((string= modifier "?")
 751       (list '\? elem))
 752      (t
 753       elem))))
 754
 755 ;;*******************************************************************
 756 ;;**
 757 ;;**  Substituting special XML sequences
 758 ;;**
 759 ;;*******************************************************************
 760
 761 (defun xml-substitute-special (string)
 762   "Return STRING, after subsituting entity references."
 763   ;; This originally made repeated passes through the string from the
 764   ;; beginning, which isn't correct, since then either "&amp;amp;" or
 765   ;; "&#38;amp;" won't DTRT.
 766
 767   (let ((point 0)
 768         children end-point)
 769     (while (string-match "&\\([^;]*\\);" string point)
 770       (setq end-point (match-end 0))
 771       (let* ((this-part (match-string 1 string))
 772              (prev-part (substring string point (match-beginning 0)))
 773              (entity (assoc this-part xml-entity-alist))
 774              (expansion
 775               (cond ((string-match "#\\([0-9]+\\)" this-part)
 776                      (let ((c (decode-char
 777                                'ucs
 778                                (string-to-number (match-string 1 this-part)))))
 779                        (if c (string c))))
 780                     ((string-match "#x\\([[:xdigit:]]+\\)" this-part)
 781                      (let ((c (decode-char
 782                                'ucs
 783                                (string-to-number (match-string 1 this-part) 16))))
 784                        (if c (string c))))
 785                     (entity
 786                      (cdr entity))
 787                     ((eq (length this-part) 0)
 788                      (error "XML: (Not Well-Formed) No entity given"))
 789                     (t
 790                      (if xml-validating-parser
 791                          (error "XML: (Validity) Undefined entity `%s'"
 792                                 this-part)
 793                        xml-undefined-entity)))))
 794
 795         (cond ((null children)
 796                ;; FIXME: If we have an entity that expands into XML, this won't work.
 797                (setq children
 798                      (concat prev-part expansion)))
 799               ((stringp children)
 800                (if (stringp expansion)
 801                    (setq children (concat children prev-part expansion))
 802                  (setq children (list expansion (concat prev-part children)))))
 803               ((and (stringp expansion)
 804                     (stringp (car children)))
 805                (setcar children (concat prev-part expansion (car children))))
 806               ((stringp expansion)
 807                (setq children (append (concat prev-part expansion)
 808                                       children)))
 809               ((stringp (car children))
 810                (setcar children (concat (car children) prev-part))
 811                (setq children (append expansion children)))
 812               (t
 813                (setq children (list expansion
 814                                     prev-part
 815                                     children))))
 816         (setq point end-point)))
 817     (cond ((stringp children)
 818            (concat children (substring string point)))
 819           ((stringp (car (last children)))
 820            (concat (car (last children)) (substring string point)))
 821           ((null children)
 822            string)
 823           (t
 824            (concat (mapconcat 'identity
 825                               (nreverse children)
 826                               "")
 827                    (substring string point))))))
 828
 829 ;;*******************************************************************
 830 ;;**
 831 ;;**  Printing a tree.
 832 ;;**  This function is intended mainly for debugging purposes.
 833 ;;**
 834 ;;*******************************************************************
 835
 836 (defun xml-debug-print (xml &optional indent-string)
 837   "Outputs the XML in the current buffer.
 838 XML can be a tree or a list of nodes.
 839 The first line is indented with the optional INDENT-STRING."
 840   (setq indent-string (or indent-string ""))
 841   (dolist (node xml)
 842     (xml-debug-print-internal node indent-string)))
 843
 844 (defalias 'xml-print 'xml-debug-print)
 845
 846 (defun xml-debug-print-internal (xml indent-string)
 847   "Outputs the XML tree in the current buffer.
 848 The first line is indented with INDENT-STRING."
 849   (let ((tree xml)
 850         attlist)
 851     (insert indent-string ?< (symbol-name (xml-node-name tree)))
 852
 853     ;;  output the attribute list
 854     (setq attlist (xml-node-attributes tree))
 855     (while attlist
 856       (insert ?\  (symbol-name (caar attlist)) "=\"" (cdar attlist) ?\")
 857       (setq attlist (cdr attlist)))
 858
 859     (setq tree (xml-node-children tree))
 860
 861     (if (null tree)
 862         (insert ?/ ?>)
 863       (insert ?>)
 864
 865       ;;  output the children
 866       (dolist (node tree)
 867         (cond
 868          ((listp node)
 869           (insert ?\n)
 870           (xml-debug-print-internal node (concat indent-string "  ")))
 871          ((stringp node) (insert node))
 872          (t
 873           (error "Invalid XML tree"))))
 874
 875       (when (not (and (null (cdr tree))
 876                       (stringp (car tree))))
 877         (insert ?\n indent-string))
 878       (insert ?< ?/ (symbol-name (xml-node-name xml)) ?>))))
 879
 880 (provide 'xml)
 881
 882 ;; arch-tag: 5864b283-5a68-4b59-a20d-36a72b353b9b
 883 ;;; xml.el ends here