lisp/ibuf-ext.el

   1 ;;; ibuf-ext.el --- extensions for ibuffer  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2000-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Colin Walters <walters@verbum.org>
   6 ;; Maintainer: John Paul Wallington <jpw@gnu.org>
   7 ;; Created: 2 Dec 2001
   8 ;; Keywords: buffer, convenience
   9 ;; Package: ibuffer
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; These functions should be automatically loaded when called, but you
  29 ;; can explicitly (require 'ibuf-ext) in your ~/.emacs to have them
  30 ;; preloaded.
  31
  32 ;;; Code:
  33
  34 (require 'ibuffer)
  35
  36 (eval-when-compile
  37   (require 'ibuf-macs)
  38   (require 'cl-lib))
  39
  40 ;;; Utility functions
  41 (defun ibuffer-delete-alist (key alist)
  42   "Delete all entries in ALIST that have a key equal to KEY."
  43   (let (entry)
  44     (while (setq entry (assoc key alist))
  45       (setq alist (delete entry alist)))
  46     alist))
  47
  48 ;; borrowed from Gnus
  49 (defun ibuffer-remove-duplicates (list)
  50   "Return a copy of LIST with duplicate elements removed."
  51   (let ((new nil)
  52         (tail list))
  53     (while tail
  54       (or (member (car tail) new)
  55           (setq new (cons (car tail) new)))
  56       (setq tail (cdr tail)))
  57     (nreverse new)))
  58
  59 (defun ibuffer-split-list (ibuffer-split-list-fn ibuffer-split-list-elts)
  60   (let ((hip-crowd nil)
  61         (lamers nil))
  62     (dolist (ibuffer-split-list-elt ibuffer-split-list-elts)
  63       (if (funcall ibuffer-split-list-fn ibuffer-split-list-elt)
  64           (push ibuffer-split-list-elt hip-crowd)
  65         (push ibuffer-split-list-elt lamers)))
  66     ;; Too bad Emacs Lisp doesn't have multiple values.
  67     (list (nreverse hip-crowd) (nreverse lamers))))
  68
  69 (defcustom ibuffer-never-show-predicates nil
  70   "A list of predicates (a regexp or function) for buffers not to display.
  71 If a regexp, then it will be matched against the buffer's name.
  72 If a function, it will be called with the buffer as an argument, and
  73 should return non-nil if this buffer should not be shown."
  74   :type '(repeat (choice regexp function))
  75   :require 'ibuf-ext
  76   :group 'ibuffer)
  77
  78 (defcustom ibuffer-always-show-predicates nil
  79   "A list of predicates (a regexp or function) for buffers to always display.
  80 If a regexp, then it will be matched against the buffer's name.
  81 If a function, it will be called with the buffer as an argument, and
  82 should return non-nil if this buffer should be shown.
  83 Note that buffers matching one of these predicates will be shown
  84 regardless of any active filters in this buffer."
  85   :type '(repeat (choice regexp function))
  86   :group 'ibuffer)
  87
  88 (defcustom ibuffer-never-search-content-name
  89   (let* ((names    '("Completions" "Help" "Messages" "Pp Eval Output"
  90                      "CompileLog" "Info" "Buffer List" "Ibuffer" "Apropos"))
  91          (partial  '("Customize Option: " "Async Shell Command\\*"
  92                      "Shell Command Output\\*" "ediff "))
  93          (beg      "\\`\\*")
  94          (end      "\\*\\'")
  95          (excluded (mapcar (lambda (x)
  96                              (format "%s%s" beg x)) partial)))
  97     (dolist (str names (nreverse excluded))
  98       (push (format "%s%s%s" beg str end) excluded)))
  99   "A list of regexps for buffers ignored by `ibuffer-mark-by-content-regexp'.
 100 Buffers whose name matches a regexp in this list, are not searched."
 101   :version "25.2"
 102   :type '(repeat regexp)
 103   :require 'ibuf-ext
 104   :group 'ibuffer)
 105
 106 (defcustom ibuffer-never-search-content-mode '(dired-mode)
 107   "A list of major modes ignored by `ibuffer-mark-by-content-regexp'.
 108 Buffers whose major mode is in this list, are not searched."
 109   :version "25.2"
 110   :type '(repeat regexp)
 111   :require 'ibuf-ext
 112   :group 'ibuffer)
 113
 114 (defvar ibuffer-tmp-hide-regexps nil
 115   "A list of regexps which should match buffer names to not show.")
 116
 117 (defvar ibuffer-tmp-show-regexps nil
 118   "A list of regexps which should match buffer names to always show.")
 119
 120 (defvar ibuffer-auto-buffers-changed nil)
 121
 122 (defcustom ibuffer-saved-filters '(("gnus"
 123                                     ((or (mode . message-mode)
 124                                          (mode . mail-mode)
 125                                          (mode . gnus-group-mode)
 126                                          (mode . gnus-summary-mode)
 127                                          (mode . gnus-article-mode))))
 128                                    ("programming"
 129                                     ((or (mode . emacs-lisp-mode)
 130                                          (mode . cperl-mode)
 131                                          (mode . c-mode)
 132                                          (mode . java-mode)
 133                                          (mode . idl-mode)
 134                                          (mode . lisp-mode)))))
 135
 136   "An alist of filter qualifiers to switch between.
 137
 138 This variable should look like ((\"STRING\" QUALIFIERS)
 139                                 (\"STRING\" QUALIFIERS) ...), where
 140 QUALIFIERS is a list of the same form as
 141 `ibuffer-filtering-qualifiers'.
 142 See also the variables `ibuffer-filtering-qualifiers',
 143 `ibuffer-filtering-alist', and the functions
 144 `ibuffer-switch-to-saved-filters', `ibuffer-save-filters'."
 145   :type '(repeat sexp)
 146   :group 'ibuffer)
 147
 148 (defvar ibuffer-filtering-qualifiers nil
 149   "A list like (SYMBOL . QUALIFIER) which filters the current buffer list.
 150 See also `ibuffer-filtering-alist'.")
 151
 152 ;; This is now frobbed by `define-ibuffer-filter'.
 153 (defvar ibuffer-filtering-alist nil
 154   "An alist of (SYMBOL DESCRIPTION FUNCTION) which describes a filter.
 155
 156 You most likely do not want to modify this variable directly; see
 157 `define-ibuffer-filter'.
 158
 159 SYMBOL is the symbolic name of the filter.  DESCRIPTION is used when
 160 displaying information to the user.  FUNCTION is given a buffer and
 161 the value of the qualifier, and returns non-nil if and only if the
 162 buffer should be displayed.")
 163
 164 (defcustom ibuffer-filter-format-alist nil
 165   "An alist which has special formats used when a filter is active.
 166 The contents of this variable should look like:
 167  ((FILTER (FORMAT FORMAT ...)) (FILTER (FORMAT FORMAT ...)) ...)
 168
 169 For example, suppose that when you add a filter for buffers whose
 170 major mode is `emacs-lisp-mode', you only want to see the mark and the
 171 name of the buffer.  You could accomplish that by adding:
 172  (mode ((mark \" \" name)))
 173 to this variable."
 174   :type '(repeat (list :tag "Association" (symbol :tag "Filter")
 175                        (list :tag "Formats" (repeat (sexp :tag "Format")))))
 176   :group 'ibuffer)
 177
 178 (defvar ibuffer-cached-filter-formats nil)
 179 (defvar ibuffer-compiled-filter-formats nil)
 180
 181 (defvar ibuffer-filter-groups nil
 182   "A list like ((\"NAME\" ((SYMBOL . QUALIFIER) ...) ...) which groups buffers.
 183 The SYMBOL should be one from `ibuffer-filtering-alist'.
 184 The QUALIFIER should be the same as QUALIFIER in
 185 `ibuffer-filtering-qualifiers'.")
 186
 187 (defcustom ibuffer-show-empty-filter-groups t
 188   "If non-nil, then show the names of filter groups which are empty."
 189   :type 'boolean
 190   :group 'ibuffer)
 191
 192 (defcustom ibuffer-saved-filter-groups nil
 193   "An alist of filtering groups to switch between.
 194
 195 This variable should look like ((\"STRING\" QUALIFIERS)
 196                                 (\"STRING\" QUALIFIERS) ...), where
 197 QUALIFIERS is a list of the same form as
 198 `ibuffer-filtering-qualifiers'.
 199
 200 See also the variables `ibuffer-filter-groups',
 201 `ibuffer-filtering-qualifiers', `ibuffer-filtering-alist', and the
 202 functions `ibuffer-switch-to-saved-filter-groups',
 203 `ibuffer-save-filter-groups'."
 204   :type '(repeat sexp)
 205   :group 'ibuffer)
 206
 207 (defvar ibuffer-hidden-filter-groups nil
 208   "A list of filtering groups which are currently hidden.")
 209
 210 (defvar ibuffer-filter-group-kill-ring nil)
 211
 212 (defcustom ibuffer-old-time 72
 213   "The number of hours before a buffer is considered \"old\"."
 214   :type '(choice (const :tag "72 hours (3 days)" 72)
 215                  (const :tag "48 hours (2 days)" 48)
 216                  (const :tag "24 hours (1 day)" 24)
 217                  (integer :tag "hours"))
 218   :group 'ibuffer)
 219
 220 (defcustom ibuffer-save-with-custom t
 221   "If non-nil, then use Custom to save interactively changed variables.
 222 Currently, this only applies to `ibuffer-saved-filters' and
 223 `ibuffer-saved-filter-groups'."
 224   :type 'boolean
 225   :group 'ibuffer)
 226
 227 (defun ibuffer-ext-visible-p (buf all &optional ibuffer-buf)
 228   (or
 229    (ibuffer-buf-matches-predicates buf ibuffer-tmp-show-regexps)
 230    (and (not
 231          (or
 232           (ibuffer-buf-matches-predicates buf ibuffer-tmp-hide-regexps)
 233           (ibuffer-buf-matches-predicates buf ibuffer-never-show-predicates)))
 234         (or all
 235             (not
 236              (ibuffer-buf-matches-predicates buf ibuffer-maybe-show-predicates)))
 237         (or ibuffer-view-ibuffer
 238             (and ibuffer-buf
 239                  (not (eq ibuffer-buf buf))))
 240         (or
 241          (ibuffer-included-in-filters-p buf ibuffer-filtering-qualifiers)
 242          (ibuffer-buf-matches-predicates buf ibuffer-always-show-predicates)))))
 243
 244 ;;;###autoload
 245 (define-minor-mode ibuffer-auto-mode
 246   "Toggle use of Ibuffer's auto-update facility (Ibuffer Auto mode).
 247 With a prefix argument ARG, enable Ibuffer Auto mode if ARG is
 248 positive, and disable it otherwise.  If called from Lisp, enable
 249 the mode if ARG is omitted or nil."
 250   nil nil nil
 251   (unless (derived-mode-p 'ibuffer-mode)
 252     (error "This buffer is not in Ibuffer mode"))
 253   (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed) ; Initialize state vector
 254   (add-hook 'post-command-hook 'ibuffer-auto-update-changed))
 255
 256 (defun ibuffer-auto-update-changed ()
 257   (when (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed)
 258     (dolist (buf (buffer-list))
 259       (ignore-errors
 260         (with-current-buffer buf
 261           (when (and ibuffer-auto-mode
 262                      (derived-mode-p 'ibuffer-mode))
 263             (ibuffer-update nil t)))))))
 264
 265 ;;;###autoload
 266 (defun ibuffer-mouse-filter-by-mode (event)
 267   "Enable or disable filtering by the major mode chosen via mouse."
 268   (interactive "e")
 269   (ibuffer-interactive-filter-by-mode event))
 270
 271 ;;;###autoload
 272 (defun ibuffer-interactive-filter-by-mode (event-or-point)
 273   "Enable or disable filtering by the major mode at point."
 274   (interactive "d")
 275   (if (eventp event-or-point)
 276       (posn-set-point (event-end event-or-point))
 277     (goto-char event-or-point))
 278   (let ((buf (ibuffer-current-buffer)))
 279     (if (assq 'mode ibuffer-filtering-qualifiers)
 280         (setq ibuffer-filtering-qualifiers
 281               (ibuffer-delete-alist 'mode ibuffer-filtering-qualifiers))
 282       (ibuffer-push-filter (cons 'mode (buffer-local-value 'major-mode buf)))))
 283   (ibuffer-update nil t))
 284
 285 ;;;###autoload
 286 (defun ibuffer-mouse-toggle-filter-group (event)
 287   "Toggle the display status of the filter group chosen with the mouse."
 288   (interactive "e")
 289   (ibuffer-toggle-filter-group-1 (save-excursion
 290                                    (mouse-set-point event)
 291                                    (point))))
 292
 293 ;;;###autoload
 294 (defun ibuffer-toggle-filter-group ()
 295   "Toggle the display status of the filter group on this line."
 296   (interactive)
 297   (ibuffer-toggle-filter-group-1 (point)))
 298
 299 (defun ibuffer-toggle-filter-group-1 (posn)
 300   (let ((name (get-text-property posn 'ibuffer-filter-group-name)))
 301     (unless (stringp name)
 302       (error "No filtering group name present"))
 303     (if (member name ibuffer-hidden-filter-groups)
 304         (setq ibuffer-hidden-filter-groups
 305               (delete name ibuffer-hidden-filter-groups))
 306       (push name ibuffer-hidden-filter-groups))
 307     (ibuffer-update nil t)))
 308
 309 ;;;###autoload
 310 (defun ibuffer-forward-filter-group (&optional count)
 311   "Move point forwards by COUNT filtering groups."
 312   (interactive "P")
 313   (unless count
 314     (setq count 1))
 315   (when (> count 0)
 316     (when (get-text-property (point) 'ibuffer-filter-group-name)
 317       (goto-char (next-single-property-change
 318                   (point) 'ibuffer-filter-group-name
 319                   nil (point-max))))
 320     (goto-char (next-single-property-change
 321                 (point) 'ibuffer-filter-group-name
 322                 nil (point-max)))
 323     (ibuffer-forward-filter-group (1- count)))
 324   (ibuffer-forward-line 0))
 325
 326 ;;;###autoload
 327 (defun ibuffer-backward-filter-group (&optional count)
 328   "Move point backwards by COUNT filtering groups."
 329   (interactive "P")
 330   (unless count
 331     (setq count 1))
 332   (when (> count 0)
 333     (when (get-text-property (point) 'ibuffer-filter-group-name)
 334       (goto-char (previous-single-property-change
 335                   (point) 'ibuffer-filter-group-name
 336                   nil (point-min))))
 337     (goto-char (previous-single-property-change
 338                 (point) 'ibuffer-filter-group-name
 339                 nil (point-min)))
 340     (ibuffer-backward-filter-group (1- count)))
 341   (when (= (point) (point-min))
 342     (goto-char (point-max))
 343     (ibuffer-backward-filter-group 1))
 344   (ibuffer-forward-line 0))
 345
 346 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe "ibuf-ext")
 347 (define-ibuffer-op shell-command-pipe (command)
 348   "Pipe the contents of each marked buffer to shell command COMMAND."
 349   (:interactive "sPipe to shell command: "
 350    :opstring "Shell command executed on"
 351    :modifier-p nil)
 352   (shell-command-on-region
 353    (point-min) (point-max) command))
 354
 355 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe-replace "ibuf-ext")
 356 (define-ibuffer-op shell-command-pipe-replace (command)
 357   "Replace the contents of marked buffers with output of pipe to COMMAND."
 358   (:interactive "sPipe to shell command (replace): "
 359    :opstring "Buffer contents replaced in"
 360    :active-opstring "replace buffer contents in"
 361    :dangerous t
 362    :modifier-p t)
 363   (with-current-buffer buf
 364     (shell-command-on-region (point-min) (point-max)
 365                              command nil t)))
 366
 367 ;;;###autoload (autoload 'ibuffer-do-shell-command-file "ibuf-ext")
 368 (define-ibuffer-op shell-command-file (command)
 369   "Run shell command COMMAND separately on files of marked buffers."
 370   (:interactive "sShell command on buffer's file: "
 371    :opstring "Shell command executed on"
 372    :modifier-p nil)
 373   (shell-command (concat command " "
 374                          (shell-quote-argument
 375                           (or buffer-file-name
 376                               (let ((file
 377                                      (make-temp-file
 378                                       (substring
 379                                        (buffer-name) 0
 380                                        (min 10 (length (buffer-name)))))))
 381                                 (write-region nil nil file nil 0)
 382                                 file))))))
 383
 384 ;;;###autoload (autoload 'ibuffer-do-eval "ibuf-ext")
 385 (define-ibuffer-op eval (form)
 386   "Evaluate FORM in each of the buffers.
 387 Does not display the buffer during evaluation. See
 388 `ibuffer-do-view-and-eval' for that."
 389   (:interactive
 390    (list
 391     (read-from-minibuffer
 392      "Eval in buffers (form): "
 393      nil read-expression-map t 'read-expression-history))
 394    :opstring "evaluated in"
 395    :modifier-p :maybe)
 396   (eval form))
 397
 398 ;;;###autoload (autoload 'ibuffer-do-view-and-eval "ibuf-ext")
 399 (define-ibuffer-op view-and-eval (form)
 400   "Evaluate FORM while displaying each of the marked buffers.
 401 To evaluate a form without viewing the buffer, see `ibuffer-do-eval'."
 402   (:interactive
 403    (list
 404     (read-from-minibuffer
 405      "Eval viewing in buffers (form): "
 406      nil read-expression-map t 'read-expression-history))
 407    :opstring "evaluated in"
 408    :complex t
 409    :modifier-p :maybe)
 410   (let ((ibuffer-buf (current-buffer)))
 411     (unwind-protect
 412         (progn
 413           (switch-to-buffer buf)
 414           (eval form))
 415       (switch-to-buffer ibuffer-buf))))
 416
 417 ;;;###autoload (autoload 'ibuffer-do-rename-uniquely "ibuf-ext")
 418 (define-ibuffer-op rename-uniquely ()
 419   "Rename marked buffers as with `rename-uniquely'."
 420   (:opstring "renamed"
 421    :modifier-p t)
 422   (rename-uniquely))
 423
 424 ;;;###autoload (autoload 'ibuffer-do-revert "ibuf-ext")
 425 (define-ibuffer-op revert ()
 426   "Revert marked buffers as with `revert-buffer'."
 427   (:dangerous t
 428    :opstring "reverted"
 429    :active-opstring "revert"
 430    :modifier-p :maybe)
 431   (revert-buffer t t))
 432
 433 ;;;###autoload (autoload 'ibuffer-do-isearch "ibuf-ext")
 434 (define-ibuffer-op ibuffer-do-isearch ()
 435   "Perform a `isearch-forward' in marked buffers."
 436   (:interactive ()
 437    :opstring "searched in"
 438    :complex t
 439    :modifier-p :maybe)
 440   (multi-isearch-buffers (ibuffer-get-marked-buffers)))
 441
 442 ;;;###autoload (autoload 'ibuffer-do-isearch-regexp "ibuf-ext")
 443 (define-ibuffer-op ibuffer-do-isearch-regexp ()
 444   "Perform a `isearch-forward-regexp' in marked buffers."
 445   (:interactive ()
 446    :opstring "searched regexp in"
 447    :complex t
 448    :modifier-p :maybe)
 449   (multi-isearch-buffers-regexp (ibuffer-get-marked-buffers)))
 450
 451 ;;;###autoload (autoload 'ibuffer-do-replace-regexp "ibuf-ext")
 452 (define-ibuffer-op replace-regexp (from-str to-str)
 453   "Perform a `replace-regexp' in marked buffers."
 454   (:interactive
 455    (let* ((from-str (read-from-minibuffer "Replace regexp: "))
 456           (to-str (read-from-minibuffer (concat "Replace " from-str
 457                                                 " with: "))))
 458      (list from-str to-str))
 459    :opstring "replaced in"
 460    :complex t
 461    :modifier-p :maybe)
 462   (save-window-excursion
 463     (switch-to-buffer buf)
 464     (save-excursion
 465       (goto-char (point-min))
 466       (let ((case-fold-search ibuffer-case-fold-search))
 467         (while (re-search-forward from-str nil t)
 468           (replace-match to-str))))
 469     t))
 470
 471 ;;;###autoload (autoload 'ibuffer-do-query-replace "ibuf-ext")
 472 (define-ibuffer-op query-replace (&rest args)
 473   "Perform a `query-replace' in marked buffers."
 474   (:interactive
 475    (query-replace-read-args "Query replace" t t)
 476    :opstring "replaced in"
 477    :complex t
 478    :modifier-p :maybe)
 479   (save-window-excursion
 480     (switch-to-buffer buf)
 481     (save-excursion
 482       (let ((case-fold-search ibuffer-case-fold-search))
 483         (goto-char (point-min))
 484         (apply #'query-replace args)))
 485     t))
 486
 487 ;;;###autoload (autoload 'ibuffer-do-query-replace-regexp "ibuf-ext")
 488 (define-ibuffer-op query-replace-regexp (&rest args)
 489   "Perform a `query-replace-regexp' in marked buffers."
 490   (:interactive
 491    (query-replace-read-args "Query replace regexp" t t)
 492    :opstring "replaced in"
 493    :complex t
 494    :modifier-p :maybe)
 495   (save-window-excursion
 496     (switch-to-buffer buf)
 497     (save-excursion
 498       (let ((case-fold-search ibuffer-case-fold-search))
 499         (goto-char (point-min))
 500         (apply #'query-replace-regexp args)))
 501     t))
 502
 503 ;;;###autoload (autoload 'ibuffer-do-print "ibuf-ext")
 504 (define-ibuffer-op print ()
 505   "Print marked buffers as with `print-buffer'."
 506   (:opstring "printed"
 507    :modifier-p nil)
 508   (print-buffer))
 509
 510 ;;;###autoload
 511 (defun ibuffer-included-in-filters-p (buf filters)
 512   (not
 513    (memq nil ;; a filter will return nil if it failed
 514          (mapcar
 515           ;; filter should be like (TYPE . QUALIFIER), or
 516           ;; (or (TYPE . QUALIFIER) (TYPE . QUALIFIER) ...)
 517           #'(lambda (qual)
 518               (ibuffer-included-in-filter-p buf qual))
 519           filters))))
 520
 521 (defun ibuffer-included-in-filter-p (buf filter)
 522   (if (eq (car filter) 'not)
 523       (not (ibuffer-included-in-filter-p-1 buf (cdr filter)))
 524     (ibuffer-included-in-filter-p-1 buf filter)))
 525
 526 (defun ibuffer-included-in-filter-p-1 (buf filter)
 527   (not
 528    (not
 529     (pcase (car filter)
 530       (`or
 531        (memq t (mapcar #'(lambda (x)
 532                            (ibuffer-included-in-filter-p buf x))
 533                        (cdr filter))))
 534       (`saved
 535        (let ((data
 536               (assoc (cdr filter)
 537                      ibuffer-saved-filters)))
 538          (unless data
 539            (ibuffer-filter-disable t)
 540            (error "Unknown saved filter %s" (cdr filter)))
 541          (ibuffer-included-in-filters-p buf (cadr data))))
 542       (_
 543        (pcase-let ((`(,_type ,_desc ,func)
 544                     (assq (car filter) ibuffer-filtering-alist)))
 545          (unless func
 546            (ibuffer-filter-disable t)
 547            (error "Undefined filter %s" (car filter)))
 548          (funcall func buf (cdr filter))))))))
 549
 550 (defun ibuffer-generate-filter-groups (bmarklist &optional noempty nodefault)
 551   (let ((filter-group-alist (if nodefault
 552                                 ibuffer-filter-groups
 553                               (append ibuffer-filter-groups
 554                                       (list (cons "Default" nil))))))
 555     ;; (dolist (hidden ibuffer-hidden-filter-groups)
 556     ;;   (setq filter-group-alist (ibuffer-delete-alist
 557     ;;                             hidden filter-group-alist)))
 558     (let ((vec (make-vector (length filter-group-alist) nil))
 559           (i 0))
 560       (dolist (filtergroup filter-group-alist)
 561         (let ((filterset (cdr filtergroup)))
 562           (cl-multiple-value-bind (hip-crowd lamers)
 563               (cl-values-list
 564                (ibuffer-split-list (lambda (bufmark)
 565                                      (ibuffer-included-in-filters-p (car bufmark)
 566                                                                     filterset))
 567                                    bmarklist))
 568             (aset vec i hip-crowd)
 569             (cl-incf i)
 570             (setq bmarklist lamers))))
 571       (let (ret)
 572         (dotimes (j i)
 573           (let ((bufs (aref vec j)))
 574             (unless (and noempty (null bufs))
 575               (push (cons (car (nth j filter-group-alist))
 576                           bufs)
 577                     ret))))
 578         ret))))
 579
 580 ;;;###autoload
 581 (defun ibuffer-filters-to-filter-group (name)
 582   "Make the current filters into a filtering group."
 583   (interactive "sName for filtering group: ")
 584   (when (null ibuffer-filtering-qualifiers)
 585     (error "No filters in effect"))
 586   (push (cons name ibuffer-filtering-qualifiers) ibuffer-filter-groups)
 587   (ibuffer-filter-disable))
 588
 589 ;;;###autoload
 590 (defun ibuffer-set-filter-groups-by-mode ()
 591   "Set the current filter groups to filter by mode."
 592   (interactive)
 593   (setq ibuffer-filter-groups
 594         (mapcar (lambda (mode)
 595                   (cons (format "%s" mode) `((mode . ,mode))))
 596                 (let ((modes
 597                        (ibuffer-remove-duplicates
 598                         (mapcar (lambda (buf)
 599                                   (buffer-local-value 'major-mode buf))
 600                                 (buffer-list)))))
 601                   (if ibuffer-view-ibuffer
 602                       modes
 603                     (delq 'ibuffer-mode modes)))))
 604   (ibuffer-update nil t))
 605
 606 ;;;###autoload
 607 (defun ibuffer-pop-filter-group ()
 608   "Remove the first filter group."
 609   (interactive)
 610   (when (null ibuffer-filter-groups)
 611     (error "No filter groups active"))
 612   (setq ibuffer-hidden-filter-groups
 613         (delete (pop ibuffer-filter-groups)
 614                 ibuffer-hidden-filter-groups))
 615   (ibuffer-update nil t))
 616
 617 (defun ibuffer-read-filter-group-name (msg &optional nodefault noerror)
 618   (when (and (not noerror) (null ibuffer-filter-groups))
 619     (error "No filter groups active"))
 620   ;; `ibuffer-generate-filter-groups' returns all non-hidden filter
 621   ;; groups, possibly excluding empty groups or Default.
 622   ;; We add `ibuffer-hidden-filter-groups' to the list, excluding
 623   ;; Default if necessary.
 624   (completing-read msg (nconc
 625                         (ibuffer-generate-filter-groups
 626                          (ibuffer-current-state-list)
 627                          (not ibuffer-show-empty-filter-groups)
 628                          nodefault)
 629                         (if nodefault
 630                             (remove "Default" ibuffer-hidden-filter-groups)
 631                           ibuffer-hidden-filter-groups))
 632                    nil t))
 633
 634 ;;;###autoload
 635 (defun ibuffer-decompose-filter-group (group)
 636   "Decompose the filter group GROUP into active filters."
 637   (interactive
 638    (list (ibuffer-read-filter-group-name "Decompose filter group: " t)))
 639   (let ((data (cdr (assoc group ibuffer-filter-groups))))
 640     (setq ibuffer-filter-groups (ibuffer-delete-alist
 641                                  group ibuffer-filter-groups)
 642           ibuffer-filtering-qualifiers data))
 643   (ibuffer-update nil t))
 644
 645 ;;;###autoload
 646 (defun ibuffer-clear-filter-groups ()
 647   "Remove all filter groups."
 648   (interactive)
 649   (setq ibuffer-filter-groups nil
 650         ibuffer-hidden-filter-groups nil)
 651   (ibuffer-update nil t))
 652
 653 (defun ibuffer-current-filter-groups-with-position ()
 654   (save-excursion
 655     (goto-char (point-min))
 656     (let ((pos nil)
 657           (result nil))
 658       (while (and (not (eobp))
 659                   (setq pos (next-single-property-change
 660                              (point) 'ibuffer-filter-group-name)))
 661         (goto-char pos)
 662         (push (cons (get-text-property (point) 'ibuffer-filter-group-name)
 663                     pos)
 664               result)
 665         (goto-char (next-single-property-change
 666                     pos 'ibuffer-filter-group-name)))
 667       (nreverse result))))
 668
 669 ;;;###autoload
 670 (defun ibuffer-jump-to-filter-group (name)
 671   "Move point to the filter group whose name is NAME."
 672   (interactive
 673    (list (ibuffer-read-filter-group-name "Jump to filter group: ")))
 674   (ibuffer-aif (assoc name (ibuffer-current-filter-groups-with-position))
 675       (goto-char (cdr it))
 676     (error "No filter group with name %s" name)))
 677
 678 ;;;###autoload
 679 (defun ibuffer-kill-filter-group (name)
 680   "Kill the filter group named NAME.
 681 The group will be added to `ibuffer-filter-group-kill-ring'."
 682   (interactive (list (ibuffer-read-filter-group-name "Kill filter group: " t)))
 683   (when (equal name "Default")
 684     (error "Can't kill default filter group"))
 685   (ibuffer-aif (assoc name ibuffer-filter-groups)
 686       (progn
 687         (push (copy-tree it) ibuffer-filter-group-kill-ring)
 688         (setq ibuffer-filter-groups (ibuffer-delete-alist
 689                                      name ibuffer-filter-groups))
 690         (setq ibuffer-hidden-filter-groups
 691               (delete name ibuffer-hidden-filter-groups)))
 692     (error "No filter group with name \"%s\"" name))
 693   (ibuffer-update nil t))
 694
 695 ;;;###autoload
 696 (defun ibuffer-kill-line (&optional arg interactive-p)
 697   "Kill the filter group at point.
 698 See also `ibuffer-kill-filter-group'."
 699   (interactive "P\np")
 700   (ibuffer-aif (save-excursion
 701                  (ibuffer-forward-line 0)
 702                  (get-text-property (point) 'ibuffer-filter-group-name))
 703       (progn
 704         (ibuffer-kill-filter-group it))
 705       (funcall (if interactive-p #'call-interactively #'funcall)
 706                #'kill-line arg)))
 707
 708 (defun ibuffer-insert-filter-group-before (newgroup group)
 709   (let* ((found nil)
 710          (pos (let ((groups (mapcar #'car ibuffer-filter-groups))
 711                     (res 0))
 712                 (while groups
 713                   (if (equal (car groups) group)
 714                       (setq found t
 715                             groups nil)
 716                     (cl-incf res)
 717                     (setq groups (cdr groups))))
 718                 res)))
 719     (cond ((not found)
 720            (setq ibuffer-filter-groups
 721                  (nconc ibuffer-filter-groups (list newgroup))))
 722           ((zerop pos)
 723            (push newgroup ibuffer-filter-groups))
 724           (t
 725            (let ((cell (nthcdr pos ibuffer-filter-groups)))
 726              (setf (cdr cell) (cons (car cell) (cdr cell)))
 727              (setf (car cell) newgroup))))))
 728
 729 ;;;###autoload
 730 (defun ibuffer-yank ()
 731   "Yank the last killed filter group before group at point."
 732   (interactive)
 733   (ibuffer-yank-filter-group
 734    (or (get-text-property (point) 'ibuffer-filter-group-name)
 735        (get-text-property (point) 'ibuffer-filter-group)
 736        (error "No filter group at point"))))
 737
 738 ;;;###autoload
 739 (defun ibuffer-yank-filter-group (name)
 740   "Yank the last killed filter group before group named NAME."
 741   (interactive (list (ibuffer-read-filter-group-name
 742                         "Yank filter group before group: ")))
 743   (unless ibuffer-filter-group-kill-ring
 744     (error "The Ibuffer filter group kill-ring is empty"))
 745   (save-excursion
 746     (ibuffer-forward-line 0)
 747     (ibuffer-insert-filter-group-before (pop ibuffer-filter-group-kill-ring)
 748                                         name))
 749   (ibuffer-update nil t))
 750
 751 ;;;###autoload
 752 (defun ibuffer-save-filter-groups (name groups)
 753   "Save all active filter groups GROUPS as NAME.
 754 They are added to `ibuffer-saved-filter-groups'.  Interactively,
 755 prompt for NAME, and use the current filters."
 756   (interactive
 757    (if (null ibuffer-filter-groups)
 758        (error "No filter groups active")
 759      (list
 760       (read-from-minibuffer "Save current filter groups as: ")
 761       ibuffer-filter-groups)))
 762   (ibuffer-aif (assoc name ibuffer-saved-filter-groups)
 763       (setcdr it groups)
 764     (push (cons name groups) ibuffer-saved-filter-groups))
 765   (ibuffer-maybe-save-stuff))
 766
 767 ;;;###autoload
 768 (defun ibuffer-delete-saved-filter-groups (name)
 769   "Delete saved filter groups with NAME.
 770 They are removed from `ibuffer-saved-filter-groups'."
 771   (interactive
 772    (list
 773     (if (null ibuffer-saved-filter-groups)
 774         (error "No saved filter groups")
 775       (completing-read "Delete saved filter group: "
 776                        ibuffer-saved-filter-groups nil t))))
 777   (setq ibuffer-saved-filter-groups
 778         (ibuffer-delete-alist name ibuffer-saved-filter-groups))
 779   (ibuffer-maybe-save-stuff)
 780   (ibuffer-update nil t))
 781
 782 ;;;###autoload
 783 (defun ibuffer-switch-to-saved-filter-groups (name)
 784   "Set this buffer's filter groups to saved version with NAME.
 785 The value from `ibuffer-saved-filter-groups' is used."
 786   (interactive
 787    (list
 788     (cond ((null ibuffer-saved-filter-groups)
 789            (error "No saved filters"))
 790           ;; `ibuffer-saved-filter-groups' is a user variable that defaults
 791           ;; to nil.  We assume that with one element in this list the user
 792           ;; knows what she wants.  See bug#12331.
 793           ((null (cdr ibuffer-saved-filter-groups))
 794            (caar ibuffer-saved-filter-groups))
 795           (t
 796            (completing-read "Switch to saved filter group: "
 797                             ibuffer-saved-filter-groups nil t)))))
 798   (setq ibuffer-filter-groups (cdr (assoc name ibuffer-saved-filter-groups))
 799         ibuffer-hidden-filter-groups nil)
 800   (ibuffer-update nil t))
 801
 802 ;;;###autoload
 803 (defun ibuffer-filter-disable (&optional delete-filter-groups)
 804   "Disable all filters currently in effect in this buffer.
 805 With optional arg DELETE-FILTER-GROUPS non-nil, delete all filter
 806 group definitions by setting `ibuffer-filter-groups' to nil."
 807   (interactive)
 808   (setq ibuffer-filtering-qualifiers nil)
 809   (if delete-filter-groups
 810       (setq ibuffer-filter-groups nil))
 811   (let ((buf (ibuffer-current-buffer)))
 812     (ibuffer-update nil t)
 813     (when buf
 814       (ibuffer-jump-to-buffer (buffer-name buf)))))
 815
 816 ;;;###autoload
 817 (defun ibuffer-pop-filter ()
 818   "Remove the top filter in this buffer."
 819   (interactive)
 820   (when (null ibuffer-filtering-qualifiers)
 821     (error "No filters in effect"))
 822   (pop ibuffer-filtering-qualifiers)
 823   (let ((buf (ibuffer-current-buffer)))
 824     (ibuffer-update nil t)
 825     (when buf
 826       (ibuffer-jump-to-buffer (buffer-name buf)))))
 827
 828 (defun ibuffer-push-filter (qualifier)
 829   "Add QUALIFIER to `ibuffer-filtering-qualifiers'."
 830   (push qualifier ibuffer-filtering-qualifiers))
 831
 832 ;;;###autoload
 833 (defun ibuffer-decompose-filter ()
 834   "Separate the top compound filter (OR, NOT, or SAVED) in this buffer.
 835
 836 This means that the topmost filter on the filtering stack, which must
 837 be a complex filter like (OR [name: foo] [mode: bar-mode]), will be
 838 turned into two separate filters [name: foo] and [mode: bar-mode]."
 839   (interactive)
 840   (when (null ibuffer-filtering-qualifiers)
 841     (error "No filters in effect"))
 842   (let ((lim (pop ibuffer-filtering-qualifiers)))
 843     (pcase (car lim)
 844       (`or
 845        (setq ibuffer-filtering-qualifiers (append
 846                                           (cdr lim)
 847                                           ibuffer-filtering-qualifiers)))
 848       (`saved
 849        (let ((data
 850               (assoc (cdr lim)
 851                      ibuffer-saved-filters)))
 852          (unless data
 853            (ibuffer-filter-disable)
 854            (error "Unknown saved filter %s" (cdr lim)))
 855          (setq ibuffer-filtering-qualifiers (append
 856                                             (cadr data)
 857                                             ibuffer-filtering-qualifiers))))
 858       (`not
 859        (push (cdr lim)
 860              ibuffer-filtering-qualifiers))
 861       (_
 862        (error "Filter type %s is not compound" (car lim)))))
 863   (ibuffer-update nil t))
 864
 865 ;;;###autoload
 866 (defun ibuffer-exchange-filters ()
 867   "Exchange the top two filters on the stack in this buffer."
 868   (interactive)
 869   (when (< (length ibuffer-filtering-qualifiers)
 870            2)
 871     (error "Need two filters to exchange"))
 872   (let ((first (pop ibuffer-filtering-qualifiers))
 873         (second (pop ibuffer-filtering-qualifiers)))
 874     (push first ibuffer-filtering-qualifiers)
 875     (push second ibuffer-filtering-qualifiers))
 876   (ibuffer-update nil t))
 877
 878 ;;;###autoload
 879 (defun ibuffer-negate-filter ()
 880   "Negate the sense of the top filter in the current buffer."
 881   (interactive)
 882   (when (null ibuffer-filtering-qualifiers)
 883     (error "No filters in effect"))
 884   (let ((lim (pop ibuffer-filtering-qualifiers)))
 885     (push (if (eq (car lim) 'not)
 886               (cdr lim)
 887             (cons 'not lim))
 888           ibuffer-filtering-qualifiers))
 889   (ibuffer-update nil t))
 890
 891 ;;;###autoload
 892 (defun ibuffer-or-filter (&optional reverse)
 893   "Replace the top two filters in this buffer with their logical OR.
 894 If optional argument REVERSE is non-nil, instead break the top OR
 895 filter into parts."
 896   (interactive "P")
 897   (if reverse
 898       (progn
 899         (when (or (null ibuffer-filtering-qualifiers)
 900                   (not (eq 'or (caar ibuffer-filtering-qualifiers))))
 901           (error "Top filter is not an OR"))
 902         (let ((lim (pop ibuffer-filtering-qualifiers)))
 903           (setq ibuffer-filtering-qualifiers
 904                 (nconc (cdr lim) ibuffer-filtering-qualifiers))))
 905     (when (< (length ibuffer-filtering-qualifiers) 2)
 906       (error "Need two filters to OR"))
 907     ;; If the second filter is an OR, just add to it.
 908     (let ((first (pop ibuffer-filtering-qualifiers))
 909           (second (pop ibuffer-filtering-qualifiers)))
 910       (if (eq 'or (car second))
 911           (push (nconc (list 'or first) (cdr second))
 912                 ibuffer-filtering-qualifiers)
 913         (push (list 'or first second)
 914               ibuffer-filtering-qualifiers))))
 915   (ibuffer-update nil t))
 916
 917 (defun ibuffer-maybe-save-stuff ()
 918   (when ibuffer-save-with-custom
 919     (if (fboundp 'customize-save-variable)
 920         (progn
 921           (customize-save-variable 'ibuffer-saved-filters
 922                                    ibuffer-saved-filters)
 923           (customize-save-variable 'ibuffer-saved-filter-groups
 924                                    ibuffer-saved-filter-groups))
 925       (message "Not saved permanently: Customize not available"))))
 926
 927 ;;;###autoload
 928 (defun ibuffer-save-filters (name filters)
 929   "Save FILTERS in this buffer with name NAME in `ibuffer-saved-filters'.
 930 Interactively, prompt for NAME, and use the current filters."
 931   (interactive
 932    (if (null ibuffer-filtering-qualifiers)
 933        (error "No filters currently in effect")
 934      (list
 935       (read-from-minibuffer "Save current filters as: ")
 936       ibuffer-filtering-qualifiers)))
 937   (ibuffer-aif (assoc name ibuffer-saved-filters)
 938       (setcdr it filters)
 939     (push (list name filters) ibuffer-saved-filters))
 940   (ibuffer-maybe-save-stuff))
 941
 942 ;;;###autoload
 943 (defun ibuffer-delete-saved-filters (name)
 944   "Delete saved filters with NAME from `ibuffer-saved-filters'."
 945   (interactive
 946    (list
 947     (if (null ibuffer-saved-filters)
 948         (error "No saved filters")
 949       (completing-read "Delete saved filters: "
 950                        ibuffer-saved-filters nil t))))
 951   (setq ibuffer-saved-filters
 952         (ibuffer-delete-alist name ibuffer-saved-filters))
 953   (ibuffer-maybe-save-stuff)
 954   (ibuffer-update nil t))
 955
 956 ;;;###autoload
 957 (defun ibuffer-add-saved-filters (name)
 958   "Add saved filters from `ibuffer-saved-filters' to this buffer's filters."
 959   (interactive
 960    (list
 961     (if (null ibuffer-saved-filters)
 962         (error "No saved filters")
 963       (completing-read "Add saved filters: "
 964                        ibuffer-saved-filters nil t))))
 965   (push (cons 'saved name) ibuffer-filtering-qualifiers)
 966   (ibuffer-update nil t))
 967
 968 ;;;###autoload
 969 (defun ibuffer-switch-to-saved-filters (name)
 970   "Set this buffer's filters to filters with NAME from `ibuffer-saved-filters'."
 971   (interactive
 972    (list
 973     (if (null ibuffer-saved-filters)
 974         (error "No saved filters")
 975       (completing-read "Switch to saved filters: "
 976                        ibuffer-saved-filters nil t))))
 977   (setq ibuffer-filtering-qualifiers (list (cons 'saved name)))
 978   (ibuffer-update nil t))
 979
 980 (defun ibuffer-format-filter-group-data (filter)
 981   (if (equal filter "Default")
 982       ""
 983     (concat "Filter:" (mapconcat #'ibuffer-format-qualifier
 984                                  (cdr (assq filter ibuffer-filter-groups))
 985                                  " "))))
 986
 987 (defun ibuffer-format-qualifier (qualifier)
 988   (if (eq (car-safe qualifier) 'not)
 989       (concat " [NOT" (ibuffer-format-qualifier-1 (cdr qualifier)) "]")
 990     (ibuffer-format-qualifier-1 qualifier)))
 991
 992 (defun ibuffer-format-qualifier-1 (qualifier)
 993   (pcase (car qualifier)
 994     (`saved
 995      (concat " [filter: " (cdr qualifier) "]"))
 996     (`or
 997      (concat " [OR" (mapconcat #'ibuffer-format-qualifier
 998                                (cdr qualifier) "") "]"))
 999     (_
1000      (let ((type (assq (car qualifier) ibuffer-filtering-alist)))
1001        (unless qualifier
1002          (error "Ibuffer: bad qualifier %s" qualifier))
1003        (concat " [" (cadr type) ": " (format "%s]" (cdr qualifier)))))))
1004
1005
1006 (defun ibuffer-list-buffer-modes (&optional include-parents)
1007   "Create a completion table of buffer modes currently in use.
1008 If INCLUDE-PARENTS is non-nil then include parent modes."
1009   (let ((modes))
1010     (dolist (buf (buffer-list))
1011       (let ((this-mode (buffer-local-value 'major-mode buf)))
1012         (while (and this-mode (not (memq this-mode modes)))
1013           (push this-mode modes)
1014           (setq this-mode (and include-parents
1015                                (get this-mode 'derived-mode-parent))))))
1016     (mapcar #'symbol-name modes)))
1017
1018
1019 ;;; Extra operation definitions
1020
1021 ;;;###autoload (autoload 'ibuffer-filter-by-mode "ibuf-ext")
1022 (define-ibuffer-filter mode
1023   "Toggle current view to buffers with major mode QUALIFIER."
1024   (:description "major mode"
1025    :reader
1026    (let* ((buf (ibuffer-current-buffer))
1027           (default (if (and buf (buffer-live-p buf))
1028                        (symbol-name (buffer-local-value
1029                                      'major-mode buf)))))
1030      (intern
1031       (completing-read
1032        (if default
1033            (format "Filter by major mode (default %s): " default)
1034          "Filter by major mode: ")
1035        obarray
1036        #'(lambda (e)
1037            (string-match "-mode\\'" (symbol-name e)))
1038        t nil nil default))))
1039   (eq qualifier (buffer-local-value 'major-mode buf)))
1040
1041 ;;;###autoload (autoload 'ibuffer-filter-by-used-mode "ibuf-ext")
1042 (define-ibuffer-filter used-mode
1043   "Toggle current view to buffers with major mode QUALIFIER.
1044 Called interactively, this function allows selection of modes
1045 currently used by buffers."
1046   (:description "major mode in use"
1047    :reader
1048    (let* ((buf (ibuffer-current-buffer))
1049           (default (if (and buf (buffer-live-p buf))
1050                        (symbol-name (buffer-local-value
1051                                      'major-mode buf)))))
1052      (intern
1053       (completing-read
1054        (if default
1055            (format "Filter by major mode (default %s): " default)
1056          "Filter by major mode: ")
1057        (ibuffer-list-buffer-modes) nil t nil nil default))))
1058   (eq qualifier (buffer-local-value 'major-mode buf)))
1059
1060 ;;;###autoload (autoload 'ibuffer-filter-by-derived-mode "ibuf-ext")
1061 (define-ibuffer-filter derived-mode
1062     "Toggle current view to buffers whose major mode inherits from QUALIFIER."
1063   (:description "derived mode"
1064                 :reader
1065                 (intern
1066                  (completing-read "Filter by derived mode: "
1067                                   (ibuffer-list-buffer-modes t)
1068                                   nil t)))
1069   (with-current-buffer buf (derived-mode-p qualifier)))
1070
1071 ;;;###autoload (autoload 'ibuffer-filter-by-name "ibuf-ext")
1072 (define-ibuffer-filter name
1073   "Toggle current view to buffers with name matching QUALIFIER."
1074   (:description "buffer name"
1075    :reader (read-from-minibuffer "Filter by name (regexp): "))
1076   (string-match qualifier (buffer-name buf)))
1077
1078 ;;;###autoload (autoload 'ibuffer-filter-by-filename "ibuf-ext")
1079 (define-ibuffer-filter filename
1080   "Toggle current view to buffers with filename matching QUALIFIER."
1081   (:description "filename"
1082    :reader (read-from-minibuffer "Filter by filename (regexp): "))
1083   (ibuffer-awhen (with-current-buffer buf (ibuffer-buffer-file-name))
1084     (string-match qualifier it)))
1085
1086 ;;;###autoload (autoload 'ibuffer-filter-by-size-gt  "ibuf-ext")
1087 (define-ibuffer-filter size-gt
1088   "Toggle current view to buffers with size greater than QUALIFIER."
1089   (:description "size greater than"
1090    :reader
1091    (string-to-number (read-from-minibuffer "Filter by size greater than: ")))
1092   (> (with-current-buffer buf (buffer-size))
1093      qualifier))
1094
1095 ;;;###autoload (autoload 'ibuffer-filter-by-size-lt  "ibuf-ext")
1096 (define-ibuffer-filter size-lt
1097    "Toggle current view to buffers with size less than QUALIFIER."
1098   (:description "size less than"
1099    :reader
1100    (string-to-number (read-from-minibuffer "Filter by size less than: ")))
1101   (< (with-current-buffer buf (buffer-size))
1102      qualifier))
1103
1104 ;;;###autoload (autoload 'ibuffer-filter-by-content "ibuf-ext")
1105 (define-ibuffer-filter content
1106    "Toggle current view to buffers whose contents match QUALIFIER."
1107   (:description "content"
1108    :reader (read-from-minibuffer "Filter by content (regexp): "))
1109   (with-current-buffer buf
1110     (save-excursion
1111       (goto-char (point-min))
1112       (re-search-forward qualifier nil t))))
1113
1114 ;;;###autoload (autoload 'ibuffer-filter-by-predicate "ibuf-ext")
1115 (define-ibuffer-filter predicate
1116    "Toggle current view to buffers for which QUALIFIER returns non-nil."
1117   (:description "predicate"
1118    :reader (read-minibuffer "Filter by predicate (form): "))
1119   (with-current-buffer buf
1120     (eval qualifier)))
1121
1122 ;;; Sorting
1123
1124 ;;;###autoload
1125 (defun ibuffer-toggle-sorting-mode ()
1126   "Toggle the current sorting mode.
1127 Default sorting modes are:
1128  Recency - the last time the buffer was viewed
1129  Name - the name of the buffer
1130  Major Mode - the name of the major mode of the buffer
1131  Size - the size of the buffer"
1132   (interactive)
1133   (let ((modes (mapcar #'car ibuffer-sorting-functions-alist)))
1134     (cl-pushnew 'recency modes)
1135     (setq modes (sort modes #'string-lessp))
1136     (let ((next (or (car-safe (cdr-safe (memq ibuffer-sorting-mode modes)))
1137                     (car modes))))
1138       (setq ibuffer-sorting-mode next)
1139       (message "Sorting by %s" next)))
1140   (ibuffer-redisplay t))
1141
1142 ;;;###autoload
1143 (defun ibuffer-invert-sorting ()
1144   "Toggle whether or not sorting is in reverse order."
1145   (interactive)
1146   (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep))
1147   (message "Sorting order %s"
1148            (if ibuffer-sorting-reversep
1149                "reversed"
1150              "normal"))
1151   (ibuffer-redisplay t))
1152
1153 ;;;###autoload (autoload 'ibuffer-do-sort-by-major-mode "ibuf-ext")
1154 (define-ibuffer-sorter major-mode
1155   "Sort the buffers by major modes.
1156 Ordering is lexicographic."
1157   (:description "major mode")
1158   (string-lessp (downcase
1159                  (symbol-name (buffer-local-value 'major-mode (car a))))
1160                 (downcase
1161                  (symbol-name (buffer-local-value 'major-mode (car b))))))
1162
1163 ;;;###autoload (autoload 'ibuffer-do-sort-by-mode-name "ibuf-ext")
1164 (define-ibuffer-sorter mode-name
1165   "Sort the buffers by their mode name.
1166 Ordering is lexicographic."
1167   (:description "major mode name")
1168   (string-lessp (downcase
1169                  (with-current-buffer
1170                      (car a)
1171                    (format-mode-line mode-name)))
1172                 (downcase
1173                  (with-current-buffer
1174                      (car b)
1175                    (format-mode-line mode-name)))))
1176
1177 ;;;###autoload (autoload 'ibuffer-do-sort-by-alphabetic "ibuf-ext")
1178 (define-ibuffer-sorter alphabetic
1179   "Sort the buffers by their names.
1180 Ordering is lexicographic."
1181   (:description "buffer name")
1182   (string-lessp
1183    (buffer-name (car a))
1184    (buffer-name (car b))))
1185
1186 ;;;###autoload (autoload 'ibuffer-do-sort-by-size "ibuf-ext")
1187 (define-ibuffer-sorter size
1188  "Sort the buffers by their size."
1189   (:description "size")
1190   (< (with-current-buffer (car a)
1191        (buffer-size))
1192      (with-current-buffer (car b)
1193        (buffer-size))))
1194
1195 ;;;###autoload (autoload 'ibuffer-do-sort-by-filename/process "ibuf-ext")
1196 (define-ibuffer-sorter filename/process
1197  "Sort the buffers by their file name/process name."
1198   (:description "file name")
1199   (string-lessp
1200    ;; FIXME: For now just compare the file name and the process name
1201    ;; (if it exists).  Is there a better way to do this?
1202    (or (buffer-file-name (car a))
1203        (let ((pr-a (get-buffer-process (car a))))
1204          (and (processp pr-a) (process-name pr-a))))
1205    (or (buffer-file-name (car b))
1206        (let ((pr-b (get-buffer-process (car b))))
1207          (and (processp pr-b) (process-name pr-b))))))
1208
1209 ;;; Functions to emulate bs.el
1210
1211 ;;;###autoload
1212 (defun ibuffer-bs-show ()
1213   "Emulate `bs-show' from the bs.el package."
1214   (interactive)
1215   (ibuffer t "*Ibuffer-bs*" '((filename . ".*")) nil t)
1216   (define-key (current-local-map) "a" 'ibuffer-bs-toggle-all))
1217
1218 (defun ibuffer-bs-toggle-all ()
1219   "Emulate `bs-toggle-show-all' from the bs.el package."
1220   (interactive)
1221   (if ibuffer-filtering-qualifiers
1222       (ibuffer-pop-filter)
1223     (progn (ibuffer-push-filter '(filename . ".*"))
1224            (ibuffer-update nil t))))
1225
1226 ;;; Handy functions
1227
1228 ;;;###autoload
1229 (defun ibuffer-add-to-tmp-hide (regexp)
1230   "Add REGEXP to `ibuffer-tmp-hide-regexps'.
1231 This means that buffers whose name matches REGEXP will not be shown
1232 for this Ibuffer session."
1233   (interactive
1234    (list
1235     (read-from-minibuffer "Never show buffers matching: "
1236                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1237   (push regexp ibuffer-tmp-hide-regexps))
1238
1239 ;;;###autoload
1240 (defun ibuffer-add-to-tmp-show (regexp)
1241   "Add REGEXP to `ibuffer-tmp-show-regexps'.
1242 This means that buffers whose name matches REGEXP will always be shown
1243 for this Ibuffer session."
1244   (interactive
1245    (list
1246     (read-from-minibuffer "Always show buffers matching: "
1247                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1248   (push regexp ibuffer-tmp-show-regexps))
1249
1250 ;;;###autoload
1251 (defun ibuffer-forward-next-marked (&optional count mark direction)
1252   "Move forward by COUNT marked buffers (default 1).
1253
1254 If MARK is non-nil, it should be a character denoting the type of mark
1255 to move by.  The default is `ibuffer-marked-char'.
1256
1257 If DIRECTION is non-nil, it should be an integer; negative integers
1258 mean move backwards, non-negative integers mean move forwards."
1259   (interactive "P")
1260   (unless count
1261     (setq count 1))
1262   (unless mark
1263     (setq mark ibuffer-marked-char))
1264   (unless direction
1265     (setq direction 1))
1266   ;; Skip the title
1267   (ibuffer-forward-line 0)
1268   (let ((opos (point)))
1269     (ibuffer-forward-line direction)
1270     (while (not (or (= (point) opos)
1271                     (eq (ibuffer-current-mark) mark)))
1272       (ibuffer-forward-line direction))
1273     (when (and (= (point) opos)
1274                (not (eq (ibuffer-current-mark) mark)))
1275       (error "No buffers with mark %c" mark))))
1276
1277 ;;;###autoload
1278 (defun ibuffer-backwards-next-marked (&optional count mark)
1279    "Move backwards by COUNT marked buffers (default 1).
1280
1281 If MARK is non-nil, it should be a character denoting the type of mark
1282 to move by.  The default is `ibuffer-marked-char'."
1283    (interactive "P")
1284    (ibuffer-forward-next-marked count mark -1))
1285
1286 ;;;###autoload
1287 (defun ibuffer-do-kill-lines ()
1288   "Hide all of the currently marked lines."
1289   (interactive)
1290   (if (= (ibuffer-count-marked-lines) 0)
1291       (message "No buffers marked; use 'm' to mark a buffer")
1292     (let ((count
1293            (ibuffer-map-marked-lines
1294             #'(lambda (_buf _mark)
1295                 'kill))))
1296       (message "Killed %s lines" count))))
1297
1298 ;;;###autoload
1299 (defun ibuffer-jump-to-buffer (name)
1300   "Move point to the buffer whose name is NAME.
1301
1302 If called interactively, prompt for a buffer name and go to the
1303 corresponding line in the Ibuffer buffer.  If said buffer is in a
1304 hidden group filter, open it.
1305
1306 If `ibuffer-jump-offer-only-visible-buffers' is non-nil, only offer
1307 visible buffers in the completion list.  Calling the command with
1308 a prefix argument reverses the meaning of that variable."
1309   (interactive (list
1310                 (let ((only-visible ibuffer-jump-offer-only-visible-buffers))
1311                   (when current-prefix-arg
1312                     (setq only-visible (not only-visible)))
1313                   (if only-visible
1314                       (let ((table (mapcar #'(lambda (x)
1315                                                (buffer-name (car x)))
1316                                            (ibuffer-current-state-list))))
1317                         (when (null table)
1318                           (error "No buffers!"))
1319                         (completing-read "Jump to buffer: "
1320                                          table nil t))
1321                     (read-buffer "Jump to buffer: " nil t)))))
1322   (when (not (string= "" name))
1323     (let (buf-point)
1324       ;; Blindly search for our buffer: it is very likely that it is
1325       ;; not in a hidden filter group.
1326       (ibuffer-map-lines #'(lambda (buf _marks)
1327                              (when (string= (buffer-name buf) name)
1328                                (setq buf-point (point))
1329                                nil))
1330                          t nil)
1331       (when (and
1332              (null buf-point)
1333              (not (null ibuffer-hidden-filter-groups)))
1334         ;; We did not find our buffer.  It must be in a hidden filter
1335         ;; group, so go through all hidden filter groups to find it.
1336         (catch 'found
1337           (dolist (group ibuffer-hidden-filter-groups)
1338             (ibuffer-jump-to-filter-group group)
1339             (ibuffer-toggle-filter-group)
1340             (ibuffer-map-lines #'(lambda (buf _marks)
1341                                    (when (string= (buffer-name buf) name)
1342                                      (setq buf-point (point))
1343                                      nil))
1344                                t group)
1345             (if buf-point
1346                 (throw 'found nil)
1347               (ibuffer-toggle-filter-group)))))
1348       (if (null buf-point)
1349           ;; Still not found even though we expanded all hidden filter
1350           ;; groups: that must be because it's hidden by predicate:
1351           ;; we won't bother trying to display it.
1352           (error "No buffer with name %s" name)
1353         (goto-char buf-point)))))
1354
1355 (declare-function diff-sentinel "diff"
1356                   (code &optional old-temp-file new-temp-file))
1357
1358 (defun ibuffer-diff-buffer-with-file-1 (buffer)
1359   (let ((bufferfile (buffer-local-value 'buffer-file-name buffer))
1360         (tempfile (make-temp-file "buffer-content-")))
1361     (when bufferfile
1362       (unwind-protect
1363           (progn
1364             (with-current-buffer buffer
1365               (write-region nil nil tempfile nil 'nomessage))
1366             (let* ((old (expand-file-name bufferfile))
1367                    (new (expand-file-name tempfile))
1368                    (oldtmp (file-local-copy old))
1369                    (newtmp (file-local-copy new))
1370                    (switches diff-switches)
1371                    (command
1372                     (mapconcat
1373                      'identity
1374                      `(,diff-command
1375                        ;; Use explicitly specified switches
1376                        ,@(if (listp switches) switches (list switches))
1377                        ,@(if (or old new)
1378                              (list "-L" (shell-quote-argument old)
1379                                    "-L" (shell-quote-argument
1380                                          (format "Buffer %s" (buffer-name buffer)))))
1381                        ,(shell-quote-argument (or oldtmp old))
1382                        ,(shell-quote-argument (or newtmp new)))
1383                      " ")))
1384               (let ((inhibit-read-only t))
1385                 (insert command "\n")
1386                 (diff-sentinel
1387                  (call-process shell-file-name nil
1388                                (current-buffer) nil
1389                                shell-command-switch command))
1390                 (insert "\n")))))
1391       (sit-for 0)
1392       (when (file-exists-p tempfile)
1393         (delete-file tempfile)))))
1394
1395 ;;;###autoload
1396 (defun ibuffer-diff-with-file ()
1397   "View the differences between marked buffers and their associated files.
1398 If no buffers are marked, use buffer at point.
1399 This requires the external program \"diff\" to be in your `exec-path'."
1400   (interactive)
1401   (require 'diff)
1402   (let ((marked-bufs (ibuffer-get-marked-buffers)))
1403     (when (null marked-bufs)
1404       (setq marked-bufs (list (ibuffer-current-buffer t))))
1405     (with-current-buffer (get-buffer-create "*Ibuffer Diff*")
1406       (setq buffer-read-only nil)
1407       (buffer-disable-undo (current-buffer))
1408       (erase-buffer)
1409       (buffer-enable-undo (current-buffer))
1410       (diff-mode)
1411       (dolist (buf marked-bufs)
1412         (unless (buffer-live-p buf)
1413           (error "Buffer %s has been killed" buf))
1414         (ibuffer-diff-buffer-with-file-1 buf))
1415       (setq buffer-read-only t)))
1416   (switch-to-buffer "*Ibuffer Diff*"))
1417
1418 ;;;###autoload
1419 (defun ibuffer-copy-filename-as-kill (&optional arg)
1420   "Copy filenames of marked buffers into the kill ring.
1421
1422 The names are separated by a space.
1423 If a buffer has no filename, it is ignored.
1424
1425 With no prefix arg, use the filename sans its directory of each marked file.
1426 With a zero prefix arg, use the complete filename of each marked file.
1427 With \\[universal-argument], use the filename of each marked file relative
1428 to `ibuffer-default-directory' if non-nil, otherwise `default-directory'.
1429
1430 You can then feed the file name(s) to other commands with \\[yank]."
1431   (interactive "p")
1432   (if (zerop (ibuffer-count-marked-lines))
1433       (message "No buffers marked; use 'm' to mark a buffer")
1434     (let ((result "")
1435           (type (cond ((or (null arg) (zerop arg))
1436                        'full)
1437                       ((= arg 4)
1438                        'relative)
1439                       (t
1440                        'name))))
1441       (ibuffer-map-marked-lines
1442        #'(lambda (buf _mark)
1443            (setq result
1444                  (concat result
1445                          (let ((name (buffer-file-name buf)))
1446                            (cond (name
1447                                   (concat
1448                                    (pcase type
1449                                      (`full
1450                                       name)
1451                                      (`relative
1452                                       (file-relative-name
1453                                        name (or ibuffer-default-directory
1454                                                 default-directory)))
1455                                      (_
1456                                       (file-name-nondirectory name))) " "))
1457                                  (t "")))))))
1458       (when (not (zerop (length result)))
1459         (setq result
1460               (substring result 0 -1)))
1461       (kill-new result)
1462       (message "%s" result))))
1463
1464 ;;;###autoload
1465 (defun ibuffer-copy-buffername-as-kill ()
1466   "Copy buffer names of marked buffers into the kill ring.
1467 The names are separated by a space.
1468 You can then feed the file name(s) to other commands with \\[yank]."
1469   (interactive)
1470   (if (zerop (ibuffer-count-marked-lines))
1471       (message "No buffers marked; use 'm' to mark a buffer")
1472     (let ((res ""))
1473       (ibuffer-map-marked-lines
1474        #'(lambda (buf _mark)
1475            (setq res (concat res (buffer-name buf) " "))))
1476       (when (not (zerop (length res)))
1477         (setq res (substring res 0 -1)))
1478       (kill-new res)
1479       (message res))))
1480
1481 (defun ibuffer-mark-on-buffer (func &optional ibuffer-mark-on-buffer-mark group)
1482   (let ((count
1483          (ibuffer-map-lines
1484           #'(lambda (buf _mark)
1485               (when (funcall func buf)
1486                 (ibuffer-set-mark-1 (or ibuffer-mark-on-buffer-mark
1487                                         ibuffer-marked-char))
1488                 t))
1489           nil
1490           group)))
1491     (ibuffer-redisplay t)
1492     (unless (eq ibuffer-mark-on-buffer-mark ?\s)
1493       (message "Marked %s buffers" count))))
1494
1495 ;;;###autoload
1496 (defun ibuffer-mark-by-name-regexp (regexp)
1497   "Mark all buffers whose name matches REGEXP."
1498   (interactive "sMark by name (regexp): ")
1499   (ibuffer-mark-on-buffer
1500    #'(lambda (buf)
1501        (string-match regexp (buffer-name buf)))))
1502
1503 (defun ibuffer-locked-buffer-p (&optional buf)
1504   "Return non-nil if BUF is locked.
1505 When BUF nil, default to the buffer at current line."
1506   (let ((cbuffer (or buf (ibuffer-current-buffer))))
1507     (when cbuffer
1508       (with-current-buffer cbuffer
1509         (and (boundp 'emacs-lock-mode) emacs-lock-mode)))))
1510
1511 ;;;###autoload
1512 (defun ibuffer-mark-by-locked ()
1513   "Mark all locked buffers."
1514   (interactive)
1515   (when (featurep 'emacs-lock)
1516     (ibuffer-mark-on-buffer
1517      (lambda (buf)
1518        (ibuffer-locked-buffer-p buf)))))
1519
1520 ;;;###autoload
1521 (defun ibuffer-mark-by-mode-regexp (regexp)
1522   "Mark all buffers whose major mode matches REGEXP."
1523   (interactive "sMark by major mode (regexp): ")
1524   (ibuffer-mark-on-buffer
1525    #'(lambda (buf)
1526        (with-current-buffer buf
1527          (string-match regexp (format-mode-line mode-name nil nil buf))))))
1528
1529 ;;;###autoload
1530 (defun ibuffer-mark-by-file-name-regexp (regexp)
1531   "Mark all buffers whose file name matches REGEXP."
1532   (interactive "sMark by file name (regexp): ")
1533   (ibuffer-mark-on-buffer
1534    #'(lambda (buf)
1535        (let ((name (or (buffer-file-name buf)
1536                        (with-current-buffer buf
1537                          (and
1538                           (boundp 'dired-directory)
1539                           (stringp dired-directory)
1540                           dired-directory)))))
1541          (when name
1542            (string-match regexp name))))))
1543
1544 ;;;###autoload
1545 (defun ibuffer-mark-by-content-regexp (regexp &optional all-buffers)
1546   "Mark all buffers whose content matches REGEXP.
1547 Optional arg ALL-BUFFERS, if non-nil, then search in all buffers.
1548 Otherwise buffers whose name matches an element of
1549 `ibuffer-never-search-content-name' or whose major mode is on
1550 `ibuffer-never-search-content-mode' are excluded."
1551   (interactive (let ((reg (read-string "Mark by content (regexp): ")))
1552                  (list reg current-prefix-arg)))
1553   (ibuffer-mark-on-buffer
1554    #'(lambda (buf)
1555        (let ((mode (with-current-buffer buf major-mode))
1556              res)
1557          (cond ((and (not all-buffers)
1558                      (or
1559                       (memq mode ibuffer-never-search-content-mode)
1560                       (cl-some (lambda (x) (string-match x (buffer-name buf)))
1561                                ibuffer-never-search-content-name)))
1562                 (setq res nil))
1563                (t
1564                 (with-current-buffer buf
1565                   (save-mark-and-excursion
1566                    (goto-char (point-min))
1567                    (setq res (re-search-forward regexp nil t)))))) res))))
1568
1569 ;;;###autoload
1570 (defun ibuffer-mark-by-mode (mode)
1571   "Mark all buffers whose major mode equals MODE."
1572   (interactive
1573    (let* ((buf (ibuffer-current-buffer))
1574           (default (if (and buf (buffer-live-p buf))
1575                        (symbol-name (buffer-local-value
1576                                      'major-mode buf)))))
1577      (list (intern
1578             (completing-read
1579              (if default
1580                  (format "Mark by major mode (default %s): " default)
1581                "Mark by major mode: ")
1582              (ibuffer-list-buffer-modes) nil t nil nil default)))))
1583   (ibuffer-mark-on-buffer
1584    #'(lambda (buf)
1585        (eq (buffer-local-value 'major-mode buf) mode))))
1586
1587 ;;;###autoload
1588 (defun ibuffer-mark-modified-buffers ()
1589   "Mark all modified buffers."
1590   (interactive)
1591   (ibuffer-mark-on-buffer
1592    #'(lambda (buf) (buffer-modified-p buf))))
1593
1594 ;;;###autoload
1595 (defun ibuffer-mark-unsaved-buffers ()
1596   "Mark all modified buffers that have an associated file."
1597   (interactive)
1598   (ibuffer-mark-on-buffer
1599    #'(lambda (buf) (and (buffer-local-value 'buffer-file-name buf)
1600                         (buffer-modified-p buf)))))
1601
1602 ;;;###autoload
1603 (defun ibuffer-mark-dissociated-buffers ()
1604   "Mark all buffers whose associated file does not exist."
1605   (interactive)
1606   (ibuffer-mark-on-buffer
1607    #'(lambda (buf)
1608        (with-current-buffer buf
1609          (or
1610           (and buffer-file-name
1611                (not (file-exists-p buffer-file-name)))
1612           (and (eq major-mode 'dired-mode)
1613                (boundp 'dired-directory)
1614                (stringp dired-directory)
1615                (not (file-exists-p (file-name-directory dired-directory)))))))))
1616
1617 ;;;###autoload
1618 (defun ibuffer-mark-help-buffers ()
1619   "Mark buffers whose major mode is in variable `ibuffer-help-buffer-modes'."
1620   (interactive)
1621   (ibuffer-mark-on-buffer
1622    #'(lambda (buf)
1623        (with-current-buffer buf
1624          (memq major-mode ibuffer-help-buffer-modes)))))
1625
1626 ;;;###autoload
1627 (defun ibuffer-mark-compressed-file-buffers ()
1628   "Mark buffers whose associated file is compressed."
1629   (interactive)
1630   (ibuffer-mark-on-buffer
1631    #'(lambda (buf)
1632        (with-current-buffer buf
1633          (and buffer-file-name
1634               (string-match ibuffer-compressed-file-name-regexp
1635                            buffer-file-name))))))
1636
1637 ;;;###autoload
1638 (defun ibuffer-mark-old-buffers ()
1639   "Mark buffers which have not been viewed in `ibuffer-old-time' hours."
1640   (interactive)
1641   (ibuffer-mark-on-buffer
1642    #'(lambda (buf)
1643        (with-current-buffer buf
1644          ;; hacked from midnight.el
1645          (when buffer-display-time
1646            (let* ((now (float-time))
1647                   (then (float-time buffer-display-time)))
1648              (> (- now then) (* 60 60 ibuffer-old-time))))))))
1649
1650 ;;;###autoload
1651 (defun ibuffer-mark-special-buffers ()
1652   "Mark all buffers whose name begins and ends with `*'."
1653   (interactive)
1654   (ibuffer-mark-on-buffer
1655    #'(lambda (buf) (string-match "^\\*.+\\*$"
1656                                  (buffer-name buf)))))
1657
1658 ;;;###autoload
1659 (defun ibuffer-mark-read-only-buffers ()
1660   "Mark all read-only buffers."
1661   (interactive)
1662   (ibuffer-mark-on-buffer
1663    #'(lambda (buf) (buffer-local-value 'buffer-read-only buf))))
1664
1665 ;;;###autoload
1666 (defun ibuffer-mark-dired-buffers ()
1667   "Mark all `dired' buffers."
1668   (interactive)
1669   (ibuffer-mark-on-buffer
1670    #'(lambda (buf) (eq (buffer-local-value 'major-mode buf) 'dired-mode))))
1671
1672 ;;;###autoload
1673 (defun ibuffer-do-occur (regexp &optional nlines)
1674   "View lines which match REGEXP in all marked buffers.
1675 Optional argument NLINES says how many lines of context to display: it
1676 defaults to one."
1677   (interactive (occur-read-primary-args))
1678   (if (or (not (integerp nlines))
1679           (< nlines 0))
1680       (setq nlines 0))
1681   (when (zerop (ibuffer-count-marked-lines))
1682     (ibuffer-set-mark ibuffer-marked-char))
1683   (let ((ibuffer-do-occur-bufs nil))
1684     ;; Accumulate a list of marked buffers
1685     (ibuffer-map-marked-lines
1686      #'(lambda (buf _mark)
1687          (push buf ibuffer-do-occur-bufs)))
1688     (occur-1 regexp nlines ibuffer-do-occur-bufs)))
1689
1690 (provide 'ibuf-ext)
1691
1692 ;; Local Variables:
1693 ;; generated-autoload-file: "ibuffer-loaddefs.el"
1694 ;; End:
1695
1696 ;;; ibuf-ext.el ends here