lisp/gnus/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;; Keywords: news, mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'gnus-start)
  36 (require 'nnoo)
  37 (eval-when-compile (require 'cl))
  38
  39 (nnoo-declare nnmh)
  40
  41 (defvoo nnmh-directory message-directory
  42   "Mail spool directory.")
  43
  44 (defvoo nnmh-get-new-mail t
  45   "If non-nil, nnmh will check the incoming mail file and split the mail.")
  46
  47 (defvoo nnmh-prepare-save-mail-hook nil
  48   "Hook run narrowed to an article before saving.")
  49
  50 (defvoo nnmh-be-safe nil
  51   "If non-nil, nnmh will check all articles to make sure whether they are new or not.
  52 Go through the .nnmh-articles file and compare with the actual
  53 articles in this folder.  The articles that are \"new\" will be marked
  54 as unread by Gnus.")
  55
  56 \f
  57
  58 (defconst nnmh-version "nnmh 1.0"
  59   "nnmh version.")
  60
  61 (defvoo nnmh-current-directory nil
  62   "Current news group directory.")
  63
  64 (defvoo nnmh-status-string "")
  65 (defvoo nnmh-group-alist nil)
  66 ;; Don't even think about setting this variable.  It does not exist.
  67 ;; Forget about it.  Uh-huh.  Nope.  Nobody here.  It's only bound
  68 ;; dynamically by certain functions in nndraft.
  69 (defvar nnmh-allow-delete-final nil)
  70
  71 \f
  72
  73 ;;; Interface functions.
  74
  75 (nnoo-define-basics nnmh)
  76
  77 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  78   (with-current-buffer nntp-server-buffer
  79     (erase-buffer)
  80     (let* ((file nil)
  81            (number (length articles))
  82            (large (and (numberp nnmail-large-newsgroup)
  83                        (> number nnmail-large-newsgroup)))
  84            (count 0)
  85            (file-name-coding-system nnmail-pathname-coding-system)
  86            beg article)
  87       (nnmh-possibly-change-directory newsgroup server)
  88       ;; We don't support fetching by Message-ID.
  89       (if (stringp (car articles))
  90           'headers
  91         (while articles
  92           (when (and (file-exists-p
  93                       (setq file (concat (file-name-as-directory
  94                                           nnmh-current-directory)
  95                                          (int-to-string
  96                                           (setq article (pop articles))))))
  97                      (not (file-directory-p file)))
  98             (insert (format "221 %d Article retrieved.\n" article))
  99             (setq beg (point))
 100             (nnheader-insert-head file)
 101             (goto-char beg)
 102             (if (search-forward "\n\n" nil t)
 103                 (forward-char -1)
 104               (goto-char (point-max))
 105               (insert "\n\n"))
 106             (insert ".\n")
 107             (delete-region (point) (point-max)))
 108           (setq count (1+ count))
 109
 110           (and large
 111                (zerop (% count 20))
 112                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 113                                  (/ (* count 100) number))))
 114
 115         (when large
 116           (nnheader-message 5 "nnmh: Receiving headers...done"))
 117
 118         (nnheader-fold-continuation-lines)
 119         'headers))))
 120
 121 (deffoo nnmh-open-server (server &optional defs)
 122   (nnoo-change-server 'nnmh server defs)
 123   (when (not (file-exists-p nnmh-directory))
 124     (condition-case ()
 125         (make-directory nnmh-directory t)
 126       (error t)))
 127   (cond
 128    ((not (file-exists-p nnmh-directory))
 129     (nnmh-close-server)
 130     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 131    ((not (file-directory-p (file-truename nnmh-directory)))
 132     (nnmh-close-server)
 133     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 134    (t
 135     (nnheader-report 'nnmh "Opened server %s using directory %s"
 136                      server nnmh-directory)
 137     t)))
 138
 139 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 140   (nnmh-possibly-change-directory newsgroup server)
 141   (let ((file (if (stringp id)
 142                   nil
 143                 (concat nnmh-current-directory (int-to-string id))))
 144         (file-name-coding-system nnmail-pathname-coding-system)
 145         (nntp-server-buffer (or buffer nntp-server-buffer)))
 146     (and (stringp file)
 147          (file-exists-p file)
 148          (not (file-directory-p file))
 149          (save-excursion (nnmail-find-file file))
 150          (string-to-number (file-name-nondirectory file)))))
 151
 152 (deffoo nnmh-request-group (group &optional server dont-check)
 153   (nnheader-init-server-buffer)
 154   (nnmh-possibly-change-directory group server)
 155   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 156         (file-name-coding-system nnmail-pathname-coding-system)
 157         dir)
 158     (cond
 159      ((not (file-directory-p pathname))
 160       (nnheader-report
 161        'nnmh "Can't select group (no such directory): %s" group))
 162      (t
 163       (setq nnmh-current-directory pathname)
 164       (and nnmh-get-new-mail
 165            nnmh-be-safe
 166            (nnmh-update-gnus-unreads group))
 167       (cond
 168        (dont-check
 169         (nnheader-report 'nnmh "Selected group %s" group)
 170         t)
 171        (t
 172         ;; Re-scan the directory if it's on a foreign system.
 173         (nnheader-re-read-dir pathname)
 174         (setq dir
 175               (sort
 176                (mapcar 'string-to-number
 177                        (directory-files pathname nil "^[0-9]+$" t))
 178                '<))
 179         (cond
 180          (dir
 181           (setq nnmh-group-alist
 182                 (delq (assoc group nnmh-group-alist) nnmh-group-alist))
 183           (push (list group (cons (car dir) (car (last dir))))
 184                 nnmh-group-alist)
 185           (nnheader-report 'nnmh "Selected group %s" group)
 186           (nnheader-insert
 187            "211 %d %d %d %s\n" (length dir) (car dir)
 188            (car (last dir)) group))
 189          (t
 190           (nnheader-report 'nnmh "Empty group %s" group)
 191           (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 192
 193 (deffoo nnmh-request-scan (&optional group server)
 194   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 195
 196 (deffoo nnmh-request-list (&optional server dir)
 197   (nnheader-insert "")
 198   (nnmh-possibly-change-directory nil server)
 199   (let ((file-name-coding-system nnmail-pathname-coding-system)
 200         (nnmh-toplev
 201          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 202     (nnmh-request-list-1 nnmh-toplev))
 203   (setq nnmh-group-alist (nnmail-get-active))
 204   t)
 205
 206 (defvar nnmh-toplev)
 207 (defun nnmh-request-list-1 (dir)
 208   (setq dir (expand-file-name dir))
 209   ;; Recurse down all directories.
 210   (let ((dirs (and (file-readable-p dir)
 211                    (nnheader-directory-files dir t nil t)))
 212         rdir)
 213     ;; Recurse down directories.
 214     (while (setq rdir (pop dirs))
 215       (when (and (file-directory-p rdir)
 216                  (file-readable-p rdir)
 217                  (not (equal (file-truename rdir)
 218                              (file-truename dir))))
 219         (nnmh-request-list-1 rdir))))
 220   ;; For each directory, generate an active file line.
 221   (unless (string= (expand-file-name nnmh-toplev) dir)
 222     (let ((files (mapcar 'string-to-number
 223                          (directory-files dir nil "^[0-9]+$" t))))
 224       (when files
 225         (with-current-buffer nntp-server-buffer
 226           (goto-char (point-max))
 227           (insert
 228            (format
 229             "%s %.0f %.0f y\n"
 230             (progn
 231               (string-match
 232                (regexp-quote
 233                 (file-truename (file-name-as-directory
 234                                 (expand-file-name nnmh-toplev))))
 235                dir)
 236               (mm-string-to-multibyte   ;Why?  Isn't it multibyte already?
 237                (mm-encode-coding-string
 238                 (nnheader-replace-chars-in-string
 239                  (substring dir (match-end 0))
 240                  ?/ ?.)
 241                 nnmail-pathname-coding-system)))
 242             (apply 'max files)
 243             (apply 'min files)))))))
 244   t)
 245
 246 (deffoo nnmh-request-newgroups (date &optional server)
 247   (nnmh-request-list server))
 248
 249 (deffoo nnmh-request-expire-articles (articles newsgroup
 250                                                &optional server force)
 251   (nnmh-possibly-change-directory newsgroup server)
 252   (let ((is-old t)
 253         (nnmail-expiry-target
 254          (or (gnus-group-find-parameter newsgroup 'expiry-target t)
 255              nnmail-expiry-target))
 256         article rest mod-time)
 257     (nnheader-init-server-buffer)
 258
 259     (while (and articles is-old)
 260       (setq article (concat nnmh-current-directory
 261                             (int-to-string (car articles))))
 262       (when (setq mod-time (nth 5 (file-attributes article)))
 263         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 264                  (setq is-old
 265                        (nnmail-expired-article-p newsgroup mod-time force)))
 266             (progn
 267               ;; Allow a special target group. -- jcn
 268               (unless (eq nnmail-expiry-target 'delete)
 269                 (with-temp-buffer
 270                   (nnmh-request-article (car articles)
 271                                         newsgroup server (current-buffer))
 272                   (nnmail-expiry-target-group
 273                    nnmail-expiry-target newsgroup)))
 274               (nnheader-message 5 "Deleting article %s in %s..."
 275                                 article newsgroup)
 276               (condition-case ()
 277                   (funcall nnmail-delete-file-function article)
 278                 (file-error
 279                  (nnheader-message 1 "Couldn't delete article %s in %s"
 280                                    article newsgroup)
 281                  (push (car articles) rest))))
 282           (push (car articles) rest)))
 283       (setq articles (cdr articles)))
 284     (nnheader-message 5 "")
 285     (nconc rest articles)))
 286
 287 (deffoo nnmh-close-group (group &optional server)
 288   t)
 289
 290 (deffoo nnmh-request-move-article (article group server accept-form
 291                                            &optional last move-is-internal)
 292   (let ((buf (get-buffer-create " *nnmh move*"))
 293         result)
 294     (and
 295      (nnmh-deletable-article-p group article)
 296      (nnmh-request-article article group server)
 297      (with-current-buffer buf
 298        (erase-buffer)
 299        (insert-buffer-substring nntp-server-buffer)
 300        (setq result (eval accept-form))
 301        (kill-buffer (current-buffer))
 302        result)
 303      (progn
 304        (nnmh-possibly-change-directory group server)
 305        (condition-case ()
 306            (funcall nnmail-delete-file-function
 307                     (concat nnmh-current-directory (int-to-string article)))
 308          (file-error nil))))
 309     result))
 310
 311 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 312   (nnmh-possibly-change-directory group server)
 313   (nnmail-check-syntax)
 314   (when nnmail-cache-accepted-message-ids
 315     (nnmail-cache-insert (nnmail-fetch-field "message-id")
 316                          group
 317                          (nnmail-fetch-field "subject")
 318                          (nnmail-fetch-field "from")))
 319   (nnheader-init-server-buffer)
 320   (prog1
 321       (if (stringp group)
 322           (if noinsert
 323               (nnmh-active-number group)
 324             (car (nnmh-save-mail
 325                   (list (cons group (nnmh-active-number group)))
 326                   noinsert)))
 327         (let ((res (nnmail-article-group 'nnmh-active-number)))
 328           (if (and (null res)
 329                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 330               'junk
 331             (car (nnmh-save-mail res noinsert)))))
 332     (when (and last nnmail-cache-accepted-message-ids)
 333       (nnmail-cache-close))))
 334
 335 (deffoo nnmh-request-replace-article (article group buffer)
 336   (nnmh-possibly-change-directory group)
 337   (with-current-buffer buffer
 338     (nnmh-possibly-create-directory group)
 339     (ignore-errors
 340       (nnmail-write-region
 341        (point-min) (point-max)
 342        (concat nnmh-current-directory (int-to-string article))
 343        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 344       t)))
 345
 346 (deffoo nnmh-request-create-group (group &optional server args)
 347   (nnheader-init-server-buffer)
 348   (unless (assoc group nnmh-group-alist)
 349     (let (active)
 350       (push (list group (setq active (cons 1 0)))
 351             nnmh-group-alist)
 352       (nnmh-possibly-create-directory group)
 353       (nnmh-possibly-change-directory group server)
 354       (let ((articles (mapcar 'string-to-number
 355                               (directory-files
 356                                nnmh-current-directory nil "^[0-9]+$"))))
 357         (when articles
 358           (setcar active (apply 'min articles))
 359           (setcdr active (apply 'max articles))))))
 360   t)
 361
 362 (deffoo nnmh-request-delete-group (group &optional force server)
 363   (nnmh-possibly-change-directory group server)
 364   ;; Delete all articles in GROUP.
 365   (if (not force)
 366       ()                                ; Don't delete the articles.
 367     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 368       (while articles
 369         (when (file-writable-p (car articles))
 370           (nnheader-message 5 "Deleting article %s in %s..."
 371                             (car articles) group)
 372           (funcall nnmail-delete-file-function (car articles)))
 373         (setq articles (cdr articles))))
 374     ;; Try to delete the directory itself.
 375     (ignore-errors
 376       (delete-directory nnmh-current-directory)))
 377   ;; Remove the group from all structures.
 378   (setq nnmh-group-alist
 379         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 380         nnmh-current-directory nil)
 381   t)
 382
 383 (deffoo nnmh-request-rename-group (group new-name &optional server)
 384   (nnmh-possibly-change-directory group server)
 385   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 386         (old-dir (nnmail-group-pathname group nnmh-directory)))
 387     (when (ignore-errors
 388             (make-directory new-dir t)
 389             t)
 390       ;; We move the articles file by file instead of renaming
 391       ;; the directory -- there may be subgroups in this group.
 392       ;; One might be more clever, I guess.
 393       (let ((files (nnheader-article-to-file-alist old-dir)))
 394         (while files
 395           (rename-file
 396            (concat old-dir (cdar files))
 397            (concat new-dir (cdar files)))
 398           (pop files)))
 399       (when (<= (length (directory-files old-dir)) 2)
 400         (ignore-errors
 401           (delete-directory old-dir)))
 402       ;; That went ok, so we change the internal structures.
 403       (let ((entry (assoc group nnmh-group-alist)))
 404         (when entry
 405           (setcar entry new-name))
 406         (setq nnmh-current-directory nil)
 407         t))))
 408
 409 (nnoo-define-skeleton nnmh)
 410
 411 \f
 412 ;;; Internal functions.
 413
 414 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 415   (when (and server
 416              (not (nnmh-server-opened server)))
 417     (nnmh-open-server server))
 418   (when newsgroup
 419     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 420           (file-name-coding-system nnmail-pathname-coding-system))
 421       (if (file-directory-p pathname)
 422           (setq nnmh-current-directory pathname)
 423         (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory)))))
 424
 425 (defun nnmh-possibly-create-directory (group)
 426   (let (dir dirs)
 427     (setq dir (nnmail-group-pathname group nnmh-directory))
 428     (while (not (file-directory-p dir))
 429       (push dir dirs)
 430       (setq dir (file-name-directory (directory-file-name dir))))
 431     (while dirs
 432       (when (make-directory (directory-file-name (car dirs)))
 433         (error "Could not create directory %s" (car dirs)))
 434       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 435       (setq dirs (cdr dirs)))))
 436
 437 (defun nnmh-save-mail (group-art &optional noinsert)
 438   "Called narrowed to an article."
 439   (unless noinsert
 440     (nnmail-insert-lines)
 441     (nnmail-insert-xref group-art))
 442   (run-hooks 'nnmail-prepare-save-mail-hook)
 443   (run-hooks 'nnmh-prepare-save-mail-hook)
 444   (goto-char (point-min))
 445   (while (looking-at "From ")
 446     (replace-match "X-From-Line: ")
 447     (forward-line 1))
 448   ;; We save the article in all the newsgroups it belongs in.
 449   (let ((ga group-art)
 450         first)
 451     (while ga
 452       (nnmh-possibly-create-directory (caar ga))
 453       (let ((file (concat (nnmail-group-pathname
 454                            (caar ga) nnmh-directory)
 455                           (int-to-string (cdar ga)))))
 456         (if first
 457             ;; It was already saved, so we just make a hard link.
 458             (funcall nnmail-crosspost-link-function first file t)
 459           ;; Save the article.
 460           (nnmail-write-region (point-min) (point-max) file nil nil)
 461           (setq first file)))
 462       (setq ga (cdr ga))))
 463   group-art)
 464
 465 (defun nnmh-active-number (group)
 466   "Compute the next article number in GROUP."
 467   (let ((active (cadr (assoc group nnmh-group-alist)))
 468         (dir (nnmail-group-pathname group nnmh-directory))
 469         (file-name-coding-system nnmail-pathname-coding-system)
 470         file)
 471     (unless active
 472       ;; The group wasn't known to nnmh, so we just create an active
 473       ;; entry for it.
 474       (setq active (cons 1 0))
 475       (push (list group active) nnmh-group-alist)
 476       (unless (file-exists-p dir)
 477         (gnus-make-directory dir))
 478       ;; Find the highest number in the group.
 479       (let ((files (sort
 480                     (mapcar 'string-to-number
 481                             (directory-files dir nil "^[0-9]+$"))
 482                     '>)))
 483         (when files
 484           (setcdr active (car files)))))
 485     (setcdr active (1+ (cdr active)))
 486     (while (or
 487             ;; See whether the file exists...
 488             (file-exists-p
 489              (setq file (concat (nnmail-group-pathname group nnmh-directory)
 490                                 (int-to-string (cdr active)))))
 491             ;; ... or there is a buffer that will make that file exist
 492             ;; in the future.
 493             (get-file-buffer file))
 494       ;; Skip past that file.
 495       (setcdr active (1+ (cdr active))))
 496     (cdr active)))
 497
 498 (defun nnmh-update-gnus-unreads (group)
 499   ;; Go through the .nnmh-articles file and compare with the actual
 500   ;; articles in this folder.  The articles that are "new" will be
 501   ;; marked as unread by Gnus.
 502   (let* ((dir nnmh-current-directory)
 503          (files (sort (mapcar 'string-to-number
 504                               (directory-files nnmh-current-directory
 505                                                nil "^[0-9]+$" t))
 506                       '<))
 507          (nnmh-file (concat dir ".nnmh-articles"))
 508          new articles)
 509     ;; Load the .nnmh-articles file.
 510     (when (file-exists-p nnmh-file)
 511       (setq articles
 512             (let (nnmh-newsgroup-articles)
 513               (ignore-errors (load nnmh-file nil t t))
 514               nnmh-newsgroup-articles)))
 515     ;; Add all new articles to the `new' list.
 516     (let ((art files))
 517       (while art
 518         (unless (assq (car art) articles)
 519           (push (car art) new))
 520         (setq art (cdr art))))
 521     ;; Remove all deleted articles.
 522     (let ((art articles))
 523       (while art
 524         (unless (memq (caar art) files)
 525           (setq articles (delq (car art) articles)))
 526         (setq art (cdr art))))
 527     ;; Check whether the articles really are the ones that Gnus thinks
 528     ;; they are by looking at the time-stamps.
 529     (let ((arts articles)
 530           art)
 531       (while (setq art (pop arts))
 532         (when (not (equal
 533                     (nth 5 (file-attributes
 534                             (concat dir (int-to-string (car art)))))
 535                     (cdr art)))
 536           (setq articles (delq art articles))
 537           (push (car art) new))))
 538     ;; Go through all the new articles and add them, and their
 539     ;; time-stamps, to the list.
 540     (setq articles
 541           (nconc articles
 542                  (mapcar
 543                   (lambda (art)
 544                     (cons art
 545                           (nth 5 (file-attributes
 546                                   (concat dir (int-to-string art))))))
 547                   new)))
 548     ;; Make Gnus mark all new articles as unread.
 549     (when new
 550       (gnus-make-articles-unread
 551        (gnus-group-prefixed-name group (list 'nnmh ""))
 552        (setq new (sort new '<))))
 553     ;; Sort the article list with highest numbers first.
 554     (setq articles (sort articles (lambda (art1 art2)
 555                                     (> (car art1) (car art2)))))
 556     ;; Finally write this list back to the .nnmh-articles file.
 557     (with-temp-file nnmh-file
 558       (insert ";; Gnus article active file for " group "\n\n")
 559       (insert "(setq nnmh-newsgroup-articles '")
 560       (gnus-prin1 articles)
 561       (insert ")\n"))))
 562
 563 (defun nnmh-deletable-article-p (group article)
 564   "Say whether ARTICLE in GROUP can be deleted."
 565   (let ((path (concat nnmh-current-directory (int-to-string article))))
 566     ;; Writable.
 567     (and (file-writable-p path)
 568          (or
 569           ;; We can never delete the last article in the group.
 570           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 571                    article))
 572           ;; Well, we can.
 573           nnmh-allow-delete-final))))
 574
 575 (provide 'nnmh)
 576
 577 ;; arch-tag: 36c12a98-3bad-44b3-9953-628078ef0e04
 578 ;;; nnmh.el ends here