lisp/wid-edit.el

   1 ;;; wid-edit.el --- Functions for creating and using widgets -*-byte-compile-dynamic: t;-*-
   2 ;;
   3 ;; Copyright (C) 1996,97,1999,2000,01,02,2003, 2004  Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Maintainer: FSF
   7 ;; Keywords: extensions
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Wishlist items (from widget.texi):
  27
  28 ;; * The `menu-choice' tag should be prettier, something like the
  29 ;;   abbreviated menus in Open Look.
  30
  31 ;; * Finish `:tab-order'.
  32
  33 ;; * Make indentation work with glyphs and proportional fonts.
  34
  35 ;; * Add commands to show overview of object and class hierarchies to
  36 ;;   the browser.
  37
  38 ;; * Find a way to disable mouse highlight for inactive widgets.
  39
  40 ;; * Find a way to make glyphs look inactive.
  41
  42 ;; * Add `key-binding' widget.
  43
  44 ;; * Add `widget' widget for editing widget specifications.
  45
  46 ;; * Find clean way to implement variable length list.  See
  47 ;;   `TeX-printer-list' for an explanation.
  48
  49 ;; * `C-h' in `widget-prompt-value' should give type specific help.
  50
  51 ;; * A mailto widget. [This should work OK as a url-link if with
  52 ;;   browse-url-browser-function' set up appropriately.]
  53
  54 ;;; Commentary:
  55 ;;
  56 ;; See `widget.el'.
  57
  58 ;;; Code:
  59
  60 ;;; Compatibility.
  61
  62 (defun widget-event-point (event)
  63   "Character position of the end of event if that exists, or nil."
  64   (posn-point (event-end event)))
  65
  66 (defun widget-button-release-event-p (event)
  67   "Non-nil if EVENT is a mouse-button-release event object."
  68   (and (eventp event)
  69        (memq (event-basic-type event) '(mouse-1 mouse-2 mouse-3))
  70        (or (memq 'click (event-modifiers event))
  71            (memq  'drag (event-modifiers event)))))
  72
  73 ;;; Customization.
  74
  75 (defgroup widgets nil
  76   "Customization support for the Widget Library."
  77   :link '(custom-manual "(widget)Top")
  78   :link '(emacs-library-link :tag "Lisp File" "widget.el")
  79   :prefix "widget-"
  80   :group 'extensions
  81   :group 'hypermedia)
  82
  83 (defgroup widget-documentation nil
  84   "Options controling the display of documentation strings."
  85   :group 'widgets)
  86
  87 (defgroup widget-faces nil
  88   "Faces used by the widget library."
  89   :group 'widgets
  90   :group 'faces)
  91
  92 (defvar widget-documentation-face 'widget-documentation-face
  93   "Face used for documentation strings in widgets.
  94 This exists as a variable so it can be set locally in certain buffers.")
  95
  96 (defface widget-documentation-face '((((class color)
  97                                        (background dark))
  98                                       (:foreground "lime green"))
  99                                      (((class color)
 100                                        (background light))
 101                                       (:foreground "dark green"))
 102                                      (t nil))
 103   "Face used for documentation text."
 104   :group 'widget-documentation
 105   :group 'widget-faces)
 106
 107 (defvar widget-button-face 'widget-button-face
 108   "Face used for buttons in widgets.
 109 This exists as a variable so it can be set locally in certain buffers.")
 110
 111 (defface widget-button-face '((t (:weight bold)))
 112   "Face used for widget buttons."
 113   :group 'widget-faces)
 114
 115 (defcustom widget-mouse-face 'highlight
 116   "Face used for widget buttons when the mouse is above them."
 117   :type 'face
 118   :group 'widget-faces)
 119
 120 ;; TTY gets special definitions here and in the next defface, because
 121 ;; the gray colors defined for other displays cause black text on a black
 122 ;; background, at least on light-background TTYs.
 123 (defface widget-field-face '((((type tty))
 124                               :background "yellow3"
 125                               :foreground "black")
 126                              (((class grayscale color)
 127                                (background light))
 128                               :background "gray85")
 129                              (((class grayscale color)
 130                                (background dark))
 131                               :background "dim gray")
 132                              (t
 133                               :slant italic))
 134   "Face used for editable fields."
 135   :group 'widget-faces)
 136
 137 (defface widget-single-line-field-face '((((type tty))
 138                                           :background "green3"
 139                                           :foreground "black")
 140                                          (((class grayscale color)
 141                                            (background light))
 142                                           :background "gray85")
 143                                          (((class grayscale color)
 144                                            (background dark))
 145                                           :background "dim gray")
 146                                          (t
 147                                           :slant italic))
 148   "Face used for editable fields spanning only a single line."
 149   :group 'widget-faces)
 150
 151 ;;; This causes display-table to be loaded, and not usefully.
 152 ;;;(defvar widget-single-line-display-table
 153 ;;;  (let ((table (make-display-table)))
 154 ;;;    (aset table 9  "^I")
 155 ;;;    (aset table 10 "^J")
 156 ;;;    table)
 157 ;;;  "Display table used for single-line editable fields.")
 158
 159 ;;;(when (fboundp 'set-face-display-table)
 160 ;;;  (set-face-display-table 'widget-single-line-field-face
 161 ;;;                       widget-single-line-display-table))
 162
 163 ;;; Utility functions.
 164 ;;
 165 ;; These are not really widget specific.
 166
 167 (defun widget-princ-to-string (object)
 168   "Return string representation of OBJECT, any Lisp object.
 169 No quoting characters are used; no delimiters are printed around
 170 the contents of strings."
 171   (with-output-to-string
 172       (princ object)))
 173
 174 (defun widget-clear-undo ()
 175   "Clear all undo information."
 176   (buffer-disable-undo (current-buffer))
 177   (buffer-enable-undo))
 178
 179 (defcustom widget-menu-max-size 40
 180   "Largest number of items allowed in a popup-menu.
 181 Larger menus are read through the minibuffer."
 182   :group 'widgets
 183   :type 'integer)
 184
 185 (defcustom widget-menu-max-shortcuts 40
 186   "Largest number of items for which it works to choose one with a character.
 187 For a larger number of items, the minibuffer is used."
 188   :group 'widgets
 189   :type 'integer)
 190
 191 (defcustom widget-menu-minibuffer-flag nil
 192   "*Control how to ask for a choice from the keyboard.
 193 Non-nil means use the minibuffer;
 194 nil means read a single character."
 195   :group 'widgets
 196   :type 'boolean)
 197
 198 (defun widget-choose (title items &optional event)
 199   "Choose an item from a list.
 200
 201 First argument TITLE is the name of the list.
 202 Second argument ITEMS is a list whose members are either
 203  (NAME . VALUE), to indicate selectable items, or just strings to
 204  indicate unselectable items.
 205 Optional third argument EVENT is an input event.
 206
 207 The user is asked to choose between each NAME from the items alist,
 208 and the VALUE of the chosen element will be returned.  If EVENT is a
 209 mouse event, and the number of elements in items is less than
 210 `widget-menu-max-size', a popup menu will be used, otherwise the
 211 minibuffer."
 212   (cond ((and (< (length items) widget-menu-max-size)
 213               event (display-popup-menus-p))
 214          ;; Mouse click.
 215          (x-popup-menu event
 216                        (list title (cons "" items))))
 217         ((or widget-menu-minibuffer-flag
 218              (> (length items) widget-menu-max-shortcuts))
 219          ;; Read the choice of name from the minibuffer.
 220          (setq items (widget-remove-if 'stringp items))
 221          (let ((val (completing-read (concat title ": ") items nil t)))
 222            (if (stringp val)
 223                (let ((try (try-completion val items)))
 224                  (when (stringp try)
 225                    (setq val try))
 226                  (cdr (assoc val items))))))
 227         (t
 228          ;; Construct a menu of the choices
 229          ;; and then use it for prompting for a single character.
 230          (let* ((overriding-terminal-local-map (make-sparse-keymap))
 231                 (next-digit ?0)
 232                 map choice some-choice-enabled value)
 233            ;; Define SPC as a prefix char to get to this menu.
 234            (define-key overriding-terminal-local-map " "
 235              (setq map (make-sparse-keymap title)))
 236            (with-current-buffer (get-buffer-create " widget-choose")
 237              (erase-buffer)
 238              (insert "Available choices:\n\n")
 239              (while items
 240                (setq choice (car items) items (cdr items))
 241                (if (consp choice)
 242                    (let* ((name (car choice))
 243                          (function (cdr choice)))
 244                      (insert (format "%c = %s\n" next-digit name))
 245                      (define-key map (vector next-digit) function)
 246                      (setq some-choice-enabled t)))
 247                ;; Allocate digits to disabled alternatives
 248                ;; so that the digit of a given alternative never varies.
 249                (setq next-digit (1+ next-digit)))
 250              (insert "\nC-g = Quit"))
 251            (or some-choice-enabled
 252                (error "None of the choices is currently meaningful"))
 253            (define-key map [?\C-g] 'keyboard-quit)
 254            (define-key map [t] 'keyboard-quit)
 255            (define-key map [?\M-\C-v] 'scroll-other-window)
 256            (define-key map [?\M--] 'negative-argument)
 257            (setcdr map (nreverse (cdr map)))
 258            ;; Read a char with the menu, and return the result
 259            ;; that corresponds to it.
 260            (save-window-excursion
 261              (let ((buf (get-buffer " widget-choose")))
 262                (fit-window-to-buffer (display-buffer buf))
 263                (let ((cursor-in-echo-area t)
 264                      keys
 265                      (char 0)
 266                      (arg 1))
 267                  (while (not (or (and (>= char ?0) (< char next-digit))
 268                                  (eq value 'keyboard-quit)))
 269                    ;; Unread a SPC to lead to our new menu.
 270                    (setq unread-command-events (cons ?\  unread-command-events))
 271                    (setq keys (read-key-sequence title))
 272                    (setq value
 273                          (lookup-key overriding-terminal-local-map keys t)
 274                          char (string-to-char (substring keys 1)))
 275                    (cond ((eq value 'scroll-other-window)
 276                           (let ((minibuffer-scroll-window
 277                                  (get-buffer-window buf)))
 278                             (if (> 0 arg)
 279                                 (scroll-other-window-down
 280                                  (window-height minibuffer-scroll-window))
 281                               (scroll-other-window))
 282                             (setq arg 1)))
 283                          ((eq value 'negative-argument)
 284                           (setq arg -1))
 285                          (t
 286                           (setq arg 1)))))))
 287            (when (eq value 'keyboard-quit)
 288              (error "Canceled"))
 289            value))))
 290
 291 (defun widget-remove-if (predictate list)
 292   (let (result (tail list))
 293     (while tail
 294       (or (funcall predictate (car tail))
 295           (setq result (cons (car tail) result)))
 296       (setq tail (cdr tail)))
 297     (nreverse result)))
 298
 299 ;;; Widget text specifications.
 300 ;;
 301 ;; These functions are for specifying text properties.
 302
 303 ;; We can set it to nil now that get_local_map uses get_pos_property.
 304 (defconst widget-field-add-space nil
 305   "Non-nil means add extra space at the end of editable text fields.
 306 If you don't add the space, it will become impossible to edit a zero
 307 size field.")
 308
 309 (defvar widget-field-use-before-change t
 310   "Non-nil means use `before-change-functions' to track editable fields.
 311 This enables the use of undo, but doesn't work on Emacs 19.34 and earlier.
 312 Using before hooks also means that the :notify function can't know the
 313 new value.")
 314
 315 (defun widget-specify-field (widget from to)
 316   "Specify editable button for WIDGET between FROM and TO."
 317   ;; Terminating space is not part of the field, but necessary in
 318   ;; order for local-map to work.  Remove next sexp if local-map works
 319   ;; at the end of the overlay.
 320   (save-excursion
 321     (goto-char to)
 322     (cond ((null (widget-get widget :size))
 323            (forward-char 1))
 324           (widget-field-add-space
 325            (insert-and-inherit " ")))
 326     (setq to (point)))
 327   (let ((keymap (widget-get widget :keymap))
 328         (face (or (widget-get widget :value-face) 'widget-field-face))
 329         (help-echo (widget-get widget :help-echo))
 330         (rear-sticky
 331          (or (not widget-field-add-space) (widget-get widget :size))))
 332     (if (functionp help-echo)
 333       (setq help-echo 'widget-mouse-help))
 334     (when (= (char-before to) ?\n)
 335       ;; When the last character in the field is a newline, we want to
 336       ;; give it a `field' char-property of `boundary', which helps the
 337       ;; C-n/C-p act more naturally when entering/leaving the field.  We
 338      ;; do this by making a small secondary overlay to contain just that
 339       ;; one character.
 340       (let ((overlay (make-overlay (1- to) to nil t nil)))
 341         (overlay-put overlay 'field 'boundary)
 342         ;; Use `local-map' here, not `keymap', so that normal editing
 343         ;; works in the field when, say, Custom uses `suppress-keymap'.
 344         (overlay-put overlay 'local-map keymap)
 345         (overlay-put overlay 'face face)
 346         (overlay-put overlay 'help-echo help-echo))
 347       (setq to (1- to))
 348       (setq rear-sticky t))
 349     (let ((overlay (make-overlay from to nil nil rear-sticky)))
 350       (widget-put widget :field-overlay overlay)
 351       ;;(overlay-put overlay 'detachable nil)
 352       (overlay-put overlay 'field widget)
 353       (overlay-put overlay 'local-map keymap)
 354       (overlay-put overlay 'face face)
 355       (overlay-put overlay 'help-echo help-echo)))
 356   (widget-specify-secret widget))
 357
 358 (defun widget-specify-secret (field)
 359   "Replace text in FIELD with value of `:secret', if non-nil."
 360   (let ((secret (widget-get field :secret))
 361         (size (widget-get field :size)))
 362     (when secret
 363       (let ((begin (widget-field-start field))
 364             (end (widget-field-end field)))
 365         (when size
 366           (while (and (> end begin)
 367                       (eq (char-after (1- end)) ?\ ))
 368             (setq end (1- end))))
 369         (while (< begin end)
 370           (let ((old (char-after begin)))
 371             (unless (eq old secret)
 372               (subst-char-in-region begin (1+ begin) old secret)
 373               (put-text-property begin (1+ begin) 'secret old))
 374             (setq begin (1+ begin))))))))
 375
 376 (defun widget-specify-button (widget from to)
 377   "Specify button for WIDGET between FROM and TO."
 378   (let ((overlay (make-overlay from to nil t nil))
 379         (help-echo (widget-get widget :help-echo)))
 380     (widget-put widget :button-overlay overlay)
 381     (if (functionp help-echo)
 382       (setq help-echo 'widget-mouse-help))
 383     (overlay-put overlay 'button widget)
 384     (overlay-put overlay 'keymap (widget-get widget :keymap))
 385     ;; We want to avoid the face with image buttons.
 386     (unless (widget-get widget :suppress-face)
 387       (overlay-put overlay 'face (widget-apply widget :button-face-get))
 388       (overlay-put overlay 'mouse-face widget-mouse-face))
 389     (overlay-put overlay 'help-echo help-echo)))
 390
 391 (defun widget-mouse-help (window overlay point)
 392   "Help-echo callback for widgets whose :help-echo is a function."
 393   (with-current-buffer (overlay-buffer overlay)
 394     (let* ((widget (widget-at (overlay-start overlay)))
 395            (help-echo (if widget (widget-get widget :help-echo))))
 396       (if (functionp help-echo)
 397           (funcall help-echo widget)
 398         help-echo))))
 399
 400 (defun widget-specify-sample (widget from to)
 401   "Specify sample for WIDGET between FROM and TO."
 402   (let ((overlay (make-overlay from to nil t nil)))
 403     (overlay-put overlay 'face (widget-apply widget :sample-face-get))
 404     (widget-put widget :sample-overlay overlay)))
 405
 406 (defun widget-specify-doc (widget from to)
 407   "Specify documentation for WIDGET between FROM and TO."
 408   (let ((overlay (make-overlay from to nil t nil)))
 409     (overlay-put overlay 'widget-doc widget)
 410     (overlay-put overlay 'face widget-documentation-face)
 411     (widget-put widget :doc-overlay overlay)))
 412
 413 (defmacro widget-specify-insert (&rest form)
 414   "Execute FORM without inheriting any text properties."
 415   `(save-restriction
 416     (let ((inhibit-read-only t)
 417           (inhibit-modification-hooks t))
 418       (narrow-to-region (point) (point))
 419       (prog1 (progn ,@form)
 420         (goto-char (point-max))))))
 421
 422 (defface widget-inactive-face '((((class grayscale color)
 423                                   (background dark))
 424                                  (:foreground "light gray"))
 425                                 (((class grayscale color)
 426                                   (background light))
 427                                  (:foreground "dim gray"))
 428                                 (t
 429                                  (:slant italic)))
 430   "Face used for inactive widgets."
 431   :group 'widget-faces)
 432
 433 (defun widget-specify-inactive (widget from to)
 434   "Make WIDGET inactive for user modifications."
 435   (unless (widget-get widget :inactive)
 436     (let ((overlay (make-overlay from to nil t nil)))
 437       (overlay-put overlay 'face 'widget-inactive-face)
 438       ;; This is disabled, as it makes the mouse cursor change shape.
 439       ;; (overlay-put overlay 'mouse-face 'widget-inactive-face)
 440       (overlay-put overlay 'evaporate t)
 441       (overlay-put overlay 'priority 100)
 442       (overlay-put overlay 'modification-hooks '(widget-overlay-inactive))
 443       (widget-put widget :inactive overlay))))
 444
 445 (defun widget-overlay-inactive (&rest junk)
 446   "Ignoring the arguments, signal an error."
 447   (unless inhibit-read-only
 448     (error "The widget here is not active")))
 449
 450
 451 (defun widget-specify-active (widget)
 452   "Make WIDGET active for user modifications."
 453   (let ((inactive (widget-get widget :inactive)))
 454     (when inactive
 455       (delete-overlay inactive)
 456       (widget-put widget :inactive nil))))
 457
 458 ;;; Widget Properties.
 459
 460 (defsubst widget-type (widget)
 461   "Return the type of WIDGET, a symbol."
 462   (car widget))
 463
 464 ;;;###autoload
 465 (defun widgetp (widget)
 466   "Return non-nil iff WIDGET is a widget."
 467   (if (symbolp widget)
 468       (get widget 'widget-type)
 469     (and (consp widget)
 470          (symbolp (car widget))
 471          (get (car widget) 'widget-type))))
 472
 473 (defun widget-get-indirect (widget property)
 474   "In WIDGET, get the value of PROPERTY.
 475 If the value is a symbol, return its binding.
 476 Otherwise, just return the value."
 477   (let ((value (widget-get widget property)))
 478     (if (symbolp value)
 479         (symbol-value value)
 480       value)))
 481
 482 (defun widget-member (widget property)
 483   "Non-nil iff there is a definition in WIDGET for PROPERTY."
 484   (cond ((plist-member (cdr widget) property)
 485          t)
 486         ((car widget)
 487          (widget-member (get (car widget) 'widget-type) property))
 488         (t nil)))
 489
 490 (defun widget-value (widget)
 491   "Extract the current value of WIDGET."
 492   (widget-apply widget
 493                 :value-to-external (widget-apply widget :value-get)))
 494
 495 (defun widget-value-set (widget value)
 496   "Set the current value of WIDGET to VALUE."
 497   (widget-apply widget
 498                 :value-set (widget-apply widget
 499                                          :value-to-internal value)))
 500
 501 (defun widget-default-get (widget)
 502   "Extract the default external value of WIDGET."
 503   (widget-apply widget :value-to-external
 504                 (or (widget-get widget :value)
 505                     (widget-apply widget :default-get))))
 506
 507 (defun widget-match-inline (widget vals)
 508   "In WIDGET, match the start of VALS."
 509   (cond ((widget-get widget :inline)
 510          (widget-apply widget :match-inline vals))
 511         ((and (listp vals)
 512               (widget-apply widget :match (car vals)))
 513          (cons (list (car vals)) (cdr vals)))
 514         (t nil)))
 515
 516 (defun widget-apply-action (widget &optional event)
 517   "Apply :action in WIDGET in response to EVENT."
 518   (if (widget-apply widget :active)
 519       (widget-apply widget :action event)
 520     (error "Attempt to perform action on inactive widget")))
 521
 522 ;;; Helper functions.
 523 ;;
 524 ;; These are widget specific.
 525
 526 ;;;###autoload
 527 (defun widget-prompt-value (widget prompt &optional value unbound)
 528   "Prompt for a value matching WIDGET, using PROMPT.
 529 The current value is assumed to be VALUE, unless UNBOUND is non-nil."
 530   (unless (listp widget)
 531     (setq widget (list widget)))
 532   (setq prompt (format "[%s] %s" (widget-type widget) prompt))
 533   (setq widget (widget-convert widget))
 534   (let ((answer (widget-apply widget :prompt-value prompt value unbound)))
 535     (unless (widget-apply widget :match answer)
 536       (error "Value does not match %S type" (car widget)))
 537     answer))
 538
 539 (defun widget-get-sibling (widget)
 540   "Get the item WIDGET is assumed to toggle.
 541 This is only meaningful for radio buttons or checkboxes in a list."
 542   (let* ((children (widget-get (widget-get widget :parent) :children))
 543          child)
 544     (catch 'child
 545       (while children
 546         (setq child (car children)
 547               children (cdr children))
 548         (when (eq (widget-get child :button) widget)
 549           (throw 'child child)))
 550       nil)))
 551
 552 (defun widget-map-buttons (function &optional buffer maparg)
 553   "Map FUNCTION over the buttons in BUFFER.
 554 FUNCTION is called with the arguments WIDGET and MAPARG.
 555
 556 If FUNCTION returns non-nil, the walk is cancelled.
 557
 558 The arguments MAPARG, and BUFFER default to nil and (current-buffer),
 559 respectively."
 560   (let ((cur (point-min))
 561         (widget nil)
 562         (overlays (if buffer
 563                       (with-current-buffer buffer (overlay-lists))
 564                     (overlay-lists))))
 565     (setq overlays (append (car overlays) (cdr overlays)))
 566     (while (setq cur (pop overlays))
 567       (setq widget (overlay-get cur 'button))
 568       (if (and widget (funcall function widget maparg))
 569           (setq overlays nil)))))
 570
 571 ;;; Images.
 572
 573 (defcustom widget-image-directory (file-name-as-directory
 574                                    (expand-file-name "custom" data-directory))
 575   "Where widget button images are located.
 576 If this variable is nil, widget will try to locate the directory
 577 automatically."
 578   :group 'widgets
 579   :type 'directory)
 580
 581 (defcustom widget-image-enable t
 582   "If non nil, use image buttons in widgets when available."
 583   :version "21.1"
 584   :group 'widgets
 585   :type 'boolean)
 586
 587 (defcustom widget-image-conversion
 588   '((xpm ".xpm") (gif ".gif") (png ".png") (jpeg ".jpg" ".jpeg")
 589     (xbm ".xbm"))
 590   "Conversion alist from image formats to file name suffixes."
 591   :group 'widgets
 592   :type '(repeat (cons :format "%v"
 593                        (symbol :tag "Image Format" unknown)
 594                        (repeat :tag "Suffixes"
 595                                (string :format "%v")))))
 596
 597 (defun widget-image-find (image)
 598   "Create a graphical button from IMAGE.
 599 IMAGE should either already be an image, or be a file name sans
 600 extension (xpm, xbm, gif, jpg, or png) located in
 601 `widget-image-directory' or otherwise where `find-image' will find it."
 602   (cond ((not (and image widget-image-enable (display-graphic-p)))
 603          ;; We don't want or can't use images.
 604          nil)
 605         ((and (consp image)
 606               (eq 'image (car image)))
 607          ;; Already an image spec.  Use it.
 608          image)
 609         ((stringp image)
 610          ;; A string.  Look it up in relevant directories.
 611          (let* ((load-path (cons widget-image-directory load-path))
 612                 specs)
 613            (dolist (elt widget-image-conversion)
 614              (dolist (ext (cdr elt))
 615                (push (list :type (car elt) :file (concat image ext)) specs)))
 616            (setq specs (nreverse specs))
 617            (find-image specs)))
 618         (t
 619          ;; Oh well.
 620          nil)))
 621
 622 (defvar widget-button-pressed-face 'widget-button-pressed-face
 623   "Face used for pressed buttons in widgets.
 624 This exists as a variable so it can be set locally in certain
 625 buffers.")
 626
 627 (defun widget-image-insert (widget tag image &optional down inactive)
 628   "In WIDGET, insert the text TAG or, if supported, IMAGE.
 629 IMAGE should either be an image or an image file name sans extension
 630 \(xpm, xbm, gif, jpg, or png) located in `widget-image-directory'.
 631
 632 Optional arguments DOWN and INACTIVE are used instead of IMAGE when the
 633 button is pressed or inactive, respectively.  These are currently ignored."
 634   (if (and (display-graphic-p)
 635            (setq image (widget-image-find image)))
 636       (progn (widget-put widget :suppress-face t)
 637              (insert-image image
 638                            (propertize
 639                             tag 'mouse-face widget-button-pressed-face)))
 640     (insert tag)))
 641
 642 ;;; Buttons.
 643
 644 (defgroup widget-button nil
 645   "The look of various kinds of buttons."
 646   :group 'widgets)
 647
 648 (defcustom widget-button-prefix ""
 649   "String used as prefix for buttons."
 650   :type 'string
 651   :group 'widget-button)
 652
 653 (defcustom widget-button-suffix ""
 654   "String used as suffix for buttons."
 655   :type 'string
 656   :group 'widget-button)
 657
 658 ;;; Creating Widgets.
 659
 660 ;;;###autoload
 661 (defun widget-create (type &rest args)
 662   "Create widget of TYPE.
 663 The optional ARGS are additional keyword arguments."
 664   (let ((widget (apply 'widget-convert type args)))
 665     (widget-apply widget :create)
 666     widget))
 667
 668 (defun widget-create-child-and-convert (parent type &rest args)
 669   "As part of the widget PARENT, create a child widget TYPE.
 670 The child is converted, using the keyword arguments ARGS."
 671   (let ((widget (apply 'widget-convert type args)))
 672     (widget-put widget :parent parent)
 673     (unless (widget-get widget :indent)
 674       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 675                                     (or (widget-get widget :extra-offset) 0)
 676                                     (widget-get parent :offset))))
 677     (widget-apply widget :create)
 678     widget))
 679
 680 (defun widget-create-child (parent type)
 681   "Create widget of TYPE."
 682   (let ((widget (widget-copy type)))
 683     (widget-put widget :parent parent)
 684     (unless (widget-get widget :indent)
 685       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 686                                     (or (widget-get widget :extra-offset) 0)
 687                                     (widget-get parent :offset))))
 688     (widget-apply widget :create)
 689     widget))
 690
 691 (defun widget-create-child-value (parent type value)
 692   "Create widget of TYPE with value VALUE."
 693   (let ((widget (widget-copy type)))
 694     (widget-put widget :value (widget-apply widget :value-to-internal value))
 695     (widget-put widget :parent parent)
 696     (unless (widget-get widget :indent)
 697       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 698                                     (or (widget-get widget :extra-offset) 0)
 699                                     (widget-get parent :offset))))
 700     (widget-apply widget :create)
 701     widget))
 702
 703 ;;;###autoload
 704 (defun widget-delete (widget)
 705   "Delete WIDGET."
 706   (widget-apply widget :delete))
 707
 708 (defun widget-copy (widget)
 709   "Make a deep copy of WIDGET."
 710   (widget-apply (copy-sequence widget) :copy))
 711
 712 (defun widget-convert (type &rest args)
 713   "Convert TYPE to a widget without inserting it in the buffer.
 714 The optional ARGS are additional keyword arguments."
 715   ;; Don't touch the type.
 716   (let* ((widget (if (symbolp type)
 717                      (list type)
 718                    (copy-sequence type)))
 719          (current widget)
 720          done
 721          (keys args))
 722     ;; First set the :args keyword.
 723     (while (cdr current)                ;Look in the type.
 724       (if (and (keywordp (cadr current))
 725                ;; If the last element is a keyword,
 726                ;; it is still the :args element,
 727                ;; even though it is a keyword.
 728                (cddr current))
 729           (if (eq (cadr current) :args)
 730               ;; If :args is explicitly specified, obey it.
 731               (setq current nil)
 732             ;; Some other irrelevant keyword.
 733             (setq current (cdr (cdr current))))
 734         (setcdr current (list :args (cdr current)))
 735         (setq current nil)))
 736     (while (and args (not done))        ;Look in ARGS.
 737       (cond ((eq (car args) :args)
 738              ;; Handle explicit specification of :args.
 739              (setq args (cadr args)
 740                    done t))
 741             ((keywordp (car args))
 742              (setq args (cddr args)))
 743             (t (setq done t))))
 744     (when done
 745       (widget-put widget :args args))
 746     ;; Then Convert the widget.
 747     (setq type widget)
 748     (while type
 749       (let ((convert-widget (plist-get (cdr type) :convert-widget)))
 750         (if convert-widget
 751             (setq widget (funcall convert-widget widget))))
 752       (setq type (get (car type) 'widget-type)))
 753     ;; Finally set the keyword args.
 754     (while keys
 755       (let ((next (nth 0 keys)))
 756         (if (keywordp next)
 757             (progn
 758               (widget-put widget next (nth 1 keys))
 759               (setq keys (nthcdr 2 keys)))
 760           (setq keys nil))))
 761     ;; Convert the :value to internal format.
 762     (if (widget-member widget :value)
 763         (widget-put widget
 764                     :value (widget-apply widget
 765                                          :value-to-internal
 766                                          (widget-get widget :value))))
 767     ;; Return the newly create widget.
 768     widget))
 769
 770 ;;;###autoload
 771 (defun widget-insert (&rest args)
 772   "Call `insert' with ARGS even if surrounding text is read only."
 773   (let ((inhibit-read-only t)
 774         (inhibit-modification-hooks t))
 775     (apply 'insert args)))
 776
 777 (defun widget-convert-text (type from to
 778                                  &optional button-from button-to
 779                                  &rest args)
 780   "Return a widget of type TYPE with endpoint FROM TO.
 781 Optional ARGS are extra keyword arguments for TYPE.
 782 and TO will be used as the widgets end points. If optional arguments
 783 BUTTON-FROM and BUTTON-TO are given, these will be used as the widgets
 784 button end points.
 785 Optional ARGS are extra keyword arguments for TYPE."
 786   (let ((widget (apply 'widget-convert type :delete 'widget-leave-text args))
 787         (from (copy-marker from))
 788         (to (copy-marker to)))
 789     (set-marker-insertion-type from t)
 790     (set-marker-insertion-type to nil)
 791     (widget-put widget :from from)
 792     (widget-put widget :to to)
 793     (when button-from
 794       (widget-specify-button widget button-from button-to))
 795     widget))
 796
 797 (defun widget-convert-button (type from to &rest args)
 798   "Return a widget of type TYPE with endpoint FROM TO.
 799 Optional ARGS are extra keyword arguments for TYPE.
 800 No text will be inserted to the buffer, instead the text between FROM
 801 and TO will be used as the widgets end points, as well as the widgets
 802 button end points."
 803   (apply 'widget-convert-text type from to from to args))
 804
 805 (defun widget-leave-text (widget)
 806   "Remove markers and overlays from WIDGET and its children."
 807   (let ((button (widget-get widget :button-overlay))
 808         (sample (widget-get widget :sample-overlay))
 809         (doc (widget-get widget :doc-overlay))
 810         (field (widget-get widget :field-overlay)))
 811     (set-marker (widget-get widget :from) nil)
 812     (set-marker (widget-get widget :to) nil)
 813     (when button
 814       (delete-overlay button))
 815     (when sample
 816       (delete-overlay sample))
 817     (when doc
 818       (delete-overlay doc))
 819     (when field
 820       (delete-overlay field))
 821     (mapc 'widget-leave-text (widget-get widget :children))))
 822
 823 ;;; Keymap and Commands.
 824
 825 ;;;###autoload
 826 (defvar widget-keymap
 827   (let ((map (make-sparse-keymap)))
 828     (define-key map "\t" 'widget-forward)
 829     (define-key map [(shift tab)] 'widget-backward)
 830     (define-key map [backtab] 'widget-backward)
 831     (define-key map [down-mouse-2] 'widget-button-click)
 832     (define-key map "\C-m" 'widget-button-press)
 833     map)
 834   "Keymap containing useful binding for buffers containing widgets.
 835 Recommended as a parent keymap for modes using widgets.")
 836
 837 (defvar widget-global-map global-map
 838   "Keymap used for events a widget does not handle itself.")
 839 (make-variable-buffer-local 'widget-global-map)
 840
 841 (defvar widget-field-keymap
 842   (let ((map (copy-keymap widget-keymap)))
 843     (define-key map "\C-k" 'widget-kill-line)
 844     (define-key map "\M-\t" 'widget-complete)
 845     (define-key map "\C-m" 'widget-field-activate)
 846     ;; Since the widget code uses a `field' property to identify fields,
 847     ;; ordinary beginning-of-line does the right thing.
 848     ;;  (define-key map "\C-a" 'widget-beginning-of-line)
 849     (define-key map "\C-e" 'widget-end-of-line)
 850     map)
 851   "Keymap used inside an editable field.")
 852
 853 (defvar widget-text-keymap
 854   (let ((map (copy-keymap widget-keymap)))
 855     ;; Since the widget code uses a `field' property to identify fields,
 856     ;; ordinary beginning-of-line does the right thing.
 857     ;;  (define-key map "\C-a" 'widget-beginning-of-line)
 858     (define-key map "\C-e" 'widget-end-of-line)
 859     map)
 860   "Keymap used inside a text field.")
 861
 862 (defun widget-field-activate (pos &optional event)
 863   "Invoke the editable field at point."
 864   (interactive "@d")
 865   (let ((field (widget-field-at pos)))
 866     (if field
 867         (widget-apply-action field event)
 868       (call-interactively
 869        (lookup-key widget-global-map (this-command-keys))))))
 870
 871 (defface widget-button-pressed-face
 872   '((((class color))
 873      (:foreground "red"))
 874     (t
 875      (:weight bold :underline t)))
 876   "Face used for pressed buttons."
 877   :group 'widget-faces)
 878
 879 (defun widget-button-click (event)
 880   "Invoke the button that the mouse is pointing at."
 881   (interactive "e")
 882   (if (widget-event-point event)
 883       (let* ((pos (widget-event-point event))
 884              (start (event-start event))
 885              (button (get-char-property
 886                       pos 'button (and (windowp (posn-window start))
 887                                        (window-buffer (posn-window start))))))
 888         (if button
 889             ;; Mouse click on a widget button.  Do the following
 890             ;; in a save-excursion so that the click on the button
 891             ;; doesn't change point.
 892             (save-selected-window
 893               (select-window (posn-window (event-start event)))
 894               (save-excursion
 895                 (goto-char (posn-point (event-start event)))
 896                 (let* ((overlay (widget-get button :button-overlay))
 897                        (face (overlay-get overlay 'face))
 898                        (mouse-face (overlay-get overlay 'mouse-face)))
 899                   (unwind-protect
 900                       ;; Read events, including mouse-movement events
 901                       ;; until we receive a release event.  Highlight/
 902                       ;; unhighlight the button the mouse was initially
 903                       ;; on when we move over it.
 904                       (let ((track-mouse t))
 905                         (save-excursion
 906                           (when face    ; avoid changing around image
 907                             (overlay-put overlay
 908                                          'face widget-button-pressed-face)
 909                             (overlay-put overlay
 910                                          'mouse-face widget-button-pressed-face))
 911                           (unless (widget-apply button :mouse-down-action event)
 912                             (while (not (widget-button-release-event-p event))
 913                               (setq event (read-event)
 914                                     pos (widget-event-point event))
 915                               (if (and pos
 916                                        (eq (get-char-property pos 'button)
 917                                            button))
 918                                   (when face
 919                                     (overlay-put overlay
 920                                                  'face
 921                                                  widget-button-pressed-face)
 922                                     (overlay-put overlay
 923                                                  'mouse-face
 924                                                  widget-button-pressed-face))
 925                                 (overlay-put overlay 'face face)
 926                                 (overlay-put overlay 'mouse-face mouse-face))))
 927
 928                           ;; When mouse is released over the button, run
 929                           ;; its action function.
 930                           (when (and pos
 931                                      (eq (get-char-property pos 'button) button))
 932                             (widget-apply-action button event))))
 933                     (overlay-put overlay 'face face)
 934                     (overlay-put overlay 'mouse-face mouse-face))))
 935
 936               (unless (pos-visible-in-window-p (widget-event-point event))
 937                 (mouse-set-point event)
 938                 (beginning-of-line)
 939                 (recenter))
 940               )
 941
 942             (let ((up t) command)
 943               ;; Mouse click not on a widget button.  Find the global
 944               ;; command to run, and check whether it is bound to an
 945               ;; up event.
 946               (mouse-set-point event)
 947               (if (memq (event-basic-type event) '(mouse-1 down-mouse-1))
 948                   (cond ((setq command  ;down event
 949                                (lookup-key widget-global-map [down-mouse-1]))
 950                          (setq up nil))
 951                         ((setq command  ;up event
 952                                (lookup-key widget-global-map [mouse-1]))))
 953                 (cond ((setq command    ;down event
 954                              (lookup-key widget-global-map [down-mouse-2]))
 955                        (setq up nil))
 956                       ((setq command    ;up event
 957                              (lookup-key widget-global-map [mouse-2])))))
 958               (when up
 959                 ;; Don't execute up events twice.
 960                 (while (not (widget-button-release-event-p event))
 961                   (setq event (read-event))))
 962               (when command
 963                 (call-interactively command)))))
 964     (message "You clicked somewhere weird.")))
 965
 966 (defun widget-button-press (pos &optional event)
 967   "Invoke button at POS."
 968   (interactive "@d")
 969   (let ((button (get-char-property pos 'button)))
 970     (if button
 971         (widget-apply-action button event)
 972       (let ((command (lookup-key widget-global-map (this-command-keys))))
 973         (when (commandp command)
 974           (call-interactively command))))))
 975
 976 (defun widget-tabable-at (&optional pos)
 977   "Return the tabable widget at POS, or nil.
 978 POS defaults to the value of (point)."
 979   (let ((widget (widget-at pos)))
 980     (if widget
 981         (let ((order (widget-get widget :tab-order)))
 982           (if order
 983               (if (>= order 0)
 984                   widget)
 985             widget)))))
 986
 987 (defvar widget-use-overlay-change t
 988   "If non-nil, use overlay change functions to tab around in the buffer.
 989 This is much faster, but doesn't work reliably on Emacs 19.34.")
 990
 991 (defun widget-move (arg)
 992   "Move point to the ARG next field or button.
 993 ARG may be negative to move backward."
 994   (or (bobp) (> arg 0) (backward-char))
 995   (let ((wrapped 0)
 996         (number arg)
 997         (old (widget-tabable-at)))
 998     ;; Forward.
 999     (while (> arg 0)
1000       (cond ((eobp)
1001              (goto-char (point-min))
1002              (setq wrapped (1+ wrapped)))
1003             (widget-use-overlay-change
1004              (goto-char (next-overlay-change (point))))
1005             (t
1006              (forward-char 1)))
1007       (and (= wrapped 2)
1008            (eq arg number)
1009            (error "No buttons or fields found"))
1010       (let ((new (widget-tabable-at)))
1011         (when new
1012           (unless (eq new old)
1013             (setq arg (1- arg))
1014             (setq old new)))))
1015     ;; Backward.
1016     (while (< arg 0)
1017       (cond ((bobp)
1018              (goto-char (point-max))
1019              (setq wrapped (1+ wrapped)))
1020             (widget-use-overlay-change
1021              (goto-char (previous-overlay-change (point))))
1022             (t
1023              (backward-char 1)))
1024       (and (= wrapped 2)
1025            (eq arg number)
1026            (error "No buttons or fields found"))
1027       (let ((new (widget-tabable-at)))
1028         (when new
1029           (unless (eq new old)
1030             (setq arg (1+ arg))))))
1031     (let ((new (widget-tabable-at)))
1032       (while (eq (widget-tabable-at) new)
1033         (backward-char)))
1034     (forward-char))
1035   (widget-echo-help (point))
1036   (run-hooks 'widget-move-hook))
1037
1038 (defun widget-forward (arg)
1039   "Move point to the next field or button.
1040 With optional ARG, move across that many fields."
1041   (interactive "p")
1042   (run-hooks 'widget-forward-hook)
1043   (widget-move arg))
1044
1045 (defun widget-backward (arg)
1046   "Move point to the previous field or button.
1047 With optional ARG, move across that many fields."
1048   (interactive "p")
1049   (run-hooks 'widget-backward-hook)
1050   (widget-move (- arg)))
1051
1052 ;; Since the widget code uses a `field' property to identify fields,
1053 ;; ordinary beginning-of-line does the right thing.
1054 (defalias 'widget-beginning-of-line 'beginning-of-line)
1055
1056 (defun widget-end-of-line ()
1057   "Go to end of field or end of line, whichever is first.
1058 Trailing spaces at the end of padded fields are not considered part of
1059 the field."
1060   (interactive)
1061   ;; Ordinary end-of-line does the right thing, because we're inside
1062   ;; text with a `field' property.
1063   (end-of-line)
1064   (unless (eolp)
1065     ;; ... except that we want to ignore trailing spaces in fields that
1066     ;; aren't terminated by a newline, because they are used as padding,
1067     ;; and ignored when extracting the entered value of the field.
1068     (skip-chars-backward " " (field-beginning (1- (point))))))
1069
1070 (defun widget-kill-line ()
1071   "Kill to end of field or end of line, whichever is first."
1072   (interactive)
1073   (let* ((field (widget-field-find (point)))
1074          (end (and field (widget-field-end field))))
1075     (if (and field (> (line-beginning-position 2) end))
1076         (kill-region (point) end)
1077       (call-interactively 'kill-line))))
1078
1079 (defcustom widget-complete-field (lookup-key global-map "\M-\t")
1080   "Default function to call for completion inside fields."
1081   :options '(ispell-complete-word complete-tag lisp-complete-symbol)
1082   :type 'function
1083   :group 'widgets)
1084
1085 (defun widget-complete ()
1086   "Complete content of editable field from point.
1087 When not inside a field, move to the previous button or field."
1088   (interactive)
1089   (let ((field (widget-field-find (point))))
1090     (if field
1091         (widget-apply field :complete)
1092       (error "Not in an editable field"))))
1093
1094 ;;; Setting up the buffer.
1095
1096 (defvar widget-field-new nil
1097   "List of all newly created editable fields in the buffer.")
1098 (make-variable-buffer-local 'widget-field-new)
1099
1100 (defvar widget-field-list nil
1101   "List of all editable fields in the buffer.")
1102 (make-variable-buffer-local 'widget-field-list)
1103
1104 (defun widget-at (&optional pos)
1105   "The button or field at POS (default, point)."
1106   (or (get-char-property (or pos (point)) 'button)
1107       (widget-field-at pos)))
1108
1109 ;;;###autoload
1110 (defun widget-setup ()
1111   "Setup current buffer so editing string widgets works."
1112   (let ((inhibit-read-only t)
1113         (inhibit-modification-hooks t)
1114         field)
1115     (while widget-field-new
1116       (setq field (car widget-field-new)
1117             widget-field-new (cdr widget-field-new)
1118             widget-field-list (cons field widget-field-list))
1119       (let ((from (car (widget-get field :field-overlay)))
1120             (to (cdr (widget-get field :field-overlay))))
1121         (widget-specify-field field
1122                               (marker-position from) (marker-position to))
1123         (set-marker from nil)
1124         (set-marker to nil))))
1125   (widget-clear-undo)
1126   (widget-add-change))
1127
1128 (defvar widget-field-last nil)
1129 ;; Last field containing point.
1130 (make-variable-buffer-local 'widget-field-last)
1131
1132 (defvar widget-field-was nil)
1133 ;; The widget data before the change.
1134 (make-variable-buffer-local 'widget-field-was)
1135
1136 (defun widget-field-at (pos)
1137   "Return the widget field at POS, or nil if none."
1138   (let ((field (get-char-property (or pos (point)) 'field)))
1139     (if (eq field 'boundary)
1140         nil
1141       field)))
1142
1143 (defun widget-field-buffer (widget)
1144   "Return the start of WIDGET's editing field."
1145   (let ((overlay (widget-get widget :field-overlay)))
1146     (cond ((overlayp overlay)
1147            (overlay-buffer overlay))
1148           ((consp overlay)
1149            (marker-buffer (car overlay))))))
1150
1151 (defun widget-field-start (widget)
1152   "Return the start of WIDGET's editing field."
1153   (let ((overlay (widget-get widget :field-overlay)))
1154     (if (overlayp overlay)
1155         (overlay-start overlay)
1156       (car overlay))))
1157
1158 (defun widget-field-end (widget)
1159   "Return the end of WIDGET's editing field."
1160   (let ((overlay (widget-get widget :field-overlay)))
1161     ;; Don't subtract one if local-map works at the end of the overlay,
1162     ;; or if a special `boundary' field has been added after the widget
1163     ;; field.
1164     (if (overlayp overlay)
1165         (if (and (not (eq (get-char-property (overlay-end overlay)
1166                                              'field
1167                                              (widget-field-buffer widget))
1168                           'boundary))
1169                  (or widget-field-add-space
1170                      (null (widget-get widget :size))))
1171             (1- (overlay-end overlay))
1172           (overlay-end overlay))
1173       (cdr overlay))))
1174
1175 (defun widget-field-find (pos)
1176   "Return the field at POS.
1177 Unlike (get-char-property POS 'field) this, works with empty fields too."
1178   (let ((fields widget-field-list)
1179         field found)
1180     (while fields
1181       (setq field (car fields)
1182             fields (cdr fields))
1183       (when (and (<= (widget-field-start field) pos)
1184                  (<= pos (widget-field-end field)))
1185         (when found
1186           (error "Overlapping fields"))
1187         (setq found field)))
1188     found))
1189
1190 (defun widget-before-change (from to)
1191   ;; This is how, for example, a variable changes its state to `modified'.
1192   ;; when it is being edited.
1193   (unless inhibit-read-only
1194     (let ((from-field (widget-field-find from))
1195           (to-field (widget-field-find to)))
1196       (cond ((not (eq from-field to-field))
1197              (add-hook 'post-command-hook 'widget-add-change nil t)
1198              (signal 'text-read-only
1199                      '("Change should be restricted to a single field")))
1200             ((null from-field)
1201              (add-hook 'post-command-hook 'widget-add-change nil t)
1202              (signal 'text-read-only
1203                      '("Attempt to change text outside editable field")))
1204             (widget-field-use-before-change
1205              (widget-apply from-field :notify from-field))))))
1206
1207 (defun widget-add-change ()
1208   (remove-hook 'post-command-hook 'widget-add-change t)
1209   (add-hook 'before-change-functions 'widget-before-change nil t)
1210   (add-hook 'after-change-functions 'widget-after-change nil t))
1211
1212 (defun widget-after-change (from to old)
1213   "Adjust field size and text properties."
1214   (let ((field (widget-field-find from))
1215         (other (widget-field-find to)))
1216     (when field
1217       (unless (eq field other)
1218         (error "Change in different fields"))
1219       (let ((size (widget-get field :size)))
1220         (when size
1221           (let ((begin (widget-field-start field))
1222                 (end (widget-field-end field)))
1223             (cond ((< (- end begin) size)
1224                    ;; Field too small.
1225                    (save-excursion
1226                      (goto-char end)
1227                      (insert-char ?\  (- (+ begin size) end))))
1228                   ((> (- end begin) size)
1229                    ;; Field too large and
1230                    (if (or (< (point) (+ begin size))
1231                            (> (point) end))
1232                        ;; Point is outside extra space.
1233                        (setq begin (+ begin size))
1234                      ;; Point is within the extra space.
1235                      (setq begin (point)))
1236                    (save-excursion
1237                      (goto-char end)
1238                      (while (and (eq (preceding-char) ?\ )
1239                                  (> (point) begin))
1240                        (delete-backward-char 1)))))))
1241         (widget-specify-secret field))
1242       (widget-apply field :notify field))))
1243
1244 ;;; Widget Functions
1245 ;;
1246 ;; These functions are used in the definition of multiple widgets.
1247
1248 (defun widget-parent-action (widget &optional event)
1249   "Tell :parent of WIDGET to handle the :action.
1250 Optional EVENT is the event that triggered the action."
1251   (widget-apply (widget-get widget :parent) :action event))
1252
1253 (defun widget-children-value-delete (widget)
1254   "Delete all :children and :buttons in WIDGET."
1255   (mapc 'widget-delete (widget-get widget :children))
1256   (widget-put widget :children nil)
1257   (mapc 'widget-delete (widget-get widget :buttons))
1258   (widget-put widget :buttons nil))
1259
1260 (defun widget-children-validate (widget)
1261   "All the :children must be valid."
1262   (let ((children (widget-get widget :children))
1263         child found)
1264     (while (and children (not found))
1265       (setq child (car children)
1266             children (cdr children)
1267             found (widget-apply child :validate)))
1268     found))
1269
1270 (defun widget-child-value-get (widget)
1271   "Get the value of the first member of :children in WIDGET."
1272   (widget-value (car (widget-get widget :children))))
1273
1274 (defun widget-child-value-inline (widget)
1275   "Get the inline value of the first member of :children in WIDGET."
1276   (widget-apply (car (widget-get widget :children)) :value-inline))
1277
1278 (defun widget-child-validate (widget)
1279   "The result of validating the first member of :children in WIDGET."
1280   (widget-apply (car (widget-get widget :children)) :validate))
1281
1282 (defun widget-type-value-create (widget)
1283   "Convert and instantiate the value of the :type attribute of WIDGET.
1284 Store the newly created widget in the :children attribute.
1285
1286 The value of the :type attribute should be an unconverted widget type."
1287   (let ((value (widget-get widget :value))
1288         (type (widget-get widget :type)))
1289     (widget-put widget :children
1290                 (list (widget-create-child-value widget
1291                                                  (widget-convert type)
1292                                                  value)))))
1293
1294 (defun widget-type-default-get (widget)
1295   "Get default value from the :type attribute of WIDGET.
1296
1297 The value of the :type attribute should be an unconverted widget type."
1298   (widget-default-get (widget-convert (widget-get widget :type))))
1299
1300 (defun widget-type-match (widget value)
1301   "Non-nil if the :type value of WIDGET matches VALUE.
1302
1303 The value of the :type attribute should be an unconverted widget type."
1304   (widget-apply (widget-convert (widget-get widget :type)) :match value))
1305
1306 (defun widget-types-copy (widget)
1307   "Copy :args as widget types in WIDGET."
1308   (widget-put widget :args (mapcar 'widget-copy (widget-get widget :args)))
1309   widget)
1310
1311 ;; Made defsubst to speed up face editor creation.
1312 (defsubst widget-types-convert-widget (widget)
1313   "Convert :args as widget types in WIDGET."
1314   (widget-put widget :args (mapcar 'widget-convert (widget-get widget :args)))
1315   widget)
1316
1317 (defun widget-value-convert-widget (widget)
1318   "Initialize :value from :args in WIDGET."
1319   (let ((args (widget-get widget :args)))
1320     (when args
1321       (widget-put widget :value (car args))
1322       ;; Don't convert :value here, as this is done in `widget-convert'.
1323       ;; (widget-put widget :value (widget-apply widget
1324       ;;                                      :value-to-internal (car args)))
1325       (widget-put widget :args nil)))
1326   widget)
1327
1328 (defun widget-value-value-get (widget)
1329   "Return the :value property of WIDGET."
1330   (widget-get widget :value))
1331
1332 ;;; The `default' Widget.
1333
1334 (define-widget 'default nil
1335   "Basic widget other widgets are derived from."
1336   :value-to-internal (lambda (widget value) value)
1337   :value-to-external (lambda (widget value) value)
1338   :button-prefix 'widget-button-prefix
1339   :button-suffix 'widget-button-suffix
1340   :complete 'widget-default-complete
1341   :create 'widget-default-create
1342   :indent nil
1343   :offset 0
1344   :format-handler 'widget-default-format-handler
1345   :button-face-get 'widget-default-button-face-get
1346   :sample-face-get 'widget-default-sample-face-get
1347   :delete 'widget-default-delete
1348   :copy 'identity
1349   :value-set 'widget-default-value-set
1350   :value-inline 'widget-default-value-inline
1351   :value-delete 'ignore
1352   :default-get 'widget-default-default-get
1353   :menu-tag-get 'widget-default-menu-tag-get
1354   :validate #'ignore
1355   :active 'widget-default-active
1356   :activate 'widget-specify-active
1357   :deactivate 'widget-default-deactivate
1358   :mouse-down-action #'ignore
1359   :action 'widget-default-action
1360   :notify 'widget-default-notify
1361   :prompt-value 'widget-default-prompt-value)
1362
1363 (defun widget-default-complete (widget)
1364   "Call the value of the :complete-function property of WIDGET.
1365 If that does not exists, call the value of `widget-complete-field'."
1366   (call-interactively (or (widget-get widget :complete-function)
1367                           widget-complete-field)))
1368
1369 (defun widget-default-create (widget)
1370   "Create WIDGET at point in the current buffer."
1371   (widget-specify-insert
1372    (let ((from (point))
1373          button-begin button-end
1374          sample-begin sample-end
1375          doc-begin doc-end
1376          value-pos)
1377      (insert (widget-get widget :format))
1378      (goto-char from)
1379      ;; Parse escapes in format.
1380      (while (re-search-forward "%\\(.\\)" nil t)
1381        (let ((escape (char-after (match-beginning 1))))
1382          (delete-backward-char 2)
1383          (cond ((eq escape ?%)
1384                 (insert ?%))
1385                ((eq escape ?\[)
1386                 (setq button-begin (point))
1387                 (insert (widget-get-indirect widget :button-prefix)))
1388                ((eq escape ?\])
1389                 (insert (widget-get-indirect widget :button-suffix))
1390                 (setq button-end (point)))
1391                ((eq escape ?\{)
1392                 (setq sample-begin (point)))
1393                ((eq escape ?\})
1394                 (setq sample-end (point)))
1395                ((eq escape ?n)
1396                 (when (widget-get widget :indent)
1397                   (insert ?\n)
1398                   (insert-char ?  (widget-get widget :indent))))
1399                ((eq escape ?t)
1400                 (let ((image (widget-get widget :tag-glyph))
1401                       (tag (widget-get widget :tag)))
1402                   (cond (image
1403                          (widget-image-insert widget (or tag "image") image))
1404                         (tag
1405                          (insert tag))
1406                         (t
1407                          (princ (widget-get widget :value)
1408                                 (current-buffer))))))
1409                ((eq escape ?d)
1410                 (let ((doc (widget-get widget :doc)))
1411                   (when doc
1412                     (setq doc-begin (point))
1413                     (insert doc)
1414                     (while (eq (preceding-char) ?\n)
1415                       (delete-backward-char 1))
1416                     (insert ?\n)
1417                     (setq doc-end (point)))))
1418                ((eq escape ?v)
1419                 (if (and button-begin (not button-end))
1420                     (widget-apply widget :value-create)
1421                   (setq value-pos (point))))
1422                (t
1423                 (widget-apply widget :format-handler escape)))))
1424      ;; Specify button, sample, and doc, and insert value.
1425      (and button-begin button-end
1426           (widget-specify-button widget button-begin button-end))
1427      (and sample-begin sample-end
1428           (widget-specify-sample widget sample-begin sample-end))
1429      (and doc-begin doc-end
1430           (widget-specify-doc widget doc-begin doc-end))
1431      (when value-pos
1432        (goto-char value-pos)
1433        (widget-apply widget :value-create)))
1434    (let ((from (point-min-marker))
1435          (to (point-max-marker)))
1436      (set-marker-insertion-type from t)
1437      (set-marker-insertion-type to nil)
1438      (widget-put widget :from from)
1439      (widget-put widget :to to)))
1440   (widget-clear-undo))
1441
1442 (defun widget-default-format-handler (widget escape)
1443   ;; We recognize the %h escape by default.
1444   (let* ((buttons (widget-get widget :buttons)))
1445     (cond ((eq escape ?h)
1446            (let* ((doc-property (widget-get widget :documentation-property))
1447                   (doc-try (cond ((widget-get widget :doc))
1448                                  ((functionp doc-property)
1449                                   (funcall doc-property
1450                                            (widget-get widget :value)))
1451                                  ((symbolp doc-property)
1452                                   (documentation-property
1453                                    (widget-get widget :value)
1454                                    doc-property))))
1455                   (doc-text (and (stringp doc-try)
1456                                  (> (length doc-try) 1)
1457                                  doc-try))
1458                   (doc-indent (widget-get widget :documentation-indent)))
1459              (when doc-text
1460                (and (eq (preceding-char) ?\n)
1461                     (widget-get widget :indent)
1462                     (insert-char ?  (widget-get widget :indent)))
1463                ;; The `*' in the beginning is redundant.
1464                (when (eq (aref doc-text  0) ?*)
1465                  (setq doc-text (substring doc-text 1)))
1466                ;; Get rid of trailing newlines.
1467                (when (string-match "\n+\\'" doc-text)
1468                  (setq doc-text (substring doc-text 0 (match-beginning 0))))
1469                (push (widget-create-child-and-convert
1470                       widget 'documentation-string
1471                       :indent (cond ((numberp doc-indent )
1472                                      doc-indent)
1473                                     ((null doc-indent)
1474                                      nil)
1475                                     (t 0))
1476                       doc-text)
1477                      buttons))))
1478           (t
1479            (error "Unknown escape `%c'" escape)))
1480     (widget-put widget :buttons buttons)))
1481
1482 (defun widget-default-button-face-get (widget)
1483   ;; Use :button-face or widget-button-face
1484   (or (widget-get widget :button-face)
1485       (let ((parent (widget-get widget :parent)))
1486         (if parent
1487             (widget-apply parent :button-face-get)
1488           widget-button-face))))
1489
1490 (defun widget-default-sample-face-get (widget)
1491   ;; Use :sample-face.
1492   (widget-get widget :sample-face))
1493
1494 (defun widget-default-delete (widget)
1495   "Remove widget from the buffer."
1496   (let ((from (widget-get widget :from))
1497         (to (widget-get widget :to))
1498         (inactive-overlay (widget-get widget :inactive))
1499         (button-overlay (widget-get widget :button-overlay))
1500         (sample-overlay (widget-get widget :sample-overlay))
1501         (doc-overlay (widget-get widget :doc-overlay))
1502         (inhibit-modification-hooks t)
1503         (inhibit-read-only t))
1504     (widget-apply widget :value-delete)
1505     (widget-children-value-delete widget)
1506     (when inactive-overlay
1507       (delete-overlay inactive-overlay))
1508     (when button-overlay
1509       (delete-overlay button-overlay))
1510     (when sample-overlay
1511       (delete-overlay sample-overlay))
1512     (when doc-overlay
1513       (delete-overlay doc-overlay))
1514     (when (< from to)
1515       ;; Kludge: this doesn't need to be true for empty formats.
1516       (delete-region from to))
1517     (set-marker from nil)
1518     (set-marker to nil))
1519   (widget-clear-undo))
1520
1521 (defun widget-default-value-set (widget value)
1522   "Recreate widget with new value."
1523   (let* ((old-pos (point))
1524          (from (copy-marker (widget-get widget :from)))
1525          (to (copy-marker (widget-get widget :to)))
1526          (offset (if (and (<= from old-pos) (<= old-pos to))
1527                      (if (>= old-pos (1- to))
1528                          (- old-pos to 1)
1529                        (- old-pos from)))))
1530     ;;??? Bug: this ought to insert the new value before deleting the old one,
1531     ;; so that markers on either side of the value automatically
1532     ;; stay on the same side.  -- rms.
1533     (save-excursion
1534       (goto-char (widget-get widget :from))
1535       (widget-apply widget :delete)
1536       (widget-put widget :value value)
1537       (widget-apply widget :create))
1538     (if offset
1539         (if (< offset 0)
1540             (goto-char (+ (widget-get widget :to) offset 1))
1541           (goto-char (min (+ from offset) (1- (widget-get widget :to))))))))
1542
1543 (defun widget-default-value-inline (widget)
1544   "Wrap value in a list unless it is inline."
1545   (if (widget-get widget :inline)
1546       (widget-value widget)
1547     (list (widget-value widget))))
1548
1549 (defun widget-default-default-get (widget)
1550   "Get `:value'."
1551   (widget-get widget :value))
1552
1553 (defun widget-default-menu-tag-get (widget)
1554   "Use tag or value for menus."
1555   (or (widget-get widget :menu-tag)
1556       (widget-get widget :tag)
1557       (widget-princ-to-string (widget-get widget :value))))
1558
1559 (defun widget-default-active (widget)
1560   "Return t iff this widget active (user modifiable)."
1561   (or (widget-get widget :always-active)
1562       (and (not (widget-get widget :inactive))
1563            (let ((parent (widget-get widget :parent)))
1564              (or (null parent)
1565                  (widget-apply parent :active))))))
1566
1567 (defun widget-default-deactivate (widget)
1568   "Make WIDGET inactive for user modifications."
1569   (widget-specify-inactive widget
1570                            (widget-get widget :from)
1571                            (widget-get widget :to)))
1572
1573 (defun widget-default-action (widget &optional event)
1574   "Notify the parent when a widget changes."
1575   (let ((parent (widget-get widget :parent)))
1576     (when parent
1577       (widget-apply parent :notify widget event))))
1578
1579 (defun widget-default-notify (widget child &optional event)
1580   "Pass notification to parent."
1581   (widget-default-action widget event))
1582
1583 (defun widget-default-prompt-value (widget prompt value unbound)
1584   "Read an arbitrary value.  Stolen from `set-variable'."
1585 ;; (let ((initial (if unbound
1586 ;; nil
1587 ;; It would be nice if we could do a `(cons val 1)' here.
1588 ;; (prin1-to-string (custom-quote value))))))
1589   (eval-minibuffer prompt))
1590
1591 ;;; The `item' Widget.
1592
1593 (define-widget 'item 'default
1594   "Constant items for inclusion in other widgets."
1595   :convert-widget 'widget-value-convert-widget
1596   :value-create 'widget-item-value-create
1597   :value-delete 'ignore
1598   :value-get 'widget-value-value-get
1599   :match 'widget-item-match
1600   :match-inline 'widget-item-match-inline
1601   :action 'widget-item-action
1602   :format "%t\n")
1603
1604 (defun widget-item-value-create (widget)
1605   "Insert the printed representation of the value."
1606   (princ (widget-get widget :value) (current-buffer)))
1607
1608 (defun widget-item-match (widget value)
1609   ;; Match if the value is the same.
1610   (equal (widget-get widget :value) value))
1611
1612 (defun widget-item-match-inline (widget values)
1613   ;; Match if the value is the same.
1614   (let ((value (widget-get widget :value)))
1615     (and (listp value)
1616          (<= (length value) (length values))
1617          (let ((head (widget-sublist values 0 (length value))))
1618            (and (equal head value)
1619                 (cons head (widget-sublist values (length value))))))))
1620
1621 (defun widget-sublist (list start &optional end)
1622   "Return the sublist of LIST from START to END.
1623 If END is omitted, it defaults to the length of LIST."
1624   (if (> start 0) (setq list (nthcdr start list)))
1625   (if end
1626       (unless (<= end start)
1627         (setq list (copy-sequence list))
1628         (setcdr (nthcdr (- end start 1) list) nil)
1629         list)
1630     (copy-sequence list)))
1631
1632 (defun widget-item-action (widget &optional event)
1633   ;; Just notify itself.
1634   (widget-apply widget :notify widget event))
1635
1636 ;;; The `push-button' Widget.
1637
1638 ;; (defcustom widget-push-button-gui t
1639 ;;   "If non nil, use GUI push buttons when available."
1640 ;;   :group 'widgets
1641 ;;   :type 'boolean)
1642
1643 ;; Cache already created GUI objects.
1644 ;; (defvar widget-push-button-cache nil)
1645
1646 (defcustom widget-push-button-prefix "["
1647   "String used as prefix for buttons."
1648   :type 'string
1649   :group 'widget-button)
1650
1651 (defcustom widget-push-button-suffix "]"
1652   "String used as suffix for buttons."
1653   :type 'string
1654   :group 'widget-button)
1655
1656 (define-widget 'push-button 'item
1657   "A pushable button."
1658   :button-prefix ""
1659   :button-suffix ""
1660   :value-create 'widget-push-button-value-create
1661   :format "%[%v%]")
1662
1663 (defun widget-push-button-value-create (widget)
1664   "Insert text representing the `on' and `off' states."
1665   (let* ((tag (or (widget-get widget :tag)
1666                   (widget-get widget :value)))
1667          (tag-glyph (widget-get widget :tag-glyph))
1668          (text (concat widget-push-button-prefix
1669                        tag widget-push-button-suffix)))
1670     (if tag-glyph
1671         (widget-image-insert widget text tag-glyph)
1672       (insert text))))
1673
1674 ;; (defun widget-gui-action (widget)
1675 ;;   "Apply :action for WIDGET."
1676 ;;   (widget-apply-action widget (this-command-keys)))
1677
1678 ;;; The `link' Widget.
1679
1680 (defcustom widget-link-prefix "["
1681   "String used as prefix for links."
1682   :type 'string
1683   :group 'widget-button)
1684
1685 (defcustom widget-link-suffix "]"
1686   "String used as suffix for links."
1687   :type 'string
1688   :group 'widget-button)
1689
1690 (define-widget 'link 'item
1691   "An embedded link."
1692   :button-prefix 'widget-link-prefix
1693   :button-suffix 'widget-link-suffix
1694   :help-echo "Follow the link."
1695   :format "%[%t%]")
1696
1697 ;;; The `info-link' Widget.
1698
1699 (define-widget 'info-link 'link
1700   "A link to an info file."
1701   :action 'widget-info-link-action)
1702
1703 (defun widget-info-link-action (widget &optional event)
1704   "Open the info node specified by WIDGET."
1705   (info (widget-value widget)))
1706
1707 ;;; The `url-link' Widget.
1708
1709 (define-widget 'url-link 'link
1710   "A link to an www page."
1711   :action 'widget-url-link-action)
1712
1713 (defun widget-url-link-action (widget &optional event)
1714   "Open the url specified by WIDGET."
1715   (browse-url (widget-value widget)))
1716
1717 ;;; The `function-link' Widget.
1718
1719 (define-widget 'function-link 'link
1720   "A link to an Emacs function."
1721   :action 'widget-function-link-action)
1722
1723 (defun widget-function-link-action (widget &optional event)
1724   "Show the function specified by WIDGET."
1725   (describe-function (widget-value widget)))
1726
1727 ;;; The `variable-link' Widget.
1728
1729 (define-widget 'variable-link 'link
1730   "A link to an Emacs variable."
1731   :action 'widget-variable-link-action)
1732
1733 (defun widget-variable-link-action (widget &optional event)
1734   "Show the variable specified by WIDGET."
1735   (describe-variable (widget-value widget)))
1736
1737 ;;; The `file-link' Widget.
1738
1739 (define-widget 'file-link 'link
1740   "A link to a file."
1741   :action 'widget-file-link-action)
1742
1743 (defun widget-file-link-action (widget &optional event)
1744   "Find the file specified by WIDGET."
1745   (find-file (widget-value widget)))
1746
1747 ;;; The `emacs-library-link' Widget.
1748
1749 (define-widget 'emacs-library-link 'link
1750   "A link to an Emacs Lisp library file."
1751   :action 'widget-emacs-library-link-action)
1752
1753 (defun widget-emacs-library-link-action (widget &optional event)
1754   "Find the Emacs Library file specified by WIDGET."
1755   (find-file (locate-library (widget-value widget))))
1756
1757 ;;; The `emacs-commentary-link' Widget.
1758
1759 (define-widget 'emacs-commentary-link 'link
1760   "A link to Commentary in an Emacs Lisp library file."
1761   :action 'widget-emacs-commentary-link-action)
1762
1763 (defun widget-emacs-commentary-link-action (widget &optional event)
1764   "Find the Commentary section of the Emacs file specified by WIDGET."
1765   (finder-commentary (widget-value widget)))
1766
1767 ;;; The `editable-field' Widget.
1768
1769 (define-widget 'editable-field 'default
1770   "An editable text field."
1771   :convert-widget 'widget-value-convert-widget
1772   :keymap widget-field-keymap
1773   :format "%v"
1774   :help-echo "M-TAB: complete field; RET: enter value"
1775   :value ""
1776   :prompt-internal 'widget-field-prompt-internal
1777   :prompt-history 'widget-field-history
1778   :prompt-value 'widget-field-prompt-value
1779   :action 'widget-field-action
1780   :validate 'widget-field-validate
1781   :valid-regexp ""
1782   :error "Field's value doesn't match allowed forms"
1783   :value-create 'widget-field-value-create
1784   :value-delete 'widget-field-value-delete
1785   :value-get 'widget-field-value-get
1786   :match 'widget-field-match)
1787
1788 (defvar widget-field-history nil
1789   "History of field minibuffer edits.")
1790
1791 (defun widget-field-prompt-internal (widget prompt initial history)
1792   "Read string for WIDGET promptinhg with PROMPT.
1793 INITIAL is the initial input and HISTORY is a symbol containing
1794 the earlier input."
1795   (read-string prompt initial history))
1796
1797 (defun widget-field-prompt-value (widget prompt value unbound)
1798   "Prompt for a string."
1799   (widget-apply widget
1800                 :value-to-external
1801                 (widget-apply widget
1802                               :prompt-internal prompt
1803                               (unless unbound
1804                                 (cons (widget-apply widget
1805                                                     :value-to-internal value)
1806                                       0))
1807                               (widget-get widget :prompt-history))))
1808
1809 (defvar widget-edit-functions nil)
1810
1811 (defun widget-field-action (widget &optional event)
1812   "Move to next field."
1813   (widget-forward 1)
1814   (run-hook-with-args 'widget-edit-functions widget))
1815
1816 (defun widget-field-validate (widget)
1817   "Valid if the content matches `:valid-regexp'."
1818   (unless (string-match (widget-get widget :valid-regexp)
1819                         (widget-apply widget :value-get))
1820     widget))
1821
1822 (defun widget-field-value-create (widget)
1823   "Create an editable text field."
1824   (let ((size (widget-get widget :size))
1825         (value (widget-get widget :value))
1826         (from (point))
1827         ;; This is changed to a real overlay in `widget-setup'.  We
1828         ;; need the end points to behave differently until
1829         ;; `widget-setup' is called.
1830         (overlay (cons (make-marker) (make-marker))))
1831     (widget-put widget :field-overlay overlay)
1832     (insert value)
1833     (and size
1834          (< (length value) size)
1835          (insert-char ?\  (- size (length value))))
1836     (unless (memq widget widget-field-list)
1837       (setq widget-field-new (cons widget widget-field-new)))
1838     (move-marker (cdr overlay) (point))
1839     (set-marker-insertion-type (cdr overlay) nil)
1840     (when (null size)
1841       (insert ?\n))
1842     (move-marker (car overlay) from)
1843     (set-marker-insertion-type (car overlay) t)))
1844
1845 (defun widget-field-value-delete (widget)
1846   "Remove the widget from the list of active editing fields."
1847   (setq widget-field-list (delq widget widget-field-list))
1848   (setq widget-field-new (delq widget widget-field-new))
1849   ;; These are nil if the :format string doesn't contain `%v'.
1850   (let ((overlay (widget-get widget :field-overlay)))
1851     (when (overlayp overlay)
1852       (delete-overlay overlay))))
1853
1854 (defun widget-field-value-get (widget)
1855   "Return current text in editing field."
1856   (let ((from (widget-field-start widget))
1857         (to (widget-field-end widget))
1858         (buffer (widget-field-buffer widget))
1859         (size (widget-get widget :size))
1860         (secret (widget-get widget :secret))
1861         (old (current-buffer)))
1862     (if (and from to)
1863         (progn
1864           (set-buffer buffer)
1865           (while (and size
1866                       (not (zerop size))
1867                       (> to from)
1868                       (eq (char-after (1- to)) ?\ ))
1869             (setq to (1- to)))
1870           (let ((result (buffer-substring-no-properties from to)))
1871             (when secret
1872               (let ((index 0))
1873                 (while (< (+ from index) to)
1874                   (aset result index
1875                         (get-char-property (+ from index) 'secret))
1876                   (setq index (1+ index)))))
1877             (set-buffer old)
1878             result))
1879       (widget-get widget :value))))
1880
1881 (defun widget-field-match (widget value)
1882   ;; Match any string.
1883   (stringp value))
1884
1885 ;;; The `text' Widget.
1886
1887 (define-widget 'text 'editable-field
1888   "A multiline text area."
1889   :keymap widget-text-keymap)
1890
1891 ;;; The `menu-choice' Widget.
1892
1893 (define-widget 'menu-choice 'default
1894   "A menu of options."
1895   :convert-widget  'widget-types-convert-widget
1896   :copy 'widget-types-copy
1897   :format "%[%t%]: %v"
1898   :case-fold t
1899   :tag "choice"
1900   :void '(item :format "invalid (%t)\n")
1901   :value-create 'widget-choice-value-create
1902   :value-get 'widget-child-value-get
1903   :value-inline 'widget-child-value-inline
1904   :default-get 'widget-choice-default-get
1905   :mouse-down-action 'widget-choice-mouse-down-action
1906   :action 'widget-choice-action
1907   :error "Make a choice"
1908   :validate 'widget-choice-validate
1909   :match 'widget-choice-match
1910   :match-inline 'widget-choice-match-inline)
1911
1912 (defun widget-choice-value-create (widget)
1913   "Insert the first choice that matches the value."
1914   (let ((value (widget-get widget :value))
1915         (args (widget-get widget :args))
1916         (explicit (widget-get widget :explicit-choice))
1917         current)
1918     (if (and explicit (equal value (widget-get widget :explicit-choice-value)))
1919         (progn
1920           ;; If the user specified the choice for this value,
1921           ;; respect that choice as long as the value is the same.
1922           (widget-put widget :children (list (widget-create-child-value
1923                                               widget explicit value)))
1924           (widget-put widget :choice explicit))
1925       (while args
1926         (setq current (car args)
1927               args (cdr args))
1928         (when (widget-apply current :match value)
1929           (widget-put widget :children (list (widget-create-child-value
1930                                               widget current value)))
1931           (widget-put widget :choice current)
1932           (setq args nil
1933                 current nil)))
1934       (when current
1935         (let ((void (widget-get widget :void)))
1936           (widget-put widget :children (list (widget-create-child-and-convert
1937                                               widget void :value value)))
1938           (widget-put widget :choice void))))))
1939
1940 (defun widget-choice-default-get (widget)
1941   ;; Get default for the first choice.
1942   (widget-default-get (car (widget-get widget :args))))
1943
1944 (defcustom widget-choice-toggle nil
1945   "If non-nil, a binary choice will just toggle between the values.
1946 Otherwise, the user will explicitly have to choose between the values
1947 when he invoked the menu."
1948   :type 'boolean
1949   :group 'widgets)
1950
1951 (defun widget-choice-mouse-down-action (widget &optional event)
1952   ;; Return non-nil if we need a menu.
1953   (let ((args (widget-get widget :args))
1954         (old (widget-get widget :choice)))
1955     (cond ((not (display-popup-menus-p))
1956            ;; No place to pop up a menu.
1957            nil)
1958           ((< (length args) 2)
1959            ;; Empty or singleton list, just return the value.
1960            nil)
1961           ((> (length args) widget-menu-max-size)
1962            ;; Too long, prompt.
1963            nil)
1964           ((> (length args) 2)
1965            ;; Reasonable sized list, use menu.
1966            t)
1967           ((and widget-choice-toggle (memq old args))
1968            ;; We toggle.
1969            nil)
1970           (t
1971            ;; Ask which of the two.
1972            t))))
1973
1974 (defun widget-choice-action (widget &optional event)
1975   ;; Make a choice.
1976   (let ((args (widget-get widget :args))
1977         (old (widget-get widget :choice))
1978         (tag (widget-apply widget :menu-tag-get))
1979         (completion-ignore-case (widget-get widget :case-fold))
1980         this-explicit
1981         current choices)
1982     ;; Remember old value.
1983     (if (and old (not (widget-apply widget :validate)))
1984         (let* ((external (widget-value widget))
1985                (internal (widget-apply old :value-to-internal external)))
1986           (widget-put old :value internal)))
1987     ;; Find new choice.
1988     (setq current
1989           (cond ((= (length args) 0)
1990                  nil)
1991                 ((= (length args) 1)
1992                  (nth 0 args))
1993                 ((and widget-choice-toggle
1994                       (= (length args) 2)
1995                       (memq old args))
1996                  (if (eq old (nth 0 args))
1997                      (nth 1 args)
1998                    (nth 0 args)))
1999                 (t
2000                  (while args
2001                    (setq current (car args)
2002                          args (cdr args))
2003                    (setq choices
2004                          (cons (cons (widget-apply current :menu-tag-get)
2005                                      current)
2006                                choices)))
2007                  (setq this-explicit t)
2008                  (widget-choose tag (reverse choices) event))))
2009     (when current
2010       ;; If this was an explicit user choice,
2011       ;; record the choice, and the record the value it was made for.
2012       ;; widget-choice-value-create will respect this choice,
2013       ;; as long as the value is the same.
2014       (when this-explicit
2015         (widget-put widget :explicit-choice current)
2016         (widget-put widget :explicit-choice-value (widget-get widget :value)))
2017       (widget-value-set widget (widget-default-get current))
2018       (widget-setup)
2019       (widget-apply widget :notify widget event)))
2020   (run-hook-with-args 'widget-edit-functions widget))
2021
2022 (defun widget-choice-validate (widget)
2023   ;; Valid if we have made a valid choice.
2024   (if (eq (widget-get widget :void) (widget-get widget :choice))
2025       widget
2026     (widget-apply (car (widget-get widget :children)) :validate)))
2027
2028 (defun widget-choice-match (widget value)
2029   ;; Matches if one of the choices matches.
2030   (let ((args (widget-get widget :args))
2031         current found)
2032     (while (and args (not found))
2033       (setq current (car args)
2034             args (cdr args)
2035             found (widget-apply current :match value)))
2036     found))
2037
2038 (defun widget-choice-match-inline (widget values)
2039   ;; Matches if one of the choices matches.
2040   (let ((args (widget-get widget :args))
2041         current found)
2042     (while (and args (null found))
2043       (setq current (car args)
2044             args (cdr args)
2045             found (widget-match-inline current values)))
2046     found))
2047
2048 ;;; The `toggle' Widget.
2049
2050 (define-widget 'toggle 'item
2051   "Toggle between two states."
2052   :format "%[%v%]\n"
2053   :value-create 'widget-toggle-value-create
2054   :action 'widget-toggle-action
2055   :match (lambda (widget value) t)
2056   :on "on"
2057   :off "off")
2058
2059 (defun widget-toggle-value-create (widget)
2060   "Insert text representing the `on' and `off' states."
2061   (if (widget-value widget)
2062       (let ((image (widget-get widget :on-glyph)))
2063         (and (display-graphic-p)
2064              (listp image)
2065              (not (eq (car image) 'image))
2066              (widget-put widget :on-glyph (setq image (eval image))))
2067         (widget-image-insert widget
2068                              (widget-get widget :on)
2069                              image))
2070     (let ((image (widget-get widget :off-glyph)))
2071       (and (display-graphic-p)
2072            (listp image)
2073            (not (eq (car image) 'image))
2074            (widget-put widget :off-glyph (setq image (eval image))))
2075       (widget-image-insert widget (widget-get widget :off) image))))
2076
2077 (defun widget-toggle-action (widget &optional event)
2078   ;; Toggle value.
2079   (widget-value-set widget (not (widget-value widget)))
2080   (widget-apply widget :notify widget event)
2081   (run-hook-with-args 'widget-edit-functions widget))
2082
2083 ;;; The `checkbox' Widget.
2084
2085 (define-widget 'checkbox 'toggle
2086   "A checkbox toggle."
2087   :button-suffix ""
2088   :button-prefix ""
2089   :format "%[%v%]"
2090   :on "[X]"
2091   ;; We could probably do the same job as the images using single
2092   ;; space characters in a boxed face with a stretch specification to
2093   ;; make them square.
2094   :on-glyph '(create-image "\300\300\141\143\067\076\034\030"
2095                            'xbm t :width 8 :height 8
2096                            :background "grey75" ; like default mode line
2097                            :foreground "black"
2098                            :relief -2
2099                            :ascent 'center)
2100   :off "[ ]"
2101   :off-glyph '(create-image (make-string 8 0)
2102                             'xbm t :width 8 :height 8
2103                             :background "grey75"
2104                             :foreground "black"
2105                             :relief -2
2106                             :ascent 'center)
2107   :help-echo "Toggle this item."
2108   :action 'widget-checkbox-action)
2109
2110 (defun widget-checkbox-action (widget &optional event)
2111   "Toggle checkbox, notify parent, and set active state of sibling."
2112   (widget-toggle-action widget event)
2113   (let ((sibling (widget-get-sibling widget)))
2114     (when sibling
2115       (if (widget-value widget)
2116           (widget-apply sibling :activate)
2117         (widget-apply sibling :deactivate)))))
2118
2119 ;;; The `checklist' Widget.
2120
2121 (define-widget 'checklist 'default
2122   "A multiple choice widget."
2123   :convert-widget 'widget-types-convert-widget
2124   :copy 'widget-types-copy
2125   :format "%v"
2126   :offset 4
2127   :entry-format "%b %v"
2128   :greedy nil
2129   :value-create 'widget-checklist-value-create
2130   :value-get 'widget-checklist-value-get
2131   :validate 'widget-checklist-validate
2132   :match 'widget-checklist-match
2133   :match-inline 'widget-checklist-match-inline)
2134
2135 (defun widget-checklist-value-create (widget)
2136   ;; Insert all values
2137   (let ((alist (widget-checklist-match-find widget (widget-get widget :value)))
2138         (args (widget-get widget :args)))
2139     (while args
2140       (widget-checklist-add-item widget (car args) (assq (car args) alist))
2141       (setq args (cdr args)))
2142     (widget-put widget :children (nreverse (widget-get widget :children)))))
2143
2144 (defun widget-checklist-add-item (widget type chosen)
2145   "Create checklist item in WIDGET of type TYPE.
2146 If the item is checked, CHOSEN is a cons whose cdr is the value."
2147   (and (eq (preceding-char) ?\n)
2148        (widget-get widget :indent)
2149        (insert-char ?  (widget-get widget :indent)))
2150   (widget-specify-insert
2151    (let* ((children (widget-get widget :children))
2152           (buttons (widget-get widget :buttons))
2153           (button-args (or (widget-get type :sibling-args)
2154                            (widget-get widget :button-args)))
2155           (from (point))
2156           child button)
2157      (insert (widget-get widget :entry-format))
2158      (goto-char from)
2159      ;; Parse % escapes in format.
2160      (while (re-search-forward "%\\([bv%]\\)" nil t)
2161        (let ((escape (char-after (match-beginning 1))))
2162          (delete-backward-char 2)
2163          (cond ((eq escape ?%)
2164                 (insert ?%))
2165                ((eq escape ?b)
2166                 (setq button (apply 'widget-create-child-and-convert
2167                                     widget 'checkbox
2168                                     :value (not (null chosen))
2169                                     button-args)))
2170                ((eq escape ?v)
2171                 (setq child
2172                       (cond ((not chosen)
2173                              (let ((child (widget-create-child widget type)))
2174                                (widget-apply child :deactivate)
2175                                child))
2176                             ((widget-get type :inline)
2177                              (widget-create-child-value
2178                               widget type (cdr chosen)))
2179                             (t
2180                              (widget-create-child-value
2181                               widget type (car (cdr chosen)))))))
2182                (t
2183                 (error "Unknown escape `%c'" escape)))))
2184      ;; Update properties.
2185      (and button child (widget-put child :button button))
2186      (and button (widget-put widget :buttons (cons button buttons)))
2187      (and child (widget-put widget :children (cons child children))))))
2188
2189 (defun widget-checklist-match (widget values)
2190   ;; All values must match a type in the checklist.
2191   (and (listp values)
2192        (null (cdr (widget-checklist-match-inline widget values)))))
2193
2194 (defun widget-checklist-match-inline (widget values)
2195   ;; Find the values which match a type in the checklist.
2196   (let ((greedy (widget-get widget :greedy))
2197         (args (copy-sequence (widget-get widget :args)))
2198         found rest)
2199     (while values
2200       (let ((answer (widget-checklist-match-up args values)))
2201         (cond (answer
2202                (let ((vals (widget-match-inline answer values)))
2203                  (setq found (append found (car vals))
2204                        values (cdr vals)
2205                        args (delq answer args))))
2206               (greedy
2207                (setq rest (append rest (list (car values)))
2208                      values (cdr values)))
2209               (t
2210                (setq rest (append rest values)
2211                      values nil)))))
2212     (cons found rest)))
2213
2214 (defun widget-checklist-match-find (widget vals)
2215   "Find the vals which match a type in the checklist.
2216 Return an alist of (TYPE MATCH)."
2217   (let ((greedy (widget-get widget :greedy))
2218         (args (copy-sequence (widget-get widget :args)))
2219         found)
2220     (while vals
2221       (let ((answer (widget-checklist-match-up args vals)))
2222         (cond (answer
2223                (let ((match (widget-match-inline answer vals)))
2224                  (setq found (cons (cons answer (car match)) found)
2225                        vals (cdr match)
2226                        args (delq answer args))))
2227               (greedy
2228                (setq vals (cdr vals)))
2229               (t
2230                (setq vals nil)))))
2231     found))
2232
2233 (defun widget-checklist-match-up (args vals)
2234   "Return the first type from ARGS that matches VALS."
2235   (let (current found)
2236     (while (and args (null found))
2237       (setq current (car args)
2238             args (cdr args)
2239             found (widget-match-inline current vals)))
2240     (if found
2241         current)))
2242
2243 (defun widget-checklist-value-get (widget)
2244   ;; The values of all selected items.
2245   (let ((children (widget-get widget :children))
2246         child result)
2247     (while children
2248       (setq child (car children)
2249             children (cdr children))
2250       (if (widget-value (widget-get child :button))
2251           (setq result (append result (widget-apply child :value-inline)))))
2252     result))
2253
2254 (defun widget-checklist-validate (widget)
2255   ;; Ticked chilren must be valid.
2256   (let ((children (widget-get widget :children))
2257         child button found)
2258     (while (and children (not found))
2259       (setq child (car children)
2260             children (cdr children)
2261             button (widget-get child :button)
2262             found (and (widget-value button)
2263                        (widget-apply child :validate))))
2264     found))
2265
2266 ;;; The `option' Widget
2267
2268 (define-widget 'option 'checklist
2269   "An widget with an optional item."
2270   :inline t)
2271
2272 ;;; The `choice-item' Widget.
2273
2274 (define-widget 'choice-item 'item
2275   "Button items that delegate action events to their parents."
2276   :action 'widget-parent-action
2277   :format "%[%t%] \n")
2278
2279 ;;; The `radio-button' Widget.
2280
2281 (define-widget 'radio-button 'toggle
2282   "A radio button for use in the `radio' widget."
2283   :notify 'widget-radio-button-notify
2284   :format "%[%v%]"
2285   :button-suffix ""
2286   :button-prefix ""
2287   :on "(*)"
2288   :on-glyph "radio1"
2289   :off "( )"
2290   :off-glyph "radio0")
2291
2292 (defun widget-radio-button-notify (widget child &optional event)
2293   ;; Tell daddy.
2294   (widget-apply (widget-get widget :parent) :action widget event))
2295
2296 ;;; The `radio-button-choice' Widget.
2297
2298 (define-widget 'radio-button-choice 'default
2299   "Select one of multiple options."
2300   :convert-widget 'widget-types-convert-widget
2301   :copy 'widget-types-copy
2302   :offset 4
2303   :format "%v"
2304   :entry-format "%b %v"
2305   :value-create 'widget-radio-value-create
2306   :value-get 'widget-radio-value-get
2307   :value-inline 'widget-radio-value-inline
2308   :value-set 'widget-radio-value-set
2309   :error "You must push one of the buttons"
2310   :validate 'widget-radio-validate
2311   :match 'widget-choice-match
2312   :match-inline 'widget-choice-match-inline
2313   :action 'widget-radio-action)
2314
2315 (defun widget-radio-value-create (widget)
2316   ;; Insert all values
2317   (let ((args (widget-get widget :args))
2318         arg)
2319     (while args
2320       (setq arg (car args)
2321             args (cdr args))
2322       (widget-radio-add-item widget arg))))
2323
2324 (defun widget-radio-add-item (widget type)
2325   "Add to radio widget WIDGET a new radio button item of type TYPE."
2326   ;; (setq type (widget-convert type))
2327   (and (eq (preceding-char) ?\n)
2328        (widget-get widget :indent)
2329        (insert-char ?  (widget-get widget :indent)))
2330   (widget-specify-insert
2331    (let* ((value (widget-get widget :value))
2332           (children (widget-get widget :children))
2333           (buttons (widget-get widget :buttons))
2334           (button-args (or (widget-get type :sibling-args)
2335                            (widget-get widget :button-args)))
2336           (from (point))
2337           (chosen (and (null (widget-get widget :choice))
2338                        (widget-apply type :match value)))
2339           child button)
2340      (insert (widget-get widget :entry-format))
2341      (goto-char from)
2342      ;; Parse % escapes in format.
2343      (while (re-search-forward "%\\([bv%]\\)" nil t)
2344        (let ((escape (char-after (match-beginning 1))))
2345          (delete-backward-char 2)
2346          (cond ((eq escape ?%)
2347                 (insert ?%))
2348                ((eq escape ?b)
2349                 (setq button (apply 'widget-create-child-and-convert
2350                                     widget 'radio-button
2351                                     :value (not (null chosen))
2352                                     button-args)))
2353                ((eq escape ?v)
2354                 (setq child (if chosen
2355                                 (widget-create-child-value
2356                                  widget type value)
2357                               (widget-create-child widget type)))
2358                 (unless chosen
2359                   (widget-apply child :deactivate)))
2360                (t
2361                 (error "Unknown escape `%c'" escape)))))
2362      ;; Update properties.
2363      (when chosen
2364        (widget-put widget :choice type))
2365      (when button
2366        (widget-put child :button button)
2367        (widget-put widget :buttons (nconc buttons (list button))))
2368      (when child
2369        (widget-put widget :children (nconc children (list child))))
2370      child)))
2371
2372 (defun widget-radio-value-get (widget)
2373   ;; Get value of the child widget.
2374   (let ((chosen (widget-radio-chosen widget)))
2375     (and chosen (widget-value chosen))))
2376
2377 (defun widget-radio-chosen (widget)
2378   "Return the widget representing the chosen radio button."
2379   (let ((children (widget-get widget :children))
2380         current found)
2381     (while children
2382       (setq current (car children)
2383             children (cdr children))
2384       (when (widget-apply (widget-get current :button) :value-get)
2385         (setq found current
2386               children nil)))
2387     found))
2388
2389 (defun widget-radio-value-inline (widget)
2390   ;; Get value of the child widget.
2391   (let ((children (widget-get widget :children))
2392         current found)
2393     (while children
2394       (setq current (car children)
2395             children (cdr children))
2396       (when (widget-apply (widget-get current :button) :value-get)
2397         (setq found (widget-apply current :value-inline)
2398               children nil)))
2399     found))
2400
2401 (defun widget-radio-value-set (widget value)
2402   ;; We can't just delete and recreate a radio widget, since children
2403   ;; can be added after the original creation and won't be recreated
2404   ;; by `:create'.
2405   (let ((children (widget-get widget :children))
2406         current found)
2407     (while children
2408       (setq current (car children)
2409             children (cdr children))
2410       (let* ((button (widget-get current :button))
2411              (match (and (not found)
2412                          (widget-apply current :match value))))
2413         (widget-value-set button match)
2414         (if match
2415             (progn
2416               (widget-value-set current value)
2417               (widget-apply current :activate))
2418           (widget-apply current :deactivate))
2419         (setq found (or found match))))))
2420
2421 (defun widget-radio-validate (widget)
2422   ;; Valid if we have made a valid choice.
2423   (let ((children (widget-get widget :children))
2424         current found button)
2425     (while (and children (not found))
2426       (setq current (car children)
2427             children (cdr children)
2428             button (widget-get current :button)
2429             found (widget-apply button :value-get)))
2430     (if found
2431         (widget-apply current :validate)
2432       widget)))
2433
2434 (defun widget-radio-action (widget child event)
2435   ;; Check if a radio button was pressed.
2436   (let ((children (widget-get widget :children))
2437         (buttons (widget-get widget :buttons))
2438         current)
2439     (when (memq child buttons)
2440       (while children
2441         (setq current (car children)
2442               children (cdr children))
2443         (let* ((button (widget-get current :button)))
2444           (cond ((eq child button)
2445                  (widget-value-set button t)
2446                  (widget-apply current :activate))
2447                 ((widget-value button)
2448                  (widget-value-set button nil)
2449                  (widget-apply current :deactivate)))))))
2450   ;; Pass notification to parent.
2451   (widget-apply widget :notify child event))
2452
2453 ;;; The `insert-button' Widget.
2454
2455 (define-widget 'insert-button 'push-button
2456   "An insert button for the `editable-list' widget."
2457   :tag "INS"
2458   :help-echo "Insert a new item into the list at this position."
2459   :action 'widget-insert-button-action)
2460
2461 (defun widget-insert-button-action (widget &optional event)
2462   ;; Ask the parent to insert a new item.
2463   (widget-apply (widget-get widget :parent)
2464                 :insert-before (widget-get widget :widget)))
2465
2466 ;;; The `delete-button' Widget.
2467
2468 (define-widget 'delete-button 'push-button
2469   "A delete button for the `editable-list' widget."
2470   :tag "DEL"
2471   :help-echo "Delete this item from the list."
2472   :action 'widget-delete-button-action)
2473
2474 (defun widget-delete-button-action (widget &optional event)
2475   ;; Ask the parent to insert a new item.
2476   (widget-apply (widget-get widget :parent)
2477                 :delete-at (widget-get widget :widget)))
2478
2479 ;;; The `editable-list' Widget.
2480
2481 ;; (defcustom widget-editable-list-gui nil
2482 ;;   "If non nil, use GUI push-buttons in editable list when available."
2483 ;;   :type 'boolean
2484 ;;   :group 'widgets)
2485
2486 (define-widget 'editable-list 'default
2487   "A variable list of widgets of the same type."
2488   :convert-widget 'widget-types-convert-widget
2489   :copy 'widget-types-copy
2490   :offset 12
2491   :format "%v%i\n"
2492   :format-handler 'widget-editable-list-format-handler
2493   :entry-format "%i %d %v"
2494   :value-create 'widget-editable-list-value-create
2495   :value-get 'widget-editable-list-value-get
2496   :validate 'widget-children-validate
2497   :match 'widget-editable-list-match
2498   :match-inline 'widget-editable-list-match-inline
2499   :insert-before 'widget-editable-list-insert-before
2500   :delete-at 'widget-editable-list-delete-at)
2501
2502 (defun widget-editable-list-format-handler (widget escape)
2503   ;; We recognize the insert button.
2504     ;; (let ((widget-push-button-gui widget-editable-list-gui))
2505     (cond ((eq escape ?i)
2506            (and (widget-get widget :indent)
2507                 (insert-char ?\  (widget-get widget :indent)))
2508            (apply 'widget-create-child-and-convert
2509                   widget 'insert-button
2510                   (widget-get widget :append-button-args)))
2511           (t
2512            (widget-default-format-handler widget escape)))
2513     ;; )
2514   )
2515
2516 (defun widget-editable-list-value-create (widget)
2517   ;; Insert all values
2518   (let* ((value (widget-get widget :value))
2519          (type (nth 0 (widget-get widget :args)))
2520          children)
2521     (widget-put widget :value-pos (copy-marker (point)))
2522     (set-marker-insertion-type (widget-get widget :value-pos) t)
2523     (while value
2524       (let ((answer (widget-match-inline type value)))
2525         (if answer
2526             (setq children (cons (widget-editable-list-entry-create
2527                                   widget
2528                                   (if (widget-get type :inline)
2529                                       (car answer)
2530                                     (car (car answer)))
2531                                   t)
2532                                  children)
2533                   value (cdr answer))
2534           (setq value nil))))
2535     (widget-put widget :children (nreverse children))))
2536
2537 (defun widget-editable-list-value-get (widget)
2538   ;; Get value of the child widget.
2539   (apply 'append (mapcar (lambda (child) (widget-apply child :value-inline))
2540                          (widget-get widget :children))))
2541
2542 (defun widget-editable-list-match (widget value)
2543   ;; Value must be a list and all the members must match the type.
2544   (and (listp value)
2545        (null (cdr (widget-editable-list-match-inline widget value)))))
2546
2547 (defun widget-editable-list-match-inline (widget value)
2548   (let ((type (nth 0 (widget-get widget :args)))
2549         (ok t)
2550         found)
2551     (while (and value ok)
2552       (let ((answer (widget-match-inline type value)))
2553         (if answer
2554             (setq found (append found (car answer))
2555                   value (cdr answer))
2556           (setq ok nil))))
2557     (cons found value)))
2558
2559 (defun widget-editable-list-insert-before (widget before)
2560   ;; Insert a new child in the list of children.
2561   (save-excursion
2562     (let ((children (widget-get widget :children))
2563           (inhibit-read-only t)
2564           before-change-functions
2565           after-change-functions)
2566       (cond (before
2567              (goto-char (widget-get before :entry-from)))
2568             (t
2569              (goto-char (widget-get widget :value-pos))))
2570       (let ((child (widget-editable-list-entry-create
2571                     widget nil nil)))
2572         (when (< (widget-get child :entry-from) (widget-get widget :from))
2573           (set-marker (widget-get widget :from)
2574                       (widget-get child :entry-from)))
2575         (if (eq (car children) before)
2576             (widget-put widget :children (cons child children))
2577           (while (not (eq (car (cdr children)) before))
2578             (setq children (cdr children)))
2579           (setcdr children (cons child (cdr children)))))))
2580   (widget-setup)
2581   (widget-apply widget :notify widget))
2582
2583 (defun widget-editable-list-delete-at (widget child)
2584   ;; Delete child from list of children.
2585   (save-excursion
2586     (let ((buttons (copy-sequence (widget-get widget :buttons)))
2587           button
2588           (inhibit-read-only t)
2589           before-change-functions
2590           after-change-functions)
2591       (while buttons
2592         (setq button (car buttons)
2593               buttons (cdr buttons))
2594         (when (eq (widget-get button :widget) child)
2595           (widget-put widget
2596                       :buttons (delq button (widget-get widget :buttons)))
2597           (widget-delete button))))
2598     (let ((entry-from (widget-get child :entry-from))
2599           (entry-to (widget-get child :entry-to))
2600           (inhibit-read-only t)
2601           before-change-functions
2602           after-change-functions)
2603       (widget-delete child)
2604       (delete-region entry-from entry-to)
2605       (set-marker entry-from nil)
2606       (set-marker entry-to nil))
2607     (widget-put widget :children (delq child (widget-get widget :children))))
2608   (widget-setup)
2609   (widget-apply widget :notify widget))
2610
2611 (defun widget-editable-list-entry-create (widget value conv)
2612   ;; Create a new entry to the list.
2613   (let ((type (nth 0 (widget-get widget :args)))
2614         ;; (widget-push-button-gui widget-editable-list-gui)
2615         child delete insert)
2616     (widget-specify-insert
2617      (save-excursion
2618        (and (widget-get widget :indent)
2619             (insert-char ?\  (widget-get widget :indent)))
2620        (insert (widget-get widget :entry-format)))
2621      ;; Parse % escapes in format.
2622      (while (re-search-forward "%\\(.\\)" nil t)
2623        (let ((escape (char-after (match-beginning 1))))
2624          (delete-backward-char 2)
2625          (cond ((eq escape ?%)
2626                 (insert ?%))
2627                ((eq escape ?i)
2628                 (setq insert (apply 'widget-create-child-and-convert
2629                                     widget 'insert-button
2630                                     (widget-get widget :insert-button-args))))
2631                ((eq escape ?d)
2632                 (setq delete (apply 'widget-create-child-and-convert
2633                                     widget 'delete-button
2634                                     (widget-get widget :delete-button-args))))
2635                ((eq escape ?v)
2636                 (if conv
2637                     (setq child (widget-create-child-value
2638                                  widget type value))
2639                   (setq child (widget-create-child-value
2640                                widget type (widget-default-get type)))))
2641                (t
2642                 (error "Unknown escape `%c'" escape)))))
2643      (let ((buttons (widget-get widget :buttons)))
2644        (if insert (push insert buttons))
2645        (if delete (push delete buttons))
2646        (widget-put widget :buttons buttons))
2647      (let ((entry-from (point-min-marker))
2648            (entry-to (point-max-marker)))
2649        (set-marker-insertion-type entry-from t)
2650        (set-marker-insertion-type entry-to nil)
2651        (widget-put child :entry-from entry-from)
2652        (widget-put child :entry-to entry-to)))
2653     (if insert (widget-put insert :widget child))
2654     (if delete (widget-put delete :widget child))
2655     child))
2656
2657 ;;; The `group' Widget.
2658
2659 (define-widget 'group 'default
2660   "A widget which groups other widgets inside."
2661   :convert-widget 'widget-types-convert-widget
2662   :copy 'widget-types-copy
2663   :format "%v"
2664   :value-create 'widget-group-value-create
2665   :value-get 'widget-editable-list-value-get
2666   :default-get 'widget-group-default-get
2667   :validate 'widget-children-validate
2668   :match 'widget-group-match
2669   :match-inline 'widget-group-match-inline)
2670
2671 (defun widget-group-value-create (widget)
2672   ;; Create each component.
2673   (let ((args (widget-get widget :args))
2674         (value (widget-get widget :value))
2675         arg answer children)
2676     (while args
2677       (setq arg (car args)
2678             args (cdr args)
2679             answer (widget-match-inline arg value)
2680             value (cdr answer))
2681       (and (eq (preceding-char) ?\n)
2682            (widget-get widget :indent)
2683            (insert-char ?\  (widget-get widget :indent)))
2684       (push (cond ((null answer)
2685                    (widget-create-child widget arg))
2686                   ((widget-get arg :inline)
2687                    (widget-create-child-value widget arg (car answer)))
2688                   (t
2689                    (widget-create-child-value widget arg (car (car answer)))))
2690             children))
2691     (widget-put widget :children (nreverse children))))
2692
2693 (defun widget-group-default-get (widget)
2694   ;; Get the default of the components.
2695   (mapcar 'widget-default-get (widget-get widget :args)))
2696
2697 (defun widget-group-match (widget values)
2698   ;; Match if the components match.
2699   (and (listp values)
2700        (let ((match (widget-group-match-inline widget values)))
2701          (and match (null (cdr match))))))
2702
2703 (defun widget-group-match-inline (widget vals)
2704   ;; Match if the components match.
2705   (let ((args (widget-get widget :args))
2706         argument answer found)
2707     (while args
2708       (setq argument (car args)
2709             args (cdr args)
2710             answer (widget-match-inline argument vals))
2711       (if answer
2712           (setq vals (cdr answer)
2713                 found (append found (car answer)))
2714         (setq vals nil
2715               args nil)))
2716     (if answer
2717         (cons found vals))))
2718
2719 ;;; The `visibility' Widget.
2720
2721 (define-widget 'visibility 'item
2722   "An indicator and manipulator for hidden items."
2723   :format "%[%v%]"
2724   :button-prefix ""
2725   :button-suffix ""
2726   :on "Hide"
2727   :off "Show"
2728   :value-create 'widget-visibility-value-create
2729   :action 'widget-toggle-action
2730   :match (lambda (widget value) t))
2731
2732 (defun widget-visibility-value-create (widget)
2733   ;; Insert text representing the `on' and `off' states.
2734   (let ((on (widget-get widget :on))
2735         (off (widget-get widget :off)))
2736     (if on
2737         (setq on (concat widget-push-button-prefix
2738                          on
2739                          widget-push-button-suffix))
2740       (setq on ""))
2741     (if off
2742         (setq off (concat widget-push-button-prefix
2743                           off
2744                           widget-push-button-suffix))
2745       (setq off ""))
2746     (if (widget-value widget)
2747         (widget-image-insert widget on "down" "down-pushed")
2748       (widget-image-insert widget off "right" "right-pushed"))))
2749
2750 ;;; The `documentation-link' Widget.
2751 ;;
2752 ;; This is a helper widget for `documentation-string'.
2753
2754 (define-widget 'documentation-link 'link
2755   "Link type used in documentation strings."
2756   :tab-order -1
2757   :help-echo "Describe this symbol"
2758   :action 'widget-documentation-link-action)
2759
2760 (defun widget-documentation-link-action (widget &optional event)
2761   "Display documentation for WIDGET's value.  Ignore optional argument EVENT."
2762   (let* ((string (widget-get widget :value))
2763          (symbol (intern string)))
2764     (if (and (fboundp symbol) (boundp symbol))
2765         ;; If there are two doc strings, give the user a way to pick one.
2766         (apropos (concat "\\`" (regexp-quote string) "\\'"))
2767       (if (fboundp symbol)
2768           (describe-function symbol)
2769         (describe-variable symbol)))))
2770
2771 (defcustom widget-documentation-links t
2772   "Add hyperlinks to documentation strings when non-nil."
2773   :type 'boolean
2774   :group 'widget-documentation)
2775
2776 (defcustom widget-documentation-link-regexp "`\\([^\n`' ]+\\)'"
2777   "Regexp for matching potential links in documentation strings.
2778 The first group should be the link itself."
2779   :type 'regexp
2780   :group 'widget-documentation)
2781
2782 (defcustom widget-documentation-link-p 'intern-soft
2783   "Predicate used to test if a string is useful as a link.
2784 The value should be a function.  The function will be called one
2785 argument, a string, and should return non-nil if there should be a
2786 link for that string."
2787   :type 'function
2788   :options '(widget-documentation-link-p)
2789   :group 'widget-documentation)
2790
2791 (defcustom widget-documentation-link-type 'documentation-link
2792   "Widget type used for links in documentation strings."
2793   :type 'symbol
2794   :group 'widget-documentation)
2795
2796 (defun widget-documentation-link-add (widget from to)
2797   (widget-specify-doc widget from to)
2798   (when widget-documentation-links
2799     (let ((regexp widget-documentation-link-regexp)
2800           (buttons (widget-get widget :buttons))
2801           (widget-mouse-face (default-value 'widget-mouse-face))
2802           (widget-button-face widget-documentation-face)
2803           (widget-button-pressed-face widget-documentation-face))
2804       (save-excursion
2805         (goto-char from)
2806         (while (re-search-forward regexp to t)
2807           (let ((name (match-string 1))
2808                 (begin (match-beginning 1))
2809                 (end (match-end 1)))
2810             (when (funcall widget-documentation-link-p name)
2811               (push (widget-convert-button widget-documentation-link-type
2812                                            begin end :value name)
2813                     buttons)))))
2814       (widget-put widget :buttons buttons)))
2815   (let ((indent (widget-get widget :indent)))
2816     (when (and indent (not (zerop indent)))
2817       (save-excursion
2818         (save-restriction
2819           (narrow-to-region from to)
2820           (goto-char (point-min))
2821           (while (search-forward "\n" nil t)
2822             (insert-char ?\  indent)))))))
2823
2824 ;;; The `documentation-string' Widget.
2825
2826 (define-widget 'documentation-string 'item
2827   "A documentation string."
2828   :format "%v"
2829   :action 'widget-documentation-string-action
2830   :value-create 'widget-documentation-string-value-create)
2831
2832 (defun widget-documentation-string-value-create (widget)
2833   ;; Insert documentation string.
2834   (let ((doc (widget-value widget))
2835         (indent (widget-get widget :indent))
2836         (shown (widget-get (widget-get widget :parent) :documentation-shown))
2837         (start (point)))
2838     (if (string-match "\n" doc)
2839         (let ((before (substring doc 0 (match-beginning 0)))
2840               (after (substring doc (match-beginning 0)))
2841               button)
2842           (insert before ?\ )
2843           (widget-documentation-link-add widget start (point))
2844           (setq button
2845                 (widget-create-child-and-convert
2846                  widget 'visibility
2847                  :help-echo "Show or hide rest of the documentation."
2848                  :on "Hide Rest"
2849                  :off "More"
2850                  :always-active t
2851                  :action 'widget-parent-action
2852                  shown))
2853           (when shown
2854             (setq start (point))
2855             (when (and indent (not (zerop indent)))
2856               (insert-char ?\  indent))
2857             (insert after)
2858             (widget-documentation-link-add widget start (point)))
2859           (widget-put widget :buttons (list button)))
2860       (insert doc)
2861       (widget-documentation-link-add widget start (point))))
2862   (insert ?\n))
2863
2864 (defun widget-documentation-string-action (widget &rest ignore)
2865   ;; Toggle documentation.
2866   (let ((parent (widget-get widget :parent)))
2867     (widget-put parent :documentation-shown
2868                 (not (widget-get parent :documentation-shown))))
2869   ;; Redraw.
2870   (widget-value-set widget (widget-value widget)))
2871 \f
2872 ;;; The Sexp Widgets.
2873
2874 (define-widget 'const 'item
2875   "An immutable sexp."
2876   :prompt-value 'widget-const-prompt-value
2877   :format "%t\n%d")
2878
2879 (defun widget-const-prompt-value (widget prompt value unbound)
2880   ;; Return the value of the const.
2881   (widget-value widget))
2882
2883 (define-widget 'function-item 'const
2884   "An immutable function name."
2885   :format "%v\n%h"
2886   :documentation-property (lambda (symbol)
2887                             (condition-case nil
2888                                 (documentation symbol t)
2889                               (error nil))))
2890
2891 (define-widget 'variable-item 'const
2892   "An immutable variable name."
2893   :format "%v\n%h"
2894   :documentation-property 'variable-documentation)
2895
2896 (define-widget 'other 'sexp
2897   "Matches any value, but doesn't let the user edit the value.
2898 This is useful as last item in a `choice' widget.
2899 You should use this widget type with a default value,
2900 as in (other DEFAULT) or (other :tag \"NAME\" DEFAULT).
2901 If the user selects this alternative, that specifies DEFAULT
2902 as the value."
2903   :tag "Other"
2904   :format "%t%n"
2905   :value 'other)
2906
2907 (defvar widget-string-prompt-value-history nil
2908   "History of input to `widget-string-prompt-value'.")
2909
2910 (define-widget 'string 'editable-field
2911   "A string"
2912   :tag "String"
2913   :format "%{%t%}: %v"
2914   :complete-function 'ispell-complete-word
2915   :prompt-history 'widget-string-prompt-value-history)
2916
2917 (define-widget 'regexp 'string
2918   "A regular expression."
2919   :match 'widget-regexp-match
2920   :validate 'widget-regexp-validate
2921   ;; Doesn't work well with terminating newline.
2922   ;; :value-face 'widget-single-line-field-face
2923   :tag "Regexp")
2924
2925 (defun widget-regexp-match (widget value)
2926   ;; Match valid regexps.
2927   (and (stringp value)
2928        (condition-case nil
2929            (prog1 t
2930              (string-match value ""))
2931          (error nil))))
2932
2933 (defun widget-regexp-validate (widget)
2934   "Check that the value of WIDGET is a valid regexp."
2935   (condition-case data
2936       (prog1 nil
2937         (string-match (widget-value widget) ""))
2938     (error (widget-put widget :error (error-message-string data))
2939            widget)))
2940
2941 (define-widget 'file 'string
2942   "A file widget.
2943 It will read a file name from the minibuffer when invoked."
2944   :complete-function 'widget-file-complete
2945   :prompt-value 'widget-file-prompt-value
2946   :format "%{%t%}: %v"
2947   ;; Doesn't work well with terminating newline.
2948   ;; :value-face 'widget-single-line-field-face
2949   :tag "File")
2950
2951 (defun widget-file-complete ()
2952   "Perform completion on file name preceding point."
2953   (interactive)
2954   (let* ((end (point))
2955          (beg (save-excursion
2956                 (skip-chars-backward "^ ")
2957                 (point)))
2958          (pattern (buffer-substring beg end))
2959          (name-part (file-name-nondirectory pattern))
2960          (directory (file-name-directory pattern))
2961          (completion (file-name-completion name-part directory)))
2962     (cond ((eq completion t))
2963           ((null completion)
2964            (message "Can't find completion for \"%s\"" pattern)
2965            (ding))
2966           ((not (string= name-part completion))
2967            (delete-region beg end)
2968            (insert (expand-file-name completion directory)))
2969           (t
2970            (message "Making completion list...")
2971            (with-output-to-temp-buffer "*Completions*"
2972              (display-completion-list
2973               (sort (file-name-all-completions name-part directory)
2974                     'string<)))
2975            (message "Making completion list...%s" "done")))))
2976
2977 (defun widget-file-prompt-value (widget prompt value unbound)
2978   ;; Read file from minibuffer.
2979   (abbreviate-file-name
2980    (if unbound
2981        (read-file-name prompt)
2982      (let ((prompt2 (format "%s (default %s) " prompt value))
2983            (dir (file-name-directory value))
2984            (file (file-name-nondirectory value))
2985            (must-match (widget-get widget :must-match)))
2986        (read-file-name prompt2 dir nil must-match file)))))
2987
2988 ;;;(defun widget-file-action (widget &optional event)
2989 ;;;  ;; Read a file name from the minibuffer.
2990 ;;;  (let* ((value (widget-value widget))
2991 ;;;      (dir (file-name-directory value))
2992 ;;;      (file (file-name-nondirectory value))
2993 ;;;      (menu-tag (widget-apply widget :menu-tag-get))
2994 ;;;      (must-match (widget-get widget :must-match))
2995 ;;;      (answer (read-file-name (concat menu-tag ": (default `" value "') ")
2996 ;;;                              dir nil must-match file)))
2997 ;;;    (widget-value-set widget (abbreviate-file-name answer))
2998 ;;;    (widget-setup)
2999 ;;;    (widget-apply widget :notify widget event)))
3000
3001 ;; Fixme: use file-name-as-directory.
3002 (define-widget 'directory 'file
3003   "A directory widget.
3004 It will read a directory name from the minibuffer when invoked."
3005   :tag "Directory")
3006
3007 (defvar widget-symbol-prompt-value-history nil
3008   "History of input to `widget-symbol-prompt-value'.")
3009
3010 (define-widget 'symbol 'editable-field
3011   "A Lisp symbol."
3012   :value nil
3013   :tag "Symbol"
3014   :format "%{%t%}: %v"
3015   :match (lambda (widget value) (symbolp value))
3016   :complete-function 'lisp-complete-symbol
3017   :prompt-internal 'widget-symbol-prompt-internal
3018   :prompt-match 'symbolp
3019   :prompt-history 'widget-symbol-prompt-value-history
3020   :value-to-internal (lambda (widget value)
3021                        (if (symbolp value)
3022                            (symbol-name value)
3023                          value))
3024   :value-to-external (lambda (widget value)
3025                        (if (stringp value)
3026                            (intern value)
3027                          value)))
3028
3029 (defun widget-symbol-prompt-internal (widget prompt initial history)
3030   ;; Read file from minibuffer.
3031   (let ((answer (completing-read prompt obarray
3032                                  (widget-get widget :prompt-match)
3033                                  nil initial history)))
3034     (if (and (stringp answer)
3035              (not (zerop (length answer))))
3036         answer
3037       (error "No value"))))
3038
3039 (defvar widget-function-prompt-value-history nil
3040   "History of input to `widget-function-prompt-value'.")
3041
3042 (define-widget 'function 'sexp
3043   "A Lisp function."
3044   :complete-function (lambda ()
3045                        (interactive)
3046                        (lisp-complete-symbol 'fboundp))
3047   :prompt-value 'widget-field-prompt-value
3048   :prompt-internal 'widget-symbol-prompt-internal
3049   :prompt-match 'fboundp
3050   :prompt-history 'widget-function-prompt-value-history
3051   :action 'widget-field-action
3052   :match-alternatives '(functionp)
3053   :validate (lambda (widget)
3054               (unless (functionp (widget-value widget))
3055                 (widget-put widget :error (format "Invalid function: %S"
3056                                                   (widget-value widget)))
3057                 widget))
3058   :value 'ignore
3059   :tag "Function")
3060
3061 (defvar widget-variable-prompt-value-history nil
3062   "History of input to `widget-variable-prompt-value'.")
3063
3064 (define-widget 'variable 'symbol
3065   "A Lisp variable."
3066   :prompt-match 'boundp
3067   :prompt-history 'widget-variable-prompt-value-history
3068   :complete-function (lambda ()
3069                        (interactive)
3070                        (lisp-complete-symbol 'boundp))
3071   :tag "Variable")
3072
3073 (defvar widget-coding-system-prompt-value-history nil
3074   "History of input to `widget-coding-system-prompt-value'.")
3075
3076 (define-widget 'coding-system 'symbol
3077   "A MULE coding-system."
3078   :format "%{%t%}: %v"
3079   :tag "Coding system"
3080   :base-only nil
3081   :prompt-history 'widget-coding-system-prompt-value-history
3082   :prompt-value 'widget-coding-system-prompt-value
3083   :action 'widget-coding-system-action
3084   :complete-function (lambda ()
3085                        (interactive)
3086                        (lisp-complete-symbol 'coding-system-p))
3087   :validate (lambda (widget)
3088               (unless (coding-system-p (widget-value widget))
3089                 (widget-put widget :error (format "Invalid coding system: %S"
3090                                                   (widget-value widget)))
3091                 widget))
3092   :value 'undecided
3093   :prompt-match 'coding-system-p)
3094
3095 (defun widget-coding-system-prompt-value (widget prompt value unbound)
3096   "Read coding-system from minibuffer."
3097   (if (widget-get widget :base-only)
3098       (intern
3099        (completing-read (format "%s (default %s) " prompt value)
3100                         (mapcar #'list (coding-system-list t)) nil nil nil
3101                         coding-system-history))
3102       (read-coding-system (format "%s (default %s) " prompt value) value)))
3103
3104 (defun widget-coding-system-action (widget &optional event)
3105   (let ((answer
3106          (widget-coding-system-prompt-value
3107           widget
3108           (widget-apply widget :menu-tag-get)
3109           (widget-value widget)
3110           t)))
3111     (widget-value-set widget answer)
3112     (widget-apply widget :notify widget event)
3113     (widget-setup)))
3114 \f
3115 (define-widget 'sexp 'editable-field
3116   "An arbitrary Lisp expression."
3117   :tag "Lisp expression"
3118   :format "%{%t%}: %v"
3119   :value nil
3120   :validate 'widget-sexp-validate
3121   :match (lambda (widget value) t)
3122   :value-to-internal 'widget-sexp-value-to-internal
3123   :value-to-external (lambda (widget value) (read value))
3124   :prompt-history 'widget-sexp-prompt-value-history
3125   :prompt-value 'widget-sexp-prompt-value)
3126
3127 (defun widget-sexp-value-to-internal (widget value)
3128   ;; Use pp for printer representation.
3129   (let ((pp (if (symbolp value)
3130                 (prin1-to-string value)
3131               (pp-to-string value))))
3132     (while (string-match "\n\\'" pp)
3133       (setq pp (substring pp 0 -1)))
3134     (if (or (string-match "\n\\'" pp)
3135             (> (length pp) 40))
3136         (concat "\n" pp)
3137       pp)))
3138
3139 (defun widget-sexp-validate (widget)
3140   ;; Valid if we can read the string and there is no junk left after it.
3141   (with-temp-buffer
3142     (insert (widget-apply widget :value-get))
3143     (goto-char (point-min))
3144     (let (err)
3145       (condition-case data
3146           (progn
3147             ;; Avoid a confusing end-of-file error.
3148             (skip-syntax-forward "\\s-")
3149             (if (eobp)
3150                 (setq err "Empty sexp -- use `nil'?")
3151               (unless (widget-apply widget :match (read (current-buffer)))
3152                 (setq err (widget-get widget :type-error))))
3153             (if (and (not (eobp))
3154                      (not err))
3155                 (setq err (format "Junk at end of expression: %s"
3156                                   (buffer-substring (point)
3157                                                     (point-max))))))
3158         (end-of-file                    ; Avoid confusing error message.
3159          (setq err "Unbalanced sexp"))
3160         (error (setq err (error-message-string data))))
3161       (if (not err)
3162           nil
3163         (widget-put widget :error err)
3164         widget))))
3165
3166 (defvar widget-sexp-prompt-value-history nil
3167   "History of input to `widget-sexp-prompt-value'.")
3168
3169 (defun widget-sexp-prompt-value (widget prompt value unbound)
3170   ;; Read an arbitrary sexp.
3171   (let ((found (read-string prompt
3172                             (if unbound nil (cons (prin1-to-string value) 0))
3173                             (widget-get widget :prompt-history))))
3174     (let ((answer (read-from-string found)))
3175       (unless (= (cdr answer) (length found))
3176         (error "Junk at end of expression: %s"
3177                (substring found (cdr answer))))
3178       (car answer))))
3179
3180 (define-widget 'restricted-sexp 'sexp
3181   "A Lisp expression restricted to values that match.
3182 To use this type, you must define :match or :match-alternatives."
3183   :type-error "The specified value is not valid"
3184   :match 'widget-restricted-sexp-match
3185   :value-to-internal (lambda (widget value)
3186                        (if (widget-apply widget :match value)
3187                            (prin1-to-string value)
3188                          value)))
3189
3190 (defun widget-restricted-sexp-match (widget value)
3191   (let ((alternatives (widget-get widget :match-alternatives))
3192         matched)
3193     (while (and alternatives (not matched))
3194       (if (cond ((functionp (car alternatives))
3195                  (funcall (car alternatives) value))
3196                 ((and (consp (car alternatives))
3197                       (eq (car (car alternatives)) 'quote))
3198                  (eq value (nth 1 (car alternatives)))))
3199           (setq matched t))
3200       (setq alternatives (cdr alternatives)))
3201     matched))
3202 \f
3203 (define-widget 'integer 'restricted-sexp
3204   "An integer."
3205   :tag "Integer"
3206   :value 0
3207   :type-error "This field should contain an integer"
3208   :match-alternatives '(integerp))
3209
3210 (define-widget 'number 'restricted-sexp
3211   "A number (floating point or integer)."
3212   :tag "Number"
3213   :value 0.0
3214   :type-error "This field should contain a number (floating point or integer)"
3215   :match-alternatives '(numberp))
3216
3217 (define-widget 'float 'restricted-sexp
3218   "A floating point number."
3219   :tag "Floating point number"
3220   :value 0.0
3221   :type-error "This field should contain a floating point number"
3222   :match-alternatives '(floatp))
3223
3224 (define-widget 'character 'editable-field
3225   "A character."
3226   :tag "Character"
3227   :value 0
3228   :size 1
3229   :format "%{%t%}: %v\n"
3230   :valid-regexp "\\`.\\'"
3231   :error "This field should contain a single character"
3232   :value-to-internal (lambda (widget value)
3233                        (if (stringp value)
3234                            value
3235                          (char-to-string value)))
3236   :value-to-external (lambda (widget value)
3237                        (if (stringp value)
3238                            (aref value 0)
3239                          value))
3240   :match (lambda (widget value)
3241            (char-valid-p value)))
3242
3243 (define-widget 'list 'group
3244   "A Lisp list."
3245   :tag "List"
3246   :format "%{%t%}:\n%v")
3247
3248 (define-widget 'vector 'group
3249   "A Lisp vector."
3250   :tag "Vector"
3251   :format "%{%t%}:\n%v"
3252   :match 'widget-vector-match
3253   :value-to-internal (lambda (widget value) (append value nil))
3254   :value-to-external (lambda (widget value) (apply 'vector value)))
3255
3256 (defun widget-vector-match (widget value)
3257   (and (vectorp value)
3258        (widget-group-match widget
3259                            (widget-apply widget :value-to-internal value))))
3260
3261 (define-widget 'cons 'group
3262   "A cons-cell."
3263   :tag "Cons-cell"
3264   :format "%{%t%}:\n%v"
3265   :match 'widget-cons-match
3266   :value-to-internal (lambda (widget value)
3267                        (list (car value) (cdr value)))
3268   :value-to-external (lambda (widget value)
3269                        (apply 'cons value)))
3270
3271 (defun widget-cons-match (widget value)
3272   (and (consp value)
3273        (widget-group-match widget
3274                            (widget-apply widget :value-to-internal value))))
3275 \f
3276 ;;; The `lazy' Widget.
3277 ;;
3278 ;; Recursive datatypes.
3279
3280 (define-widget 'lazy 'default
3281   "Base widget for recursive datastructures.
3282
3283 The `lazy' widget will, when instantiated, contain a single inferior
3284 widget, of the widget type specified by the :type parameter.  The
3285 value of the `lazy' widget is the same as the value of the inferior
3286 widget.  When deriving a new widget from the 'lazy' widget, the :type
3287 parameter is allowed to refer to the widget currently being defined,
3288 thus allowing recursive datastructures to be described.
3289
3290 The :type parameter takes the same arguments as the defcustom
3291 parameter with the same name.
3292
3293 Most composite widgets, i.e. widgets containing other widgets, does
3294 not allow recursion.  That is, when you define a new widget type, none
3295 of the inferior widgets may be of the same type you are currently
3296 defining.
3297
3298 In Lisp, however, it is custom to define datastructures in terms of
3299 themselves.  A list, for example, is defined as either nil, or a cons
3300 cell whose cdr itself is a list.  The obvious way to translate this
3301 into a widget type would be
3302
3303   (define-widget 'my-list 'choice
3304     \"A list of sexps.\"
3305     :tag \"Sexp list\"
3306     :args '((const nil) (cons :value (nil) sexp my-list)))
3307
3308 Here we attempt to define my-list as a choice of either the constant
3309 nil, or a cons-cell containing a sexp and my-lisp.  This will not work
3310 because the `choice' widget does not allow recursion.
3311
3312 Using the `lazy' widget you can overcome this problem, as in this
3313 example:
3314
3315   (define-widget 'sexp-list 'lazy
3316     \"A list of sexps.\"
3317     :tag \"Sexp list\"
3318     :type '(choice (const nil) (cons :value (nil) sexp sexp-list)))"
3319   :format "%{%t%}: %v"
3320   ;; We don't convert :type because we want to allow recursive
3321   ;; datastructures.  This is slow, so we should not create speed
3322   ;; critical widgets by deriving from this.
3323   :convert-widget 'widget-value-convert-widget
3324   :value-create 'widget-type-value-create
3325   :value-get 'widget-child-value-get
3326   :value-inline 'widget-child-value-inline
3327   :default-get 'widget-type-default-get
3328   :match 'widget-type-match
3329   :validate 'widget-child-validate)
3330
3331 \f
3332 ;;; The `plist' Widget.
3333 ;;
3334 ;; Property lists.
3335
3336 (define-widget 'plist 'list
3337   "A property list."
3338   :key-type '(symbol :tag "Key")
3339   :value-type '(sexp :tag "Value")
3340   :convert-widget 'widget-plist-convert-widget
3341   :tag "Plist")
3342
3343 (defvar widget-plist-value-type)        ;Dynamic variable
3344
3345 (defun widget-plist-convert-widget (widget)
3346   ;; Handle `:options'.
3347   (let* ((options (widget-get widget :options))
3348          (widget-plist-value-type (widget-get widget :value-type))
3349          (other `(editable-list :inline t
3350                                 (group :inline t
3351                                        ,(widget-get widget :key-type)
3352                                        ,widget-plist-value-type)))
3353          (args (if options
3354                    (list `(checklist :inline t
3355                                      :greedy t
3356                                      ,@(mapcar 'widget-plist-convert-option
3357                                                options))
3358                          other)
3359                  (list other))))
3360     (widget-put widget :args args)
3361     widget))
3362
3363 (defun widget-plist-convert-option (option)
3364   ;; Convert a single plist option.
3365   (let (key-type value-type)
3366     (if (listp option)
3367         (let ((key (nth 0 option)))
3368           (setq value-type (nth 1 option))
3369           (if (listp key)
3370               (setq key-type key)
3371             (setq key-type `(const ,key))))
3372       (setq key-type `(const ,option)
3373             value-type widget-plist-value-type))
3374     `(group :format "Key: %v" :inline t ,key-type ,value-type)))
3375
3376
3377 ;;; The `alist' Widget.
3378 ;;
3379 ;; Association lists.
3380
3381 (define-widget 'alist 'list
3382   "An association list."
3383   :key-type '(sexp :tag "Key")
3384   :value-type '(sexp :tag "Value")
3385   :convert-widget 'widget-alist-convert-widget
3386   :tag "Alist")
3387
3388 (defvar widget-alist-value-type)        ;Dynamic variable
3389
3390 (defun widget-alist-convert-widget (widget)
3391   ;; Handle `:options'.
3392   (let* ((options (widget-get widget :options))
3393          (widget-alist-value-type (widget-get widget :value-type))
3394          (other `(editable-list :inline t
3395                                 (cons :format "%v"
3396                                       ,(widget-get widget :key-type)
3397                                       ,widget-alist-value-type)))
3398          (args (if options
3399                    (list `(checklist :inline t
3400                                      :greedy t
3401                                      ,@(mapcar 'widget-alist-convert-option
3402                                                options))
3403                          other)
3404                  (list other))))
3405     (widget-put widget :args args)
3406     widget))
3407
3408 (defun widget-alist-convert-option (option)
3409   ;; Convert a single alist option.
3410   (let (key-type value-type)
3411     (if (listp option)
3412         (let ((key (nth 0 option)))
3413           (setq value-type (nth 1 option))
3414           (if (listp key)
3415               (setq key-type key)
3416             (setq key-type `(const ,key))))
3417       (setq key-type `(const ,option)
3418             value-type widget-alist-value-type))
3419     `(cons :format "Key: %v" ,key-type ,value-type)))
3420 \f
3421 (define-widget 'choice 'menu-choice
3422   "A union of several sexp types."
3423   :tag "Choice"
3424   :format "%{%t%}: %[Value Menu%] %v"
3425   :button-prefix 'widget-push-button-prefix
3426   :button-suffix 'widget-push-button-suffix
3427   :prompt-value 'widget-choice-prompt-value)
3428
3429 (defun widget-choice-prompt-value (widget prompt value unbound)
3430   "Make a choice."
3431   (let ((args (widget-get widget :args))
3432         (completion-ignore-case (widget-get widget :case-fold))
3433         current choices old)
3434     ;; Find the first arg that matches VALUE.
3435     (let ((look args))
3436       (while look
3437         (if (widget-apply (car look) :match value)
3438             (setq old (car look)
3439                   look nil)
3440           (setq look (cdr look)))))
3441     ;; Find new choice.
3442     (setq current
3443           (cond ((= (length args) 0)
3444                  nil)
3445                 ((= (length args) 1)
3446                  (nth 0 args))
3447                 ((and (= (length args) 2)
3448                       (memq old args))
3449                  (if (eq old (nth 0 args))
3450                      (nth 1 args)
3451                    (nth 0 args)))
3452                 (t
3453                  (while args
3454                    (setq current (car args)
3455                          args (cdr args))
3456                    (setq choices
3457                          (cons (cons (widget-apply current :menu-tag-get)
3458                                      current)
3459                                choices)))
3460                  (let ((val (completing-read prompt choices nil t)))
3461                    (if (stringp val)
3462                        (let ((try (try-completion val choices)))
3463                          (when (stringp try)
3464                            (setq val try))
3465                          (cdr (assoc val choices)))
3466                      nil)))))
3467     (if current
3468         (widget-prompt-value current prompt nil t)
3469       value)))
3470 \f
3471 (define-widget 'radio 'radio-button-choice
3472   "A union of several sexp types."
3473   :tag "Choice"
3474   :format "%{%t%}:\n%v"
3475   :prompt-value 'widget-choice-prompt-value)
3476
3477 (define-widget 'repeat 'editable-list
3478   "A variable length homogeneous list."
3479   :tag "Repeat"
3480   :format "%{%t%}:\n%v%i\n")
3481
3482 (define-widget 'set 'checklist
3483   "A list of members from a fixed set."
3484   :tag "Set"
3485   :format "%{%t%}:\n%v")
3486
3487 (define-widget 'boolean 'toggle
3488   "To be nil or non-nil, that is the question."
3489   :tag "Boolean"
3490   :prompt-value 'widget-boolean-prompt-value
3491   :button-prefix 'widget-push-button-prefix
3492   :button-suffix 'widget-push-button-suffix
3493   :format "%{%t%}: %[Toggle%]  %v\n"
3494   :on "on (non-nil)"
3495   :off "off (nil)")
3496
3497 (defun widget-boolean-prompt-value (widget prompt value unbound)
3498   ;; Toggle a boolean.
3499   (y-or-n-p prompt))
3500 \f
3501 ;;; The `color' Widget.
3502
3503 ;; Fixme: match
3504 (define-widget 'color 'editable-field
3505   "Choose a color name (with sample)."
3506   :format "%t: %v (%{sample%})\n"
3507   :size 10
3508   :tag "Color"
3509   :value "black"
3510   :complete 'widget-color-complete
3511   :sample-face-get 'widget-color-sample-face-get
3512   :notify 'widget-color-notify
3513   :action 'widget-color-action)
3514
3515 (defun widget-color-complete (widget)
3516   "Complete the color in WIDGET."
3517   (require 'facemenu)                   ; for facemenu-color-alist
3518   (let* ((prefix (buffer-substring-no-properties (widget-field-start widget)
3519                                                  (point)))
3520          (list (or facemenu-color-alist (defined-colors)))
3521          (completion (try-completion prefix list)))
3522     (cond ((eq completion t)
3523            (message "Exact match."))
3524           ((null completion)
3525            (error "Can't find completion for \"%s\"" prefix))
3526           ((not (string-equal prefix completion))
3527            (insert-and-inherit (substring completion (length prefix))))
3528           (t
3529            (message "Making completion list...")
3530            (with-output-to-temp-buffer "*Completions*"
3531              (display-completion-list (all-completions prefix list nil)))
3532            (message "Making completion list...done")))))
3533
3534 (defun widget-color-sample-face-get (widget)
3535   (let* ((value (condition-case nil
3536                     (widget-value widget)
3537                   (error (widget-get widget :value)))))
3538     (if (color-defined-p value)
3539         (list (cons 'foreground-color value))
3540       'default)))
3541
3542 (defun widget-color-action (widget &optional event)
3543   "Prompt for a color."
3544   (let* ((tag (widget-apply widget :menu-tag-get))
3545          (prompt (concat tag ": "))
3546          (value (widget-value widget))
3547          (start (widget-field-start widget))
3548          (answer (facemenu-read-color prompt)))
3549     (unless (zerop (length answer))
3550       (widget-value-set widget answer)
3551       (widget-setup)
3552       (widget-apply widget :notify widget event))))
3553
3554 (defun widget-color-notify (widget child &optional event)
3555   "Update the sample, and notofy the parent."
3556   (overlay-put (widget-get widget :sample-overlay)
3557                'face (widget-apply widget :sample-face-get))
3558   (widget-default-notify widget child event))
3559 \f
3560 ;;; The Help Echo
3561
3562 (defun widget-echo-help (pos)
3563   "Display help-echo text for widget at POS."
3564   (let* ((widget (widget-at pos))
3565          (help-echo (and widget (widget-get widget :help-echo))))
3566     (if (functionp help-echo)
3567         (setq help-echo (funcall help-echo widget)))
3568     (if help-echo (message "%s" (eval help-echo)))))
3569
3570 ;;; The End:
3571
3572 (provide 'wid-edit)
3573
3574 ;;; arch-tag: a076e75e-18a1-4b46-8be5-3f317bcbc707
3575 ;;; wid-edit.el ends here