lisp/emacs-lisp/check-declare.el

   1 ;;; check-declare.el --- Check declare-function statements
   2
   3 ;; Copyright (C) 2007-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Glenn Morris <rgm@gnu.org>
   6 ;; Keywords: lisp, tools, maint
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; The byte-compiler often warns about undefined functions that you
  26 ;; know will actually be defined when it matters.  The `declare-function'
  27 ;; statement allows you to suppress these warnings.  This package
  28 ;; checks that all such statements in a file or directory are accurate.
  29 ;; The entry points are `check-declare-file' and `check-declare-directory'.
  30
  31 ;; For more information, see Info node `(elisp)Declaring Functions'.
  32
  33 ;;; TODO:
  34
  35 ;; 1. Warn about functions marked as obsolete, eg
  36 ;; password-read-and-add in smime.el.
  37 ;; 2. defmethod, defclass argument checking.
  38 ;; 3. defclass also defines -p and -child-p.
  39
  40 ;;; Code:
  41
  42 (defconst check-declare-warning-buffer "*Check Declarations Warnings*"
  43   "Name of buffer used to display any `check-declare' warnings.")
  44
  45 (defun check-declare-locate (file basefile)
  46   "Return the full path of FILE.
  47 Expands files with a \".c\" or \".m\" extension relative to the Emacs
  48 \"src/\" directory.  Otherwise, `locate-library' searches for FILE.
  49 If that fails, expands FILE relative to BASEFILE's directory part.
  50 The returned file might not exist.  If FILE has an \"ext:\" prefix, so does
  51 the result."
  52   (let ((ext (string-match "^ext:" file))
  53         tfile)
  54     (if ext
  55         (setq file (substring file 4)))
  56     (setq file
  57           (if (member (file-name-extension file) '("c" "m"))
  58               (expand-file-name file (expand-file-name "src" source-directory))
  59             (if (setq tfile (locate-library file))
  60                 (progn
  61                   (setq tfile
  62                         (replace-regexp-in-string "\\.elc\\'" ".el" tfile))
  63                   (if (and (not (file-exists-p tfile))
  64                            (file-exists-p (concat tfile ".gz")))
  65                       (concat tfile ".gz")
  66                     tfile))
  67               (setq tfile (expand-file-name file
  68                                             (file-name-directory basefile)))
  69               (if (or (file-exists-p tfile)
  70                       (string-match "\\.el\\'" tfile))
  71                   tfile
  72                 (concat tfile ".el")))))
  73     (if ext (concat "ext:" file)
  74       file)))
  75
  76 (defun check-declare-scan (file)
  77   "Scan FILE for `declare-function' calls.
  78 Return a list with elements of the form (FNFILE FN ARGLIST FILEONLY),
  79 where only the first two elements need be present.  This claims that FNFILE
  80 defines FN, with ARGLIST.  FILEONLY non-nil means only check that FNFILE
  81 exists, not that it defines FN.  This is for function definitions that we
  82 don't know how to recognize (e.g. some macros)."
  83   (let ((m (format "Scanning %s..." file))
  84         alist form len fn fnfile arglist fileonly)
  85     (message "%s" m)
  86     (with-temp-buffer
  87       (insert-file-contents file)
  88       ;; FIXME we could theoretically be inside a string.
  89       (while (re-search-forward "^[ \t]*\\((declare-function\\)[ \t\n]" nil t)
  90         (goto-char (match-beginning 1))
  91         (if (and (setq form (ignore-errors (read (current-buffer))))
  92                  ;; Exclude element of byte-compile-initial-macro-environment.
  93                  (or (listp (cdr form)) (setq form nil))
  94                  (> (setq len (length form)) 2)
  95                  (< len 6)
  96                  (symbolp (setq fn (cadr form)))
  97                  (setq fn (symbol-name fn)) ; later we use as a search string
  98                  (stringp (setq fnfile (nth 2 form)))
  99                  (setq fnfile (check-declare-locate fnfile
 100                                                     (expand-file-name file)))
 101                  ;; Use t to distinguish unspecified arglist from empty one.
 102                  (or (eq t (setq arglist (if (> len 3)
 103                                              (nth 3 form)
 104                                            t)))
 105                      (listp arglist))
 106                  (symbolp (setq fileonly (nth 4 form))))
 107             (setq alist (cons (list fnfile fn arglist fileonly) alist))
 108           ;; FIXME make this more noticeable.
 109           (if form (message "Malformed declaration for `%s'" (cadr form))))))
 110     (message "%sdone" m)
 111     alist))
 112
 113 (defun check-declare-errmsg (errlist &optional full)
 114   "Return a string with the number of errors in ERRLIST, if any.
 115 Normally just counts the number of elements in ERRLIST.
 116 With optional argument FULL, sums the number of elements in each element."
 117   (if errlist
 118       (let ((l (length errlist)))
 119         (when full
 120           (setq l 0)
 121           (dolist (e errlist)
 122             (setq l (+ l (1- (length e))))))
 123         (format "%d problem%s found" l (if (= l 1) "" "s")))
 124     "OK"))
 125
 126 (autoload 'byte-compile-arglist-signature "bytecomp")
 127
 128 (defgroup check-declare nil
 129   "Check declare-function statements."
 130   :group 'tools)
 131
 132 (defcustom check-declare-ext-errors nil
 133   "When non-nil, warn about functions not found in :ext."
 134   :type 'boolean)
 135
 136 (defun check-declare-verify (fnfile fnlist)
 137   "Check that FNFILE contains function definitions matching FNLIST.
 138 Each element of FNLIST has the form (FILE FN ARGLIST FILEONLY), where
 139 only the first two elements need be present.  This means FILE claimed FN
 140 was defined in FNFILE with the specified ARGLIST.  FILEONLY non-nil means
 141 to only check that FNFILE exists, not that it actually defines FN.
 142
 143 Returns nil if all claims are found to be true, otherwise a list
 144 of errors with elements of the form \(FILE FN TYPE), where TYPE
 145 is a string giving details of the error."
 146   (let ((m (format "Checking %s..." fnfile))
 147         (cflag (member (file-name-extension fnfile) '("c" "m")))
 148         (ext (string-match "^ext:" fnfile))
 149         re fn sig siglist arglist type errlist minargs maxargs)
 150     (message "%s" m)
 151     (if ext
 152         (setq fnfile (substring fnfile 4)))
 153     (if (file-regular-p fnfile)
 154         (with-temp-buffer
 155           (insert-file-contents fnfile)
 156           ;; defsubst's don't _have_ to be known at compile time.
 157           (setq re (format (if cflag
 158                                "^[ \t]*\\(DEFUN\\)[ \t]*([ \t]*\"%s\""
 159                              "^[ \t]*(\\(fset[ \t]+'\\|\
 160 cl-def\\(?:generic\\|method\\)\\|\
 161 def\\(?:un\\|subst\\|foo\\|method\\|class\\|\
 162 ine-\\(?:derived\\|generic\\|\\(?:global\\(?:ized\\)?-\\)?minor\\)-mode\\|\
 163 \\(?:ine-obsolete-function-\\)?alias[ \t]+'\\|\
 164 ine-overloadable-function\\)\\)\
 165 [ \t]*%s\\([ \t;]+\\|$\\)")
 166                            (regexp-opt (mapcar 'cadr fnlist) t)))
 167           (while (re-search-forward re nil t)
 168             (skip-chars-forward " \t\n")
 169             (setq fn (match-string 2)
 170                   type (match-string 1)
 171                   ;; (min . max) for a fixed number of arguments, or
 172                   ;; arglists with optional elements.
 173                   ;; (min) for arglists with &rest.
 174                   ;; sig = 'err means we could not find an arglist.
 175                   sig (cond (cflag
 176                              (or
 177                               (when (search-forward "," nil t 3)
 178                                 (skip-chars-forward " \t\n")
 179                                 ;; Assuming minargs and maxargs on same line.
 180                                 (when (looking-at "\\([0-9]+\\)[ \t]*,[ \t]*\
 181 \\([0-9]+\\|MANY\\|UNEVALLED\\)")
 182                                   (setq minargs (string-to-number
 183                                                  (match-string 1))
 184                                         maxargs (match-string 2))
 185                                   (cons minargs (unless (string-match "[^0-9]"
 186                                                                       maxargs)
 187                                                  (string-to-number
 188                                                   maxargs)))))
 189                               'err))
 190                             ((string-match
 191                               "\\`define-\\(derived\\|generic\\)-mode\\'"
 192                               type)
 193                              '(0 . 0))
 194                             ((string-match
 195                               "\\`define\\(-global\\(ized\\)?\\)?-minor-mode\\'"
 196                               type)
 197                              '(0 . 1))
 198                             ;; Prompt to update.
 199                             ((string-match
 200                               "\\`define-obsolete-function-alias\\>"
 201                               type)
 202                              'obsolete)
 203                             ;; Can't easily check arguments in these cases.
 204                             ((string-match "\\`\\(def\\(alias\\|class\\)\\|\
 205 fset\\|\\(?:cl-\\)?defmethod\\)\\>" type)
 206                              t)
 207                             ((looking-at "\\((\\|nil\\)")
 208                              (byte-compile-arglist-signature
 209                               (read (current-buffer))))
 210                             (t
 211                              'err))
 212                   ;; alist of functions and arglist signatures.
 213                   siglist (cons (cons fn sig) siglist)))))
 214     (dolist (e fnlist)
 215       (setq arglist (nth 2 e)
 216             type
 217             (if (not re)
 218                 "file not found"
 219               (if (not (setq sig (assoc (cadr e) siglist)))
 220                   (unless (nth 3 e)     ; fileonly
 221                     "function not found")
 222                 (setq sig (cdr sig))
 223                 (cond ((eq sig 'obsolete) ; check even when no arglist specified
 224                        "obsolete alias")
 225                       ;; arglist t means no arglist specified, as
 226                       ;; opposed to an empty arglist.
 227                       ((eq arglist t) nil)
 228                       ((eq sig t) nil) ; eg defalias - can't check arguments
 229                       ((eq sig 'err)
 230                        "arglist not found") ; internal error
 231                       ((not (equal (byte-compile-arglist-signature
 232                                     arglist)
 233                                    sig))
 234                        "arglist mismatch")))))
 235       (when type
 236         (setq errlist (cons (list (car e) (cadr e) type) errlist))))
 237     (message "%s%s" m
 238              (if (or re (or check-declare-ext-errors
 239                             (not ext)))
 240                  (check-declare-errmsg errlist)
 241                (progn
 242                  (setq errlist nil)
 243                  "skipping external file")))
 244     errlist))
 245
 246 (defun check-declare-sort (alist)
 247   "Sort a list with elements FILE (FNFILE ...).
 248 Returned list has elements FNFILE (FILE ...)."
 249   (let (file fnfile rest sort a)
 250     (dolist (e alist)
 251       (setq file (car e))
 252       (dolist (f (cdr e))
 253         (setq fnfile (car f)
 254               rest (cdr f))
 255         (if (setq a (assoc fnfile sort))
 256             (setcdr a (append (cdr a) (list (cons file rest))))
 257           (setq sort (cons (list fnfile (cons file rest)) sort)))))
 258     sort))
 259
 260 (defun check-declare-warn (file fn fnfile type)
 261   "Warn that FILE made a false claim about FN in FNFILE.
 262 TYPE is a string giving the nature of the error.  Warning is displayed in
 263 `check-declare-warning-buffer'."
 264   (let ((warning-prefix-function
 265          (lambda (level entry)
 266            (let ((line 0)
 267                  (col 0))
 268              (insert
 269               (with-current-buffer (find-file-noselect file)
 270                 (goto-char (point-min))
 271                 (when (re-search-forward
 272                        (format "(declare-function[ \t\n]+%s" fn) nil t)
 273                   (goto-char (match-beginning 0))
 274                   (setq line (line-number-at-pos))
 275                   (setq col (1+ (current-column))))
 276                 (format "%s:%d:%d:"
 277                         (file-name-nondirectory file)
 278                         line col))))
 279            entry))
 280         (warning-fill-prefix "    "))
 281     (display-warning 'check-declare
 282                      (format-message "said `%s' was defined in %s: %s"
 283                                      fn (file-name-nondirectory fnfile) type)
 284                      nil check-declare-warning-buffer)))
 285
 286 (declare-function compilation-forget-errors "compile" ())
 287
 288 (defun check-declare-files (&rest files)
 289   "Check veracity of all `declare-function' statements in FILES.
 290 Return a list of any errors found."
 291   (let (alist err errlist)
 292     (dolist (file files)
 293       (setq alist (cons (cons file (check-declare-scan file)) alist)))
 294     ;; Sort so that things are ordered by the files supposed to
 295     ;; contain the defuns.
 296     (dolist (e (check-declare-sort alist))
 297       (if (setq err (check-declare-verify (car e) (cdr e)))
 298           (setq errlist (cons (cons (car e) err) errlist))))
 299     (setq errlist (nreverse errlist))
 300     (if (get-buffer check-declare-warning-buffer)
 301         (kill-buffer check-declare-warning-buffer))
 302     (with-current-buffer (get-buffer-create check-declare-warning-buffer)
 303       (unless (derived-mode-p 'compilation-mode)
 304         (compilation-mode))
 305       (let ((inhibit-read-only t))
 306         (insert "\f\n"))
 307       (compilation-forget-errors))
 308     ;; Sort back again so that errors are ordered by the files
 309     ;; containing the declare-function statements.
 310     (dolist (e (check-declare-sort errlist))
 311       (dolist (f (cdr e))
 312         (check-declare-warn (car e) (cadr f) (car f) (nth 2 f))))
 313     errlist))
 314
 315 ;;;###autoload
 316 (defun check-declare-file (file)
 317   "Check veracity of all `declare-function' statements in FILE.
 318 See `check-declare-directory' for more information."
 319   (interactive "fFile to check: ")
 320   (or (file-exists-p file)
 321       (error "File `%s' not found" file))
 322   (let ((m (format "Checking %s..." file))
 323         errlist)
 324     (message "%s" m)
 325     (setq errlist (check-declare-files file))
 326     (message "%s%s" m (check-declare-errmsg errlist))
 327     errlist))
 328
 329 ;;;###autoload
 330 (defun check-declare-directory (root)
 331   "Check veracity of all `declare-function' statements under directory ROOT.
 332 Returns non-nil if any false statements are found."
 333   (interactive "DDirectory to check: ")
 334   (or (file-directory-p (setq root (expand-file-name root)))
 335       (error "Directory `%s' not found" root))
 336   (let ((m "Checking `declare-function' statements...")
 337         (m2 "Finding files with declarations...")
 338         errlist files)
 339     (message "%s" m)
 340     (message "%s" m2)
 341     (setq files (process-lines find-program root
 342                                "-name" "*.el"
 343                                "-exec" grep-program
 344                                "-l" "^[ \t]*(declare-function" "{}" ";"))
 345     (message "%s%d found" m2 (length files))
 346     (when files
 347       (setq errlist (apply 'check-declare-files files))
 348       (message "%s%s" m (check-declare-errmsg errlist t))
 349       errlist)))
 350
 351 (provide 'check-declare)
 352
 353 ;;; check-declare.el ends here.