lisp/vc-bzr.el

   1 ;;; vc-bzr.el --- VC backend for the bzr revision control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Love <fx@gnu.org>
   6 ;;         Riccardo Murri <riccardo.murri@gmail.com>
   7 ;; Keywords: tools
   8 ;; Created: Sept 2006
   9 ;; Version: 2008-01-04 (Bzr revno 25)
  10 ;; URL: http://launchpad.net/vc-bzr
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; See <URL:http://bazaar-vcs.org/> concerning bzr.  See
  30 ;; <URL:http://launchpad.net/vc-bzr> for alternate development
  31 ;; branches of `vc-bzr'.
  32
  33 ;; Load this library to register bzr support in VC.
  34
  35 ;; Known bugs
  36 ;; ==========
  37
  38 ;; When editing a symlink and *both* the symlink and its target
  39 ;; are bzr-versioned, `vc-bzr` presently runs `bzr status` on the
  40 ;; symlink, thereby not detecting whether the actual contents
  41 ;; (that is, the target contents) are changed.
  42 ;; See https://bugs.launchpad.net/vc-bzr/+bug/116607
  43
  44 ;; For an up-to-date list of bugs, please see:
  45 ;;   https://bugs.launchpad.net/vc-bzr/+bugs
  46
  47 ;;; Properties of the backend
  48
  49 (defun vc-bzr-revision-granularity () 'repository)
  50 (defun vc-bzr-checkout-model (files) 'implicit)
  51
  52 ;;; Code:
  53
  54 (eval-when-compile
  55   (require 'cl)
  56   (require 'vc)  ;; for vc-exec-after
  57   (require 'vc-dir))
  58
  59 ;; Clear up the cache to force vc-call to check again and discover
  60 ;; new functions when we reload this file.
  61 (put 'Bzr 'vc-functions nil)
  62
  63 (defgroup vc-bzr nil
  64   "VC bzr backend."
  65   :version "22.2"
  66   :group 'vc)
  67
  68 (defcustom vc-bzr-program "bzr"
  69   "Name of the bzr command (excluding any arguments)."
  70   :group 'vc-bzr
  71   :type 'string)
  72
  73 (defcustom vc-bzr-diff-switches nil
  74   "String or list of strings specifying switches for bzr diff under VC.
  75 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  76   :type '(choice (const :tag "Unspecified" nil)
  77                  (const :tag "None" t)
  78                  (string :tag "Argument String")
  79                  (repeat :tag "Argument List" :value ("") string))
  80   :group 'vc-bzr)
  81
  82 (defcustom vc-bzr-log-switches nil
  83   "String or list of strings specifying switches for bzr log under VC."
  84   :type '(choice (const :tag "None" nil)
  85                  (string :tag "Argument String")
  86                  (repeat :tag "Argument List" :value ("") string))
  87   :group 'vc-bzr)
  88
  89 ;; since v0.9, bzr supports removing the progress indicators
  90 ;; by setting environment variable BZR_PROGRESS_BAR to "none".
  91 (defun vc-bzr-command (bzr-command buffer okstatus file-or-list &rest args)
  92   "Wrapper round `vc-do-command' using `vc-bzr-program' as COMMAND.
  93 Invoke the bzr command adding `BZR_PROGRESS_BAR=none' and
  94 `LC_MESSAGES=C' to the environment."
  95   (let ((process-environment
  96          (list* "BZR_PROGRESS_BAR=none" ; Suppress progress output (bzr >=0.9)
  97                 "LC_MESSAGES=C"         ; Force English output
  98                 process-environment)))
  99     (apply 'vc-do-command (or buffer "*vc*") okstatus vc-bzr-program
 100            file-or-list bzr-command args)))
 101
 102
 103 ;;;###autoload
 104 (defconst vc-bzr-admin-dirname ".bzr"
 105   "Name of the directory containing Bzr repository status files.")
 106 ;;;###autoload
 107 (defconst vc-bzr-admin-checkout-format-file
 108   (concat vc-bzr-admin-dirname "/checkout/format"))
 109 (defconst vc-bzr-admin-dirstate
 110   (concat vc-bzr-admin-dirname "/checkout/dirstate"))
 111 (defconst vc-bzr-admin-branch-format-file
 112   (concat vc-bzr-admin-dirname "/branch/format"))
 113 (defconst vc-bzr-admin-revhistory
 114   (concat vc-bzr-admin-dirname "/branch/revision-history"))
 115 (defconst vc-bzr-admin-lastrev
 116   (concat vc-bzr-admin-dirname "/branch/last-revision"))
 117
 118 ;;;###autoload (defun vc-bzr-registered (file)
 119 ;;;###autoload   (if (vc-find-root file vc-bzr-admin-checkout-format-file)
 120 ;;;###autoload       (progn
 121 ;;;###autoload         (load "vc-bzr")
 122 ;;;###autoload         (vc-bzr-registered file))))
 123
 124 (defun vc-bzr-root (file)
 125   "Return the root directory of the bzr repository containing FILE."
 126   ;; Cache technique copied from vc-arch.el.
 127   (or (vc-file-getprop file 'bzr-root)
 128       (let ((root (vc-find-root file vc-bzr-admin-checkout-format-file)))
 129         (when root (vc-file-setprop file 'bzr-root root)))))
 130
 131 (require 'sha1)                         ;For sha1-program
 132
 133 (defun vc-bzr-sha1 (file)
 134   (with-temp-buffer
 135     (set-buffer-multibyte nil)
 136     (let ((prog sha1-program)
 137           (args nil)
 138           process-file-side-effects)
 139       (when (consp prog)
 140         (setq args (cdr prog))
 141         (setq prog (car prog)))
 142       (apply 'process-file prog (file-relative-name file) t nil args)
 143       (buffer-substring (point-min) (+ (point-min) 40)))))
 144
 145 (defun vc-bzr-state-heuristic (file)
 146   "Like `vc-bzr-state' but hopefully without running Bzr."
 147   ;; `bzr status' was excrutiatingly slow with large histories and
 148   ;; pending merges, so try to avoid using it until they fix their
 149   ;; performance problems.
 150   ;; This function tries first to parse Bzr internal file
 151   ;; `checkout/dirstate', but it may fail if Bzr internal file format
 152   ;; has changed.  As a safeguard, the `checkout/dirstate' file is
 153   ;; only parsed if it contains the string `#bazaar dirstate flat
 154   ;; format 3' in the first line.
 155   ;; If the `checkout/dirstate' file cannot be parsed, fall back to
 156   ;; running `vc-bzr-state'."
 157   (lexical-let ((root (vc-bzr-root file)))
 158     (when root    ; Short cut.
 159       ;; This looks at internal files.  May break if they change
 160       ;; their format.
 161       (lexical-let ((dirstate (expand-file-name vc-bzr-admin-dirstate root)))
 162         (condition-case nil
 163             (with-temp-buffer
 164               (insert-file-contents dirstate)
 165               (goto-char (point-min))
 166               (if (not (looking-at "#bazaar dirstate flat format 3"))
 167                   (vc-bzr-state file)   ; Some other unknown format?
 168                 (let* ((relfile (file-relative-name file root))
 169                        (reldir (file-name-directory relfile)))
 170                   (if (re-search-forward
 171                        (concat "^\0"
 172                                (if reldir (regexp-quote
 173                                            (directory-file-name reldir)))
 174                                "\0"
 175                                (regexp-quote (file-name-nondirectory relfile))
 176                                "\0"
 177                                "[^\0]*\0"     ;id?
 178                                "\\([^\0]*\\)\0" ;"a/f/d", a=removed?
 179                                "\\([^\0]*\\)\0" ;sha1 (empty if conflicted)?
 180                                "\\([^\0]*\\)\0" ;size?p
 181                                "[^\0]*\0"       ;"y/n", executable?
 182                                "[^\0]*\0"       ;?
 183                                "\\([^\0]*\\)\0" ;"a/f/d" a=added?
 184                                "\\([^\0]*\\)\0" ;sha1 again?
 185                                "\\([^\0]*\\)\0" ;size again?
 186                                "[^\0]*\0" ;"y/n", executable again?
 187                                "[^\0]*\0" ;last revid?
 188                                ;; There are more fields when merges are pending.
 189                                )
 190                        nil t)
 191                       ;; Apparently the second sha1 is the one we want: when
 192                       ;; there's a conflict, the first sha1 is absent (and the
 193                       ;; first size seems to correspond to the file with
 194                       ;; conflict markers).
 195                       (cond
 196                        ((eq (char-after (match-beginning 1)) ?a) 'removed)
 197                        ((eq (char-after (match-beginning 4)) ?a) 'added)
 198                        ((or (and (eq (string-to-number (match-string 3))
 199                                  (nth 7 (file-attributes file)))
 200                              (equal (match-string 5)
 201                                     (vc-bzr-sha1 file)))
 202                             (and
 203                              ;; It looks like for lightweight
 204                              ;; checkouts \2 is empty and we need to
 205                              ;; look for size in \6.
 206                              (eq (match-beginning 2) (match-end 2))
 207                              (eq (string-to-number (match-string 6))
 208                                  (nth 7 (file-attributes file)))
 209                              (equal (match-string 5)
 210                                     (vc-bzr-sha1 file))))
 211                         'up-to-date)
 212                        (t 'edited))
 213                     'unregistered))))
 214           ;; Either the dirstate file can't be read, or the sha1
 215           ;; executable is missing, or ...
 216           ;; In either case, recent versions of Bzr aren't that slow
 217           ;; any more.
 218           (error (vc-bzr-state file)))))))
 219
 220
 221 (defun vc-bzr-registered (file)
 222   "Return non-nil if FILE is registered with bzr."
 223   (let ((state (vc-bzr-state-heuristic file)))
 224     (not (memq state '(nil unregistered ignored)))))
 225
 226 (defconst vc-bzr-state-words
 227   "added\\|ignored\\|kind changed\\|modified\\|removed\\|renamed\\|unknown"
 228   "Regexp matching file status words as reported in `bzr' output.")
 229
 230 (defun vc-bzr-file-name-relative (filename)
 231   "Return file name FILENAME stripped of the initial Bzr repository path."
 232   (lexical-let*
 233       ((filename* (expand-file-name filename))
 234        (rootdir (vc-bzr-root filename*)))
 235     (when rootdir
 236          (file-relative-name filename* rootdir))))
 237
 238 (defun vc-bzr-status (file)
 239   "Return FILE status according to Bzr.
 240 Return value is a cons (STATUS . WARNING), where WARNING is a
 241 string or nil, and STATUS is one of the symbols: `added',
 242 `ignored', `kindchanged', `modified', `removed', `renamed', `unknown',
 243 which directly correspond to `bzr status' output, or 'unchanged
 244 for files whose copy in the working tree is identical to the one
 245 in the branch repository, or nil for files that are not
 246 registered with Bzr.
 247
 248 If any error occurred in running `bzr status', then return nil."
 249   (with-temp-buffer
 250     (let ((ret (condition-case nil
 251                    (vc-bzr-command "status" t 0 file)
 252                  (file-error nil)))     ; vc-bzr-program not found.
 253           (status 'unchanged))
 254           ;; the only secure status indication in `bzr status' output
 255           ;; is a couple of lines following the pattern::
 256           ;;   | <status>:
 257           ;;   |   <file name>
 258           ;; if the file is up-to-date, we get no status report from `bzr',
 259           ;; so if the regexp search for the above pattern fails, we consider
 260           ;; the file to be up-to-date.
 261           (goto-char (point-min))
 262           (when (re-search-forward
 263                  ;; bzr prints paths relative to the repository root.
 264                  (concat "^\\(" vc-bzr-state-words "\\):[ \t\n]+"
 265                          (regexp-quote (vc-bzr-file-name-relative file))
 266                          ;; Bzr appends a '/' to directory names and
 267                          ;; '*' to executable files
 268                          (if (file-directory-p file) "/?" "\\*?")
 269                          "[ \t\n]*$")
 270                  nil t)
 271             (lexical-let ((statusword (match-string 1)))
 272               ;; Erase the status text that matched.
 273               (delete-region (match-beginning 0) (match-end 0))
 274               (setq status
 275                     (intern (replace-regexp-in-string " " "" statusword)))))
 276           (when status
 277             (goto-char (point-min))
 278             (skip-chars-forward " \n\t") ;Throw away spaces.
 279             (cons status
 280                   ;; "bzr" will output warnings and informational messages to
 281                   ;; stderr; due to Emacs' `vc-do-command' (and, it seems,
 282                   ;; `start-process' itself) limitations, we cannot catch stderr
 283                   ;; and stdout into different buffers.  So, if there's anything
 284                   ;; left in the buffer after removing the above status
 285                   ;; keywords, let us just presume that any other message from
 286                   ;; "bzr" is a user warning, and display it.
 287                   (unless (eobp) (buffer-substring (point) (point-max))))))))
 288
 289 (defun vc-bzr-state (file)
 290   (lexical-let ((result (vc-bzr-status file)))
 291     (when (consp result)
 292       (when (cdr result)
 293         (message "Warnings in `bzr' output: %s" (cdr result)))
 294       (cdr (assq (car result)
 295                  '((added . added)
 296                    (kindchanged . edited)
 297                    (renamed . edited)
 298                    (modified . edited)
 299                    (removed . removed)
 300                    (ignored . ignored)
 301                    (unknown . unregistered)
 302                    (unchanged . up-to-date)))))))
 303
 304 (defun vc-bzr-resolve-when-done ()
 305   "Call \"bzr resolve\" if the conflict markers have been removed."
 306   (save-excursion
 307     (goto-char (point-min))
 308     (unless (re-search-forward "^<<<<<<< " nil t)
 309       (vc-bzr-command "resolve" nil 0 buffer-file-name)
 310       ;; Remove the hook so that it is not called multiple times.
 311       (remove-hook 'after-save-hook 'vc-bzr-resolve-when-done t))))
 312
 313 (defun vc-bzr-find-file-hook ()
 314   (when (and buffer-file-name
 315              ;; FIXME: We should check that "bzr status" says "conflict".
 316              (file-exists-p (concat buffer-file-name ".BASE"))
 317              (file-exists-p (concat buffer-file-name ".OTHER"))
 318              (file-exists-p (concat buffer-file-name ".THIS"))
 319              ;; If "bzr status" says there's a conflict but there are no
 320              ;; conflict markers, it's not clear what we should do.
 321              (save-excursion
 322                (goto-char (point-min))
 323                (re-search-forward "^<<<<<<< " nil t)))
 324     ;; TODO: the merge algorithm used in `bzr merge' is nicely configurable,
 325     ;; but the one in `bzr pull' isn't, so it would be good to provide an
 326     ;; elisp function to remerge from the .BASE/OTHER/THIS files.
 327     (smerge-start-session)
 328     (add-hook 'after-save-hook 'vc-bzr-resolve-when-done nil t)
 329     (message "There are unresolved conflicts in this file")))
 330
 331 (defun vc-bzr-workfile-unchanged-p (file)
 332   (eq 'unchanged (car (vc-bzr-status file))))
 333
 334 (defun vc-bzr-working-revision (file)
 335   ;; Together with the code in vc-state-heuristic, this makes it possible
 336   ;; to get the initial VC state of a Bzr file even if Bzr is not installed.
 337   (lexical-let*
 338       ((rootdir (vc-bzr-root file))
 339        (branch-format-file (expand-file-name vc-bzr-admin-branch-format-file
 340                                              rootdir))
 341        (revhistory-file (expand-file-name vc-bzr-admin-revhistory rootdir))
 342        (lastrev-file (expand-file-name vc-bzr-admin-lastrev rootdir)))
 343     ;; This looks at internal files to avoid forking a bzr process.
 344     ;; May break if they change their format.
 345     (if (and (file-exists-p branch-format-file)
 346              ;; For lightweight checkouts (obtained with bzr checkout --lightweight)
 347              ;; the branch-format-file does not contain the revision
 348              ;; information, we need to look up the branch-format-file
 349              ;; in the place where the lightweight checkout comes
 350              ;; from.  We only do that if it's a local file.
 351              (let ((location-fname (expand-file-name
 352                                     (concat vc-bzr-admin-dirname
 353                                             "/branch/location") rootdir)))
 354                ;; The existence of this file is how we distinguish
 355                ;; lightweight checkouts.
 356                (if (file-exists-p location-fname)
 357                    (with-temp-buffer
 358                      (insert-file-contents location-fname)
 359                      ;; If the lightweight checkout points to a
 360                      ;; location in the local file system, then we can
 361                      ;; look there for the version information.
 362                      (when (re-search-forward "file://\\(.+\\)" nil t)
 363                        (let ((l-c-parent-dir (match-string 1)))
 364                          (when (and (memq system-type '(ms-dos windows-nt))
 365                                     (string-match-p "^/[[:alpha:]]:" l-c-parent-dir))
 366                            ;;; The non-Windows code takes a shortcut by using the host/path
 367                            ;;; separator slash as the start of the absolute path.  That
 368                            ;;; does not work on Windows, so we must remove it (bug#5345)
 369                            (setq l-c-parent-dir (substring l-c-parent-dir 1)))
 370                          (setq branch-format-file
 371                                (expand-file-name vc-bzr-admin-branch-format-file
 372                                                  l-c-parent-dir))
 373                          (setq lastrev-file
 374                                (expand-file-name vc-bzr-admin-lastrev l-c-parent-dir))
 375                          ;; FIXME: maybe it's overkill to check if both these files exist.
 376                          (and (file-exists-p branch-format-file)
 377                               (file-exists-p lastrev-file)))))
 378                  t)))
 379         (with-temp-buffer
 380           (insert-file-contents branch-format-file)
 381           (goto-char (point-min))
 382           (cond
 383            ((or
 384              (looking-at "Bazaar-NG branch, format 0.0.4")
 385              (looking-at "Bazaar-NG branch format 5"))
 386             ;; count lines in .bzr/branch/revision-history
 387             (insert-file-contents revhistory-file)
 388             (number-to-string (count-lines (line-end-position) (point-max))))
 389            ((or
 390              (looking-at "Bazaar Branch Format 6 (bzr 0.15)")
 391              (looking-at "Bazaar Branch Format 7 (needs bzr 1.6)"))
 392             ;; revno is the first number in .bzr/branch/last-revision
 393             (insert-file-contents lastrev-file)
 394             (when (re-search-forward "[0-9]+" nil t)
 395               (buffer-substring (match-beginning 0) (match-end 0))))))
 396       ;; fallback to calling "bzr revno"
 397       (lexical-let*
 398           ((result (vc-bzr-command-discarding-stderr
 399                     vc-bzr-program "revno" (file-relative-name file)))
 400            (exitcode (car result))
 401            (output (cdr result)))
 402         (cond
 403          ((eq exitcode 0) (substring output 0 -1))
 404          (t nil))))))
 405
 406 (defun vc-bzr-create-repo ()
 407   "Create a new Bzr repository."
 408   (vc-bzr-command "init" nil 0 nil))
 409
 410 (defun vc-bzr-init-revision (&optional file)
 411   "Always return nil, as Bzr cannot register explicit versions."
 412   nil)
 413
 414 (defun vc-bzr-previous-revision (file rev)
 415   (if (string-match "\\`[0-9]+\\'" rev)
 416       (number-to-string (1- (string-to-number rev)))
 417     (concat "before:" rev)))
 418
 419 (defun vc-bzr-next-revision (file rev)
 420   (if (string-match "\\`[0-9]+\\'" rev)
 421       (number-to-string (1+ (string-to-number rev)))
 422     (error "Don't know how to compute the next revision of %s" rev)))
 423
 424 (defun vc-bzr-register (files &optional rev comment)
 425   "Register FILE under bzr.
 426 Signal an error unless REV is nil.
 427 COMMENT is ignored."
 428   (if rev (error "Can't register explicit revision with bzr"))
 429   (vc-bzr-command "add" nil 0 files))
 430
 431 ;; Could run `bzr status' in the directory and see if it succeeds, but
 432 ;; that's relatively expensive.
 433 (defalias 'vc-bzr-responsible-p 'vc-bzr-root
 434   "Return non-nil if FILE is (potentially) controlled by bzr.
 435 The criterion is that there is a `.bzr' directory in the same
 436 or a superior directory.")
 437
 438 (defun vc-bzr-could-register (file)
 439   "Return non-nil if FILE could be registered under bzr."
 440   (and (vc-bzr-responsible-p file)      ; shortcut
 441        (condition-case ()
 442            (with-temp-buffer
 443              (vc-bzr-command "add" t 0 file "--dry-run")
 444              ;; The command succeeds with no output if file is
 445              ;; registered (in bzr 0.8).
 446              (goto-char (point-min))
 447              (looking-at "added "))
 448          (error))))
 449
 450 (defun vc-bzr-unregister (file)
 451   "Unregister FILE from bzr."
 452   (vc-bzr-command "remove" nil 0 file "--keep"))
 453
 454 (defun vc-bzr-checkin (files rev comment &optional extra-args)
 455   "Check FILE in to bzr with log message COMMENT.
 456 REV non-nil gets an error."
 457   (if rev (error "Can't check in a specific revision with bzr"))
 458   (apply 'vc-bzr-command "commit" nil 0 files (append (list "-m" comment) extra-args)))
 459
 460 (defun vc-bzr-find-revision (file rev buffer)
 461   "Fetch revision REV of file FILE and put it into BUFFER."
 462     (with-current-buffer buffer
 463       (if (and rev (stringp rev) (not (string= rev "")))
 464           (vc-bzr-command "cat" t 0 file "-r" rev)
 465         (vc-bzr-command "cat" t 0 file))))
 466
 467 (defun vc-bzr-checkout (file &optional editable rev)
 468   (if rev (error "Operation not supported")
 469     ;; Else, there's nothing to do.
 470     nil))
 471
 472 (defun vc-bzr-revert (file &optional contents-done)
 473   (unless contents-done
 474     (with-temp-buffer (vc-bzr-command "revert" t 0 file))))
 475
 476 (defvar log-view-message-re)
 477 (defvar log-view-file-re)
 478 (defvar log-view-font-lock-keywords)
 479 (defvar log-view-current-tag-function)
 480 (defvar log-view-per-file-logs)
 481
 482 (define-derived-mode vc-bzr-log-view-mode log-view-mode "Bzr-Log-View"
 483   (remove-hook 'log-view-mode-hook 'vc-bzr-log-view-mode) ;Deactivate the hack.
 484   (require 'add-log)
 485   (set (make-local-variable 'log-view-per-file-logs) nil)
 486   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 487   (set (make-local-variable 'log-view-message-re)
 488        (if (eq vc-log-view-type 'short)
 489            "^ *\\([0-9.]+\\): \\(.*?\\)[ \t]+\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}\\)\\( \\[merge\\]\\)?"
 490          "^ *\\(?:revno: \\([0-9.]+\\)\\|merged: .+\\)"))
 491   (set (make-local-variable 'log-view-font-lock-keywords)
 492        ;; log-view-font-lock-keywords is careful to use the buffer-local
 493        ;; value of log-view-message-re only since Emacs-23.
 494        (if (eq vc-log-view-type 'short)
 495          (append `((,log-view-message-re
 496                     (1 'log-view-message-face)
 497                     (2 'change-log-name)
 498                     (3 'change-log-date)
 499                     (4 'change-log-list nil lax))))
 500          (append `((,log-view-message-re . 'log-view-message-face))
 501                  ;; log-view-font-lock-keywords
 502                  '(("^ *\\(?:committer\\|author\\): \
 503 \\([^<(]+?\\)[  ]*[(<]\\([[:alnum:]_.+-]+@[[:alnum:]_.-]+\\)[>)]"
 504                     (1 'change-log-name)
 505                     (2 'change-log-email))
 506                    ("^ *timestamp: \\(.*\\)" (1 'change-log-date-face)))))))
 507
 508 (defun vc-bzr-print-log (files buffer &optional shortlog start-revision limit)
 509   "Get bzr change log for FILES into specified BUFFER."
 510   ;; `vc-do-command' creates the buffer, but we need it before running
 511   ;; the command.
 512   (vc-setup-buffer buffer)
 513   ;; If the buffer exists from a previous invocation it might be
 514   ;; read-only.
 515   ;; FIXME: `vc-bzr-command' runs `bzr log' with `LC_MESSAGES=C', so
 516   ;; the log display may not what the user wants - but I see no other
 517   ;; way of getting the above regexps working.
 518   (with-current-buffer buffer
 519     (apply 'vc-bzr-command "log" buffer 'async files
 520            (append
 521             (when shortlog '("--line"))
 522             (when start-revision (list (format "-r..%s" start-revision)))
 523             (when limit (list "-l" (format "%s" limit)))
 524             (if (stringp vc-bzr-log-switches)
 525                 (list vc-bzr-log-switches)
 526               vc-bzr-log-switches)))))
 527
 528 (defun vc-bzr-log-incoming (buffer remote-location)
 529   (apply 'vc-bzr-command "missing" buffer 'async nil
 530          (list "--theirs-only" (unless (string= remote-location "") remote-location))))
 531
 532 (defun vc-bzr-log-outgoing (buffer remote-location)
 533   (apply 'vc-bzr-command "missing" buffer 'async nil
 534          (list "--mine-only" (unless (string= remote-location "") remote-location))))
 535
 536 (defun vc-bzr-show-log-entry (revision)
 537   "Find entry for patch name REVISION in bzr change log buffer."
 538   (goto-char (point-min))
 539   (when revision
 540     (let (case-fold-search
 541           found)
 542       (if (re-search-forward
 543            ;; "revno:" can appear either at the beginning of a line,
 544            ;; or indented.
 545            (concat "^[ ]*-+\n[ ]*revno: "
 546                    ;; The revision can contain ".", quote it so that it
 547                    ;; does not interfere with regexp matching.
 548                    (regexp-quote revision) "$") nil t)
 549           (progn
 550             (beginning-of-line 0)
 551             (setq found t))
 552         (goto-char (point-min)))
 553       found)))
 554
 555 (declare-function log-edit-mode "log-edit" ())
 556 (defvar log-edit-extra-flags)
 557 (defvar log-edit-before-checkin-process)
 558
 559 (define-derived-mode vc-bzr-log-edit-mode log-edit-mode "Bzr-Log-Edit"
 560   "Mode for editing Bzr commit logs.
 561 If a line like:
 562 Author: NAME
 563 is present in the log, it is removed, and
 564 --author NAME
 565 is passed to the bzr commit command.  Similarly with Fixes: and --fixes."
 566   (set (make-local-variable 'log-edit-extra-flags) nil)
 567   (set (make-local-variable 'log-edit-before-checkin-process)
 568        '(("^\\(Author\\|Fixes\\):[ \t]+\\(.*\\)[ \t]*$" .
 569           (list (format "--%s" (downcase (match-string 1)))
 570                 (match-string 2))))))
 571
 572 (defun vc-bzr-diff (files &optional rev1 rev2 buffer)
 573   "VC bzr backend for diff."
 574   ;; `bzr diff' exits with code 1 if diff is non-empty.
 575   (apply #'vc-bzr-command "diff" (or buffer "*vc-diff*")
 576          (if vc-disable-async-diff 1 'async) files
 577          "--diff-options" (mapconcat 'identity
 578                                      (vc-switches 'bzr 'diff)
 579                                      " ")
 580          ;; This `when' is just an optimization because bzr-1.2 is *much*
 581          ;; faster when the revision argument is not given.
 582          (when (or rev1 rev2)
 583            (list "-r" (format "%s..%s"
 584                               (or rev1 "revno:-1")
 585                               (or rev2 ""))))))
 586
 587
 588 ;; FIXME: vc-{next,previous}-revision need fixing in vc.el to deal with
 589 ;; straight integer revisions.
 590
 591 (defun vc-bzr-delete-file (file)
 592   "Delete FILE and delete it in the bzr repository."
 593   (condition-case ()
 594       (delete-file file)
 595     (file-error nil))
 596   (vc-bzr-command "remove" nil 0 file))
 597
 598 (defun vc-bzr-rename-file (old new)
 599   "Rename file from OLD to NEW using `bzr mv'."
 600   (vc-bzr-command "mv" nil 0 new old))
 601
 602 (defvar vc-bzr-annotation-table nil
 603   "Internal use.")
 604 (make-variable-buffer-local 'vc-bzr-annotation-table)
 605
 606 (defun vc-bzr-annotate-command (file buffer &optional revision)
 607   "Prepare BUFFER for `vc-annotate' on FILE.
 608 Each line is tagged with the revision number, which has a `help-echo'
 609 property containing author and date information."
 610   (apply #'vc-bzr-command "annotate" buffer 'async file "--long" "--all"
 611          (if revision (list "-r" revision)))
 612   (lexical-let ((table (make-hash-table :test 'equal)))
 613     (set-process-filter
 614      (get-buffer-process buffer)
 615      (lambda (proc string)
 616        (when (process-buffer proc)
 617          (with-current-buffer (process-buffer proc)
 618            (setq string (concat (process-get proc :vc-left-over) string))
 619            (while (string-match "^\\( *[0-9.]+ *\\) \\([^\n ]+\\) +\\([0-9]\\{8\\}\\)\\( |.*\n\\)" string)
 620              (let* ((rev (match-string 1 string))
 621                     (author (match-string 2 string))
 622                     (date (match-string 3 string))
 623                     (key (substring string (match-beginning 0)
 624                                     (match-beginning 4)))
 625                     (line (match-string 4 string))
 626                     (tag (gethash key table))
 627                     (inhibit-read-only t))
 628                (setq string (substring string (match-end 0)))
 629                (unless tag
 630                  (setq tag
 631                        (propertize
 632                         (format "%s %-7.7s" rev author)
 633                         'help-echo (format "Revision: %d, author: %s, date: %s"
 634                                            (string-to-number rev)
 635                                            author date)
 636                         'mouse-face 'highlight))
 637                  (puthash key tag table))
 638                (goto-char (process-mark proc))
 639                (insert tag line)
 640                (move-marker (process-mark proc) (point))))
 641            (process-put proc :vc-left-over string)))))))
 642
 643 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 644
 645 (defun vc-bzr-annotate-time ()
 646   (when (re-search-forward "^ *[0-9.]+ +[^\n ]* +|" nil t)
 647     (let ((prop (get-text-property (line-beginning-position) 'help-echo)))
 648       (string-match "[0-9]+\\'" prop)
 649       (let ((str (match-string-no-properties 0 prop)))
 650       (vc-annotate-convert-time
 651        (encode-time 0 0 0
 652                       (string-to-number (substring str 6 8))
 653                       (string-to-number (substring str 4 6))
 654                       (string-to-number (substring str 0 4))))))))
 655
 656 (defun vc-bzr-annotate-extract-revision-at-line ()
 657   "Return revision for current line of annoation buffer, or nil.
 658 Return nil if current line isn't annotated."
 659   (save-excursion
 660     (beginning-of-line)
 661     (if (looking-at "^ *\\([0-9.]+\\) +[^\n ]* +|")
 662         (match-string-no-properties 1))))
 663
 664 (defun vc-bzr-command-discarding-stderr (command &rest args)
 665   "Execute shell command COMMAND (with ARGS); return its output and exitcode.
 666 Return value is a cons (EXITCODE . OUTPUT), where EXITCODE is
 667 the (numerical) exit code of the process, and OUTPUT is a string
 668 containing whatever the process sent to its standard output
 669 stream.  Standard error output is discarded."
 670   (with-temp-buffer
 671     (cons
 672      (apply #'process-file command nil (list (current-buffer) nil) nil args)
 673      (buffer-substring (point-min) (point-max)))))
 674
 675 (defstruct (vc-bzr-extra-fileinfo
 676             (:copier nil)
 677             (:constructor vc-bzr-create-extra-fileinfo (extra-name))
 678             (:conc-name vc-bzr-extra-fileinfo->))
 679   extra-name)         ;; original name for rename targets, new name for
 680
 681 (defun vc-bzr-dir-printer (info)
 682   "Pretty-printer for the vc-dir-fileinfo structure."
 683   (let ((extra (vc-dir-fileinfo->extra info)))
 684     (vc-default-dir-printer 'Bzr info)
 685     (when extra
 686       (insert (propertize
 687                (format "   (renamed from %s)"
 688                        (vc-bzr-extra-fileinfo->extra-name extra))
 689                'face 'font-lock-comment-face)))))
 690
 691 ;; FIXME: this needs testing, it's probably incomplete.
 692 (defun vc-bzr-after-dir-status (update-function relative-dir)
 693   (let ((status-str nil)
 694         (translation '(("+N " . added)
 695                        ("-D " . removed)
 696                        (" M " . edited) ;; file text modified
 697                        ("  *" . edited) ;; execute bit changed
 698                        (" M*" . edited) ;; text modified + execute bit changed
 699                        ;; FIXME: what about ignored files?
 700                        (" D " . missing)
 701                        ;; For conflicts, should we list the .THIS/.BASE/.OTHER?
 702                        ("C  " . conflict)
 703                        ("?  " . unregistered)
 704                        ;; No such state, but we need to distinguish this case.
 705                        ("R  " . renamed)
 706                        ("RM " . renamed)
 707                        ;; For a non existent file FOO, the output is:
 708                        ;; bzr: ERROR: Path(s) do not exist: FOO
 709                        ("bzr" . not-found)
 710                        ;; If the tree is not up to date, bzr will print this warning:
 711                        ;; working tree is out of date, run 'bzr update'
 712                        ;; ignore it.
 713                        ;; FIXME: maybe this warning can be put in the vc-dir header...
 714                        ("wor" . not-found)
 715                        ;; Ignore "P " and "P." for pending patches.
 716                        ("P  " . not-found)
 717                        ("P. " . not-found)
 718                        ))
 719         (translated nil)
 720         (result nil))
 721       (goto-char (point-min))
 722       (while (not (eobp))
 723         (setq status-str
 724               (buffer-substring-no-properties (point) (+ (point) 3)))
 725         (setq translated (cdr (assoc status-str translation)))
 726         (cond
 727          ((eq translated 'conflict)
 728           ;; For conflicts the file appears twice in the listing: once
 729           ;; with the M flag and once with the C flag, so take care
 730           ;; not to add it twice to `result'.  Ugly.
 731           (let* ((file
 732                   (buffer-substring-no-properties
 733                    ;;For files with conflicts the format is:
 734                    ;;C   Text conflict in FILENAME
 735                    ;; Bah.
 736                    (+ (point) 21) (line-end-position)))
 737                  (entry (assoc file result)))
 738             (when entry
 739               (setf (nth 1 entry) 'conflict))))
 740          ((eq translated 'renamed)
 741           (re-search-forward "R[ M]  \\(.*\\) => \\(.*\\)$" (line-end-position) t)
 742           (let ((new-name (file-relative-name (match-string 2) relative-dir))
 743                 (old-name (file-relative-name (match-string 1) relative-dir)))
 744             (push (list new-name 'edited
 745                       (vc-bzr-create-extra-fileinfo old-name)) result)))
 746          ;; do nothing for non existent files
 747          ((eq translated 'not-found))
 748          (t
 749           (push (list (file-relative-name
 750                        (buffer-substring-no-properties
 751                         (+ (point) 4)
 752                         (line-end-position)) relative-dir)
 753                       translated) result)))
 754         (forward-line))
 755       (funcall update-function result)))
 756
 757 (defun vc-bzr-dir-status (dir update-function)
 758   "Return a list of conses (file . state) for DIR."
 759   (vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S")
 760   (vc-exec-after
 761    `(vc-bzr-after-dir-status (quote ,update-function)
 762                              ;; "bzr status" results are relative to
 763                              ;; the bzr root directory, NOT to the
 764                              ;; directory "bzr status" was invoked in.
 765                              ;; Ugh.
 766                              ;; We pass the relative directory here so
 767                              ;; that `vc-bzr-after-dir-status' can
 768                              ;; frob the results accordingly.
 769                              (file-relative-name ,dir (vc-bzr-root ,dir)))))
 770
 771 (defun vc-bzr-dir-status-files (dir files default-state update-function)
 772   "Return a list of conses (file . state) for DIR."
 773   (apply 'vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S" files)
 774   (vc-exec-after
 775    `(vc-bzr-after-dir-status (quote ,update-function)
 776                              (file-relative-name ,dir (vc-bzr-root ,dir)))))
 777
 778 (defvar vc-bzr-shelve-map
 779   (let ((map (make-sparse-keymap)))
 780     ;; Turn off vc-dir marking
 781     (define-key map [mouse-2] 'ignore)
 782
 783     (define-key map [down-mouse-3] 'vc-bzr-shelve-menu)
 784     (define-key map "\C-k" 'vc-bzr-shelve-delete-at-point)
 785     (define-key map "=" 'vc-bzr-shelve-show-at-point)
 786     (define-key map "\C-m" 'vc-bzr-shelve-show-at-point)
 787     (define-key map "A" 'vc-bzr-shelve-apply-and-keep-at-point)
 788     (define-key map "P" 'vc-bzr-shelve-apply-at-point)
 789     (define-key map "S" 'vc-bzr-shelve-snapshot)
 790     map))
 791
 792 (defvar vc-bzr-shelve-menu-map
 793   (let ((map (make-sparse-keymap "Bzr Shelve")))
 794     (define-key map [de]
 795       '(menu-item "Delete shelf" vc-bzr-shelve-delete-at-point
 796                   :help "Delete the current shelf"))
 797     (define-key map [ap]
 798       '(menu-item "Apply and keep shelf" vc-bzr-shelve-apply-and-keep-at-point
 799                   :help "Apply the current shelf and keep it"))
 800     (define-key map [po]
 801       '(menu-item "Apply and remove shelf (pop)" vc-bzr-shelve-apply-at-point
 802                   :help "Apply the current shelf and remove it"))
 803     (define-key map [sh]
 804       '(menu-item "Show shelve" vc-bzr-shelve-show-at-point
 805                   :help "Show the contents of the current shelve"))
 806     map))
 807
 808 (defvar vc-bzr-extra-menu-map
 809   (let ((map (make-sparse-keymap)))
 810     (define-key map [bzr-sn]
 811       '(menu-item "Shelve a snapshot" vc-bzr-shelve-snapshot
 812                   :help "Shelve the current state of the tree and keep the current state"))
 813     (define-key map [bzr-sh]
 814       '(menu-item "Shelve..." vc-bzr-shelve
 815                   :help "Shelve changes"))
 816     map))
 817
 818 (defun vc-bzr-extra-menu () vc-bzr-extra-menu-map)
 819
 820 (defun vc-bzr-extra-status-menu () vc-bzr-extra-menu-map)
 821
 822 (defun vc-bzr-dir-extra-headers (dir)
 823   (let*
 824       ((str (with-temp-buffer
 825               (vc-bzr-command "info" t 0 dir)
 826               (buffer-string)))
 827        (shelve (vc-bzr-shelve-list))
 828        (shelve-help-echo "Use M-x vc-bzr-shelve to create shelves")
 829        (root-dir (vc-bzr-root dir))
 830        (pending-merge
 831         ;; FIXME: looking for .bzr/checkout/merge-hashes is not a
 832         ;; reliable method to detect pending merges, disable this
 833         ;; until a proper solution is implemented.
 834         (and nil
 835          (file-exists-p
 836          (expand-file-name ".bzr/checkout/merge-hashes" root-dir))))
 837        (pending-merge-help-echo
 838         (format "A merge has been performed.\nA commit from the top-level directory (%s)\nis required before being able to check in anything else" root-dir))
 839        (light-checkout
 840         (when (string-match ".+light checkout root: \\(.+\\)$" str)
 841           (match-string 1 str)))
 842        (light-checkout-branch
 843         (when light-checkout
 844           (when (string-match ".+checkout of branch: \\(.+\\)$" str)
 845             (match-string 1 str)))))
 846     (concat
 847      (propertize "Parent branch      : " 'face 'font-lock-type-face)
 848      (propertize
 849       (if (string-match "parent branch: \\(.+\\)$" str)
 850           (match-string 1 str)
 851         "None")
 852        'face 'font-lock-variable-name-face)
 853      "\n"
 854       (when light-checkout
 855         (concat
 856          (propertize "Light checkout root: " 'face 'font-lock-type-face)
 857          (propertize light-checkout 'face 'font-lock-variable-name-face)
 858          "\n"))
 859       (when light-checkout-branch
 860         (concat
 861          (propertize "Checkout of branch : " 'face 'font-lock-type-face)
 862          (propertize light-checkout-branch 'face 'font-lock-variable-name-face)
 863          "\n"))
 864       (when pending-merge
 865         (concat
 866          (propertize "Warning            : " 'face 'font-lock-warning-face
 867                      'help-echo pending-merge-help-echo)
 868          (propertize "Pending merges, commit recommended before any other action"
 869                      'help-echo pending-merge-help-echo
 870                      'face 'font-lock-warning-face)
 871          "\n"))
 872       (if shelve
 873           (concat
 874            (propertize "Shelves            :\n" 'face 'font-lock-type-face
 875                        'help-echo shelve-help-echo)
 876            (mapconcat
 877             (lambda (x)
 878               (propertize x
 879                           'face 'font-lock-variable-name-face
 880                           'mouse-face 'highlight
 881                           'help-echo "mouse-3: Show shelve menu\nA: Apply and keep shelf\nP: Apply and remove shelf (pop)\nS: Snapshot to a shelf\nC-k: Delete shelf"
 882                           'keymap vc-bzr-shelve-map))
 883             shelve "\n"))
 884         (concat
 885          (propertize "Shelves            : " 'face 'font-lock-type-face
 886                      'help-echo shelve-help-echo)
 887          (propertize "No shelved changes"
 888                      'help-echo shelve-help-echo
 889                      'face 'font-lock-variable-name-face))))))
 890
 891 (defun vc-bzr-shelve (name)
 892   "Create a shelve."
 893   (interactive "sShelf name: ")
 894   (let ((root (vc-bzr-root default-directory)))
 895     (when root
 896       (vc-bzr-command "shelve" nil 0 nil "--all" "-m" name)
 897       (vc-resynch-buffer root t t))))
 898
 899 (defun vc-bzr-shelve-show (name)
 900   "Show the contents of shelve NAME."
 901   (interactive "sShelve name: ")
 902   (vc-setup-buffer "*vc-bzr-shelve*")
 903   ;; FIXME: how can you show the contents of a shelf?
 904   (vc-bzr-command "unshelve" "*vc-bzr-shelve*" 'async nil "--preview" name)
 905   (set-buffer "*vc-bzr-shelve*")
 906   (diff-mode)
 907   (setq buffer-read-only t)
 908   (pop-to-buffer (current-buffer)))
 909
 910 (defun vc-bzr-shelve-apply (name)
 911   "Apply shelve NAME and remove it afterwards."
 912   (interactive "sApply (and remove) shelf: ")
 913   (vc-bzr-command "unshelve" "*vc-bzr-shelve*" 0 nil "--apply" name)
 914   (vc-resynch-buffer (vc-bzr-root default-directory) t t))
 915
 916 (defun vc-bzr-shelve-apply-and-keep (name)
 917   "Apply shelve NAME and keep it afterwards."
 918   (interactive "sApply (and keep) shelf: ")
 919   (vc-bzr-command "unshelve" "*vc-bzr-shelve*" 0 nil "--apply" "--keep" name)
 920   (vc-resynch-buffer (vc-bzr-root default-directory) t t))
 921
 922 (defun vc-bzr-shelve-snapshot ()
 923   "Create a stash with the current tree state."
 924   (interactive)
 925   (vc-bzr-command "shelve" nil 0 nil "--all" "-m"
 926                   (let ((ct (current-time)))
 927                     (concat
 928                      (format-time-string "Snapshot on %Y-%m-%d" ct)
 929                      (format-time-string " at %H:%M" ct))))
 930   (vc-bzr-command "unshelve" "*vc-bzr-shelve*" 0 nil "--apply" "--keep")
 931   (vc-resynch-buffer (vc-bzr-root default-directory) t t))
 932
 933 (defun vc-bzr-shelve-list ()
 934   (with-temp-buffer
 935     (vc-bzr-command "shelve" (current-buffer) 1 nil "--list" "-q")
 936     (delete
 937      ""
 938      (split-string
 939       (buffer-substring (point-min) (point-max))
 940       "\n"))))
 941
 942 (defun vc-bzr-shelve-get-at-point (point)
 943   (save-excursion
 944     (goto-char point)
 945     (beginning-of-line)
 946     (if (looking-at "^ +\\([0-9]+\\):")
 947         (match-string 1)
 948       (error "Cannot find shelf at point"))))
 949
 950 (defun vc-bzr-shelve-delete-at-point ()
 951   (interactive)
 952   (let ((shelve (vc-bzr-shelve-get-at-point (point))))
 953     (when (y-or-n-p (format "Remove shelf %s ?" shelve))
 954       (vc-bzr-command "unshelve" nil 0 nil "--delete-only" shelve)
 955       (vc-dir-refresh))))
 956
 957 (defun vc-bzr-shelve-show-at-point ()
 958   (interactive)
 959   (vc-bzr-shelve-show (vc-bzr-shelve-get-at-point (point))))
 960
 961 (defun vc-bzr-shelve-apply-at-point ()
 962   (interactive)
 963   (vc-bzr-shelve-apply (vc-bzr-shelve-get-at-point (point))))
 964
 965 (defun vc-bzr-shelve-apply-and-keep-at-point ()
 966   (interactive)
 967   (vc-bzr-shelve-apply-and-keep (vc-bzr-shelve-get-at-point (point))))
 968
 969 (defun vc-bzr-shelve-menu (e)
 970   (interactive "e")
 971   (vc-dir-at-event e (popup-menu vc-bzr-shelve-menu-map e)))
 972
 973 (defun vc-bzr-revision-table (files)
 974   (let ((vc-bzr-revisions '())
 975         (default-directory (file-name-directory (car files))))
 976     (with-temp-buffer
 977       (vc-bzr-command "log" t 0 files "--line")
 978       (let ((start (point-min))
 979             (loglines (buffer-substring-no-properties (point-min) (point-max))))
 980         (while (string-match "^\\([0-9]+\\):" loglines)
 981           (push (match-string 1 loglines) vc-bzr-revisions)
 982           (setq start (+ start (match-end 0)))
 983           (setq loglines (buffer-substring-no-properties start (point-max))))))
 984     vc-bzr-revisions))
 985
 986 ;;; Revision completion
 987
 988 (eval-and-compile
 989   (defconst vc-bzr-revision-keywords
 990     '("revno" "revid" "last" "before"
 991       "tag" "date" "ancestor" "branch" "submit")))
 992
 993 (defun vc-bzr-revision-completion-table (files)
 994   (lexical-let ((files files))
 995     ;; What about using `files'?!?  --Stef
 996     (lambda (string pred action)
 997       (cond
 998        ((string-match "\\`\\(ancestor\\|branch\\|\\(revno:\\)?[-0-9]+:\\):"
 999                       string)
1000         (completion-table-with-context (substring string 0 (match-end 0))
1001                                        'completion-file-name-table
1002                                        (substring string (match-end 0))
1003                                        ;; Dropping `pred' for no good reason.
1004                                        'file-directory-p
1005                                        action))
1006        ((string-match "\\`\\(before\\):" string)
1007         (completion-table-with-context (substring string 0 (match-end 0))
1008                                        (vc-bzr-revision-completion-table files)
1009                                        (substring string (match-end 0))
1010                                        pred
1011                                        action))
1012        ((string-match "\\`\\(tag\\):" string)
1013         (let ((prefix (substring string 0 (match-end 0)))
1014               (tag (substring string (match-end 0)))
1015               (table nil)
1016               process-file-side-effects)
1017           (with-temp-buffer
1018             ;; "bzr-1.2 tags" is much faster with --show-ids.
1019             (process-file vc-bzr-program nil '(t) nil "tags" "--show-ids")
1020             ;; The output is ambiguous, unless we assume that revids do not
1021             ;; contain spaces.
1022             (goto-char (point-min))
1023             (while (re-search-forward "^\\(.*[^ \n]\\) +[^ \n]*$" nil t)
1024               (push (match-string-no-properties 1) table)))
1025           (completion-table-with-context prefix table tag pred action)))
1026
1027        ((string-match "\\`\\([a-z]+\\):" string)
1028         ;; no actual completion for the remaining keywords.
1029         (completion-table-with-context (substring string 0 (match-end 0))
1030                                        (if (member (match-string 1 string)
1031                                                    vc-bzr-revision-keywords)
1032                                            ;; If it's a valid keyword,
1033                                            ;; use a non-empty table to
1034                                            ;; indicate it.
1035                                            '("") nil)
1036                                        (substring string (match-end 0))
1037                                        pred
1038                                        action))
1039        (t
1040         ;; Could use completion-table-with-terminator, except that it
1041         ;; currently doesn't work right w.r.t pcm and doesn't give
1042         ;; the *Completions* output we want.
1043         (complete-with-action action (eval-when-compile
1044                                        (mapcar (lambda (s) (concat s ":"))
1045                                                vc-bzr-revision-keywords))
1046                               string pred))))))
1047
1048 (eval-after-load "vc"
1049   '(add-to-list 'vc-directory-exclusion-list vc-bzr-admin-dirname t))
1050
1051 (provide 'vc-bzr)
1052 ;; arch-tag: 8101bad8-4e92-4e7d-85ae-d8e08b4e7c06
1053 ;;; vc-bzr.el ends here