lisp/finder.el

   1 ;;; finder.el --- topic & keyword-based code finder
   2
   3 ;; Copyright (C) 1992, 1997, 1998, 1999, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   6 ;; Created: 16 Jun 1992
   7 ;; Version: 1.0
   8 ;; Keywords: help
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This mode uses the Keywords library header to provide code-finding
  30 ;; services by keyword.
  31 ;;
  32 ;; Things to do:
  33 ;;    1. Support multiple keywords per search.  This could be extremely hairy;
  34 ;; there doesn't seem to be any way to get completing-read to exit on
  35 ;; an EOL with no substring pending, which is what we'd want to end the loop.
  36 ;;    2. Search by string in synopsis line?
  37 ;;    3. Function to check finder-package-info for unknown keywords.
  38
  39 ;;; Code:
  40
  41 (require 'lisp-mnt)
  42 (require 'find-func)                    ;for find-library(-suffixes)
  43 ;; Use `load' rather than `require' so that it doesn't get loaded
  44 ;; during byte-compilation (at which point it might be missing).
  45 (load "finder-inf" t t)
  46
  47 (defvar finder-mode-hook nil
  48   "*Hook run when function `finder-mode' is called.")
  49
  50 ;; Local variable in finder buffer.
  51 (defvar finder-headmark)
  52
  53 ;; These are supposed to correspond to top-level customization groups,
  54 ;; says rms.
  55 (defvar finder-known-keywords
  56   '(
  57     (abbrev     . "abbreviation handling, typing shortcuts, macros")
  58     ;; Too specific:
  59     (bib        . "code related to the `bib' bibliography processor")
  60     (c          . "support for the C language and related languages")
  61     (calendar   . "calendar and time management support")
  62     (comm       . "communications, networking, remote access to files")
  63     (convenience . "convenience features for faster editing")
  64     (data       . "support for editing files of data")
  65     (docs       . "support for Emacs documentation")
  66     (emulations . "emulations of other editors")
  67     (extensions . "Emacs Lisp language extensions")
  68     (faces      . "support for multiple fonts")
  69     (files      . "support for editing and manipulating files")
  70     (frames     . "support for Emacs frames and window systems")
  71     (games      . "games, jokes and amusements")
  72     (hardware   . "support for interfacing with exotic hardware")
  73     (help       . "support for on-line help systems")
  74     (hypermedia . "support for links between text or other media types")
  75     (i18n       . "internationalization and alternate character-set support")
  76     (internal   . "code for Emacs internals, build process, defaults")
  77     (languages  . "specialized modes for editing programming languages")
  78     (lisp       . "Lisp support, including Emacs Lisp")
  79     (local      . "code local to your site")
  80     (maint      . "maintenance aids for the Emacs development group")
  81     (mail       . "modes for electronic-mail handling")
  82     (matching   . "various sorts of searching and matching")
  83     (mouse      . "mouse support")
  84     (multimedia . "images and sound support")
  85     (news       . "support for netnews reading and posting")
  86     (oop        . "support for object-oriented programming")
  87     (outlines   . "support for hierarchical outlining")
  88     (processes  . "process, subshell, compilation, and job control support")
  89     (terminals  . "support for terminal types")
  90     (tex        . "supporting code for the TeX formatter")
  91     (tools      . "programming tools")
  92     (unix       . "front-ends/assistants for, or emulators of, UNIX-like features")
  93 ;; Not a custom group and not currently useful.
  94 ;;    (vms      . "support code for vms")
  95     (wp         . "word processing")
  96     ))
  97
  98 (defvar finder-mode-map nil)
  99 (or finder-mode-map
 100     (let ((map (make-sparse-keymap)))
 101       (define-key map " "       'finder-select)
 102       (define-key map "f"       'finder-select)
 103       (define-key map [mouse-2] 'finder-mouse-select)
 104       (define-key map "\C-m"    'finder-select)
 105       (define-key map "?"       'finder-summary)
 106       (define-key map "q"       'finder-exit)
 107       (define-key map "d"       'finder-list-keywords)
 108       (setq finder-mode-map map)))
 109
 110
 111 ;;; Code for regenerating the keyword list.
 112
 113 (defvar finder-package-info nil
 114   "Assoc list mapping file names to description & keyword lists.")
 115
 116 (defvar generated-finder-keywords-file "finder-inf.el"
 117   "File \\[finder-compile-keywords] puts finder keywords into.")
 118
 119 (defun finder-compile-keywords (&rest dirs)
 120   "Regenerate the keywords association list into `generated-finder-keywords-file'.
 121 Optional arguments DIRS are a list of Emacs Lisp directories to compile from;
 122 no arguments compiles from `load-path'."
 123   (save-excursion
 124     (let ((processed nil))
 125       (find-file generated-finder-keywords-file)
 126       (erase-buffer)
 127       (insert ";;; " (file-name-nondirectory generated-finder-keywords-file)
 128               " --- keyword-to-package mapping\n")
 129       (insert ";; This file is part of GNU Emacs.\n")
 130       (insert ";;; Commentary:\n")
 131       (insert ";; Don't edit this file.  It's generated by finder.el\n\n")
 132       (insert ";;; Code:\n")
 133       (insert "\n(setq finder-package-info '(\n")
 134       (mapcar
 135        (lambda (d)
 136          (when (file-exists-p (directory-file-name d))
 137            (message "Directory %s" d)
 138            (mapcar
 139             (lambda (f)
 140               (if (and (or (string-match "^[^=].*\\.el$" f)
 141                            ;; Allow compressed files also.  Fixme:
 142                            ;; generalize this, especially for
 143                            ;; MS-DOG-type filenames.
 144                            (and (string-match "^[^=].*\\.el\\.\\(gz\\|Z\\)$" f)
 145                                 (require 'jka-compr)))
 146                        ;; Ignore lock files.
 147                        (not (string-match "^.#" f))
 148                        (not (member f processed)))
 149                   (let (summary keystart keywords)
 150                     (setq processed (cons f processed))
 151                     (save-excursion
 152                       (set-buffer (get-buffer-create "*finder-scratch*"))
 153                       (buffer-disable-undo (current-buffer))
 154                       (erase-buffer)
 155                       (insert-file-contents
 156                        (concat (file-name-as-directory (or d ".")) f))
 157                       (setq summary (lm-synopsis))
 158                       (setq keywords (lm-keywords)))
 159                     (insert
 160                      (format "    (\"%s\"\n        "
 161                              (if (string-match "\\.\\(gz\\|Z\\)$" f)
 162                                  (file-name-sans-extension f)
 163                                f)))
 164                     (prin1 summary (current-buffer))
 165                     (insert
 166                      "\n        ")
 167                     (setq keystart (point))
 168                     (insert
 169                      (if keywords (format "(%s)" keywords) "nil")
 170                      ")\n")
 171                     (subst-char-in-region keystart (point) ?, ? )
 172                     )))
 173             (directory-files (or d ".")))))
 174        (or dirs load-path))
 175       (insert "))\n
 176 \(provide '" (file-name-sans-extension
 177               (file-name-nondirectory generated-finder-keywords-file)) ")
 178
 179 ;;; Local Variables:
 180 ;;; version-control: never
 181 ;;; no-byte-compile: t
 182 ;;; no-update-autoloads: t
 183 ;;; End:
 184 ;;; " (file-name-nondirectory generated-finder-keywords-file) " ends here\n")
 185       (kill-buffer "*finder-scratch*")
 186       (eval-current-buffer) ;; So we get the new keyword list immediately
 187       (basic-save-buffer))))
 188
 189 (defun finder-compile-keywords-make-dist ()
 190   "Regenerate `finder-inf.el' for the Emacs distribution."
 191   (apply 'finder-compile-keywords command-line-args-left)
 192   (kill-emacs))
 193
 194 ;;; Now the retrieval code
 195
 196 (defun finder-insert-at-column (column &rest strings)
 197   "Insert, at column COLUMN, other args STRINGS."
 198   (if (>= (current-column) column) (insert "\n"))
 199   (move-to-column column t)
 200   (apply 'insert strings))
 201
 202 (defvar finder-help-echo nil)
 203
 204 (defun finder-mouse-face-on-line ()
 205   "Put `mouse-face' and `help-echo' properties on the previous line."
 206   (save-excursion
 207     (previous-line 1)
 208     (unless finder-help-echo
 209       (setq finder-help-echo
 210             (let* ((keys1 (where-is-internal 'finder-select
 211                                              finder-mode-map))
 212                    (keys (nconc (where-is-internal
 213                                  'finder-mouse-select finder-mode-map)
 214                                 keys1)))
 215               (concat (mapconcat 'key-description keys ", ")
 216                       ": select item"))))
 217     (add-text-properties
 218      (line-beginning-position) (line-end-position)
 219      '(mouse-face highlight
 220                   help-echo finder-help-echo))))
 221
 222 ;;;###autoload
 223 (defun finder-list-keywords ()
 224   "Display descriptions of the keywords in the Finder buffer."
 225   (interactive)
 226   (if (get-buffer "*Finder*")
 227       (pop-to-buffer "*Finder*")
 228     (pop-to-buffer (set-buffer (get-buffer-create "*Finder*")))
 229     (finder-mode)
 230     (setq buffer-read-only nil)
 231     (erase-buffer)
 232     (mapc
 233      (lambda (assoc)
 234        (let ((keyword (car assoc)))
 235          (insert (symbol-name keyword))
 236          (finder-insert-at-column 14 (concat (cdr assoc) "\n"))
 237          (finder-mouse-face-on-line)))
 238      finder-known-keywords)
 239     (goto-char (point-min))
 240     (setq finder-headmark (point))
 241     (setq buffer-read-only t)
 242     (set-buffer-modified-p nil)
 243     (balance-windows)
 244     (finder-summary)))
 245
 246 (defun finder-list-matches (key)
 247   (pop-to-buffer (set-buffer (get-buffer-create "*Finder Category*")))
 248   (finder-mode)
 249   (setq buffer-read-only nil)
 250   (erase-buffer)
 251   (let ((id (intern key)))
 252     (insert
 253      "The following packages match the keyword `" key "':\n\n")
 254     (setq finder-headmark (point))
 255     (mapc
 256      (lambda (x)
 257        (if (memq id (car (cdr (cdr x))))
 258            (progn
 259              (insert (car x))
 260              (finder-insert-at-column 16 (concat (nth 1 x) "\n"))
 261              (finder-mouse-face-on-line))))
 262      finder-package-info)
 263     (goto-char (point-min))
 264     (forward-line)
 265     (setq buffer-read-only t)
 266     (set-buffer-modified-p nil)
 267     (shrink-window-if-larger-than-buffer)
 268     (finder-summary)))
 269
 270 ;;;###autoload
 271 (defun finder-commentary (file)
 272   "Display FILE's commentary section.
 273 FILE should be in a form suitable for passing to `locate-library'."
 274   (interactive
 275    (list
 276     (completing-read "Library name: "
 277                      'locate-file-completion
 278                      (cons (or find-function-source-path load-path)
 279                            (find-library-suffixes)))))
 280   (let* ((str (lm-commentary (find-library-name file))))
 281     (if (null str)
 282         (error "Can't find any Commentary section"))
 283     ;; This used to use *Finder* but that would clobber the
 284     ;; directory of categories.
 285     (delete-other-windows)
 286     (pop-to-buffer "*Finder-package*")
 287     (setq buffer-read-only nil)
 288     (erase-buffer)
 289     (insert str)
 290     (goto-char (point-min))
 291     (delete-blank-lines)
 292     (goto-char (point-max))
 293     (delete-blank-lines)
 294     (goto-char (point-min))
 295     (while (re-search-forward "^;+ ?" nil t)
 296       (replace-match "" nil nil))
 297     (goto-char (point-min))
 298     (setq buffer-read-only t)
 299     (set-buffer-modified-p nil)
 300     (shrink-window-if-larger-than-buffer)
 301     (finder-mode)
 302     (finder-summary)))
 303
 304 (defun finder-current-item ()
 305   (if (and finder-headmark (< (point) finder-headmark))
 306       (error "No keyword or filename on this line")
 307     (save-excursion
 308       (beginning-of-line)
 309       (current-word))))
 310
 311 (defun finder-select ()
 312   "Select item on current line in a finder buffer."
 313   (interactive)
 314   (let ((key (finder-current-item)))
 315       (if (string-match "\\.el$" key)
 316           (finder-commentary key)
 317         (finder-list-matches key))))
 318
 319 (defun finder-mouse-select (event)
 320   "Select item in a finder buffer with the mouse."
 321   (interactive "e")
 322   (save-excursion
 323     (set-buffer (window-buffer (posn-window (event-start event))))
 324     (goto-char (posn-point (event-start event)))
 325     (finder-select)))
 326
 327 ;;;###autoload
 328 (defun finder-by-keyword ()
 329   "Find packages matching a given keyword."
 330   (interactive)
 331   (finder-list-keywords))
 332
 333 (defun finder-mode ()
 334   "Major mode for browsing package documentation.
 335 \\<finder-mode-map>
 336 \\[finder-select]       more help for the item on the current line
 337 \\[finder-exit] exit Finder mode and kill the Finder buffer."
 338   (interactive)
 339   (use-local-map finder-mode-map)
 340   (set-syntax-table emacs-lisp-mode-syntax-table)
 341   (setq mode-name "Finder")
 342   (setq major-mode 'finder-mode)
 343   (make-local-variable 'finder-headmark)
 344   (setq finder-headmark nil)
 345   (run-hooks 'finder-mode-hook))
 346
 347 (defun finder-summary ()
 348   "Summarize basic Finder commands."
 349   (interactive)
 350   (message "%s"
 351    (substitute-command-keys
 352     "\\<finder-mode-map>\\[finder-select] = select, \
 353 \\[finder-mouse-select] = select, \\[finder-list-keywords] = to \
 354 finder directory, \\[finder-exit] = quit, \\[finder-summary] = help")))
 355
 356 (defun finder-exit ()
 357   "Exit Finder mode and kill the buffer."
 358   (interactive)
 359   (or (one-window-p t)
 360       (delete-window))
 361   ;; Can happen in either buffer -- kill each of the two that exists
 362   (and (get-buffer "*Finder*")
 363        (kill-buffer "*Finder*"))
 364   (and (get-buffer "*Finder Category*")
 365        (kill-buffer "*Finder Category*")))
 366
 367 \f
 368 (provide 'finder)
 369
 370 ;;; arch-tag: ec85ff49-8cb8-41f5-a63f-9131d53ce2c5
 371 ;;; finder.el ends here