| blob | 4c1dda688966cbd35ebdf046c017f32ff26c515b |
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004, 2005
7 dnl Free Software Foundation, Inc.
8 dnl
9 dnl This file is part of GNU Emacs.
10 dnl
11 dnl GNU Emacs is free software; you can redistribute it and/or modify
12 dnl it under the terms of the GNU General Public License as published by
13 dnl the Free Software Foundation; either version 2, or (at your option)
14 dnl any later version.
15 dnl
16 dnl GNU Emacs is distributed in the hope that it will be useful,
17 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
18 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19 dnl GNU General Public License for more details.
20 dnl
21 dnl You should have received a copy of the GNU General Public License
22 dnl along with GNU Emacs; see the file COPYING. If not, write to the
23 dnl Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
24 dnl Boston, MA 02110-1301, USA.
26 AC_PREREQ(2.54)dnl
27 AC_INIT(src/lisp.h)
28 AC_CONFIG_HEADER(src/config.h:src/config.in)
30 dnl Support for --program-prefix, --program-suffix and
31 dnl --program-transform-name options
32 AC_ARG_PROGRAM
34 lispdir='${datadir}/emacs/${version}/lisp'
35 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
36 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
37 lisppath='${locallisppath}:${lispdir}'
38 etcdir='${datadir}/emacs/${version}/etc'
39 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
40 docdir='${datadir}/emacs/${version}/etc'
41 gamedir='${localstatedir}/games/emacs'
43 gameuser=games
45 AC_ARG_WITH(gcc,
46 [ --without-gcc don't use GCC to compile Emacs if GCC is found])
47 AC_ARG_WITH(pop,
48 [ --without-pop don't support POP mail retrieval with movemail],
49 [if test "$withval" = yes; then
50 AC_DEFINE(MAIL_USE_POP)
51 else :
52 fi],
53 AC_DEFINE(MAIL_USE_POP))
54 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
55 AC_ARG_WITH(kerberos,
56 [ --with-kerberos support Kerberos-authenticated POP],
57 [AC_DEFINE(KERBEROS)])
58 AH_TEMPLATE(KERBEROS,
59 [Define to support Kerberos-authenticated POP mail retrieval.])dnl
60 AC_ARG_WITH(kerberos5,
61 [ --with-kerberos5 support Kerberos version 5 authenticated POP],
62 [if test "${with_kerberos5+set}" = set; then
63 if test "${with_kerberos+set}" != set; then
64 with_kerberos=yes
65 AC_DEFINE(KERBEROS)
66 fi
67 fi
68 AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])])
69 AC_ARG_WITH(hesiod,
70 [ --with-hesiod support Hesiod to get the POP server host],
71 [AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])])
73 AC_ARG_WITH(sound,
74 [ --without-sound don't compile with sound support])
76 dnl This should be the last --with option, because --with-x is
77 dnl added later on when we find the path of X, and it's best to
78 dnl keep them together visually.
79 AC_ARG_WITH(x-toolkit,
80 [ --with-x-toolkit=KIT use an X toolkit
81 (KIT = yes/lucid/athena/motif/gtk/no)],
82 [ case "${withval}" in
83 y | ye | yes ) val=athena ;;
84 n | no ) val=no ;;
85 l | lu | luc | luci | lucid ) val=lucid ;;
86 a | at | ath | athe | athen | athena ) val=athena ;;
87 m | mo | mot | moti | motif ) val=motif ;;
88 g | gt | gtk ) val=gtk ;;
89 dnl These don't currently work.
90 dnl o | op | ope | open | open- | open-l | open-lo \
91 dnl | open-loo | open-look ) val=open-look ;;
92 * )
93 dnl AC_MSG_ERROR([the `--with-x-toolkit' option is supposed to have a value
94 dnl which is `yes', `no', `lucid', `athena', `motif' or `open-look'.])
95 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid\;
96 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
97 Currently, `yes', `athena' and `lucid' are synonyms.])
98 ;;
99 esac
100 with_x_toolkit=$val
101 ])
102 AC_ARG_WITH(xpm,
103 [ --with-xpm use -lXpm for displaying XPM images])
104 AC_ARG_WITH(jpeg,
105 [ --with-jpeg use -ljpeg for displaying JPEG images])
106 AC_ARG_WITH(tiff,
107 [ --with-tiff use -ltiff for displaying TIFF images])
108 AC_ARG_WITH(gif,
109 [ --with-gif use -lungif for displaying GIF images])
110 AC_ARG_WITH(png,
111 [ --with-png use -lpng for displaying PNG images])
112 AC_ARG_WITH(gtk,
113 [ --with-gtk use GTK (same as --with-x-toolkit=gtk)])
114 AC_ARG_WITH(pkg-config-prog,
115 [ --with-pkg-config-prog Path to pkg-config to use for finding GTK])
116 AC_ARG_WITH(toolkit-scroll-bars,
117 [ --without-toolkit-scroll-bars
118 don't use Motif or Xaw3d scroll bars])
119 AC_ARG_WITH(xim,
120 [ --without-xim don't use X11 XIM])
121 AC_ARG_WITH(carbon,
122 [ --without-carbon don't use Carbon GUI on Mac OS X])
123 AC_ARG_ENABLE(carbon-app,
124 [[ --enable-carbon-app[=DIR] [DIR=/Application]
125 specify install directory for Emacs.app on Mac OS X]],
126 [ carbon_appdir_x=${enableval}])
128 AC_ARG_ENABLE(asserts,
129 [ --enable-asserts compile code with asserts enabled],
130 USE_XASSERTS=$enableval,
131 USE_XASSERTS=no)
133 AC_ARG_ENABLE(maintainer-mode,
134 [ --enable-maintainer-mode enable make rules and dependencies not useful
135 (and sometimes confusing) to the casual installer],
136 USE_MAINTAINER_MODE=$enableval,
137 USE_MAINTAINER_MODE=no)
138 if test $USE_MAINTAINER_MODE = yes; then
139 MAINT=
140 else
141 MAINT=#
142 fi
143 AC_SUBST(MAINT)
145 AC_ARG_ENABLE(locallisppath,
146 [ --enable-locallisppath=PATH
147 directories Emacs should search for lisp files
148 specific to this site],
149 if test "${enableval}" = "no"; then
150 locallisppath=
151 elif test "${enableval}" != "yes"; then
152 locallisppath=${enableval}
153 fi)
155 #### Make srcdir absolute, if it isn't already. It's important to
156 #### avoid running the path through pwd unnecessarily, since pwd can
157 #### give you automounter prefixes, which can go away. We do all this
158 #### so Emacs can find its files when run uninstalled.
159 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
160 unset CDPATH
161 case "${srcdir}" in
162 /* ) ;;
163 . )
164 ## We may be able to use the $PWD environment variable to make this
165 ## absolute. But sometimes PWD is inaccurate.
166 ## Note: we used to use ${PWD} at the end instead of `pwd`,
167 ## but that tested only for a well-formed and valid PWD,
168 ## it did not object when PWD was well-formed and valid but just wrong.
169 if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`" ;
170 then
171 srcdir="$PWD"
172 else
173 srcdir="`(cd ${srcdir}; pwd)`"
174 fi
175 ;;
176 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
177 esac
179 #### Check if the source directory already has a configured system in it.
180 if test `pwd` != `(cd ${srcdir} && pwd)` \
181 && test -f "${srcdir}/src/config.h" ; then
182 AC_MSG_WARN([[The directory tree `${srcdir}' is being used
183 as a build directory right now; it has been configured in its own
184 right. To configure in another directory as well, you MUST
185 use GNU make. If you do not have GNU make, then you must
186 now do `make distclean' in ${srcdir},
187 and then run $0 again.]])
188 fi
190 #### Given the configuration name, set machfile and opsysfile to the
191 #### names of the m/*.h and s/*.h files we should use.
193 ### Canonicalize the configuration name.
195 AC_CANONICAL_HOST
196 canonical=$host
197 configuration=${host_alias-$host}
199 dnl This used to use changequote, but, apart from `changequote is evil'
200 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
201 dnl the great gob of text. Thus it's not processed for possible expansion.
202 dnl Just make sure the brackets remain balanced.
203 dnl
204 dnl Since Emacs can't find matching pairs of quotes, boundaries are
205 dnl indicated by comments.
206 dnl quotation begins
207 [
209 ### If you add support for a new configuration, add code to this
210 ### switch statement to recognize your configuration name and select
211 ### the appropriate operating system and machine description files.
213 ### You would hope that you could choose an m/*.h file pretty much
214 ### based on the machine portion of the configuration name, and an s-
215 ### file based on the operating system portion. However, it turns out
216 ### that each m/*.h file is pretty manufacturer-specific - for
217 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
218 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
219 ### machines. So we basically have to have a special case for each
220 ### configuration name.
221 ###
222 ### As far as handling version numbers on operating systems is
223 ### concerned, make sure things will fail in a fixable way. If
224 ### /etc/MACHINES doesn't say anything about version numbers, be
225 ### prepared to handle anything reasonably. If version numbers
226 ### matter, be sure /etc/MACHINES says something about it.
227 ###
228 ### Eric Raymond says we should accept strings like "sysvr4" to mean
229 ### "System V Release 4"; he writes, "The old convention encouraged
230 ### confusion between `system' and `release' levels'."
232 machine='' opsys='' unported=no
233 case "${canonical}" in
235 ## FreeBSD ports
236 *-*-freebsd* )
237 opsys=freebsd
238 case "${canonical}" in
239 alpha*-*-freebsd*) machine=alpha ;;
240 i[3456]86-*-freebsd*) machine=intel386 ;;
241 esac
242 ;;
244 ## NetBSD ports
245 *-*-netbsd* )
246 opsys=netbsd
247 if test -f /usr/lib/crti.o; then]
248 dnl The close and open brackets here are because this section is quoted --
249 dnl see the `changequote' comment above.
250 AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
251 [ fi
253 case "${canonical}" in
254 alpha*-*-netbsd*) machine=alpha ;;
255 i[3456]86-*-netbsd*) machine=intel386 ;;
256 m68k-*-netbsd*)
257 # This is somewhat bogus.
258 machine=hp9000s300 ;;
259 powerpc-apple-netbsd*) machine=macppc ;;
260 mips-*-netbsd*) machine=pmax ;;
261 mipsel-*-netbsd*) machine=pmax ;;
262 mipseb-*-netbsd*) machine=pmax ;;
263 ns32k-*-netbsd*) machine=ns32000 ;;
264 powerpc-*-netbsd*) machine=macppc ;;
265 sparc*-*-netbsd*) machine=sparc ;;
266 vax-*-netbsd*) machine=vax ;;
267 arm-*-netbsd*) machine=arm ;;
268 esac
269 ;;
271 ## OpenBSD ports
272 *-*-openbsd* )
273 opsys=openbsd
274 case "${canonical}" in
275 alpha*-*-openbsd*) machine=alpha ;;
276 i386-*-openbsd*) machine=intel386 ;;
277 m68k-*-openbsd*) machine=hp9000s300 ;;
278 mipsel-*-openbsd*) machine=pmax ;;
279 ns32k-*-openbsd*) machine=ns32000 ;;
280 sparc-*-openbsd*) machine=sparc ;;
281 vax-*-openbsd*) machine=vax ;;
282 esac
283 ;;
285 ## LynxOS ports
286 *-*-lynxos* )
287 opsys=lynxos
288 case "${canonical}" in
289 i[3456]86-*-lynxos*) machine=intel386 ;;
290 powerpc-*-lynxos*) machine=powerpc ;;
291 esac
292 ;;
294 ## Acorn RISCiX:
295 arm-acorn-riscix1.1* )
296 machine=acorn opsys=riscix1-1
297 ;;
298 arm-acorn-riscix1.2* | arm-acorn-riscix )
299 ## This name is riscix12 instead of riscix1.2
300 ## to avoid a file name conflict on MSDOS.
301 machine=acorn opsys=riscix12
302 ;;
304 ## BSDI ports
305 *-*-bsdi* )
306 opsys=bsdi
307 case "${canonical}" in
308 i[345]86-*-bsdi*) machine=intel386 ;;
309 sparc-*-bsdi*) machine=sparc ;;
310 powerpc-*-bsdi*) machine=macppc ;;
311 esac
312 case "${canonical}" in
313 *-*-bsd386* | *-*-bsdi1* ) opsys=bsd386 ;;
314 *-*-bsdi2.0* ) opsys=bsdos2 ;;
315 *-*-bsdi2* ) opsys=bsdos2-1 ;;
316 *-*-bsdi3* ) opsys=bsdos3 ;;
317 *-*-bsdi[45]* ) opsys=bsdos4 ;;
318 esac
319 ;;
321 ## Alliant machines
322 ## Strictly speaking, we need the version of the alliant operating
323 ## system to choose the right machine file, but currently the
324 ## configuration name doesn't tell us enough to choose the right
325 ## one; we need to give alliants their own operating system name to
326 ## do this right. When someone cares, they can help us.
327 fx80-alliant-* )
328 machine=alliant4 opsys=bsd4-2
329 ;;
330 i860-alliant-* )
331 machine=alliant-2800 opsys=bsd4-3
332 ;;
334 ## Alpha (DEC) machines.
335 alpha*-dec-osf* )
336 machine=alpha opsys=osf1
337 # This is needed to find X11R6.1 libraries for certain tests.
338 NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
339 GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
340 # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
341 # due to non-traditional preprocessing with the current compiler
342 # defaults. OSF 4 can also have that compiler version, and there
343 # seems always to have been a usable /usr/bin/cpp.
344 NON_GNU_CPP=/usr/bin/cpp
345 case "${canonical}" in
346 alpha*-dec-osf[5-9]*)
347 opsys=osf5-0 ;;
348 esac
349 ;;
351 alpha*-*-linux-gnu* )
352 machine=alpha opsys=gnu-linux
353 ;;
355 arm*-*-linux-gnu* )
356 machine=arm opsys=gnu-linux
357 ;;
359 ## Altos 3068
360 m68*-altos-sysv* )
361 machine=altos opsys=usg5-2
362 ;;
364 ## Amdahl UTS
365 580-amdahl-sysv* )
366 machine=amdahl opsys=usg5-2-2
367 ;;
369 ## Apollo, Domain/OS
370 m68*-apollo-* )
371 machine=apollo opsys=bsd4-3
372 ;;
374 ## AT&T 3b2, 3b5, 3b15, 3b20
375 we32k-att-sysv* )
376 machine=att3b opsys=usg5-2-2
377 ;;
379 ## AT&T 3b1 - The Mighty Unix PC!
380 m68*-att-sysv* )
381 machine=7300 opsys=usg5-2-2
382 ;;
384 ## Bull dpx20
385 rs6000-bull-bosx* )
386 machine=ibmrs6000 opsys=aix3-2
387 ;;
389 ## Bull dpx2
390 m68*-bull-sysv3* )
391 machine=dpx2 opsys=usg5-3
392 ;;
394 ## Bull sps7
395 m68*-bull-sysv2* )
396 machine=sps7 opsys=usg5-2
397 ;;
399 ## CCI 5/32, 6/32 -- see "Tahoe".
401 ## Celerity
402 ## I don't know what configuration name to use for this; config.sub
403 ## doesn't seem to know anything about it. Hey, Celerity users, get
404 ## in touch with us!
405 celerity-celerity-bsd* )
406 machine=celerity opsys=bsd4-2
407 ;;
409 ## Clipper
410 ## What operating systems does this chip run that Emacs has been
411 ## tested on?
412 clipper-* )
413 machine=clipper
414 ## We'll use the catch-all code at the bottom to guess the
415 ## operating system.
416 ;;
418 ## Compaq Nonstop
419 mips-compaq-nonstopux* )
420 machine=nonstopux opsys=nonstopux
421 ;;
423 ## Convex
424 *-convex-bsd* | *-convex-convexos* )
425 machine=convex opsys=bsd4-3
426 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
427 NON_GNU_CPP="cc -E -P"
428 ;;
430 ## Cubix QBx/386
431 i[3456]86-cubix-sysv* )
432 machine=intel386 opsys=usg5-3
433 ;;
435 ## Cydra 5
436 cydra*-cydrome-sysv* )
437 machine=cydra5 opsys=usg5-3
438 ;;
440 ## Data General AViiON Machines
441 ## DG changed naming conventions with the release of 5.4.4.10, they
442 ## dropped the initial 5.4 but left the intervening R. Because of the
443 ## R this shouldn't conflict with older versions of the OS (which I
444 ## think were named like dgux4.*). In addition, DG new AViiONs series
445 ## uses either Motorola M88k or Intel Pentium CPUs.
446 m88k-dg-dguxR4.* | m88k-dg-dgux4* )
447 machine=aviion opsys=dgux4
448 ;;
449 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
450 ## This name is dgux5-4-3 instead of dgux5-4r3
451 ## to avoid a file name conflict on MSDOS.
452 machine=aviion opsys=dgux5-4-3
453 ;;
454 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
455 machine=aviion opsys=dgux5-4r2
456 ;;
457 m88k-dg-dgux* )
458 machine=aviion opsys=dgux
459 ;;
461 ## Data General AViiON Intel (x86) Machines
462 ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
463 ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
464 i[345]86-dg-dguxR4* )
465 machine=aviion-intel opsys=dgux4
466 ;;
468 ## DECstations
469 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
470 machine=pmax opsys=bsd4-2
471 ;;
472 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
473 machine=pmax opsys=bsd4-3
474 ;;
475 mips-dec-ultrix* )
476 machine=pmax opsys=ultrix4-3
477 ;;
478 mips-dec-osf* )
479 machine=pmax opsys=osf1
480 ;;
481 mips-dec-mach_bsd4.3* )
482 machine=pmax opsys=mach-bsd4-3
483 ;;
485 ## Motorola Delta machines
486 m68k-motorola-sysv* | m68000-motorola-sysv* )
487 machine=delta opsys=usg5-3
488 if test -z "`type gnucc | grep 'not found'`"
489 then
490 if test -s /etc/167config
491 then CC="gnucc -m68040"
492 else CC="gnucc -m68881"
493 fi
494 else
495 if test -z "`type gcc | grep 'not found'`"
496 then CC=gcc
497 else CC=cc
498 fi
499 fi
500 ;;
501 m88k-motorola-sysv4* )
502 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
503 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
504 # I hope there are not other 4.0 versions for this machine
505 # which really need usg5-4 instead.
506 machine=delta88k opsys=usg5-4-2
507 ;;
508 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
509 machine=delta88k opsys=usg5-3
510 ;;
512 ## Dual machines
513 m68*-dual-sysv* )
514 machine=dual opsys=usg5-2
515 ;;
516 m68*-dual-uniplus* )
517 machine=dual opsys=unipl5-2
518 ;;
520 ## Elxsi 6400
521 elxsi-elxsi-sysv* )
522 machine=elxsi opsys=usg5-2
523 ;;
525 ## Encore machines
526 ns16k-encore-bsd* )
527 machine=ns16000 opsys=umax
528 ;;
530 ## The GEC 63 - apparently, this port isn't really finished yet.
531 # I'm sure we finished off the last of the machines, though. -- fx
533 ## Gould Power Node and NP1
534 pn-gould-bsd4.2* )
535 machine=gould opsys=bsd4-2
536 ;;
537 pn-gould-bsd4.3* )
538 machine=gould opsys=bsd4-3
539 ;;
540 np1-gould-bsd* )
541 machine=gould-np1 opsys=bsd4-3
542 ;;
544 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
545 ## as far as Emacs is concerned).
546 m88k-harris-cxux* )
547 # Build needs to be different on 7.0 and later releases
548 case "`uname -r`" in
549 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
550 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
551 esac
552 NON_GNU_CPP="/lib/cpp"
553 ;;
554 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
555 m68k-harris-cxux* )
556 machine=nh3000 opsys=cxux
557 ;;
558 ## Harris power pc NightHawk running Power UNIX (Series 6000)
559 powerpc-harris-powerunix )
560 machine=nh6000 opsys=powerunix
561 NON_GNU_CPP="cc -Xo -E -P"
562 ;;
563 ## SR2001/SR2201 running HI-UX/MPP
564 hppa1.1-hitachi-hiuxmpp* )
565 machine=sr2k opsys=hiuxmpp
566 ;;
567 hppa1.1-hitachi-hiuxwe2* )
568 machine=sr2k opsys=hiuxwe2
569 ;;
570 ## Honeywell XPS100
571 xps*-honeywell-sysv* )
572 machine=xps100 opsys=usg5-2
573 ;;
575 ## HP 9000 series 200 or 300
576 m68*-hp-bsd* )
577 machine=hp9000s300 opsys=bsd4-3
578 ;;
579 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
580 m68*-hp-hpux* )
581 case "`uname -r`" in
582 ## Someone's system reports A.B8.05 for this.
583 ## I wonder what other possibilities there are.
584 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
585 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
586 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
587 *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
588 *) machine=hp9000s300 opsys=hpux ;;
589 esac
590 ;;
592 ## HP 9000 series 700 and 800, running HP/UX
593 hppa*-hp-hpux7* )
594 machine=hp800 opsys=hpux
595 ;;
596 hppa*-hp-hpux8* )
597 machine=hp800 opsys=hpux8
598 ;;
599 hppa*-hp-hpux9shr* )
600 machine=hp800 opsys=hpux9shr
601 ;;
602 hppa*-hp-hpux9* )
603 machine=hp800 opsys=hpux9
604 ;;
605 hppa*-hp-hpux10.2* )
606 machine=hp800 opsys=hpux10-20
607 ;;
608 hppa*-hp-hpux10* )
609 machine=hp800 opsys=hpux10
610 ;;
611 hppa*-hp-hpux1[1-9]* )
612 machine=hp800 opsys=hpux11
613 ;;
615 hppa*-*-linux-gnu* )
616 machine=hp800 opsys=gnu-linux
617 ;;
619 ## HP 9000 series 700 and 800, running HP/UX
620 hppa*-hp-hpux* )
621 ## Cross-compilation? Nah!
622 case "`uname -r`" in
623 ## Someone's system reports A.B8.05 for this.
624 ## I wonder what other possibilities there are.
625 *.B8.* ) machine=hp800 opsys=hpux8 ;;
626 *.08.* ) machine=hp800 opsys=hpux8 ;;
627 *.09.* ) machine=hp800 opsys=hpux9 ;;
628 *) machine=hp800 opsys=hpux10 ;;
629 esac
630 ;;
631 hppa*-*-nextstep* )
632 machine=hp800 opsys=nextstep
633 ;;
635 ## Orion machines
636 orion-orion-bsd* )
637 machine=orion opsys=bsd4-2
638 ;;
639 clipper-orion-bsd* )
640 machine=orion105 opsys=bsd4-2
641 ;;
643 ## IBM machines
644 i[3456]86-ibm-aix1.1* )
645 machine=ibmps2-aix opsys=usg5-2-2
646 ;;
647 i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
648 machine=ibmps2-aix opsys=usg5-3
649 ;;
650 i370-ibm-aix*)
651 machine=ibm370aix opsys=usg5-3
652 ;;
653 s390-*-linux-gnu* )
654 machine=ibms390 opsys=gnu-linux
655 ;;
656 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
657 machine=ibmrs6000 opsys=aix3-1
658 ;;
659 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
660 machine=ibmrs6000 opsys=aix3-2-5
661 ;;
662 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
663 machine=ibmrs6000 opsys=aix4-1
664 ;;
665 rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2* )
666 machine=ibmrs6000 opsys=aix4-2
667 ;;
668 rs6000-ibm-aix5* | powerpc-ibm-aix5* )
669 machine=ibmrs6000 opsys=aix4-2
670 ;;
671 rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0* )
672 machine=ibmrs6000 opsys=aix4
673 ;;
674 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
675 machine=ibmrs6000 opsys=aix4-1
676 ;;
677 rs6000-ibm-aix* | powerpc-ibm-aix* )
678 machine=ibmrs6000 opsys=aix3-2
679 ;;
680 romp-ibm-bsd4.3* )
681 machine=ibmrt opsys=bsd4-3
682 ;;
683 romp-ibm-bsd4.2* )
684 machine=ibmrt opsys=bsd4-2
685 ;;
686 romp-ibm-aos4.3* )
687 machine=ibmrt opsys=bsd4-3
688 ;;
689 romp-ibm-aos4.2* )
690 machine=ibmrt opsys=bsd4-2
691 ;;
692 romp-ibm-aos* )
693 machine=ibmrt opsys=bsd4-3
694 ;;
695 romp-ibm-bsd* )
696 machine=ibmrt opsys=bsd4-3
697 ;;
698 romp-ibm-aix* )
699 machine=ibmrt-aix opsys=usg5-2-2
700 ;;
702 ## Integrated Solutions `Optimum V'
703 m68*-isi-bsd4.2* )
704 machine=isi-ov opsys=bsd4-2
705 ;;
706 m68*-isi-bsd4.3* )
707 machine=isi-ov opsys=bsd4-3
708 ;;
710 ## Intel 386 machines where we do care about the manufacturer
711 i[3456]86-intsys-sysv* )
712 machine=is386 opsys=usg5-2-2
713 ;;
715 ## Prime EXL
716 i[3456]86-prime-sysv* )
717 machine=i386 opsys=usg5-3
718 ;;
720 ## Sequent Symmetry running Dynix
721 i[3456]86-sequent-bsd* )
722 machine=symmetry opsys=bsd4-3
723 ;;
725 ## Sequent Symmetry running ptx 4, which is a modified SVR4.
726 i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
727 machine=sequent-ptx opsys=ptx4
728 NON_GNU_CPP=/lib/cpp
729 ;;
731 ## Sequent Symmetry running DYNIX/ptx
732 ## Use the old cpp rather than the newer ANSI one.
733 i[3456]86-sequent-ptx* )
734 machine=sequent-ptx opsys=ptx
735 NON_GNU_CPP="/lib/cpp"
736 ;;
738 ## ncr machine running svr4.3.
739 i[3456]86-ncr-sysv4.3 )
740 machine=ncr386 opsys=usg5-4-3
741 ;;
743 ## Unspecified sysv on an ncr machine defaults to svr4.2.
744 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
745 i[3456]86-ncr-sysv* )
746 machine=ncr386 opsys=usg5-4-2
747 ;;
749 ## Intel Paragon OSF/1
750 i860-intel-osf1* )
751 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
752 ;;
754 ## Intel 860
755 i860-*-sysv4* )
756 machine=i860 opsys=usg5-4
757 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
758 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
759 ;;
761 ## Macintosh PowerPC
762 powerpc*-*-linux-gnu* )
763 machine=macppc opsys=gnu-linux
764 ;;
766 ## Masscomp machines
767 m68*-masscomp-rtu* )
768 machine=masscomp opsys=rtu
769 ;;
771 ## Megatest machines
772 m68*-megatest-bsd* )
773 machine=mega68 opsys=bsd4-2
774 ;;
776 ## Workstations sold by MIPS
777 ## This is not necessarily all workstations using the MIPS processor -
778 ## Irises are produced by SGI, and DECstations by DEC.
780 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
781 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
782 ## it gives for choosing between the alternatives seems to be "Use
783 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
784 ## the BSD world." I'll assume that these are instructions for
785 ## handling two odd situations, and that every other situation
786 ## should use mips.h and usg5-2-2, they being listed first.
787 mips-mips-usg* )
788 machine=mips4
789 ## Fall through to the general code at the bottom to decide on the OS.
790 ;;
791 mips-mips-riscos4* )
792 machine=mips4 opsys=bsd4-3
793 NON_GNU_CC="cc -systype bsd43"
794 NON_GNU_CPP="cc -systype bsd43 -E"
795 ;;
796 mips-mips-riscos5* )
797 machine=mips4 opsys=riscos5
798 NON_GNU_CC="cc -systype bsd43"
799 NON_GNU_CPP="cc -systype bsd43 -E"
800 ;;
801 mips-mips-bsd* )
802 machine=mips opsys=bsd4-3
803 ;;
804 mips-mips-* )
805 machine=mips opsys=usg5-2-2
806 ;;
808 ## NeXT
809 m68*-next-* | m68k-*-nextstep* )
810 machine=m68k opsys=nextstep
811 ;;
813 ## The complete machine from National Semiconductor
814 ns32k-ns-genix* )
815 machine=ns32000 opsys=usg5-2
816 ;;
818 ## NCR machines
819 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
820 machine=tower32 opsys=usg5-2-2
821 ;;
822 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
823 machine=tower32v3 opsys=usg5-3
824 ;;
826 ## NEC EWS4800
827 mips-nec-sysv4*)
828 machine=ews4800 opsys=ux4800
829 ;;
831 ## Nixdorf Targon 31
832 m68*-nixdorf-sysv* )
833 machine=targon31 opsys=usg5-2-2
834 ;;
836 ## Nu (TI or LMI)
837 m68*-nu-sysv* )
838 machine=nu opsys=usg5-2
839 ;;
841 ## Plexus
842 m68*-plexus-sysv* )
843 machine=plexus opsys=usg5-2
844 ;;
846 ## Pyramid machines
847 ## I don't really have any idea what sort of processor the Pyramid has,
848 ## so I'm assuming it is its own architecture.
849 pyramid-pyramid-bsd* )
850 machine=pyramid opsys=bsd4-2
851 ;;
853 ## Sequent Balance
854 ns32k-sequent-bsd4.2* )
855 machine=sequent opsys=bsd4-2
856 ;;
857 ns32k-sequent-bsd4.3* )
858 machine=sequent opsys=bsd4-3
859 ;;
861 ## Siemens Nixdorf
862 mips-siemens-sysv* | mips-sni-sysv*)
863 machine=mips-siemens opsys=usg5-4
864 NON_GNU_CC=/usr/ccs/bin/cc
865 NON_GNU_CPP=/usr/ccs/lib/cpp
866 ;;
868 ## Silicon Graphics machines
869 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
870 m68*-sgi-iris3.5* )
871 machine=irist opsys=iris3-5
872 ;;
873 m68*-sgi-iris3.6* | m68*-sgi-iris*)
874 machine=irist opsys=iris3-6
875 ;;
876 ## Iris 4D
877 mips-sgi-irix3* )
878 machine=iris4d opsys=irix3-3
879 ;;
880 mips-sgi-irix4* )
881 machine=iris4d opsys=irix4-0
882 ;;
883 mips-sgi-irix6.5 )
884 machine=iris4d opsys=irix6-5
885 # Without defining _LANGUAGE_C, things get masked out in the headers
886 # so that, for instance, grepping for `free' in stdlib.h fails and
887 # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
888 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
889 NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
890 ;;
891 mips-sgi-irix6* )
892 machine=iris4d opsys=irix6-0
893 # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
894 # but presumably it does no harm.
895 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
896 # -32 probably isn't necessary in later v.6s -- anyone know which?
897 NON_GCC_TEST_OPTIONS=-32
898 ;;
899 mips-sgi-irix5.[01]* )
900 machine=iris4d opsys=irix5-0
901 ;;
902 mips-sgi-irix5* | mips-sgi-irix* )
903 machine=iris4d opsys=irix5-2
904 ;;
906 ## SONY machines
907 m68*-sony-bsd4.2* )
908 machine=news opsys=bsd4-2
909 ;;
910 m68*-sony-bsd4.3* )
911 machine=news opsys=bsd4-3
912 ;;
913 m68*-sony-newsos3* | m68*-sony-news3*)
914 machine=news opsys=bsd4-3
915 ;;
916 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
917 machine=news-risc opsys=bsd4-3
918 ;;
919 mips-sony-newsos6* )
920 machine=news-r6 opsys=newsos6
921 ;;
922 mips-sony-news* )
923 machine=news-risc opsys=newsos5
924 ;;
926 ## Stride
927 m68*-stride-sysv* )
928 machine=stride opsys=usg5-2
929 ;;
931 ## Suns
932 sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
933 machine=sparc opsys=gnu-linux
934 ;;
936 *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
937 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
938 | rs6000-*-solaris2*)
939 case "${canonical}" in
940 m68*-sunos1* ) machine=sun1 ;;
941 m68*-sunos2* ) machine=sun2 ;;
942 m68* ) machine=sun3 ;;
943 i[3456]86-sun-sunos[34]* ) machine=sun386 ;;
944 i[3456]86-*-* ) machine=intel386 ;;
945 powerpcle* ) machine=powerpcle ;;
946 powerpc* | rs6000* ) machine=ibmrs6000 ;;
947 sparc* ) machine=sparc ;;
948 * ) unported=yes ;;
949 esac
950 case "${canonical}" in
951 ## The Sun386 didn't get past 4.0.
952 i[3456]86-*-sunos4 ) opsys=sunos4-0 ;;
953 *-sunos4.0* ) opsys=sunos4-0 ;;
954 *-sunos4.1.[3-9]*noshare )
955 ## This name is sunos413 instead of sunos4-1-3
956 ## to avoid a file name conflict on MSDOS.
957 opsys=sunos413
958 NON_GNU_CPP=/usr/lib/cpp
959 NON_GCC_TEST_OPTIONS=-Bstatic
960 GCC_TEST_OPTIONS=-static
961 ;;
962 *-sunos4.1.[3-9]* | *-sunos4shr*)
963 opsys=sunos4shr
964 NON_GNU_CPP=/usr/lib/cpp
965 ;;
966 *-sunos4* | *-sunos )
967 opsys=sunos4-1
968 NON_GCC_TEST_OPTIONS=-Bstatic
969 GCC_TEST_OPTIONS=-static
970 ;;
971 *-sunos5.3* | *-solaris2.3* )
972 opsys=sol2-3
973 NON_GNU_CPP=/usr/ccs/lib/cpp
974 ;;
975 *-sunos5.4* | *-solaris2.4* )
976 opsys=sol2-4
977 NON_GNU_CPP=/usr/ccs/lib/cpp
978 RANLIB="ar -ts"
979 ;;
980 *-sunos5.5* | *-solaris2.5* )
981 opsys=sol2-5
982 NON_GNU_CPP=/usr/ccs/lib/cpp
983 RANLIB="ar -ts"
984 ;;
985 *-sunos5.6* | *-solaris2.6* )
986 opsys=sol2-6
987 NON_GNU_CPP=/usr/ccs/lib/cpp
988 RANLIB="ar -ts"
989 ;;
990 *-sunos5* | *-solaris* )
991 opsys=sol2-6
992 NON_GNU_CPP=/usr/ccs/lib/cpp
993 ;;
994 * ) opsys=bsd4-2 ;;
995 esac
996 ## Watch out for a compiler that we know will not work.
997 case "${canonical}" in
998 *-solaris* | *-sunos5* )
999 if [ "x$CC" = x/usr/ucb/cc ]; then
1000 ## /usr/ucb/cc doesn't work;
1001 ## we should find some other compiler that does work.
1002 unset CC
1003 fi
1004 ;;
1005 *) ;;
1006 esac
1007 ;;
1008 sparc-*-nextstep* )
1009 machine=sparc opsys=nextstep
1010 ;;
1012 ## Tadpole 68k
1013 m68*-tadpole-sysv* )
1014 machine=tad68k opsys=usg5-3
1015 ;;
1017 ## Tahoe machines
1018 tahoe-tahoe-bsd4.2* )
1019 machine=tahoe opsys=bsd4-2
1020 ;;
1021 tahoe-tahoe-bsd4.3* )
1022 machine=tahoe opsys=bsd4-3
1023 ;;
1025 ## Tandem Integrity S2
1026 mips-tandem-sysv* )
1027 machine=tandem-s2 opsys=usg5-3
1028 ;;
1030 ## Tektronix XD88
1031 m88k-tektronix-sysv3* )
1032 machine=tekxd88 opsys=usg5-3
1033 ;;
1035 ## Tektronix 16000 box (6130?)
1036 ns16k-tektronix-bsd* )
1037 machine=ns16000 opsys=bsd4-2
1038 ;;
1039 ## Tektronix 4300
1040 ## src/m/tek4300.h hints that this is a m68k machine.
1041 m68*-tektronix-bsd* )
1042 machine=tek4300 opsys=bsd4-3
1043 ;;
1045 ## Titan P2 or P3
1046 ## We seem to have lost the machine-description file titan.h!
1047 titan-titan-sysv* )
1048 machine=titan opsys=usg5-3
1049 ;;
1051 ## Ustation E30 (SS5E)
1052 m68*-unisys-uniplus* )
1053 machine=ustation opsystem=unipl5-2
1054 ;;
1056 ## Vaxen.
1057 vax-dec-* )
1058 machine=vax
1059 case "${canonical}" in
1060 *-bsd4.1* ) opsys=bsd4-1 ;;
1061 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
1062 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
1063 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
1064 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
1065 *-vms* ) opsys=vms ;;
1066 * ) unported=yes
1067 esac
1068 ;;
1070 ## Whitechapel MG1
1071 ns16k-whitechapel-* )
1072 machine=mg1
1073 ## We don't know what sort of OS runs on these; we'll let the
1074 ## operating system guessing code below try.
1075 ;;
1077 ## Wicat
1078 m68*-wicat-sysv* )
1079 machine=wicat opsys=usg5-2
1080 ;;
1082 ## IA-64
1083 ia64*-*-linux* )
1084 machine=ia64 opsys=gnu-linux
1085 ;;
1087 ## Intel 386 machines where we don't care about the manufacturer
1088 i[3456]86-*-* )
1089 machine=intel386
1090 case "${canonical}" in
1091 *-cygwin ) opsys=cygwin ;;
1092 *-darwin ) opsys=darwin
1093 CPP="${CC-cc} -E -no-cpp-precomp"
1094 ;;
1095 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
1096 *-isc2.2* ) opsys=isc2-2 ;;
1097 *-isc4.0* ) opsys=isc4-0 ;;
1098 *-isc4.* ) opsys=isc4-1
1099 GCC_TEST_OPTIONS=-posix
1100 NON_GCC_TEST_OPTIONS=-Xp
1101 ;;
1102 *-isc* ) opsys=isc3-0 ;;
1103 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
1104 *-esix* ) opsys=esix ;;
1105 *-xenix* ) opsys=xenix ;;
1106 *-linux-gnu* ) opsys=gnu-linux ;;
1107 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
1108 *-sco3.2v5* ) opsys=sco5
1109 NON_GNU_CPP=/lib/cpp
1110 # Prevent -belf from being passed to $CPP.
1111 # /lib/cpp does not accept it.
1112 OVERRIDE_CPPFLAGS=" "
1113 ;;
1114 *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1115 *-sysv5uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1116 *-sysv5OpenUNIX* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1117 *-386bsd* ) opsys=386bsd ;;
1118 *-nextstep* ) opsys=nextstep ;;
1119 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1120 esac
1121 ;;
1123 ## m68k Linux-based GNU system
1124 m68k-*-linux-gnu* )
1125 machine=m68k opsys=gnu-linux
1126 ;;
1128 ## Mips Linux-based GNU system
1129 mips-*-linux-gnu* | mipsel-*-linux-gnu* )
1130 machine=mips opsys=gnu-linux
1131 ;;
1133 ## UXP/DS
1134 sparc-fujitsu-sysv4* )
1135 machine=sparc opsys=uxpds
1136 NON_GNU_CPP=/usr/ccs/lib/cpp
1137 RANLIB="ar -ts"
1138 ;;
1140 ## UXP/V
1141 f301-fujitsu-uxpv4.1)
1142 machine=f301 opsys=uxpv
1143 ;;
1145 ## Darwin / Mac OS X
1146 powerpc-apple-darwin* )
1147 machine=powermac opsys=darwin
1148 # Define CPP as follows to make autoconf work correctly.
1149 CPP="${CC-cc} -E -no-cpp-precomp"
1150 # Use fink packages if available.
1151 if test -d /sw/include && test -d /sw/lib; then
1152 GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
1153 CPP="${CPP} ${GCC_TEST_OPTIONS}"
1154 NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
1155 fi
1156 ;;
1158 ## AMD x86-64 Linux-based GNU system
1159 x86_64-*-linux-gnu* )
1160 machine=amdx86-64 opsys=gnu-linux
1161 ;;
1163 * )
1164 unported=yes
1165 ;;
1166 esac
1168 ### If the code above didn't choose an operating system, just choose
1169 ### an operating system based on the configuration name. You really
1170 ### only want to use this when you have no idea what the right
1171 ### operating system is; if you know what operating systems a machine
1172 ### runs, it's cleaner to make it explicit in the case statement
1173 ### above.
1174 if test x"${opsys}" = x; then
1175 case "${canonical}" in
1176 *-gnu* ) opsys=gnu ;;
1177 *-bsd4.[01] ) opsys=bsd4-1 ;;
1178 *-bsd4.2 ) opsys=bsd4-2 ;;
1179 *-bsd4.3 ) opsys=bsd4-3 ;;
1180 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
1181 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
1182 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
1183 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
1184 *-sysv4.2uw* ) opsys=unixware ;;
1185 *-sysv5uw* ) opsys=unixware ;;
1186 *-sysv5OpenUNIX* ) opsys=unixware ;;
1187 *-sysv4.1* | *-sysvr4.1* )
1188 NON_GNU_CPP=/usr/lib/cpp
1189 opsys=usg5-4 ;;
1190 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1191 if [ x$NON_GNU_CPP = x ]; then
1192 if [ -f /usr/ccs/lib/cpp ]; then
1193 NON_GNU_CPP=/usr/ccs/lib/cpp
1194 else
1195 NON_GNU_CPP=/lib/cpp
1196 fi
1197 fi
1198 opsys=usg5-4-2 ;;
1199 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
1200 * )
1201 unported=yes
1202 ;;
1203 esac
1204 fi
1206 ]
1207 dnl quotation ends
1209 if test $unported = yes; then
1210 AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
1211 Check `etc/MACHINES' for recognized configuration names.])
1212 fi
1214 machfile="m/${machine}.h"
1215 opsysfile="s/${opsys}.h"
1218 #### Choose a compiler.
1219 test -n "$CC" && cc_specified=yes
1221 # Save the value of CFLAGS that the user specified.
1222 SPECIFIED_CFLAGS="$CFLAGS"
1224 case ${with_gcc} in
1225 "yes" ) CC="gcc" GCC=yes ;;
1226 "no" ) : ${CC=cc} ;;
1227 * )
1228 esac
1229 AC_PROG_CC
1231 # On Suns, sometimes $CPP names a directory.
1232 if test -n "$CPP" && test -d "$CPP"; then
1233 CPP=
1234 fi
1236 #### Some systems specify a CPP to use unless we are using GCC.
1237 #### Now that we know whether we are using GCC, we can decide whether
1238 #### to use that one.
1239 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1240 then
1241 CPP="$NON_GNU_CPP"
1242 fi
1244 #### Some systems specify a CC to use unless we are using GCC.
1245 #### Now that we know whether we are using GCC, we can decide whether
1246 #### to use that one.
1247 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1248 test x$cc_specified != xyes
1249 then
1250 CC="$NON_GNU_CC"
1251 fi
1253 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1254 then
1255 CC="$CC $GCC_TEST_OPTIONS"
1256 fi
1258 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1259 then
1260 CC="$CC $NON_GCC_TEST_OPTIONS"
1261 fi
1263 #### Some other nice autoconf tests.
1265 dnl checks for programs
1266 AC_PROG_LN_S
1267 AC_PROG_CPP
1268 AC_PROG_INSTALL
1269 if test "x$RANLIB" = x; then
1270 AC_PROG_RANLIB
1271 fi
1272 AC_PATH_PROG(INSTALL_INFO, install-info)
1273 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
1274 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
1276 dnl Add our options to ac_link now, after it is set up.
1278 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1279 then
1280 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1281 fi
1283 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1284 then
1285 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1286 fi
1288 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1289 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1290 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1291 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1292 dnl if not built to support GNU ld.
1294 late_LDFLAGS=$LDFLAGS
1295 if test "$GCC" = yes; then
1296 LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
1297 else
1298 LDFLAGS="$LDFLAGS -znocombreloc"
1299 fi
1301 AC_MSG_CHECKING([for -znocombreloc])
1302 AC_LINK_IFELSE([main(){return 0;}],
1303 [AC_MSG_RESULT(yes)],
1304 LDFLAGS=$late_LDFLAGS
1305 [AC_MSG_RESULT(no)])
1307 dnl checks for Unix variants
1308 AC_AIX
1311 #### Extract some information from the operating system and machine files.
1313 AC_CHECKING([the machine- and system-dependent files to find out
1314 - which libraries the lib-src programs will want, and
1315 - whether the GNU malloc routines are usable])
1317 ### First figure out CFLAGS (which we use for running the compiler here)
1318 ### and REAL_CFLAGS (which we use for real compilation).
1319 ### The two are the same except on a few systems, where they are made
1320 ### different to work around various lossages. For example,
1321 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1322 ### as implying static linking.
1324 ### If the CFLAGS env var is specified, we use that value
1325 ### instead of the default.
1327 ### It's not important that this name contain the PID; you can't run
1328 ### two configures in the same directory and have anything work
1329 ### anyway.
1330 tempcname="conftest.c"
1332 echo '
1333 #include "'${srcdir}'/src/'${opsysfile}'"
1334 #include "'${srcdir}'/src/'${machfile}'"
1335 #ifndef LIBS_MACHINE
1336 #define LIBS_MACHINE
1337 #endif
1338 #ifndef LIBS_SYSTEM
1339 #define LIBS_SYSTEM
1340 #endif
1341 #ifndef C_SWITCH_SYSTEM
1342 #define C_SWITCH_SYSTEM
1343 #endif
1344 #ifndef C_SWITCH_MACHINE
1345 #define C_SWITCH_MACHINE
1346 #endif
1347 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1348 configure___ c_switch_system=C_SWITCH_SYSTEM
1349 configure___ c_switch_machine=C_SWITCH_MACHINE
1351 #ifndef LIB_X11_LIB
1352 #define LIB_X11_LIB -lX11
1353 #endif
1355 #ifndef LIBX11_MACHINE
1356 #define LIBX11_MACHINE
1357 #endif
1359 #ifndef LIBX11_SYSTEM
1360 #define LIBX11_SYSTEM
1361 #endif
1362 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1364 #ifdef UNEXEC
1365 configure___ unexec=UNEXEC
1366 #else
1367 configure___ unexec=unexec.o
1368 #endif
1370 #ifdef SYSTEM_MALLOC
1371 configure___ system_malloc=yes
1372 #else
1373 configure___ system_malloc=no
1374 #endif
1376 #ifdef USE_MMAP_FOR_BUFFERS
1377 configure___ use_mmap_for_buffers=yes
1378 #else
1379 configure___ use_mmap_for_buffers=no
1380 #endif
1382 #ifndef C_DEBUG_SWITCH
1383 #define C_DEBUG_SWITCH -g
1384 #endif
1386 #ifndef C_OPTIMIZE_SWITCH
1387 #ifdef __GNUC__
1388 #define C_OPTIMIZE_SWITCH -O2
1389 #else
1390 #define C_OPTIMIZE_SWITCH -O
1391 #endif
1392 #endif
1394 #ifndef LD_SWITCH_MACHINE
1395 #define LD_SWITCH_MACHINE
1396 #endif
1398 #ifndef LD_SWITCH_SYSTEM
1399 #define LD_SWITCH_SYSTEM
1400 #endif
1402 #ifndef LD_SWITCH_X_SITE_AUX
1403 #define LD_SWITCH_X_SITE_AUX
1404 #endif
1406 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1407 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1409 #ifdef THIS_IS_CONFIGURE
1411 /* Get the CFLAGS for tests in configure. */
1412 #ifdef __GNUC__
1413 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1414 #else
1415 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1416 #endif
1418 #else /* not THIS_IS_CONFIGURE */
1420 /* Get the CFLAGS for real compilation. */
1421 #ifdef __GNUC__
1422 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1423 #else
1424 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1425 #endif
1427 #endif /* not THIS_IS_CONFIGURE */
1428 ' > ${tempcname}
1430 # The value of CPP is a quoted variable reference, so we need to do this
1431 # to get its actual value...
1432 CPP=`eval "echo $CPP"`
1433 [eval `${CPP} -Isrc ${tempcname} \
1434 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1435 if test "x$SPECIFIED_CFLAGS" = x; then
1436 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1437 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1438 else
1439 REAL_CFLAGS="$CFLAGS"
1440 fi]
1441 rm ${tempcname}
1443 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1445 ### Make sure subsequent tests use flags consistent with the build flags.
1447 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1448 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1449 else
1450 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1451 fi
1453 dnl For AC_FUNC_GETLOADAVG, at least:
1454 AC_CONFIG_LIBOBJ_DIR(src)
1456 AC_GNU_SOURCE
1458 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1459 AC_SYS_LARGEFILE
1461 if test "${with_sound}" != "no"; then
1462 # Sound support for GNU/Linux and the free BSDs.
1463 AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1464 # Emulation library used on NetBSD.
1465 AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1466 AC_SUBST(LIBSOUND)
1467 fi
1469 dnl checks for header files
1470 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1471 linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1472 termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1473 sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1474 sys/utsname.h pwd.h)
1476 AC_MSG_CHECKING(if personality LINUX32 can be set)
1477 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1478 emacs_cv_personality_linux32=yes,
1479 emacs_cv_personality_linux32=no)
1480 AC_MSG_RESULT($emacs_cv_personality_linux32)
1482 if test $emacs_cv_personality_linux32 = yes; then
1483 AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1484 [Define to 1 if personality LINUX32 can be set.])
1485 fi
1487 dnl On Solaris 8 there's a compilation warning for term.h because
1488 dnl it doesn't define `bool'.
1489 AC_CHECK_HEADERS(term.h, , , -)
1490 AC_HEADER_STDC
1491 AC_HEADER_TIME
1492 AC_CHECK_DECLS([sys_siglist])
1493 if test $ac_cv_have_decl_sys_siglist != yes; then
1494 # For Tru64, at least:
1495 AC_CHECK_DECLS([__sys_siglist])
1496 if test $ac_cv_have_decl___sys_siglist = yes; then
1497 AC_DEFINE(sys_siglist, __sys_siglist,
1498 [Define to any substitute for sys_siglist.])
1499 fi
1500 fi
1501 AC_HEADER_SYS_WAIT
1503 dnl Some systems have utime.h but don't declare the struct anyplace.
1504 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1505 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1506 #include <sys/time.h>
1507 #include <time.h>
1508 #else
1509 #ifdef HAVE_SYS_TIME_H
1510 #include <sys/time.h>
1511 #else
1512 #include <time.h>
1513 #endif
1514 #endif
1515 #ifdef HAVE_UTIME_H
1516 #include <utime.h>
1517 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1518 emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1519 if test $emacs_cv_struct_utimbuf = yes; then
1520 AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1521 fi
1523 dnl checks for typedefs
1524 AC_TYPE_SIGNAL
1526 dnl Check for speed_t typedef.
1527 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1528 [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1529 emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1530 if test $emacs_cv_speed_t = yes; then
1531 AC_DEFINE(HAVE_SPEED_T, 1,
1532 [Define to 1 if `speed_t' is declared by <termios.h>.])
1533 fi
1535 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1536 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1537 #include <sys/time.h>
1538 #include <time.h>
1539 #else
1540 #ifdef HAVE_SYS_TIME_H
1541 #include <sys/time.h>
1542 #else
1543 #include <time.h>
1544 #endif
1545 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1546 emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1547 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1548 if test $emacs_cv_struct_timeval = yes; then
1549 AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1550 fi
1552 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1553 AC_TRY_COMPILE([#include <math.h>],
1554 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1555 emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1556 HAVE_EXCEPTION=$emacs_cv_struct_exception
1557 if test $emacs_cv_struct_exception != yes; then
1558 AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1559 fi
1561 AC_CHECK_HEADERS(sys/socket.h)
1562 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1563 #if HAVE_SYS_SOCKET_H
1564 #include <sys/socket.h>
1565 #endif])
1567 dnl checks for structure members
1568 AC_STRUCT_TM
1569 AC_STRUCT_TIMEZONE
1570 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1571 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1572 [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1573 [#include <time.h>])
1574 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1575 struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1576 struct ifreq.ifr_addr], , ,
1577 [AC_INCLUDES_DEFAULT
1578 #if HAVE_SYS_SOCKET_H
1579 #include <sys/socket.h>
1580 #endif
1581 #if HAVE_NET_IF_H
1582 #include <net/if.h>
1583 #endif])
1585 dnl checks for compiler characteristics
1587 dnl Testing __STDC__ to determine prototype support isn't good enough.
1588 dnl DEC C, for instance, doesn't define it with default options, and
1589 dnl is used on 64-bit systems (OSF Alphas). Similarly for volatile
1590 dnl and void *.
1591 AC_C_PROTOTYPES
1592 AC_C_VOLATILE
1593 AC_C_CONST
1594 dnl This isn't useful because we can't turn on use of `inline' unless
1595 dnl the compiler groks `extern inline'.
1596 dnl AC_C_INLINE
1597 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1598 [AC_TRY_COMPILE(, [void * foo;],
1599 emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1600 if test $emacs_cv_void_star = yes; then
1601 AC_DEFINE(POINTER_TYPE, void)
1602 else
1603 AC_DEFINE(POINTER_TYPE, char)
1604 fi
1605 AH_TEMPLATE(POINTER_TYPE,
1606 [Define as `void' if your compiler accepts `void *'; otherwise
1607 define as `char'.])dnl
1611 dnl This could be used for targets which can have both byte sexes.
1612 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1613 dnl AC_C_BIGENDIAN
1615 dnl check for Make feature
1616 AC_PROG_MAKE_SET
1618 dnl checks for operating system services
1619 AC_SYS_LONG_FILE_NAMES
1621 #### Choose a window system.
1623 AC_PATH_X
1624 if test "$no_x" = yes; then
1625 window_system=none
1626 else
1627 window_system=x11
1628 fi
1630 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1631 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1632 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1633 x_default_search_path=""
1634 for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1635 x_search_path="\
1636 ${x_library}/X11/%L/%T/%N%C%S:\
1637 ${x_library}/X11/%l/%T/%N%C%S:\
1638 ${x_library}/X11/%T/%N%C%S:\
1639 ${x_library}/X11/%L/%T/%N%S:\
1640 ${x_library}/X11/%l/%T/%N%S:\
1641 ${x_library}/X11/%T/%N%S"
1642 if test x"${x_default_search_path}" = x; then
1643 x_default_search_path=${x_search_path}
1644 else
1645 x_default_search_path="${x_search_path}:${x_default_search_path}"
1646 fi
1647 done
1648 fi
1649 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1650 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1651 fi
1653 if test x"${x_includes}" = x; then
1654 bitmapdir=/usr/include/X11/bitmaps
1655 else
1656 # accumulate include directories that have X11 bitmap subdirectories
1657 bmd_acc="dummyval"
1658 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1659 if test -d "${bmd}/X11/bitmaps"; then
1660 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1661 fi
1662 if test -d "${bmd}/bitmaps"; then
1663 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1664 fi
1665 done
1666 if test ${bmd_acc} != "dummyval"; then
1667 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1668 fi
1669 fi
1671 HAVE_CARBON=no
1672 if test "${with_carbon}" != no; then
1673 AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1674 fi
1675 if test "${window_system}" = x11 && test "${HAVE_CARBON}" = yes; then
1676 if test "${with_carbon+set}" != set \
1677 && test "${carbon_appdir_x+set}" != set; then
1678 HAVE_CARBON=no
1679 fi
1680 fi
1681 if test "${HAVE_CARBON}" = yes; then
1682 window_system=mac
1683 fi
1685 case "${window_system}" in
1686 x11 )
1687 HAVE_X_WINDOWS=yes
1688 HAVE_X11=yes
1689 case "${with_x_toolkit}" in
1690 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1691 motif ) USE_X_TOOLKIT=MOTIF ;;
1692 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1693 gtk ) with_gtk=yes
1694 dnl Dont set this for GTK. A lot of tests below assumes Xt when
1695 dnl USE_X_TOOLKIT is set.
1696 USE_X_TOOLKIT=none ;;
1697 no ) USE_X_TOOLKIT=none ;;
1698 dnl If user did not say whether to use a toolkit,
1699 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1700 * ) USE_X_TOOLKIT=maybe ;;
1701 esac
1702 ;;
1703 mac | none )
1704 HAVE_X_WINDOWS=no
1705 HAVE_X11=no
1706 USE_X_TOOLKIT=none
1707 ;;
1708 esac
1710 ### If we're using X11, we should use the X menu package.
1711 HAVE_MENUS=no
1712 case ${HAVE_X11} in
1713 yes ) HAVE_MENUS=yes ;;
1714 esac
1716 if test "${opsys}" = "hpux9"; then
1717 case "${x_libraries}" in
1718 *X11R4* )
1719 opsysfile="s/hpux9-x11r4.h"
1720 ;;
1721 esac
1722 fi
1724 if test "${opsys}" = "hpux9shr"; then
1725 case "${x_libraries}" in
1726 *X11R4* )
1727 opsysfile="s/hpux9shxr4.h"
1728 ;;
1729 esac
1730 fi
1732 ### Compute the unexec source name from the object name.
1733 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1735 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1736 # Assume not, until told otherwise.
1737 GNU_MALLOC=yes
1738 doug_lea_malloc=yes
1739 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1740 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1741 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1742 emacs_cv_var___after_morecore_hook,
1743 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1744 emacs_cv_var___after_morecore_hook=yes,
1745 emacs_cv_var___after_morecore_hook=no)])
1746 if test $emacs_cv_var___after_morecore_hook = no; then
1747 doug_lea_malloc=no
1748 fi
1749 if test "${system_malloc}" = "yes"; then
1750 GNU_MALLOC=no
1751 GNU_MALLOC_reason="
1752 (The GNU allocators don't work with this system configuration.)"
1753 fi
1754 if test "$doug_lea_malloc" = "yes" ; then
1755 if test "$GNU_MALLOC" = yes ; then
1756 GNU_MALLOC_reason="
1757 (Using Doug Lea's new malloc from the GNU C Library.)"
1758 fi
1759 AC_DEFINE(DOUG_LEA_MALLOC, 1,
1760 [Define to 1 if you are using the GNU C Library.])
1761 fi
1763 if test x"${REL_ALLOC}" = x; then
1764 REL_ALLOC=${GNU_MALLOC}
1765 fi
1767 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1768 dnl the system configuration file (s/*.h) to turn the use of mmap
1769 dnl in the relocating allocator on.
1771 AC_FUNC_MMAP
1772 if test $use_mmap_for_buffers = yes; then
1773 REL_ALLOC=no
1774 fi
1776 LIBS="$libsrc_libs $LIBS"
1778 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1779 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1780 AC_CHECK_LIB(dnet, dnet_ntoa)
1781 dnl This causes -lresolv to get used in subsequent tests,
1782 dnl which causes failures on some systems such as HPUX 9.
1783 dnl AC_CHECK_LIB(resolv, gethostbyname)
1785 dnl FIXME replace main with a function we actually want from this library.
1786 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1788 AC_CHECK_LIB(pthreads, cma_open)
1790 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1791 if test -d /usr/X386/include; then
1792 HAVE_XFREE386=yes
1793 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1794 else
1795 HAVE_XFREE386=no
1796 fi
1797 AC_MSG_RESULT($HAVE_XFREE386)
1799 dnl Check for need for bigtoc support on IBM AIX
1801 case ${host_os} in
1802 aix*)
1803 AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1804 case $GCC in
1805 yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1806 *) gdb_cv_bigtoc=-bbigtoc ;;
1807 esac
1809 LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1810 AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1811 ])
1812 ;;
1813 esac
1815 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1816 # used for the tests that follow. We set them back to REAL_CFLAGS and
1817 # REAL_CPPFLAGS later on.
1819 REAL_CPPFLAGS="$CPPFLAGS"
1821 if test "${HAVE_X11}" = "yes"; then
1822 DEFS="$C_SWITCH_X_SITE $DEFS"
1823 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1824 LIBS="$LIBX $LIBS"
1825 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1826 CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1828 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1829 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1830 # but it's more convenient here to set LD_RUN_PATH
1831 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1832 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1833 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1834 export LD_RUN_PATH
1835 fi
1837 if test "${opsys}" = "gnu-linux"; then
1838 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1839 AC_TRY_LINK([],
1840 [XOpenDisplay ("foo");],
1841 [xlinux_first_failure=no],
1842 [xlinux_first_failure=yes])
1843 if test "${xlinux_first_failure}" = "yes"; then
1844 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1845 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1846 OLD_CPPFLAGS="$CPPFLAGS"
1847 OLD_LIBS="$LIBS"
1848 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1849 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1850 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1851 LIBS="$LIBS -b i486-linuxaout"
1852 AC_TRY_LINK([],
1853 [XOpenDisplay ("foo");],
1854 [xlinux_second_failure=no],
1855 [xlinux_second_failure=yes])
1856 if test "${xlinux_second_failure}" = "yes"; then
1857 # If we get the same failure with -b, there is no use adding -b.
1858 # So take it out. This plays safe.
1859 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1860 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1861 CPPFLAGS="$OLD_CPPFLAGS"
1862 LIBS="$OLD_LIBS"
1863 AC_MSG_RESULT(no)
1864 else
1865 AC_MSG_RESULT(yes)
1866 fi
1867 else
1868 AC_MSG_RESULT(no)
1869 fi
1870 fi
1872 # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1873 # header files included from there.
1874 AC_MSG_CHECKING(for Xkb)
1875 AC_TRY_LINK([#include <X11/Xlib.h>
1876 #include <X11/XKBlib.h>],
1877 [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1878 emacs_xkb=yes, emacs_xkb=no)
1879 AC_MSG_RESULT($emacs_xkb)
1880 if test $emacs_xkb = yes; then
1881 AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1882 fi
1884 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1885 XScreenNumberOfScreen XSetWMProtocols)
1886 fi
1888 if test "${window_system}" = "x11"; then
1889 AC_MSG_CHECKING(X11 version 6)
1890 AC_CACHE_VAL(emacs_cv_x11_version_6,
1891 [AC_TRY_LINK([#include <X11/Xlib.h>],
1892 [#if XlibSpecificationRelease < 6
1893 fail;
1894 #endif
1895 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1896 if test $emacs_cv_x11_version_6 = yes; then
1897 AC_MSG_RESULT(6 or newer)
1898 AC_DEFINE(HAVE_X11R6, 1,
1899 [Define to 1 if you have the X11R6 or newer version of Xlib.])
1900 else
1901 AC_MSG_RESULT(before 6)
1902 fi
1903 fi
1905 if test "${window_system}" = "x11"; then
1906 AC_MSG_CHECKING(X11 version 5)
1907 AC_CACHE_VAL(emacs_cv_x11_version_5,
1908 [AC_TRY_LINK([#include <X11/Xlib.h>],
1909 [#if XlibSpecificationRelease < 5
1910 fail;
1911 #endif
1912 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no)])
1913 if test $emacs_cv_x11_version_5 = yes; then
1914 AC_MSG_RESULT(5 or newer)
1915 HAVE_X11R5=yes
1916 AC_DEFINE(HAVE_X11R5, 1,
1917 [Define to 1 if you have the X11R5 or newer version of Xlib.])
1918 else
1919 HAVE_X11R5=no
1920 AC_MSG_RESULT(before 5)
1921 fi
1922 fi
1924 dnl This function defintion taken from Gnome 2.0
1925 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1926 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1927 dnl also defines GSTUFF_PKG_ERRORS on error
1928 AC_DEFUN([PKG_CHECK_MODULES], [
1929 succeeded=no
1931 if test -z "$PKG_CONFIG"; then
1932 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1933 fi
1935 if test "$PKG_CONFIG" = "no" ; then
1936 echo "*** The pkg-config script could not be found. Make sure it is"
1937 echo "*** in your path, or give the full path to pkg-config with"
1938 echo "*** the PKG_CONFIG environment variable or --with-pkg-config-prog."
1939 echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1940 else
1941 PKG_CONFIG_MIN_VERSION=0.9.0
1942 if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1943 AC_MSG_CHECKING(for $2)
1945 if $PKG_CONFIG --exists "$2" ; then
1946 AC_MSG_RESULT(yes)
1947 succeeded=yes
1949 AC_MSG_CHECKING($1_CFLAGS)
1950 $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1951 AC_MSG_RESULT($$1_CFLAGS)
1953 AC_MSG_CHECKING($1_LIBS)
1954 $1_LIBS=`$PKG_CONFIG --libs "$2"`
1955 AC_MSG_RESULT($$1_LIBS)
1956 else
1957 $1_CFLAGS=""
1958 $1_LIBS=""
1959 ## If we have a custom action on failure, don't print errors, but
1960 ## do set a variable so people can do so.
1961 $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1962 ifelse([$4], ,echo $$1_PKG_ERRORS,)
1963 fi
1965 AC_SUBST($1_CFLAGS)
1966 AC_SUBST($1_LIBS)
1967 else
1968 echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1969 echo "*** See http://www.freedesktop.org/software/pkgconfig"
1970 fi
1971 fi
1973 if test $succeeded = yes; then
1974 ifelse([$3], , :, [$3])
1975 else
1976 ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1977 fi
1978 ])
1980 HAVE_GTK=no
1981 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "gtk"; then
1982 if test "$USE_X_TOOLKIT" != "none" && test "$USE_X_TOOLKIT" != "maybe"; then
1983 AC_MSG_ERROR([Conflicting options, --with-gtk is incompatible with --with-x-toolkit=${with_x_toolkit}]);
1984 fi
1985 GLIB_REQUIRED=2.0.1
1986 GTK_REQUIRED=2.0.1
1987 GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1989 dnl Check if --with-pkg-config-prog has been given.
1990 if test "X${with_pkg_config_prog}" != X; then
1991 PKG_CONFIG="${with_pkg_config_prog}"
1992 fi
1993 dnl Checks for libraries.
1994 PKG_CHECK_MODULES(GTK, $GTK_MODULES)
1995 AC_SUBST(GTK_CFLAGS)
1996 AC_SUBST(GTK_LIBS)
1997 C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1998 CFLAGS="$CFLAGS $GTK_CFLAGS"
1999 LIBS="$GTK_LIBS $LIBS"
2000 HAVE_GTK=yes
2001 AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
2002 USE_X_TOOLKIT=none
2004 dnl GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2005 dnl a lot if #ifdef:s, say we have toolkit scrollbars.
2006 if test "$with_toolkit_scroll_bars" != no; then
2007 with_toolkit_scroll_bars=yes
2008 fi
2010 dnl Check if we can use multiple displays with this GTK version.
2011 dnl If gdk_display_open exists, assume all others are there also.
2012 HAVE_GTK_MULTIDISPLAY=no
2013 AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
2014 if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
2015 AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
2016 [Define to 1 if GTK can handle more than one display.])
2017 fi
2018 dnl Check if we have the old file selection dialog.
2019 dnl If gdk_display_open exists, assume all others are there also.
2020 HAVE_GTK_FILE_SELECTION=no
2021 AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
2023 dnl Check if we have the new file chooser dialog
2024 dnl If gdk_display_open exists, assume all others are there also.
2025 HAVE_GTK_FILE_CHOOSER=no
2026 AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
2028 if test "$HAVE_GTK_FILE_SELECTION" = yes \
2029 && test "$HAVE_GTK_FILE_CHOOSER" = yes; then
2030 AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
2031 [Define to 1 if GTK has both file selection and chooser dialog.])
2032 fi
2034 dnl Check if pthreads are available. Emacs only needs this when using
2035 dnl gtk_file_chooser under Gnome.
2036 if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
2037 HAVE_GTK_AND_PTHREAD=no
2038 AC_CHECK_HEADERS(pthread.h)
2039 if test "$ac_cv_header_pthread_h"; then
2040 AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
2041 fi
2042 if test "$HAVE_GTK_AND_PTHREAD" = yes; then
2043 GTK_LIBS="$GTK_LIBS -lpthread"
2044 AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
2045 [Define to 1 if you have GTK and pthread (-lpthread).])
2046 fi
2047 fi
2048 fi
2050 dnl Do not put whitespace before the #include statements below.
2051 dnl Older compilers (eg sunos4 cc) choke on it.
2052 if test x"${USE_X_TOOLKIT}" = xmaybe; then
2053 if test x"${HAVE_X11R5}" = xyes; then
2054 AC_MSG_CHECKING(X11 version 5 with Xaw)
2055 AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
2056 [AC_TRY_LINK([
2057 #include <X11/Intrinsic.h>
2058 #include <X11/Xaw/Simple.h>],
2059 [],
2060 emacs_cv_x11_version_5_with_xaw=yes,
2061 emacs_cv_x11_version_5_with_xaw=no)])
2062 if test $emacs_cv_x11_version_5_with_xaw = yes; then
2063 AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
2064 USE_X_TOOLKIT=LUCID
2065 else
2066 AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
2067 USE_X_TOOLKIT=none
2068 fi
2069 else
2070 USE_X_TOOLKIT=none
2071 fi
2072 fi
2074 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2076 if test "${USE_X_TOOLKIT}" != "none"; then
2077 AC_MSG_CHECKING(X11 toolkit version)
2078 AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2079 [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2080 [#if XtSpecificationRelease < 6
2081 fail;
2082 #endif
2083 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2084 HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2085 if test $emacs_cv_x11_toolkit_version_6 = yes; then
2086 AC_MSG_RESULT(6 or newer)
2087 AC_DEFINE(HAVE_X11XTR6, 1,
2088 [Define to 1 if you have the X11R6 or newer version of Xt.])
2089 else
2090 AC_MSG_RESULT(before 6)
2091 fi
2093 dnl If using toolkit, check whether libXmu.a exists.
2094 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2095 OLDLIBS="$LIBS"
2096 if test x$HAVE_X11XTR6 = xyes; then
2097 LIBS="-lXt -lSM -lICE $LIBS"
2098 else
2099 LIBS="-lXt $LIBS"
2100 fi
2101 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2102 test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2103 fi
2105 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2106 if test "${HAVE_X11}" = "yes"; then
2107 if test "${USE_X_TOOLKIT}" != "none"; then
2108 AC_CHECK_LIB(Xext, XShapeQueryExtension)
2109 fi
2110 fi
2112 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2113 AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2114 [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2115 [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2116 int x = 5;
2117 #else
2118 Motif version prior to 2.1.
2119 #endif],
2120 emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2121 HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
2122 if test $emacs_cv_motif_version_2_1 = yes; then
2123 HAVE_LIBXP=no
2124 AC_DEFINE(HAVE_MOTIF_2_1, 1,
2125 [Define to 1 if you have Motif 2.1 or newer.])
2126 AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
2127 if test ${HAVE_LIBXP} = yes; then
2128 AC_DEFINE(HAVE_LIBXP, 1,
2129 [Define to 1 if you have the Xp library (-lXp).])
2130 fi
2131 else
2132 AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2133 # We put this in CFLAGS temporarily to precede other -I options
2134 # that might be in CFLAGS temporarily.
2135 # We put this in CPPFLAGS where it precedes the other -I options.
2136 OLD_CPPFLAGS=$CPPFLAGS
2137 OLD_CFLAGS=$CFLAGS
2138 CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2139 CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2140 [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2141 [int x = 5;],
2142 emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2143 if test $emacs_cv_lesstif = yes; then
2144 # Make sure this -I option remains in CPPFLAGS after it is set
2145 # back to REAL_CPPFLAGS.
2146 # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2147 # have those other -I options anyway. Ultimately, having this
2148 # directory ultimately in CPPFLAGS will be enough.
2149 REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2150 LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2151 else
2152 CFLAGS=$OLD_CFLAGS
2153 CPPFLAGS=$OLD_CPPFLAGS
2154 fi
2155 fi
2156 fi
2158 ### Is -lXaw3d available?
2159 HAVE_XAW3D=no
2160 if test "${HAVE_X11}" = "yes"; then
2161 if test "${USE_X_TOOLKIT}" != "none"; then
2162 dnl Fixme: determine what Scrollbar.h needs to avoid compilation
2163 dnl errors from the test without the `-'.
2164 AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
2165 [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes)], , -)
2166 if test "${HAVE_XAW3D}" = "yes"; then
2167 AC_DEFINE(HAVE_XAW3D, 1,
2168 [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2169 fi
2170 fi
2171 fi
2173 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2174 dnl using Motif or Xaw3d is available, and unless
2175 dnl --with-toolkit-scroll-bars=no was specified.
2177 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2178 [Define to 1 if we should use toolkit scroll bars.])dnl
2179 USE_TOOLKIT_SCROLL_BARS=no
2180 if test "${with_toolkit_scroll_bars}" != "no"; then
2181 if test "${USE_X_TOOLKIT}" != "none"; then
2182 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2183 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2184 HAVE_XAW3D=no
2185 USE_TOOLKIT_SCROLL_BARS=yes
2186 elif test "${HAVE_XAW3D}" = "yes"; then
2187 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2188 USE_TOOLKIT_SCROLL_BARS=yes
2189 fi
2190 elif test "${HAVE_GTK}" = "yes"; then
2191 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2192 USE_TOOLKIT_SCROLL_BARS=yes
2193 elif test "${HAVE_CARBON}" = "yes"; then
2194 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2195 USE_TOOLKIT_SCROLL_BARS=yes
2196 fi
2197 fi
2199 dnl See if XIM is available.
2200 AC_TRY_COMPILE([
2201 #include <X11/Xlib.h>
2202 #include <X11/Xresource.h>],
2203 [XIMProc callback;],
2204 HAVE_XIM=yes
2205 AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available]),
2206 HAVE_XIM=no)
2208 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2210 if test "${with_xim}" != "no"; then
2211 AC_DEFINE(USE_XIM, 1,
2212 [Define to 1 if we should use XIM, if it is available.])
2213 fi
2216 if test "${HAVE_XIM}" != "no"; then
2217 late_CFLAGS=$CFLAGS
2218 if test "$GCC" = yes; then
2219 CFLAGS="$CFLAGS --pedantic-errors"
2220 fi
2221 AC_TRY_COMPILE([
2222 #include <X11/Xlib.h>
2223 #include <X11/Xresource.h>],
2224 [Display *display;
2225 XrmDatabase db;
2226 char *res_name;
2227 char *res_class;
2228 XIMProc callback;
2229 XPointer *client_data;
2230 #ifndef __GNUC__
2231 /* If we're not using GCC, it's probably not XFree86, and this is
2232 probably right, but we can't use something like --pedantic-errors. */
2233 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2234 char*, XIMProc, XPointer*);
2235 #endif
2236 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2237 client_data);],
2238 [emacs_cv_arg6_star=yes])
2239 AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2240 [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2241 either XPointer or XPointer*.])dnl
2242 if test "$emacs_cv_arg6_star" = yes; then
2243 AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2244 else
2245 AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2246 fi
2247 CFLAGS=$late_CFLAGS
2248 fi
2250 ### Use -lXpm if available, unless `--with-xpm=no'.
2251 HAVE_XPM=no
2252 if test "${HAVE_X11}" = "yes"; then
2253 if test "${with_xpm}" != "no"; then
2254 AC_CHECK_HEADER(X11/xpm.h,
2255 AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
2256 if test "${HAVE_XPM}" = "yes"; then
2257 AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2258 AC_EGREP_CPP(no_return_alloc_pixels,
2259 [#include "X11/xpm.h"
2260 #ifndef XpmReturnAllocPixels
2261 no_return_alloc_pixels
2262 #endif
2263 ], HAVE_XPM=no, HAVE_XPM=yes)
2265 if test "${HAVE_XPM}" = "yes"; then
2266 AC_MSG_RESULT(yes)
2267 else
2268 AC_MSG_RESULT(no)
2269 fi
2270 fi
2271 fi
2273 if test "${HAVE_XPM}" = "yes"; then
2274 AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2275 fi
2276 fi
2278 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2279 HAVE_JPEG=no
2280 if test "${HAVE_X11}" = "yes"; then
2281 if test "${with_jpeg}" != "no"; then
2282 dnl Checking for jpeglib.h can lose because of a redefinition of
2283 dnl HAVE_STDLIB_H.
2284 AC_CHECK_HEADER(jerror.h,
2285 AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes))
2286 fi
2288 AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2289 if test "${HAVE_JPEG}" = "yes"; then
2290 AC_DEFINE(HAVE_JPEG)
2291 AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2292 [#include <jpeglib.h>
2293 version=JPEG_LIB_VERSION
2294 ],
2295 AC_DEFINE(HAVE_JPEG),
2296 [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2297 HAVE_JPEG=no])
2298 fi
2299 fi
2301 ### Use -lpng if available, unless `--with-png=no'.
2302 HAVE_PNG=no
2303 if test "${HAVE_X11}" = "yes"; then
2304 if test "${with_png}" != "no"; then
2305 # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2306 # in /usr/include/libpng.
2307 AC_CHECK_HEADERS(png.h libpng/png.h)
2308 if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2309 AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2310 fi
2311 fi
2313 if test "${HAVE_PNG}" = "yes"; then
2314 AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2315 fi
2316 fi
2318 ### Use -ltiff if available, unless `--with-tiff=no'.
2319 HAVE_TIFF=no
2320 if test "${HAVE_X11}" = "yes"; then
2321 if test "${with_tiff}" != "no"; then
2322 AC_CHECK_HEADER(tiffio.h,
2323 tifflibs="-lz -lm"
2324 # At least one tiff package requires the jpeg library.
2325 if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2326 AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
2327 fi
2329 if test "${HAVE_TIFF}" = "yes"; then
2330 AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2331 fi
2332 fi
2334 ### Use -lgif if available, unless `--with-gif=no'.
2335 HAVE_GIF=no
2336 if test "${HAVE_X11}" = "yes"; then
2337 if test "${with_gif}" != "no"; then
2338 AC_CHECK_HEADER(gif_lib.h,
2339 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2340 # Earlier versions can crash Emacs.
2341 AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes))
2342 fi
2344 if test "${HAVE_GIF}" = "yes"; then
2345 AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have the ungif library (-lungif).])
2346 fi
2347 fi
2349 dnl Check for malloc/malloc.h on darwin
2350 AC_CHECK_HEADER(malloc/malloc.h, AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.]))
2352 ### Use Mac OS X Carbon API to implement GUI.
2353 if test "${HAVE_CARBON}" = "yes"; then
2354 AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2355 ## Specify the install directory
2356 carbon_appdir=
2357 if test "${carbon_appdir_x}" != ""; then
2358 case ${carbon_appdir_x} in
2359 y | ye | yes) carbon_appdir=/Applications ;;
2360 * ) carbon_appdir=${carbon_appdir_x} ;;
2361 esac
2362 fi
2363 # We also have mouse menus.
2364 HAVE_MENUS=yes
2366 tmp_CFLAGS="$CFLAGS"
2367 CFLAGS="$CFLAGS -framework Carbon"
2368 AC_CHECK_FUNC(CancelMenuTracking, have_cmt=yes, have_cmt=no)
2369 if test "$have_cmt" = yes; then
2370 AC_DEFINE(HAVE_CANCELMENUTRACKING, 1,
2371 [Define to 1 if CancelMenuTracking is available (Mac OSX).])
2372 fi
2373 CFLAGS="$tmp_CFLAGS"
2374 fi
2376 ### Use session management (-lSM -lICE) if available
2377 HAVE_X_SM=no
2378 if test "${HAVE_X11}" = "yes"; then
2379 AC_CHECK_HEADER(X11/SM/SMlib.h,
2380 AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE))
2382 if test "${HAVE_X_SM}" = "yes"; then
2383 AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2384 case "$LIBS" in
2385 *-lSM*) ;;
2386 *) LIBS="-lSM -lICE $LIBS" ;;
2387 esac
2388 fi
2389 fi
2391 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2392 AC_CACHE_CHECK(whether netdb declares h_errno,
2393 emacs_cv_netdb_declares_h_errno,
2394 [AC_TRY_LINK([#include <netdb.h>],
2395 [return h_errno;],
2396 emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2397 if test $emacs_cv_netdb_declares_h_errno = yes; then
2398 AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2399 fi
2401 AC_FUNC_ALLOCA
2403 # fmod, logb, and frexp are found in -lm on most systems.
2404 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2405 AC_CHECK_LIB(m, sqrt)
2407 # Check for mail-locking functions in a "mail" library. Probably this should
2408 # have the same check as for liblockfile below.
2409 AC_CHECK_LIB(mail, maillock)
2410 dnl Debian, at least:
2411 AC_CHECK_LIB(lockfile, maillock)
2412 # If we have the shared liblockfile, assume we must use it for mail
2413 # locking (e.g. Debian). If we couldn't link against liblockfile
2414 # (no liblockfile.a installed), ensure that we don't need to.
2415 if test "$ac_cv_lib_lockfile_maillock" = no; then
2416 dnl This works for files generally, not just executables.
2417 dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf?
2418 AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2419 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2420 if test $ac_cv_prog_liblockfile = yes; then
2421 AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2422 This probably means that movemail could lose mail.
2423 There may be a `development' package to install containing liblockfile.])
2424 else :
2425 fi
2426 fi
2427 AC_CHECK_FUNCS(touchlock)
2428 AC_CHECK_HEADERS(maillock.h)
2430 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2431 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2432 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
2433 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2434 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2435 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2436 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2437 gai_strerror mkstemp getline getdelim mremap memmove fsync bzero \
2438 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2440 AC_CHECK_HEADERS(sys/un.h)
2442 AC_FUNC_MKTIME
2443 if test "$ac_cv_func_working_mktime" = no; then
2444 AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2445 fi
2447 AC_FUNC_GETLOADAVG
2449 AC_FUNC_FSEEKO
2451 # Configure getopt.
2452 m4_include([m4/getopt.m4])
2453 gl_GETOPT_IFELSE([
2454 gl_GETOPT_SUBSTITUTE_HEADER
2455 gl_PREREQ_GETOPT
2456 GETOPTOBJS='getopt.o getopt1.o'
2457 ])
2458 AC_SUBST(GETOPTOBJS)
2460 AC_FUNC_GETPGRP
2462 AC_FUNC_STRFTIME
2464 # UNIX98 PTYs.
2465 AC_CHECK_FUNCS(grantpt)
2467 # PTY-related GNU extensions.
2468 AC_CHECK_FUNCS(getpt)
2470 # Check this now, so that we will NOT find the above functions in ncurses.
2471 # That is because we have not set up to link ncurses in lib-src.
2472 # It's better to believe a function is not available
2473 # than to expect to find it in ncurses.
2474 AC_CHECK_LIB(ncurses, tparm)
2476 # Do we need the Hesiod library to provide the support routines?
2477 if test "$with_hesiod" = yes ; then
2478 # Don't set $LIBS here -- see comments above.
2479 resolv=no
2480 AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2481 [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2482 [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2483 if test "$resolv" = yes ; then
2484 RESOLVLIB=-lresolv
2485 AC_DEFINE(HAVE_LIBRESOLV, 1,
2486 [Define to 1 if you have the resolv library (-lresolv).])
2487 else
2488 RESOLVLIB=
2489 fi
2490 AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2491 AC_DEFINE(HAVE_LIBHESIOD, 1,
2492 [Define to 1 if you have the hesiod library (-lhesiod).]),
2493 :, $RESOLVLIB)])
2494 fi
2496 # These tell us which Kerberos-related libraries to use.
2497 if test "${with_kerberos+set}" = set; then
2498 AC_CHECK_LIB(com_err, com_err)
2499 AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2500 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2501 AC_CHECK_LIB(krb5, krb5_init_context)
2502 if test "${with_kerberos5+set}" != set; then
2503 AC_CHECK_LIB(des425, des_cbc_encrypt,,
2504 AC_CHECK_LIB(des, des_cbc_encrypt))
2505 AC_CHECK_LIB(krb4, krb_get_cred,,
2506 AC_CHECK_LIB(krb, krb_get_cred))
2507 fi
2509 if test "${with_kerberos5+set}" = set; then
2510 AC_CHECK_HEADERS(krb5.h)
2511 else
2512 AC_CHECK_HEADERS(des.h,,
2513 [AC_CHECK_HEADERS(kerberosIV/des.h,,
2514 [AC_CHECK_HEADERS(kerberos/des.h)])])
2515 AC_CHECK_HEADERS(krb.h,,
2516 [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2517 [AC_CHECK_HEADERS(kerberos/krb.h)])])
2518 fi
2519 AC_CHECK_HEADERS(com_err.h)
2520 fi
2522 # Solaris requires -lintl if you want strerror (which calls dgettext)
2523 # to return localized messages.
2524 AC_CHECK_LIB(intl, dgettext)
2526 AC_MSG_CHECKING(whether localtime caches TZ)
2527 AC_CACHE_VAL(emacs_cv_localtime_cache,
2528 [if test x$ac_cv_func_tzset = xyes; then
2529 AC_TRY_RUN([#include <time.h>
2530 extern char **environ;
2531 unset_TZ ()
2532 {
2533 char **from, **to;
2534 for (to = from = environ; (*to = *from); from++)
2535 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2536 to++;
2537 }
2538 char TZ_GMT0[] = "TZ=GMT0";
2539 char TZ_PST8[] = "TZ=PST8";
2540 main()
2541 {
2542 time_t now = time ((time_t *) 0);
2543 int hour_GMT0, hour_unset;
2544 if (putenv (TZ_GMT0) != 0)
2545 exit (1);
2546 hour_GMT0 = localtime (&now)->tm_hour;
2547 unset_TZ ();
2548 hour_unset = localtime (&now)->tm_hour;
2549 if (putenv (TZ_PST8) != 0)
2550 exit (1);
2551 if (localtime (&now)->tm_hour == hour_GMT0)
2552 exit (1);
2553 unset_TZ ();
2554 if (localtime (&now)->tm_hour != hour_unset)
2555 exit (1);
2556 exit (0);
2557 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2558 [# If we have tzset, assume the worst when cross-compiling.
2559 emacs_cv_localtime_cache=yes])
2560 else
2561 # If we lack tzset, report that localtime does not cache TZ,
2562 # since we can't invalidate the cache if we don't have tzset.
2563 emacs_cv_localtime_cache=no
2564 fi])dnl
2565 AC_MSG_RESULT($emacs_cv_localtime_cache)
2566 if test $emacs_cv_localtime_cache = yes; then
2567 AC_DEFINE(LOCALTIME_CACHE, 1,
2568 [Define to 1 if localtime caches TZ.])
2569 fi
2571 if test "x$HAVE_TIMEVAL" = xyes; then
2572 AC_CHECK_FUNCS(gettimeofday)
2573 if test $ac_cv_func_gettimeofday = yes; then
2574 AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2575 emacs_cv_gettimeofday_two_arguments,
2576 [AC_TRY_COMPILE([
2577 #ifdef TIME_WITH_SYS_TIME
2578 #include <sys/time.h>
2579 #include <time.h>
2580 #else
2581 #ifdef HAVE_SYS_TIME_H
2582 #include <sys/time.h>
2583 #else
2584 #include <time.h>
2585 #endif
2586 #endif],
2587 [struct timeval time;
2588 gettimeofday (&time, 0);],
2589 emacs_cv_gettimeofday_two_arguments=yes,
2590 emacs_cv_gettimeofday_two_arguments=no)])
2591 if test $emacs_cv_gettimeofday_two_arguments = no; then
2592 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2593 [Define to 1 if gettimeofday accepts only one argument.])
2594 fi
2595 fi
2596 fi
2598 # This defines (or not) HAVE_TZNAME and HAVE_TM_ZONE.
2599 AC_STRUCT_TIMEZONE
2601 dnl Note that AC_STRUCT_TIMEZONE doesn't do what you might expect.
2602 if test "$ac_cv_func_gettimeofday" = yes; then
2603 AC_CACHE_CHECK([for struct timezone], emacs_cv_struct_timezone,
2604 [AC_TRY_COMPILE([#include <sys/time.h>],
2605 [struct timezone tz;],
2606 dnl It may be that we can't call gettimeofday with a non-null pointer,
2607 dnl even though we have struct timezone (e.g. HPUX). In that case
2608 dnl we'll lie about struct timezone.
2609 [AC_TRY_RUN([
2610 #ifdef TIME_WITH_SYS_TIME
2611 #include <sys/time.h>
2612 #include <time.h>
2613 #else
2614 #ifdef HAVE_SYS_TIME_H
2615 #include <sys/time.h>
2616 #else
2617 #include <time.h>
2618 #endif
2619 #endif
2620 main () {
2621 struct timeval time;
2622 struct timezone dummy;
2623 exit (gettimeofday (&time, &dummy));
2624 }],
2625 emacs_cv_struct_timezone=yes,
2626 emacs_cv_struct_timezone=no, emacs_cv_struct_timezone=yes)],
2627 emacs_cv_struct_timezone=no)])
2628 fi
2630 ok_so_far=yes
2631 AC_CHECK_FUNC(socket, , ok_so_far=no)
2632 if test $ok_so_far = yes; then
2633 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2634 fi
2635 if test $ok_so_far = yes; then
2636 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2637 fi
2638 if test $ok_so_far = yes; then
2639 dnl Fixme: Not used. Should this be HAVE_SOCKETS?
2640 AC_DEFINE(HAVE_INET_SOCKETS, 1,
2641 [Define to 1 if you have inet sockets.])
2642 fi
2644 AC_CHECK_HEADERS(sys/ioctl.h)
2646 if test -f /usr/lpp/X11/bin/smt.exp; then
2647 AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2648 [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2649 fi
2651 AC_MSG_CHECKING(whether system supports dynamic ptys)
2652 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2653 AC_MSG_RESULT(yes)
2654 AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2655 else
2656 AC_MSG_RESULT(no)
2657 fi
2659 AC_FUNC_FORK
2661 dnl Adapted from Haible's version.
2662 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2663 [AC_TRY_LINK([#include <langinfo.h>],
2664 [char* cs = nl_langinfo(CODESET);],
2665 emacs_cv_langinfo_codeset=yes,
2666 emacs_cv_langinfo_codeset=no)
2667 ])
2668 if test $emacs_cv_langinfo_codeset = yes; then
2669 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2670 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2671 fi
2673 AC_CHECK_TYPES(size_t)
2675 AC_TYPE_MBSTATE_T
2677 dnl Restrict could probably be used effectively other than in regex.c.
2678 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2679 [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2680 emacs_cv_c_restrict=yes,
2681 [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2682 emacs_cv_c_restrict=__restrict,
2683 emacs_cv_c_restrict=no)])])
2684 case "$emacs_cv_c_restrict" in
2685 yes) emacs_restrict=restrict;;
2686 no) emacs_restrict="";;
2687 *) emacs_restrict="$emacs_cv_c_restrict";;
2688 esac
2689 if test "$emacs_restrict" != __restrict; then
2690 AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2691 [Define to compiler's equivalent of C99 restrict keyword.
2692 Don't define if equivalent is `__restrict'.])
2693 fi
2695 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2696 [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2697 emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2698 if test "$emacs_cv_c_restrict_arr" = yes; then
2699 AC_DEFINE(__restrict_arr, __restrict,
2700 [Define to compiler's equivalent of C99 restrict keyword in array
2701 declarations. Define as empty for no equivalent.])
2702 fi
2704 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2705 dnl how the tty code is related to POSIX and/or other versions of termios.
2706 dnl The following looks like a useful start.
2707 dnl
2708 dnl AC_SYS_POSIX_TERMIOS
2709 dnl if test $ac_cv_sys_posix_termios = yes; then
2710 dnl AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2711 dnl and macros for terminal control.])
2712 dnl AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2713 dnl fi
2715 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used. (Needs libobj replacement.)
2717 # Set up the CFLAGS for real compilation, so we can substitute it.
2718 CFLAGS="$REAL_CFLAGS"
2719 CPPFLAGS="$REAL_CPPFLAGS"
2721 #### Find out which version of Emacs this is.
2722 [version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
2723 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2724 if test x"${version}" = x; then
2725 AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2726 fi
2728 ### Specify what sort of things we'll be editing into Makefile and config.h.
2729 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2730 AC_SUBST(version)
2731 AC_SUBST(configuration)
2732 AC_SUBST(canonical)
2733 AC_SUBST(srcdir)
2734 AC_SUBST(prefix)
2735 AC_SUBST(exec_prefix)
2736 AC_SUBST(bindir)
2737 AC_SUBST(datadir)
2738 AC_SUBST(sharedstatedir)
2739 AC_SUBST(libexecdir)
2740 AC_SUBST(mandir)
2741 AC_SUBST(infodir)
2742 AC_SUBST(lispdir)
2743 AC_SUBST(locallisppath)
2744 AC_SUBST(lisppath)
2745 AC_SUBST(x_default_search_path)
2746 AC_SUBST(etcdir)
2747 AC_SUBST(archlibdir)
2748 AC_SUBST(docdir)
2749 AC_SUBST(bitmapdir)
2750 AC_SUBST(gamedir)
2751 AC_SUBST(gameuser)
2752 AC_SUBST(c_switch_system)
2753 AC_SUBST(c_switch_machine)
2754 AC_SUBST(LD_SWITCH_X_SITE)
2755 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2756 AC_SUBST(C_SWITCH_X_SITE)
2757 AC_SUBST(CFLAGS)
2758 AC_SUBST(X_TOOLKIT_TYPE)
2759 AC_SUBST(machfile)
2760 AC_SUBST(opsysfile)
2761 AC_SUBST(GETLOADAVG_LIBS)
2762 AC_SUBST(carbon_appdir)
2764 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}",
2765 [Define to the canonical Emacs configuration name.])
2766 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2767 [Define to the options passed to configure.])
2768 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}",
2769 [Define to the used machine dependent file.])
2770 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2771 [Define to the used os dependent file.])
2772 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2773 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2774 may need to deal with X Windows. For instance, if you've defined
2775 HAVE_X_WINDOWS above and your X libraries aren't in a place that
2776 your loader can find on its own, you might want to add "-L/..." or
2777 something similar.])
2778 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2779 [Define LD_SWITCH_X_SITE_AUX with an -R option
2780 in case it's needed (for Solaris, for example).])
2781 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE},
2782 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2783 may need to deal with X Windows. For instance, if you've defined
2784 HAVE_X_WINDOWS above and your X include files aren't in a place
2785 that your compiler can find on its own, you might want to add
2786 "-I/..." or something similar.])
2787 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC},
2788 [Define to the unexec source file name.])
2790 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2791 AC_DEFINE(HAVE_X_WINDOWS, 1,
2792 [Define to 1 if you want to use the X window system.])
2793 fi
2794 if test "${USE_X_TOOLKIT}" != "none" ; then
2795 AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2796 fi
2797 if test "${HAVE_X11}" = "yes" ; then
2798 AC_DEFINE(HAVE_X11, 1,
2799 [Define to 1 if you want to use version 11 of X windows.
2800 Otherwise, Emacs expects to use version 10.])
2801 fi
2802 if test "${HAVE_XFREE386}" = "yes" ; then
2803 AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
2804 fi
2805 if test "${HAVE_MENUS}" = "yes" ; then
2806 AC_DEFINE(HAVE_MENUS, 1,
2807 [Define to 1 if you have mouse menus.
2808 (This is automatic if you use X, but the option to specify it remains.)
2809 It is also defined with other window systems that support xmenu.c.])
2810 fi
2811 if test "${GNU_MALLOC}" = "yes" ; then
2812 AC_DEFINE(GNU_MALLOC, 1,
2813 [Define to 1 if you want to use the GNU memory allocator.])
2814 fi
2815 if test "${REL_ALLOC}" = "yes" ; then
2816 AC_DEFINE(REL_ALLOC, 1,
2817 [Define REL_ALLOC if you want to use the relocating allocator for
2818 buffer space.])
2819 fi
2821 AH_TOP([/* GNU Emacs site configuration template file.
2822 Copyright (C) 1988, 1993, 1994, 1999, 2000, 2002, 2004
2823 Free Software Foundation, Inc.
2825 This file is part of GNU Emacs.
2827 GNU Emacs is free software; you can redistribute it and/or modify
2828 it under the terms of the GNU General Public License as published by
2829 the Free Software Foundation; either version 2, or (at your option)
2830 any later version.
2832 GNU Emacs is distributed in the hope that it will be useful,
2833 but WITHOUT ANY WARRANTY; without even the implied warranty of
2834 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
2835 GNU General Public License for more details.
2837 You should have received a copy of the GNU General Public License
2838 along with GNU Emacs; see the file COPYING. If not, write to the
2839 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
2840 Boston, MA 02110-1301, USA. */
2843 /* No code in Emacs #includes config.h twice, but some bits of code
2844 intended to work with other packages as well (like gmalloc.c)
2845 think they can include it as many times as they like. */
2846 #ifndef EMACS_CONFIG_H
2847 #define EMACS_CONFIG_H
2848 ])dnl
2850 AH_BOTTOM([
2851 /* If we're using any sort of window system, define some consequences. */
2852 #ifdef HAVE_X_WINDOWS
2853 #define HAVE_WINDOW_SYSTEM
2854 #define MULTI_KBOARD
2855 #define HAVE_MOUSE
2856 #endif
2858 /* If we're using the Carbon API on Mac OS X, define a few more
2859 variables as well. */
2860 #ifdef HAVE_CARBON
2861 #define HAVE_WINDOW_SYSTEM
2862 #define HAVE_MOUSE
2863 #endif
2865 /* Define USER_FULL_NAME to return a string
2866 that is the user's full name.
2867 It can assume that the variable `pw'
2868 points to the password file entry for this user.
2870 At some sites, the pw_gecos field contains
2871 the user's full name. If neither this nor any other
2872 field contains the right thing, use pw_name,
2873 giving the user's login name, since that is better than nothing. */
2874 #define USER_FULL_NAME pw->pw_gecos
2876 /* Define AMPERSAND_FULL_NAME if you use the convention
2877 that & in the full name stands for the login id. */
2878 /* Turned on June 1996 supposing nobody will mind it. */
2879 #define AMPERSAND_FULL_NAME
2881 /* We have blockinput.h. */
2882 #define DO_BLOCK_INPUT
2884 /* Define HAVE_SOUND if we have sound support. We know it works
2885 and compiles only on the specified platforms. For others,
2886 it probably doesn't make sense to try. */
2888 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2889 #ifdef HAVE_MACHINE_SOUNDCARD_H
2890 #define HAVE_SOUND 1
2891 #endif
2892 #ifdef HAVE_SYS_SOUNDCARD_H
2893 #define HAVE_SOUND 1
2894 #endif
2895 #ifdef HAVE_SOUNDCARD_H
2896 #define HAVE_SOUND 1
2897 #endif
2898 #endif /* __FreeBSD__ || __NetBSD__ || __linux__ */
2900 /* If using GNU, then support inline function declarations. */
2901 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2902 generally, because even if non-gcc compilers accept `inline', they
2903 may reject `extern inline'. */
2904 #if defined (__GNUC__) && defined (OPTIMIZE)
2905 #define INLINE __inline__
2906 #else
2907 #define INLINE
2908 #endif
2910 /* Include the os and machine dependent files. */
2911 #include config_opsysfile
2912 #include config_machfile
2914 /* Load in the conversion definitions if this system
2915 needs them and the source file being compiled has not
2916 said to inhibit this. There should be no need for you
2917 to alter these lines. */
2919 #ifdef SHORTNAMES
2920 #ifndef NO_SHORTNAMES
2921 #include "../shortnames/remap.h"
2922 #endif /* not NO_SHORTNAMES */
2923 #endif /* SHORTNAMES */
2925 /* If no remapping takes place, static variables cannot be dumped as
2926 pure, so don't worry about the `static' keyword. */
2927 #ifdef NO_REMAP
2928 #undef static
2929 #endif
2931 /* Define `subprocesses' should be defined if you want to
2932 have code for asynchronous subprocesses
2933 (as used in M-x compile and M-x shell).
2934 These do not work for some USG systems yet;
2935 for the ones where they work, the s/SYSTEM.h file defines this flag. */
2937 #ifndef VMS
2938 #ifndef USG
2939 /* #define subprocesses */
2940 #endif
2941 #endif
2943 /* SIGTYPE is the macro we actually use. */
2944 #ifndef SIGTYPE
2945 #define SIGTYPE RETSIGTYPE
2946 #endif
2948 #ifdef emacs /* Don't do this for lib-src. */
2949 /* Tell regex.c to use a type compatible with Emacs. */
2950 #define RE_TRANSLATE_TYPE Lisp_Object
2951 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2952 #ifdef make_number
2953 /* If make_number is a macro, use it. */
2954 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2955 #else
2956 /* If make_number is a function, avoid it. */
2957 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2958 #endif
2959 #endif
2961 /* Avoid link-time collision with system mktime if we will use our own. */
2962 #if ! HAVE_MKTIME || BROKEN_MKTIME
2963 #define mktime emacs_mktime
2964 #endif
2966 #define my_strftime nstrftime /* for strftime.c */
2968 /* The rest of the code currently tests the CPP symbol BSTRING.
2969 Override any claims made by the system-description files.
2970 Note that on some SCO version it is possible to have bcopy and not bcmp. */
2971 #undef BSTRING
2972 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2973 #define BSTRING
2974 #endif
2976 /* Some of the files of Emacs which are intended for use with other
2977 programs assume that if you have a config.h file, you must declare
2978 the type of getenv.
2980 This declaration shouldn't appear when alloca.s or Makefile.in
2981 includes config.h. */
2982 #ifndef NOT_C_CODE
2983 extern char *getenv ();
2984 #endif
2986 /* These default definitions are good for almost all machines.
2987 The exceptions override them in m/MACHINE.h. */
2989 #ifndef BITS_PER_CHAR
2990 #define BITS_PER_CHAR 8
2991 #endif
2993 #ifndef BITS_PER_SHORT
2994 #define BITS_PER_SHORT 16
2995 #endif
2997 /* Note that lisp.h uses this in a preprocessor conditional, so it
2998 would not work to use sizeof. That being so, we do all of them
2999 without sizeof, for uniformity's sake. */
3000 #ifndef BITS_PER_INT
3001 #define BITS_PER_INT 32
3002 #endif
3004 #ifndef BITS_PER_LONG
3005 #ifdef _LP64
3006 #define BITS_PER_LONG 64
3007 #else
3008 #define BITS_PER_LONG 32
3009 #endif
3010 #endif
3012 /* Define if the compiler supports function prototypes. It may do so
3013 but not define __STDC__ (e.g. DEC C by default) or may define it as
3014 zero. */
3015 #undef PROTOTYPES
3016 /* For mktime.c: */
3017 #ifndef __P
3018 # if defined PROTOTYPES
3019 # define __P(args) args
3020 # else
3021 # define __P(args) ()
3022 # endif /* GCC. */
3023 #endif /* __P */
3025 /* Don't include "string.h" or <stdlib.h> in non-C code. */
3026 #ifndef NOT_C_CODE
3027 #ifdef HAVE_STRING_H
3028 #include "string.h"
3029 #endif
3030 #ifdef HAVE_STRINGS_H
3031 #include "strings.h" /* May be needed for bcopy & al. */
3032 #endif
3033 #ifdef HAVE_STDLIB_H
3034 #include <stdlib.h>
3035 #endif
3036 #ifndef __GNUC__
3037 # ifdef HAVE_ALLOCA_H
3038 # include <alloca.h>
3039 # else /* AIX files deal with #pragma. */
3040 # ifndef alloca /* predefined by HP cc +Olibcalls */
3041 char *alloca ();
3042 # endif
3043 # endif /* HAVE_ALLOCA_H */
3044 #endif /* __GNUC__ */
3045 #ifndef HAVE_SIZE_T
3046 typedef unsigned size_t;
3047 #endif
3048 #endif /* NOT_C_CODE */
3050 /* Define HAVE_X_I18N if we have usable i18n support. */
3052 #ifdef HAVE_X11R6
3053 #define HAVE_X_I18N
3054 #elif defined HAVE_X11R5 && !defined X11R5_INHIBIT_I18N
3055 #define HAVE_X_I18N
3056 #endif
3058 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support. */
3060 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3061 #define HAVE_X11R6_XIM
3062 #endif
3064 /* Should we enable expensive run-time checking of data types? */
3065 #undef ENABLE_CHECKING
3067 #if defined __GNUC__ && (__GNUC__ > 2 \
3068 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3069 #define NO_RETURN __attribute__ ((__noreturn__))
3070 #else
3071 #define NO_RETURN /* nothing */
3072 #endif
3074 /* These won't be used automatically yet. We also need to know, at least,
3075 that the stack is continuous. */
3076 #ifdef __GNUC__
3077 # ifndef GC_SETJMP_WORKS
3078 /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3079 see NON_SAVING_SETJMP in the target descriptions. */
3080 /* Exceptions (see NON_SAVING_SETJMP in target description) are ns32k,
3081 SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3082 Fixme: Deal with ns32k, SVR3. */
3083 # define GC_SETJMP_WORKS 1
3084 # endif
3085 # ifndef GC_LISP_OBJECT_ALIGNMENT
3086 # define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3087 # endif
3088 #endif
3090 #ifndef HAVE_BCOPY
3091 #define bcopy(a,b,s) memcpy (b,a,s)
3092 #endif
3093 #ifndef HAVE_BZERO
3094 #define bzero(a,s) memset (a,0,s)
3095 #endif
3096 #ifndef HAVE_BCMP
3097 #define BCMP memcmp
3098 #endif
3100 #endif /* EMACS_CONFIG_H */
3102 /*
3103 Local Variables:
3104 mode: c
3105 End:
3106 */
3107 ])dnl
3109 #### Report on what we decided to do.
3110 #### Report GTK as a toolkit, even if it doesn't use Xt.
3111 #### It makes printing result more understandable as using GTK sets
3112 #### toolkit_scroll_bars to yes by default.
3113 if test "${HAVE_GTK}" = "yes"; then
3114 USE_X_TOOLKIT=GTK
3115 fi
3117 echo "
3118 Configured for \`${canonical}'.
3120 Where should the build process find the source code? ${srcdir}
3121 What operating system and machine description files should Emacs use?
3122 \`${opsysfile}' and \`${machfile}'
3123 What compiler should emacs be built with? ${CC} ${CFLAGS}
3124 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
3125 Should Emacs use a relocating allocator for buffers? ${REL_ALLOC}
3126 Should Emacs use mmap(2) for buffer allocation? $use_mmap_for_buffers
3127 What window system should Emacs use? ${window_system}
3128 What toolkit should Emacs use? ${USE_X_TOOLKIT}"
3130 if test -n "${x_includes}"; then
3131 echo " Where do we find X Windows header files? ${x_includes}"
3132 else
3133 echo " Where do we find X Windows header files? Standard dirs"
3134 fi
3135 if test -n "${x_libraries}"; then
3136 echo " Where do we find X Windows libraries? ${x_libraries}"
3137 else
3138 echo " Where do we find X Windows libraries? Standard dirs"
3139 fi
3141 echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}"
3142 echo " Does Emacs use -lXpm? ${HAVE_XPM}"
3143 echo " Does Emacs use -ljpeg? ${HAVE_JPEG}"
3144 echo " Does Emacs use -ltiff? ${HAVE_TIFF}"
3145 echo " Does Emacs use -lungif? ${HAVE_GIF}"
3146 echo " Does Emacs use -lpng? ${HAVE_PNG}"
3147 echo " Does Emacs use X toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}"
3148 echo
3150 if test $USE_XASSERTS = yes; then
3151 echo " Compiling with asserts turned on."
3152 CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3153 echo
3154 fi
3158 # Remove any trailing slashes in these variables.
3159 [test "${prefix}" != NONE &&
3160 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3161 test "${exec_prefix}" != NONE &&
3162 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3164 ## Check if the C preprocessor will convert `..' to `. .'. If so, set
3165 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3166 ## from Makefile.c can correctly provide the arg `-traditional' to the
3167 ## C preprocessor.
3169 AC_EGREP_CPP(yes..yes,
3170 [yes..yes],
3171 CPP_NEED_TRADITIONAL=no,
3172 CPP_NEED_TRADITIONAL=yes)
3174 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3175 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
3176 lisp/Makefile lispref/Makefile lispintro/Makefile leim/Makefile, [
3178 ### Make the necessary directories, if they don't exist.
3179 for dir in etc lisp ; do
3180 test -d ${dir} || mkdir ${dir}
3181 done
3183 # Build src/Makefile from ${srcdir}/src/Makefile.c
3184 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3185 # This must be done after src/config.h is built, since we rely on that file.
3187 # Now get this: Some word that is part of the ${srcdir} directory name
3188 # or the ${configuration} value might, just might, happen to be an
3189 # identifier like `sun4' or `i386' or something, and be predefined by
3190 # the C preprocessor to some helpful value like 1, or maybe the empty
3191 # string. Needless to say consequent macro substitutions are less
3192 # than conducive to the makefile finding the correct directory.
3193 [undefs="`echo $top_srcdir $configuration $canonical |
3194 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
3195 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3196 `"]
3198 echo creating src/epaths.h
3199 ${MAKE-make} epaths-force
3201 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3202 # `..' to `. .' unless invoked with -traditional
3204 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3205 CPPFLAGS="$CPPFLAGS -traditional"
3206 fi
3208 echo creating lib-src/Makefile
3209 ( cd lib-src
3210 rm -f junk.c junk1.c junk2.c
3211 sed -e '/start of cpp stuff/q' \
3212 < Makefile.c > junk1.c
3213 sed -e '1,/start of cpp stuff/d'\
3214 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3215 < Makefile.c > junk.c
3216 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3217 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
3218 cat junk1.c junk2.c > Makefile.new
3219 rm -f junk.c junk1.c junk2.c
3220 chmod 444 Makefile.new
3221 mv -f Makefile.new Makefile
3222 )
3224 echo creating src/Makefile
3225 ( cd src
3226 rm -f junk.c junk1.c junk2.c
3227 sed -e '/start of cpp stuff/q' \
3228 < Makefile.c > junk1.c
3229 sed -e '1,/start of cpp stuff/d'\
3230 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3231 < Makefile.c > junk.c
3232 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3233 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
3234 cat junk1.c junk2.c > Makefile.new
3235 rm -f junk.c junk1.c junk2.c
3236 chmod 444 Makefile.new
3237 mv -f Makefile.new Makefile
3238 )
3240 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3241 echo creating src/.gdbinit
3242 echo source $srcdir/src/.gdbinit > src/.gdbinit
3243 fi
3245 # This is how we know whether to re-run configure in certain cases.
3246 touch src/config.stamp
3248 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3250 m4_if(dnl Do not change this comment
3251 arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3252 )dnl