lisp/gnus/mml.el

   1 ;;; mml.el --- A package for parsing and validating MML documents
   2
   3 ;; Copyright (C) 1998-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software: you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22
  23 ;;; Code:
  24
  25 ;; For Emacs <22.2 and XEmacs.
  26 (eval-and-compile
  27   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  28
  29 (require 'mm-util)
  30 (require 'mm-bodies)
  31 (require 'mm-encode)
  32 (require 'mm-decode)
  33 (require 'mml-sec)
  34 (eval-when-compile (require 'cl))
  35 (eval-when-compile
  36   (when (featurep 'xemacs)
  37     (require 'easy-mmode))) ; for `define-minor-mode'
  38
  39 (autoload 'message-make-message-id "message")
  40 (declare-function gnus-setup-posting-charset "gnus-msg" (group))
  41 (autoload 'gnus-make-local-hook "gnus-util")
  42 (autoload 'gnus-completing-read "gnus-util")
  43 (autoload 'message-fetch-field "message")
  44 (autoload 'message-mark-active-p "message")
  45 (autoload 'message-info "message")
  46 (autoload 'fill-flowed-encode "flow-fill")
  47 (autoload 'message-posting-charset "message")
  48 (autoload 'dnd-get-local-file-name "dnd")
  49
  50 (autoload 'message-options-set    "message")
  51 (autoload 'message-narrow-to-head "message")
  52 (autoload 'message-in-body-p      "message")
  53 (autoload 'message-mail-p         "message")
  54
  55 (defvar gnus-article-mime-handles)
  56 (defvar gnus-mouse-2)
  57 (defvar gnus-newsrc-hashtb)
  58 (defvar message-default-charset)
  59 (defvar message-deletable-headers)
  60 (defvar message-options)
  61 (defvar message-posting-charset)
  62 (defvar message-required-mail-headers)
  63 (defvar message-required-news-headers)
  64 (defvar dnd-protocol-alist)
  65 (defvar mml-dnd-protocol-alist)
  66
  67 (defcustom mml-content-type-parameters
  68   '(name access-type expiration size permission format)
  69   "*A list of acceptable parameters in MML tag.
  70 These parameters are generated in Content-Type header if exists."
  71   :version "22.1"
  72   :type '(repeat (symbol :tag "Parameter"))
  73   :group 'message)
  74
  75 (defcustom mml-content-disposition-parameters
  76   '(filename creation-date modification-date read-date)
  77   "*A list of acceptable parameters in MML tag.
  78 These parameters are generated in Content-Disposition header if exists."
  79   :version "22.1"
  80   :type '(repeat (symbol :tag "Parameter"))
  81   :group 'message)
  82
  83 (defcustom mml-content-disposition-alist
  84   '((text (rtf . "attachment") (t . "inline"))
  85     (t . "attachment"))
  86   "Alist of MIME types or regexps matching file names and default dispositions.
  87 Each element should be one of the following three forms:
  88
  89   (REGEXP . DISPOSITION)
  90   (SUPERTYPE (SUBTYPE . DISPOSITION) (SUBTYPE . DISPOSITION)...)
  91   (TYPE . DISPOSITION)
  92
  93 Where REGEXP is a string which matches the file name (if any) of an
  94 attachment, SUPERTYPE, SUBTYPE and TYPE should be symbols which are a
  95 MIME supertype (e.g., text), a MIME subtype (e.g., plain) and a MIME
  96 type (e.g., text/plain) respectively, and DISPOSITION should be either
  97 the string \"attachment\" or the string \"inline\".  The value t for
  98 SUPERTYPE, SUBTYPE or TYPE matches any of those types.  The first
  99 match found will be used."
 100   :version "23.1" ;; No Gnus
 101   :type (let ((dispositions '(radio :format "DISPOSITION: %v"
 102                                     :value "attachment"
 103                                     (const :format "%v " "attachment")
 104                                     (const :format "%v\n" "inline"))))
 105           `(repeat
 106             :offset 0
 107             (choice :format "%[Value Menu%]%v"
 108                     (cons :tag "(REGEXP . DISPOSITION)" :extra-offset 4
 109                           (regexp :tag "REGEXP" :value ".*")
 110                           ,dispositions)
 111                     (cons :tag "(SUPERTYPE (SUBTYPE . DISPOSITION)...)"
 112                           :indent 0
 113                           (symbol :tag "    SUPERTYPE" :value text)
 114                           (repeat :format "%v%i\n" :offset 0 :extra-offset 4
 115                                   (cons :format "%v" :extra-offset 5
 116                                         (symbol :tag "SUBTYPE" :value t)
 117                                         ,dispositions)))
 118                     (cons :tag "(TYPE . DISPOSITION)" :extra-offset 4
 119                           (symbol :tag "TYPE" :value t)
 120                           ,dispositions))))
 121   :group 'message)
 122
 123 (defcustom mml-insert-mime-headers-always t
 124   "If non-nil, always put Content-Type: text/plain at top of empty parts.
 125 It is necessary to work against a bug in certain clients."
 126   :version "24.1"
 127   :type 'boolean
 128   :group 'message)
 129
 130 (defcustom mml-enable-flowed t
 131   "If non-nil, enable format=flowed usage when encoding a message.
 132 This is only performed when filling on text/plain with hard
 133 newlines in the text."
 134   :version "24.1"
 135   :type 'boolean
 136   :group 'message)
 137
 138 (defvar mml-tweak-type-alist nil
 139   "A list of (TYPE . FUNCTION) for tweaking MML parts.
 140 TYPE is a string containing a regexp to match the MIME type.  FUNCTION
 141 is a Lisp function which is called with the MML handle to tweak the
 142 part.  This variable is used only when no TWEAK parameter exists in
 143 the MML handle.")
 144
 145 (defvar mml-tweak-function-alist nil
 146   "A list of (NAME . FUNCTION) for tweaking MML parts.
 147 NAME is a string containing the name of the TWEAK parameter in the MML
 148 handle.  FUNCTION is a Lisp function which is called with the MML
 149 handle to tweak the part.")
 150
 151 (defvar mml-tweak-sexp-alist
 152   '((mml-externalize-attachments . mml-tweak-externalize-attachments))
 153   "A list of (SEXP . FUNCTION) for tweaking MML parts.
 154 SEXP is an s-expression.  If the evaluation of SEXP is non-nil, FUNCTION
 155 is called.  FUNCTION is a Lisp function which is called with the MML
 156 handle to tweak the part.")
 157
 158 (defvar mml-externalize-attachments nil
 159   "*If non-nil, local-file attachments are generated as external parts.")
 160
 161 (defvar mml-generate-multipart-alist nil
 162   "*Alist of multipart generation functions.
 163 Each entry has the form (NAME . FUNCTION), where
 164 NAME is a string containing the name of the part (without the
 165 leading \"/multipart/\"),
 166 FUNCTION is a Lisp function which is called to generate the part.
 167
 168 The Lisp function has to supply the appropriate MIME headers and the
 169 contents of this part.")
 170
 171 (defvar mml-syntax-table
 172   (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
 173     (modify-syntax-entry ?\\ "/" table)
 174     (modify-syntax-entry ?< "(" table)
 175     (modify-syntax-entry ?> ")" table)
 176     (modify-syntax-entry ?@ "w" table)
 177     (modify-syntax-entry ?/ "w" table)
 178     (modify-syntax-entry ?= " " table)
 179     (modify-syntax-entry ?* " " table)
 180     (modify-syntax-entry ?\; " " table)
 181     (modify-syntax-entry ?\' " " table)
 182     table))
 183
 184 (defvar mml-boundary-function 'mml-make-boundary
 185   "A function called to suggest a boundary.
 186 The function may be called several times, and should try to make a new
 187 suggestion each time.  The function is called with one parameter,
 188 which is a number that says how many times the function has been
 189 called for this message.")
 190
 191 (defvar mml-confirmation-set nil
 192   "A list of symbols, each of which disables some warning.
 193 `unknown-encoding': always send messages contain characters with
 194 unknown encoding; `use-ascii': always use ASCII for those characters
 195 with unknown encoding; `multipart': always send messages with more than
 196 one charsets.")
 197
 198 (defvar mml-generate-default-type "text/plain"
 199   "Content type by which the Content-Type header can be omitted.
 200 The Content-Type header will not be put in the MIME part if the type
 201 equals the value and there's no parameter (e.g. charset, format, etc.)
 202 and `mml-insert-mime-headers-always' is nil.  The value will be bound
 203 to \"message/rfc822\" when encoding an article to be forwarded as a MIME
 204 part.  This is for the internal use, you should never modify the value.")
 205
 206 (defvar mml-buffer-list nil)
 207
 208 (defun mml-generate-new-buffer (name)
 209   (let ((buf (generate-new-buffer name)))
 210     (push buf mml-buffer-list)
 211     buf))
 212
 213 (defun mml-destroy-buffers ()
 214   (let (kill-buffer-hook)
 215     (mapc 'kill-buffer mml-buffer-list)
 216     (setq mml-buffer-list nil)))
 217
 218 (defun mml-parse ()
 219   "Parse the current buffer as an MML document."
 220   (save-excursion
 221     (goto-char (point-min))
 222     (with-syntax-table mml-syntax-table
 223       (mml-parse-1))))
 224
 225 (defun mml-parse-1 ()
 226   "Parse the current buffer as an MML document."
 227   (let (struct tag point contents charsets warn use-ascii no-markup-p raw)
 228     (while (and (not (eobp))
 229                 (not (looking-at "<#/multipart")))
 230       (cond
 231        ((looking-at "<#secure")
 232         ;; The secure part is essentially a meta-meta tag, which
 233         ;; expands to either a part tag if there are no other parts in
 234         ;; the document or a multipart tag if there are other parts
 235         ;; included in the message
 236         (let* (secure-mode
 237                (taginfo (mml-read-tag))
 238                (keyfile (cdr (assq 'keyfile taginfo)))
 239                (certfiles (delq nil (mapcar (lambda (tag)
 240                                               (if (eq (car-safe tag) 'certfile)
 241                                                   (cdr tag)))
 242                                             taginfo)))
 243                (recipients (cdr (assq 'recipients taginfo)))
 244                (sender (cdr (assq 'sender taginfo)))
 245                (location (cdr (assq 'tag-location taginfo)))
 246                (mode (cdr (assq 'mode taginfo)))
 247                (method (cdr (assq 'method taginfo)))
 248                tags)
 249           (save-excursion
 250             (if (re-search-forward
 251                  "<#/?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 252                 (setq secure-mode "multipart")
 253               (setq secure-mode "part")))
 254           (save-excursion
 255             (goto-char location)
 256             (re-search-forward "<#secure[^\n]*>\n"))
 257           (delete-region (match-beginning 0) (match-end 0))
 258           (cond ((string= mode "sign")
 259                  (setq tags (list "sign" method)))
 260                 ((string= mode "encrypt")
 261                  (setq tags (list "encrypt" method)))
 262                 ((string= mode "signencrypt")
 263                  (setq tags (list "sign" method "encrypt" method))))
 264           (eval `(mml-insert-tag ,secure-mode
 265                                  ,@tags
 266                                  ,(if keyfile "keyfile")
 267                                  ,keyfile
 268                                  ,@(apply #'append
 269                                           (mapcar (lambda (certfile)
 270                                                     (list "certfile" certfile))
 271                                                   certfiles))
 272                                  ,(if recipients "recipients")
 273                                  ,recipients
 274                                  ,(if sender "sender")
 275                                  ,sender))
 276           ;; restart the parse
 277           (goto-char location)))
 278        ((looking-at "<#multipart")
 279         (push (nconc (mml-read-tag) (mml-parse-1)) struct))
 280        ((looking-at "<#external")
 281         (push (nconc (mml-read-tag) (list (cons 'contents (mml-read-part))))
 282               struct))
 283        (t
 284         (if (or (looking-at "<#part") (looking-at "<#mml"))
 285             (setq tag (mml-read-tag)
 286                   no-markup-p nil
 287                   warn nil)
 288           (setq tag (list 'part '(type . "text/plain"))
 289                 no-markup-p t
 290                 warn t))
 291         (setq raw (cdr (assq 'raw tag))
 292               point (point)
 293               contents (mml-read-part (eq 'mml (car tag)))
 294               charsets (cond
 295                         (raw nil)
 296                         ((assq 'charset tag)
 297                          (list
 298                           (intern (downcase (cdr (assq 'charset tag))))))
 299                         (t
 300                          (mm-find-mime-charset-region point (point)
 301                                                       mm-hack-charsets))))
 302         (when (and (not raw) (memq nil charsets))
 303           (if (or (memq 'unknown-encoding mml-confirmation-set)
 304                   (message-options-get 'unknown-encoding)
 305                   (and (y-or-n-p "\
 306 Message contains characters with unknown encoding.  Really send? ")
 307                        (message-options-set 'unknown-encoding t)))
 308               (if (setq use-ascii
 309                         (or (memq 'use-ascii mml-confirmation-set)
 310                             (message-options-get 'use-ascii)
 311                             (and (y-or-n-p "Use ASCII as charset? ")
 312                                  (message-options-set 'use-ascii t))))
 313                   (setq charsets (delq nil charsets))
 314                 (setq warn nil))
 315             (error "Edit your message to remove those characters")))
 316         (if (or raw
 317                 (eq 'mml (car tag))
 318                 (< (length charsets) 2))
 319             (if (or (not no-markup-p)
 320                     (string-match "[^ \t\r\n]" contents))
 321                 ;; Don't create blank parts.
 322                 (push (nconc tag (list (cons 'contents contents)))
 323                       struct))
 324           (let ((nstruct (mml-parse-singlepart-with-multiple-charsets
 325                           tag point (point) use-ascii)))
 326             (when (and warn
 327                        (not (memq 'multipart mml-confirmation-set))
 328                        (not (message-options-get 'multipart))
 329                        (not (and (y-or-n-p (format "\
 330 A message part needs to be split into %d charset parts.  Really send? "
 331                                                    (length nstruct)))
 332                                  (message-options-set 'multipart t))))
 333               (error "Edit your message to use only one charset"))
 334             (setq struct (nconc nstruct struct)))))))
 335     (unless (eobp)
 336       (forward-line 1))
 337     (nreverse struct)))
 338
 339 (defun mml-parse-singlepart-with-multiple-charsets
 340   (orig-tag beg end &optional use-ascii)
 341   (save-excursion
 342     (save-restriction
 343       (narrow-to-region beg end)
 344       (goto-char (point-min))
 345       (let ((current (or (mm-mime-charset (mm-charset-after))
 346                          (and use-ascii 'us-ascii)))
 347             charset struct space newline paragraph)
 348         (while (not (eobp))
 349           (setq charset (mm-mime-charset (mm-charset-after)))
 350           (cond
 351            ;; The charset remains the same.
 352            ((eq charset 'us-ascii))
 353            ((or (and use-ascii (not charset))
 354                 (eq charset current))
 355             (setq space nil
 356                   newline nil
 357                   paragraph nil))
 358            ;; The initial charset was ascii.
 359            ((eq current 'us-ascii)
 360             (setq current charset
 361                   space nil
 362                   newline nil
 363                   paragraph nil))
 364            ;; We have a change in charsets.
 365            (t
 366             (push (append
 367                    orig-tag
 368                    (list (cons 'contents
 369                                (buffer-substring-no-properties
 370                                 beg (or paragraph newline space (point))))))
 371                   struct)
 372             (setq beg (or paragraph newline space (point))
 373                   current charset
 374                   space nil
 375                   newline nil
 376                   paragraph nil)))
 377           ;; Compute places where it might be nice to break the part.
 378           (cond
 379            ((memq (following-char) '(?  ?\t))
 380             (setq space (1+ (point))))
 381            ((and (eq (following-char) ?\n)
 382                  (not (bobp))
 383                  (eq (char-after (1- (point))) ?\n))
 384             (setq paragraph (point)))
 385            ((eq (following-char) ?\n)
 386             (setq newline (1+ (point)))))
 387           (forward-char 1))
 388         ;; Do the final part.
 389         (unless (= beg (point))
 390           (push (append orig-tag
 391                         (list (cons 'contents
 392                                     (buffer-substring-no-properties
 393                                      beg (point)))))
 394                 struct))
 395         struct))))
 396
 397 (defun mml-read-tag ()
 398   "Read a tag and return the contents."
 399   (let ((orig-point (point))
 400         contents name elem val)
 401     (forward-char 2)
 402     (setq name (buffer-substring-no-properties
 403                 (point) (progn (forward-sexp 1) (point))))
 404     (skip-chars-forward " \t\n")
 405     (while (not (looking-at ">[ \t]*\n?"))
 406       (setq elem (buffer-substring-no-properties
 407                   (point) (progn (forward-sexp 1) (point))))
 408       (skip-chars-forward "= \t\n")
 409       (setq val (buffer-substring-no-properties
 410                  (point) (progn (forward-sexp 1) (point))))
 411       (when (string-match "\\`\"" val)
 412         (setq val (read val))) ;; inverse of prin1 in mml-insert-tag
 413       (push (cons (intern elem) val) contents)
 414       (skip-chars-forward " \t\n"))
 415     (goto-char (match-end 0))
 416     ;; Don't skip the leading space.
 417     ;;(skip-chars-forward " \t\n")
 418     ;; Put the tag location into the returned contents
 419     (setq contents (append (list (cons 'tag-location orig-point)) contents))
 420     (cons (intern name) (nreverse contents))))
 421
 422 (defun mml-buffer-substring-no-properties-except-hard-newlines (start end)
 423   (let ((str (buffer-substring-no-properties start end))
 424         (bufstart start) tmp)
 425     (while (setq tmp (text-property-any start end 'hard 't))
 426       (set-text-properties (- tmp bufstart) (- tmp bufstart -1)
 427                            '(hard t) str)
 428       (setq start (1+ tmp)))
 429     str))
 430
 431 (defun mml-read-part (&optional mml)
 432   "Return the buffer up till the next part, multipart or closing part or multipart.
 433 If MML is non-nil, return the buffer up till the correspondent mml tag."
 434   (let ((beg (point)) (count 1))
 435     ;; If the tag ended at the end of the line, we go to the next line.
 436     (when (looking-at "[ \t]*\n")
 437       (forward-line 1))
 438     (if mml
 439         (progn
 440           (while (and (> count 0) (not (eobp)))
 441             (if (re-search-forward "<#\\(/\\)?mml." nil t)
 442                 (setq count (+ count (if (match-beginning 1) -1 1)))
 443               (goto-char (point-max))))
 444           (mml-buffer-substring-no-properties-except-hard-newlines
 445            beg (if (> count 0)
 446                    (point)
 447                  (match-beginning 0))))
 448       (if (re-search-forward
 449            "<#\\(/\\)?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 450           (prog1
 451               (mml-buffer-substring-no-properties-except-hard-newlines
 452                beg (match-beginning 0))
 453             (if (or (not (match-beginning 1))
 454                     (equal (match-string 2) "multipart"))
 455                 (goto-char (match-beginning 0))
 456               (when (looking-at "[ \t]*\n")
 457                 (forward-line 1))))
 458         (mml-buffer-substring-no-properties-except-hard-newlines
 459          beg (goto-char (point-max)))))))
 460
 461 (defvar mml-boundary nil)
 462 (defvar mml-base-boundary "-=-=")
 463 (defvar mml-multipart-number 0)
 464
 465 (defun mml-generate-mime ()
 466   "Generate a MIME message based on the current MML document."
 467   (let ((cont (mml-parse))
 468         (mml-multipart-number mml-multipart-number))
 469     (if (not cont)
 470         nil
 471       (mm-with-multibyte-buffer
 472         (if (and (consp (car cont))
 473                  (= (length cont) 1))
 474             (mml-generate-mime-1 (car cont))
 475           (mml-generate-mime-1 (nconc (list 'multipart '(type . "mixed"))
 476                                       cont)))
 477         (buffer-string)))))
 478
 479 (defun mml-generate-mime-1 (cont)
 480   (let ((mm-use-ultra-safe-encoding
 481          (or mm-use-ultra-safe-encoding (assq 'sign cont))))
 482     (save-restriction
 483       (narrow-to-region (point) (point))
 484       (mml-tweak-part cont)
 485       (cond
 486        ((or (eq (car cont) 'part) (eq (car cont) 'mml))
 487         (let* ((raw (cdr (assq 'raw cont)))
 488                (filename (cdr (assq 'filename cont)))
 489                (type (or (cdr (assq 'type cont))
 490                          (if filename
 491                              (or (mm-default-file-encoding filename)
 492                                  "application/octet-stream")
 493                            "text/plain")))
 494                (charset (cdr (assq 'charset cont)))
 495                (coding (mm-charset-to-coding-system charset))
 496                encoding flowed coded)
 497           (cond ((eq coding 'ascii)
 498                  (setq charset nil
 499                        coding nil))
 500                 (charset
 501                  ;; The value of `charset' might be a bogus alias that
 502                  ;; `mm-charset-synonym-alist' provides, like `utf8',
 503                  ;; so we prefer the MIME charset that Emacs knows for
 504                  ;; the coding system `coding'.
 505                  (setq charset (or (mm-coding-system-to-mime-charset coding)
 506                                    (intern (downcase charset))))))
 507           (if (and (not raw)
 508                    (member (car (split-string type "/")) '("text" "message")))
 509               (progn
 510                 (with-temp-buffer
 511                   (cond
 512                    ((cdr (assq 'buffer cont))
 513                     (insert-buffer-substring (cdr (assq 'buffer cont))))
 514                    ((and filename
 515                          (not (equal (cdr (assq 'nofile cont)) "yes")))
 516                     (let ((coding-system-for-read coding))
 517                       (mm-insert-file-contents filename)))
 518                    ((eq 'mml (car cont))
 519                     (insert (cdr (assq 'contents cont))))
 520                    (t
 521                     (save-restriction
 522                       (narrow-to-region (point) (point))
 523                       (insert (cdr (assq 'contents cont)))
 524                       ;; Remove quotes from quoted tags.
 525                       (goto-char (point-min))
 526                       (while (re-search-forward
 527                               "<#!+/?\\(part\\|multipart\\|external\\|mml\\)"
 528                               nil t)
 529                         (delete-region (+ (match-beginning 0) 2)
 530                                        (+ (match-beginning 0) 3))))))
 531                   (cond
 532                    ((eq (car cont) 'mml)
 533                     (let ((mml-boundary (mml-compute-boundary cont))
 534                           ;; It is necessary for the case where this
 535                           ;; function is called recursively since
 536                           ;; `m-g-d-t' will be bound to "message/rfc822"
 537                           ;; when encoding an article to be forwarded.
 538                           (mml-generate-default-type "text/plain"))
 539                       (mml-to-mime)
 540                       ;; Update handle so mml-compute-boundary can
 541                       ;; detect collisions with the nested parts.
 542                       (setcdr (assoc 'contents cont) (buffer-string)))
 543                     (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 544                       ;; ignore 0x1b, it is part of iso-2022-jp
 545                       (setq encoding (mm-body-7-or-8))))
 546                    ((string= (car (split-string type "/")) "message")
 547                     (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 548                       ;; ignore 0x1b, it is part of iso-2022-jp
 549                       (setq encoding (mm-body-7-or-8))))
 550                    (t
 551                     ;; Only perform format=flowed filling on text/plain
 552                     ;; parts where there either isn't a format parameter
 553                     ;; in the mml tag or it says "flowed" and there
 554                     ;; actually are hard newlines in the text.
 555                     (let (use-hard-newlines)
 556                       (when (and mml-enable-flowed
 557                                  (string= type "text/plain")
 558                                  (not (string= (cdr (assq 'sign cont)) "pgp"))
 559                                  (or (null (assq 'format cont))
 560                                      (string= (cdr (assq 'format cont))
 561                                               "flowed"))
 562                                  (setq use-hard-newlines
 563                                        (text-property-any
 564                                         (point-min) (point-max) 'hard 't)))
 565                         (fill-flowed-encode)
 566                         ;; Indicate that `mml-insert-mime-headers' should
 567                         ;; insert a "; format=flowed" string unless the
 568                         ;; user has already specified it.
 569                         (setq flowed (null (assq 'format cont)))))
 570                     ;; Prefer `utf-8' for text/calendar parts.
 571                     (if (or charset
 572                             (not (string= type "text/calendar")))
 573                         (setq charset (mm-encode-body charset))
 574                       (let ((mm-coding-system-priorities
 575                              (cons 'utf-8 mm-coding-system-priorities)))
 576                         (setq charset (mm-encode-body))))
 577                     (setq encoding (mm-body-encoding
 578                                     charset (cdr (assq 'encoding cont))))))
 579                   (setq coded (buffer-string)))
 580                 (mml-insert-mime-headers cont type charset encoding flowed)
 581                 (insert "\n")
 582                 (insert coded))
 583             (mm-with-unibyte-buffer
 584               (cond
 585                ((cdr (assq 'buffer cont))
 586                 (insert (mm-string-as-unibyte
 587                          (with-current-buffer (cdr (assq 'buffer cont))
 588                            (buffer-string)))))
 589                ((and filename
 590                      (not (equal (cdr (assq 'nofile cont)) "yes")))
 591                 (let ((coding-system-for-read mm-binary-coding-system))
 592                   (mm-insert-file-contents filename nil nil nil nil t))
 593                 (unless charset
 594                   (setq charset (mm-coding-system-to-mime-charset
 595                                  (mm-find-buffer-file-coding-system
 596                                   filename)))))
 597                (t
 598                 (let ((contents (cdr (assq 'contents cont))))
 599                   (if (if (featurep 'xemacs)
 600                           (string-match "[^\000-\377]" contents)
 601                         (mm-multibyte-string-p contents))
 602                       (progn
 603                         (mm-enable-multibyte)
 604                         (insert contents)
 605                         (unless raw
 606                           (setq charset (mm-encode-body charset))))
 607                     (insert contents)))))
 608               (if (setq encoding (cdr (assq 'encoding cont)))
 609                   (setq encoding (intern (downcase encoding))))
 610               (setq encoding (mm-encode-buffer type encoding)
 611                     coded (mm-string-as-multibyte (buffer-string))))
 612             (mml-insert-mime-headers cont type charset encoding nil)
 613             (insert "\n" coded))))
 614        ((eq (car cont) 'external)
 615         (insert "Content-Type: message/external-body")
 616         (let ((parameters (mml-parameter-string
 617                            cont '(expiration size permission)))
 618               (name (cdr (assq 'name cont)))
 619               (url (cdr (assq 'url cont))))
 620           (when name
 621             (setq name (mml-parse-file-name name))
 622             (if (stringp name)
 623                 (mml-insert-parameter
 624                  (mail-header-encode-parameter "name" name)
 625                  "access-type=local-file")
 626               (mml-insert-parameter
 627                (mail-header-encode-parameter
 628                 "name" (file-name-nondirectory (nth 2 name)))
 629                (mail-header-encode-parameter "site" (nth 1 name))
 630                (mail-header-encode-parameter
 631                 "directory" (file-name-directory (nth 2 name))))
 632               (mml-insert-parameter
 633                (concat "access-type="
 634                        (if (member (nth 0 name) '("ftp@" "anonymous@"))
 635                            "anon-ftp"
 636                          "ftp")))))
 637           (when url
 638             (mml-insert-parameter
 639              (mail-header-encode-parameter "url" url)
 640              "access-type=url"))
 641           (when parameters
 642             (mml-insert-parameter-string
 643              cont '(expiration size permission)))
 644           (insert "\n\n")
 645           (insert "Content-Type: "
 646                   (or (cdr (assq 'type cont))
 647                       (if name
 648                           (or (mm-default-file-encoding name)
 649                               "application/octet-stream")
 650                         "text/plain"))
 651                   "\n")
 652           (insert "Content-ID: " (message-make-message-id) "\n")
 653           (insert "Content-Transfer-Encoding: "
 654                   (or (cdr (assq 'encoding cont)) "binary"))
 655           (insert "\n\n")
 656           (insert (or (cdr (assq 'contents cont))))
 657           (insert "\n")))
 658        ((eq (car cont) 'multipart)
 659         (let* ((type (or (cdr (assq 'type cont)) "mixed"))
 660                (mml-generate-default-type (if (equal type "digest")
 661                                               "message/rfc822"
 662                                             "text/plain"))
 663                (handler (assoc type mml-generate-multipart-alist)))
 664           (if handler
 665               (funcall (cdr handler) cont)
 666             ;; No specific handler.  Use default one.
 667             (let ((mml-boundary (mml-compute-boundary cont)))
 668               (insert (format "Content-Type: multipart/%s; boundary=\"%s\""
 669                               type mml-boundary)
 670                       (if (cdr (assq 'start cont))
 671                           (format "; start=\"%s\"\n" (cdr (assq 'start cont)))
 672                         "\n"))
 673               (let ((cont cont) part)
 674                 (while (setq part (pop cont))
 675                   ;; Skip `multipart' and attributes.
 676                   (when (and (consp part) (consp (cdr part)))
 677                     (insert "\n--" mml-boundary "\n")
 678                     (mml-generate-mime-1 part)
 679                     (goto-char (point-max)))))
 680               (insert "\n--" mml-boundary "--\n")))))
 681        (t
 682         (error "Invalid element: %S" cont)))
 683       ;; handle sign & encrypt tags in a semi-smart way.
 684       (let ((sign-item (assoc (cdr (assq 'sign cont)) mml-sign-alist))
 685             (encrypt-item (assoc (cdr (assq 'encrypt cont))
 686                                  mml-encrypt-alist))
 687             sender recipients)
 688         (when (or sign-item encrypt-item)
 689           (when (setq sender (cdr (assq 'sender cont)))
 690             (message-options-set 'mml-sender sender)
 691             (message-options-set 'message-sender sender))
 692           (if (setq recipients (cdr (assq 'recipients cont)))
 693               (message-options-set 'message-recipients recipients))
 694           (let ((style (mml-signencrypt-style
 695                         (first (or sign-item encrypt-item)))))
 696             ;; check if: we're both signing & encrypting, both methods
 697             ;; are the same (why would they be different?!), and that
 698             ;; the signencrypt style allows for combined operation.
 699             (if (and sign-item encrypt-item (equal (first sign-item)
 700                                                    (first encrypt-item))
 701                      (equal style 'combined))
 702                 (funcall (nth 1 encrypt-item) cont t)
 703               ;; otherwise, revert to the old behavior.
 704               (when sign-item
 705                 (funcall (nth 1 sign-item) cont))
 706               (when encrypt-item
 707                 (funcall (nth 1 encrypt-item) cont)))))))))
 708
 709 (defun mml-compute-boundary (cont)
 710   "Return a unique boundary that does not exist in CONT."
 711   (let ((mml-boundary (funcall mml-boundary-function
 712                                (incf mml-multipart-number))))
 713     ;; This function tries again and again until it has found
 714     ;; a unique boundary.
 715     (while (not (catch 'not-unique
 716                   (mml-compute-boundary-1 cont))))
 717     mml-boundary))
 718
 719 (defun mml-compute-boundary-1 (cont)
 720   (let (filename)
 721     (cond
 722      ((member (car cont) '(part mml))
 723       (with-temp-buffer
 724         (cond
 725          ((cdr (assq 'buffer cont))
 726           (insert-buffer-substring (cdr (assq 'buffer cont))))
 727          ((and (setq filename (cdr (assq 'filename cont)))
 728                (not (equal (cdr (assq 'nofile cont)) "yes")))
 729           (mm-insert-file-contents filename nil nil nil nil t))
 730          (t
 731           (insert (cdr (assq 'contents cont)))))
 732         (goto-char (point-min))
 733         (when (re-search-forward (concat "^--" (regexp-quote mml-boundary))
 734                                  nil t)
 735           (setq mml-boundary (funcall mml-boundary-function
 736                                       (incf mml-multipart-number)))
 737           (throw 'not-unique nil))))
 738      ((eq (car cont) 'multipart)
 739       (mapc 'mml-compute-boundary-1 (cddr cont))))
 740     t))
 741
 742 (defun mml-make-boundary (number)
 743   (concat (make-string (% number 60) ?=)
 744           (if (> number 17)
 745               (format "%x" number)
 746             "")
 747           mml-base-boundary))
 748
 749 (defun mml-content-disposition (type &optional filename)
 750   "Return a default disposition name suitable to TYPE or FILENAME."
 751   (let ((defs mml-content-disposition-alist)
 752         disposition def types)
 753     (while (and (not disposition) defs)
 754       (setq def (pop defs))
 755       (cond ((stringp (car def))
 756              (when (and filename
 757                         (string-match (car def) filename))
 758                (setq disposition (cdr def))))
 759             ((consp (cdr def))
 760              (when (string= (car (setq types (split-string type "/")))
 761                             (car def))
 762                (setq type (cadr types)
 763                      types (cdr def))
 764                (while (and (not disposition) types)
 765                  (setq def (pop types))
 766                  (when (or (eq (car def) t) (string= type (car def)))
 767                    (setq disposition (cdr def))))))
 768             (t
 769              (when (or (eq (car def) t) (string= type (car def)))
 770                (setq disposition (cdr def))))))
 771     (or disposition "attachment")))
 772
 773 (defun mml-insert-mime-headers (cont type charset encoding flowed)
 774   (let (parameters id disposition description)
 775     (setq parameters
 776           (mml-parameter-string
 777            cont mml-content-type-parameters))
 778     (when (or charset
 779               parameters
 780               flowed
 781               (not (equal type mml-generate-default-type))
 782               mml-insert-mime-headers-always)
 783       (when (consp charset)
 784         (error
 785          "Can't encode a part with several charsets"))
 786       (insert "Content-Type: " type)
 787       (when charset
 788         (mml-insert-parameter
 789          (mail-header-encode-parameter "charset" (symbol-name charset))))
 790       (when flowed
 791         (mml-insert-parameter "format=flowed"))
 792       (when parameters
 793         (mml-insert-parameter-string
 794          cont mml-content-type-parameters))
 795       (insert "\n"))
 796     (when (setq id (cdr (assq 'id cont)))
 797       (insert "Content-ID: " id "\n"))
 798     (setq parameters
 799           (mml-parameter-string
 800            cont mml-content-disposition-parameters))
 801     (when (or (setq disposition (cdr (assq 'disposition cont)))
 802               parameters)
 803       (insert "Content-Disposition: "
 804               (or disposition
 805                   (mml-content-disposition type (cdr (assq 'filename cont)))))
 806       (when parameters
 807         (mml-insert-parameter-string
 808          cont mml-content-disposition-parameters))
 809       (insert "\n"))
 810     (unless (eq encoding '7bit)
 811       (insert (format "Content-Transfer-Encoding: %s\n" encoding)))
 812     (when (setq description (cdr (assq 'description cont)))
 813       (insert "Content-Description: ")
 814       (setq description (prog1
 815                             (point)
 816                           (insert description "\n")))
 817       (mail-encode-encoded-word-region description (point)))))
 818
 819 (defun mml-parameter-string (cont types)
 820   (let ((string "")
 821         value type)
 822     (while (setq type (pop types))
 823       (when (setq value (cdr (assq type cont)))
 824         ;; Strip directory component from the filename parameter.
 825         (when (eq type 'filename)
 826           (setq value (file-name-nondirectory value)))
 827         (setq string (concat string "; "
 828                              (mail-header-encode-parameter
 829                               (symbol-name type) value)))))
 830     (when (not (zerop (length string)))
 831       string)))
 832
 833 (defun mml-insert-parameter-string (cont types)
 834   (let (value type)
 835     (while (setq type (pop types))
 836       (when (setq value (cdr (assq type cont)))
 837         ;; Strip directory component from the filename parameter.
 838         (when (eq type 'filename)
 839           (setq value (file-name-nondirectory value)))
 840         (mml-insert-parameter
 841          (mail-header-encode-parameter
 842           (symbol-name type) value))))))
 843
 844 (defvar ange-ftp-name-format)
 845 (defvar efs-path-regexp)
 846
 847 (defun mml-parse-file-name (path)
 848   (if (if (boundp 'efs-path-regexp)
 849           (string-match efs-path-regexp path)
 850         (if (boundp 'ange-ftp-name-format)
 851             (string-match (car ange-ftp-name-format) path)))
 852       (list (match-string 1 path) (match-string 2 path)
 853             (substring path (1+ (match-end 2))))
 854     path))
 855
 856 (defun mml-insert-buffer (buffer)
 857   "Insert BUFFER at point and quote any MML markup."
 858   (save-restriction
 859     (narrow-to-region (point) (point))
 860     (insert-buffer-substring buffer)
 861     (mml-quote-region (point-min) (point-max))
 862     (goto-char (point-max))))
 863
 864 ;;;
 865 ;;; Transforming MIME to MML
 866 ;;;
 867
 868 ;; message-narrow-to-head autoloads message.
 869 (declare-function message-remove-header "message"
 870                   (header &optional is-regexp first reverse))
 871
 872 (defun mime-to-mml (&optional handles)
 873   "Translate the current buffer (which should be a message) into MML.
 874 If HANDLES is non-nil, use it instead reparsing the buffer."
 875   ;; First decode the head.
 876   (save-restriction
 877     (message-narrow-to-head)
 878     (let ((rfc2047-quote-decoded-words-containing-tspecials t))
 879       (mail-decode-encoded-word-region (point-min) (point-max))))
 880   (unless handles
 881     (setq handles (mm-dissect-buffer t)))
 882   (goto-char (point-min))
 883   (search-forward "\n\n" nil t)
 884   (delete-region (point) (point-max))
 885   (if (stringp (car handles))
 886       (mml-insert-mime handles)
 887     (mml-insert-mime handles t))
 888   (mm-destroy-parts handles)
 889   (save-restriction
 890     (message-narrow-to-head)
 891     ;; Remove them, they are confusing.
 892     (message-remove-header "Content-Type")
 893     (message-remove-header "MIME-Version")
 894     (message-remove-header "Content-Disposition")
 895     (message-remove-header "Content-Transfer-Encoding")))
 896
 897 (autoload 'message-encode-message-body "message")
 898 (declare-function message-narrow-to-headers-or-head "message" ())
 899
 900 (defun mml-to-mime ()
 901   "Translate the current buffer from MML to MIME."
 902   ;; `message-encode-message-body' will insert an encoded Content-Description
 903   ;; header in the message header if the body contains a single part
 904   ;; that is specified by a user with a MML tag containing a description
 905   ;; token.  So, we encode the message header first to prevent the encoded
 906   ;; Content-Description header from being encoded again.
 907   (save-restriction
 908     (message-narrow-to-headers-or-head)
 909     ;; Skip past any From_ headers.
 910     (while (looking-at "From ")
 911       (forward-line 1))
 912     (let ((mail-parse-charset message-default-charset))
 913       (mail-encode-encoded-word-buffer)))
 914   (message-encode-message-body))
 915
 916 (defun mml-insert-mime (handle &optional no-markup)
 917   (let (textp buffer mmlp)
 918     ;; Determine type and stuff.
 919     (unless (stringp (car handle))
 920       (unless (setq textp (equal (mm-handle-media-supertype handle) "text"))
 921         (with-current-buffer (setq buffer (mml-generate-new-buffer " *mml*"))
 922           (if (eq (mail-content-type-get (mm-handle-type handle) 'charset)
 923                   'gnus-decoded)
 924               ;; A part that mm-uu dissected from a non-MIME message
 925               ;; because of `gnus-article-emulate-mime'.
 926               (progn
 927                 (mm-enable-multibyte)
 928                 (insert-buffer-substring (mm-handle-buffer handle)))
 929             (mm-insert-part handle 'no-cache)
 930             (if (setq mmlp (equal (mm-handle-media-type handle)
 931                                   "message/rfc822"))
 932                 (mime-to-mml))))))
 933     (if mmlp
 934         (mml-insert-mml-markup handle nil t t)
 935       (unless (and no-markup
 936                    (equal (mm-handle-media-type handle) "text/plain"))
 937         (mml-insert-mml-markup handle buffer textp)))
 938     (cond
 939      (mmlp
 940       (insert-buffer-substring buffer)
 941       (goto-char (point-max))
 942       (insert "<#/mml>\n"))
 943      ((stringp (car handle))
 944       (mapc 'mml-insert-mime (cdr handle))
 945       (insert "<#/multipart>\n"))
 946      (textp
 947       (let ((charset (mail-content-type-get
 948                       (mm-handle-type handle) 'charset))
 949             (start (point)))
 950         (if (eq charset 'gnus-decoded)
 951             (mm-insert-part handle)
 952           (insert (mm-decode-string (mm-get-part handle) charset)))
 953         (mml-quote-region start (point)))
 954       (goto-char (point-max)))
 955      (t
 956       (insert "<#/part>\n")))))
 957
 958 (defun mml-insert-mml-markup (handle &optional buffer nofile mmlp)
 959   "Take a MIME handle and insert an MML tag."
 960   (if (stringp (car handle))
 961       (progn
 962         (insert "<#multipart type=" (mm-handle-media-subtype handle))
 963         (let ((start (mm-handle-multipart-ctl-parameter handle 'start)))
 964           (when start
 965             (insert " start=\"" start "\"")))
 966         (insert ">\n"))
 967     (if mmlp
 968         (insert "<#mml type=" (mm-handle-media-type handle))
 969       (insert "<#part type=" (mm-handle-media-type handle)))
 970     (dolist (elem (append (cdr (mm-handle-type handle))
 971                           (cdr (mm-handle-disposition handle))))
 972       (unless (symbolp (cdr elem))
 973         (insert " " (symbol-name (car elem)) "=\"" (cdr elem) "\"")))
 974     (when (mm-handle-id handle)
 975       (insert " id=\"" (mm-handle-id handle) "\""))
 976     (when (mm-handle-disposition handle)
 977       (insert " disposition=" (car (mm-handle-disposition handle))))
 978     (when buffer
 979       (insert " buffer=\"" (buffer-name buffer) "\""))
 980     (when nofile
 981       (insert " nofile=yes"))
 982     (when (mm-handle-description handle)
 983       (insert " description=\"" (mm-handle-description handle) "\""))
 984     (insert ">\n")))
 985
 986 (defun mml-insert-parameter (&rest parameters)
 987   "Insert PARAMETERS in a nice way."
 988   (let (start end)
 989     (dolist (param parameters)
 990       (insert ";")
 991       (setq start (point))
 992       (insert " " param)
 993       (setq end (point))
 994       (goto-char start)
 995       (end-of-line)
 996       (if (> (current-column) 76)
 997           (progn
 998             (goto-char start)
 999             (insert "\n")
1000             (goto-char (1+ end)))
1001         (goto-char end)))))
1002
1003 ;;;
1004 ;;; Mode for inserting and editing MML forms
1005 ;;;
1006
1007 (defvar mml-mode-map
1008   (let ((sign (make-sparse-keymap))
1009         (encrypt (make-sparse-keymap))
1010         (signpart (make-sparse-keymap))
1011         (encryptpart (make-sparse-keymap))
1012         (map (make-sparse-keymap))
1013         (main (make-sparse-keymap)))
1014     (define-key map "\C-s" 'mml-secure-message-sign)
1015     (define-key map "\C-c" 'mml-secure-message-encrypt)
1016     (define-key map "\C-e" 'mml-secure-message-sign-encrypt)
1017     (define-key map "\C-p\C-s" 'mml-secure-sign)
1018     (define-key map "\C-p\C-c" 'mml-secure-encrypt)
1019     (define-key sign "p" 'mml-secure-message-sign-pgpmime)
1020     (define-key sign "o" 'mml-secure-message-sign-pgp)
1021     (define-key sign "s" 'mml-secure-message-sign-smime)
1022     (define-key signpart "p" 'mml-secure-sign-pgpmime)
1023     (define-key signpart "o" 'mml-secure-sign-pgp)
1024     (define-key signpart "s" 'mml-secure-sign-smime)
1025     (define-key encrypt "p" 'mml-secure-message-encrypt-pgpmime)
1026     (define-key encrypt "o" 'mml-secure-message-encrypt-pgp)
1027     (define-key encrypt "s" 'mml-secure-message-encrypt-smime)
1028     (define-key encryptpart "p" 'mml-secure-encrypt-pgpmime)
1029     (define-key encryptpart "o" 'mml-secure-encrypt-pgp)
1030     (define-key encryptpart "s" 'mml-secure-encrypt-smime)
1031     (define-key map "\C-n" 'mml-unsecure-message)
1032     (define-key map "f" 'mml-attach-file)
1033     (define-key map "b" 'mml-attach-buffer)
1034     (define-key map "e" 'mml-attach-external)
1035     (define-key map "q" 'mml-quote-region)
1036     (define-key map "m" 'mml-insert-multipart)
1037     (define-key map "p" 'mml-insert-part)
1038     (define-key map "v" 'mml-validate)
1039     (define-key map "P" 'mml-preview)
1040     (define-key map "s" sign)
1041     (define-key map "S" signpart)
1042     (define-key map "c" encrypt)
1043     (define-key map "C" encryptpart)
1044     ;;(define-key map "n" 'mml-narrow-to-part)
1045     ;; `M-m' conflicts with `back-to-indentation'.
1046     ;; (define-key main "\M-m" map)
1047     (define-key main "\C-c\C-m" map)
1048     main))
1049
1050 (easy-menu-define
1051   mml-menu mml-mode-map ""
1052   `("Attachments"
1053     ["Attach File..." mml-attach-file
1054      ,@(if (featurep 'xemacs) '(t)
1055          '(:help "Attach a file at point"))]
1056     ["Attach Buffer..." mml-attach-buffer
1057      ,@(if (featurep 'xemacs) '(t)
1058          '(:help "Attach a buffer to the outgoing message"))]
1059     ["Attach External..." mml-attach-external
1060      ,@(if (featurep 'xemacs) '(t)
1061          '(:help "Attach reference to an external file"))]
1062     ;; FIXME: Is it possible to do this without using
1063     ;; `gnus-gcc-externalize-attachments'?
1064     ["Externalize Attachments"
1065      (lambda ()
1066        (interactive)
1067        (if (not (and (boundp 'gnus-gcc-externalize-attachments)
1068                      (memq gnus-gcc-externalize-attachments
1069                            '(all t nil))))
1070            ;; Stupid workaround for XEmacs not honoring :visible.
1071            (message "Can't handle this value of `gnus-gcc-externalize-attachments'")
1072          (setq gnus-gcc-externalize-attachments
1073                (not gnus-gcc-externalize-attachments))
1074          (message "gnus-gcc-externalize-attachments is `%s'."
1075                   gnus-gcc-externalize-attachments)))
1076      ;; XEmacs barfs on :visible.
1077      ,@(if (featurep 'xemacs) nil
1078          '(:visible (and (boundp 'gnus-gcc-externalize-attachments)
1079                          (memq gnus-gcc-externalize-attachments
1080                                '(all t nil)))))
1081      :style toggle
1082      :selected gnus-gcc-externalize-attachments
1083      ,@(if (featurep 'xemacs) nil
1084          '(:help "Save attachments as external parts in Gcc copies"))]
1085     "----"
1086     ;;
1087     ("Change Security Method"
1088      ["PGP/MIME"
1089       (lambda () (interactive) (setq mml-secure-method "pgpmime"))
1090       ,@(if (featurep 'xemacs) nil
1091           '(:help "Set Security Method to PGP/MIME"))
1092       :style radio
1093       :selected (equal mml-secure-method "pgpmime") ]
1094      ["S/MIME"
1095       (lambda () (interactive) (setq mml-secure-method "smime"))
1096       ,@(if (featurep 'xemacs) nil
1097           '(:help "Set Security Method to S/MIME"))
1098       :style radio
1099       :selected (equal mml-secure-method "smime") ]
1100      ["Inline PGP"
1101       (lambda () (interactive) (setq mml-secure-method "pgp"))
1102       ,@(if (featurep 'xemacs) nil
1103           '(:help "Set Security Method to inline PGP"))
1104       :style radio
1105       :selected (equal mml-secure-method "pgp") ] )
1106     ;;
1107     ["Sign Message" mml-secure-message-sign t]
1108     ["Encrypt Message" mml-secure-message-encrypt t]
1109     ["Sign and Encrypt Message" mml-secure-message-sign-encrypt t]
1110     ["Encrypt/Sign off" mml-unsecure-message
1111      ,@(if (featurep 'xemacs) '(t)
1112          '(:help "Don't Encrypt/Sign Message"))]
1113     ;; Do we have separate encrypt and encrypt/sign commands for parts?
1114     ["Sign Part" mml-secure-sign t]
1115     ["Encrypt Part" mml-secure-encrypt t]
1116     "----"
1117     ;; Maybe we could remove these, because people who write MML most probably
1118     ;; don't use the menu:
1119     ["Insert Part..." mml-insert-part
1120      :active (message-in-body-p)]
1121     ["Insert Multipart..." mml-insert-multipart
1122      :active (message-in-body-p)]
1123     ;;
1124     ;;["Narrow" mml-narrow-to-part t]
1125     ["Quote MML in region" mml-quote-region
1126      :active (message-mark-active-p)
1127      ,@(if (featurep 'xemacs) nil
1128          '(:help "Quote MML tags in region"))]
1129     ["Validate MML" mml-validate t]
1130     ["Preview" mml-preview t]
1131     "----"
1132     ["Emacs MIME manual" (lambda () (interactive) (message-info 4))
1133      ,@(if (featurep 'xemacs) '(t)
1134          '(:help "Display the Emacs MIME manual"))]
1135     ["PGG manual" (lambda () (interactive) (message-info mml2015-use))
1136      ;; XEmacs barfs on :visible.
1137      ,@(if (featurep 'xemacs) nil
1138          '(:visible (and (boundp 'mml2015-use) (equal mml2015-use 'pgg))))
1139      ,@(if (featurep 'xemacs) '(t)
1140          '(:help "Display the PGG manual"))]
1141     ["EasyPG manual" (lambda () (interactive) (require 'mml2015) (message-info mml2015-use))
1142      ;; XEmacs barfs on :visible.
1143      ,@(if (featurep 'xemacs) nil
1144          '(:visible (and (boundp 'mml2015-use) (equal mml2015-use 'epg))))
1145      ,@(if (featurep 'xemacs) '(t)
1146          '(:help "Display the EasyPG manual"))]))
1147
1148 (define-minor-mode mml-mode
1149   "Minor mode for editing MML.
1150 MML is the MIME Meta Language, a minor mode for composing MIME articles.
1151 See Info node `(emacs-mime)Composing'.
1152
1153 \\{mml-mode-map}"
1154   :lighter " MML" :keymap mml-mode-map
1155   (when mml-mode
1156     (easy-menu-add mml-menu mml-mode-map)
1157     (when (boundp 'dnd-protocol-alist)
1158       (set (make-local-variable 'dnd-protocol-alist)
1159            (append mml-dnd-protocol-alist dnd-protocol-alist)))))
1160
1161 ;;;
1162 ;;; Helper functions for reading MIME stuff from the minibuffer and
1163 ;;; inserting stuff to the buffer.
1164 ;;;
1165
1166 (defcustom mml-default-directory mm-default-directory
1167   "The default directory where mml will find files.
1168 If not set, `default-directory' will be used."
1169   :type '(choice directory (const :tag "Default" nil))
1170   :version "23.1" ;; No Gnus
1171   :group 'message)
1172
1173 (defun mml-minibuffer-read-file (prompt)
1174   (let* ((completion-ignored-extensions nil)
1175          (file (read-file-name prompt
1176                                (or mml-default-directory default-directory)
1177                                nil t)))
1178     ;; Prevent some common errors.  This is inspired by similar code in
1179     ;; VM.
1180     (when (file-directory-p file)
1181       (error "%s is a directory, cannot attach" file))
1182     (unless (file-exists-p file)
1183       (error "No such file: %s" file))
1184     (unless (file-readable-p file)
1185       (error "Permission denied: %s" file))
1186     file))
1187
1188 (declare-function mailcap-parse-mimetypes "mailcap" (&optional path force))
1189 (declare-function mailcap-mime-types "mailcap" ())
1190
1191 (defun mml-minibuffer-read-type (name &optional default)
1192   (require 'mailcap)
1193   (mailcap-parse-mimetypes)
1194   (let* ((default (or default
1195                       (mm-default-file-encoding name)
1196                       ;; Perhaps here we should check what the file
1197                       ;; looks like, and offer text/plain if it looks
1198                       ;; like text/plain.
1199                       "application/octet-stream"))
1200          (string (gnus-completing-read
1201                   "Content type"
1202                   (mailcap-mime-types)
1203                   nil nil nil default)))
1204     (if (not (equal string ""))
1205         string
1206       default)))
1207
1208 (defun mml-minibuffer-read-description ()
1209   (let ((description (read-string "One line description: ")))
1210     (when (string-match "\\`[ \t]*\\'" description)
1211       (setq description nil))
1212     description))
1213
1214 (defun mml-minibuffer-read-disposition (type &optional default filename)
1215   (unless default
1216     (setq default (mml-content-disposition type filename)))
1217   (let ((disposition (gnus-completing-read
1218                       "Disposition"
1219                       '("attachment" "inline")
1220                       t nil nil default)))
1221     (if (not (equal disposition ""))
1222         disposition
1223       default)))
1224
1225 (defun mml-quote-region (beg end)
1226   "Quote the MML tags in the region."
1227   (interactive "r")
1228   (save-excursion
1229     (save-restriction
1230       ;; Temporarily narrow the region to defend from changes
1231       ;; invalidating END.
1232       (narrow-to-region beg end)
1233       (goto-char (point-min))
1234       ;; Quote parts.
1235       (while (re-search-forward
1236               "<#!*/?\\(multipart\\|part\\|external\\|mml\\)" nil t)
1237         ;; Insert ! after the #.
1238         (goto-char (+ (match-beginning 0) 2))
1239         (insert "!")))))
1240
1241 (defun mml-insert-tag (name &rest plist)
1242   "Insert an MML tag described by NAME and PLIST."
1243   (when (symbolp name)
1244     (setq name (symbol-name name)))
1245   (insert "<#" name)
1246   (while plist
1247     (let ((key (pop plist))
1248           (value (pop plist)))
1249       (when value
1250         ;; Quote VALUE if it contains suspicious characters.
1251         (when (string-match "[\"'\\~/*;() \t\n]" value)
1252           (setq value (with-output-to-string
1253                         (let (print-escape-nonascii)
1254                           (prin1 value)))))
1255         (insert (format " %s=%s" key value)))))
1256   (insert ">\n"))
1257
1258 (defun mml-insert-empty-tag (name &rest plist)
1259   "Insert an empty MML tag described by NAME and PLIST."
1260   (when (symbolp name)
1261     (setq name (symbol-name name)))
1262   (apply #'mml-insert-tag name plist)
1263   (insert "<#/" name ">\n"))
1264
1265 ;;; Attachment functions.
1266
1267 (defcustom mml-dnd-protocol-alist
1268   '(("^file:///" . mml-dnd-attach-file)
1269     ("^file://"  . dnd-open-file)
1270     ("^file:"    . mml-dnd-attach-file))
1271   "The functions to call when a drop in `mml-mode' is made.
1272 See `dnd-protocol-alist' for more information.  When nil, behave
1273 as in other buffers."
1274   :type '(choice (repeat (cons (regexp) (function)))
1275                  (const :tag "Behave as in other buffers" nil))
1276   :version "22.1" ;; Gnus 5.10.9
1277   :group 'message)
1278
1279 (defcustom mml-dnd-attach-options nil
1280   "Which options should be queried when attaching a file via drag and drop.
1281
1282 If it is a list, valid members are `type', `description' and
1283 `disposition'.  `disposition' implies `type'.  If it is nil,
1284 don't ask for options.  If it is t, ask the user whether or not
1285 to specify options."
1286   :type '(choice
1287           (const :tag "None" nil)
1288           (const :tag "Query" t)
1289           (list :value (type description disposition)
1290            (set :inline t
1291                 (const type)
1292                 (const description)
1293                 (const disposition))))
1294   :version "22.1" ;; Gnus 5.10.9
1295   :group 'message)
1296
1297 (defun mml-attach-file (file &optional type description disposition)
1298   "Attach a file to the outgoing MIME message.
1299 The file is not inserted or encoded until you send the message with
1300 `\\[message-send-and-exit]' or `\\[message-send]'.
1301
1302 FILE is the name of the file to attach.  TYPE is its
1303 content-type, a string of the form \"type/subtype\".  DESCRIPTION
1304 is a one-line description of the attachment.  The DISPOSITION
1305 specifies how the attachment is intended to be displayed.  It can
1306 be either \"inline\" (displayed automatically within the message
1307 body) or \"attachment\" (separate from the body)."
1308   (interactive
1309    (let* ((file (mml-minibuffer-read-file "Attach file: "))
1310           (type (mml-minibuffer-read-type file))
1311           (description (mml-minibuffer-read-description))
1312           (disposition (mml-minibuffer-read-disposition type nil file)))
1313      (list file type description disposition)))
1314   ;; Don't move point if this command is invoked inside the message header.
1315   (let ((head (unless (message-in-body-p)
1316                 (prog1
1317                     (point)
1318                   (goto-char (point-max))))))
1319     (mml-insert-empty-tag 'part
1320                           'type type
1321                           ;; icicles redefines read-file-name and returns a
1322                           ;; string w/ text properties :-/
1323                           'filename (mm-substring-no-properties file)
1324                           'disposition (or disposition "attachment")
1325                           'description description)
1326     (when head
1327       (unless (prog1
1328                   (pos-visible-in-window-p)
1329                 (goto-char head))
1330         (message "The file \"%s\" has been attached at the end of the message"
1331                  (file-name-nondirectory file))))))
1332
1333 (defun mml-dnd-attach-file (uri action)
1334   "Attach a drag and drop file.
1335
1336 Ask for type, description or disposition according to
1337 `mml-dnd-attach-options'."
1338   (let ((file (dnd-get-local-file-name uri t)))
1339     (when (and file (file-regular-p file))
1340       (let ((mml-dnd-attach-options mml-dnd-attach-options)
1341             type description disposition)
1342         (setq mml-dnd-attach-options
1343               (when (and (eq mml-dnd-attach-options t)
1344                          (not
1345                           (y-or-n-p
1346                            "Use default type, disposition and description? ")))
1347                 '(type description disposition)))
1348         (when (or (memq 'type mml-dnd-attach-options)
1349                   (memq 'disposition mml-dnd-attach-options))
1350           (setq type (mml-minibuffer-read-type file)))
1351         (when (memq 'description mml-dnd-attach-options)
1352           (setq description (mml-minibuffer-read-description)))
1353         (when (memq 'disposition mml-dnd-attach-options)
1354           (setq disposition (mml-minibuffer-read-disposition type nil file)))
1355         (mml-attach-file file type description disposition)))))
1356
1357 (defun mml-attach-buffer (buffer &optional type description disposition)
1358   "Attach a buffer to the outgoing MIME message.
1359 BUFFER is the name of the buffer to attach.  See
1360 `mml-attach-file' for details of operation."
1361   (interactive
1362    (let* ((buffer (read-buffer "Attach buffer: "))
1363           (type (mml-minibuffer-read-type buffer "text/plain"))
1364           (description (mml-minibuffer-read-description))
1365           (disposition (mml-minibuffer-read-disposition type nil)))
1366      (list buffer type description disposition)))
1367   ;; Don't move point if this command is invoked inside the message header.
1368   (let ((head (unless (message-in-body-p)
1369                 (prog1
1370                     (point)
1371                   (goto-char (point-max))))))
1372     (mml-insert-empty-tag 'part 'type type 'buffer buffer
1373                           'disposition disposition
1374                           'description description)
1375     (when head
1376       (unless (prog1
1377                   (pos-visible-in-window-p)
1378                 (goto-char head))
1379         (message
1380          "The buffer \"%s\" has been attached at the end of the message"
1381          buffer)))))
1382
1383 (defun mml-attach-external (file &optional type description)
1384   "Attach an external file into the buffer.
1385 FILE is an ange-ftp/efs specification of the part location.
1386 TYPE is the MIME type to use."
1387   (interactive
1388    (let* ((file (mml-minibuffer-read-file "Attach external file: "))
1389           (type (mml-minibuffer-read-type file))
1390           (description (mml-minibuffer-read-description)))
1391      (list file type description)))
1392   ;; Don't move point if this command is invoked inside the message header.
1393   (let ((head (unless (message-in-body-p)
1394                 (prog1
1395                     (point)
1396                   (goto-char (point-max))))))
1397     (mml-insert-empty-tag 'external 'type type 'name file
1398                           'disposition "attachment" 'description description)
1399     (when head
1400       (unless (prog1
1401                   (pos-visible-in-window-p)
1402                 (goto-char head))
1403         (message "The file \"%s\" has been attached at the end of the message"
1404                  (file-name-nondirectory file))))))
1405
1406 (defun mml-insert-multipart (&optional type)
1407   (interactive (if (message-in-body-p)
1408                    (list (gnus-completing-read "Multipart type"
1409                                                '("mixed" "alternative"
1410                                                  "digest" "parallel"
1411                                                  "signed" "encrypted")
1412                                                nil "mixed"))
1413                  (error "Use this command in the message body")))
1414   (or type
1415       (setq type "mixed"))
1416   (mml-insert-empty-tag "multipart" 'type type)
1417   (forward-line -1))
1418
1419 (defun mml-insert-part (&optional type)
1420   (interactive (if (message-in-body-p)
1421                    (list (mml-minibuffer-read-type ""))
1422                  (error "Use this command in the message body")))
1423   (mml-insert-tag 'part 'type type 'disposition "inline"))
1424
1425 (declare-function message-subscribed-p "message" ())
1426 (declare-function message-make-mail-followup-to "message"
1427                   (&optional only-show-subscribed))
1428 (declare-function message-position-on-field "message" (header &rest afters))
1429
1430 (defun mml-preview-insert-mail-followup-to ()
1431   "Insert a Mail-Followup-To header before previewing an article.
1432 Should be adopted if code in `message-send-mail' is changed."
1433   (when (and (message-mail-p)
1434              (message-subscribed-p)
1435              (not (mail-fetch-field "mail-followup-to"))
1436              (message-make-mail-followup-to))
1437     (message-position-on-field "Mail-Followup-To" "X-Draft-From")
1438     (insert (message-make-mail-followup-to))))
1439
1440 (defvar mml-preview-buffer nil)
1441
1442 (autoload 'gnus-make-hashtable "gnus-util")
1443 (autoload 'widget-button-press "wid-edit" nil t)
1444 (declare-function widget-event-point "wid-edit" (event))
1445 ;; If gnus-buffer-configuration is bound this is loaded.
1446 (declare-function gnus-configure-windows "gnus-win" (setting &optional force))
1447 ;; Called after message-mail-p, which autoloads message.
1448 (declare-function message-news-p                "message" ())
1449 (declare-function message-options-set-recipient "message" ())
1450 (declare-function message-generate-headers      "message" (headers))
1451 (declare-function message-sort-headers          "message" ())
1452
1453 (defun mml-preview (&optional raw)
1454   "Display current buffer with Gnus, in a new buffer.
1455 If RAW, display a raw encoded MIME message.
1456
1457 The window layout for the preview buffer is controled by the variables
1458 `special-display-buffer-names', `special-display-regexps', or
1459 `gnus-buffer-configuration' (the first match made will be used),
1460 or the `pop-to-buffer' function."
1461   (interactive "P")
1462   (setq mml-preview-buffer (generate-new-buffer
1463                             (concat (if raw "*Raw MIME preview of "
1464                                       "*MIME preview of ") (buffer-name))))
1465   (require 'gnus-msg)                 ; for gnus-setup-posting-charset
1466   (save-excursion
1467     (let* ((buf (current-buffer))
1468            (article-editing (eq major-mode 'gnus-article-edit-mode))
1469            (message-options message-options)
1470            (message-this-is-mail (message-mail-p))
1471            (message-this-is-news (message-news-p))
1472            (message-posting-charset (or (gnus-setup-posting-charset
1473                                          (save-restriction
1474                                            (message-narrow-to-headers-or-head)
1475                                            (message-fetch-field "Newsgroups")))
1476                                         message-posting-charset)))
1477       (message-options-set-recipient)
1478       (when (boundp 'gnus-buffers)
1479         (push mml-preview-buffer gnus-buffers))
1480       (save-restriction
1481         (widen)
1482         (set-buffer mml-preview-buffer)
1483         (erase-buffer)
1484         (insert-buffer-substring buf))
1485       (mml-preview-insert-mail-followup-to)
1486       (let ((message-deletable-headers (if (message-news-p)
1487                                            nil
1488                                          message-deletable-headers))
1489             (mail-header-separator (if article-editing
1490                                        ""
1491                                      mail-header-separator)))
1492         (message-generate-headers
1493          (copy-sequence (if (message-news-p)
1494                             message-required-news-headers
1495                           message-required-mail-headers)))
1496         (unless article-editing
1497           (if (re-search-forward
1498                (concat "^" (regexp-quote mail-header-separator) "\n") nil t)
1499               (replace-match "\n"))
1500           (setq mail-header-separator ""))
1501         (message-sort-headers)
1502         (mml-to-mime))
1503       (if raw
1504           (when (fboundp 'set-buffer-multibyte)
1505             (let ((s (buffer-string)))
1506               ;; Insert the content into unibyte buffer.
1507               (erase-buffer)
1508               (mm-disable-multibyte)
1509               (insert s)))
1510         (let ((gnus-newsgroup-charset (car message-posting-charset))
1511               gnus-article-prepare-hook gnus-original-article-buffer
1512               gnus-displaying-mime)
1513           (run-hooks 'gnus-article-decode-hook)
1514           (let ((gnus-newsgroup-name "dummy")
1515                 (gnus-newsrc-hashtb (or gnus-newsrc-hashtb
1516                                         (gnus-make-hashtable 5))))
1517             (gnus-article-prepare-display))))
1518       ;; Disable article-mode-map.
1519       (use-local-map nil)
1520       (gnus-make-local-hook 'kill-buffer-hook)
1521       (add-hook 'kill-buffer-hook
1522                 (lambda ()
1523                   (mm-destroy-parts gnus-article-mime-handles)) nil t)
1524       (setq buffer-read-only t)
1525       (local-set-key "q" (lambda () (interactive) (kill-buffer nil)))
1526       (local-set-key "=" (lambda () (interactive) (delete-other-windows)))
1527       (local-set-key "\r"
1528                      (lambda ()
1529                        (interactive)
1530                        (widget-button-press (point))))
1531       (local-set-key gnus-mouse-2
1532                      (lambda (event)
1533                        (interactive "@e")
1534                        (widget-button-press (widget-event-point event) event)))
1535       ;; FIXME: Buffer is in article mode, but most tool bar commands won't
1536       ;; work.  Maybe only keep the following icons: search, print, quit
1537       (goto-char (point-min))))
1538   (if (and (not (mm-special-display-p (buffer-name mml-preview-buffer)))
1539            (boundp 'gnus-buffer-configuration)
1540            (assq 'mml-preview gnus-buffer-configuration))
1541       (let ((gnus-message-buffer (current-buffer)))
1542         (gnus-configure-windows 'mml-preview))
1543     (pop-to-buffer mml-preview-buffer)))
1544
1545 (defun mml-validate ()
1546   "Validate the current MML document."
1547   (interactive)
1548   (mml-parse))
1549
1550 (defun mml-tweak-part (cont)
1551   "Tweak a MML part."
1552   (let ((tweak (cdr (assq 'tweak cont)))
1553         func)
1554     (cond
1555      (tweak
1556       (setq func
1557             (or (cdr (assoc tweak mml-tweak-function-alist))
1558                 (intern tweak))))
1559      (mml-tweak-type-alist
1560       (let ((alist mml-tweak-type-alist)
1561             (type (or (cdr (assq 'type cont)) "text/plain")))
1562         (while alist
1563           (if (string-match (caar alist) type)
1564               (setq func (cdar alist)
1565                     alist nil)
1566             (setq alist (cdr alist)))))))
1567     (if func
1568         (funcall func cont)
1569       cont)
1570     (let ((alist mml-tweak-sexp-alist))
1571       (while alist
1572         (if (eval (caar alist))
1573             (funcall (cdar alist) cont))
1574         (setq alist (cdr alist)))))
1575   cont)
1576
1577 (defun mml-tweak-externalize-attachments (cont)
1578   "Tweak attached files as external parts."
1579   (let (filename-cons)
1580     (when (and (eq (car cont) 'part)
1581                (not (cdr (assq 'buffer cont)))
1582                (and (setq filename-cons (assq 'filename cont))
1583                     (not (equal (cdr (assq 'nofile cont)) "yes"))))
1584       (setcar cont 'external)
1585       (setcar filename-cons 'name))))
1586
1587 (provide 'mml)
1588
1589 ;;; mml.el ends here