lisp/complete.el

   1 ;;; complete.el --- partial completion mechanism plus other goodies
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Dave Gillespie <daveg@synaptics.com>
   7 ;; Keywords: abbrev convenience
   8 ;; Special thanks to Hallvard Furuseth for his many ideas and contributions.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Extended completion for the Emacs minibuffer.
  30 ;;
  31 ;; The basic idea is that the command name or other completable text is
  32 ;; divided into words and each word is completed separately, so that
  33 ;; "M-x p-b" expands to "M-x print-buffer".  If the entry is ambiguous
  34 ;; each word is completed as much as possible and then the cursor is
  35 ;; left at the first position where typing another letter will resolve
  36 ;; the ambiguity.
  37 ;;
  38 ;; Word separators for this purpose are hyphen, space, and period.
  39 ;; These would most likely occur in command names, Info menu items,
  40 ;; and file names, respectively.  But all word separators are treated
  41 ;; alike at all times.
  42 ;;
  43 ;; This completion package replaces the old-style completer's key
  44 ;; bindings for TAB, SPC, RET, and `?'.  The old completer is still
  45 ;; available on the Meta versions of those keys.  If you set
  46 ;; PC-meta-flag to nil, the old completion keys will be left alone
  47 ;; and the partial completer will use the Meta versions of the keys.
  48
  49
  50 ;; Usage:  M-x partial-completion-mode.  During completable minibuffer entry,
  51 ;;
  52 ;;     TAB    means to do a partial completion;
  53 ;;     SPC    means to do a partial complete-word;
  54 ;;     RET    means to do a partial complete-and-exit;
  55 ;;     ?      means to do a partial completion-help.
  56 ;;
  57 ;; If you set PC-meta-flag to nil, then TAB, SPC, RET, and ? perform
  58 ;; original Emacs completions, and M-TAB etc. do partial completion.
  59 ;; To do this, put the command,
  60 ;;
  61 ;;       (setq PC-meta-flag nil)
  62 ;;
  63 ;; in your .emacs file.  To load partial completion automatically, put
  64 ;;
  65 ;;       (partial-completion-mode t)
  66 ;;
  67 ;; in your .emacs file, too.  Things will be faster if you byte-compile
  68 ;; this file when you install it.
  69 ;;
  70 ;; As an extra feature, in cases where RET would not normally
  71 ;; complete (such as `C-x b'), the M-RET key will always do a partial
  72 ;; complete-and-exit.  Thus `C-x b f.c RET' will select or create a
  73 ;; buffer called "f.c", but `C-x b f.c M-RET' will select the existing
  74 ;; buffer whose name matches that pattern (perhaps "filing.c").
  75 ;; (PC-meta-flag does not affect this behavior; M-RET used to be
  76 ;; undefined in this situation.)
  77 ;;
  78 ;; The regular M-TAB (lisp-complete-symbol) command also supports
  79 ;; partial completion in this package.
  80
  81 ;; In addition, this package includes a feature for accessing include
  82 ;; files.  For example, `C-x C-f <sys/time.h> RET' reads the file
  83 ;; /usr/include/sys/time.h.  The variable PC-include-file-path is a
  84 ;; list of directories in which to search for include files.  Completion
  85 ;; is supported in include file names.
  86
  87
  88 ;;; Code:
  89
  90 (defgroup partial-completion nil
  91   "Partial Completion of items."
  92   :prefix "pc-"
  93   :group 'minibuffer
  94   :group 'convenience)
  95
  96 (defcustom PC-first-char 'find-file
  97   "Control how the first character of a string is to be interpreted.
  98 If nil, the first character of a string is not taken literally if it is a word
  99 delimiter, so that \".e\" matches \"*.e*\".
 100 If t, the first character of a string is always taken literally even if it is a
 101 word delimiter, so that \".e\" matches \".e*\".
 102 If non-nil and non-t, the first character is taken literally only for file name
 103 completion."
 104   :type '(choice (const :tag "delimiter" nil)
 105                  (const :tag "literal" t)
 106                  (other :tag "find-file" find-file))
 107   :group 'partial-completion)
 108
 109 (defcustom PC-meta-flag t
 110   "If non-nil, TAB means PC completion and M-TAB means normal completion.
 111 Otherwise, TAB means normal completion and M-TAB means Partial Completion."
 112   :type 'boolean
 113   :group 'partial-completion)
 114
 115 (defcustom PC-word-delimiters "-_. "
 116   "A string of characters treated as word delimiters for completion.
 117 Some arcane rules:
 118 If `]' is in this string, it must come first.
 119 If `^' is in this string, it must not come first.
 120 If `-' is in this string, it must come first or right after `]'.
 121 In other words, if S is this string, then `[S]' must be a valid Emacs regular
 122 expression (not containing character ranges like `a-z')."
 123   :type 'string
 124   :group 'partial-completion)
 125
 126 (defcustom PC-include-file-path '("/usr/include" "/usr/local/include")
 127   "A list of directories in which to look for include files.
 128 If nil, means use the colon-separated path in the variable $INCPATH instead."
 129   :type '(repeat directory)
 130   :group 'partial-completion)
 131
 132 (defcustom PC-disable-includes nil
 133   "If non-nil, include-file support in \\[find-file] is disabled."
 134   :type 'boolean
 135   :group 'partial-completion)
 136
 137 (defvar PC-default-bindings t
 138   "If non-nil, default partial completion key bindings are suppressed.")
 139
 140 (defvar PC-env-vars-alist nil
 141   "A list of the environment variable names and values.")
 142
 143 \f
 144 (defun PC-bindings (bind)
 145   (let ((completion-map minibuffer-local-completion-map)
 146         (must-match-map minibuffer-local-must-match-map))
 147     (cond ((not bind)
 148            ;; These bindings are the default bindings.  It would be better to
 149            ;; restore the previous bindings.
 150            (define-key read-expression-map "\e\t" 'lisp-complete-symbol)
 151
 152            (define-key completion-map "\t"      'minibuffer-complete)
 153            (define-key completion-map " "       'minibuffer-complete-word)
 154            (define-key completion-map "?"       'minibuffer-completion-help)
 155
 156            (define-key must-match-map "\r"      'minibuffer-complete-and-exit)
 157            (define-key must-match-map "\n"      'minibuffer-complete-and-exit)
 158
 159            (define-key global-map [remap lisp-complete-symbol]  nil))
 160           (PC-default-bindings
 161            (define-key read-expression-map "\e\t" 'PC-lisp-complete-symbol)
 162
 163            (define-key completion-map "\t"      'PC-complete)
 164            (define-key completion-map " "       'PC-complete-word)
 165            (define-key completion-map "?"       'PC-completion-help)
 166
 167            (define-key completion-map "\e\t"    'PC-complete)
 168            (define-key completion-map "\e "     'PC-complete-word)
 169            (define-key completion-map "\e\r"    'PC-force-complete-and-exit)
 170            (define-key completion-map "\e\n"    'PC-force-complete-and-exit)
 171            (define-key completion-map "\e?"     'PC-completion-help)
 172
 173            (define-key must-match-map "\r"      'PC-complete-and-exit)
 174            (define-key must-match-map "\n"      'PC-complete-and-exit)
 175
 176            (define-key must-match-map "\e\r"    'PC-complete-and-exit)
 177            (define-key must-match-map "\e\n"    'PC-complete-and-exit)
 178
 179            (define-key global-map [remap lisp-complete-symbol]  'PC-lisp-complete-symbol)))))
 180
 181 (defvar PC-do-completion-end nil
 182   "Internal variable used by `PC-do-completion'.")
 183
 184 (make-variable-buffer-local 'PC-do-completion-end)
 185
 186 (defvar PC-goto-end nil
 187    "Internal variable set in `PC-do-completion', used in
 188 `choose-completion-string-functions'.")
 189
 190 (make-variable-buffer-local 'PC-goto-end)
 191
 192 ;;;###autoload
 193 (define-minor-mode partial-completion-mode
 194   "Toggle Partial Completion mode.
 195 With prefix ARG, turn Partial Completion mode on if ARG is positive.
 196
 197 When Partial Completion mode is enabled, TAB (or M-TAB if `PC-meta-flag' is
 198 nil) is enhanced so that if some string is divided into words and each word is
 199 delimited by a character in `PC-word-delimiters', partial words are completed
 200 as much as possible and `*' characters are treated likewise in file names.
 201
 202 For example, M-x p-c-m expands to M-x partial-completion-mode since no other
 203 command begins with that sequence of characters, and
 204 \\[find-file] f_b.c TAB might complete to foo_bar.c if that file existed and no
 205 other file in that directory begins with that sequence of characters.
 206
 207 Unless `PC-disable-includes' is non-nil, the `<...>' sequence is interpreted
 208 specially in \\[find-file].  For example,
 209 \\[find-file] <sys/time.h> RET finds the file `/usr/include/sys/time.h'.
 210 See also the variable `PC-include-file-path'.
 211
 212 Partial Completion mode extends the meaning of `completion-auto-help' (which
 213 see), so that if it is neither nil nor t, Emacs shows the `*Completions*'
 214 buffer only on the second attempt to complete.  That is, if TAB finds nothing
 215 to complete, the first TAB just says \"Next char not unique\" and the
 216 second TAB brings up the `*Completions*' buffer."
 217   :global t :group 'partial-completion
 218   ;; Deal with key bindings...
 219   (PC-bindings partial-completion-mode)
 220   ;; Deal with include file feature...
 221   (cond ((not partial-completion-mode)
 222          (remove-hook 'find-file-not-found-functions 'PC-look-for-include-file))
 223         ((not PC-disable-includes)
 224          (add-hook 'find-file-not-found-functions 'PC-look-for-include-file)))
 225   ;; Adjust the completion selection in *Completion* buffers to the way
 226   ;; we work.  The default minibuffer completion code only completes the
 227   ;; text before point and leaves the text after point alone (new in
 228   ;; Emacs-22).  In contrast we use the whole text and we even sometimes
 229   ;; move point to a place before EOB, to indicate the first position where
 230   ;; there's a difference, so when the user uses choose-completion, we have
 231   ;; to trick choose-completion into replacing the whole minibuffer text
 232   ;; rather than only the text before point.  --Stef
 233   (funcall
 234    (if partial-completion-mode 'add-hook 'remove-hook)
 235    'choose-completion-string-functions
 236    (lambda (choice buffer mini-p base-size)
 237      ;; When completing M-: (lisp- ) with point before the ), it is
 238      ;; not appropriate to go to point-max (unlike the filename case).
 239      (if (and (not PC-goto-end)
 240               mini-p)
 241          (goto-char (point-max))
 242        ;; Need a similar hack for the non-minibuffer-case -- gm.
 243        (when PC-do-completion-end
 244          (goto-char PC-do-completion-end)
 245          (setq PC-do-completion-end nil)))
 246      (setq PC-goto-end nil)
 247      nil))
 248   ;; Build the env-completion and mapping table.
 249   (when (and partial-completion-mode (null PC-env-vars-alist))
 250     (setq PC-env-vars-alist
 251           (mapcar (lambda (string)
 252                     (let ((d (string-match "=" string)))
 253                       (cons (concat "$" (substring string 0 d))
 254                             (and d (substring string (1+ d))))))
 255                   process-environment))))
 256
 257 \f
 258 (defun PC-complete ()
 259   "Like minibuffer-complete, but allows \"b--di\"-style abbreviations.
 260 For example, \"M-x b--di\" would match `byte-recompile-directory', or any
 261 name which consists of three or more words, the first beginning with \"b\"
 262 and the third beginning with \"di\".
 263
 264 The pattern \"b--d\" is ambiguous for `byte-recompile-directory' and
 265 `beginning-of-defun', so this would produce a list of completions
 266 just like when normal Emacs completions are ambiguous.
 267
 268 Word-delimiters for the purposes of Partial Completion are \"-\", \"_\",
 269 \".\", and SPC."
 270   (interactive)
 271   (if (PC-was-meta-key)
 272       (minibuffer-complete)
 273     ;; If the previous command was not this one,
 274     ;; never scroll, always retry completion.
 275     (or (eq last-command this-command)
 276         (setq minibuffer-scroll-window nil))
 277     (let ((window minibuffer-scroll-window))
 278       ;; If there's a fresh completion window with a live buffer,
 279       ;; and this command is repeated, scroll that window.
 280       (if (and window (window-buffer window)
 281                (buffer-name (window-buffer window)))
 282           (with-current-buffer (window-buffer window)
 283             (if (pos-visible-in-window-p (point-max) window)
 284                 (set-window-start window (point-min) nil)
 285               (scroll-other-window)))
 286         (PC-do-completion nil)))))
 287
 288
 289 (defun PC-complete-word ()
 290   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 291 See `PC-complete' for details.
 292 This can be bound to other keys, like `-' and `.', if you wish."
 293   (interactive)
 294   (if (eq (PC-was-meta-key) PC-meta-flag)
 295       (if (eq last-command-char ? )
 296           (minibuffer-complete-word)
 297         (self-insert-command 1))
 298     (self-insert-command 1)
 299     (if (eobp)
 300         (PC-do-completion 'word))))
 301
 302
 303 (defun PC-complete-space ()
 304   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 305 See `PC-complete' for details.
 306 This is suitable for binding to other keys which should act just like SPC."
 307   (interactive)
 308   (if (eq (PC-was-meta-key) PC-meta-flag)
 309       (minibuffer-complete-word)
 310     (insert " ")
 311     (if (eobp)
 312         (PC-do-completion 'word))))
 313
 314
 315 (defun PC-complete-and-exit ()
 316   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 317 See `PC-complete' for details."
 318   (interactive)
 319   (if (eq (PC-was-meta-key) PC-meta-flag)
 320       (minibuffer-complete-and-exit)
 321     (PC-do-complete-and-exit)))
 322
 323 (defun PC-force-complete-and-exit ()
 324   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 325 See `PC-complete' for details."
 326   (interactive)
 327   (let ((minibuffer-completion-confirm nil))
 328     (PC-do-complete-and-exit)))
 329
 330 (defun PC-do-complete-and-exit ()
 331   (cond
 332    ((= (point-max) (minibuffer-prompt-end))
 333     ;; Duplicate the "bug" that Info-menu relies on...
 334     (exit-minibuffer))
 335    ((eq minibuffer-completion-confirm 'confirm-only)
 336     (if (or (eq last-command this-command)
 337             (test-completion (field-string)
 338                              minibuffer-completion-table
 339                              minibuffer-completion-predicate))
 340         (exit-minibuffer)
 341       (PC-temp-minibuffer-message " [Confirm]")))
 342    (t
 343     (let ((flag (PC-do-completion 'exit)))
 344       (and flag
 345            (if (or (eq flag 'complete)
 346                    (not minibuffer-completion-confirm))
 347                (exit-minibuffer)
 348              (PC-temp-minibuffer-message " [Confirm]")))))))
 349
 350
 351 (defun PC-completion-help ()
 352   "Like `minibuffer-completion-help', but allows \"b--di\"-style abbreviations.
 353 See `PC-complete' for details."
 354   (interactive)
 355   (if (eq (PC-was-meta-key) PC-meta-flag)
 356       (minibuffer-completion-help)
 357     (PC-do-completion 'help)))
 358
 359 (defun PC-was-meta-key ()
 360   (or (/= (length (this-command-keys)) 1)
 361       (let ((key (aref (this-command-keys) 0)))
 362         (if (integerp key)
 363             (>= key 128)
 364           (not (null (memq 'meta (event-modifiers key))))))))
 365
 366
 367 (defvar PC-ignored-extensions 'empty-cache)
 368 (defvar PC-delims 'empty-cache)
 369 (defvar PC-ignored-regexp nil)
 370 (defvar PC-word-failed-flag nil)
 371 (defvar PC-delim-regex nil)
 372 (defvar PC-ndelims-regex nil)
 373 (defvar PC-delims-list nil)
 374
 375 (defvar PC-completion-as-file-name-predicate
 376   (lambda () minibuffer-completing-file-name)
 377   "A function testing whether a minibuffer completion now will work filename-style.
 378 The function takes no arguments, and typically looks at the value
 379 of `minibuffer-completion-table' and the minibuffer contents.")
 380
 381 ;; Returns the sequence of non-delimiter characters that follow regexp in string.
 382 (defun PC-chunk-after (string regexp)
 383   (if (not (string-match regexp string))
 384       (let ((message "String %s didn't match regexp %s"))
 385         (message message string regexp)
 386         (error message string regexp)))
 387   (let ((result (substring string (match-end 0))))
 388     ;; result may contain multiple chunks
 389     (if (string-match PC-delim-regex result)
 390         (setq result (substring result 0 (match-beginning 0))))
 391     result))
 392
 393 (defun test-completion-ignore-case (str table pred)
 394   "Like `test-completion', but ignores case when possible."
 395   ;; Binding completion-ignore-case to nil ensures, for compatibility with
 396   ;; standard completion, that the return value is exactly one of the
 397   ;; possibilities.  Do this binding only if pred is nil, out of paranoia;
 398   ;; perhaps it is safe even if pred is non-nil.
 399   (if pred
 400       (test-completion str table pred)
 401     (let ((completion-ignore-case nil))
 402       (test-completion str table pred))))
 403
 404 ;; The following function is an attempt to work around two problems:
 405
 406 ;; (1) When complete.el was written, (try-completion "" '(("") (""))) used to
 407 ;; return the value "".  With a change from 2002-07-07 it returns t which caused
 408 ;; `PC-lisp-complete-symbol' to fail with a "Wrong type argument: sequencep, t"
 409 ;; error.  `PC-try-completion' returns STRING in this case.
 410
 411 ;; (2) (try-completion "" '((""))) returned t before the above-mentioned change.
 412 ;; Since `PC-chop-word' operates on the return value of `try-completion' this
 413 ;; case might have provoked a similar error as in (1).  `PC-try-completion'
 414 ;; returns "" instead.  I don't know whether this is a real problem though.
 415
 416 ;; Since `PC-try-completion' is not a guaranteed to fix these bugs reliably, you
 417 ;; should try to look at the following discussions when you encounter problems:
 418 ;; - emacs-pretest-bug ("Partial Completion" starting 2007-02-23),
 419 ;; - emacs-devel ("[address-of-OP: Partial completion]" starting 2007-02-24),
 420 ;; - emacs-devel ("[address-of-OP: EVAL and mouse selection in *Completions*]"
 421 ;;   starting 2007-03-05).
 422 (defun PC-try-completion (string alist &optional predicate)
 423   "Like `try-completion' but return STRING instead of t."
 424   (let ((result (try-completion string alist predicate)))
 425     (if (eq result t) string result)))
 426
 427 ;; TODO document MODE magic...
 428 (defun PC-do-completion (&optional mode beg end goto-end)
 429   "Internal function to do the work of partial completion.
 430 Text to be completed lies between BEG and END.  Normally when
 431 replacing text in the minibuffer, this function replaces up to
 432 point-max (as is appropriate for completing a file name).  If
 433 GOTO-END is non-nil, however, it instead replaces up to END."
 434   (or beg (setq beg (minibuffer-prompt-end)))
 435   (or end (setq end (point-max)))
 436   (let* ((table (if (eq minibuffer-completion-table 'read-file-name-internal)
 437                     'PC-read-file-name-internal
 438                     minibuffer-completion-table))
 439          (pred minibuffer-completion-predicate)
 440          (filename (funcall PC-completion-as-file-name-predicate))
 441          (dirname nil) ; non-nil only if a filename is being completed
 442          ;; The following used to be "(dirlength 0)" which caused the erasure of
 443          ;; the entire buffer text before `point' when inserting a completion
 444          ;; into a buffer.
 445          dirlength
 446          (str (buffer-substring beg end))
 447          (incname (and filename (string-match "<\\([^\"<>]*\\)>?$" str)))
 448          (ambig nil)
 449          basestr origstr
 450          env-on
 451          regex
 452          p offset
 453          abbreviated
 454          (poss nil)
 455          helpposs
 456          (case-fold-search completion-ignore-case))
 457
 458     ;; Check if buffer contents can already be considered complete
 459     (if (and (eq mode 'exit)
 460              (test-completion str table pred))
 461         (progn
 462           ;; If completion-ignore-case is non-nil, insert the
 463           ;; completion string since that may have a different case.
 464           (when completion-ignore-case
 465             (setq str (PC-try-completion str table pred))
 466             (delete-region beg end)
 467             (insert str))
 468           'complete)
 469
 470       ;; Do substitutions in directory names
 471       (and filename
 472            (setq basestr (or (file-name-directory str) ""))
 473            (setq dirlength (length basestr))
 474            ;; Do substitutions in directory names
 475            (setq p (substitute-in-file-name basestr))
 476            (not (string-equal basestr p))
 477            (setq str (concat p (file-name-nondirectory str)))
 478            (progn
 479              (delete-region beg end)
 480              (insert str)
 481              (setq end (+ beg (length str)))))
 482
 483       ;; Prepare various delimiter strings
 484       (or (equal PC-word-delimiters PC-delims)
 485           (setq PC-delims PC-word-delimiters
 486                 PC-delim-regex (concat "[" PC-delims "]")
 487                 PC-ndelims-regex (concat "[^" PC-delims "]*")
 488                 PC-delims-list (append PC-delims nil)))
 489
 490       ;; Add wildcards if necessary
 491       (and filename
 492            (let ((dir (file-name-directory str))
 493                  (file (file-name-nondirectory str))
 494                  ;; The base dir for file-completion is passed in `predicate'.
 495                  (default-directory (expand-file-name pred)))
 496              (while (and (stringp dir) (not (file-directory-p dir)))
 497                (setq dir (directory-file-name dir))
 498                (setq file (concat (replace-regexp-in-string
 499                                    PC-delim-regex "*\\&"
 500                                    (file-name-nondirectory dir))
 501                                   "*/" file))
 502                (setq dir (file-name-directory dir)))
 503              (setq origstr str str (concat dir file))))
 504
 505       ;; Look for wildcard expansions in directory name
 506       (and filename
 507            (string-match "\\*.*/" str)
 508            (let ((pat str)
 509                  ;; The base dir for file-completion is passed in `predicate'.
 510                  (default-directory (expand-file-name pred))
 511                  files)
 512              (setq p (1+ (string-match "/[^/]*\\'" pat)))
 513              (while (setq p (string-match PC-delim-regex pat p))
 514                (setq pat (concat (substring pat 0 p)
 515                                  "*"
 516                                  (substring pat p))
 517                      p (+ p 2)))
 518              (setq files (file-expand-wildcards (concat pat "*")))
 519              (if files
 520                  (let ((dir (file-name-directory (car files)))
 521                        (p files))
 522                    (while (and (setq p (cdr p))
 523                                (equal dir (file-name-directory (car p)))))
 524                    (if p
 525                        (setq filename nil table nil pred nil
 526                              ambig t)
 527                      (delete-region beg end)
 528                      (setq str (concat dir (file-name-nondirectory str)))
 529                      (insert str)
 530                      (setq end (+ beg (length str)))))
 531                (if origstr
 532                        ;; If the wildcards were introduced by us, it's
 533                        ;; possible that PC-read-file-name-internal can
 534                        ;; still find matches for the original string
 535                        ;; even if we couldn't, so remove the added
 536                        ;; wildcards.
 537                    (setq str origstr)
 538                  (setq filename nil table nil pred nil)))))
 539
 540       ;; Strip directory name if appropriate
 541       (if filename
 542           (if incname
 543               (setq basestr (substring str incname)
 544                     dirname (substring str 0 incname))
 545             (setq basestr (file-name-nondirectory str)
 546                   dirname (file-name-directory str))
 547             ;; Make sure str is consistent with its directory and basename
 548             ;; parts.  This is important on DOZe'NT systems when str only
 549             ;; includes a drive letter, like in "d:".
 550             (setq str (concat dirname basestr)))
 551         (setq basestr str))
 552
 553       ;; Convert search pattern to a standard regular expression
 554       (setq regex (regexp-quote basestr)
 555             offset (if (and (> (length regex) 0)
 556                             (not (eq (aref basestr 0) ?\*))
 557                             (or (eq PC-first-char t)
 558                                 (and PC-first-char filename))) 1 0)
 559             p offset)
 560       (while (setq p (string-match PC-delim-regex regex p))
 561         (if (eq (aref regex p) ? )
 562             (setq regex (concat (substring regex 0 p)
 563                                 PC-ndelims-regex
 564                                 PC-delim-regex
 565                                 (substring regex (1+ p)))
 566                   p (+ p (length PC-ndelims-regex) (length PC-delim-regex)))
 567           (let ((bump (if (memq (aref regex p)
 568                                 '(?$ ?^ ?\. ?* ?+ ?? ?[ ?] ?\\))
 569                           -1 0)))
 570             (setq regex (concat (substring regex 0 (+ p bump))
 571                                 PC-ndelims-regex
 572                                 (substring regex (+ p bump)))
 573                   p (+ p (length PC-ndelims-regex) 1)))))
 574       (setq p 0)
 575       (if filename
 576           (while (setq p (string-match "\\\\\\*" regex p))
 577             (setq regex (concat (substring regex 0 p)
 578                                 "[^/]*"
 579                                 (substring regex (+ p 2))))))
 580       ;;(setq the-regex regex)
 581       (setq regex (concat "\\`" regex))
 582
 583       (and (> (length basestr) 0)
 584            (= (aref basestr 0) ?$)
 585            (setq env-on t
 586                  table PC-env-vars-alist
 587                  pred nil))
 588
 589       ;; Find an initial list of possible completions
 590         (unless (setq p (string-match (concat PC-delim-regex
 591                                              (if filename "\\|\\*" ""))
 592                                      str
 593                                       (+ (length dirname) offset)))
 594
 595           ;; Minibuffer contains no hyphens -- simple case!
 596           (setq poss (all-completions (if env-on basestr str)
 597                                       table
 598                                       pred))
 599           (unless (or poss (string-equal str ""))
 600             ;; Try completion as an abbreviation, e.g. "mvb" ->
 601             ;; "m-v-b" -> "multiple-value-bind", but only for
 602             ;; non-empty strings.
 603             (setq origstr str
 604                   abbreviated t)
 605             (if filename
 606                 (cond
 607                   ;; "alpha" or "/alpha" -> expand whole path.
 608                   ((string-match "^/?\\([A-Za-z0-9]+\\)$" str)
 609                    (setq
 610                     basestr ""
 611                     p nil
 612                     poss (file-expand-wildcards
 613                           (concat "/"
 614                                   (mapconcat #'list (match-string 1 str) "*/")
 615                                   "*"))
 616                     beg (1- beg)))
 617                   ;; Alphanumeric trailer -> expand trailing file
 618                   ((string-match "^\\(.+/\\)\\([A-Za-z0-9]+\\)$" str)
 619                    (setq regex (concat "\\`"
 620                                         (mapconcat #'list
 621                                                    (match-string 2 str)
 622                                                    "[A-Za-z0-9]*[^A-Za-z0-9]"))
 623                           p (1+ (length (match-string 1 str))))))
 624               (setq regex (concat "\\`" (mapconcat (lambda (c)
 625                                                      (regexp-quote (string c)))
 626                                                    str "[^-]*-"))
 627                     p 1))))
 628         (when p
 629         ;; Use all-completions to do an initial cull.  This is a big win,
 630         ;; since all-completions is written in C!
 631         (let ((compl (all-completions (if env-on
 632                                           (file-name-nondirectory (substring str 0 p))
 633                                         (substring str 0 p))
 634                                       table
 635                                       pred)))
 636           (setq p compl)
 637             (when (and compl abbreviated)
 638               (if filename
 639                   (progn
 640                     (setq p nil)
 641                     (dolist (x compl)
 642                       (when (string-match regex x)
 643                         (push x p)))
 644                     (setq basestr (try-completion "" p)))
 645                   (setq basestr (mapconcat 'list str "-"))
 646                   (delete-region beg end)
 647                   (setq end (+ beg (length basestr)))
 648                   (insert basestr))))
 649           (while p
 650             (and (string-match regex (car p))
 651                  (progn
 652                    (set-text-properties 0 (length (car p)) '() (car p))
 653                    (setq poss (cons (car p) poss))))
 654             (setq p (cdr p))))
 655
 656       ;; If table had duplicates, they can be here.
 657       (delete-dups poss)
 658
 659       ;; Handle completion-ignored-extensions
 660       (and filename
 661            (not (eq mode 'help))
 662            (let ((p2 poss))
 663
 664              ;; Build a regular expression representing the extensions list
 665              (or (equal completion-ignored-extensions PC-ignored-extensions)
 666                  (setq PC-ignored-regexp
 667                        (concat "\\("
 668                                (mapconcat
 669                                 'regexp-quote
 670                                 (setq PC-ignored-extensions
 671                                       completion-ignored-extensions)
 672                                 "\\|")
 673                                "\\)\\'")))
 674
 675              ;; Check if there are any without an ignored extension.
 676              ;; Also ignore `.' and `..'.
 677              (setq p nil)
 678              (while p2
 679                (or (string-match PC-ignored-regexp (car p2))
 680                    (string-match "\\(\\`\\|/\\)[.][.]?/?\\'" (car p2))
 681                    (setq p (cons (car p2) p)))
 682                (setq p2 (cdr p2)))
 683
 684              ;; If there are "good" names, use them
 685              (and p (setq poss p))))
 686
 687       ;; Now we have a list of possible completions
 688
 689       (cond
 690
 691        ;; No valid completions found
 692        ((null poss)
 693         (if (and (eq mode 'word)
 694                  (not PC-word-failed-flag))
 695             (let ((PC-word-failed-flag t))
 696               (delete-backward-char 1)
 697               (PC-do-completion 'word))
 698                (when abbreviated
 699                  (delete-region beg end)
 700                  (insert origstr))
 701           (beep)
 702           (PC-temp-minibuffer-message (if ambig
 703                                           " [Ambiguous dir name]"
 704                                         (if (eq mode 'help)
 705                                             " [No completions]"
 706                                           " [No match]")))
 707           nil))
 708
 709        ;; More than one valid completion found
 710        ((or (cdr (setq helpposs poss))
 711             (memq mode '(help word)))
 712
 713         ;; Is the actual string one of the possible completions?
 714         (setq p (and (not (eq mode 'help)) poss))
 715         (while (and p
 716                     (not (string-equal (car p) basestr)))
 717           (setq p (cdr p)))
 718         (and p (null mode)
 719              (PC-temp-minibuffer-message " [Complete, but not unique]"))
 720         (if (and p
 721                  (not (and (null mode)
 722                            (eq this-command last-command))))
 723             t
 724
 725           ;; If ambiguous, try for a partial completion
 726           (let ((improved nil)
 727                 prefix
 728                 (pt nil)
 729                 (skip "\\`"))
 730
 731             ;; Check if next few letters are the same in all cases
 732             (if (and (not (eq mode 'help))
 733                      (setq prefix (PC-try-completion
 734                                    (PC-chunk-after basestr skip) poss)))
 735                 (let ((first t) i)
 736                   ;; Retain capitalization of user input even if
 737                   ;; completion-ignore-case is set.
 738                   (if (eq mode 'word)
 739                       (setq prefix (PC-chop-word prefix basestr)))
 740                   (goto-char (+ beg (length dirname)))
 741                   (while (and (progn
 742                                 (setq i 0) ; index into prefix string
 743                                 (while (< i (length prefix))
 744                                   (if (and (< (point) end)
 745                                            (eq (downcase (aref prefix i))
 746                                                (downcase (following-char))))
 747                                       ;; same char (modulo case); no action
 748                                       (forward-char 1)
 749                                     (if (and (< (point) end)
 750                                              (and (looking-at " ")
 751                                                   (memq (aref prefix i)
 752                                                         PC-delims-list)))
 753                                         ;; replace " " by the actual delimiter
 754                                         (progn
 755                                           (delete-char 1)
 756                                           (insert (substring prefix i (1+ i))))
 757                                       ;; insert a new character
 758                                       (progn
 759                                         (and filename (looking-at "\\*")
 760                                              (progn
 761                                                (delete-char 1)
 762                                                (setq end (1- end))))
 763                                         (setq improved t)
 764                                         (insert (substring prefix i (1+ i)))
 765                                         (setq end (1+ end)))))
 766                                   (setq i (1+ i)))
 767                                 (or pt (setq pt (point)))
 768                                 (looking-at PC-delim-regex))
 769                               (setq skip (concat skip
 770                                                  (regexp-quote prefix)
 771                                                  PC-ndelims-regex)
 772                                     prefix (PC-try-completion
 773                                             (PC-chunk-after
 774                                              ;; not basestr, because that does
 775                                              ;; not reflect insertions
 776                                              (buffer-substring
 777                                               (+ beg (length dirname)) end)
 778                                              skip)
 779                                             (mapcar
 780                                              (lambda (x)
 781                                                (when (string-match skip x)
 782                                                  (substring x (match-end 0))))
 783                                              poss)))
 784                               (or (> i 0) (> (length prefix) 0))
 785                               (or (not (eq mode 'word))
 786                                   (and first (> (length prefix) 0)
 787                                        (setq first nil
 788                                              prefix (substring prefix 0 1))))))
 789                   (goto-char (if (eq mode 'word) end
 790                                (or pt beg)))))
 791
 792             (if (and (eq mode 'word)
 793                      (not PC-word-failed-flag))
 794
 795                 (if improved
 796
 797                     ;; We changed it... would it be complete without the space?
 798                     (if (test-completion (buffer-substring 1 (1- end))
 799                                          table pred)
 800                         (delete-region (1- end) end)))
 801
 802               (if improved
 803
 804                   ;; We changed it... enough to be complete?
 805                   (and (eq mode 'exit)
 806                        (test-completion-ignore-case (field-string) table pred))
 807
 808                 ;; If totally ambiguous, display a list of completions
 809                 (if (or (eq completion-auto-help t)
 810                         (and completion-auto-help
 811                              (eq last-command this-command))
 812                         (eq mode 'help))
 813                     (let ((prompt-end (minibuffer-prompt-end)))
 814                       (with-output-to-temp-buffer "*Completions*"
 815                         (display-completion-list (sort helpposs 'string-lessp))
 816                         (setq PC-do-completion-end end
 817                               PC-goto-end goto-end)
 818                         (with-current-buffer standard-output
 819                           ;; Record which part of the buffer we are completing
 820                           ;; so that choosing a completion from the list
 821                           ;; knows how much old text to replace.
 822                           ;; This was briefly nil in the non-dirname case.
 823                           ;; However, if one calls PC-lisp-complete-symbol
 824                           ;; on "(ne-f" with point on the hyphen, PC offers
 825                           ;; all completions starting with "(ne", some of
 826                           ;; which do not match the "-f" part (maybe it
 827                           ;; should not, but it does). In such cases,
 828                           ;; completion gets confused trying to figure out
 829                           ;; how much to replace, so we tell it explicitly
 830                           ;; (ie, the number of chars in the buffer before beg).
 831                           ;;
 832                           ;; Note that choose-completion-string-functions
 833                           ;; plays around with point.
 834                           (setq completion-base-size (if dirname
 835                                                          dirlength
 836                                                        (- beg prompt-end))))))
 837                              (PC-temp-minibuffer-message " [Next char not unique]"))
 838                          ;; Expansion of filenames is not reversible,
 839                          ;; so just keep the prefix.
 840            (when (and abbreviated filename)
 841              (delete-region (point) end))
 842                          nil)))))
 843
 844        ;; Only one possible completion
 845        (t
 846         (if (and (equal basestr (car poss))
 847                  (not (and env-on filename))
 848                  (not abbreviated))
 849             (if (null mode)
 850                 (PC-temp-minibuffer-message " [Sole completion]"))
 851           (delete-region beg end)
 852           (insert (format "%s"
 853                           (if filename
 854                               (substitute-in-file-name (concat dirname (car poss)))
 855                             (car poss)))))
 856         t)))))
 857
 858 (defun PC-chop-word (new old)
 859   (let ((i -1)
 860         (j -1))
 861     (while (and (setq i (string-match PC-delim-regex old (1+ i)))
 862                 (setq j (string-match PC-delim-regex new (1+ j)))))
 863     (if (and j
 864              (or (not PC-word-failed-flag)
 865                  (setq j (string-match PC-delim-regex new (1+ j)))))
 866         (substring new 0 (1+ j))
 867       new)))
 868
 869 (defvar PC-not-minibuffer nil)
 870
 871 (defun PC-temp-minibuffer-message (message)
 872   "A Lisp version of `temp_minibuffer_message' from minibuf.c."
 873   (cond (PC-not-minibuffer
 874          (message "%s" message)
 875          (sit-for 2)
 876          (message ""))
 877         ((fboundp 'temp-minibuffer-message)
 878          (temp-minibuffer-message message))
 879         (t
 880          (let ((point-max (point-max)))
 881            (save-excursion
 882              (goto-char point-max)
 883              (insert message))
 884            (let ((inhibit-quit t))
 885              (sit-for 2)
 886              (delete-region point-max (point-max))
 887              (when quit-flag
 888                (setq quit-flag nil
 889                      unread-command-events '(7))))))))
 890
 891 ;; Does not need to be buffer-local (?) because only used when one
 892 ;; PC-l-c-s immediately follows another.
 893 (defvar PC-lisp-complete-end nil
 894   "Internal variable used by `PC-lisp-complete-symbol'.")
 895
 896 (defun PC-lisp-complete-symbol ()
 897   "Perform completion on Lisp symbol preceding point.
 898 That symbol is compared against the symbols that exist
 899 and any additional characters determined by what is there
 900 are inserted.
 901 If the symbol starts just after an open-parenthesis,
 902 only symbols with function definitions are considered.
 903 Otherwise, all symbols with function definitions, values
 904 or properties are considered."
 905   (interactive)
 906   (let* ((end
 907           (save-excursion
 908             (with-syntax-table lisp-mode-syntax-table
 909               (skip-syntax-forward "_w")
 910               (point))))
 911          (beg (save-excursion
 912                 (with-syntax-table lisp-mode-syntax-table
 913                   (backward-sexp 1)
 914                   (while (= (char-syntax (following-char)) ?\')
 915                     (forward-char 1))
 916                   (point))))
 917          (minibuffer-completion-table obarray)
 918          (minibuffer-completion-predicate
 919           (if (eq (char-after (1- beg)) ?\()
 920               'fboundp
 921             (function (lambda (sym)
 922                         (or (boundp sym) (fboundp sym)
 923                             (symbol-plist sym))))))
 924          (PC-not-minibuffer t))
 925     ;; http://lists.gnu.org/archive/html/emacs-devel/2007-03/msg01211.html
 926     ;;
 927     ;; This deals with cases like running PC-l-c-s on "M-: (n-f".
 928     ;; The first call to PC-l-c-s expands this to "(ne-f", and moves
 929     ;; point to the hyphen [1]. If one calls PC-l-c-s immediately after,
 930     ;; then without the last-command check, one is offered all
 931     ;; completions of "(ne", which is presumably not what one wants.
 932     ;;
 933     ;; This is arguably (at least, it seems to be the existing intended
 934     ;; behaviour) what one _does_ want if point has been explicitly
 935     ;; positioned on the hyphen. Note that if PC-do-completion (qv) binds
 936     ;; completion-base-size to nil, then completion does not replace the
 937     ;; correct amount of text in such cases.
 938     ;;
 939     ;; Neither of these problems occur when using PC for filenames in the
 940     ;; minibuffer, because in that case PC-do-completion is called without
 941     ;; an explicit value for END, and so uses (point-max). This is fine for
 942     ;; a filename, because the end of the filename must be at the end of
 943     ;; the minibuffer. The same is not true for lisp symbols.
 944     ;;
 945     ;; [1] An alternate fix would be to not move point to the hyphen
 946     ;; in such cases, but that would make the behaviour different from
 947     ;; that for filenames. It seems PC moves point to the site of the
 948     ;; first difference between the possible completions.
 949     ;;
 950     ;; Alternatively alternatively, maybe end should be computed in
 951     ;; the same way as beg. That would change the behaviour though.
 952     (if (equal last-command 'PC-lisp-complete-symbol)
 953         (PC-do-completion nil beg PC-lisp-complete-end t)
 954       (if PC-lisp-complete-end
 955           (move-marker PC-lisp-complete-end end)
 956         (setq PC-lisp-complete-end (copy-marker end t)))
 957       (PC-do-completion nil beg end t))))
 958
 959 (defun PC-complete-as-file-name ()
 960    "Perform completion on file names preceding point.
 961  Environment vars are converted to their values."
 962    (interactive)
 963    (let* ((end (point))
 964           (beg (if (re-search-backward "[^\\][ \t\n\"\`\'][^ \t\n\"\`\']"
 965                                        (point-min) t)
 966                    (+ (point) 2)
 967                    (point-min)))
 968           (minibuffer-completion-table 'PC-read-file-name-internal)
 969           (minibuffer-completion-predicate "")
 970           (PC-not-minibuffer t))
 971      (goto-char end)
 972      (PC-do-completion nil beg end)))
 973
 974 ;; Facilities for loading C header files.  This is independent from the
 975 ;; main completion code.  See also the variable `PC-include-file-path'
 976 ;; at top of this file.
 977
 978 (defun PC-look-for-include-file ()
 979   (if (string-match "[\"<]\\([^\"<>]*\\)[\">]?$" (buffer-file-name))
 980       (let ((name (substring (buffer-file-name)
 981                              (match-beginning 1) (match-end 1)))
 982             (punc (aref (buffer-file-name) (match-beginning 0)))
 983             (path nil)
 984             new-buf)
 985         (kill-buffer (current-buffer))
 986         (if (equal name "")
 987             (with-current-buffer (car (buffer-list))
 988               (save-excursion
 989                 (beginning-of-line)
 990                 (if (looking-at
 991                      "[ \t]*#[ \t]*include[ \t]+[<\"]\\(.+\\)[>\"][ \t]*[\n/]")
 992                     (setq name (buffer-substring (match-beginning 1)
 993                                                  (match-end 1))
 994                           punc (char-after (1- (match-beginning 1))))
 995                   ;; Suggested by Frank Siebenlist:
 996                   (if (or (looking-at
 997                            "[ \t]*([ \t]*load[ \t]+\"\\([^\"]+\\)\"")
 998                           (looking-at
 999                            "[ \t]*([ \t]*load-library[ \t]+\"\\([^\"]+\\)\"")
1000                           (looking-at
1001                            "[ \t]*([ \t]*require[ \t]+'\\([^\t )]+\\)[\t )]"))
1002                       (progn
1003                         (setq name (buffer-substring (match-beginning 1)
1004                                                      (match-end 1))
1005                               punc ?\<
1006                               path load-path)
1007                         (if (string-match "\\.elc$" name)
1008                             (setq name (substring name 0 -1))
1009                           (or (string-match "\\.el$" name)
1010                               (setq name (concat name ".el")))))
1011                     (error "Not on an #include line"))))))
1012         (or (string-match "\\.[[:alnum:]]+$" name)
1013             (setq name (concat name ".h")))
1014         (if (eq punc ?\<)
1015             (let ((path (or path (PC-include-file-path))))
1016               (while (and path
1017                           (not (file-exists-p
1018                                 (concat (file-name-as-directory (car path))
1019                                         name))))
1020                 (setq path (cdr path)))
1021               (if path
1022                   (setq name (concat (file-name-as-directory (car path)) name))
1023                 (error "No such include file: <%s>" name)))
1024           (let ((dir (with-current-buffer (car (buffer-list))
1025                        default-directory)))
1026             (if (file-exists-p (concat dir name))
1027                 (setq name (concat dir name))
1028               (error "No such include file: `%s'" name))))
1029         (setq new-buf (get-file-buffer name))
1030         (if new-buf
1031             ;; no need to verify last-modified time for this!
1032             (set-buffer new-buf)
1033           (set-buffer (create-file-buffer name))
1034           (erase-buffer)
1035           (insert-file-contents name t))
1036         ;; Returning non-nil with the new buffer current
1037         ;; is sufficient to tell find-file to use it.
1038         t)
1039     nil))
1040
1041 (defun PC-include-file-path ()
1042   (or PC-include-file-path
1043       (let ((env (getenv "INCPATH"))
1044             (path nil)
1045             pos)
1046         (or env (error "No include file path specified"))
1047         (while (setq pos (string-match ":[^:]+$" env))
1048           (setq path (cons (substring env (1+ pos)) path)
1049                 env (substring env 0 pos)))
1050         path)))
1051
1052 ;; This is adapted from lib-complete.el, by Mike Williams.
1053 (defun PC-include-file-all-completions (file search-path &optional full)
1054   "Return all completions for FILE in any directory on SEARCH-PATH.
1055 If optional third argument FULL is non-nil, returned pathnames should be
1056 absolute rather than relative to some directory on the SEARCH-PATH."
1057   (setq search-path
1058         (mapcar (lambda (dir)
1059                   (if dir (file-name-as-directory dir) default-directory))
1060                 search-path))
1061   (if (file-name-absolute-p file)
1062       ;; It's an absolute file name, so don't need search-path
1063       (progn
1064         (setq file (expand-file-name file))
1065         (file-name-all-completions
1066          (file-name-nondirectory file) (file-name-directory file)))
1067     (let ((subdir (file-name-directory file))
1068           (ndfile (file-name-nondirectory file))
1069           file-lists)
1070       ;; Append subdirectory part to each element of search-path
1071       (if subdir
1072           (setq search-path
1073                 (mapcar (lambda (dir) (concat dir subdir))
1074                         search-path)
1075                 file ))
1076       ;; Make list of completions in each directory on search-path
1077       (while search-path
1078         (let* ((dir (car search-path))
1079                (subdir (if full dir subdir)))
1080           (if (file-directory-p dir)
1081               (progn
1082                 (setq file-lists
1083                       (cons
1084                        (mapcar (lambda (file) (concat subdir file))
1085                                (file-name-all-completions ndfile
1086                                                           (car search-path)))
1087                        file-lists))))
1088           (setq search-path (cdr search-path))))
1089       ;; Compress out duplicates while building complete list (slloooow!)
1090       (let ((sorted (sort (apply 'nconc file-lists)
1091                           (lambda (x y) (not (string-lessp x y)))))
1092             compressed)
1093         (while sorted
1094           (if (equal (car sorted) (car compressed)) nil
1095             (setq compressed (cons (car sorted) compressed)))
1096           (setq sorted (cdr sorted)))
1097         compressed))))
1098
1099 (defun PC-read-file-name-internal (string dir action)
1100   "Extend `read-file-name-internal' to handle include files.
1101 This is only used by "
1102   (if (string-match "<\\([^\"<>]*\\)>?\\'" string)
1103       (let* ((name (match-string 1 string))
1104              (str2 (substring string (match-beginning 0)))
1105              (completion-table
1106               (mapcar (lambda (x)
1107                         (format (if (string-match "/\\'" x) "<%s" "<%s>") x))
1108                       (PC-include-file-all-completions
1109                        name (PC-include-file-path)))))
1110               (cond
1111                ((not completion-table) nil)
1112                ((eq action 'lambda) (test-completion str2 completion-table nil))
1113                ((eq action nil) (PC-try-completion str2 completion-table nil))
1114           ((eq action t) (all-completions str2 completion-table nil))))
1115     (read-file-name-internal string dir action)))
1116 \f
1117
1118 (provide 'complete)
1119
1120 ;; arch-tag: fc7e2768-ff44-4e22-b579-4d825b968458
1121 ;;; complete.el ends here