lisp/org/org-ctags.el

   1 ;;; org-ctags.el - Integrate Emacs "tags" facility with org mode.
   2 ;;
   3 ;; Copyright (C) 2007-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Paul Sexton <eeeickythump@gmail.com>
   6
   7
   8 ;; Keywords: org, wp
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;
  26 ;; Synopsis
  27 ;; ========
  28 ;;
  29 ;; Allows org-mode to make use of the Emacs `etags' system. Defines tag
  30 ;; destinations in org-mode files as any text between <<double angled
  31 ;; brackets>>. This allows the tags-generation program `exuberant ctags' to
  32 ;; parse these files and create tag tables that record where these
  33 ;; destinations are found. Plain [[links]] in org mode files which do not have
  34 ;; <<matching destinations>> within the same file will then be interpreted as
  35 ;; links to these 'tagged' destinations, allowing seamless navigation between
  36 ;; multiple org-mode files. Topics can be created in any org mode file and
  37 ;; will always be found by plain links from other files. Other file types
  38 ;; recognized by ctags (source code files, latex files, etc) will also be
  39 ;; available as destinations for plain links, and similarly, org-mode links
  40 ;; will be available as tags from source files. Finally, the function
  41 ;; `org-ctags-find-tag-interactive' lets you choose any known tag, using
  42 ;; autocompletion, and quickly jump to it.
  43 ;;
  44 ;; Installation
  45 ;; ============
  46 ;;
  47 ;; Install org mode
  48 ;; Ensure org-ctags.el is somewhere in your emacs load path.
  49 ;; Download and install Exuberant ctags -- "http://ctags.sourceforge.net/"
  50 ;; Edit your .emacs file (see next section) and load emacs.
  51
  52 ;; To put in your init file (.emacs):
  53 ;; ==================================
  54 ;;
  55 ;; Assuming you already have org mode installed and set up:
  56 ;;
  57 ;;    (setq org-ctags-path-to-ctags "/path/to/ctags/executable")
  58 ;;    (add-hook 'org-mode-hook
  59 ;;      (lambda ()
  60 ;;        (define-key org-mode-map "\C-co" 'org-ctags-find-tag-interactive)))
  61 ;;
  62 ;; By default, with org-ctags loaded, org will first try and visit the tag
  63 ;; with the same name as the link; then, if unsuccessful, ask the user if
  64 ;; he/she wants to rebuild the 'TAGS' database and try again; then ask if
  65 ;; the user wishes to append 'tag' as a new toplevel heading at the end of
  66 ;; the buffer; and finally, defer to org's default behaviour which is to
  67 ;; search the entire text of the current buffer for 'tag'.
  68 ;;
  69 ;; This behaviour can be modified by changing the value of
  70 ;; ORG-CTAGS-OPEN-LINK-FUNCTIONS. For example I have the following in my
  71 ;; .emacs, which describes the same behaviour as the above paragraph with
  72 ;; one difference:
  73 ;;
  74 ;; (setq org-ctags-open-link-functions
  75 ;;       '(org-ctags-find-tag
  76 ;;         org-ctags-ask-rebuild-tags-file-then-find-tag
  77 ;;         org-ctags-ask-append-topic
  78 ;;         org-ctags-fail-silently))  ; <-- prevents org default behaviour
  79 ;;
  80 ;;
  81 ;; Usage
  82 ;; =====
  83 ;;
  84 ;; When you click on a link "[[foo]]" and org cannot find a matching "<<foo>>"
  85 ;; in the current buffer, the tags facility will take over. The file TAGS in
  86 ;; the active directory is examined to see if the tags facility knows about
  87 ;; "<<foo>>" in any other files. If it does, the matching file will be opened
  88 ;; and the cursor will jump to the position of "<<foo>>" in that file.
  89 ;;
  90 ;; User-visible functions:
  91 ;; - `org-ctags-find-tag-interactive': type a tag (plain link) name and visit
  92 ;;   it. With autocompletion. Bound to ctrl-O in the above setup.
  93 ;; - All the etags functions should work. These include:
  94 ;;
  95 ;;      M-.    `find-tag' -- finds the tag at point
  96 ;;
  97 ;;      C-M-.  find-tag based on regular expression
  98 ;;
  99 ;;      M-x tags-search RET -- like C-M-. but searches through ENTIRE TEXT
 100 ;;             of ALL the files referenced in the TAGS file. A quick way to
 101 ;;             search through an entire 'project'.
 102 ;;
 103 ;;      M-*    "go back" from a tag jump. Like `org-mark-ring-goto'.
 104 ;;             You may need to bind this key yourself with (eg)
 105 ;;             (global-set-key (kbd "<M-kp-multiply>") 'pop-tag-mark)
 106 ;;
 107 ;;      (see etags chapter in Emacs manual for more)
 108 ;;
 109 ;;
 110 ;; Keeping the TAGS file up to date
 111 ;; ================================
 112 ;;
 113 ;; Tags mode has no way of knowing that you have created new tags by typing in
 114 ;; your org-mode buffer.  New tags make it into the TAGS file in 3 ways:
 115 ;;
 116 ;; 1. You re-run (org-ctags-create-tags "directory") to rebuild the file.
 117 ;; 2. You put the function `org-ctags-ask-rebuild-tags-file-then-find-tag' in
 118 ;;    your `org-open-link-functions' list, as is done in the setup
 119 ;;    above. This will cause the TAGS file to be rebuilt whenever a link
 120 ;;    cannot be found. This may be slow with large file collections however.
 121 ;; 3. You run the following from the command line (all 1 line):
 122 ;;
 123 ;;      ctags --langdef=orgmode --langmap=orgmode:.org
 124 ;;        --regex-orgmode="/<<([^>]+)>>/\1/d,definition/"
 125 ;;          -f /your/path/TAGS -e -R /your/path/*.org
 126 ;;
 127 ;; If you are paranoid, you might want to run (org-ctags-create-tags
 128 ;; "/path/to/org/files") at startup, by including the following toplevel form
 129 ;; in .emacs. However this can cause a pause of several seconds if ctags has
 130 ;; to scan lots of files.
 131 ;;
 132 ;;     (progn
 133 ;;       (message "-- rebuilding tags tables...")
 134 ;;       (mapc 'org-create-tags tags-table-list))
 135
 136 ;;; Code:
 137
 138 (eval-when-compile (require 'cl))
 139
 140 (require 'org)
 141
 142 (declare-function org-pop-to-buffer-same-window "org-compat" (&optional buffer-or-name norecord label))
 143
 144 (defgroup org-ctags nil
 145   "Options concerning use of ctags within org mode."
 146   :tag "Org-Ctags"
 147   :group 'org-link)
 148
 149 (defvar org-ctags-enabled-p t
 150   "Activate ctags support in org mode?")
 151
 152 (defvar org-ctags-tag-regexp "/<<([^>]+)>>/\\1/d,definition/"
 153   "Regexp expression used by ctags external program.
 154 The regexp matches tag destinations in org-mode files.
 155 Format is: /REGEXP/TAGNAME/FLAGS,TAGTYPE/
 156 See the ctags documentation for more information.")
 157
 158 (defcustom org-ctags-path-to-ctags
 159   (case system-type
 160     (windows-nt "ctags.exe")
 161     (darwin "ctags-exuberant")
 162     (t "ctags-exuberant"))
 163   "Full path to the ctags executable file."
 164   :group 'org-ctags
 165   :version "24.1"
 166   :type 'file)
 167
 168 (defcustom org-ctags-open-link-functions
 169   '(org-ctags-find-tag
 170     org-ctags-ask-rebuild-tags-file-then-find-tag
 171     org-ctags-ask-append-topic)
 172   "List of functions to be prepended to ORG-OPEN-LINK-FUNCTIONS when ORG-CTAGS is active."
 173   :group 'org-ctags
 174   :version "24.1"
 175   :type 'hook
 176   :options '(org-ctags-find-tag
 177              org-ctags-ask-rebuild-tags-file-then-find-tag
 178              org-ctags-rebuild-tags-file-then-find-tag
 179              org-ctags-ask-append-topic
 180              org-ctags-append-topic
 181              org-ctags-ask-visit-buffer-or-file
 182              org-ctags-visit-buffer-or-file
 183              org-ctags-fail-silently))
 184
 185
 186 (defvar org-ctags-tag-list nil
 187   "List of all tags in the active TAGS file.
 188 Created as a local variable in each buffer.")
 189
 190 (defcustom org-ctags-new-topic-template
 191   "<<%t>>\n\n\n\n\n\n"
 192   "Text to insert when creating a new org file via opening a hyperlink.
 193 The following patterns are replaced in the string:
 194     `%t' - replaced with the capitalized title of the hyperlink"
 195   :group 'org-ctags
 196   :type 'string)
 197
 198
 199 (add-hook 'org-mode-hook
 200           (lambda ()
 201             (when (and org-ctags-enabled-p
 202                        (buffer-file-name))
 203               ;; Make sure this file's directory is added to default
 204               ;; directories in which to search for tags.
 205               (let ((tags-filename
 206                      (expand-file-name
 207                       (concat (file-name-directory (buffer-file-name))
 208                               "/TAGS"))))
 209                 (when (file-exists-p tags-filename)
 210                   (visit-tags-table tags-filename))))))
 211
 212
 213 (defadvice visit-tags-table (after org-ctags-load-tag-list activate compile)
 214   (when (and org-ctags-enabled-p tags-file-name)
 215     (set (make-local-variable 'org-ctags-tag-list)
 216          (org-ctags-all-tags-in-current-tags-table))))
 217
 218
 219 (defun org-ctags-enable ()
 220   (put 'org-mode 'find-tag-default-function 'org-ctags-find-tag-at-point)
 221   (setq org-ctags-enabled-p t)
 222   (dolist (fn org-ctags-open-link-functions)
 223     (add-hook 'org-open-link-functions fn t)))
 224
 225
 226 ;;; General utility functions.  ===============================================
 227 ;; These work outside org-ctags mode.
 228
 229 (defun org-ctags-get-filename-for-tag (tag)
 230   "TAG is a string.  Search the active TAGS file for a matching tag.
 231 If the tag is found, return a list containing the filename, line number, and
 232 buffer position where the tag is found."
 233   (interactive "sTag: ")
 234   (unless tags-file-name
 235     (call-interactively (visit-tags-table)))
 236   (save-excursion
 237     (visit-tags-table-buffer 'same)
 238     (when tags-file-name
 239       (with-current-buffer (get-file-buffer tags-file-name)
 240         (goto-char (point-min))
 241         (cond
 242          ((re-search-forward (format "^.*\x7f%s\x01\\([0-9]+\\),\\([0-9]+\\)$"
 243                                      (regexp-quote tag)) nil t)
 244           (let ((line (string-to-number (match-string 1)))
 245                 (pos (string-to-number (match-string 2))))
 246             (cond
 247              ((re-search-backward "\f\n\\(.*\\),[0-9]+\n")
 248               (list (match-string 1) line pos))
 249              (t              ; can't find a file name preceding the matched
 250                              ; tag??
 251               (error "Malformed TAGS file: %s" (buffer-name))))))
 252          (t                               ; tag not found
 253           nil))))))
 254
 255
 256 (defun org-ctags-all-tags-in-current-tags-table ()
 257   "Read all tags defined in the active TAGS file, into a list of strings.
 258 Return the list."
 259   (interactive)
 260   (let ((taglist nil))
 261     (unless tags-file-name
 262       (call-interactively (visit-tags-table)))
 263     (save-excursion
 264       (visit-tags-table-buffer 'same)
 265       (with-current-buffer (get-file-buffer tags-file-name)
 266         (goto-char (point-min))
 267         (while (re-search-forward "^.*\x7f\\(.*\\)\x01\\([0-9]+\\),\\([0-9]+\\)$"
 268                                   nil t)
 269           (push (substring-no-properties (match-string 1)) taglist)))
 270       taglist)))
 271
 272
 273 (defun org-ctags-string-search-and-replace (search replace string)
 274   "Replace all instances of SEARCH with REPLACE in STRING."
 275   (replace-regexp-in-string (regexp-quote search) replace string t t))
 276
 277
 278 (defun y-or-n-minibuffer (prompt)
 279   (let ((use-dialog-box nil))
 280     (y-or-n-p prompt)))
 281
 282
 283 ;;; Internal functions =======================================================
 284
 285
 286 (defun org-ctags-open-file (name &optional title)
 287   "Visit or create a file called `NAME.org', and insert a new topic.
 288 The new topic will be titled NAME (or TITLE if supplied)."
 289   (interactive "sFile name: ")
 290   (let ((filename (substitute-in-file-name (expand-file-name name))))
 291     (condition-case v
 292         (progn
 293           (org-open-file name t)
 294           (message "Opened file OK")
 295           (goto-char (point-max))
 296           (insert (org-ctags-string-search-and-replace
 297                    "%t" (capitalize (or title name))
 298                    org-ctags-new-topic-template))
 299           (message "Inserted new file text OK")
 300           (org-mode-restart))
 301       (error (error "Error %S in org-ctags-open-file" v)))))
 302
 303
 304 ;;;; Misc interoperability with etags system =================================
 305
 306
 307 (defadvice find-tag (before org-ctags-set-org-mark-before-finding-tag
 308                             activate compile)
 309   "Before trying to find a tag, save our current position on org mark ring."
 310   (save-excursion
 311     (if (and (eq major-mode 'org-mode) org-ctags-enabled-p)
 312         (org-mark-ring-push))))
 313
 314
 315
 316 (defun org-ctags-find-tag-at-point ()
 317   "Determine default tag to search for, based on text at point.
 318 If there is no plausible default, return nil."
 319   (let (from to bound)
 320     (when (or (ignore-errors
 321                 ;; Look for hyperlink around `point'.
 322                 (save-excursion
 323                   (search-backward "[[") (setq from (+ 2 (point))))
 324                 (save-excursion
 325                   (goto-char from)
 326                   (search-forward "]") (setq to (- (point) 1)))
 327                 (and (> to from) (>= (point) from) (<= (point) to)))
 328               (progn
 329                 ;; Look at text around `point'.
 330                 (save-excursion
 331                   (skip-syntax-backward "w_") (setq from (point)))
 332                 (save-excursion
 333                   (skip-syntax-forward "w_") (setq to (point)))
 334                 (> to from))
 335               ;; Look between `line-beginning-position' and `point'.
 336               (save-excursion
 337                 (and (setq bound (line-beginning-position))
 338                      (skip-syntax-backward "^w_" bound)
 339                      (> (setq to (point)) bound)
 340                      (skip-syntax-backward "w_")
 341                      (setq from (point))))
 342               ;; Look between `point' and `line-end-position'.
 343               (save-excursion
 344                 (and (setq bound (line-end-position))
 345                      (skip-syntax-forward "^w_" bound)
 346                      (< (setq from (point)) bound)
 347                      (skip-syntax-forward "w_")
 348                      (setq to (point)))))
 349       (buffer-substring-no-properties from to))))
 350
 351
 352 ;;; Functions for use with 'org-open-link-functions' hook =================
 353
 354
 355 (defun org-ctags-find-tag (name)
 356   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 357 Look for a tag called `NAME' in the current TAGS table.  If it is found,
 358 visit the file and location where the tag is found."
 359   (interactive "sTag: ")
 360   (let ((old-buf (current-buffer))
 361         (old-pnt (point-marker))
 362         (old-mark (copy-marker (mark-marker))))
 363     (condition-case nil
 364         (progn (find-tag name)
 365                t)
 366       (error
 367        ;; only restore old location if find-tag raises error
 368        (set-buffer old-buf)
 369        (goto-char old-pnt)
 370        (set-marker (mark-marker) old-mark)
 371        nil))))
 372
 373
 374 (defun org-ctags-visit-buffer-or-file (name &optional create)
 375   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 376 Visit buffer named `NAME.org'.  If there is no such buffer, visit the file
 377 with the same name if it exists.  If the file does not exist, then behavior
 378 depends on the value of CREATE.
 379
 380 If CREATE is nil (default), then return nil.  Do not create a new file.
 381 If CREATE is t, create the new file and visit it.
 382 If CREATE is the symbol `ask', then ask the user if they wish to create
 383 the new file."
 384   (interactive)
 385   (let ((filename (concat (substitute-in-file-name
 386                            (expand-file-name name))
 387                           ".org")))
 388     (cond
 389      ((get-buffer (concat name ".org"))
 390       ;; Buffer is already open
 391       (org-pop-to-buffer-same-window (get-buffer (concat name ".org"))))
 392      ((file-exists-p filename)
 393       ;; File exists but is not open --> open it
 394       (message "Opening existing org file `%S'..."
 395                filename)
 396       (org-open-file filename t))
 397      ((or (eql create t)
 398           (and (eql create 'ask)
 399                (y-or-n-p (format "File `%s.org' not found; create?" name))))
 400       (org-ctags-open-file filename name))
 401      (t ;; File does not exist, and we don't want to create it.
 402       nil))))
 403
 404
 405 (defun org-ctags-ask-visit-buffer-or-file (name)
 406   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 407 Wrapper for org-ctags-visit-buffer-or-file, which ensures the user is
 408 asked before creating a new file."
 409   (org-ctags-visit-buffer-or-file name 'ask))
 410
 411
 412 (defun org-ctags-append-topic (name &optional narrowp)
 413   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 414 Append a new toplevel heading to the end of the current buffer. The
 415 heading contains NAME surrounded by <<angular brackets>>, thus making
 416 the heading a destination for the tag `NAME'."
 417   (interactive "sTopic: ")
 418   (widen)
 419   (goto-char (point-max))
 420   (newline 2)
 421   (message "Adding topic in buffer %s" (buffer-name))
 422   (insert (org-ctags-string-search-and-replace
 423            "%t" (capitalize name) org-ctags-new-topic-template))
 424   (backward-char 4)
 425   (org-update-radio-target-regexp)
 426   (end-of-line)
 427   (forward-line 2)
 428   (when narrowp
 429     ;;(org-tree-to-indirect-buffer 1)  ;; opens new frame
 430     (org-narrow-to-subtree))
 431   t)
 432
 433
 434 (defun org-ctags-ask-append-topic (name &optional narrowp)
 435   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 436 Wrapper for org-ctags-append-topic, which first asks the user if they want
 437 to append a new topic."
 438   (if (y-or-n-p (format "Topic `%s' not found; append to end of buffer?"
 439                         name))
 440       (org-ctags-append-topic name narrowp)
 441     nil))
 442
 443
 444 (defun org-ctags-rebuild-tags-file-then-find-tag (name)
 445   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 446 Like ORG-CTAGS-FIND-TAG, but calls the external ctags program first,
 447 to rebuild (update) the TAGS file."
 448   (unless tags-file-name
 449     (call-interactively (visit-tags-table)))
 450   (when (buffer-file-name)
 451     (org-ctags-create-tags))
 452   (org-ctags-find-tag name))
 453
 454
 455 (defun org-ctags-ask-rebuild-tags-file-then-find-tag (name)
 456   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 457 Wrapper for org-ctags-rebuild-tags-file-then-find-tag."
 458   (if (and (buffer-file-name)
 459              (y-or-n-p
 460               (format
 461                "Tag `%s' not found.  Rebuild table `%s/TAGS' and look again?"
 462                name
 463                (file-name-directory (buffer-file-name)))))
 464     (org-ctags-rebuild-tags-file-then-find-tag name)
 465     nil))
 466
 467
 468 (defun org-ctags-fail-silently (name)
 469   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 470 Put as the last function in the list if you want to prevent org's default
 471 behavior of free text search."
 472   t)
 473
 474
 475 ;;; User-visible functions ===================================================
 476
 477
 478 (defun org-ctags-create-tags (&optional directory-name)
 479   "(Re)create tags file in the directory of the active buffer.
 480 The file will contain tag definitions for all the files in the
 481 directory and its subdirectories which are recognized by ctags.
 482 This will include files ending in `.org' as well as most other
 483 source files (.C, .H, .EL, .LISP, etc).  All the resulting tags
 484 end up in one file, called TAGS, located in the directory.  This
 485 function may take several seconds to finish if the directory or
 486 its subdirectories contain large numbers of taggable files."
 487   (interactive)
 488   (assert (buffer-file-name))
 489   (let ((dir-name (or directory-name
 490                       (file-name-directory (buffer-file-name))))
 491         (exitcode nil))
 492     (save-excursion
 493       (setq exitcode
 494             (shell-command
 495              (format (concat "%s --langdef=orgmode --langmap=orgmode:.org "
 496                              "--regex-orgmode=\"%s\" -f \"%s\" -e -R \"%s\"")
 497                      org-ctags-path-to-ctags
 498                      org-ctags-tag-regexp
 499                      (expand-file-name (concat dir-name "/TAGS"))
 500                      (expand-file-name (concat dir-name "/*")))))
 501       (cond
 502        ((eql 0 exitcode)
 503         (set (make-local-variable 'org-ctags-tag-list)
 504              (org-ctags-all-tags-in-current-tags-table)))
 505        (t
 506         ;; This seems to behave differently on Linux, so just ignore
 507         ;; error codes for now
 508         ;;(error "Calling ctags executable resulted in error code: %s"
 509         ;;       exitcode)
 510         nil)))))
 511
 512
 513 (defvar org-ctags-find-tag-history nil
 514   "History of tags visited by org-ctags-find-tag-interactive.")
 515
 516 (defun org-ctags-find-tag-interactive ()
 517   "Prompt for the name of a tag, with autocompletion, then visit the named tag.
 518 Uses `ido-mode' if available.
 519 If the user enters a string that does not match an existing tag, create
 520 a new topic."
 521   (interactive)
 522   (let* ((completing-read-fn (if (fboundp 'ido-completing-read)
 523                                  'ido-completing-read
 524                                'completing-read))
 525          (tag (funcall completing-read-fn "Topic: " org-ctags-tag-list
 526                        nil 'confirm nil 'org-ctags-find-tag-history)))
 527     (when tag
 528       (cond
 529        ((member tag org-ctags-tag-list)
 530         ;; Existing tag
 531         (push tag org-ctags-find-tag-history)
 532         (find-tag tag))
 533        (t
 534         ;; New tag
 535         (run-hook-with-args-until-success
 536                 'org-open-link-functions tag))))))
 537
 538
 539 (org-ctags-enable)
 540
 541 (provide 'org-ctags)
 542
 543 ;;; org-ctags.el ends here