lisp/buff-menu.el

   1 ;;; buff-menu.el --- buffer menu main function and support functions -*- coding:utf-8 -*-
   2
   3 ;; Copyright (C) 1985-1987, 1993-1995, 2000-2011
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: convenience
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Edit, delete, or change attributes of all currently active Emacs
  28 ;; buffers from a list summarizing their state.  A good way to browse
  29 ;; any special or scratch buffers you have loaded, since you can't find
  30 ;; them by filename.  The single entry point is `list-buffers',
  31 ;; normally bound to C-x C-b.
  32
  33 ;;; Change Log:
  34
  35 ;; Buffer-menu-view: New function
  36 ;; Buffer-menu-view-other-window: New function
  37
  38 ;; Merged by esr with recent mods to Emacs 19 buff-menu, 23 Mar 1993
  39 ;;
  40 ;; Modified by Bob Weiner, Motorola, Inc., 4/14/89
  41 ;;
  42 ;; Added optional backup argument to 'Buffer-menu-unmark' to make it undelete
  43 ;; current entry and then move to previous one.
  44 ;;
  45 ;; Based on FSF code dating back to 1985.
  46
  47 ;;; Code:
  48
  49 ;;Trying to preserve the old window configuration works well in
  50 ;;simple scenarios, when you enter the buffer menu, use it, and exit it.
  51 ;;But it does strange things when you switch back to the buffer list buffer
  52 ;;with C-x b, later on, when the window configuration is different.
  53 ;;The choice seems to be, either restore the window configuration
  54 ;;in all cases, or in no cases.
  55 ;;I decided it was better not to restore the window config at all. -- rms.
  56
  57 ;;But since then, I changed buffer-menu to use the selected window,
  58 ;;so q now once again goes back to the previous window configuration.
  59
  60 ;;(defvar Buffer-menu-window-config nil
  61 ;;  "Window configuration saved from entry to `buffer-menu'.")
  62
  63 ;; Put buffer *Buffer List* into proper mode right away
  64 ;; so that from now on even list-buffers is enough to get a buffer menu.
  65
  66 (defgroup Buffer-menu nil
  67   "Show a menu of all buffers in a buffer."
  68   :group 'tools
  69   :group 'convenience)
  70
  71 (defcustom Buffer-menu-use-header-line t
  72   "Non-nil means to use an immovable header-line."
  73   :type 'boolean
  74   :group 'Buffer-menu)
  75
  76 (defface buffer-menu-buffer
  77   '((t (:weight bold)))
  78   "Face used to highlight buffer names in the buffer menu."
  79   :group 'Buffer-menu)
  80 (put 'Buffer-menu-buffer 'face-alias 'buffer-menu-buffer)
  81
  82 (defcustom Buffer-menu-buffer+size-width 26
  83   "How wide to jointly make the buffer name and size columns."
  84   :type 'number
  85   :group 'Buffer-menu)
  86
  87 (defcustom Buffer-menu-mode-width 16
  88   "How wide to make the mode name column."
  89   :type 'number
  90   :group 'Buffer-menu)
  91
  92 (defcustom Buffer-menu-use-frame-buffer-list t
  93   "If non-nil, the Buffer Menu uses the selected frame's buffer list.
  94 Buffers that were never selected in that frame are listed at the end.
  95 If the value is nil, the Buffer Menu uses the global buffer list.
  96 This variable matters if the Buffer Menu is sorted by visited order,
  97 as it is by default."
  98   :type 'boolean
  99   :group 'Buffer-menu
 100   :version "22.1")
 101
 102 ;; This should get updated & resorted when you click on a column heading
 103 (defvar Buffer-menu-sort-column nil
 104   "Which column to sort the menu on.
 105 Use 2 to sort by buffer names, or 5 to sort by file names.
 106 A nil value means sort by visited order (the default).")
 107
 108 (defconst Buffer-menu-buffer-column 4)
 109
 110 (defvar Buffer-menu-files-only nil
 111   "Non-nil if the current buffer-menu lists only file buffers.
 112 This variable determines whether reverting the buffer lists only
 113 file buffers.  It affects both manual reverting and reverting by
 114 Auto Revert Mode.")
 115 (make-variable-buffer-local 'Buffer-menu-files-only)
 116
 117 (defvar Buffer-menu--buffers nil
 118   "If non-nil, list of buffers shown in the current buffer-menu.
 119 This variable determines whether reverting the buffer lists only
 120 these buffers.  It affects both manual reverting and reverting by
 121 Auto Revert Mode.")
 122 (make-variable-buffer-local 'Buffer-menu--buffers)
 123
 124 (defvar Info-current-file) ;; from info.el
 125 (defvar Info-current-node) ;; from info.el
 126
 127 (defvar Buffer-menu-mode-map
 128   (let ((map (make-keymap))
 129         (menu-map (make-sparse-keymap)))
 130     (suppress-keymap map t)
 131     (define-key map "v" 'Buffer-menu-select)
 132     (define-key map "2" 'Buffer-menu-2-window)
 133     (define-key map "1" 'Buffer-menu-1-window)
 134     (define-key map "f" 'Buffer-menu-this-window)
 135     (define-key map "e" 'Buffer-menu-this-window)
 136     (define-key map "\C-m" 'Buffer-menu-this-window)
 137     (define-key map "o" 'Buffer-menu-other-window)
 138     (define-key map "\C-o" 'Buffer-menu-switch-other-window)
 139     (define-key map "s" 'Buffer-menu-save)
 140     (define-key map "d" 'Buffer-menu-delete)
 141     (define-key map "k" 'Buffer-menu-delete)
 142     (define-key map "\C-d" 'Buffer-menu-delete-backwards)
 143     (define-key map "\C-k" 'Buffer-menu-delete)
 144     (define-key map "x" 'Buffer-menu-execute)
 145     (define-key map " " 'next-line)
 146     (define-key map "n" 'next-line)
 147     (define-key map "p" 'previous-line)
 148     (define-key map "\177" 'Buffer-menu-backup-unmark)
 149     (define-key map "~" 'Buffer-menu-not-modified)
 150     (define-key map "u" 'Buffer-menu-unmark)
 151     (define-key map "m" 'Buffer-menu-mark)
 152     (define-key map "t" 'Buffer-menu-visit-tags-table)
 153     (define-key map "%" 'Buffer-menu-toggle-read-only)
 154     (define-key map "b" 'Buffer-menu-bury)
 155     (define-key map "V" 'Buffer-menu-view)
 156     (define-key map "T" 'Buffer-menu-toggle-files-only)
 157     (define-key map [mouse-2] 'Buffer-menu-mouse-select)
 158     (define-key map [follow-link] 'mouse-face)
 159     (define-key map (kbd "M-s a C-s")   'Buffer-menu-isearch-buffers)
 160     (define-key map (kbd "M-s a M-C-s") 'Buffer-menu-isearch-buffers-regexp)
 161     (define-key map [menu-bar Buffer-menu-mode] (cons (purecopy "Buffer-Menu") menu-map))
 162     (define-key menu-map [quit]
 163       `(menu-item ,(purecopy "Quit") quit-window
 164                  :help ,(purecopy "Remove the buffer menu from the display")))
 165     (define-key menu-map [rev]
 166       `(menu-item ,(purecopy "Refresh") revert-buffer
 167                  :help ,(purecopy "Refresh the *Buffer List* buffer contents")))
 168     (define-key menu-map [s0] menu-bar-separator)
 169     (define-key menu-map [tf]
 170       `(menu-item ,(purecopy "Show only file buffers") Buffer-menu-toggle-files-only
 171                   :button (:toggle . Buffer-menu-files-only)
 172                   :help ,(purecopy "Toggle whether the current buffer-menu displays only file buffers")))
 173     (define-key menu-map [s1] menu-bar-separator)
 174     ;; FIXME: The "Select" entries could use better names...
 175     (define-key menu-map [sel]
 176       `(menu-item ,(purecopy "Select marked") Buffer-menu-select
 177                  :help ,(purecopy "Select this line's buffer; also display buffers marked with `>'")))
 178     (define-key menu-map [bm2]
 179       `(menu-item ,(purecopy "Select two") Buffer-menu-2-window
 180                  :help ,(purecopy "Select this line's buffer, with previous buffer in second window")))
 181     (define-key menu-map [bm1]
 182       `(menu-item ,(purecopy "Select current") Buffer-menu-1-window
 183                  :help ,(purecopy "Select this line's buffer, alone, in full frame")))
 184     (define-key menu-map [ow]
 185       `(menu-item ,(purecopy "Select in other window") Buffer-menu-other-window
 186                  :help ,(purecopy "Select this line's buffer in other window, leaving buffer menu visible")))
 187     (define-key menu-map [tw]
 188       `(menu-item ,(purecopy "Select in current window") Buffer-menu-this-window
 189                  :help ,(purecopy "Select this line's buffer in this window")))
 190     (define-key menu-map [s2] menu-bar-separator)
 191     (define-key menu-map [is]
 192       `(menu-item ,(purecopy "Regexp Isearch marked buffers") Buffer-menu-isearch-buffers-regexp
 193                  :help ,(purecopy "Search for a regexp through all marked buffers using Isearch")))
 194     (define-key menu-map [ir]
 195       `(menu-item ,(purecopy "Isearch marked buffers") Buffer-menu-isearch-buffers
 196                  :help ,(purecopy "Search for a string through all marked buffers using Isearch")))
 197     (define-key menu-map [s3] menu-bar-separator)
 198     (define-key menu-map [by]
 199       `(menu-item ,(purecopy "Bury") Buffer-menu-bury
 200                  :help ,(purecopy "Bury the buffer listed on this line")))
 201     (define-key menu-map [vt]
 202       `(menu-item ,(purecopy "Set unmodified") Buffer-menu-not-modified
 203                  :help ,(purecopy "Mark buffer on this line as unmodified (no changes to save)")))
 204     (define-key menu-map [ex]
 205       `(menu-item ,(purecopy "Execute") Buffer-menu-execute
 206                  :help ,(purecopy "Save and/or delete buffers marked with s or k commands")))
 207     (define-key menu-map [s4] menu-bar-separator)
 208     (define-key menu-map [delb]
 209       `(menu-item ,(purecopy "Mark for delete and move backwards") Buffer-menu-delete-backwards
 210                  :help ,(purecopy "Mark buffer on this line to be deleted by x command and move up one line")))
 211     (define-key menu-map [del]
 212       `(menu-item ,(purecopy "Mark for delete") Buffer-menu-delete
 213                  :help ,(purecopy "Mark buffer on this line to be deleted by x command")))
 214
 215     (define-key menu-map [sv]
 216       `(menu-item ,(purecopy "Mark for save") Buffer-menu-save
 217                  :help ,(purecopy "Mark buffer on this line to be saved by x command")))
 218     (define-key menu-map [umk]
 219       `(menu-item ,(purecopy "Unmark") Buffer-menu-unmark
 220                  :help ,(purecopy "Cancel all requested operations on buffer on this line and move down")))
 221     (define-key menu-map [mk]
 222       `(menu-item ,(purecopy "Mark") Buffer-menu-mark
 223                  :help ,(purecopy "Mark buffer on this line for being displayed by v command")))
 224     map)
 225   "Local keymap for `Buffer-menu-mode' buffers.")
 226
 227 ;; Buffer Menu mode is suitable only for specially formatted data.
 228 (put 'Buffer-menu-mode 'mode-class 'special)
 229
 230 (define-derived-mode Buffer-menu-mode special-mode "Buffer Menu"
 231   "Major mode for editing a list of buffers.
 232 Each line describes one of the buffers in Emacs.
 233 Letters do not insert themselves; instead, they are commands.
 234 \\<Buffer-menu-mode-map>
 235 \\[Buffer-menu-mouse-select] -- select buffer you click on, in place of the buffer menu.
 236 \\[Buffer-menu-this-window] -- select current line's buffer in place of the buffer menu.
 237 \\[Buffer-menu-other-window] -- select that buffer in another window,
 238   so the buffer menu buffer remains visible in its window.
 239 \\[Buffer-menu-view] -- select current line's buffer, but in view-mode.
 240 \\[Buffer-menu-view-other-window] -- select that buffer in
 241   another window, in view-mode.
 242 \\[Buffer-menu-switch-other-window] -- make another window display that buffer.
 243 \\[Buffer-menu-mark] -- mark current line's buffer to be displayed.
 244 \\[Buffer-menu-select] -- select current line's buffer.
 245   Also show buffers marked with m, in other windows.
 246 \\[Buffer-menu-1-window] -- select that buffer in full-frame window.
 247 \\[Buffer-menu-2-window] -- select that buffer in one window,
 248   together with buffer selected before this one in another window.
 249 \\[Buffer-menu-isearch-buffers] -- Do incremental search in the marked buffers.
 250 \\[Buffer-menu-isearch-buffers-regexp] -- Isearch for regexp in the marked buffers.
 251 \\[Buffer-menu-visit-tags-table] -- visit-tags-table this buffer.
 252 \\[Buffer-menu-not-modified] -- clear modified-flag on that buffer.
 253 \\[Buffer-menu-save] -- mark that buffer to be saved, and move down.
 254 \\[Buffer-menu-delete] -- mark that buffer to be deleted, and move down.
 255 \\[Buffer-menu-delete-backwards] -- mark that buffer to be deleted, and move up.
 256 \\[Buffer-menu-execute] -- delete or save marked buffers.
 257 \\[Buffer-menu-unmark] -- remove all kinds of marks from current line.
 258   With prefix argument, also move up one line.
 259 \\[Buffer-menu-backup-unmark] -- back up a line and remove marks.
 260 \\[Buffer-menu-toggle-read-only] -- toggle read-only status of buffer on this line.
 261 \\[revert-buffer] -- update the list of buffers.
 262 \\[Buffer-menu-toggle-files-only] -- toggle whether the menu displays only file buffers.
 263 \\[Buffer-menu-bury] -- bury the buffer listed on this line."
 264   (set (make-local-variable 'revert-buffer-function)
 265        'Buffer-menu-revert-function)
 266   (set (make-local-variable 'buffer-stale-function)
 267        (lambda (&optional _noconfirm) 'fast))
 268   (setq truncate-lines t)
 269   (setq buffer-read-only t)
 270   ;; Force L2R direction, to avoid messing the display if the first
 271   ;; buffer in the list happens to begin with a strong R2L character.
 272   (setq bidi-paragraph-direction 'left-to-right))
 273
 274 (define-obsolete-variable-alias 'buffer-menu-mode-hook
 275   'Buffer-menu-mode-hook "23.1")
 276
 277 (defun Buffer-menu-revert-function (_ignore1 _ignore2)
 278   (or (eq buffer-undo-list t)
 279       (setq buffer-undo-list nil))
 280   ;; We can not use save-excursion here.  The buffer gets erased.
 281   (let ((opoint (point))
 282         (eobp (eobp))
 283         (ocol (current-column))
 284         (oline (progn (move-to-column Buffer-menu-buffer-column)
 285                       (get-text-property (point) 'buffer)))
 286         (prop (point-min))
 287         ;; do not make undo records for the reversion.
 288         (buffer-undo-list t))
 289     ;; We can be called by Auto Revert Mode with the "*Buffer Menu*"
 290     ;; temporarily the current buffer.  Make sure that the
 291     ;; interactively current buffer is correctly identified with a `.'
 292     ;; by `list-buffers-noselect'.
 293     (with-current-buffer (window-buffer)
 294       (list-buffers-noselect Buffer-menu-files-only Buffer-menu--buffers))
 295     (if oline
 296         (while (setq prop (next-single-property-change prop 'buffer))
 297           (when (eq (get-text-property prop 'buffer) oline)
 298             (goto-char prop)
 299             (move-to-column ocol)))
 300       (goto-char (if eobp (point-max) opoint)))))
 301
 302 (defun Buffer-menu-toggle-files-only (arg)
 303   "Toggle whether the current buffer-menu displays only file buffers.
 304 With a positive ARG display only file buffers.  With zero or
 305 negative ARG, display other buffers as well."
 306   (interactive "P")
 307   (setq Buffer-menu-files-only
 308         (cond ((not arg) (not Buffer-menu-files-only))
 309               ((> (prefix-numeric-value arg) 0) t)))
 310   (revert-buffer))
 311
 312 \f
 313 (defun Buffer-menu-buffer (error-if-non-existent-p)
 314   "Return buffer described by this line of buffer menu."
 315   (let* ((where (+ (line-beginning-position) Buffer-menu-buffer-column))
 316          (name (and (not (eobp)) (get-text-property where 'buffer-name)))
 317          (buf (and (not (eobp)) (get-text-property where 'buffer))))
 318     (if name
 319         (or (get-buffer name)
 320             (and buf (buffer-name buf) buf)
 321             (if error-if-non-existent-p
 322                 (error "No buffer named `%s'" name)
 323               nil))
 324       (or (and buf (buffer-name buf) buf)
 325           (if error-if-non-existent-p
 326               (error "No buffer on this line")
 327             nil)))))
 328 \f
 329 (defun buffer-menu (&optional arg)
 330   "Make a menu of buffers so you can save, delete or select them.
 331 With argument, show only buffers that are visiting files.
 332 Type ? after invocation to get help on commands available.
 333 Type q to remove the buffer menu from the display.
 334
 335 The first column shows `>' for a buffer you have
 336 marked to be displayed, `D' for one you have marked for
 337 deletion, and `.' for the current buffer.
 338
 339 The C column has a `.' for the buffer from which you came.
 340 The R column has a `%' if the buffer is read-only.
 341 The M column has a `*' if it is modified,
 342 or `S' if you have marked it for saving.
 343 After this come the buffer name, its size in characters,
 344 its major mode, and the visited file name (if any)."
 345   (interactive "P")
 346 ;;;  (setq Buffer-menu-window-config (current-window-configuration))
 347   (switch-to-buffer (list-buffers-noselect arg))
 348   (message
 349    "Commands: d, s, x, u; f, o, 1, 2, m, v; ~, %%; q to quit; ? for help."))
 350
 351 (defun buffer-menu-other-window (&optional arg)
 352   "Display a list of buffers in another window.
 353 With the buffer list buffer, you can save, delete or select the buffers.
 354 With argument, show only buffers that are visiting files.
 355 Type ? after invocation to get help on commands available.
 356 Type q to remove the buffer menu from the display.
 357 For more information, see the function `buffer-menu'."
 358   (interactive "P")
 359 ;;;  (setq Buffer-menu-window-config (current-window-configuration))
 360   (switch-to-buffer-other-window (list-buffers-noselect arg))
 361   (message
 362    "Commands: d, s, x, u; f, o, 1, 2, m, v; ~, %%; q to quit; ? for help."))
 363
 364 (defun Buffer-menu-no-header ()
 365   (beginning-of-line)
 366   (if (or Buffer-menu-use-header-line
 367           (not (eq (char-after) ?C)))
 368       t
 369     (ding)
 370     (forward-line 1)
 371     nil))
 372
 373 (defun Buffer-menu-mark ()
 374   "Mark buffer on this line for being displayed by \\<Buffer-menu-mode-map>\\[Buffer-menu-select] command."
 375   (interactive)
 376   (when (Buffer-menu-no-header)
 377     (let ((inhibit-read-only t))
 378       (delete-char 1)
 379       (insert ?>)
 380       (forward-line 1))))
 381
 382 (defun Buffer-menu-unmark (&optional backup)
 383   "Cancel all requested operations on buffer on this line and move down.
 384 Optional prefix arg means move up."
 385   (interactive "P")
 386   (when (Buffer-menu-no-header)
 387     (let* ((buf (Buffer-menu-buffer t))
 388            (mod (buffer-modified-p buf))
 389            (readonly (with-current-buffer buf buffer-read-only))
 390            (inhibit-read-only t))
 391       (delete-char 3)
 392       (insert (if readonly (if mod " %*" " % ") (if mod "  *" "   ")))))
 393   (forward-line (if backup -1 1)))
 394
 395 (defun Buffer-menu-backup-unmark ()
 396   "Move up and cancel all requested operations on buffer on line above."
 397   (interactive)
 398   (forward-line -1)
 399   (Buffer-menu-unmark)
 400   (forward-line -1))
 401
 402 (defun Buffer-menu-delete (&optional arg)
 403   "Mark buffer on this line to be deleted by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command.
 404 Prefix arg is how many buffers to delete.
 405 Negative arg means delete backwards."
 406   (interactive "p")
 407   (when (Buffer-menu-no-header)
 408     (let ((inhibit-read-only t))
 409       (if (or (null arg) (= arg 0))
 410           (setq arg 1))
 411       (while (> arg 0)
 412         (delete-char 1)
 413         (insert ?D)
 414         (forward-line 1)
 415         (setq arg (1- arg)))
 416       (while (and (< arg 0)
 417                   (Buffer-menu-no-header))
 418         (delete-char 1)
 419         (insert ?D)
 420         (forward-line -1)
 421         (setq arg (1+ arg))))))
 422
 423 (defun Buffer-menu-delete-backwards (&optional arg)
 424   "Mark buffer on this line to be deleted by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command
 425 and then move up one line.  Prefix arg means move that many lines."
 426   (interactive "p")
 427   (Buffer-menu-delete (- (or arg 1))))
 428
 429 (defun Buffer-menu-save ()
 430   "Mark buffer on this line to be saved by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command."
 431   (interactive)
 432   (when (Buffer-menu-no-header)
 433     (let ((inhibit-read-only t))
 434       (forward-char 2)
 435       (delete-char 1)
 436       (insert ?S)
 437       (forward-line 1))))
 438
 439 (defun Buffer-menu-not-modified (&optional arg)
 440   "Mark buffer on this line as unmodified (no changes to save)."
 441   (interactive "P")
 442   (with-current-buffer (Buffer-menu-buffer t)
 443     (set-buffer-modified-p arg))
 444   (save-excursion
 445    (beginning-of-line)
 446    (forward-char 2)
 447    (if (= (char-after) (if arg ?\s ?*))
 448        (let ((inhibit-read-only t))
 449          (delete-char 1)
 450          (insert (if arg ?* ?\s))))))
 451
 452 (defun Buffer-menu-beginning ()
 453   (goto-char (point-min))
 454   (unless Buffer-menu-use-header-line
 455     (forward-line)))
 456
 457 (defun Buffer-menu-execute ()
 458   "Save and/or delete buffers marked with \\<Buffer-menu-mode-map>\\[Buffer-menu-save] or \\<Buffer-menu-mode-map>\\[Buffer-menu-delete] commands."
 459   (interactive)
 460   (save-excursion
 461     (Buffer-menu-beginning)
 462     (while (re-search-forward "^..S" nil t)
 463       (let ((modp nil))
 464         (with-current-buffer (Buffer-menu-buffer t)
 465           (save-buffer)
 466           (setq modp (buffer-modified-p)))
 467         (let ((inhibit-read-only t))
 468           (delete-char -1)
 469           (insert (if modp ?* ?\s))))))
 470   (save-excursion
 471     (Buffer-menu-beginning)
 472     (let ((buff-menu-buffer (current-buffer))
 473           (inhibit-read-only t))
 474       (while (re-search-forward "^D" nil t)
 475         (forward-char -1)
 476         (let ((buf (Buffer-menu-buffer nil)))
 477           (or (eq buf nil)
 478               (eq buf buff-menu-buffer)
 479               (save-excursion (kill-buffer buf)))
 480           (if (and buf (buffer-name buf))
 481             (progn (delete-char 1)
 482                    (insert ?\s))
 483           (delete-region (point) (progn (forward-line 1) (point)))
 484             (unless (bobp)
 485               (forward-char -1))))))))
 486
 487 (defun Buffer-menu-select ()
 488   "Select this line's buffer; also display buffers marked with `>'.
 489 You can mark buffers with the \\<Buffer-menu-mode-map>\\[Buffer-menu-mark] command.
 490 This command deletes and replaces all the previously existing windows
 491 in the selected frame."
 492   (interactive)
 493   (let ((buff (Buffer-menu-buffer t))
 494         (menu (current-buffer))
 495         (others ())
 496         tem)
 497     (Buffer-menu-beginning)
 498     (while (re-search-forward "^>" nil t)
 499       (setq tem (Buffer-menu-buffer t))
 500       (let ((inhibit-read-only t))
 501         (delete-char -1)
 502         (insert ?\s))
 503       (or (eq tem buff) (memq tem others) (setq others (cons tem others))))
 504     (setq others (nreverse others)
 505           tem (/ (1- (frame-height)) (1+ (length others))))
 506     (delete-other-windows)
 507     (switch-to-buffer buff)
 508     (or (eq menu buff)
 509         (bury-buffer menu))
 510     (if (equal (length others) 0)
 511         (progn
 512 ;;;       ;; Restore previous window configuration before displaying
 513 ;;;       ;; selected buffers.
 514 ;;;       (if Buffer-menu-window-config
 515 ;;;           (progn
 516 ;;;             (set-window-configuration Buffer-menu-window-config)
 517 ;;;             (setq Buffer-menu-window-config nil)))
 518           (switch-to-buffer buff))
 519       (while others
 520         (split-window nil tem)
 521         (other-window 1)
 522         (switch-to-buffer (car others))
 523         (setq others (cdr others)))
 524       (other-window 1)                          ;back to the beginning!
 525 )))
 526
 527 (defun Buffer-menu-marked-buffers ()
 528   "Return a list of buffers marked with the \\<Buffer-menu-mode-map>\\[Buffer-menu-mark] command."
 529   (let (buffers)
 530     (Buffer-menu-beginning)
 531     (while (re-search-forward "^>" nil t)
 532       (setq buffers (cons (Buffer-menu-buffer t) buffers)))
 533     (nreverse buffers)))
 534
 535 (defun Buffer-menu-isearch-buffers ()
 536   "Search for a string through all marked buffers using Isearch."
 537   (interactive)
 538   (multi-isearch-buffers (Buffer-menu-marked-buffers)))
 539
 540 (defun Buffer-menu-isearch-buffers-regexp ()
 541   "Search for a regexp through all marked buffers using Isearch."
 542   (interactive)
 543   (multi-isearch-buffers-regexp (Buffer-menu-marked-buffers)))
 544
 545 \f
 546 (defun Buffer-menu-visit-tags-table ()
 547   "Visit the tags table in the buffer on this line.  See `visit-tags-table'."
 548   (interactive)
 549   (let ((file (buffer-file-name (Buffer-menu-buffer t))))
 550     (if file
 551         (visit-tags-table file)
 552       (error "Specified buffer has no file"))))
 553
 554 (defun Buffer-menu-1-window ()
 555   "Select this line's buffer, alone, in full frame."
 556   (interactive)
 557   (switch-to-buffer (Buffer-menu-buffer t))
 558   (bury-buffer (other-buffer))
 559   (delete-other-windows))
 560
 561 (defun Buffer-menu-mouse-select (event)
 562   "Select the buffer whose line you click on."
 563   (interactive "e")
 564   (let (buffer)
 565     (with-current-buffer (window-buffer (posn-window (event-end event)))
 566       (save-excursion
 567         (goto-char (posn-point (event-end event)))
 568         (setq buffer (Buffer-menu-buffer t))))
 569     (select-window (posn-window (event-end event)))
 570     (if (and (window-dedicated-p (selected-window))
 571              (eq (selected-window) (frame-root-window)))
 572         (switch-to-buffer-other-frame buffer)
 573       (switch-to-buffer buffer))))
 574
 575 (defun Buffer-menu-this-window ()
 576   "Select this line's buffer in this window."
 577   (interactive)
 578   (switch-to-buffer (Buffer-menu-buffer t)))
 579
 580 (defun Buffer-menu-other-window ()
 581   "Select this line's buffer in other window, leaving buffer menu visible."
 582   (interactive)
 583   (switch-to-buffer-other-window (Buffer-menu-buffer t)))
 584
 585 (defun Buffer-menu-switch-other-window ()
 586   "Make the other window select this line's buffer.
 587 The current window remains selected."
 588   (interactive)
 589   (let ((pop-up-windows t)
 590         same-window-buffer-names
 591         same-window-regexps)
 592     (display-buffer (Buffer-menu-buffer t))))
 593
 594 (defun Buffer-menu-2-window ()
 595   "Select this line's buffer, with previous buffer in second window."
 596   (interactive)
 597   (let ((buff (Buffer-menu-buffer t))
 598         (menu (current-buffer))
 599         (pop-up-windows t)
 600         same-window-buffer-names
 601         same-window-regexps)
 602     (delete-other-windows)
 603     (switch-to-buffer (other-buffer))
 604     (pop-to-buffer buff)
 605     (bury-buffer menu)))
 606
 607 (defun Buffer-menu-toggle-read-only ()
 608   "Toggle read-only status of buffer on this line, perhaps via version control."
 609   (interactive)
 610   (let (char)
 611     (with-current-buffer (Buffer-menu-buffer t)
 612       (toggle-read-only)
 613       (setq char (if buffer-read-only ?% ?\s)))
 614     (save-excursion
 615       (beginning-of-line)
 616       (forward-char 1)
 617       (if (/= (following-char) char)
 618           (let ((inhibit-read-only t))
 619             (delete-char 1)
 620             (insert char))))))
 621
 622 (defun Buffer-menu-bury ()
 623   "Bury the buffer listed on this line."
 624   (interactive)
 625   (when (Buffer-menu-no-header)
 626     (save-excursion
 627       (beginning-of-line)
 628       (bury-buffer (Buffer-menu-buffer t))
 629       (let ((line (buffer-substring (point) (progn (forward-line 1) (point))))
 630             (inhibit-read-only t))
 631         (delete-region (point) (progn (forward-line -1) (point)))
 632         (goto-char (point-max))
 633         (insert line))
 634       (message "Buried buffer moved to the end"))))
 635
 636
 637 (defun Buffer-menu-view ()
 638   "View this line's buffer in View mode."
 639   (interactive)
 640   (view-buffer (Buffer-menu-buffer t)))
 641
 642
 643 (defun Buffer-menu-view-other-window ()
 644   "View this line's buffer in View mode in another window."
 645   (interactive)
 646   (view-buffer-other-window (Buffer-menu-buffer t)))
 647 \f
 648
 649 ;;;###autoload
 650 (define-key ctl-x-map "\C-b" 'list-buffers)
 651
 652 ;;;###autoload
 653 (defun list-buffers (&optional files-only)
 654   "Display a list of names of existing buffers.
 655 The list is displayed in a buffer named `*Buffer List*'.
 656 Note that buffers with names starting with spaces are omitted.
 657 Non-null optional arg FILES-ONLY means mention only file buffers.
 658
 659 For more information, see the function `buffer-menu'."
 660   (interactive "P")
 661   (display-buffer (list-buffers-noselect files-only)))
 662
 663 (defconst Buffer-menu-short-ellipsis
 664   ;; This file is preloaded, so we can't use char-displayable-p here
 665   ;; because we don't know yet what display we're going to connect to.
 666   ":" ;; (if (char-displayable-p ?…) "…" ":")
 667   )
 668
 669 (defun Buffer-menu-buffer+size (name size &optional name-props size-props lrm)
 670   (if (> (+ (string-width name) (string-width size) 2)
 671          Buffer-menu-buffer+size-width)
 672       (setq name
 673             (let ((tail
 674                    (if (string-match "<[0-9]+>$" name)
 675                        (match-string 0 name)
 676                      "")))
 677               (concat (truncate-string-to-width
 678                        name
 679                        (- Buffer-menu-buffer+size-width
 680                           (max (string-width size) 3)
 681                           (string-width tail)
 682                           2))
 683                       Buffer-menu-short-ellipsis
 684                       tail
 685                       ;; Append an invisible LRM character to the
 686                       ;; buffer's name to avoid ugly display with the
 687                       ;; buffer size to the left of the name, when the
 688                       ;; name begins with R2L character.
 689                       (if lrm (propertize (string ?\x200e) 'invisible t) ""))))
 690     ;; Don't put properties on (buffer-name).
 691     (setq name (concat (copy-sequence name)
 692                        (if lrm
 693                            (propertize (string ?\x200e) 'invisible t)
 694                          ""))))
 695   (add-text-properties 0 (length name) name-props name)
 696   (add-text-properties 0 (length size) size-props size)
 697   (let ((name+space-width (- Buffer-menu-buffer+size-width
 698                              (string-width size))))
 699     (concat name
 700             (propertize (make-string (- name+space-width (string-width name))
 701                                      ?\s)
 702                         'display `(space :align-to
 703                                          ,(+ Buffer-menu-buffer-column
 704                                              name+space-width)))
 705             size)))
 706
 707 (defun Buffer-menu-sort (column)
 708   "Sort the buffer menu by COLUMN."
 709   (interactive "P")
 710   (when column
 711     (setq column (prefix-numeric-value column))
 712     (if (< column 2) (setq column 2))
 713     (if (> column 5) (setq column 5)))
 714   (setq Buffer-menu-sort-column column)
 715   (let ((inhibit-read-only t) l buf m1 m2)
 716     (save-excursion
 717       (Buffer-menu-beginning)
 718       (while (not (eobp))
 719         (when (buffer-live-p
 720                (setq buf (get-text-property
 721                           (+ (point)
 722                              Buffer-menu-buffer-column)
 723                           'buffer)))
 724           (setq m1 (char-after)
 725                 m1 (if (memq m1 '(?> ?D)) m1)
 726                 m2 (char-after (+ (point) 2))
 727                 m2 (if (eq m2 ?S) m2))
 728           (if (or m1 m2)
 729               (push (list buf m1 m2) l)))
 730         (forward-line)))
 731     (revert-buffer)
 732     (save-excursion
 733       (Buffer-menu-beginning)
 734       (while (not (eobp))
 735         (when (setq buf (assq (get-text-property (+ (point)
 736                                                     Buffer-menu-buffer-column)
 737                                                  'buffer) l))
 738           (setq m1 (cadr buf)
 739                 m2 (cadr (cdr buf)))
 740           (when m1
 741             (delete-char 1)
 742             (insert m1)
 743             (backward-char 1))
 744           (when m2
 745             (forward-char 2)
 746             (delete-char 1)
 747             (insert m2)))
 748         (forward-line)))))
 749
 750 (defun Buffer-menu-sort-by-column (&optional e)
 751   "Sort the buffer menu by the column clicked on."
 752   (interactive (list last-input-event))
 753   (if e (mouse-select-window e))
 754   (let* ((pos (event-start e))
 755          (obj (posn-object pos))
 756          (col (if obj
 757                   (get-text-property (cdr obj) 'column (car obj))
 758                 (get-text-property (posn-point pos) 'column))))
 759     (Buffer-menu-sort col)))
 760
 761 (defvar Buffer-menu-sort-button-map
 762   (let ((map (make-sparse-keymap)))
 763     ;; This keymap handles both nil and non-nil values for
 764     ;; Buffer-menu-use-header-line.
 765     (define-key map [header-line mouse-1] 'Buffer-menu-sort-by-column)
 766     (define-key map [header-line mouse-2] 'Buffer-menu-sort-by-column)
 767     (define-key map [mouse-2] 'Buffer-menu-sort-by-column)
 768     (define-key map [follow-link] 'mouse-face)
 769     (define-key map "\C-m" 'Buffer-menu-sort-by-column)
 770     map)
 771   "Local keymap for Buffer menu sort buttons.")
 772
 773 (defun Buffer-menu-make-sort-button (name column)
 774   (if (equal column Buffer-menu-sort-column) (setq column nil))
 775   (propertize name
 776               'column column
 777               'help-echo (concat
 778                           (if Buffer-menu-use-header-line
 779                               "mouse-1, mouse-2: sort by "
 780                             "mouse-2, RET: sort by ")
 781                           (if column (downcase name) "visited order"))
 782               'mouse-face 'highlight
 783               'keymap Buffer-menu-sort-button-map))
 784
 785 (defun list-buffers-noselect (&optional files-only buffer-list)
 786   "Create and return a buffer with a list of names of existing buffers.
 787 The buffer is named `*Buffer List*'.
 788 Note that buffers with names starting with spaces are omitted.
 789 Non-null optional arg FILES-ONLY means mention only file buffers.
 790
 791 If BUFFER-LIST is non-nil, it should be a list of buffers;
 792 it means list those buffers and no others.
 793
 794 For more information, see the function `buffer-menu'."
 795   (let* ((old-buffer (current-buffer))
 796          (standard-output standard-output)
 797          (mode-end (make-string (- Buffer-menu-mode-width 2) ?\s))
 798          (header (concat "CRM "
 799                          (Buffer-menu-buffer+size
 800                           (Buffer-menu-make-sort-button "Buffer" 2)
 801                           (Buffer-menu-make-sort-button "Size" 3))
 802                          "  "
 803                          (Buffer-menu-make-sort-button "Mode" 4) mode-end
 804                          (Buffer-menu-make-sort-button "File" 5) "\n"))
 805          list desired-point)
 806     (when Buffer-menu-use-header-line
 807       (let ((pos 0))
 808         ;; Turn whitespace chars in the header into stretch specs so
 809         ;; they work regardless of the header-line face.
 810         (while (string-match "[ \t\n]+" header pos)
 811           (setq pos (match-end 0))
 812           (put-text-property (match-beginning 0) pos 'display
 813                              ;; Assume fixed-size chars in the buffer.
 814                              (list 'space :align-to pos)
 815                              header)))
 816       ;; Try to better align the one-char headers.
 817       (put-text-property 0 3 'face 'fixed-pitch header)
 818       ;; Add a "dummy" leading space to align the beginning of the header
 819       ;; line with the beginning of the text (rather than with the left
 820       ;; scrollbar or the left fringe).  --Stef
 821       (setq header (concat (propertize " " 'display '(space :align-to 0))
 822                            header)))
 823     (with-current-buffer (get-buffer-create "*Buffer List*")
 824       (setq buffer-read-only nil)
 825       (erase-buffer)
 826       (setq standard-output (current-buffer))
 827       ;; Force L2R direction, to avoid messing the display if the
 828       ;; first buffer in the list happens to begin with a strong R2L
 829       ;; character.
 830       (setq bidi-paragraph-direction 'left-to-right)
 831       (unless Buffer-menu-use-header-line
 832         ;; Use U+2014 (EM DASH) to underline if possible, else use ASCII
 833         ;; (i.e. U+002D, HYPHEN-MINUS).
 834         (let ((underline (if (char-displayable-p ?\u2014) ?\u2014 ?-)))
 835           (insert header
 836                   (apply 'string
 837                          (mapcar (lambda (c)
 838                                    (if (memq c '(?\n ?\s)) c underline))
 839                                  header)))))
 840       ;; Collect info for every buffer we're interested in.
 841       (dolist (buffer (or buffer-list
 842                           (buffer-list
 843                            (when Buffer-menu-use-frame-buffer-list
 844                              (selected-frame)))))
 845         (with-current-buffer buffer
 846           (let ((name (buffer-name))
 847                 (file buffer-file-name))
 848             (unless (and (not buffer-list)
 849                          (or
 850                           ;; Don't mention internal buffers.
 851                           (and (string= (substring name 0 1) " ") (null file))
 852                           ;; Maybe don't mention buffers without files.
 853                           (and files-only (not file))
 854                           (string= name "*Buffer List*")))
 855               ;; Otherwise output info.
 856               (let ((mode (concat (format-mode-line mode-name nil nil buffer)
 857                                   (if mode-line-process
 858                                       (format-mode-line mode-line-process
 859                                                         nil nil buffer))))
 860                     (bits (string
 861                            (if (eq buffer old-buffer) ?. ?\s)
 862                            ;; Handle readonly status.  The output buffer
 863                            ;; is special cased to appear readonly; it is
 864                            ;; actually made so at a later date.
 865                            (if (or (eq buffer standard-output)
 866                                    buffer-read-only)
 867                                ?% ?\s)
 868                            ;; Identify modified buffers.
 869                            (if (buffer-modified-p) ?* ?\s)
 870                            ;; Space separator.
 871                            ?\s)))
 872                 (unless file
 873                   ;; No visited file.  Check local value of
 874                   ;; list-buffers-directory and, for Info buffers,
 875                   ;; Info-current-file.
 876                   (cond ((and (boundp 'list-buffers-directory)
 877                               list-buffers-directory)
 878                          (setq file list-buffers-directory))
 879                         ((eq major-mode 'Info-mode)
 880                          (setq file Info-current-file)
 881                          (cond
 882                           ((equal file "dir")
 883                            (setq file "*Info Directory*"))
 884                           ((eq file 'apropos)
 885                            (setq file "*Info Apropos*"))
 886                           ((eq file 'history)
 887                            (setq file "*Info History*"))
 888                           ((eq file 'toc)
 889                            (setq file "*Info TOC*"))
 890                           ((not (stringp file))  ;; avoid errors
 891                            (setq file nil))
 892                           (t
 893                            (setq file (concat "("
 894                                               (file-name-nondirectory file)
 895                                               ") "
 896                                               Info-current-node)))))))
 897                 (push (list buffer bits name (buffer-size) mode file)
 898                       list))))))
 899       ;; Preserve the original buffer-list ordering, just in case.
 900       (setq list (nreverse list))
 901       ;; Place the buffers's info in the output buffer, sorted if necessary.
 902       (dolist (buffer
 903                (if Buffer-menu-sort-column
 904                    (sort list
 905                          (if (eq Buffer-menu-sort-column 3)
 906                              (lambda (a b)
 907                                (< (nth Buffer-menu-sort-column a)
 908                                   (nth Buffer-menu-sort-column b)))
 909                            (lambda (a b)
 910                              (string< (nth Buffer-menu-sort-column a)
 911                                       (nth Buffer-menu-sort-column b)))))
 912                  list))
 913         (if (eq (car buffer) old-buffer)
 914             (setq desired-point (point)))
 915         (insert (cadr buffer)
 916                 ;; Put the buffer name into a text property
 917                 ;; so we don't have to extract it from the text.
 918                 ;; This way we avoid problems with unusual buffer names.
 919                 (let ((name (nth 2 buffer))
 920                       (size (int-to-string (nth 3 buffer))))
 921                   (Buffer-menu-buffer+size name size
 922                          `(buffer-name ,name
 923                                        buffer ,(car buffer)
 924                                        font-lock-face buffer-menu-buffer
 925                                        mouse-face highlight
 926                                        help-echo
 927                                        ,(if (>= (length name)
 928                                                 (- Buffer-menu-buffer+size-width
 929                                                    (max (length size) 3)
 930                                                    2))
 931                                             name
 932                                           "mouse-2: select this buffer"))
 933                          nil t))
 934                 "  "
 935                 (if (> (string-width (nth 4 buffer)) Buffer-menu-mode-width)
 936                     (truncate-string-to-width (nth 4 buffer)
 937                                               Buffer-menu-mode-width)
 938                   (nth 4 buffer)))
 939         (when (nth 5 buffer)
 940           (indent-to (+ Buffer-menu-buffer-column Buffer-menu-buffer+size-width
 941                         Buffer-menu-mode-width 4) 1)
 942           (princ (abbreviate-file-name (nth 5 buffer))))
 943         (princ "\n"))
 944       (Buffer-menu-mode)
 945       (when Buffer-menu-use-header-line
 946         (setq header-line-format header))
 947       ;; DESIRED-POINT doesn't have to be set; it is not when the
 948       ;; current buffer is not displayed for some reason.
 949       (and desired-point
 950            (goto-char desired-point))
 951       (setq Buffer-menu-files-only files-only)
 952       (setq Buffer-menu--buffers buffer-list)
 953       (set-buffer-modified-p nil)
 954       (current-buffer))))
 955
 956 ;;; buff-menu.el ends here