configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 dnl FIXME hesiod support may not be present, so it seems like an error
  95 dnl to define, or at least use, this unconditionally.
  96 if test "$with_hesiod" != no; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 101 if test "$with_mmdf" != no; then
 102    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 106 if test "$with_mail_unlink" != no; then
 107    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 108 fi
 109
 110 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 111     [string giving default POP mail host])],
 112     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 113
 114 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 115
 116 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 117 if test "$with_sync_input" = yes; then
 118    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 119 fi
 120
 121 dnl FIXME currently it is not the last.
 122 dnl This should be the last --with option, because --with-x is
 123 dnl added later on when we find the path of X, and it's best to
 124 dnl keep them together visually.
 125 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 126  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 127 [         case "${withval}" in
 128             y | ye | yes )      val=gtk ;;
 129             n | no )            val=no  ;;
 130             l | lu | luc | luci | lucid )       val=lucid ;;
 131             a | at | ath | athe | athen | athena )      val=athena ;;
 132             m | mo | mot | moti | motif )       val=motif ;;
 133             g | gt | gtk  )     val=gtk ;;
 134             * )
 135 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 136 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 137 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 138             ;;
 139           esac
 140           with_x_toolkit=$val
 141 ])
 142
 143 dnl _ON results in a '--without' option in the --help output, so
 144 dnl the help text should refer to "don't compile", etc.
 145 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 146 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 147 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 148 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 149 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 150 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 151 OPTION_DEFAULT_OFF([imagemagick],[compile with ImageMagick image support])
 152
 153 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 154 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 155 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 156
 157 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 158 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 159 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 160 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 161
 162 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 163 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 164 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 165 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 166
 167 ## For the times when you want to build Emacs but don't have
 168 ## a suitable makeinfo, and can live without the manuals.
 169 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 170 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 171
 172 dnl Can remove these in Emacs 24.
 173 AC_ARG_WITH([gtk],,
 174   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 175 specify a toolkit.])],,)
 176
 177 AC_ARG_WITH([gcc],,
 178   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 179 variable to specify a compiler.])],,)
 180
 181 AC_ARG_WITH([pkg-config-prog],dnl
 182 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 183                   [path to pkg-config for finding GTK and librsvg])])
 184 if test "X${with_pkg_config_prog}" != X; then
 185    if test "${with_pkg_config_prog}" != yes; then
 186       PKG_CONFIG="${with_pkg_config_prog}"
 187    fi
 188 fi
 189
 190 CRT_DIR=
 191 AC_ARG_WITH([crt-dir],dnl
 192 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 193 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 194 CRT_DIR="${with_crt_dir}"
 195
 196 AC_ARG_WITH([gnustep-conf],dnl
 197 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 198 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 199   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 200 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 201      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 202
 203 AC_ARG_ENABLE(ns-self-contained,
 204 [AS_HELP_STRING([--disable-ns-self-contained],
 205                 [disable self contained build under NeXTstep])],
 206    EN_NS_SELF_CONTAINED=$enableval,
 207    EN_NS_SELF_CONTAINED=yes)
 208
 209 AC_ARG_ENABLE(asserts,
 210 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 211       USE_XASSERTS=$enableval,
 212       USE_XASSERTS=no)
 213
 214 AC_ARG_ENABLE(maintainer-mode,
 215 [AS_HELP_STRING([--enable-maintainer-mode],
 216                 [enable make rules and dependencies not useful (and sometimes
 217                  confusing) to the casual installer])],
 218       USE_MAINTAINER_MODE=$enableval,
 219       USE_MAINTAINER_MODE=no)
 220 if test $USE_MAINTAINER_MODE = yes; then
 221   MAINT=
 222 else
 223   MAINT=#
 224 fi
 225 AC_SUBST(MAINT)
 226
 227 AC_ARG_ENABLE(locallisppath,
 228 [AS_HELP_STRING([--enable-locallisppath=PATH],
 229                 [directories Emacs should search for lisp files specific
 230                  to this site])],
 231 if test "${enableval}" = "no"; then
 232   locallisppath=
 233 elif test "${enableval}" != "yes"; then
 234   locallisppath=${enableval}
 235 fi)
 236
 237 AC_ARG_ENABLE(checking,
 238 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 239                 [enable expensive run-time checks.  With LIST,
 240                  enable only specific categories of checks.
 241                  Categories are: all,yes,no.
 242                  Flags are: stringbytes, stringoverrun, stringfreelist,
 243                  xmallocoverrun, conslist])],
 244 [ac_checking_flags="${enableval}"],[])
 245 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 246 for check in $ac_checking_flags
 247 do
 248         case $check in
 249         # these set all the flags to specific states
 250         yes)            ac_enable_checking=1 ;;
 251         no)             ac_enable_checking= ;
 252                         ac_gc_check_stringbytes= ;
 253                         ac_gc_check_string_overrun= ;
 254                         ac_gc_check_string_free_list= ;
 255                         ac_xmalloc_overrun= ;
 256                         ac_gc_check_cons_list= ;;
 257         all)            ac_enable_checking=1 ;
 258                         ac_gc_check_stringbytes=1 ;
 259                         ac_gc_check_string_overrun=1 ;
 260                         ac_gc_check_string_free_list=1 ;
 261                         ac_xmalloc_overrun=1 ;
 262                         ac_gc_check_cons_list=1 ;;
 263         # these enable particular checks
 264         stringbytes)    ac_gc_check_stringbytes=1 ;;
 265         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 266         stringfreelist) ac_gc_check_string_free_list=1 ;;
 267         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 268         conslist)       ac_gc_check_cons_list=1 ;;
 269         *)      AC_MSG_ERROR(unknown check category $check) ;;
 270         esac
 271 done
 272 IFS="$ac_save_IFS"
 273
 274 if test x$ac_enable_checking != x ; then
 275   AC_DEFINE(ENABLE_CHECKING, 1,
 276 [Enable expensive run-time checking of data types?])
 277 fi
 278 if test x$ac_gc_check_stringbytes != x ; then
 279   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 280 [Define this temporarily to hunt a bug.  If defined, the size of
 281    strings is redundantly recorded in sdata structures so that it can
 282    be compared to the sizes recorded in Lisp strings.])
 283 fi
 284 if test x$ac_gc_check_stringoverrun != x ; then
 285   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 286 [Define this to check for short string overrun.])
 287 fi
 288 if test x$ac_gc_check_string_free_list != x ; then
 289   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 290 [Define this to check the string free list.])
 291 fi
 292 if test x$ac_xmalloc_overrun != x ; then
 293   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 294 [Define this to check for malloc buffer overrun.])
 295 fi
 296 if test x$ac_gc_check_cons_list != x ; then
 297   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 298 [Define this to check for errors in cons list.])
 299 fi
 300
 301 AC_ARG_ENABLE(profiling,
 302 [AS_HELP_STRING([--enable-profiling],
 303                 [build emacs with profiling support.
 304                  This might not work on all platforms])],
 305 [ac_enable_profiling="${enableval}"],[])
 306 if test x$ac_enable_profiling != x ; then
 307    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 308    PROFILING_LDFLAGS="-pg"
 309 else
 310    PROFILING_CFLAGS=
 311    PROFILING_LDFLAGS=
 312 fi
 313
 314 AC_ARG_ENABLE(autodepend,
 315 [AS_HELP_STRING([--enable-autodepend],
 316                 [automatically generate dependencies to .h-files.
 317                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 318                  found])],
 319 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 320
 321 #### Make srcdir absolute, if it isn't already.  It's important to
 322 #### avoid running the path through pwd unnecessarily, since pwd can
 323 #### give you automounter prefixes, which can go away.  We do all this
 324 #### so Emacs can find its files when run uninstalled.
 325 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 326 unset CDPATH
 327 case "${srcdir}" in
 328   /* ) ;;
 329   . )
 330     ## We may be able to use the $PWD environment variable to make this
 331     ## absolute.  But sometimes PWD is inaccurate.
 332     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 333     ## but that tested only for a well-formed and valid PWD,
 334     ## it did not object when PWD was well-formed and valid but just wrong.
 335     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 336     then
 337       srcdir="$PWD"
 338     else
 339       srcdir="`(cd ${srcdir}; pwd)`"
 340     fi
 341   ;;
 342   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 343 esac
 344
 345 #### Check if the source directory already has a configured system in it.
 346 if test `pwd` != `(cd ${srcdir} && pwd)` \
 347    && test -f "${srcdir}/src/config.h" ; then
 348   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 349    as a build directory right now; it has been configured in its own
 350    right.  To configure in another directory as well, you MUST
 351    use GNU make.  If you do not have GNU make, then you must
 352    now do `make distclean' in ${srcdir},
 353    and then run $0 again.]])
 354 fi
 355
 356 #### Given the configuration name, set machfile and opsysfile to the
 357 #### names of the m/*.h and s/*.h files we should use.
 358
 359 ### Canonicalize the configuration name.
 360
 361 AC_CANONICAL_HOST
 362 canonical=$host
 363 configuration=${host_alias-${build_alias-$host}}
 364
 365 dnl This used to use changequote, but, apart from `changequote is evil'
 366 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 367 dnl the great gob of text.  Thus it's not processed for possible expansion.
 368 dnl Just make sure the brackets remain balanced.
 369 dnl
 370 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 371 dnl indicated by comments.
 372 dnl quotation begins
 373 [
 374
 375 ### If you add support for a new configuration, add code to this
 376 ### switch statement to recognize your configuration name and select
 377 ### the appropriate operating system and machine description files.
 378
 379 ### You would hope that you could choose an m/*.h file pretty much
 380 ### based on the machine portion of the configuration name, and an s-
 381 ### file based on the operating system portion.  However, it turns out
 382 ### that each m/*.h file is pretty manufacturer-specific - for
 383 ### example mips.h is MIPS
 384 ### So we basically have to have a special case for each
 385 ### configuration name.
 386 ###
 387 ### As far as handling version numbers on operating systems is
 388 ### concerned, make sure things will fail in a fixable way.  If
 389 ### /etc/MACHINES doesn't say anything about version numbers, be
 390 ### prepared to handle anything reasonably.  If version numbers
 391 ### matter, be sure /etc/MACHINES says something about it.
 392 ###
 393 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 394 ### "System V Release 4"; he writes, "The old convention encouraged
 395 ### confusion between `system' and `release' levels'."
 396
 397 machine='' opsys='' unported=no
 398 case "${canonical}" in
 399
 400   ## FreeBSD ports
 401   *-*-freebsd* )
 402     opsys=freebsd
 403     case "${canonical}" in
 404       alpha*-*-freebsd*)        machine=alpha ;;
 405       arm*-*-freebsd*)          machine=arm ;;
 406       ia64-*-freebsd*)          machine=ia64 ;;
 407       sparc-*-freebsd*)         machine=sparc ;;
 408       sparc64-*-freebsd*)       machine=sparc ;;
 409       powerpc-*-freebsd*)       machine=macppc ;;
 410       i[3456]86-*-freebsd*)     machine=intel386 ;;
 411       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 412     esac
 413   ;;
 414
 415   ## FreeBSD kernel + glibc based userland
 416   *-*-kfreebsd*gnu* )
 417     opsys=gnu-kfreebsd
 418     case "${canonical}" in
 419       alpha*-*-kfreebsd*)       machine=alpha ;;
 420       ia64-*-kfreebsd*)         machine=ia64 ;;
 421       sparc-*-kfreebsd*)        machine=sparc ;;
 422       sparc64-*-kfreebsd*)      machine=sparc ;;
 423       powerpc-*-kfreebsd*)      machine=macppc ;;
 424       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 425       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 426     esac
 427   ;;
 428
 429   ## NetBSD ports
 430   *-*-netbsd* )
 431     opsys=netbsd
 432     case "${canonical}" in
 433       alpha*-*-netbsd*) machine=alpha ;;
 434       i[3456]86-*-netbsd*) machine=intel386 ;;
 435       mips-*-netbsd*)   machine=mips ;;
 436       mipsel-*-netbsd*) machine=mips ;;
 437       mipseb-*-netbsd*) machine=mips ;;
 438       powerpc-*-netbsd*) machine=macppc ;;
 439       sparc*-*-netbsd*) machine=sparc ;;
 440       vax-*-netbsd*)    machine=vax ;;
 441       arm-*-netbsd*)    machine=arm ;;
 442       x86_64-*-netbsd*) machine=amdx86-64 ;;
 443       hppa-*-netbsd*)   machine=hp800 ;;
 444       m68k-*-netbsd*)   machine=m68k ;;
 445     esac
 446   ;;
 447
 448   ## OpenBSD ports
 449   *-*-openbsd* )
 450     opsys=openbsd
 451     case "${canonical}" in
 452       alpha*-*-openbsd*)        machine=alpha ;;
 453       arm-*-openbsd*)          machine=arm ;;
 454       i386-*-openbsd*)         machine=intel386 ;;
 455       powerpc-*-openbsd*)      machine=macppc ;;
 456       sparc*-*-openbsd*)       machine=sparc ;;
 457       vax-*-openbsd*)          machine=vax ;;
 458       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 459       hppa-*-openbsd*)         machine=hp800 ;;
 460     esac
 461   ;;
 462
 463   alpha*-*-linux-gnu* )
 464     machine=alpha opsys=gnu-linux
 465   ;;
 466
 467   arm*-*-linux-gnu* )
 468     machine=arm opsys=gnu-linux
 469   ;;
 470
 471   ## Apple Darwin / Mac OS X
 472   *-apple-darwin* )
 473     case "${canonical}" in
 474       i[3456]86-* )  machine=intel386 ;;
 475       powerpc-* )    machine=macppc ;;
 476       x86_64-* )     machine=amdx86-64 ;;
 477       * )            unported=yes ;;
 478     esac
 479     opsys=darwin
 480     # Define CPP as follows to make autoconf work correctly.
 481     CPP="${CC-cc} -E -no-cpp-precomp"
 482     # Use fink packages if available.
 483     if test -d /sw/include && test -d /sw/lib; then
 484       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 485       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 486       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 487     fi
 488   ;;
 489
 490   ## HP 9000 series 700 and 800, running HP/UX
 491   hppa*-hp-hpux10.2* )
 492     machine=hp800 opsys=hpux10-20
 493   ;;
 494   hppa*-hp-hpux1[1-9]* )
 495     machine=hp800 opsys=hpux11
 496     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 497   ;;
 498
 499   hppa*-*-linux-gnu* )
 500     machine=hp800 opsys=gnu-linux
 501   ;;
 502
 503   ## IBM machines
 504   s390-*-linux-gnu* )
 505     machine=ibms390 opsys=gnu-linux
 506   ;;
 507   s390x-*-linux-gnu* )
 508     machine=ibms390x opsys=gnu-linux
 509   ;;
 510   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 511     machine=ibmrs6000 opsys=aix4-2
 512   ;;
 513   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 514     machine=ibmrs6000 opsys=aix4-2
 515   ;;
 516   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 517     machine=ibmrs6000 opsys=aix4-2
 518   ;;
 519   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 520     machine=ibmrs6000 opsys=aix4-2
 521   ;;
 522
 523   ## Macintosh PowerPC
 524   powerpc*-*-linux-gnu* )
 525     machine=macppc opsys=gnu-linux
 526   ;;
 527
 528   ## Silicon Graphics machines
 529   ## Iris 4D
 530   mips-sgi-irix6.5 )
 531     machine=iris4d opsys=irix6-5
 532     # Without defining _LANGUAGE_C, things get masked out in the headers
 533     # so that, for instance, grepping for `free' in stdlib.h fails and
 534     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 535     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 536     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 537   ;;
 538
 539   ## Suns
 540   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 541     machine=sparc opsys=gnu-linux
 542   ;;
 543
 544   *-sun-solaris* \
 545     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 546     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 547     case "${canonical}" in
 548       i[3456]86-*-* )     machine=intel386 ;;
 549       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 550       sparc* )          machine=sparc ;;
 551       * )               unported=yes ;;
 552     esac
 553     case "${canonical}" in
 554       *-sunos5.6* | *-solaris2.6* )
 555                 opsys=sol2-6
 556                 NON_GNU_CPP=/usr/ccs/lib/cpp
 557                 RANLIB="ar -ts"
 558                 ;;
 559       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 560                 opsys=sol2-6
 561                 emacs_check_sunpro_c=yes
 562                 NON_GNU_CPP=/usr/ccs/lib/cpp
 563                 ;;
 564       *-sunos5* | *-solaris* )
 565                 opsys=sol2-10
 566                 emacs_check_sunpro_c=yes
 567                 NON_GNU_CPP=/usr/ccs/lib/cpp
 568                 ;;
 569     esac
 570     ## Watch out for a compiler that we know will not work.
 571     case "${canonical}" in
 572      *-solaris* | *-sunos5* )
 573                 if [ "x$CC" = x/usr/ucb/cc ]; then
 574                   ## /usr/ucb/cc doesn't work;
 575                   ## we should find some other compiler that does work.
 576                   unset CC
 577                 fi
 578                 ;;
 579       *) ;;
 580     esac
 581   ;;
 582
 583   ## IA-64
 584   ia64*-*-linux* )
 585     machine=ia64 opsys=gnu-linux
 586   ;;
 587
 588   ## Intel 386 machines where we don't care about the manufacturer
 589   i[3456]86-*-* )
 590     machine=intel386
 591     case "${canonical}" in
 592       *-cygwin )                opsys=cygwin ;;
 593       *-darwin* )               opsys=darwin
 594                                 CPP="${CC-cc} -E -no-cpp-precomp"
 595                                 ;;
 596       *-linux-gnu* )            opsys=gnu-linux ;;
 597       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 598       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 599       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 600       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 601     esac
 602   ;;
 603
 604   ## m68k Linux-based GNU system
 605   m68k-*-linux-gnu* )
 606     machine=m68k opsys=gnu-linux
 607   ;;
 608
 609   ## Mips Linux-based GNU system
 610   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 611     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 612     machine=mips opsys=gnu-linux
 613   ;;
 614
 615   ## AMD x86-64 Linux-based GNU system
 616   x86_64-*-linux-gnu* )
 617     machine=amdx86-64 opsys=gnu-linux
 618   ;;
 619
 620   ## Tensilica Xtensa Linux-based GNU system
 621   xtensa*-*-linux-gnu* )
 622     machine=xtensa opsys=gnu-linux
 623     ;;
 624
 625   ## SuperH Linux-based GNU system
 626   sh[34]*-*-linux-gnu* )
 627     machine=sh3 opsys=gnu-linux
 628   ;;
 629
 630   * )
 631     unported=yes
 632   ;;
 633 esac
 634
 635 ### If the code above didn't choose an operating system, just choose
 636 ### an operating system based on the configuration name.  You really
 637 ### only want to use this when you have no idea what the right
 638 ### operating system is; if you know what operating systems a machine
 639 ### runs, it's cleaner to make it explicit in the case statement
 640 ### above.
 641 if test x"${opsys}" = x; then
 642   case "${canonical}" in
 643     *-gnu* )                            opsys=gnu ;;
 644     * )
 645       unported=yes
 646     ;;
 647   esac
 648 fi
 649
 650 ]
 651 dnl quotation ends
 652
 653 if test $unported = yes; then
 654   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 655 Check `etc/MACHINES' for recognized configuration names.])
 656 fi
 657
 658 machfile="m/${machine}.h"
 659 opsysfile="s/${opsys}.h"
 660
 661
 662 #### Choose a compiler.
 663 test -n "$CC" && cc_specified=yes
 664
 665 # Save the value of CFLAGS that the user specified.
 666 SPECIFIED_CFLAGS="$CFLAGS"
 667
 668 dnl Sets GCC=yes if using gcc.
 669 AC_PROG_CC
 670
 671 # On Suns, sometimes $CPP names a directory.
 672 if test -n "$CPP" && test -d "$CPP"; then
 673   CPP=
 674 fi
 675
 676 ## If not using gcc, and on Solaris, and no CPP specified, see if
 677 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 678 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 679  test x"$CPP" = x; then
 680   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 681   AC_CACHE_VAL(emacs_cv_sunpro_c,
 682   [AC_TRY_LINK([],
 683 [#ifndef __SUNPRO_C
 684 fail;
 685 #endif
 686 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 687   AC_MSG_RESULT($emacs_cv_sunpro_c)
 688
 689   if test x"$emacs_cv_sunpro_c" = xyes; then
 690     NON_GNU_CPP="$CC -E -Xs"
 691   fi
 692 fi
 693
 694 #### Some systems specify a CPP to use unless we are using GCC.
 695 #### Now that we know whether we are using GCC, we can decide whether
 696 #### to use that one.
 697 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 698 then
 699   CPP="$NON_GNU_CPP"
 700 fi
 701
 702 #### Some systems specify a CC to use unless we are using GCC.
 703 #### Now that we know whether we are using GCC, we can decide whether
 704 #### to use that one.
 705 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 706   test x$cc_specified != xyes
 707 then
 708   CC="$NON_GNU_CC"
 709 fi
 710
 711 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 712 then
 713   CC="$CC $GCC_TEST_OPTIONS"
 714 fi
 715
 716 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 717 then
 718   CC="$CC $NON_GCC_TEST_OPTIONS"
 719 fi
 720
 721 dnl checks for Unix variants
 722 AC_USE_SYSTEM_EXTENSIONS
 723
 724 ### Use -Wno-pointer-sign if the compiler supports it
 725 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 726 SAVE_CFLAGS="$CFLAGS"
 727 CFLAGS="$CFLAGS -Wno-pointer-sign"
 728 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 729 if test $has_option = yes; then
 730    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 731 fi
 732 AC_MSG_RESULT($has_option)
 733 CFLAGS="$SAVE_CFLAGS"
 734 unset has_option
 735 unset SAVE_CFLAGS
 736
 737 ### Use -Wdeclaration-after-statement if the compiler supports it
 738 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 739 SAVE_CFLAGS="$CFLAGS"
 740 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 741 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 742 if test $has_option = yes; then
 743    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 744 fi
 745 AC_MSG_RESULT($has_option)
 746 CFLAGS="$SAVE_CFLAGS"
 747 unset has_option
 748 unset SAVE_CFLAGS
 749
 750 #### Some other nice autoconf tests.
 751
 752 dnl checks for programs
 753 AC_PROG_CPP
 754 AC_PROG_INSTALL
 755 if test "x$RANLIB" = x; then
 756   AC_PROG_RANLIB
 757 fi
 758
 759 ## Although we're running on an amd64 kernel, we're actually compiling for
 760 ## the x86 architecture.  The user should probably have provided an
 761 ## explicit --build to `configure', but if everything else than the kernel
 762 ## is running in i386 mode, we can help them out.
 763 if test "$machine" = "amdx86-64"; then
 764   AC_CHECK_DECL([i386])
 765   if test "$ac_cv_have_decl_i386" = "yes"; then
 766     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 767     machine=intel386
 768     machfile="m/${machine}.h"
 769   fi
 770 fi
 771
 772 AC_PATH_PROG(INSTALL_INFO, install-info)
 773 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 774 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 775 dnl Don't use GZIP, which is used by gzip for additional parameters.
 776 AC_PATH_PROG(GZIP_PROG, gzip)
 777
 778
 779 ## Need makeinfo >= 4.6 (?) to build the manuals.
 780 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 781 dnl By this stage, configure has already checked for egrep and set EGREP,
 782 dnl or exited with an error if no egrep was found.
 783 if test "$MAKEINFO" != "no" && \
 784   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 785    MAKEINFO=no
 786 fi
 787
 788 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 789 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 790 ## therefore in the category of "special tools" not normally required, which
 791 ## configure does not have to check for (eg autoconf itself).
 792 ## In a Bazaar checkout on the other hand, the manuals are not included.
 793 ## So makeinfo is a requirement to build from Bazaar, and configure
 794 ## should test for it as it does for any other build requirement.
 795 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 796 ## with pre-built manuals, from a Bazaar checkout.
 797 if test "$MAKEINFO" = "no"; then
 798   if test "x${with_makeinfo}" = "xno"; then
 799     MAKEINFO=off
 800   elif test ! -e $srcdir/info/emacs; then
 801     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 802 source tree does not seem to have pre-built manuals in the `info' directory.
 803 Either install a suitable version of makeinfo, or re-run configure
 804 with the `--without-makeinfo' option to build without the manuals.] )
 805   fi
 806 fi
 807
 808 dnl Add our options to ac_link now, after it is set up.
 809
 810 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 811 then
 812   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 813 fi
 814
 815 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 816 then
 817   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 818 fi
 819
 820 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 821 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 822 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 823 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 824 dnl if not built to support GNU ld.
 825
 826 late_LDFLAGS=$LDFLAGS
 827 if test "$GCC" = yes; then
 828   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 829 else
 830   LDFLAGS="$LDFLAGS -znocombreloc"
 831 fi
 832
 833 AC_MSG_CHECKING([for -znocombreloc])
 834 AC_LINK_IFELSE([main(){return 0;}],
 835   [AC_MSG_RESULT(yes)],
 836   LDFLAGS=$late_LDFLAGS
 837   [AC_MSG_RESULT(no)])
 838
 839 #### Extract some information from the operating system and machine files.
 840
 841 AC_CHECKING([the machine- and system-dependent files to find out
 842  - which libraries the lib-src programs will want, and
 843  - whether the GNU malloc routines are usable])
 844
 845 ### First figure out CFLAGS (which we use for running the compiler here)
 846 ### and REAL_CFLAGS (which we use for real compilation).
 847 ### The two are the same except on a few systems, where they are made
 848 ### different to work around various lossages.  For example,
 849 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 850 ### as implying static linking.
 851
 852 ### If the CFLAGS env var is specified, we use that value
 853 ### instead of the default.
 854
 855 ### It's not important that this name contain the PID; you can't run
 856 ### two configures in the same directory and have anything work
 857 ### anyway.
 858 tempcname="conftest.c"
 859
 860 echo '
 861 #include "'${srcdir}'/src/'${opsysfile}'"
 862 #include "'${srcdir}'/src/'${machfile}'"
 863
 864 configure___ LIBX=-lX11
 865
 866 configure___ unexec=UNEXEC
 867
 868 #ifdef SYSTEM_MALLOC
 869 configure___ system_malloc=yes
 870 #else
 871 configure___ system_malloc=no
 872 #endif
 873
 874 #ifdef USE_MMAP_FOR_BUFFERS
 875 configure___ use_mmap_for_buffers=yes
 876 #else
 877 configure___ use_mmap_for_buffers=no
 878 #endif
 879
 880 #ifndef C_OPTIMIZE_SWITCH
 881 #ifdef __GNUC__
 882 #define C_OPTIMIZE_SWITCH -O2
 883 #else
 884 #define C_OPTIMIZE_SWITCH -O
 885 #endif
 886 #endif
 887
 888 #ifndef C_WARNINGS_SWITCH
 889 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 890 #endif
 891
 892 #ifdef THIS_IS_CONFIGURE
 893
 894 /* Get the CFLAGS for tests in configure.  */
 895 #ifdef __GNUC__
 896 configure___ CFLAGS=-g C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 897 #else
 898 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 899 #endif
 900
 901 #else /* not THIS_IS_CONFIGURE */
 902
 903 /* Get the CFLAGS for real compilation.  */
 904 #ifdef __GNUC__
 905 configure___ REAL_CFLAGS=-g C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 906 #else
 907 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 908 #endif
 909
 910 #endif /* not THIS_IS_CONFIGURE */
 911 ' > ${tempcname}
 912
 913 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 914
 915 # The value of CPP is a quoted variable reference, so we need to do this
 916 # to get its actual value...
 917 CPP=`eval "echo $CPP"`
 918 [eval `${CPP} -Isrc ${tempcname} \
 919        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 920 if test "x$SPECIFIED_CFLAGS" = x; then
 921   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 922          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 923 else
 924   REAL_CFLAGS="$CFLAGS"
 925 fi]
 926 rm ${tempcname}
 927
 928
 929 LD_SWITCH_SYSTEM=
 930 case "$opsys" in
 931   freebsd)
 932    ## Let `ld' find image libs and similar things in /usr/local/lib.
 933    ## The system compiler, GCC, has apparently been modified to not
 934    ## look there, contrary to what a stock GCC would do.
 935    LD_SWITCH_SYSTEM=-L/usr/local/lib
 936    ;;
 937
 938   gnu-linux)
 939    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 940    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 941    ;;
 942
 943   netbsd)
 944    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 945    ;;
 946
 947   openbsd)
 948    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 949    ## otherwise Emacs dumps core on elf systems.
 950    LD_SWITCH_SYSTEM="-Z"
 951    ;;
 952 esac
 953 AC_SUBST(LD_SWITCH_SYSTEM)
 954
 955 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 956
 957 ## This is fun.  Some settings of LD_SWITCH_SYSTEM reference
 958 ## LD_SWITCH_X_SITE_AUX, which has not been defined yet.  When using
 959 ## cpp, it was expanded to null.  Thus LD_SWITCH_SYSTEM had different
 960 ## values in configure and the Makefiles.  How helpful.
 961 ## FIXME why not use LD_SWITCH_SYSTEM_TEMACS (or somesuch) instead?
 962 case "$opsys" in
 963   gnu-linux)
 964    ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
 965    LD_SWITCH_SYSTEM="$LD_SWITCH_SYSTEM \$(LD_SWITCH_X_SITE_AUX)" ;;
 966
 967   netbsd|openbsd)
 968    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 969    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 970 esac
 971
 972
 973 C_SWITCH_MACHINE=
 974 if test "$machine" = "alpha"; then
 975   AC_CHECK_DECL([__ELF__])
 976   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 977     ## With ELF, make sure that all common symbols get allocated to in the
 978     ## data section.  Otherwise, the dump of temacs may miss variables in
 979     ## the shared library that have been initialized.  For example, with
 980     ## GNU libc, __malloc_initialized would normally be resolved to the
 981     ## shared library's .bss section, which is fatal.
 982     if test "x$GCC" = "xyes"; then
 983       C_SWITCH_MACHINE="-fno-common"
 984     else
 985       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 986     fi
 987   fi
 988 fi
 989 AC_SUBST(C_SWITCH_MACHINE)
 990
 991
 992 C_SWITCH_SYSTEM=
 993 ## Some programs in src produce warnings saying certain subprograms
 994 ## are too complex and need a MAXMEM value greater than 2000 for
 995 ## additional optimization.  --nils@exp-math.uni-essen.de
 996 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 997   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 998 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 999 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1000 AC_SUBST(C_SWITCH_SYSTEM)
1001
1002
1003 LIBS_SYSTEM=
1004 case "$opsys" in
1005   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1006   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1007
1008   freebsd) LIBS_SYSTEM="-lutil" ;;
1009
1010   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1011
1012   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1013
1014   ## Motif needs -lgen.
1015   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1016 esac
1017 AC_SUBST(LIBS_SYSTEM)
1018
1019
1020 ### Make sure subsequent tests use flags consistent with the build flags.
1021
1022 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1023   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1024 else
1025   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1026 fi
1027
1028 dnl For AC_FUNC_GETLOADAVG, at least:
1029 AC_CONFIG_LIBOBJ_DIR(src)
1030
1031 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1032 AC_SYS_LARGEFILE
1033
1034
1035 ## If user specified a crt-dir, use that unconditionally.
1036 if test "X$CRT_DIR" = "X"; then
1037
1038   case "$canonical" in
1039     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1040     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1041     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1042     ## For anything else (eg /usr/lib32), it is up the user to specify
1043     ## the location (bug#5655).
1044     ## Test for crtn.o, not just the directory, because sometimes the
1045     ## directory exists but does not have the relevant files (bug#1287).
1046     ## FIXME better to test for binary compatibility somehow.
1047     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1048     ;;
1049
1050     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1051   esac
1052
1053   case "$opsys" in
1054     hpux10-20) CRT_DIR=/lib ;;
1055   esac
1056
1057   ## Default is /usr/lib.
1058   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1059
1060 else
1061
1062   ## Some platforms don't use any of these files, so it is not
1063   ## appropriate to put this test outside the if block.
1064   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1065     AC_MSG_ERROR([crt*.o not found in specified location.])
1066
1067 fi
1068
1069 AC_SUBST(CRT_DIR)
1070
1071 LIB_MATH=-lm
1072 LIB_STANDARD=
1073 START_FILES=
1074
1075 case $opsys in
1076   cygwin )
1077     LIB_MATH=
1078     START_FILES='ecrt0.o'
1079     ;;
1080   darwin )
1081     ## Adding -lm confuses the dynamic linker, so omit it.
1082     LIB_MATH=
1083     START_FILES='pre-crt0.o'
1084     ;;
1085   freebsd )
1086     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1087     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1088     ;;
1089   gnu-linux | gnu-kfreebsd )
1090     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1091     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1092     ;;
1093   hpux10-20 | hpux11 )
1094     LIB_STANDARD=-lc
1095     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1096     ;;
1097   netbsd | openbsd )
1098     if test -f $(CRT_DIR)/crti.o; then
1099         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1100         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1101     else
1102         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1103         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1104     fi
1105     ;;
1106 esac
1107
1108 AC_SUBST(LIB_MATH)
1109 AC_SUBST(START_FILES)
1110
1111 dnl This function definition taken from Gnome 2.0
1112 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1113 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1114 dnl also defines GSTUFF_PKG_ERRORS on error
1115 AC_DEFUN([PKG_CHECK_MODULES], [
1116   succeeded=no
1117
1118   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1119
1120   if test "$PKG_CONFIG" = "no" ; then
1121      ifelse([$4], , [AC_MSG_ERROR([
1122       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1123   else
1124      PKG_CONFIG_MIN_VERSION=0.9.0
1125      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1126         AC_MSG_CHECKING(for $2)
1127
1128         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1129             AC_MSG_RESULT(yes)
1130             succeeded=yes
1131
1132             AC_MSG_CHECKING($1_CFLAGS)
1133             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1134             AC_MSG_RESULT($$1_CFLAGS)
1135
1136             AC_MSG_CHECKING($1_LIBS)
1137             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1138             AC_MSG_RESULT($$1_LIBS)
1139         else
1140             AC_MSG_RESULT(no)
1141             $1_CFLAGS=""
1142             $1_LIBS=""
1143             ## If we have a custom action on failure, don't print errors, but
1144             ## do set a variable so people can do so.
1145             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1146             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1147         fi
1148
1149         AC_SUBST($1_CFLAGS)
1150         AC_SUBST($1_LIBS)
1151      else
1152         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1153         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1154      fi
1155   fi
1156
1157   if test $succeeded = yes; then
1158      ifelse([$3], , :, [$3])
1159   else
1160      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1161   fi
1162 ])
1163
1164
1165 if test "${with_sound}" != "no"; then
1166   # Sound support for GNU/Linux and the free BSDs.
1167   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1168   # Emulation library used on NetBSD.
1169   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1170   AC_SUBST(LIBSOUND)
1171
1172   ALSA_REQUIRED=1.0.0
1173   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1174   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1175   if test $HAVE_ALSA = yes; then
1176     SAVE_CFLAGS="$CFLAGS"
1177     SAVE_LDFLAGS="$LDFLAGS"
1178     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1179     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1180     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1181                     emacs_alsa_normal=yes,
1182                     emacs_alsa_normal=no)
1183     if test "$emacs_alsa_normal" != yes; then
1184       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1185                      [snd_lib_error_set_handler (0);],
1186                      emacs_alsa_subdir=yes,
1187                      emacs_alsa_subdir=no)
1188       if test "$emacs_alsa_subdir" != yes; then
1189         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1190       fi
1191       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1192     fi
1193
1194     CFLAGS="$SAVE_CFLAGS"
1195     LDFLAGS="$SAVE_LDFLAGS"
1196     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1197     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1198     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1199   fi
1200   AC_SUBST(CFLAGS_SOUND)
1201 fi
1202
1203 dnl checks for header files
1204 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1205   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1206   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1207   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1208   sys/utsname.h pwd.h utmp.h)
1209
1210 AC_MSG_CHECKING(if personality LINUX32 can be set)
1211 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1212                emacs_cv_personality_linux32=yes,
1213                emacs_cv_personality_linux32=no)
1214 AC_MSG_RESULT($emacs_cv_personality_linux32)
1215
1216 if test $emacs_cv_personality_linux32 = yes; then
1217   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1218             [Define to 1 if personality LINUX32 can be set.])
1219 fi
1220
1221 dnl On Solaris 8 there's a compilation warning for term.h because
1222 dnl it doesn't define `bool'.
1223 AC_CHECK_HEADERS(term.h, , , -)
1224 AC_HEADER_STDC
1225 AC_HEADER_TIME
1226 AC_CHECK_DECLS([sys_siglist])
1227 if test $ac_cv_have_decl_sys_siglist != yes; then
1228   # For Tru64, at least:
1229   AC_CHECK_DECLS([__sys_siglist])
1230   if test $ac_cv_have_decl___sys_siglist = yes; then
1231     AC_DEFINE(sys_siglist, __sys_siglist,
1232               [Define to any substitute for sys_siglist.])
1233   fi
1234 fi
1235 AC_HEADER_SYS_WAIT
1236
1237 dnl Some systems have utime.h but don't declare the struct anyplace.
1238 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1239 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1240 #include <sys/time.h>
1241 #include <time.h>
1242 #else
1243 #ifdef HAVE_SYS_TIME_H
1244 #include <sys/time.h>
1245 #else
1246 #include <time.h>
1247 #endif
1248 #endif
1249 #ifdef HAVE_UTIME_H
1250 #include <utime.h>
1251 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1252   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1253 if test $emacs_cv_struct_utimbuf = yes; then
1254   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1255 fi
1256
1257 dnl checks for typedefs
1258 AC_TYPE_SIGNAL
1259
1260 dnl Check for speed_t typedef.
1261 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1262   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1263     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1264 if test $emacs_cv_speed_t = yes; then
1265   AC_DEFINE(HAVE_SPEED_T, 1,
1266            [Define to 1 if `speed_t' is declared by <termios.h>.])
1267 fi
1268
1269 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1270 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1271 #include <sys/time.h>
1272 #include <time.h>
1273 #else
1274 #ifdef HAVE_SYS_TIME_H
1275 #include <sys/time.h>
1276 #else
1277 #include <time.h>
1278 #endif
1279 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1280   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1281 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1282 if test $emacs_cv_struct_timeval = yes; then
1283   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1284 fi
1285
1286 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1287 AC_TRY_COMPILE([#include <math.h>],
1288 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1289   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1290 HAVE_EXCEPTION=$emacs_cv_struct_exception
1291 if test $emacs_cv_struct_exception != yes; then
1292   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1293 fi
1294
1295 AC_CHECK_HEADERS(sys/socket.h)
1296 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1297 #if HAVE_SYS_SOCKET_H
1298 #include <sys/socket.h>
1299 #endif])
1300
1301 dnl checks for structure members
1302 AC_STRUCT_TM
1303 AC_STRUCT_TIMEZONE
1304 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1305                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1306                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1307                 [#include <time.h>])
1308 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1309                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1310                   struct ifreq.ifr_addr], , ,
1311                  [AC_INCLUDES_DEFAULT
1312 #if HAVE_SYS_SOCKET_H
1313 #include <sys/socket.h>
1314 #endif
1315 #if HAVE_NET_IF_H
1316 #include <net/if.h>
1317 #endif])
1318
1319 dnl checks for compiler characteristics
1320
1321 dnl Testing __STDC__ to determine prototype support isn't good enough.
1322 dnl DEC C, for instance, doesn't define it with default options, and
1323 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1324 dnl and void *.
1325 AC_C_PROTOTYPES
1326 AC_C_VOLATILE
1327 AC_C_CONST
1328 dnl This isn't useful because we can't turn on use of `inline' unless
1329 dnl the compiler groks `extern inline'.
1330 dnl AC_C_INLINE
1331 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1332   [AC_TRY_COMPILE(, [void * foo;],
1333                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1334 if test $emacs_cv_void_star = yes; then
1335   AC_DEFINE(POINTER_TYPE, void)
1336 else
1337   AC_DEFINE(POINTER_TYPE, char)
1338 fi
1339 AH_TEMPLATE(POINTER_TYPE,
1340             [Define as `void' if your compiler accepts `void *'; otherwise
1341              define as `char'.])dnl
1342
1343
1344
1345 dnl This could be used for targets which can have both byte sexes.
1346 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1347 dnl AC_C_BIGENDIAN
1348
1349 dnl check for Make feature
1350 AC_PROG_MAKE_SET
1351
1352 dnl check for GNU Make if we have GCC and autodepend is on.
1353 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1354    AC_MSG_CHECKING([whether we are using GNU Make])
1355    HAVE_GNU_MAKE=no
1356    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1357    if test "x$testval" != x; then
1358       HAVE_GNU_MAKE=yes
1359    else
1360       ac_enable_autodepend=no
1361    fi
1362    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1363    if test $HAVE_GNU_MAKE = yes; then
1364       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1365       SAVE_CFLAGS="$CFLAGS"
1366       CFLAGS="$CFLAGS -MMD -MF deps.d"
1367       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1368       CFLAGS="$SAVE_CFLAGS"
1369       test -f deps.d || ac_enable_autodepend=no
1370       rm -rf deps.d
1371       AC_MSG_RESULT([$ac_enable_autodepend])
1372    fi
1373    if test $ac_enable_autodepend = yes; then
1374       AC_DEFINE(AUTO_DEPEND, 1, [Generate dependencies with gcc.])
1375    fi
1376 fi
1377
1378 dnl checks for operating system services
1379 AC_SYS_LONG_FILE_NAMES
1380
1381 #### Choose a window system.
1382
1383 AC_PATH_X
1384 if test "$no_x" = yes; then
1385   window_system=none
1386 else
1387   window_system=x11
1388 fi
1389
1390 ## Workaround for bug in autoconf <= 2.62.
1391 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1392 ## No need to do anything special for these standard directories.
1393 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1394
1395    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1396
1397 fi
1398
1399 LD_SWITCH_X_SITE_AUX=
1400 LD_SWITCH_X_SITE_AUX_RPATH=
1401 if test "${x_libraries}" != NONE; then
1402   if test -n "${x_libraries}"; then
1403     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1404     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1405     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1406   fi
1407   x_default_search_path=""
1408   x_search_path=${x_libraries}
1409   if test -z "${x_search_path}"; then
1410     x_search_path=/usr/lib
1411   fi
1412   for x_library in `echo ${x_search_path}: | \
1413                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1414     x_search_path="\
1415 ${x_library}/X11/%L/%T/%N%C%S:\
1416 ${x_library}/X11/%l/%T/%N%C%S:\
1417 ${x_library}/X11/%T/%N%C%S:\
1418 ${x_library}/X11/%L/%T/%N%S:\
1419 ${x_library}/X11/%l/%T/%N%S:\
1420 ${x_library}/X11/%T/%N%S"
1421     if test x"${x_default_search_path}" = x; then
1422       x_default_search_path=${x_search_path}
1423     else
1424       x_default_search_path="${x_search_path}:${x_default_search_path}"
1425     fi
1426   done
1427 fi
1428 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1429 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1430
1431 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1432   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1433 fi
1434
1435 if test x"${x_includes}" = x; then
1436   bitmapdir=/usr/include/X11/bitmaps
1437 else
1438   # accumulate include directories that have X11 bitmap subdirectories
1439   bmd_acc="dummyval"
1440   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1441     if test -d "${bmd}/X11/bitmaps"; then
1442       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1443     fi
1444     if test -d "${bmd}/bitmaps"; then
1445       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1446     fi
1447   done
1448   if test ${bmd_acc} != "dummyval"; then
1449     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1450   fi
1451 fi
1452
1453 HAVE_NS=no
1454 NS_IMPL_COCOA=no
1455 NS_IMPL_GNUSTEP=no
1456 tmp_CPPFLAGS="$CPPFLAGS"
1457 tmp_CFLAGS="$CFLAGS"
1458 CPPFLAGS="$CPPFLAGS -x objective-c"
1459 CFLAGS="$CFLAGS -x objective-c"
1460 if test "${with_ns}" != no; then
1461   if test "${opsys}" = darwin; then
1462      NS_IMPL_COCOA=yes
1463      ns_appdir=`pwd`/nextstep/Emacs.app
1464      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1465      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1466      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1467   elif test -f $GNUSTEP_CONFIG_FILE; then
1468      NS_IMPL_GNUSTEP=yes
1469      ns_appdir=`pwd`/nextstep/Emacs.app
1470      ns_appbindir=`pwd`/nextstep/Emacs.app
1471      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1472      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1473      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1474      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1475      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1476      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1477      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1478      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1479      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1480      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1481      LIB_STANDARD=
1482   fi
1483   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1484                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1485   files are missing or cannot be compiled.])])
1486   NS_HAVE_NSINTEGER=yes
1487   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1488                                      [NSInteger i;])],
1489                     ns_have_nsinteger=yes,
1490                     ns_have_nsinteger=no)
1491   if test $ns_have_nsinteger = no; then
1492     NS_HAVE_NSINTEGER=no
1493   fi
1494 fi
1495
1496 NS_OBJ=
1497 NS_SUPPORT=
1498 if test "${HAVE_NS}" = yes; then
1499   window_system=nextstep
1500   with_xft=no
1501   # set up packaging dirs
1502   exec_prefix=${ns_appbindir}
1503   libexecdir=${ns_appbindir}/libexec
1504   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1505      prefix=${ns_appresdir}
1506   fi
1507   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1508   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1509 fi
1510 CFLAGS="$tmp_CFLAGS"
1511 CPPFLAGS="$tmp_CPPFLAGS"
1512 AC_SUBST(NS_OBJ)
1513 AC_SUBST(NS_SUPPORT)
1514 AC_SUBST(LIB_STANDARD)
1515
1516 case "${window_system}" in
1517   x11 )
1518     HAVE_X_WINDOWS=yes
1519     HAVE_X11=yes
1520     case "${with_x_toolkit}" in
1521       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1522       motif ) USE_X_TOOLKIT=MOTIF ;;
1523       gtk ) with_gtk=yes
1524 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1525 dnl USE_X_TOOLKIT is set.
1526             USE_X_TOOLKIT=none ;;
1527       no ) USE_X_TOOLKIT=none ;;
1528 dnl If user did not say whether to use a toolkit, make this decision later:
1529 dnl use the toolkit if we have gtk, or X11R5 or newer.
1530       * ) USE_X_TOOLKIT=maybe ;;
1531     esac
1532   ;;
1533   nextstep | none )
1534     HAVE_X_WINDOWS=no
1535     HAVE_X11=no
1536     USE_X_TOOLKIT=none
1537   ;;
1538 esac
1539
1540 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1541    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1542    if test "$HAVE_XSERVER" = true ||
1543       test -n "$DISPLAY" ||
1544       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1545         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1546 were found.  You should install the relevant development files for X
1547 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1548 sure you have development files for image handling, i.e.
1549 tiff, gif, jpeg, png and xpm.
1550 If you are sure you want Emacs compiled without X window support, pass
1551   --without-x
1552 to configure.])
1553    fi
1554 fi
1555
1556 ### If we're using X11, we should use the X menu package.
1557 HAVE_MENUS=no
1558 case ${HAVE_X11} in
1559   yes ) HAVE_MENUS=yes ;;
1560 esac
1561
1562 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1563 # Assume not, until told otherwise.
1564 GNU_MALLOC=yes
1565 doug_lea_malloc=yes
1566 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1567 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1568 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1569                emacs_cv_var___after_morecore_hook,
1570 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1571   emacs_cv_var___after_morecore_hook=yes,
1572   emacs_cv_var___after_morecore_hook=no)])
1573 if test $emacs_cv_var___after_morecore_hook = no; then
1574   doug_lea_malloc=no
1575 fi
1576 if test "${system_malloc}" = "yes"; then
1577   GNU_MALLOC=no
1578   GNU_MALLOC_reason="
1579     (The GNU allocators don't work with this system configuration.)"
1580 fi
1581 if test "$doug_lea_malloc" = "yes" ; then
1582   if test "$GNU_MALLOC" = yes ; then
1583     GNU_MALLOC_reason="
1584       (Using Doug Lea's new malloc from the GNU C Library.)"
1585   fi
1586   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1587             [Define to 1 if you are using the GNU C Library.])
1588 fi
1589
1590 if test x"${REL_ALLOC}" = x; then
1591   REL_ALLOC=${GNU_MALLOC}
1592 fi
1593
1594 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1595 dnl the system configuration file (s/*.h) to turn the use of mmap
1596 dnl in the relocating allocator on.
1597
1598 AC_FUNC_MMAP
1599 if test $use_mmap_for_buffers = yes; then
1600   REL_ALLOC=no
1601 fi
1602
1603 LIBS="$LIBS_SYSTEM $LIBS"
1604
1605 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1606 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1607 AC_CHECK_LIB(dnet, dnet_ntoa)
1608 dnl This causes -lresolv to get used in subsequent tests,
1609 dnl which causes failures on some systems such as HPUX 9.
1610 dnl AC_CHECK_LIB(resolv, gethostbyname)
1611
1612 dnl FIXME replace main with a function we actually want from this library.
1613 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1614
1615 AC_CHECK_LIB(pthreads, cma_open)
1616
1617 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1618 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1619 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1620 ## added to LIBS in configure would never contain the pthreads part,
1621 ## but the value used in Makefiles might.  FIXME?
1622 ##
1623 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1624 ## be harmless on older versions of X where it happens to exist.
1625 test "$opsys" = "aix4-2" && \
1626   test $ac_cv_lib_pthreads_cma_open = yes && \
1627   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1628
1629 dnl Check for need for bigtoc support on IBM AIX
1630
1631 case ${host_os} in
1632 aix*)
1633   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1634     case $GCC in
1635     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1636     *) gdb_cv_bigtoc=-bbigtoc ;;
1637     esac
1638
1639     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1640     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1641   ])
1642   ;;
1643 esac
1644
1645 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1646 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1647 # REAL_CPPFLAGS later on.
1648
1649 REAL_CPPFLAGS="$CPPFLAGS"
1650
1651 if test "${HAVE_X11}" = "yes"; then
1652   DEFS="$C_SWITCH_X_SITE $DEFS"
1653   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1654   LIBS="$LIBX $LIBS"
1655   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1656   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1657
1658   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1659   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1660   # but it's more convenient here to set LD_RUN_PATH
1661   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1662   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1663     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1664     export LD_RUN_PATH
1665   fi
1666
1667   if test "${opsys}" = "gnu-linux"; then
1668     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1669     AC_TRY_LINK([],
1670      [XOpenDisplay ("foo");],
1671      [xlinux_first_failure=no],
1672      [xlinux_first_failure=yes])
1673     if test "${xlinux_first_failure}" = "yes"; then
1674       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1675       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1676       OLD_CPPFLAGS="$CPPFLAGS"
1677       OLD_LIBS="$LIBS"
1678       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1679       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1680       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1681       LIBS="$LIBS -b i486-linuxaout"
1682       AC_TRY_LINK([],
1683        [XOpenDisplay ("foo");],
1684        [xlinux_second_failure=no],
1685        [xlinux_second_failure=yes])
1686       if test "${xlinux_second_failure}" = "yes"; then
1687         # If we get the same failure with -b, there is no use adding -b.
1688         # So take it out.  This plays safe.
1689         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1690         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1691         CPPFLAGS="$OLD_CPPFLAGS"
1692         LIBS="$OLD_LIBS"
1693         AC_MSG_RESULT(no)
1694       else
1695         AC_MSG_RESULT(yes)
1696       fi
1697     else
1698       AC_MSG_RESULT(no)
1699     fi
1700   fi
1701
1702   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1703   # header files included from there.
1704   AC_MSG_CHECKING(for Xkb)
1705   AC_TRY_LINK([#include <X11/Xlib.h>
1706 #include <X11/XKBlib.h>],
1707         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1708         emacs_xkb=yes, emacs_xkb=no)
1709   AC_MSG_RESULT($emacs_xkb)
1710   if test $emacs_xkb = yes; then
1711     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1712   fi
1713
1714   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1715 XScreenNumberOfScreen XSetWMProtocols)
1716 fi
1717
1718 if test "${window_system}" = "x11"; then
1719   AC_MSG_CHECKING(X11 version 6)
1720   AC_CACHE_VAL(emacs_cv_x11_version_6,
1721   [AC_TRY_LINK([#include <X11/Xlib.h>],
1722 [#if XlibSpecificationRelease < 6
1723 fail;
1724 #endif
1725 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1726   if test $emacs_cv_x11_version_6 = yes; then
1727     AC_MSG_RESULT(6 or newer)
1728     AC_DEFINE(HAVE_X11R6, 1,
1729               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1730   else
1731     AC_MSG_RESULT(before 6)
1732   fi
1733 fi
1734
1735
1736 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1737 HAVE_RSVG=no
1738 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1739   if test "${with_rsvg}" != "no"; then
1740     RSVG_REQUIRED=2.11.0
1741     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1742
1743     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1744     AC_SUBST(RSVG_CFLAGS)
1745     AC_SUBST(RSVG_LIBS)
1746
1747     if test ".${RSVG_CFLAGS}" != "."; then
1748       HAVE_RSVG=yes
1749       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1750       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1751       LIBS="$RSVG_LIBS $LIBS"
1752     fi
1753   fi
1754 fi
1755
1756 HAVE_IMAGEMAGICK=no
1757 if test "${with_imagemagick}" != "no"; then
1758   IMAGEMAGICK_MODULE="Wand"
1759   PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, :, :)
1760   AC_SUBST(IMAGEMAGICK_CFLAGS)
1761   AC_SUBST(IMAGEMAGICK_LIBS)
1762
1763   if test ".${IMAGEMAGICK_CFLAGS}" != "."; then
1764     HAVE_IMAGEMAGICK=yes
1765     AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1766     CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1767     LIBS="$IMAGEMAGICK_LIBS $LIBS"
1768   fi
1769
1770   AC_DEFINE(HAVE_MAGICKEXPORTIMAGEPIXELS, 1, [Define to 1 if MagickExportImagePixels is defined.])
1771   AC_CHECK_FUNCS_ONCE(MagickExportImagePixels)
1772
1773 fi
1774
1775
1776 HAVE_GTK=no
1777 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1778   GLIB_REQUIRED=2.6
1779   GTK_REQUIRED=2.6
1780   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1781
1782   dnl Checks for libraries.
1783   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1784   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1785      AC_MSG_ERROR($GTK_PKG_ERRORS)
1786   fi
1787 fi
1788
1789
1790 GTK_OBJ=
1791 if test x"$pkg_check_gtk" = xyes; then
1792
1793   AC_SUBST(GTK_CFLAGS)
1794   AC_SUBST(GTK_LIBS)
1795   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1796   CFLAGS="$CFLAGS $GTK_CFLAGS"
1797   LIBS="$GTK_LIBS $LIBS"
1798   dnl Try to compile a simple GTK program.
1799   GTK_COMPILES=no
1800   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1801   if test "${GTK_COMPILES}" != "yes"; then
1802     if test "$USE_X_TOOLKIT" != "maybe"; then
1803       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1804     fi
1805   else
1806     HAVE_GTK=yes
1807     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1808     GTK_OBJ=gtkutil.o
1809     USE_X_TOOLKIT=none
1810     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1811       :
1812     else
1813       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1814        closing open displays.  This is no problem if you just use
1815        one display, but if you use more than one and close one of them
1816        Emacs may crash.]])
1817       sleep 3
1818     fi
1819   fi
1820
1821 fi
1822 AC_SUBST(GTK_OBJ)
1823
1824
1825 if test "${HAVE_GTK}" = "yes"; then
1826
1827   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1828   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1829   if test "$with_toolkit_scroll_bars" != no; then
1830     with_toolkit_scroll_bars=yes
1831   fi
1832
1833   dnl  Check if we can use multiple displays with this GTK version.
1834   dnl  If gdk_display_open exists, assume all others are there also.
1835   HAVE_GTK_MULTIDISPLAY=no
1836   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1837   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1838     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1839               [Define to 1 if GTK can handle more than one display.])
1840   fi
1841
1842   dnl  Check if we have the old file selection dialog declared and
1843   dnl  in the link library.  In 2.x it may be in the library,
1844   dnl  but not declared if deprecated featured has been selected out.
1845   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1846   HAVE_GTK_FILE_SELECTION=no
1847   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1848                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1849 #include <gtk/gtk.h>])
1850   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1851     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1852                    HAVE_GTK_FILE_SELECTION=no)
1853   fi
1854
1855   dnl  Check if we have the new file chooser dialog
1856   HAVE_GTK_FILE_CHOOSER=no
1857   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1858                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1859 #include <gtk/gtk.h>])
1860   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1861     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1862                    HAVE_GTK_FILE_CHOOSER=no)
1863   fi
1864
1865   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1866      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1867     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1868               [Define to 1 if GTK has both file selection and chooser dialog.])
1869   fi
1870
1871   dnl Check if pthreads are available.  Emacs only needs this when using
1872   dnl gtk_file_chooser under Gnome.
1873   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1874     HAVE_GTK_AND_PTHREAD=no
1875     AC_CHECK_HEADERS(pthread.h)
1876     if test "$ac_cv_header_pthread_h"; then
1877       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1878     fi
1879     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1880       case "${canonical}" in
1881         *-hpux*) ;;
1882         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1883       esac
1884       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1885                [Define to 1 if you have GTK and pthread (-lpthread).])
1886     fi
1887   fi
1888 fi
1889
1890 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1891 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1892 dnl also not configured.
1893 HAVE_DBUS=no
1894 DBUS_OBJ=
1895 if test "${with_dbus}" = "yes"; then
1896    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1897    if test "$HAVE_DBUS" = yes; then
1898      LIBS="$LIBS $DBUS_LIBS"
1899      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1900      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1901      DBUS_OBJ=dbusbind.o
1902    fi
1903 fi
1904 AC_SUBST(DBUS_OBJ)
1905
1906 dnl GConf has been tested under GNU/Linux only.
1907 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1908 HAVE_GCONF=no
1909 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1910    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1911    if test "$HAVE_GCONF" = yes; then
1912       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1913    fi
1914 fi
1915
1916 dnl SELinux is available for GNU/Linux only.
1917 HAVE_LIBSELINUX=no
1918 LIBSELINUX_LIBS=
1919 if test "${with_selinux}" = "yes"; then
1920    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1921    if test "$HAVE_LIBSELINUX" = yes; then
1922       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1923       LIBSELINUX_LIBS=-lselinux
1924    fi
1925 fi
1926 AC_SUBST(LIBSELINUX_LIBS)
1927
1928 dnl Do not put whitespace before the #include statements below.
1929 dnl Older compilers (eg sunos4 cc) choke on it.
1930 HAVE_XAW3D=no
1931 LUCID_LIBW=
1932 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1933   if test "$with_xaw3d" != no; then
1934     AC_MSG_CHECKING(for xaw3d)
1935     AC_CACHE_VAL(emacs_cv_xaw3d,
1936     [AC_TRY_LINK([
1937 #include <X11/Intrinsic.h>
1938 #include <X11/Xaw3d/Simple.h>],
1939       [],
1940       emacs_cv_xaw3d=yes,
1941       emacs_cv_xaw3d=no)])
1942   else
1943     emacs_cv_xaw3d=no
1944   fi
1945   if test $emacs_cv_xaw3d = yes; then
1946     AC_MSG_RESULT([yes; using Lucid toolkit])
1947     USE_X_TOOLKIT=LUCID
1948     HAVE_XAW3D=yes
1949     LUCID_LIBW=-lXaw3d
1950     AC_DEFINE(HAVE_XAW3D, 1,
1951               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1952   else
1953     AC_MSG_RESULT(no)
1954     AC_MSG_CHECKING(for libXaw)
1955     AC_CACHE_VAL(emacs_cv_xaw,
1956     [AC_TRY_LINK([
1957 #include <X11/Intrinsic.h>
1958 #include <X11/Xaw/Simple.h>],
1959       [],
1960       emacs_cv_xaw=yes,
1961       emacs_cv_xaw=no)])
1962     if test $emacs_cv_xaw = yes; then
1963       AC_MSG_RESULT([yes; using Lucid toolkit])
1964       USE_X_TOOLKIT=LUCID
1965       LUCID_LIBW=-lXaw
1966     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1967       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1968     else
1969       AC_MSG_RESULT([no; do not use toolkit by default])
1970       USE_X_TOOLKIT=none
1971     fi
1972   fi
1973 fi
1974
1975 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1976
1977 LIBXTR6=
1978 if test "${USE_X_TOOLKIT}" != "none"; then
1979   AC_MSG_CHECKING(X11 toolkit version)
1980   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1981   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1982 [#if XtSpecificationRelease < 6
1983 fail;
1984 #endif
1985 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1986   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1987   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1988     AC_MSG_RESULT(6 or newer)
1989     AC_DEFINE(HAVE_X11XTR6, 1,
1990               [Define to 1 if you have the X11R6 or newer version of Xt.])
1991     LIBXTR6="-lSM -lICE"
1992     case "$opsys" in
1993       ## Use libw.a along with X11R6 Xt.
1994       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
1995     esac
1996   else
1997     AC_MSG_RESULT(before 6)
1998   fi
1999
2000 dnl If using toolkit, check whether libXmu.a exists.
2001 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2002   OLDLIBS="$LIBS"
2003   if test x$HAVE_X11XTR6 = xyes; then
2004     LIBS="-lXt -lSM -lICE $LIBS"
2005   else
2006     LIBS="-lXt $LIBS"
2007   fi
2008   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2009   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2010 fi
2011 AC_SUBST(LIBXTR6)
2012
2013 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2014 dnl Why not just test for libxmu in the normal way?
2015 LIBXMU=-lXmu
2016 case "$machine" in
2017   ## These machines don't supply Xmu.
2018   hpux* | aix4-2 )
2019     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2020     ;;
2021 esac
2022 AC_SUBST(LIBXMU)
2023
2024 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2025 if test "${HAVE_X11}" = "yes"; then
2026   if test "${USE_X_TOOLKIT}" != "none"; then
2027     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2028   fi
2029 fi
2030
2031 LIBXP=
2032 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2033   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2034   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2035     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2036 int x = 5;
2037 #else
2038 Motif version prior to 2.1.
2039 #endif],
2040     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2041   if test $emacs_cv_motif_version_2_1 = yes; then
2042     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2043   else
2044     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2045     # We put this in CFLAGS temporarily to precede other -I options
2046     # that might be in CFLAGS temporarily.
2047     # We put this in CPPFLAGS where it precedes the other -I options.
2048     OLD_CPPFLAGS=$CPPFLAGS
2049     OLD_CFLAGS=$CFLAGS
2050     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2051     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2052     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2053       [int x = 5;],
2054       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2055     if test $emacs_cv_lesstif = yes; then
2056       # Make sure this -I option remains in CPPFLAGS after it is set
2057       # back to REAL_CPPFLAGS.
2058       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2059       # have those other -I options anyway.  Ultimately, having this
2060       # directory ultimately in CPPFLAGS will be enough.
2061       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2062       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2063     else
2064       CFLAGS=$OLD_CFLAGS
2065       CPPFLAGS=$OLD_CPPFLAGS
2066     fi
2067   fi
2068 fi
2069
2070 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2071 dnl using Motif or Xaw3d is available, and unless
2072 dnl --with-toolkit-scroll-bars=no was specified.
2073
2074 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2075             [Define to 1 if we should use toolkit scroll bars.])dnl
2076 USE_TOOLKIT_SCROLL_BARS=no
2077 if test "${with_toolkit_scroll_bars}" != "no"; then
2078   if test "${USE_X_TOOLKIT}" != "none"; then
2079     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2080       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2081       HAVE_XAW3D=no
2082       USE_TOOLKIT_SCROLL_BARS=yes
2083     elif test "${HAVE_XAW3D}" = "yes"; then
2084       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2085       USE_TOOLKIT_SCROLL_BARS=yes
2086     fi
2087   elif test "${HAVE_GTK}" = "yes"; then
2088     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2089     USE_TOOLKIT_SCROLL_BARS=yes
2090   elif test "${HAVE_NS}" = "yes"; then
2091     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2092     USE_TOOLKIT_SCROLL_BARS=yes
2093   fi
2094 fi
2095
2096 dnl See if XIM is available.
2097 AC_TRY_COMPILE([
2098           #include <X11/Xlib.h>
2099           #include <X11/Xresource.h>],
2100          [XIMProc  callback;],
2101          [HAVE_XIM=yes
2102          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2103          HAVE_XIM=no)
2104
2105 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2106
2107 if test "${with_xim}" != "no"; then
2108   AC_DEFINE(USE_XIM, 1,
2109             [Define to 1 if we should use XIM, if it is available.])
2110 fi
2111
2112
2113 if test "${HAVE_XIM}" != "no"; then
2114   late_CFLAGS=$CFLAGS
2115   if test "$GCC" = yes; then
2116     CFLAGS="$CFLAGS --pedantic-errors"
2117   fi
2118   AC_TRY_COMPILE([
2119 #include <X11/Xlib.h>
2120 #include <X11/Xresource.h>],
2121 [Display *display;
2122 XrmDatabase db;
2123 char *res_name;
2124 char *res_class;
2125 XIMProc  callback;
2126 XPointer *client_data;
2127 #ifndef __GNUC__
2128 /* If we're not using GCC, it's probably not XFree86, and this is
2129    probably right, but we can't use something like --pedantic-errors.  */
2130 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2131                                            char*, XIMProc, XPointer*);
2132 #endif
2133 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2134    client_data);],
2135     [emacs_cv_arg6_star=yes])
2136   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2137          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2138 either XPointer or XPointer*.])dnl
2139   if test "$emacs_cv_arg6_star" = yes; then
2140     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2141   else
2142     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2143   fi
2144   CFLAGS=$late_CFLAGS
2145 fi
2146
2147 ### Start of font-backend (under any platform) section.
2148 # (nothing here yet -- this is a placeholder)
2149 ### End of font-backend (under any platform) section.
2150
2151 ### Start of font-backend (under X11) section.
2152 if test "${HAVE_X11}" = "yes"; then
2153    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2154
2155    ## Use -lXft if available, unless `--with-xft=no'.
2156    HAVE_XFT=maybe
2157     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2158       with_xft="no";
2159     fi
2160     if test "x${with_xft}" != "xno"; then
2161
2162       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2163       ## Because xftfont.c uses XRenderQueryExtension, we also
2164       ## need to link to -lXrender.
2165       HAVE_XRENDER=no
2166       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2167       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2168         OLD_CPPFLAGS="$CPPFLAGS"
2169         OLD_CFLAGS="$CFLAGS"
2170         OLD_LIBS="$LIBS"
2171         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2172         CFLAGS="$CFLAGS $XFT_CFLAGS"
2173         XFT_LIBS="-lXrender $XFT_LIBS"
2174         LIBS="$XFT_LIBS $LIBS"
2175         AC_CHECK_HEADER(X11/Xft/Xft.h,
2176           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2177
2178         if test "${HAVE_XFT}" = "yes"; then
2179           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2180             AC_SUBST(XFT_LIBS)
2181           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2182         else
2183           CPPFLAGS="$OLD_CPPFLAGS"
2184           CFLAGS="$OLD_CFLAGS"
2185           LIBS="$OLD_LIBS"
2186         fi                        # "${HAVE_XFT}" = "yes"
2187       fi                          # "$HAVE_XFT" != no
2188     fi                            # "x${with_xft}" != "xno"
2189
2190     dnl For the "Does Emacs use" message at the end.
2191     if test "$HAVE_XFT" != "yes"; then
2192        HAVE_XFT=no
2193     fi
2194
2195
2196     HAVE_FREETYPE=no
2197     ## We used to allow building with FreeType and without Xft.
2198     ## However, the ftx font backend driver is not in good shape.
2199     if test "${HAVE_XFT}" = "yes"; then
2200       dnl As we use Xft, we anyway use freetype.
2201       dnl There's no need for additional CFLAGS and LIBS.
2202       HAVE_FREETYPE=yes
2203       FONTCONFIG_CFLAGS=
2204       FONTCONFIG_LIBS=
2205     fi
2206
2207     HAVE_LIBOTF=no
2208     if test "${HAVE_FREETYPE}" = "yes"; then
2209       AC_DEFINE(HAVE_FREETYPE, 1,
2210                 [Define to 1 if using the freetype and fontconfig libraries.])
2211       if test "${with_libotf}" != "no"; then
2212         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2213                           HAVE_LIBOTF=no)
2214         if test "$HAVE_LIBOTF" = "yes"; then
2215           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2216           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2217                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2218                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2219           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2220             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2221                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2222           fi
2223         fi
2224       fi
2225     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2226     dnl Does the new font backend require it, or can it work without it?
2227     fi
2228
2229     HAVE_M17N_FLT=no
2230     if test "${HAVE_LIBOTF}" = yes; then
2231       if test "${with_m17n_flt}" != "no"; then
2232         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2233         if test "$HAVE_M17N_FLT" = "yes"; then
2234           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2235         fi
2236       fi
2237     fi
2238 else
2239     HAVE_XFT=no
2240     HAVE_FREETYPE=no
2241     HAVE_LIBOTF=no
2242     HAVE_M17N_FLT=no
2243 fi
2244
2245 FONT_OBJ=xfont.o
2246 if test "$HAVE_XFT" = "yes"; then
2247   FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
2248 elif test "$HAVE_FREETYPE" = "yes"; then
2249   FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
2250 fi
2251 AC_SUBST(FONT_OBJ)
2252
2253 ### End of font-backend (under X11) section.
2254
2255 AC_SUBST(FREETYPE_CFLAGS)
2256 AC_SUBST(FREETYPE_LIBS)
2257 AC_SUBST(FONTCONFIG_CFLAGS)
2258 AC_SUBST(FONTCONFIG_LIBS)
2259 AC_SUBST(LIBOTF_CFLAGS)
2260 AC_SUBST(LIBOTF_LIBS)
2261 AC_SUBST(M17N_FLT_CFLAGS)
2262 AC_SUBST(M17N_FLT_LIBS)
2263
2264 ### Use -lXpm if available, unless `--with-xpm=no'.
2265 HAVE_XPM=no
2266 LIBXPM=
2267 if test "${HAVE_X11}" = "yes"; then
2268   if test "${with_xpm}" != "no"; then
2269     AC_CHECK_HEADER(X11/xpm.h,
2270       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2271     if test "${HAVE_XPM}" = "yes"; then
2272       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2273       AC_EGREP_CPP(no_return_alloc_pixels,
2274       [#include "X11/xpm.h"
2275 #ifndef XpmReturnAllocPixels
2276 no_return_alloc_pixels
2277 #endif
2278       ], HAVE_XPM=no, HAVE_XPM=yes)
2279
2280       if test "${HAVE_XPM}" = "yes"; then
2281         AC_MSG_RESULT(yes)
2282       else
2283         AC_MSG_RESULT(no)
2284       fi
2285     fi
2286   fi
2287
2288   if test "${HAVE_XPM}" = "yes"; then
2289     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2290     LIBXPM=-lXpm
2291   fi
2292 fi
2293 AC_SUBST(LIBXPM)
2294
2295 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2296 HAVE_JPEG=no
2297 LIBJPEG=
2298 if test "${HAVE_X11}" = "yes"; then
2299   if test "${with_jpeg}" != "no"; then
2300     dnl Checking for jpeglib.h can lose because of a redefinition of
2301     dnl  HAVE_STDLIB_H.
2302     AC_CHECK_HEADER(jerror.h,
2303       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2304   fi
2305
2306   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2307   if test "${HAVE_JPEG}" = "yes"; then
2308     AC_DEFINE(HAVE_JPEG)
2309     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2310         [#include <jpeglib.h>
2311          version=JPEG_LIB_VERSION
2312 ],
2313         [AC_DEFINE(HAVE_JPEG)],
2314         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2315         HAVE_JPEG=no])
2316   fi
2317   if test "${HAVE_JPEG}" = "yes"; then
2318     LIBJPEG=-ljpeg
2319   fi
2320 fi
2321 AC_SUBST(LIBJPEG)
2322
2323 ### Use -lpng if available, unless `--with-png=no'.
2324 HAVE_PNG=no
2325 LIBPNG=
2326 if test "${HAVE_X11}" = "yes"; then
2327   if test "${with_png}" != "no"; then
2328     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2329     # in /usr/include/libpng.
2330     AC_CHECK_HEADERS(png.h libpng/png.h)
2331     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2332       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2333     fi
2334   fi
2335
2336   if test "${HAVE_PNG}" = "yes"; then
2337     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2338     LIBPNG="-lpng -lz -lm"
2339   fi
2340 fi
2341 AC_SUBST(LIBPNG)
2342
2343 ### Use -ltiff if available, unless `--with-tiff=no'.
2344 HAVE_TIFF=no
2345 LIBTIFF=
2346 if test "${HAVE_X11}" = "yes"; then
2347   if test "${with_tiff}" != "no"; then
2348     AC_CHECK_HEADER(tiffio.h,
2349       [tifflibs="-lz -lm"
2350       # At least one tiff package requires the jpeg library.
2351       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2352       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2353   fi
2354
2355   if test "${HAVE_TIFF}" = "yes"; then
2356     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2357     dnl FIXME -lz -lm, as per libpng?
2358     LIBTIFF=-ltiff
2359   fi
2360 fi
2361 AC_SUBST(LIBTIFF)
2362
2363 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2364 HAVE_GIF=no
2365 LIBGIF=
2366 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2367   AC_CHECK_HEADER(gif_lib.h,
2368 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2369 # Earlier versions can crash Emacs.
2370     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2371
2372   if test "$HAVE_GIF" = yes; then
2373     LIBGIF=-lgif
2374   elif test "$HAVE_GIF" = maybe; then
2375 # If gif_lib.h but no libgif, try libungif.
2376     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2377     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2378   fi
2379
2380   if test "${HAVE_GIF}" = "yes"; then
2381     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2382   fi
2383 fi
2384 AC_SUBST(LIBGIF)
2385
2386 dnl Check for required libraries.
2387 if test "${HAVE_X11}" = "yes"; then
2388   MISSING=""
2389   WITH_NO=""
2390   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2391     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2392   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2393     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2394   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2395     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2396   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2397     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2398   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2399     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2400
2401   if test "X${MISSING}" != X; then
2402     AC_MSG_ERROR([The following required libraries were not found:
2403     $MISSING
2404 Maybe some development libraries/packages are missing?
2405 If you don't want to link with them give
2406     $WITH_NO
2407 as options to configure])
2408   fi
2409 fi
2410
2411 ### Use -lgpm if available, unless `--with-gpm=no'.
2412 HAVE_GPM=no
2413 LIBGPM=
2414 GPM_MOUSE_SUPPORT=
2415 if test "${with_gpm}" != "no"; then
2416   AC_CHECK_HEADER(gpm.h,
2417     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2418
2419   if test "${HAVE_GPM}" = "yes"; then
2420     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2421     LIBGPM=-lgpm
2422     GPM_MOUSE_SUPPORT="\${lispsource}mouse.elc"
2423   fi
2424 fi
2425 AC_SUBST(LIBGPM)
2426 AC_SUBST(GPM_MOUSE_SUPPORT)
2427
2428 dnl Check for malloc/malloc.h on darwin
2429 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2430
2431 C_SWITCH_X_SYSTEM=
2432 ### Use NeXTstep API to implement GUI.
2433 if test "${HAVE_NS}" = "yes"; then
2434   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2435   if test "${NS_IMPL_COCOA}" = "yes"; then
2436     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2437     GNU_OBJC_CFLAGS=
2438   fi
2439   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2440     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2441     # See also .m.o rule in Makefile.in */
2442     # FIXME: are all these flags really needed?  Document here why.  */
2443     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2444     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2445   fi
2446   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2447     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2448   fi
2449   # We also have mouse menus.
2450   HAVE_MENUS=yes
2451   OTHER_FILES=ns-app
2452 fi
2453
2454
2455 ### Use session management (-lSM -lICE) if available
2456 HAVE_X_SM=no
2457 LIBXSM=
2458 if test "${HAVE_X11}" = "yes"; then
2459   AC_CHECK_HEADER(X11/SM/SMlib.h,
2460     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2461
2462   if test "${HAVE_X_SM}" = "yes"; then
2463     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2464     LIBXSM="-lSM -lICE"
2465     case "$LIBS" in
2466       *-lSM*) ;;
2467       *)      LIBS="$LIBXSM $LIBS" ;;
2468     esac
2469   fi
2470 fi
2471 AC_SUBST(LIBXSM)
2472
2473 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2474 AC_CACHE_CHECK(whether netdb declares h_errno,
2475                emacs_cv_netdb_declares_h_errno,
2476 [AC_TRY_LINK([#include <netdb.h>],
2477   [return h_errno;],
2478   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2479 if test $emacs_cv_netdb_declares_h_errno = yes; then
2480   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2481 fi
2482
2483 AC_FUNC_ALLOCA
2484
2485 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2486 dnl FIXME is there an autoconf test that does the right thing, without
2487 dnl needing to call A_M_E afterwards?
2488 if test x"$ac_cv_func_alloca_works" != xyes; then
2489    AC_MSG_ERROR( [a system implementation of alloca is required] )
2490 fi
2491
2492 # fmod, logb, and frexp are found in -lm on most systems.
2493 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2494 AC_CHECK_LIB(m, sqrt)
2495
2496 # Check for mail-locking functions in a "mail" library.  Probably this should
2497 # have the same check as for liblockfile below.
2498 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2499 if test $have_mail = yes; then
2500   LIBS_MAIL=-lmail
2501   LIBS="$LIBS_MAIL $LIBS"
2502   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2503 else
2504   LIBS_MAIL=
2505 fi
2506 dnl Debian, at least:
2507 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2508 if test $have_lockfile = yes; then
2509    LIBS_MAIL=-llockfile
2510    LIBS="$LIBS_MAIL $LIBS"
2511    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2512 else
2513 # If we have the shared liblockfile, assume we must use it for mail
2514 # locking (e.g. Debian).  If we couldn't link against liblockfile
2515 # (no liblockfile.a installed), ensure that we don't need to.
2516   dnl This works for files generally, not just executables.
2517   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2518   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2519                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2520   if test $ac_cv_prog_liblockfile = yes; then
2521     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2522 This probably means that movemail could lose mail.
2523 There may be a `development' package to install containing liblockfile.])
2524   fi
2525 fi
2526 AC_CHECK_FUNCS(touchlock)
2527 AC_CHECK_HEADERS(maillock.h)
2528 AC_SUBST(LIBS_MAIL)
2529
2530 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2531 ## interlock access to the mail spool.  The alternative is a lock file named
2532 ## /usr/spool/mail/$USER.lock.
2533 mail_lock=no
2534 case "$opsys" in
2535   aix4-2) mail_lock="lockf" ;;
2536
2537   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2538
2539   ## On GNU/Linux systems, both methods are used by various mail programs.
2540   ## I assume most people are using newer mailers that have heard of flock.
2541   ## Change this if you need to.
2542   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2543   ## configure gets the right answers, and that means *NOT* using flock.
2544   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2545   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2546   ## Debian maintainer hasn't provided a clean fix for Emacs.
2547   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2548   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2549   ## correct logic.  -- fx
2550   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2551   ## liblockfile is a Free Software replacement for libmail, used on
2552   ## Debian systems and elsewhere. -rfr.
2553   gnu-*)
2554     mail_lock="flock"
2555     if test $have_mail = yes || test $have_lockfile = yes; then
2556       test $ac_cv_header_maillock_h = yes && mail_lock=no
2557     fi
2558     ;;
2559 esac
2560
2561 BLESSMAIL_TARGET=
2562 case "$mail_lock" in
2563   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2564
2565   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2566
2567   *) BLESSMAIL_TARGET="need-blessmail" ;;
2568 esac
2569 AC_SUBST(BLESSMAIL_TARGET)
2570
2571
2572 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2573 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2574 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2575 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2576 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2577 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2578 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2579 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2580 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2581 cfmakeraw cfsetspeed isnan copysign)
2582
2583 AC_CHECK_HEADERS(sys/un.h)
2584
2585 AC_FUNC_MKTIME
2586 if test "$ac_cv_func_working_mktime" = no; then
2587   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2588 fi
2589
2590 AC_FUNC_GETLOADAVG
2591
2592 AC_FUNC_FSEEKO
2593
2594 # Configure getopt.
2595 m4_include([m4/getopt.m4])
2596 gl_GETOPT_IFELSE([
2597   gl_GETOPT_SUBSTITUTE_HEADER
2598   gl_PREREQ_GETOPT
2599   GETOPTOBJS='getopt.o getopt1.o'
2600 ])
2601 AC_SUBST(GETOPTOBJS)
2602
2603 AC_FUNC_GETPGRP
2604
2605 AC_FUNC_STRFTIME
2606
2607 # UNIX98 PTYs.
2608 AC_CHECK_FUNCS(grantpt)
2609
2610 # PTY-related GNU extensions.
2611 AC_CHECK_FUNCS(getpt)
2612
2613 # Check this now, so that we will NOT find the above functions in ncurses.
2614 # That is because we have not set up to link ncurses in lib-src.
2615 # It's better to believe a function is not available
2616 # than to expect to find it in ncurses.
2617 # Also we need tputs and friends to be able to build at all.
2618 have_tputs_et_al=true
2619 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2620 if test "$have_tputs_et_al" != true; then
2621   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2622 Maybe some development libraries/packages are missing?  Try installing
2623 libncurses-dev(el), libterminfo-dev(el) or similar.])
2624 fi
2625 # Must define this when any termcap library is found.
2626 AC_DEFINE(HAVE_LIBNCURSES, 1,
2627           [Define to 1 if you have the `ncurses' library (-lncurses).])
2628 ## FIXME This was the cpp logic, but I am not sure it is right.
2629 ## The above test has not necessarily found libncurses.
2630 HAVE_LIBNCURSES=yes
2631
2632 ## Use terminfo instead of termcap?
2633 ## Note only system files NOT using terminfo are:
2634 ## bsd-common, freebsd < 40000, ms-w32, msdos, netbsd, and
2635 ## darwin|gnu without ncurses.
2636 TERMINFO=no
2637 LIBS_TERMCAP=
2638 case "$opsys" in
2639   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2640   ## hpux10-20: Use the system provided termcap(3) library.
2641   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2642   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2643   aix4-2|cygwin|hpux*|irix6-5|openbsd|usg5-4|sol2*|unixware) TERMINFO=yes ;;
2644
2645   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2646   ##  The ncurses library has been moved out of the System framework in
2647   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2648   ##  option to use it.
2649   darwin|gnu*)
2650     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2651     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2652       TERMINFO=yes
2653       LIBS_TERMCAP="-lncurses"
2654     fi
2655     ;;
2656
2657   freebsd)
2658     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2659     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2660     [AC_TRY_LINK([#include <osreldate.h>],
2661 [#if __FreeBSD_version < 400000
2662 fail;
2663 #endif
2664 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2665
2666     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2667
2668     if test $emacs_cv_freebsd_terminfo = yes; then
2669       TERMINFO=yes
2670       LIBS_TERMCAP="-lncurses"
2671     else
2672       LIBS_TERMCAP="-ltermcap"
2673     fi
2674     ;;
2675
2676 esac
2677
2678 case "$opsys" in
2679   ## hpux: Make sure we get select from libc rather than from libcurses
2680   ##  because libcurses on HPUX 10.10 has a broken version of select.
2681   ##  We used to use -lc -lcurses, but this may be cleaner.
2682   hpux*|netbsd) LIBS_TERMCAP="-ltermcap" ;;
2683
2684   openbsd) LIBS_TERMCAP="-lncurses" ;;
2685
2686   ## Must use system termcap, if we use any termcap.  It does special things.
2687   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2688 esac
2689
2690 TERMCAP_OBJ=tparam.o
2691 if test $TERMINFO = yes; then
2692   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2693
2694   ## Default used to be -ltermcap.  Add a case above if need something else.
2695   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2696
2697   TERMCAP_OBJ=terminfo.o
2698 fi
2699 AC_SUBST(LIBS_TERMCAP)
2700 AC_SUBST(TERMCAP_OBJ)
2701
2702
2703 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2704 resolv=no
2705 AC_TRY_LINK([#include <netinet/in.h>
2706 #include <arpa/nameser.h>
2707 #include <resolv.h>],
2708     [return res_init();],
2709     have_res_init=yes, have_res_init=no)
2710 if test "$have_res_init" = no; then
2711   OLIBS="$LIBS"
2712   LIBS="$LIBS -lresolv"
2713   AC_MSG_CHECKING(for res_init with -lresolv)
2714   AC_TRY_LINK([#include <netinet/in.h>
2715 #include <arpa/nameser.h>
2716 #include <resolv.h>],
2717     [return res_init();],
2718     have_res_init=yes, have_res_init=no)
2719   AC_MSG_RESULT($have_res_init)
2720   if test "$have_res_init" = yes ; then
2721     resolv=yes
2722   fi
2723   LIBS="$OLIBS"
2724 fi
2725
2726 if test "$have_res_init" = yes; then
2727   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2728 fi
2729
2730 # Do we need the Hesiod library to provide the support routines?
2731 LIBHESIOD=
2732 if test "$with_hesiod" != no ; then
2733   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2734   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2735      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2736                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2737   if test "$resolv" = yes ; then
2738     RESOLVLIB=-lresolv
2739   else
2740     RESOLVLIB=
2741   fi
2742   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2743         hesiod=yes, :, $RESOLVLIB)])
2744
2745   if test x"$hesiod" = xyes; then
2746     AC_DEFINE(HAVE_LIBHESIOD, 1,
2747               [Define to 1 if you have the hesiod library (-lhesiod).])
2748     LIBHESIOD=-lhesiod
2749   fi
2750 fi
2751 AC_SUBST(LIBHESIOD)
2752
2753 # Do we need libresolv (due to res_init or Hesiod)?
2754 if test "$resolv" = yes ; then
2755   AC_DEFINE(HAVE_LIBRESOLV, 1,
2756             [Define to 1 if you have the resolv library (-lresolv).])
2757   LIBRESOLV=-lresolv
2758 else
2759   LIBRESOLV=
2760 fi
2761 AC_SUBST(LIBRESOLV)
2762
2763 # These tell us which Kerberos-related libraries to use.
2764 COM_ERRLIB=
2765 CRYPTOLIB=
2766 KRB5LIB=
2767 DESLIB=
2768 KRB4LIB=
2769
2770 if test "${with_kerberos}" != no; then
2771   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2772   if test $have_com_err = yes; then
2773     COM_ERRLIB=-lcom_err
2774     LIBS="$COM_ERRLIB $LIBS"
2775     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2776   fi
2777   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2778   if test $have_crypto = yes; then
2779     CRYPTOLIB=-lcrypto
2780     LIBS="$CRYPTOLIB $LIBS"
2781     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2782   fi
2783   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2784   if test $have_k5crypto = yes; then
2785     CRYPTOLIB=-lk5crypto
2786     LIBS="$CRYPTOLIB $LIBS"
2787     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2788   fi
2789   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2790   if test $have_krb5=yes; then
2791     KRB5LIB=-lkrb5
2792     LIBS="$KRB5LIB $LIBS"
2793     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2794   fi
2795   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2796   if test "${with_kerberos5}" = no; then
2797     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2798     if test $have_des425 = yes; then
2799       DESLIB=-ldes425
2800       LIBS="$DESLIB $LIBS"
2801       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2802     else
2803       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2804       if test $have_des = yes; then
2805         DESLIB=-ldes
2806         LIBS="$DESLIB $LIBS"
2807         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2808       fi
2809     fi
2810     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2811     if test $have_krb4 = yes; then
2812       KRB4LIB=-lkrb4
2813       LIBS="$KRB4LIB $LIBS"
2814       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2815     else
2816       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2817       if test $have_krb = yes; then
2818         KRB4LIB=-lkrb
2819         LIBS="$KRB4LIB $LIBS"
2820         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2821       fi
2822     fi
2823   fi
2824
2825   if test "${with_kerberos5}" != no; then
2826     AC_CHECK_HEADERS(krb5.h,
2827       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2828                         [#include <krb5.h>])])
2829   else
2830     AC_CHECK_HEADERS(des.h,,
2831                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2832                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2833     AC_CHECK_HEADERS(krb.h,,
2834                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2835                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2836   fi
2837   AC_CHECK_HEADERS(com_err.h)
2838 fi
2839
2840 AC_SUBST(COM_ERRLIB)
2841 AC_SUBST(CRYPTOLIB)
2842 AC_SUBST(KRB5LIB)
2843 AC_SUBST(DESLIB)
2844 AC_SUBST(KRB4LIB)
2845
2846 # Solaris requires -lintl if you want strerror (which calls dgettext)
2847 # to return localized messages.
2848 AC_CHECK_LIB(intl, dgettext)
2849
2850 AC_MSG_CHECKING(whether localtime caches TZ)
2851 AC_CACHE_VAL(emacs_cv_localtime_cache,
2852 [if test x$ac_cv_func_tzset = xyes; then
2853 AC_TRY_RUN([#include <time.h>
2854 extern char **environ;
2855 unset_TZ ()
2856 {
2857   char **from, **to;
2858   for (to = from = environ; (*to = *from); from++)
2859     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2860       to++;
2861 }
2862 char TZ_GMT0[] = "TZ=GMT0";
2863 char TZ_PST8[] = "TZ=PST8";
2864 main()
2865 {
2866   time_t now = time ((time_t *) 0);
2867   int hour_GMT0, hour_unset;
2868   if (putenv (TZ_GMT0) != 0)
2869     exit (1);
2870   hour_GMT0 = localtime (&now)->tm_hour;
2871   unset_TZ ();
2872   hour_unset = localtime (&now)->tm_hour;
2873   if (putenv (TZ_PST8) != 0)
2874     exit (1);
2875   if (localtime (&now)->tm_hour == hour_GMT0)
2876     exit (1);
2877   unset_TZ ();
2878   if (localtime (&now)->tm_hour != hour_unset)
2879     exit (1);
2880   exit (0);
2881 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2882 [# If we have tzset, assume the worst when cross-compiling.
2883 emacs_cv_localtime_cache=yes])
2884 else
2885         # If we lack tzset, report that localtime does not cache TZ,
2886         # since we can't invalidate the cache if we don't have tzset.
2887         emacs_cv_localtime_cache=no
2888 fi])dnl
2889 AC_MSG_RESULT($emacs_cv_localtime_cache)
2890 if test $emacs_cv_localtime_cache = yes; then
2891   AC_DEFINE(LOCALTIME_CACHE, 1,
2892             [Define to 1 if localtime caches TZ.])
2893 fi
2894
2895 if test "x$HAVE_TIMEVAL" = xyes; then
2896   AC_CHECK_FUNCS(gettimeofday)
2897   if test $ac_cv_func_gettimeofday = yes; then
2898     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2899                    emacs_cv_gettimeofday_two_arguments,
2900     [AC_TRY_COMPILE([
2901 #ifdef TIME_WITH_SYS_TIME
2902 #include <sys/time.h>
2903 #include <time.h>
2904 #else
2905 #ifdef HAVE_SYS_TIME_H
2906 #include <sys/time.h>
2907 #else
2908 #include <time.h>
2909 #endif
2910 #endif],
2911       [struct timeval time;
2912        gettimeofday (&time, 0);],
2913       emacs_cv_gettimeofday_two_arguments=yes,
2914       emacs_cv_gettimeofday_two_arguments=no)])
2915     if test $emacs_cv_gettimeofday_two_arguments = no; then
2916       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2917                 [Define to 1 if gettimeofday accepts only one argument.])
2918     fi
2919   fi
2920 fi
2921
2922 ok_so_far=yes
2923 AC_CHECK_FUNC(socket, , ok_so_far=no)
2924 if test $ok_so_far = yes; then
2925   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2926 fi
2927 if test $ok_so_far = yes; then
2928   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2929 fi
2930 if test $ok_so_far = yes; then
2931 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2932   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2933             [Define to 1 if you have inet sockets.])
2934 fi
2935
2936 AC_CHECK_HEADERS(sys/ioctl.h)
2937
2938 if test -f /usr/lpp/X11/bin/smt.exp; then
2939   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2940             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2941 fi
2942
2943 AC_MSG_CHECKING(whether system supports dynamic ptys)
2944 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2945   AC_MSG_RESULT(yes)
2946   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2947 else
2948   AC_MSG_RESULT(no)
2949 fi
2950
2951 AC_FUNC_FORK
2952
2953 dnl Adapted from Haible's version.
2954 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2955   [AC_TRY_LINK([#include <langinfo.h>],
2956     [char* cs = nl_langinfo(CODESET);],
2957     emacs_cv_langinfo_codeset=yes,
2958     emacs_cv_langinfo_codeset=no)
2959   ])
2960 if test $emacs_cv_langinfo_codeset = yes; then
2961   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2962     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2963 fi
2964
2965 AC_CHECK_TYPES(size_t)
2966
2967 AC_TYPE_MBSTATE_T
2968
2969 dnl Restrict could probably be used effectively other than in regex.c.
2970 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2971   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2972                   emacs_cv_c_restrict=yes,
2973                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2974                                   emacs_cv_c_restrict=__restrict,
2975                                   emacs_cv_c_restrict=no)])])
2976 case "$emacs_cv_c_restrict" in
2977   yes) emacs_restrict=restrict;;
2978   no) emacs_restrict="";;
2979   *) emacs_restrict="$emacs_cv_c_restrict";;
2980 esac
2981 if test "$emacs_restrict" != __restrict; then
2982   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2983     [Define to compiler's equivalent of C99 restrict keyword.
2984      Don't define if equivalent is `__restrict'.])
2985 fi
2986
2987 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2988   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2989                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2990 if test "$emacs_cv_c_restrict_arr" = yes; then
2991   AC_DEFINE(__restrict_arr, __restrict,
2992     [Define to compiler's equivalent of C99 restrict keyword in array
2993      declarations.  Define as empty for no equivalent.])
2994 fi
2995
2996 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2997 dnl how the tty code is related to POSIX and/or other versions of termios.
2998 dnl The following looks like a useful start.
2999 dnl
3000 dnl AC_SYS_POSIX_TERMIOS
3001 dnl if test $ac_cv_sys_posix_termios = yes; then
3002 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3003 dnl                                and macros for terminal control.])
3004 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3005 dnl fi
3006
3007 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3008
3009 # Set up the CFLAGS for real compilation, so we can substitute it.
3010 CFLAGS="$REAL_CFLAGS"
3011 CPPFLAGS="$REAL_CPPFLAGS"
3012
3013 ## Hack to detect a buggy GCC version.
3014 if test "x$GCC" = xyes \
3015    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3016    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3017    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3018    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3019 fi
3020
3021 #### Find out which version of Emacs this is.
3022 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
3023          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3024 if test x"${version}" = x; then
3025   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
3026 fi
3027 if test x"${version}" != x"$PACKAGE_VERSION"; then
3028   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/lisp/version.el'.])
3029 fi
3030
3031 ### Specify what sort of things we'll be editing into Makefile and config.h.
3032 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3033 AC_SUBST(version)
3034 AC_SUBST(configuration)
3035 AC_SUBST(canonical)
3036 AC_SUBST(srcdir)
3037 AC_SUBST(prefix)
3038 AC_SUBST(exec_prefix)
3039 AC_SUBST(bindir)
3040 AC_SUBST(datadir)
3041 AC_SUBST(sharedstatedir)
3042 AC_SUBST(libexecdir)
3043 AC_SUBST(mandir)
3044 AC_SUBST(infodir)
3045 AC_SUBST(lispdir)
3046 AC_SUBST(locallisppath)
3047 AC_SUBST(lisppath)
3048 AC_SUBST(x_default_search_path)
3049 AC_SUBST(etcdir)
3050 AC_SUBST(archlibdir)
3051 AC_SUBST(docdir)
3052 AC_SUBST(bitmapdir)
3053 AC_SUBST(gamedir)
3054 AC_SUBST(gameuser)
3055 AC_SUBST(unexec)
3056 AC_SUBST(LD_SWITCH_X_SITE)
3057 AC_SUBST(C_SWITCH_X_SITE)
3058 AC_SUBST(C_SWITCH_X_SYSTEM)
3059 AC_SUBST(CFLAGS)
3060 ## Used in lwlib/Makefile.in.
3061 AC_SUBST(X_TOOLKIT_TYPE)
3062 AC_SUBST(machfile)
3063 AC_SUBST(opsysfile)
3064 AC_SUBST(GETLOADAVG_LIBS)
3065 AC_SUBST(ns_appdir)
3066 AC_SUBST(ns_appbindir)
3067 AC_SUBST(ns_appresdir)
3068 AC_SUBST(ns_appsrc)
3069 AC_SUBST(GNUSTEP_MAKEFILES)
3070 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
3071 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
3072 AC_SUBST(GNU_OBJC_CFLAGS)
3073 AC_SUBST(OTHER_FILES)
3074
3075 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3076                    [Define to the canonical Emacs configuration name.])
3077 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3078                    [Define to the options passed to configure.])
3079 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3080                    [Define to the used machine dependent file.])
3081 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3082                    [Define to the used os dependent file.])
3083 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
3084 [Define LD_SWITCH_X_SITE to contain any special flags your loader
3085  may need to deal with X Windows.  For instance, if you've defined
3086  HAVE_X_WINDOWS above and your X libraries aren't in a place that
3087  your loader can find on its own, you might want to add "-L/..." or
3088  something similar.])
3089 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
3090 [Define C_SWITCH_X_SITE to contain any special flags your compiler
3091  may need to deal with X Windows.  For instance, if you've defined
3092  HAVE_X_WINDOWS above and your X include files aren't in a place
3093  that your compiler can find on its own, you might want to add
3094  "-I/..." or something similar.])
3095
3096 XMENU_OBJ=
3097 XOBJ=
3098 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3099   AC_DEFINE(HAVE_X_WINDOWS, 1,
3100             [Define to 1 if you want to use the X window system.])
3101   XMENU_OBJ=xmenu.o
3102   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3103 fi
3104 AC_SUBST(XMENU_OBJ)
3105 AC_SUBST(XOBJ)
3106
3107 WIDGET_OBJ=
3108 MOTIF_LIBW=
3109 if test "${USE_X_TOOLKIT}" != "none" ; then
3110   WIDGET_OBJ=widget.o
3111   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3112   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3113     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3114   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3115     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3116     MOTIF_LIBW=-lXm
3117     case "$opsys" in
3118       gnu-linux)
3119         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3120         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3121         ;;
3122
3123       unixware)
3124         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3125         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3126         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3127         ;;
3128
3129       aix4-2)
3130         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3131         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3132         ;;
3133     esac
3134     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3135   fi
3136 fi
3137 AC_SUBST(WIDGET_OBJ)
3138
3139 TOOLKIT_LIBW=
3140 case "$USE_X_TOOLKIT" in
3141   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3142   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3143   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3144 esac
3145 AC_SUBST(TOOLKIT_LIBW)
3146
3147 if test "$USE_X_TOOLKIT" = "none"; then
3148   LIBXT_OTHER="\$(LIBXSM)"
3149 else
3150   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3151 fi
3152 AC_SUBST(LIBXT_OTHER)
3153
3154 ## The X Menu stuff is present in the X10 distribution, but missing
3155 ## from X11.  If we have X10, just use the installed library;
3156 ## otherwise, use our own copy.
3157 if test "${HAVE_X11}" = "yes" ; then
3158   AC_DEFINE(HAVE_X11, 1,
3159             [Define to 1 if you want to use version 11 of X windows.
3160              Otherwise, Emacs expects to use version 10.])
3161
3162   if test "$USE_X_TOOLKIT" = "none"; then
3163     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3164   else
3165     OLDXMENU="\${lwlibdir}liblw.a"
3166   fi
3167   LIBXMENU="\$(OLDXMENU)"
3168   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3169 else
3170   OLDXMENU=
3171   LIBXMENU="-lXMenu"
3172   LIBX_OTHER=
3173 fi
3174
3175 if test "$HAVE_GTK" = "yes"; then
3176   OLDXMENU=
3177   LIBXMENU=
3178 fi
3179
3180 AC_SUBST(OLDXMENU)
3181 AC_SUBST(LIBXMENU)
3182 AC_SUBST(LIBX_OTHER)
3183
3184 if test "${HAVE_MENUS}" = "yes" ; then
3185   AC_DEFINE(HAVE_MENUS, 1,
3186             [Define to 1 if you have mouse menus.
3187              (This is automatic if you use X, but the option to specify it remains.)
3188              It is also defined with other window systems that support xmenu.c.])
3189 fi
3190 if test "${GNU_MALLOC}" = "yes" ; then
3191   AC_DEFINE(GNU_MALLOC, 1,
3192             [Define to 1 if you want to use the GNU memory allocator.])
3193 fi
3194 if test "${REL_ALLOC}" = "yes" ; then
3195   AC_DEFINE(REL_ALLOC, 1,
3196             [Define REL_ALLOC if you want to use the relocating allocator for
3197              buffer space.])
3198 fi
3199
3200
3201 if test "$opsys" = "cygwin"; then
3202   CYGWIN_OBJ="sheap.o"
3203   ## Cygwin differs because of its unexec().
3204   PRE_ALLOC_OBJ=
3205   POST_ALLOC_OBJ="lastfile.o vm-limit.o"
3206 else
3207   CYGWIN_OBJ=
3208   PRE_ALLOC_OBJ=lastfile.o
3209   POST_ALLOC_OBJ="\$(vmlimitobj)"
3210 fi
3211 AC_SUBST(CYGWIN_OBJ)
3212 AC_SUBST(PRE_ALLOC_OBJ)
3213 AC_SUBST(POST_ALLOC_OBJ)
3214
3215
3216 case "$opsys" in
3217   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3218
3219   darwin)
3220   ## The -headerpad option tells ld (see man page) to leave room at the
3221   ## end of the header for adding load commands.  Needed for dumping.
3222   ## 0x690 is the total size of 30 segment load commands (at 56
3223   ## each); under Cocoa 31 commands are required.
3224   if test "$HAVE_NS" = "yes"; then
3225     libs_nsgui="-framework AppKit"
3226     headerpad_extra=6C8
3227   else
3228     libs_nsgui=
3229     headerpad_extra=690
3230   fi
3231   LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3232   ;;
3233
3234   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3235 esac
3236 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3237
3238
3239 ## This exists because src/Makefile.in did some extra fiddling around
3240 ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3241 ##   #ifndef LD_SWITCH_SYSTEM
3242 ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3243 ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3244 ## not using gcc, darwin system not on an alpha (ie darwin, since
3245 ## darwin + alpha does not occur).
3246 ## Note that unlike L_S_S, this is not used in ac_link.
3247 if test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3248    test "$opsys" = "darwin"; then
3249   LD_SWITCH_SYSTEM_EXTRA="-X"
3250 else
3251   LD_SWITCH_SYSTEM_EXTRA=
3252 fi
3253 AC_SUBST(LD_SWITCH_SYSTEM_EXTRA)
3254
3255
3256 LIB_GCC=
3257 if test "x$GCC" = "xyes"; then
3258
3259   case "$opsys" in
3260     ## cygwin: don't link against static libgcc.
3261     cygwin|freebsd|netbsd|openbsd) LIB_GCC= ;;
3262
3263     gnu-*)
3264       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3265       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3266       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3267       if test "$machine" = "arm"; then
3268         LIB_GCC="-lgcc_s"
3269       else
3270         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3271         ## immediately undefine it again and redefine it to empty.
3272         ## Was the C_SWITCH_X_SITE part really necessary?
3273 ##      LIB_GCC=`$(CC) $(C_SWITCH_X_SITE) -print-libgcc-file-name`
3274         LIB_GCC=
3275       fi
3276       ;;
3277
3278     ## Ask GCC where to find libgcc.a.
3279     *) LIB_GCC=`$(CC) -print-libgcc-file-name 2> /dev/null` ;;
3280   esac
3281 fi                              dnl if $GCC
3282 AC_SUBST(LIB_GCC)
3283
3284
3285 AH_TOP([/* GNU Emacs site configuration template file.
3286    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3287      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3288
3289 This file is part of GNU Emacs.
3290
3291 GNU Emacs is free software: you can redistribute it and/or modify
3292 it under the terms of the GNU General Public License as published by
3293 the Free Software Foundation, either version 3 of the License, or
3294 (at your option) any later version.
3295
3296 GNU Emacs is distributed in the hope that it will be useful,
3297 but WITHOUT ANY WARRANTY; without even the implied warranty of
3298 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3299 GNU General Public License for more details.
3300
3301 You should have received a copy of the GNU General Public License
3302 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3303
3304
3305 /* No code in Emacs #includes config.h twice, but some bits of code
3306    intended to work with other packages as well (like gmalloc.c)
3307    think they can include it as many times as they like.  */
3308 #ifndef EMACS_CONFIG_H
3309 #define EMACS_CONFIG_H
3310 ])dnl
3311
3312 AH_BOTTOM([
3313 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
3314 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
3315 #define HAVE_WINDOW_SYSTEM
3316 #define HAVE_MOUSE
3317 #endif
3318
3319 /* Define AMPERSAND_FULL_NAME if you use the convention
3320    that & in the full name stands for the login id.  */
3321 /* Turned on June 1996 supposing nobody will mind it.  */
3322 #define AMPERSAND_FULL_NAME
3323
3324 /* Define HAVE_SOUND if we have sound support.  We know it works
3325    and compiles only on the specified platforms.   For others,
3326    it probably doesn't make sense to try.  */
3327
3328 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
3329 #ifdef HAVE_MACHINE_SOUNDCARD_H
3330 #define HAVE_SOUND 1
3331 #endif
3332 #ifdef HAVE_SYS_SOUNDCARD_H
3333 #define HAVE_SOUND 1
3334 #endif
3335 #ifdef HAVE_SOUNDCARD_H
3336 #define HAVE_SOUND 1
3337 #endif
3338 #ifdef HAVE_ALSA
3339 #define HAVE_SOUND 1
3340 #endif
3341 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
3342
3343 /* If using GNU, then support inline function declarations. */
3344 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3345    generally, because even if non-gcc compilers accept `inline', they
3346    may reject `extern inline'.  */
3347 #if defined (__GNUC__) && defined (OPTIMIZE)
3348 #define INLINE __inline__
3349 #else
3350 #define INLINE
3351 #endif
3352
3353 /* `subprocesses' should be defined if you want to
3354    have code for asynchronous subprocesses
3355    (as used in M-x compile and M-x shell).
3356    Only MSDOS does not support this (it overrides
3357    this in its config_opsysfile below).  */
3358
3359 #define subprocesses
3360
3361 /* Include the os and machine dependent files.  */
3362 #include config_opsysfile
3363 #include config_machfile
3364
3365 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3366   (There is probably a better place to do this, but right now the Cocoa
3367    side does this in s/darwin.h and we cannot
3368    parallel this exactly since GNUstep is multi-OS. */
3369 #ifdef HAVE_NS
3370 # ifdef NS_IMPL_GNUSTEP
3371 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3372 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3373 #  define SYSTEM_PURESIZE_EXTRA 30000
3374 # endif /* NS_IMPL_GNUSTEP */
3375 #endif /* HAVE_NS */
3376
3377 /* SIGTYPE is the macro we actually use.  */
3378 #ifndef SIGTYPE
3379 #define SIGTYPE RETSIGTYPE
3380 #endif
3381
3382 #ifdef emacs /* Don't do this for lib-src.  */
3383 /* Tell regex.c to use a type compatible with Emacs.  */
3384 #define RE_TRANSLATE_TYPE Lisp_Object
3385 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3386 #ifdef make_number
3387 /* If make_number is a macro, use it.  */
3388 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3389 #else
3390 /* If make_number is a function, avoid it.  */
3391 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3392 #endif
3393 #endif
3394
3395 /* Avoid link-time collision with system mktime if we will use our own.  */
3396 #if ! HAVE_MKTIME || BROKEN_MKTIME
3397 #define mktime emacs_mktime
3398 #endif
3399
3400 #define my_strftime nstrftime   /* for strftime.c */
3401
3402 /* The rest of the code currently tests the CPP symbol BSTRING.
3403    Override any claims made by the system-description files.
3404    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
3405 #undef BSTRING
3406 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
3407 #define BSTRING
3408 #endif
3409
3410 /* Some of the files of Emacs which are intended for use with other
3411    programs assume that if you have a config.h file, you must declare
3412    the type of getenv.
3413
3414    This declaration shouldn't appear when alloca.s or Makefile.in
3415    includes config.h.  */
3416 #ifndef NOT_C_CODE
3417 extern char *getenv ();
3418 #endif
3419
3420 /* These default definitions are good for almost all machines.
3421    The exceptions override them in m/MACHINE.h.  */
3422
3423 #ifndef BITS_PER_CHAR
3424 #define BITS_PER_CHAR 8
3425 #endif
3426
3427 #ifndef BITS_PER_SHORT
3428 #define BITS_PER_SHORT 16
3429 #endif
3430
3431 /* Note that lisp.h uses this in a preprocessor conditional, so it
3432    would not work to use sizeof.  That being so, we do all of them
3433    without sizeof, for uniformity's sake.  */
3434 #ifndef BITS_PER_INT
3435 #define BITS_PER_INT 32
3436 #endif
3437
3438 #ifndef BITS_PER_LONG
3439 #ifdef _LP64
3440 #define BITS_PER_LONG 64
3441 #else
3442 #define BITS_PER_LONG 32
3443 #endif
3444 #endif
3445
3446 /* Define if the compiler supports function prototypes.  It may do so
3447    but not define __STDC__ (e.g. DEC C by default) or may define it as
3448    zero.  */
3449 #undef PROTOTYPES
3450 /* For mktime.c:  */
3451 #ifndef __P
3452 # if defined PROTOTYPES
3453 #  define __P(args) args
3454 # else
3455 #  define __P(args) ()
3456 # endif  /* GCC.  */
3457 #endif /* __P */
3458
3459 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
3460 #ifndef NOT_C_CODE
3461 #ifdef HAVE_STRING_H
3462 #include "string.h"
3463 #endif
3464 #ifdef HAVE_STRINGS_H
3465 #include "strings.h"  /* May be needed for bcopy & al. */
3466 #endif
3467 #ifdef HAVE_STDLIB_H
3468 #include <stdlib.h>
3469 #endif
3470 #ifndef __GNUC__
3471 # ifdef HAVE_ALLOCA_H
3472 #  include <alloca.h>
3473 # else /* AIX files deal with #pragma.  */
3474 #  ifndef alloca /* predefined by HP cc +Olibcalls */
3475 char *alloca ();
3476 #  endif
3477 # endif /* HAVE_ALLOCA_H */
3478 #endif /* __GNUC__ */
3479 #ifndef HAVE_SIZE_T
3480 typedef unsigned size_t;
3481 #endif
3482 #endif /* NOT_C_CODE */
3483
3484 /* Define HAVE_X_I18N if we have usable i18n support.  */
3485
3486 #ifdef HAVE_X11R6
3487 #define HAVE_X_I18N
3488 #elif !defined X11R5_INHIBIT_I18N
3489 #define HAVE_X_I18N
3490 #endif
3491
3492 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3493
3494 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3495 #define HAVE_X11R6_XIM
3496 #endif
3497
3498 #if defined __GNUC__ && (__GNUC__ > 2 \
3499                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3500 #define NO_RETURN       __attribute__ ((__noreturn__))
3501 #else
3502 #define NO_RETURN       /* nothing */
3503 #endif
3504
3505 /* These won't be used automatically yet.  We also need to know, at least,
3506    that the stack is continuous.  */
3507 #ifdef __GNUC__
3508 #  ifndef GC_SETJMP_WORKS
3509   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3510      see NON_SAVING_SETJMP in the target descriptions.  */
3511   /* Exceptions (see NON_SAVING_SETJMP in target description) are
3512      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3513      Fixme: Deal with SVR3.  */
3514 #    define GC_SETJMP_WORKS 1
3515 #  endif
3516 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3517 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3518 #  endif
3519 #endif
3520
3521 #ifndef HAVE_BCOPY
3522 #define bcopy(a,b,s) memcpy (b,a,s)
3523 #endif
3524 #ifndef HAVE_BZERO
3525 #define bzero(a,s) memset (a,0,s)
3526 #endif
3527 #ifndef HAVE_BCMP
3528 #define BCMP memcmp
3529 #endif
3530
3531 #endif /* EMACS_CONFIG_H */
3532
3533 /*
3534 Local Variables:
3535 mode: c
3536 End:
3537 */
3538 ])dnl
3539
3540 #### Report on what we decided to do.
3541 #### Report GTK as a toolkit, even if it doesn't use Xt.
3542 #### It makes printing result more understandable as using GTK sets
3543 #### toolkit_scroll_bars to yes by default.
3544 if test "${HAVE_GTK}" = "yes"; then
3545   USE_X_TOOLKIT=GTK
3546 fi
3547
3548 echo "
3549 Configured for \`${canonical}'.
3550
3551   Where should the build process find the source code?    ${srcdir}
3552   What operating system and machine description files should Emacs use?
3553         \`${opsysfile}' and \`${machfile}'
3554   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3555   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3556   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3557   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3558   What window system should Emacs use?                    ${window_system}
3559   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3560
3561 if test -n "${x_includes}"; then
3562 echo "  Where do we find X Windows header files?                ${x_includes}"
3563 else
3564 echo "  Where do we find X Windows header files?                Standard dirs"
3565 fi
3566 if test -n "${x_libraries}"; then
3567 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3568 else
3569 echo "  Where do we find X Windows libraries?                   Standard dirs"
3570 fi
3571
3572 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3573 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3574 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3575 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3576 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3577 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3578 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3579 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3580 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3581 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3582 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3583 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3584
3585 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3586 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3587 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3588 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3589
3590 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3591 echo
3592
3593 if test $USE_XASSERTS = yes; then
3594    echo "  Compiling with asserts turned on."
3595    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3596 fi
3597
3598 echo
3599
3600 if test "$HAVE_NS" = "yes"; then
3601    echo
3602    echo "You must run \"make install\" in order to test the built application.
3603 The installed application will go to nextstep/Emacs.app and can be
3604 run or moved from there."
3605    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3606       echo "The application will be fully self-contained."
3607     else
3608       echo "The lisp resources for the application will be installed under ${prefix}.
3609 You may need to run \"make install\" with sudo.  The application will fail
3610 to run if these resources are not installed."
3611    fi
3612    echo
3613 fi
3614
3615 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3616   echo "D-Bus integration has been tested for GNU/Linux only."
3617   echo
3618 fi
3619
3620
3621 # Remove any trailing slashes in these variables.
3622 [test "${prefix}" != NONE &&
3623   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3624 test "${exec_prefix}" != NONE &&
3625   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3626
3627 # Now get this: Some word that is part of the ${srcdir} directory name
3628 # or the ${configuration} value might, just might, happen to be an
3629 # identifier like `sun4' or `i386' or something, and be predefined by
3630 # the C preprocessor to some helpful value like 1, or maybe the empty
3631 # string.  Needless to say consequent macro substitutions are less
3632 # than conducive to the makefile finding the correct directory.
3633 [cpp_undefs="`echo $srcdir $configuration $canonical unix |
3634   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3635   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3636
3637 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3638 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3639 ## from Makefile.c can correctly provide the arg `-traditional' to the
3640 ## C preprocessor.
3641
3642 AC_EGREP_CPP(yes..yes,
3643         [yes..yes],
3644         CPP_NEED_TRADITIONAL=no,
3645         CPP_NEED_TRADITIONAL=yes)
3646
3647 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3648         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3649         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3650         lwlib/Makefile lisp/Makefile leim/Makefile, [
3651
3652 ### Make the necessary directories, if they don't exist.
3653 for dir in etc lisp ; do
3654   test -d ${dir} || mkdir ${dir}
3655 done
3656
3657 # Build src/Makefile from ${srcdir}/src/Makefile.c
3658 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3659 # This must be done after src/config.h is built, since we rely on that file.
3660
3661 echo creating src/epaths.h
3662 ${MAKE-make} epaths-force
3663
3664 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3665 # `..' to `. .'  unless invoked with -traditional
3666
3667 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3668   CPPFLAGS="$CPPFLAGS -traditional"
3669 fi
3670
3671 echo creating src/Makefile
3672 ( cd src
3673   rm -f junk.c junk1.c junk2.c
3674   sed -e '/start of cpp stuff/q' \
3675       < Makefile.c > junk1.c
3676   sed -e '1,/start of cpp stuff/d'\
3677       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3678       < Makefile.c > junk.c
3679   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3680       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3681   cat junk1.c junk2.c > Makefile.new
3682   rm -f junk.c junk1.c junk2.c
3683   chmod 444 Makefile.new
3684   mv -f Makefile.new Makefile
3685 )
3686
3687 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3688   echo creating src/.gdbinit
3689   echo source $srcdir/src/.gdbinit > src/.gdbinit
3690 fi
3691
3692 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3693
3694 m4_if(dnl       Do not change this comment
3695    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3696 )dnl