lisp/autorevert.el

   1 ;;; autorevert.el --- revert buffers when files on disk change
   2
   3 ;; Copyright (C) 1997-1999, 2001-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Anders Lindgren <andersl@andersl.com>
   6 ;; Keywords: convenience
   7 ;; Created: 1997-06-01
   8 ;; Date: 1999-11-30
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Introduction:
  28 ;;
  29 ;; Whenever a file that Emacs is editing has been changed by another
  30 ;; program the user normally has to execute the command `revert-buffer'
  31 ;; to load the new content of the file into Emacs.
  32 ;;
  33 ;; This package contains two minor modes: Global Auto-Revert Mode and
  34 ;; Auto-Revert Mode.  Both modes automatically revert buffers
  35 ;; whenever the corresponding files have been changed on disk and the
  36 ;; buffer contains no unsaved changes.
  37 ;;
  38 ;; Auto-Revert Mode can be activated for individual buffers.  Global
  39 ;; Auto-Revert Mode applies to all file buffers. (If the user option
  40 ;; `global-auto-revert-non-file-buffers' is non-nil, it also applies
  41 ;; to some non-file buffers.  This option is disabled by default.)
  42 ;; Since checking a remote file is too slow, these modes do not check
  43 ;; or revert remote files.
  44 ;;
  45 ;; Both modes operate by checking the time stamp of all files at
  46 ;; intervals of `auto-revert-interval'.  The default is every five
  47 ;; seconds.  The check is aborted whenever the user actually uses
  48 ;; Emacs.  You should never even notice that this package is active
  49 ;; (except that your buffers will be reverted, of course).
  50 ;;
  51 ;; After reverting a file buffer, Auto Revert Mode normally puts point
  52 ;; at the same position that a regular manual revert would.  However,
  53 ;; there is one exception to this rule.  If point is at the end of the
  54 ;; buffer before reverting, it stays at the end.  Similarly if point
  55 ;; is displayed at the end of a file buffer in any window, it will stay
  56 ;; at the end of the buffer in that window, even if the window is not
  57 ;; selected.  This way, you can use Auto Revert Mode to `tail' a file.
  58 ;; Just put point at the end of the buffer and it will stay there.
  59 ;; These rules apply to file buffers. For non-file buffers, the
  60 ;; behavior may be mode dependent.
  61 ;;
  62 ;; While you can use Auto Revert Mode to tail a file, this package
  63 ;; contains a third minor mode, Auto Revert Tail Mode, which does so
  64 ;; more efficiently, as long as you are sure that the file will only
  65 ;; change by growing at the end.  It only appends the new output,
  66 ;; instead of reverting the entire buffer.  It does so even if the
  67 ;; buffer contains unsaved changes.  (Because they will not be lost.)
  68 ;; Auto Revert Tail Mode works also for remote files.
  69
  70 ;; Usage:
  71 ;;
  72 ;; Go to the appropriate buffer and press either of:
  73 ;;   M-x auto-revert-mode RET
  74 ;;   M-x auto-revert-tail-mode RET
  75 ;;
  76 ;; To activate Global Auto-Revert Mode, press:
  77 ;;   M-x global-auto-revert-mode RET
  78 ;;
  79 ;; To activate Global Auto-Revert Mode every time Emacs is started
  80 ;; customize the option `global-auto-revert-mode' or the following
  81 ;; line could be added to your ~/.emacs:
  82 ;;   (global-auto-revert-mode 1)
  83 ;;
  84 ;; The function `turn-on-auto-revert-mode' could be added to any major
  85 ;; mode hook to activate Auto-Revert Mode for all buffers in that
  86 ;; mode.  For example, the following line will activate Auto-Revert
  87 ;; Mode in all C mode buffers:
  88 ;;
  89 ;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
  90
  91 ;;; Code:
  92
  93 ;; Dependencies:
  94
  95 (require 'timer)
  96
  97 (eval-when-compile (require 'cl))
  98
  99
 100 ;; Custom Group:
 101 ;;
 102 ;; The two modes will be placed next to Auto Save Mode under the
 103 ;; Files group under Emacs.
 104
 105 (defgroup auto-revert nil
 106   "Revert individual buffers when files on disk change.
 107
 108 Auto-Revert Mode can be activated for individual buffer.
 109 Global Auto-Revert Mode applies to all buffers."
 110   :group 'files
 111   :group 'convenience)
 112
 113
 114 ;; Variables:
 115
 116 ;;; What's this?: ;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
 117 ;;; What's this?: ;;;###autoload
 118 (defvar auto-revert-mode nil
 119   "Non-nil when Auto-Revert Mode is active.
 120 Never set this variable directly, use the command `auto-revert-mode' instead.")
 121 (put 'auto-revert-mode 'permanent-local t)
 122
 123 (defvar auto-revert-tail-mode nil
 124   "Non-nil when Auto-Revert Tail Mode is active.
 125 Never set this variable directly, use the command
 126 `auto-revert-tail-mode' instead.")
 127 (put 'auto-revert-tail-mode 'permanent-local t)
 128
 129 (defvar auto-revert-timer nil
 130   "Timer used by Auto-Revert Mode.")
 131
 132 (defcustom auto-revert-interval 5
 133   "Time, in seconds, between Auto-Revert Mode file checks.
 134 The value may be an integer or floating point number.
 135
 136 If a timer is already active, there are two ways to make sure
 137 that the new value will take effect immediately.  You can set
 138 this variable through Custom or you can call the command
 139 `auto-revert-set-timer' after setting the variable.  Otherwise,
 140 the new value will take effect the first time Auto Revert Mode
 141 calls `auto-revert-set-timer' for internal reasons or in your
 142 next editing session."
 143   :group 'auto-revert
 144   :type 'number
 145   :set (lambda (variable value)
 146          (set-default variable value)
 147          (and (boundp 'auto-revert-timer)
 148               auto-revert-timer
 149               (auto-revert-set-timer))))
 150
 151 (defcustom auto-revert-stop-on-user-input t
 152   "When non-nil, user input temporarily interrupts Auto-Revert Mode.
 153 With this setting, Auto-Revert Mode checks for user input after
 154 handling each buffer and does not process any further buffers
 155 \(until the next run of the timer) if user input is available.
 156 When nil, Auto-Revert Mode checks files and reverts buffers,
 157 with quitting disabled, without paying attention to user input.
 158 Thus, with this setting, Emacs might be non-responsive at times."
 159   :group 'auto-revert
 160   :type 'boolean)
 161
 162 (defcustom auto-revert-verbose t
 163   "When nil, Auto-Revert Mode does not generate any messages.
 164 When non-nil, a message is generated whenever a file is reverted."
 165   :group 'auto-revert
 166   :type 'boolean)
 167
 168 (defcustom auto-revert-mode-text " ARev"
 169   "String to display in the mode line when Auto-Revert Mode is active.
 170
 171 \(When the string is not empty, make sure that it has a leading space.)"
 172   :tag "Auto Revert Mode Text"          ; To separate it from `global-...'
 173   :group 'auto-revert
 174   :type 'string)
 175
 176 (defcustom auto-revert-tail-mode-text " Tail"
 177   "String to display in the mode line when Auto-Revert Tail Mode is active.
 178
 179 \(When the string is not empty, make sure that it has a leading space.)"
 180   :group 'auto-revert
 181   :type 'string
 182   :version "22.1")
 183
 184 (defcustom auto-revert-mode-hook nil
 185   "Functions to run when Auto-Revert Mode is activated."
 186   :tag "Auto Revert Mode Hook"          ; To separate it from `global-...'
 187   :group 'auto-revert
 188   :type 'hook)
 189
 190 (defcustom global-auto-revert-mode-text ""
 191   "String to display when Global Auto-Revert Mode is active.
 192
 193 The default is nothing since when this mode is active this text doesn't
 194 vary over time, or between buffers.  Hence mode line text
 195 would only waste precious space."
 196   :group 'auto-revert
 197   :type 'string)
 198
 199 (defcustom global-auto-revert-mode-hook nil
 200   "Hook called when Global Auto-Revert Mode is activated."
 201   :group 'auto-revert
 202   :type 'hook)
 203
 204 (defcustom global-auto-revert-non-file-buffers nil
 205   "When nil, Global Auto-Revert mode operates only on file-visiting buffers.
 206
 207 When non-nil, both file buffers and buffers with a custom
 208 `revert-buffer-function' and a `buffer-stale-function' are
 209 reverted by Global Auto-Revert mode.  These include the Buffer
 210 List buffer displayed by `buffer-menu', and Dired buffers showing
 211 complete local directories.  The Buffer List buffer reverts every
 212 `auto-revert-interval' seconds; Dired buffers when the file list of
 213 the main directory changes.  Dired buffers do not auto-revert as
 214 a result of changes in subdirectories, or in the contents, size,
 215 modes, etc., of files.  You may still sometimes want to revert
 216 them manually.
 217
 218 Use this option with care since it could lead to excessive auto-reverts.
 219 For more information, see Info node `(emacs)Autorevert'."
 220   :group 'auto-revert
 221   :type 'boolean
 222   :link '(info-link "(emacs)Autorevert"))
 223
 224 (defcustom global-auto-revert-ignore-modes ()
 225   "List of major modes Global Auto-Revert Mode should not check."
 226   :group 'auto-revert
 227   :type '(repeat sexp))
 228
 229 (defcustom auto-revert-load-hook nil
 230   "Functions to run when Auto-Revert Mode is first loaded."
 231   :tag "Load Hook"
 232   :group 'auto-revert
 233   :type 'hook)
 234
 235 (defcustom auto-revert-check-vc-info nil
 236   "If non-nil Auto Revert Mode reliably updates version control info.
 237 Auto Revert Mode updates version control info whenever the buffer
 238 needs reverting, regardless of the value of this variable.
 239 However, the version control state can change without changes to
 240 the work file.  If the change is made from the current Emacs
 241 session, all info is updated.  But if, for instance, a new
 242 version is checked in from outside the current Emacs session, the
 243 version control number in the mode line, as well as other version
 244 control related information, may not be properly updated.  If you
 245 are worried about this, set this variable to a non-nil value.
 246
 247 This currently works by automatically updating the version
 248 control info every `auto-revert-interval' seconds.  Nevertheless,
 249 it should not cause excessive CPU usage on a reasonably fast
 250 machine, if it does not apply to too many version controlled
 251 buffers.  CPU usage depends on the version control system."
 252   :group 'auto-revert
 253   :type 'boolean
 254   :version "22.1")
 255
 256 (defvar global-auto-revert-ignore-buffer nil
 257   "When non-nil, Global Auto-Revert Mode will not revert this buffer.
 258 This variable becomes buffer local when set in any fashion.")
 259 (make-variable-buffer-local 'global-auto-revert-ignore-buffer)
 260
 261 ;; Internal variables:
 262
 263 (defvar auto-revert-buffer-list ()
 264   "List of buffers in Auto-Revert Mode.
 265
 266 Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
 267 buffers to this list.
 268
 269 The timer function `auto-revert-buffers' is responsible for purging
 270 the list of old buffers.")
 271
 272 (defvar auto-revert-remaining-buffers ()
 273   "Buffers not checked when user input stopped execution.")
 274
 275 (defvar auto-revert-tail-pos 0
 276   "Position of last known end of file.")
 277
 278 (add-hook 'find-file-hook
 279           (lambda ()
 280             (set (make-local-variable 'auto-revert-tail-pos)
 281                  (nth 7 (file-attributes buffer-file-name)))))
 282
 283 ;; Functions:
 284
 285 ;;;###autoload
 286 (define-minor-mode auto-revert-mode
 287   "Toggle reverting buffer when the file changes (Auto Revert mode).
 288 With a prefix argument ARG, enable Auto Revert mode if ARG is
 289 positive, and disable it otherwise.  If called from Lisp, enable
 290 the mode if ARG is omitted or nil.
 291
 292 Auto Revert mode is a minor mode that affects only the current
 293 buffer.  When enabled, it reverts the buffer when the file on
 294 disk changes.
 295
 296 Use `global-auto-revert-mode' to automatically revert all buffers.
 297 Use `auto-revert-tail-mode' if you know that the file will only grow
 298 without being changed in the part that is already in the buffer."
 299   :group 'auto-revert :lighter auto-revert-mode-text
 300   (if auto-revert-mode
 301       (if (not (memq (current-buffer) auto-revert-buffer-list))
 302           (push (current-buffer) auto-revert-buffer-list))
 303     (setq auto-revert-buffer-list
 304           (delq (current-buffer) auto-revert-buffer-list)))
 305   (auto-revert-set-timer)
 306   (when auto-revert-mode
 307     (auto-revert-buffers)
 308     (setq auto-revert-tail-mode nil)))
 309
 310
 311 ;;;###autoload
 312 (defun turn-on-auto-revert-mode ()
 313   "Turn on Auto-Revert Mode.
 314
 315 This function is designed to be added to hooks, for example:
 316   (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
 317   (auto-revert-mode 1))
 318
 319
 320 ;;;###autoload
 321 (define-minor-mode auto-revert-tail-mode
 322   "Toggle reverting tail of buffer when the file grows.
 323 With a prefix argument ARG, enable Auto-Revert Tail mode if ARG
 324 is positive, and disable it otherwise.  If called from Lisp,
 325 enable the mode if ARG is omitted or nil.
 326
 327 When Auto Revert Tail mode is enabled, the tail of the file is
 328 constantly followed, as with the shell command `tail -f'.  This
 329 means that whenever the file grows on disk (presumably because
 330 some background process is appending to it from time to time),
 331 this is reflected in the current buffer.
 332
 333 You can edit the buffer and turn this mode off and on again as
 334 you please.  But make sure the background process has stopped
 335 writing before you save the file!
 336
 337 Use `auto-revert-mode' for changes other than appends!"
 338   :group 'find-file :lighter auto-revert-tail-mode-text
 339   (when auto-revert-tail-mode
 340     (unless buffer-file-name
 341       (auto-revert-tail-mode 0)
 342       (error "This buffer is not visiting a file"))
 343     (if (and (buffer-modified-p)
 344              (zerop auto-revert-tail-pos) ; library was loaded only after finding file
 345              (not (y-or-n-p "Buffer is modified, so tail offset may be wrong.  Proceed? ")))
 346         (auto-revert-tail-mode 0)
 347       ;; a-r-tail-pos stores the size of the file at the time of the
 348       ;; last revert. After this package loads, it adds a
 349       ;; find-file-hook to set this variable every time a file is
 350       ;; loaded.  If the package is loaded only _after_ visiting the
 351       ;; file to be reverted, then we have no idea what the value of
 352       ;; a-r-tail-pos should have been when the file was visited.  If
 353       ;; the file has changed on disk in the meantime, all we can do
 354       ;; is offer to revert the whole thing. If you choose not to
 355       ;; revert, then you might miss some output then happened
 356       ;; between visiting the file and activating a-r-t-mode.
 357       (and (zerop auto-revert-tail-pos)
 358            (not (verify-visited-file-modtime (current-buffer)))
 359            (y-or-n-p "File changed on disk, content may be missing.  \
 360 Perform a full revert? ")
 361            ;; Use this (not just revert-buffer) for point-preservation.
 362            (auto-revert-handler))
 363       ;; else we might reappend our own end when we save
 364       (add-hook 'before-save-hook (lambda () (auto-revert-tail-mode 0)) nil t)
 365       (or (local-variable-p 'auto-revert-tail-pos) ; don't lose prior position
 366           (set (make-local-variable 'auto-revert-tail-pos)
 367                (nth 7 (file-attributes buffer-file-name))))
 368       ;; let auto-revert-mode set up the mechanism for us if it isn't already
 369       (or auto-revert-mode
 370           (let ((auto-revert-tail-mode t))
 371             (auto-revert-mode 1)))
 372       (setq auto-revert-mode nil))))
 373
 374
 375 ;;;###autoload
 376 (defun turn-on-auto-revert-tail-mode ()
 377   "Turn on Auto-Revert Tail mode.
 378
 379 This function is designed to be added to hooks, for example:
 380   (add-hook 'my-logfile-mode-hook 'turn-on-auto-revert-tail-mode)"
 381   (auto-revert-tail-mode 1))
 382
 383
 384 ;;;###autoload
 385 (define-minor-mode global-auto-revert-mode
 386   "Toggle Global Auto Revert mode.
 387 With a prefix argument ARG, enable Global Auto Revert mode if ARG
 388 is positive, and disable it otherwise.  If called from Lisp,
 389 enable the mode if ARG is omitted or nil.
 390
 391 Global Auto Revert mode is a global minor mode that reverts any
 392 buffer associated with a file when the file changes on disk.  Use
 393 `auto-revert-mode' to revert a particular buffer.
 394
 395 If `global-auto-revert-non-file-buffers' is non-nil, this mode
 396 may also revert some non-file buffers, as described in the
 397 documentation of that variable.  It ignores buffers with modes
 398 matching `global-auto-revert-ignore-modes', and buffers with a
 399 non-nil vale of `global-auto-revert-ignore-buffer'.
 400
 401 This function calls the hook `global-auto-revert-mode-hook'.
 402 It displays the text that `global-auto-revert-mode-text'
 403 specifies in the mode line."
 404   :global t :group 'auto-revert :lighter global-auto-revert-mode-text
 405   (auto-revert-set-timer)
 406   (when global-auto-revert-mode
 407     (auto-revert-buffers)))
 408
 409
 410 (defun auto-revert-set-timer ()
 411   "Restart or cancel the timer used by Auto-Revert Mode.
 412 If such a timer is active, cancel it.  Start a new timer if
 413 Global Auto-Revert Mode is active or if Auto-Revert Mode is active
 414 in some buffer.  Restarting the timer ensures that Auto-Revert Mode
 415 will use an up-to-date value of `auto-revert-interval'"
 416   (interactive)
 417   (if (timerp auto-revert-timer)
 418       (cancel-timer auto-revert-timer))
 419   (setq auto-revert-timer
 420         (if (or global-auto-revert-mode auto-revert-buffer-list)
 421             (run-with-timer auto-revert-interval
 422                             auto-revert-interval
 423                             'auto-revert-buffers))))
 424
 425 (defun auto-revert-active-p ()
 426   "Check if auto-revert is active (in current buffer or globally)."
 427   (or auto-revert-mode
 428       auto-revert-tail-mode
 429       (and
 430        global-auto-revert-mode
 431        (not global-auto-revert-ignore-buffer)
 432        (not (memq major-mode
 433                   global-auto-revert-ignore-modes)))))
 434
 435 (defun auto-revert-handler ()
 436   "Revert current buffer, if appropriate.
 437 This is an internal function used by Auto-Revert Mode."
 438   (when (or auto-revert-tail-mode (not (buffer-modified-p)))
 439     (let* ((buffer (current-buffer)) size
 440            (revert
 441             (or (and buffer-file-name
 442                      (file-readable-p buffer-file-name)
 443                      (if auto-revert-tail-mode
 444                          ;; Tramp caches the file attributes.  Setting
 445                          ;; `remote-file-name-inhibit-cache' forces Tramp
 446                          ;; to reread the values.
 447                          (let ((remote-file-name-inhibit-cache t))
 448                            (/= auto-revert-tail-pos
 449                                (setq size
 450                                      (nth 7 (file-attributes
 451                                              buffer-file-name)))))
 452                        (and (not (file-remote-p buffer-file-name))
 453                             (not (verify-visited-file-modtime buffer)))))
 454                 (and (or auto-revert-mode
 455                          global-auto-revert-non-file-buffers)
 456                      revert-buffer-function
 457                      (boundp 'buffer-stale-function)
 458                      (functionp buffer-stale-function)
 459                      (funcall buffer-stale-function t))))
 460            eob eoblist)
 461       (when revert
 462         (when (and auto-revert-verbose
 463                    (not (eq revert 'fast)))
 464           (message "Reverting buffer `%s'." (buffer-name)))
 465         ;; If point (or a window point) is at the end of the buffer,
 466         ;; we want to keep it at the end after reverting.  This allows
 467         ;; to tail a file.
 468         (when buffer-file-name
 469           (setq eob (eobp))
 470           (walk-windows
 471            (lambda (window)
 472              (and (eq (window-buffer window) buffer)
 473                   (= (window-point window) (point-max))
 474                   (push window eoblist)))
 475            'no-mini t))
 476         (if auto-revert-tail-mode
 477             (auto-revert-tail-handler size)
 478           ;; Bind buffer-read-only in case user has done C-x C-q,
 479           ;; so as not to forget that.  This gives undesirable results
 480           ;; when the file's mode changes, but that is less common.
 481           (let ((buffer-read-only buffer-read-only))
 482             (revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)))
 483         (when buffer-file-name
 484           (when eob (goto-char (point-max)))
 485           (dolist (window eoblist)
 486             (set-window-point window (point-max)))))
 487       ;; `preserve-modes' avoids changing the (minor) modes.  But we
 488       ;; do want to reset the mode for VC, so we do it manually.
 489       (when (or revert auto-revert-check-vc-info)
 490         (vc-find-file-hook)))))
 491
 492 (defun auto-revert-tail-handler (size)
 493   (let ((modified (buffer-modified-p))
 494         (inhibit-read-only t)           ; Ignore.
 495         (file buffer-file-name)
 496         (buffer-file-name nil))         ; Ignore that file has changed.
 497     (when (/= auto-revert-tail-pos size)
 498       (run-hooks 'before-revert-hook)
 499       (undo-boundary)
 500       (save-restriction
 501         (widen)
 502         (save-excursion
 503           (goto-char (point-max))
 504           (insert-file-contents file nil
 505                                 (and (< auto-revert-tail-pos size)
 506                                      auto-revert-tail-pos)
 507                                 size)))
 508       (run-hooks 'after-revert-hook)
 509       (undo-boundary)
 510       (setq auto-revert-tail-pos size)
 511       (restore-buffer-modified-p modified)))
 512   (set-visited-file-modtime))
 513
 514 (defun auto-revert-buffers ()
 515   "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
 516
 517 Should `global-auto-revert-mode' be active all file buffers are checked.
 518
 519 Should `auto-revert-mode' be active in some buffers, those buffers
 520 are checked.
 521
 522 Non-file buffers that have a custom `revert-buffer-function' and
 523 a `buffer-stale-function' are reverted either when Auto-Revert
 524 Mode is active in that buffer, or when the variable
 525 `global-auto-revert-non-file-buffers' is non-nil and Global
 526 Auto-Revert Mode is active.
 527
 528 This function stops whenever there is user input.  The buffers not
 529 checked are stored in the variable `auto-revert-remaining-buffers'.
 530
 531 To avoid starvation, the buffers in `auto-revert-remaining-buffers'
 532 are checked first the next time this function is called.
 533
 534 This function is also responsible for removing buffers no longer in
 535 Auto-Revert mode from `auto-revert-buffer-list', and for canceling
 536 the timer when no buffers need to be checked."
 537   (save-match-data
 538     (let ((bufs (if global-auto-revert-mode
 539                     (buffer-list)
 540                   auto-revert-buffer-list))
 541           (remaining ())
 542           (new ()))
 543       ;; Partition `bufs' into two halves depending on whether or not
 544       ;; the buffers are in `auto-revert-remaining-buffers'.  The two
 545       ;; halves are then re-joined with the "remaining" buffers at the
 546       ;; head of the list.
 547       (dolist (buf auto-revert-remaining-buffers)
 548         (if (memq buf bufs)
 549             (push buf remaining)))
 550       (dolist (buf bufs)
 551         (if (not (memq buf remaining))
 552             (push buf new)))
 553       (setq bufs (nreverse (nconc new remaining)))
 554       (while (and bufs
 555                   (not (and auto-revert-stop-on-user-input
 556                             (input-pending-p))))
 557         (let ((buf (car bufs)))
 558           (if (buffer-live-p buf)
 559               (with-current-buffer buf
 560                 ;; Test if someone has turned off Auto-Revert Mode in a
 561                 ;; non-standard way, for example by changing major mode.
 562                 (if (and (not auto-revert-mode)
 563                          (not auto-revert-tail-mode)
 564                          (memq buf auto-revert-buffer-list))
 565                     (setq auto-revert-buffer-list
 566                           (delq buf auto-revert-buffer-list)))
 567                 (when (auto-revert-active-p) (auto-revert-handler)))
 568             ;; Remove dead buffer from `auto-revert-buffer-list'.
 569             (setq auto-revert-buffer-list
 570                   (delq buf auto-revert-buffer-list))))
 571         (setq bufs (cdr bufs)))
 572       (setq auto-revert-remaining-buffers bufs)
 573       ;; Check if we should cancel the timer.
 574       (when (and (not global-auto-revert-mode)
 575                  (null auto-revert-buffer-list))
 576         (cancel-timer auto-revert-timer)
 577         (setq auto-revert-timer nil)))))
 578
 579
 580 ;; The end:
 581 (provide 'autorevert)
 582
 583 (run-hooks 'auto-revert-load-hook)
 584
 585 ;;; autorevert.el ends here